CMakeLists.txt

   1 cmake_minimum_required(VERSION 2.6)
   2
   3 project(libwebsockets)
   4
   5 set(PACKAGE "libwebsockets")
   6 set(CPACK_PACKAGE_NAME "${PACKAGE}")
   7 set(CPACK_PACKAGE_VERSION_MAJOR "1")
   8 set(CPACK_PACKAGE_VERSION_MINOR "3")
   9 set(CPACK_PACKAGE_VERSION "${CPACK_PACKAGE_VERSION_MAJOR}.${CPACK_PACKAGE_VERSION_MINOR}")
  10 set(CPACK_PACKAGE_VENDOR "andy@warmcat.com")
  11 set(CPACK_PACKAGE_DESCRIPTION_SUMMARY "${PACKAGE} ${PACKAGE_VERSION}")
  12 set(SOVERSION "4.0.0")
  13 set(CPACK_SOURCE_GENERATOR "TGZ")
  14 set(CPACK_SOURCE_PACKAGE_FILE_NAME "${CPACK_PACKAGE_NAME}-${CPACK_PACKAGE_VERSION}")
  15 set(VERSION "${CPACK_PACKAGE_VERSION}")
  16
  17 set(LWS_LIBRARY_VERSION ${CPACK_PACKAGE_VERSION})
  18 set(CMAKE_MODULE_PATH ${CMAKE_MODULE_PATH} "${PROJECT_SOURCE_DIR}/cmake/")
  19
  20 message(STATUS "CMAKE_TOOLCHAIN_FILE='${CMAKE_TOOLCHAIN_FILE}'")
  21
  22 # Try to find the current Git hash.
  23 find_package(Git)
  24 if(GIT_EXECUTABLE)
  25         execute_process(
  26     WORKING_DIRECTORY "${CMAKE_CURRENT_SOURCE_DIR}"
  27     COMMAND "${GIT_EXECUTABLE}" log -n 1 --pretty=%h
  28     OUTPUT_VARIABLE GIT_HASH
  29     OUTPUT_STRIP_TRAILING_WHITESPACE
  30     )
  31
  32     set(LWS_BUILD_HASH ${GIT_HASH})
  33     message("Git commit hash: ${LWS_BUILD_HASH}")
  34 endif()
  35
  36 option(LWS_WITH_SSL "Include SSL support (default OpenSSL, CyaSSL if LWS_USE_CYASSL is set)" ON)
  37 option(LWS_SSL_CLIENT_USE_OS_CA_CERTS "SSL support should make use of OS installed CA root certs" ON)
  38 option(LWS_USE_EXTERNAL_ZLIB "Search the system for ZLib instead of using the included one (on Windows)" OFF)
  39 option(LWS_USE_CYASSL "Use CyaSSL replacement for OpenSSL. When settings this, you also need to specify LWS_CYASSL_LIB and LWS_CYASSL_INCLUDE_DIRS" OFF)
  40 option(LWS_WITHOUT_BUILTIN_GETIFADDRS "Don't use BSD getifaddrs implementation from libwebsockets if it is missing (this will result in a compilation error) ... Default is your libc provides it. On some systems such as uclibc it doesn't exist." OFF)
  41 option(LWS_WITHOUT_CLIENT "Don't build the client part of the library" OFF)
  42 option(LWS_WITHOUT_SERVER "Don't build the server part of the library" OFF)
  43 option(LWS_LINK_TESTAPPS_DYNAMIC "Link the test apps to the shared version of the library. Default is to link statically" OFF)
  44 option(LWS_WITHOUT_TESTAPPS "Don't build the libwebsocket-test-apps" OFF)
  45 option(LWS_WITHOUT_TEST_SERVER "Don't build the test server" OFF)
  46 option(LWS_WITHOUT_TEST_SERVER_EXTPOLL "Don't build the test server version that uses external poll" OFF)
  47 option(LWS_WITHOUT_TEST_PING "Don't build the ping test application" OFF)
  48 option(LWS_WITHOUT_TEST_CLIENT "Don't build the client test application" OFF)
  49 option(LWS_WITHOUT_TEST_FRAGGLE "Don't build the ping test application" OFF)
  50 option(LWS_WITHOUT_DEBUG "Don't compile debug related code" OFF)
  51 option(LWS_WITHOUT_EXTENSIONS "Don't compile with extensions" OFF)
  52 option(LWS_WITH_LATENCY "Build latency measuring code into the library" OFF)
  53 option(LWS_WITHOUT_DAEMONIZE "Don't build the daemonization api" OFF)
  54 option(LWS_WITH_LIBEV "Compile with support for libev" OFF)
  55 option(LWS_IPV6 "Compile with support for ipv6" ON)
  56
  57 # Allow the user to override installation directories.
  58 set(LWS_INSTALL_LIB_DIR       lib CACHE PATH "Installation directory for libraries")
  59 set(LWS_INSTALL_BIN_DIR       bin CACHE PATH "Installation directory for executables")
  60 set(LWS_INSTALL_INCLUDE_DIR   include CACHE PATH "Installation directory for header files")
  61 set(LWS_INSTALL_EXAMPLES_DIR  bin CACHE PATH "Installation directory for example files")
  62
  63 if (LWS_WITHOUT_CLIENT AND LWS_WITHOUT_SERVER)
  64         message(FATAL_ERROR "Makes no sense to compile without both client or server.")
  65 endif()
  66
  67 # The base dir where the test-apps look for the SSL certs.
  68 set(LWS_OPENSSL_CLIENT_CERTS ../share CACHE PATH "Server SSL certificate directory")
  69 if (WIN32)
  70         set(LWS_OPENSSL_CLIENT_CERTS . CACHE PATH "Client SSL certificate directory")
  71 else()
  72         set(LWS_OPENSSL_CLIENT_CERTS /etc/pki/tls/certs/ CACHE PATH "Client SSL certificate directory")
  73 endif()
  74
  75 set(LWS_CYASSL_LIB CACHE PATH "Path to the CyaSSL library")
  76 set(LWS_CYASSL_INCLUDE_DIRS CACHE PATH "Path to the CyaSSL include directory")
  77
  78 if (LWS_USE_CYASSL)
  79         if ("${LWS_CYASSL_LIB}" STREQUAL "" OR "${LWS_CYASSL_INCLUDE_DIRS}" STREQUAL "")
  80                 message(FATAL_ERROR "You must set LWS_CYASSL_LIB and LWS_CYASSL_INCLUDE_DIRS when LWS_USE_CYASSL is turned on")
  81         endif()
  82         set(USE_CYASSL 1)
  83 endif()
  84
  85 if (LWS_WITHOUT_EXTENSIONS)
  86         set(LWS_NO_EXTENSIONS 1)
  87 endif()
  88
  89 if (LWS_WITH_SSL)
  90         set(LWS_OPENSSL_SUPPORT 1)
  91 endif()
  92
  93 if (LWS_SSL_CLIENT_USE_OS_CA_CERTS)
  94         set(LWS_SSL_CLIENT_USE_OS_CA_CERTS 1)
  95 endif()
  96
  97 if (LWS_WITH_LATENCY)
  98         set(LWS_LATENCY 1)
  99 endif()
 100
 101 if (LWS_WITHOUT_DAEMONIZE OR WIN32)
 102         set(LWS_NO_DAEMONIZE 1)
 103 endif()
 104
 105 if (LWS_WITHOUT_SERVER)
 106         set(LWS_NO_SERVER 1)
 107 endif()
 108
 109 if (LWS_WITHOUT_CLIENT)
 110         set(LWS_NO_CLIENT 1)
 111 endif()
 112
 113 if (LWS_WITHOUT_DEBUG)
 114         set(_DEBUG 0)
 115 else()
 116         set(_DEBUG 1)
 117 endif()
 118
 119 if (LWS_WITH_LIBEV)
 120         set(LWS_USE_LIBEV 1)
 121         set(LWS_NO_EXTERNAL_POLL 1)
 122 endif()
 123
 124 if (LWS_IPV6)
 125         set(LWS_USE_IPV6 1)
 126 endif()
 127
 128 if (MINGW)
 129         set(LWS_MINGW_SUPPORT 1)
 130 endif()
 131
 132 include_directories("${PROJECT_BINARY_DIR}")
 133
 134 include(CheckCSourceCompiles)
 135
 136 # Check for different inline keyword versions.
 137 foreach(KEYWORD "inline" "__inline__" "__inline")
 138         set(CMAKE_REQUIRED_DEFINITIONS "-DKEYWORD=${KEYWORD}")
 139         CHECK_C_SOURCE_COMPILES(
 140                 "
 141                 #include <stdio.h>
 142                 KEYWORD void a() {}
 143                 int main(int argc, char **argv) { a(); return 0; }
 144                 " HAVE_${KEYWORD})
 145 endforeach()
 146
 147 if (NOT HAVE_inline)
 148         if (HAVE___inline__)
 149                 set(inline __inline__)
 150         elseif(HAVE___inline)
 151                 set(inline __inline)
 152         endif()
 153 endif()
 154
 155 # Put the libaries and binaries that get built into directories at the
 156 # top of the build tree rather than in hard-to-find leaf directories.
 157 SET(CMAKE_RUNTIME_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin")
 158 SET(CMAKE_LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/lib")
 159 SET(CMAKE_ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/lib")
 160
 161 # Put absolute path of dynamic libraries into the object code. Some
 162 # architectures, notably Mac OS X, need this.
 163 SET(CMAKE_INSTALL_NAME_DIR "${CMAKE_INSTALL_PREFIX}/${LWS_INSTALL_LIB_DIR}${LIB_SUFFIX}")
 164
 165 # So we can include the CMake generated config file only when
 166 # building with CMAKE.
 167 add_definitions(-DCMAKE_BUILD)
 168
 169 include(CheckFunctionExists)
 170 include(CheckIncludeFile)
 171 include(CheckIncludeFiles)
 172 include(CheckLibraryExists)
 173 include(CheckTypeSize)
 174
 175 CHECK_FUNCTION_EXISTS(bzero HAVE_BZERO)
 176 CHECK_FUNCTION_EXISTS(fork HAVE_FORK)
 177 CHECK_FUNCTION_EXISTS(getenv HAVE_GETENV)
 178 CHECK_FUNCTION_EXISTS(malloc HAVE_MALLOC)
 179 CHECK_FUNCTION_EXISTS(memset HAVE_MEMSET)
 180 CHECK_FUNCTION_EXISTS(realloc HAVE_REALLOC)
 181 CHECK_FUNCTION_EXISTS(socket HAVE_SOCKET)
 182 CHECK_FUNCTION_EXISTS(strerror HAVE_STRERROR)
 183 CHECK_FUNCTION_EXISTS(vfork HAVE_VFORK)
 184 CHECK_FUNCTION_EXISTS(getifaddrs HAVE_GETIFADDRS)
 185
 186 if (NOT HAVE_GETIFADDRS)
 187         if (LWS_WITHOUT_BUILTIN_GETIFADDRS)
 188                 message(FATAL_ERROR "No getifaddrs was found on the system. Turn off the LWS_WITHOUT_BUILTIN_GETIFADDRS compile option to use the supplied BSD version.")
 189         endif()
 190
 191         set(LWS_BUILTIN_GETIFADDRS 1)
 192 endif()
 193
 194 CHECK_INCLUDE_FILE(dlfcn.h HAVE_DLFCN_H)
 195 CHECK_INCLUDE_FILE(fcntl.h HAVE_FCNTL_H)
 196 CHECK_INCLUDE_FILE(inttypes.h HAVE_INTTYPES_H)
 197 CHECK_INCLUDE_FILE(memory.h HAVE_MEMORY_H)
 198 CHECK_INCLUDE_FILE(netinet/in.h HAVE_NETINET_IN_H)
 199 CHECK_INCLUDE_FILE(stdint.h HAVE_STDINT_H)
 200 CHECK_INCLUDE_FILE(stdlib.h HAVE_STDLIB_H)
 201 CHECK_INCLUDE_FILE(strings.h HAVE_STRINGS_H)
 202 CHECK_INCLUDE_FILE(string.h HAVE_STRING_H)
 203 CHECK_INCLUDE_FILE(sys/prctl.h HAVE_SYS_PRCTL_H)
 204 CHECK_INCLUDE_FILE(sys/socket.h HAVE_SYS_SOCKET_H)
 205 CHECK_INCLUDE_FILE(sys/stat.h HAVE_SYS_STAT_H)
 206 CHECK_INCLUDE_FILE(sys/types.h HAVE_SYS_TYPES_H)
 207 CHECK_INCLUDE_FILE(unistd.h HAVE_UNISTD_H)
 208 CHECK_INCLUDE_FILE(vfork.h HAVE_VFORK_H)
 209 CHECK_INCLUDE_FILE(zlib.h HAVE_ZLIB_H)
 210
 211 # TODO: These can be tested if they actually work also...
 212 set(HAVE_WORKING_FORK HAVE_FORK)
 213 set(HAVE_WORKING_VFORK HAVE_VFORK)
 214
 215 CHECK_INCLUDE_FILES("stdlib.h;stdarg.h;string.h;float.h" STDC_HEADERS)
 216
 217 CHECK_TYPE_SIZE(pid_t PID_T_SIZE)
 218 CHECK_TYPE_SIZE(size_t SIZE_T_SIZE)
 219
 220 if (NOT PID_T_SIZE)
 221         set(pid_t int)
 222 endif()
 223
 224 if (NOT SIZE_T_SIZE)
 225         set(size_t "unsigned int")
 226 endif()
 227
 228 if (NOT HAVE_MALLOC)
 229         set(malloc rpl_malloc)
 230 endif()
 231
 232 if (NOT HAVE_REALLOC)
 233         set(realloc rpl_realloc)
 234 endif()
 235
 236 # Generate the config.h that includes all the compilation settings.
 237 configure_file(
 238        "${PROJECT_SOURCE_DIR}/config.h.cmake"
 239        "${PROJECT_BINARY_DIR}/lws_config.h")
 240
 241 if (MSVC)
 242         # Turn off stupid microsoft security warnings.
 243         add_definitions(-D_CRT_SECURE_NO_DEPRECATE -D_CRT_NONSTDC_NO_DEPRECATE)
 244 endif(MSVC)
 245
 246 include_directories("${PROJECT_SOURCE_DIR}/lib")
 247
 248 # Group headers and sources.
 249 # Some IDEs use this for nicer file structure.
 250 set(HDR_PRIVATE
 251         lib/private-libwebsockets.h
 252         "${PROJECT_BINARY_DIR}/lws_config.h"
 253         )
 254
 255 set(HDR_PUBLIC
 256         "${PROJECT_SOURCE_DIR}/lib/libwebsockets.h"
 257         )
 258
 259 set(SOURCES
 260         lib/base64-decode.c
 261         lib/handshake.c
 262         lib/libwebsockets.c
 263         lib/output.c
 264         lib/parsers.c
 265         lib/sha-1.c
 266         )
 267
 268 if (NOT LWS_WITHOUT_CLIENT)
 269         list(APPEND SOURCES
 270                 lib/client.c
 271                 lib/client-handshake.c
 272                 lib/client-parser.c
 273                 )
 274 endif()
 275
 276 # select the active platform files
 277
 278 if (WIN32)
 279         list(APPEND SOURCES
 280                 lib/lws-plat-win.c
 281                 )
 282 else()
 283         list(APPEND SOURCES
 284                 lib/lws-plat-unix.c
 285                 )
 286 endif()
 287
 288 if (NOT LWS_WITHOUT_SERVER)
 289         list(APPEND SOURCES
 290                 lib/server.c
 291                 lib/server-handshake.c
 292                 )
 293 endif()
 294
 295 if (NOT LWS_WITHOUT_EXTENSIONS)
 296         list(APPEND HDR_PRIVATE
 297                 lib/extension-deflate-frame.h
 298                 lib/extension-deflate-stream.h
 299                 )
 300
 301         list(APPEND SOURCES
 302                 lib/extension.c
 303                 lib/extension-deflate-frame.c
 304                 lib/extension-deflate-stream.c
 305                 )
 306 endif()
 307
 308 # Add helper files for Windows.
 309 if (WIN32)
 310         set(WIN32_HELPERS_PATH win32port/win32helpers)
 311         include_directories(${WIN32_HELPERS_PATH})
 312 else(WIN32)
 313         # Unix.
 314         if (NOT LWS_WITHOUT_DAEMONIZE)
 315                 list(APPEND SOURCES
 316                         lib/daemonize.c
 317                         )
 318         endif()
 319 endif(WIN32)
 320
 321 if (UNIX)
 322         if (NOT HAVE_GETIFADDRS)
 323                 list(APPEND HDR_PRIVATE lib/getifaddrs.h)
 324                 list(APPEND SOURCES lib/getifaddrs.c)
 325         endif()
 326 endif(UNIX)
 327
 328
 329 if (CMAKE_COMPILER_IS_GNUCC OR CMAKE_COMPILER_IS_GNUCXX)
 330     if (UNIX)
 331         set( CMAKE_C_FLAGS "-Wall -Werror -O4 -fvisibility=hidden ${CMAKE_C_FLAGS}" )
 332     else(UNIX)
 333         set( CMAKE_C_FLAGS "-Wall -O4 -fvisibility=hidden ${CMAKE_C_FLAGS}" )
 334     endif(UNIX)
 335 endif ()
 336
 337 source_group("Headers Private"  FILES ${HDR_PRIVATE})
 338 source_group("Headers Public"   FILES ${HDR_PUBLIC})
 339 source_group("Sources"          FILES ${SOURCES})
 340
 341 #
 342 # Create the lib.
 343 #
 344 add_library(websockets STATIC
 345                         ${HDR_PRIVATE}
 346                         ${HDR_PUBLIC}
 347                         ${SOURCES})
 348 add_library(websockets_shared SHARED
 349                         ${HDR_PRIVATE}
 350                         ${HDR_PUBLIC}
 351                         ${SOURCES})
 352
 353 if (WIN32)
 354         # On Windows libs have the same file ending (.lib)
 355         # for both static and shared libraries, so we
 356         # need a unique name for the static one.
 357         set_target_properties(websockets
 358                 PROPERTIES
 359                 OUTPUT_NAME websockets_static)
 360
 361         # Compile as DLL (export function declarations)
 362         set_property(
 363                 TARGET websockets_shared
 364                 PROPERTY COMPILE_DEFINITIONS
 365                 LWS_DLL
 366                 LWS_INTERNAL
 367                 )
 368 endif(WIN32)
 369
 370 # We want the shared lib to be named "libwebsockets"
 371 # not "libwebsocket_shared".
 372 set_target_properties(websockets_shared
 373                 PROPERTIES
 374                 OUTPUT_NAME websockets)
 375
 376 # Set the so version of the lib.
 377 # Equivalent to LDFLAGS=-version-info x:x:x
 378 if(CMAKE_COMPILER_IS_GNUCC OR CMAKE_COMPILER_IS_GNUCXX)
 379         foreach(lib websockets websockets_shared)
 380                 set_target_properties(${lib}
 381                         PROPERTIES
 382                         SOVERSION ${SOVERSION})
 383         endforeach()
 384 endif()
 385
 386 set(LIB_LIST)
 387
 388 #
 389 # Find libraries.
 390 #
 391
 392 #
 393 # ZLIB (Only needed for deflate extensions).
 394 #
 395 if (NOT LWS_WITHOUT_EXTENSIONS)
 396         if (WIN32 AND NOT LWS_USE_EXTERNAL_ZLIB)
 397                 message("Using included Zlib version")
 398
 399                 # Compile ZLib if needed.
 400                 set(WIN32_ZLIB_PATH "win32port/zlib")
 401                 set(ZLIB_SRCS
 402                         ${WIN32_ZLIB_PATH}/adler32.c
 403                         ${WIN32_ZLIB_PATH}/compress.c
 404                         ${WIN32_ZLIB_PATH}/crc32.c
 405                         ${WIN32_ZLIB_PATH}/deflate.c
 406                         ${WIN32_ZLIB_PATH}/gzclose.c
 407                         ${WIN32_ZLIB_PATH}/gzio.c
 408                         ${WIN32_ZLIB_PATH}/gzlib.c
 409                         ${WIN32_ZLIB_PATH}/gzread.c
 410                         ${WIN32_ZLIB_PATH}/gzwrite.c
 411                         ${WIN32_ZLIB_PATH}/infback.c
 412                         ${WIN32_ZLIB_PATH}/inffast.c
 413                         ${WIN32_ZLIB_PATH}/inflate.c
 414                         ${WIN32_ZLIB_PATH}/inftrees.c
 415                         ${WIN32_ZLIB_PATH}/trees.c
 416                         ${WIN32_ZLIB_PATH}/uncompr.c
 417                         ${WIN32_ZLIB_PATH}/zutil.c
 418                 )
 419
 420                 # Create the library.
 421                 add_library(ZLIB STATIC ${ZLIB_SRCS})
 422
 423                 # Set the same variables as find_package would.
 424                 set(ZLIB_INCLUDE_DIRS ${WIN32_ZLIB_PATH})
 425                 get_property(ZLIB_LIBRARIES TARGET ZLIB PROPERTY LOCATION)
 426                 set(ZLIB_FOUND 1)
 427         else()
 428                 find_package(ZLIB REQUIRED)
 429         endif()
 430
 431         # Make sure ZLib is compiled before the libs.
 432         foreach (lib websockets websockets_shared)
 433                 add_dependencies(${lib} ZLIB)
 434         endforeach()
 435
 436         message("ZLib include dirs: ${ZLIB_INCLUDE_DIRS}")
 437         message("ZLib libraries: ${ZLIB_LIBRARIES}")
 438         include_directories(${ZLIB_INCLUDE_DIRS})
 439         list(APPEND LIB_LIST ${ZLIB_LIBRARIES})
 440 endif(NOT LWS_WITHOUT_EXTENSIONS)
 441
 442 #
 443 # OpenSSL
 444 #
 445 if (LWS_WITH_SSL)
 446         message("Compiling with SSL support")
 447
 448         if (LWS_USE_CYASSL)
 449                 # Use CyaSSL as OpenSSL replacement.
 450                 # TODO: Add a find_package command for this also.
 451                 message("CyaSSL include dir: ${LWS_CYASSL_INCLUDE_DIRS}")
 452                 message("CyaSSL libraries: ${LWS_CYASSL_LIB}")
 453
 454                 # Additional to the root directory we need to include
 455                 # the cyassl/ subdirectory which contains the OpenSSL
 456                 # compatability layer headers.
 457                 foreach(inc ${LWS_CYASSL_INCLUDE_DIRS})
 458                         include_directories("${inc}" "${inc}/cyassl")
 459                 endforeach()
 460
 461                 list(APPEND LIB_LIST "${LWS_CYASSL_LIB}")
 462         else()
 463                 # TODO: Add support for STATIC also.
 464                 find_package(OpenSSL REQUIRED)
 465
 466                 message("OpenSSL include dir: ${OPENSSL_INCLUDE_DIR}")
 467                 message("OpenSSL libraries: ${OPENSSL_LIBRARIES}")
 468
 469                 include_directories("${OPENSSL_INCLUDE_DIR}")
 470                 list(APPEND LIB_LIST ${OPENSSL_LIBRARIES})
 471         endif()
 472 endif(LWS_WITH_SSL)
 473
 474 if (LWS_WITH_LIBEV)
 475         list(APPEND LIB_LIST "ev")
 476 endif(LWS_WITH_LIBEV)
 477
 478 #
 479 # Platform specific libs.
 480 #
 481 if (WINCE)
 482         list(APPEND LIB_LIST ws2.lib)
 483 elseif (WIN32)
 484         list(APPEND LIB_LIST ws2_32.lib)
 485 endif()
 486
 487 if (UNIX)
 488         list(APPEND LIB_LIST m)
 489 endif()
 490
 491 # Setup the linking for all libs.
 492 foreach (lib websockets websockets_shared)
 493         target_link_libraries(${lib} ${LIB_LIST})
 494 endforeach()
 495
 496 #
 497 # Test applications
 498 #
 499 set(TEST_APP_LIST)
 500 if (NOT LWS_WITHOUT_TESTAPPS)
 501         #
 502         # Helper function for adding a test app.
 503         #
 504         macro(create_test_app TEST_NAME MAIN_SRC)
 505
 506                 set(TEST_SRCS ${MAIN_SRC})
 507                 set(TEST_HDR)
 508
 509                 if (WIN32)
 510                         list(APPEND TEST_SRCS
 511                                 ${WIN32_HELPERS_PATH}/getopt.c
 512                                 ${WIN32_HELPERS_PATH}/getopt_long.c
 513                                 ${WIN32_HELPERS_PATH}/gettimeofday.c
 514                         )
 515
 516                         list(APPEND TEST_HDR
 517                                 ${WIN32_HELPERS_PATH}/getopt.h
 518                                 ${WIN32_HELPERS_PATH}/gettimeofday.h
 519                         )
 520                 endif(WIN32)
 521
 522                 source_group("Headers Private"   FILES ${TEST_HDR})
 523                 source_group("Sources"   FILES ${TEST_SRCS})
 524                 add_executable(${TEST_NAME} ${TEST_SRCS} ${TEST_HDR})
 525
 526                 if (LWS_LINK_TESTAPPS_DYNAMIC)
 527                         target_link_libraries(${TEST_NAME} websockets_shared)
 528                         add_dependencies(${TEST_NAME} websockets_shared)
 529                 else(LWS_LINK_TESTAPPS_DYNAMIC)
 530                         target_link_libraries(${TEST_NAME} websockets)
 531                         add_dependencies(${TEST_NAME} websockets)
 532                 endif(LWS_LINK_TESTAPPS_DYNAMIC)
 533
 534                 # Set test app specific defines.
 535                 set_property(TARGET ${TEST_NAME}
 536                                         PROPERTY COMPILE_DEFINITIONS
 537                                                 INSTALL_DATADIR="${CMAKE_INSTALL_PREFIX}/share"
 538                                         )
 539
 540                 # Prefix the binary names with libwebsockets.
 541                 set_target_properties(${TEST_NAME}
 542                         PROPERTIES
 543                         OUTPUT_NAME libwebsockets-${TEST_NAME})
 544
 545                 # Add to the list of tests.
 546                 list(APPEND TEST_APP_LIST ${TEST_NAME})
 547         endmacro()
 548
 549         if (LWS_WITH_SSL AND NOT LWS_USE_CYASSL)
 550                 message("Searching for OpenSSL executable and dlls")
 551                 find_package(OpenSSLbins)
 552                 message("OpenSSL executable: ${OPENSSL_EXECUTABLE}")
 553         endif()
 554
 555         if (NOT LWS_WITHOUT_SERVER)
 556                 #
 557                 # test-server
 558                 #
 559                 if (NOT LWS_WITHOUT_TEST_SERVER)
 560                         create_test_app(test-server "test-server/test-server.c")
 561                 endif()
 562
 563                 #
 564                 # test-server-extpoll
 565                 #
 566                 if (NOT LWS_WITHOUT_TEST_SERVER_EXTPOLL)
 567                         create_test_app(test-server-extpoll "test-server/test-server.c")
 568                         # Set defines for this executable only.
 569                         set_property(
 570                                 TARGET test-server-extpoll
 571                                 PROPERTY COMPILE_DEFINITIONS
 572                                         EXTERNAL_POLL
 573                                         INSTALL_DATADIR="${CMAKE_INSTALL_PREFIX}/share"
 574                                 )
 575
 576                         # We need to link against winsock code.
 577                         if (WIN32)
 578                                 target_link_libraries(test-server-extpoll ws2_32.lib)
 579                         endif(WIN32)
 580                 endif()
 581
 582                 # Data files for running the test server.
 583                 set(TEST_SERVER_DATA
 584                         "${PROJECT_SOURCE_DIR}/test-server/favicon.ico"
 585                         "${PROJECT_SOURCE_DIR}/test-server/leaf.jpg"
 586                         "${PROJECT_SOURCE_DIR}/test-server/libwebsockets.org-logo.png"
 587                         "${PROJECT_SOURCE_DIR}/test-server/test.html")
 588
 589                 # Generate self-signed SSL certs for the test-server.
 590                 if (LWS_WITH_SSL AND OPENSSL_EXECUTABLE AND NOT LWS_WITHOUT_TEST_SERVER)
 591                         message("Generating SSL Certificates for the test-server...")
 592
 593                         set(TEST_SERVER_SSL_KEY "${PROJECT_BINARY_DIR}/libwebsockets-test-server.key.pem")
 594                         set(TEST_SERVER_SSL_CERT "${PROJECT_BINARY_DIR}/libwebsockets-test-server.pem")
 595
 596                         if (WIN32)
 597                                 file(WRITE "${PROJECT_BINARY_DIR}/openssl_input.txt"
 598                                         "GB\n"
 599                                         "Erewhon\n"
 600                                         "All around\n"
 601                                         "libwebsockets-test\n"
 602                                         "localhost\n"
 603                                         "none@invalid.org\n\n"
 604                                         )
 605
 606                                 # The "type" command is a bit picky with paths.
 607                                 file(TO_NATIVE_PATH "${PROJECT_BINARY_DIR}/openssl_input.txt" OPENSSL_INPUT_WIN_PATH)
 608                                 message("OPENSSL_INPUT_WIN_PATH = ${OPENSSL_INPUT_WIN_PATH}")
 609                                 message("cmd = \"${OPENSSL_EXECUTABLE}\" req -new -newkey rsa:1024 -days 10000 -nodes -x509 -keyout \"${TEST_SERVER_SSL_KEY}\" -out \"${TEST_SERVER_SSL_CERT}\"")
 610
 611                                 execute_process(
 612                                         COMMAND cmd /c type "${OPENSSL_INPUT_WIN_PATH}"
 613                                         COMMAND "${OPENSSL_EXECUTABLE}" req -new -newkey rsa:1024 -days 10000 -nodes -x509 -keyout "${TEST_SERVER_SSL_KEY}" -out "${TEST_SERVER_SSL_CERT}"
 614                                         RESULT_VARIABLE OPENSSL_RETURN_CODE)
 615
 616                                 message("\n")
 617
 618                                 if (OPENSSL_RETURN_CODE)
 619                                         message(WARNING "!!! Failed to generate SSL certificate for Test Server using cmd.exe !!!:\nOpenSSL return code = ${OPENSSL_RETURN_CODE}")
 620                                 else()
 621                                         message("SUCCSESFULLY generated SSL certificate")
 622                                 endif()
 623                         else()
 624                                 # Unix.
 625                                 execute_process(
 626                                         COMMAND printf "GB\\nErewhon\\nAll around\\nlibwebsockets-test\\n\\nlocalhost\\nnone@invalid.org\\n"
 627                                         COMMAND "${OPENSSL_EXECUTABLE}"
 628                                                 req -new -newkey rsa:1024 -days 10000 -nodes -x509 -keyout "${TEST_SERVER_SSL_KEY}" -out "${TEST_SERVER_SSL_CERT}"
 629                                         RESULT_VARIABLE OPENSSL_RETURN_CODE)
 630
 631                                 if (OPENSSL_RETURN_CODE)
 632                                         message(WARNING "!!! Failed to generate SSL certificate for Test Server!!!:\nOpenSSL return code = ${OPENSSL_RETURN_CODE}")
 633                                 else()
 634                                         message("SUCCSESFULLY generated SSL certificate")
 635                                 endif()
 636                         endif()
 637
 638                         list(APPEND TEST_SERVER_DATA
 639                                 "${TEST_SERVER_SSL_KEY}"
 640                                 "${TEST_SERVER_SSL_CERT}")
 641                 endif()
 642
 643                 add_custom_command(TARGET test-server
 644                                                 POST_BUILD
 645                                                 COMMAND "${CMAKE_COMMAND}" -E make_directory "$<TARGET_FILE_DIR:test-server>/../share/libwebsockets-test-server")
 646
 647                 # Copy the file needed to run the server so that the test apps can
 648                 # reach them from their default output location
 649                 foreach (TEST_FILE ${TEST_SERVER_DATA})
 650                         if (EXISTS ${TEST_FILE})
 651                                 add_custom_command(TARGET test-server
 652                                                         POST_BUILD
 653                                                         COMMAND "${CMAKE_COMMAND}" -E copy "${TEST_FILE}" "$<TARGET_FILE_DIR:test-server>/../share/libwebsockets-test-server" VERBATIM)
 654                         endif()
 655                 endforeach()
 656         endif(NOT LWS_WITHOUT_SERVER)
 657
 658         if (NOT LWS_WITHOUT_CLIENT)
 659                 #
 660                 # test-client
 661                 #
 662                 if (NOT LWS_WITHOUT_TEST_CLIENT)
 663                         create_test_app(test-client "test-server/test-client.c")
 664                 endif()
 665
 666                 #
 667                 # test-fraggle
 668                 #
 669                 if (NOT LWS_WITHOUT_TEST_FRAGGLE)
 670                         create_test_app(test-fraggle "test-server/test-fraggle.c")
 671                 endif()
 672
 673                 #
 674                 # test-ping
 675                 #
 676                 if (NOT LWS_WITHOUT_TEST_PING)
 677                         create_test_app(test-ping "test-server/test-ping.c")
 678                 endif()
 679                 #
 680                 # test-echo
 681                 #
 682                 if (NOT WITHOUT_TEST_ECHO)
 683                         create_test_app(test-echo "test-server/test-echo.c")
 684                 endif()
 685
 686         endif(NOT LWS_WITHOUT_CLIENT)
 687
 688         #
 689         # Copy OpenSSL dlls to the output directory on Windows.
 690         # (Otherwise we'll get an error when trying to run)
 691         #
 692         if (WIN32 AND LWS_WITH_SSL AND NOT LWS_USE_CYASSL)
 693                 if(OPENSSL_BIN_FOUND)
 694                         message("OpenSSL dlls found:")
 695                         message("  Libeay: ${LIBEAY_BIN}")
 696                         message("  SSLeay: ${SSLEAY_BIN}")
 697
 698                         foreach(TARGET_BIN ${TEST_APP_LIST})
 699                                 add_custom_command(TARGET ${TARGET_BIN}
 700                                         POST_BUILD
 701                                         COMMAND "${CMAKE_COMMAND}" -E copy "${LIBEAY_BIN}" "$<TARGET_FILE_DIR:${TARGET_BIN}>" VERBATIM)
 702
 703                                 add_custom_command(TARGET ${TARGET_BIN}
 704                                         POST_BUILD
 705                                         COMMAND "${CMAKE_COMMAND}" -E copy "${SSLEAY_BIN}" "$<TARGET_FILE_DIR:${TARGET_BIN}>" VERBATIM)
 706                         endforeach()
 707                 endif()
 708         endif()
 709 endif(NOT LWS_WITHOUT_TESTAPPS)
 710
 711 if (UNIX)
 712         # Generate documentation.
 713         # TODO: Fix this on Windows.
 714         message("Generating API documentation")
 715         file(GLOB C_FILES "${PROJECT_SOURCE_DIR}/lib/*.c")
 716         execute_process(COMMAND "${CMAKE_COMMAND}" -E make_directory "${PROJECT_BINARY_DIR}/doc/")
 717
 718         execute_process(
 719                 COMMAND "${PROJECT_SOURCE_DIR}/scripts/kernel-doc" -html ${C_FILES} ${HDR_PUBLIC}
 720                 OUTPUT_FILE "${PROJECT_BINARY_DIR}/doc/libwebsockets-api-doc.html"
 721                 ERROR_QUIET)
 722
 723         execute_process(
 724                 COMMAND "${PROJECT_SOURCE_DIR}/scripts/kernel-doc" -text ${C_FILES} ${HDR_PUBLIC}
 725                 OUTPUT_FILE "${PROJECT_BINARY_DIR}/doc/libwebsockets-api-doc.txt"
 726                 ERROR_QUIET)
 727
 728 # Generate and install pkgconfig.
 729 # (This is not indented, because the tabs will be part of the output)
 730 file(WRITE "${PROJECT_BINARY_DIR}/libwebsockets.pc"
 731 "prefix=\"${CMAKE_INSTALL_PREFIX}\"
 732 exec_prefix=\${prefix}
 733 libdir=\${exec_prefix}/lib${LIB_SUFFIX}
 734 includedir=\${prefix}/include
 735
 736 Name: libwebsockets
 737 Description: Websockets server and client library
 738 Version: ${CPACK_PACKAGE_VERSION_MAJOR}.${CPACK_PACKAGE_VERSION_MINOR}
 739
 740 Libs: -L\${libdir} -lwebsockets
 741 Cflags: -I\${includedir}"
 742 )
 743
 744         install(FILES "${PROJECT_BINARY_DIR}/libwebsockets.pc"
 745                 DESTINATION lib${LIB_SUFFIX}/pkgconfig)
 746 endif(UNIX)
 747
 748 #
 749 # Installation preparations.
 750 #
 751
 752 if(WIN32 AND NOT CYGWIN)
 753   set(DEF_INSTALL_CMAKE_DIR cmake)
 754 else()
 755   set(DEF_INSTALL_CMAKE_DIR lib/cmake/libwebsockets)
 756 endif()
 757
 758 set(LWS_INSTALL_CMAKE_DIR ${DEF_INSTALL_CMAKE_DIR} CACHE PATH "Installation directory for CMake files")
 759
 760 # Export targets (This is used for other CMake projects to easily find the libraries and include files).
 761 export(TARGETS websockets websockets_shared
 762         FILE "${PROJECT_BINARY_DIR}/LibwebsocketsTargets.cmake")
 763 export(PACKAGE libwebsockets)
 764
 765 # Generate the config file for the build-tree.
 766 set(LWS__INCLUDE_DIRS
 767     "${PROJECT_SOURCE_DIR}/lib"
 768     "${PROJECT_BINARY_DIR}")
 769 set(LIBWEBSOCKETS_INCLUDE_DIRS ${LWS__INCLUDE_DIRS} CACHE PATH "Libwebsockets include directories")
 770 configure_file(${PROJECT_SOURCE_DIR}/cmake/LibwebsocketsConfig.cmake.in
 771                 ${PROJECT_BINARY_DIR}/LibwebsocketsConfig.cmake
 772                 @ONLY)
 773
 774 # Generate the config file for the installation tree.
 775 get_filename_component(LWS_ABSOLUTE_INSTALL_CMAKE_DIR ${LWS_INSTALL_CMAKE_DIR} ABSOLUTE)
 776 get_filename_component(LWS_ABSOLUTE_INSTALL_INCLUDE_DIR ${LWS_INSTALL_INCLUDE_DIR} ABSOLUTE)
 777 file(RELATIVE_PATH
 778     REL_INCLUDE_DIR
 779     "${LWS_ABSOLUTE_INSTALL_CMAKE_DIR}"
 780     "${LWS_ABSOLUTE_INSTALL_INCLUDE_DIR}") # Calculate the relative directory from the cmake dir.
 781
 782 # Note the EVENT_CMAKE_DIR is defined in JanssonConfig.cmake.in,
 783 # we escape it here so it's evaluated when it is included instead
 784 # so that the include dirs are given relative to where the
 785 # config file is located.
 786 set(LWS__INCLUDE_DIRS
 787     "\${LWS_CMAKE_DIR}/${REL_INCLUDE_DIR}")
 788 configure_file(${PROJECT_SOURCE_DIR}/cmake/LibwebsocketsConfig.cmake.in
 789                 ${PROJECT_BINARY_DIR}${CMAKE_FILES_DIRECTORY}/LibwebsocketsConfig.cmake
 790                 @ONLY)
 791
 792 # Generate version info for both build-tree and install-tree.
 793 configure_file(${PROJECT_SOURCE_DIR}/cmake/LibwebsocketsConfigVersion.cmake.in
 794                 ${PROJECT_BINARY_DIR}/LibwebsocketsConfigVersion.cmake
 795                 @ONLY)
 796
 797 set_target_properties(websockets websockets_shared
 798                                         PROPERTIES PUBLIC_HEADER "${HDR_PUBLIC}")
 799
 800 #
 801 # Installation.
 802 #
 803
 804 # Install libs and headers.
 805 install(TARGETS websockets websockets_shared
 806                 EXPORT LibwebsocketsTargets
 807                 LIBRARY DESTINATION "${LWS_INSTALL_LIB_DIR}${LIB_SUFFIX}" COMPONENT libraries
 808                 ARCHIVE DESTINATION "${LWS_INSTALL_LIB_DIR}${LIB_SUFFIX}" COMPONENT libraries
 809                 RUNTIME DESTINATION "${LWS_INSTALL_BIN_DIR}" COMPONENT libraries # Windows DLLs
 810                 PUBLIC_HEADER DESTINATION "${LWS_INSTALL_INCLUDE_DIR}" COMPONENT dev)
 811 set(CPACK_COMPONENT_LIBRARIES_DISPLAY_NAME "Libraries")
 812 set(CPACK_COMPONENT_DEV_DISPLAY_NAME "Development files")
 813
 814 # Install test apps.
 815 if (NOT LWS_WITHOUT_TESTAPPS AND NOT LWS_WITHOUT_CLIENT)
 816         install(TARGETS test-client ${TEST_APP_LIST}
 817                         RUNTIME DESTINATION ${LWS_INSTALL_EXAMPLES_DIR}
 818                         COMPONENT examples)
 819         set(CPACK_COMPONENT_EXAMPLES_DISPLAY_NAME "Example files")
 820 endif()
 821
 822 # Programs shared files used by the test-server.
 823 if (NOT LWS_WITHOUT_TESTAPPS AND NOT LWS_WITHOUT_SERVER)
 824         install(FILES ${TEST_SERVER_DATA}
 825                         DESTINATION share/libwebsockets-test-server
 826                         COMPONENT examples)
 827 endif()
 828
 829 # Install exports for the install-tree.
 830 install(EXPORT LibwebsocketsTargets
 831                 DESTINATION "${LWS_INSTALL_CMAKE_DIR}" COMPONENT dev)
 832
 833 # build subdir is not part of sources
 834 set(CPACK_SOURCE_IGNORE_FILES $(CPACK_SOURCE_IGNORE_FILES) ".git" "build" "tgz" "tar.gz")
 835
 836 # Most people are more used to "make dist" compared to "make package_source"
 837 add_custom_target(dist COMMAND "${CMAKE_MAKE_PROGRAM}" package_source)
 838
 839 include(UseRPMTools)
 840 if (RPMTools_FOUND)
 841         RPMTools_ADD_RPM_TARGETS(libwebsockets libwebsockets.spec)
 842 endif()
 843
 844 message("---------------------------------------------------------------------")
 845 message("  Settings:  (For more help do cmake -LH <srcpath>")
 846 message("---------------------------------------------------------------------")
 847 message(" LWS_WITH_SSL = ${LWS_WITH_SSL}  (SSL Support)")
 848 message(" LWS_SSL_CLIENT_USE_OS_CA_CERTS = ${LWS_SSL_CLIENT_USE_OS_CA_CERTS}")
 849 message(" LWS_USE_CYASSL = ${LWS_USE_CYASSL} (CyaSSL replacement for OpenSSL)")
 850 if (LWS_USE_CYASSL)
 851         message("   LWS_CYASSL_LIB = ${LWS_CYASSL_LIB}")
 852         message("   LWS_CYASSL_INCLUDE_DIRS = ${LWS_CYASSL_INCLUDE_DIRS}")
 853 endif()
 854 message(" LWS_WITHOUT_BUILTIN_GETIFADDRS = ${LWS_WITHOUT_BUILTIN_GETIFADDRS}")
 855 message(" LWS_WITHOUT_CLIENT = ${LWS_WITHOUT_CLIENT}")
 856 message(" LWS_WITHOUT_SERVER = ${LWS_WITHOUT_SERVER}")
 857 message(" LWS_LINK_TESTAPPS_DYNAMIC = ${LWS_LINK_TESTAPPS_DYNAMIC}")
 858 message(" LWS_WITHOUT_TESTAPPS = ${LWS_WITHOUT_TESTAPPS}")
 859 message(" LWS_WITHOUT_TEST_SERVER = ${LWS_WITHOUT_TEST_SERVER}")
 860 message(" LWS_WITHOUT_TEST_SERVER_EXTPOLL = ${LWS_WITHOUT_TEST_SERVER_EXTPOLL}")
 861 message(" LWS_WITHOUT_TEST_PING = ${LWS_WITHOUT_TEST_PING}")
 862 message(" LWS_WITHOUT_TEST_CLIENT = ${LWS_WITHOUT_TEST_CLIENT}")
 863 message(" LWS_WITHOUT_TEST_FRAGGLE = ${LWS_WITHOUT_TEST_FRAGGLE}")
 864 message(" LWS_WITHOUT_DEBUG = ${LWS_WITHOUT_DEBUG}")
 865 message(" LWS_WITHOUT_EXTENSIONS = ${LWS_WITHOUT_EXTENSIONS}")
 866 message(" LWS_WITH_LATENCY = ${LWS_WITH_LATENCY}")
 867 message(" LWS_WITHOUT_DAEMONIZE = ${LWS_WITHOUT_DAEMONIZE}")
 868 message(" LWS_USE_LIBEV = ${LWS_USE_LIBEV}")
 869 message(" LWS_USE_IPV6 = ${LWS_USE_IPV6}")
 870 message("---------------------------------------------------------------------")
 871
 872 # These will be available to parent projects including libwebsockets using add_subdirectory()
 873 set(LIBWEBSOCKETS_LIBRARIES websocket websockets_shared CACHE STRING "Libwebsocket libraries")
 874 set(LIBWEBSOCKETS_LIBRARIES_STATIC websocket CACHE STRING "Libwebsocket static library")
 875 set(LIBWEBSOCKETS_LIBRARIES_SHARED websockets_shared CACHE STRING "Libwebsocket shared library")
 876
 877 # This must always be last!
 878 include(CPack)