CMakeLists.txt

   1 cmake_minimum_required(VERSION 2.8.10)
   2
   3 # Set a default build type if none was specified
   4 if(NOT CMAKE_BUILD_TYPE AND NOT CMAKE_CONFIGURATION_TYPES)
   5   message(STATUS "Setting build type to 'Release' as none was specified.")
   6   set(CMAKE_BUILD_TYPE Release CACHE STRING "Choose the type of build." FORCE)
   7   # Set the possible values of build type for cmake-gui
   8   set_property(CACHE CMAKE_BUILD_TYPE PROPERTY STRINGS "Debug" "Release" "MinSizeRel" "RelWithDebInfo")
   9 endif()
  10
  11 project(LAPACK Fortran)
  12
  13 set(LAPACK_MAJOR_VERSION 3)
  14 set(LAPACK_MINOR_VERSION 6)
  15 set(LAPACK_PATCH_VERSION 1)
  16 set(
  17   LAPACK_VERSION
  18   ${LAPACK_MAJOR_VERSION}.${LAPACK_MINOR_VERSION}.${LAPACK_PATCH_VERSION}
  19   )
  20
  21 # Updated OSX RPATH settings
  22 # In response to CMake 3.0 generating warnings regarding policy CMP0042,
  23 # the OSX RPATH settings have been updated per recommendations found
  24 # in the CMake Wiki:
  25 #  http://www.cmake.org/Wiki/CMake_RPATH_handling#Mac_OS_X_and_the_RPATH
  26     set(CMAKE_MACOSX_RPATH ON)
  27     set(CMAKE_SKIP_BUILD_RPATH FALSE)
  28     set(CMAKE_BUILD_WITH_INSTALL_RPATH FALSE)
  29     list(FIND CMAKE_PLATFORM_IMPLICIT_LINK_DIRECTORIES "${CMAKE_INSTALL_PREFIX}/lib${LIB_SUFFIX}" isSystemDir)
  30     if("${isSystemDir}" STREQUAL "-1")
  31         set(CMAKE_INSTALL_RPATH "${CMAKE_INSTALL_PREFIX}/lib${LIB_SUFFIX}")
  32         set(CMAKE_INSTALL_RPATH_USE_LINK_PATH TRUE)
  33     endif()
  34
  35
  36 # Configure the warning and code coverage suppression file
  37 configure_file(
  38   "${LAPACK_SOURCE_DIR}/CTestCustom.cmake.in"
  39   "${LAPACK_BINARY_DIR}/CTestCustom.cmake"
  40   @ONLY
  41 )
  42
  43 # Add the CMake directory for custon CMake modules
  44 set(CMAKE_MODULE_PATH "${LAPACK_SOURCE_DIR}/CMAKE" ${CMAKE_MODULE_PATH})
  45 include(PreventInSourceBuilds)
  46 include(PreventInBuildInstalls)
  47
  48 if (UNIX)
  49    if ( "${CMAKE_Fortran_COMPILER}" MATCHES "ifort" )
  50   set( CMAKE_Fortran_FLAGS "${CMAKE_Fortran_FLAGS} -fp-model strict" )
  51    endif ()
  52    if ( "${CMAKE_Fortran_COMPILER}" MATCHES "xlf" )
  53   set( CMAKE_Fortran_FLAGS "${CMAKE_Fortran_FLAGS} -qnosave -qstrict=none" )
  54    endif ()
  55 # Delete libmtsk in linking sequence for Sun/Oracle Fortran Compiler.
  56 # This library is not present in the Sun package SolarisStudio12.3-linux-x86-bin
  57    string(REPLACE \;mtsk\; \; CMAKE_Fortran_IMPLICIT_LINK_LIBRARIES "${CMAKE_Fortran_IMPLICIT_LINK_LIBRARIES}")
  58 endif ()
  59
  60 if ( CMAKE_Fortran_COMPILER_ID STREQUAL "Compaq" )
  61    if ( WIN32 )
  62       if (CMAKE_GENERATOR STREQUAL "NMake Makefiles")
  63          get_filename_component(CMAKE_Fortran_COMPILER_CMDNAM ${CMAKE_Fortran_COMPILER} NAME_WE)
  64          message(STATUS "Using Compaq Fortran compiler with command name ${CMAKE_Fortran_COMPILER_CMDNAM}")
  65          set( cmd ${CMAKE_Fortran_COMPILER_CMDNAM} )
  66          string( TOLOWER "${cmd}" cmdlc )
  67          if ( cmdlc STREQUAL "df" )
  68             message(STATUS "Assume the Compaq Visual Fortran Compiler is being used")
  69             set(CMAKE_Fortran_USE_RESPONSE_FILE_FOR_OBJECTS 1)
  70             set(CMAKE_Fortran_USE_RESPONSE_FILE_FOR_INCLUDES 1)
  71             #This is a workaround that is needed to avoid forward-slashes in the
  72             #filenames listed in response files from incorrectly being interpreted as
  73             #introducing compiler command options
  74           if (${BUILD_SHARED_LIBS})
  75                message(FATAL_ERROR "Making of shared libraries with CVF has not been tested.")
  76             endif()
  77             set(str "NMake version 9 or later should be used. NMake version 6.0 which is\n")
  78             set(str "${str}   included with the CVF distribution fails to build Lapack because\n")
  79             set(str "${str}   the number of source files exceeds the limit for NMake v6.0\n")
  80             message(STATUS ${str})
  81             set(CMAKE_Fortran_LINK_EXECUTABLE "LINK /out:<TARGET> <LINK_FLAGS> <LINK_LIBRARIES> <OBJECTS>")
  82          endif()
  83       endif()
  84    endif()
  85 endif()
  86
  87 # Get Python
  88 message(STATUS "Looking for Python greater than 2.6 - ${PYTHONINTERP_FOUND}")
  89 find_package(PythonInterp 2.7) # lapack_testing.py uses features from python 2.7 and greater
  90 if (PYTHONINTERP_FOUND)
  91    message(STATUS "Using Python version ${PYTHON_VERSION_STRING}")
  92 else()
  93    message(STATUS "No suitable Python version found, so skipping summary tests.")
  94 endif()
  95 # --------------------------------------------------
  96
  97 set(LAPACK_INSTALL_EXPORT_NAME lapack-targets)
  98
  99 if (UNIX)
 100   include(GNUInstallDirs)
 101   set(ARCHIVE_DIR ${CMAKE_INSTALL_LIBDIR})
 102   set(LIBRARY_DIR ${CMAKE_INSTALL_LIBDIR})
 103   set(RUNTIME_DIR ${CMAKE_INSTALL_BINDIR})
 104 else()
 105   set(ARCHIVE_DIR lib${LIB_SUFFIX})
 106   set(LIBRARY_DIR lib${LIB_SUFFIX})
 107   set(RUNTIME_DIR bin)
 108 endif()
 109
 110 macro(lapack_install_library lib)
 111   install(TARGETS ${lib}
 112     EXPORT ${LAPACK_INSTALL_EXPORT_NAME}
 113     ARCHIVE DESTINATION ${ARCHIVE_DIR}
 114     LIBRARY DESTINATION ${LIBRARY_DIR}
 115     RUNTIME DESTINATION ${RUNTIME_DIR}
 116   )
 117 endmacro()
 118
 119 # --------------------------------------------------
 120 # Testing
 121
 122 enable_testing()
 123 include(CTest)
 124 enable_testing()
 125 # --------------------------------------------------
 126
 127 # Organize output files.  On Windows this also keeps .dll files next
 128 # to the .exe files that need them, making tests easy to run.
 129 set(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${LAPACK_BINARY_DIR}/bin)
 130 set(CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${LAPACK_BINARY_DIR}/lib)
 131 set(CMAKE_LIBRARY_OUTPUT_DIRECTORY ${LAPACK_BINARY_DIR}/lib)
 132
 133 # --------------------------------------------------
 134 # Check for any necessary platform specific compiler flags
 135 include( CheckLAPACKCompilerFlags )
 136 CheckLAPACKCompilerFlags()
 137
 138 # --------------------------------------------------
 139 # Check second function
 140
 141 include(CheckTimeFunction)
 142 set(TIME_FUNC NONE ${TIME_FUNC})
 143 CHECK_TIME_FUNCTION(NONE TIME_FUNC)
 144 CHECK_TIME_FUNCTION(INT_CPU_TIME TIME_FUNC)
 145 CHECK_TIME_FUNCTION(EXT_ETIME TIME_FUNC)
 146 CHECK_TIME_FUNCTION(EXT_ETIME_ TIME_FUNC)
 147 CHECK_TIME_FUNCTION(INT_ETIME TIME_FUNC)
 148 message(STATUS "--> Will use second_${TIME_FUNC}.f and dsecnd_${TIME_FUNC}.f as timing function.")
 149
 150 set(SECOND_SRC  ${LAPACK_SOURCE_DIR}/INSTALL/second_${TIME_FUNC}.f)
 151 set(DSECOND_SRC  ${LAPACK_SOURCE_DIR}/INSTALL/dsecnd_${TIME_FUNC}.f)
 152 set(PKG_CONFIG_DIR ${LIBRARY_DIR}/pkgconfig)
 153
 154
 155 # By default static library
 156 option(BUILD_SHARED_LIBS "Build shared libraries" OFF )
 157
 158 option(BUILD_TESTING "Build tests" OFF)
 159
 160 # deprecated LAPACK routines
 161 option(BUILD_DEPRECATED "Build deprecated routines" OFF)
 162
 163 # --------------------------------------------------
 164 # Precision to build
 165 # By default all precisions are generated
 166 option(BUILD_SINGLE "Build LAPACK Single Precision" ON)
 167 option(BUILD_DOUBLE "Build LAPACK Double Precision" ON)
 168 option(BUILD_COMPLEX "Build LAPACK Complex Precision" ON)
 169 option(BUILD_COMPLEX16 "Build LAPACK Double Complex Precision" ON)
 170
 171 # --------------------------------------------------
 172 # Subdirectories that need to be processed
 173 option(USE_OPTIMIZED_BLAS "Whether or not to use an optimized BLAS library instead of included netlib BLAS" OFF)
 174
 175 # Check the usage of the user provided BLAS libraries
 176 if(BLAS_LIBRARIES)
 177   include(CheckFortranFunctionExists)
 178   set(CMAKE_REQUIRED_LIBRARIES ${BLAS_LIBRARIES})
 179   CHECK_FORTRAN_FUNCTION_EXISTS("dgemm" BLAS_FOUND)
 180   unset( CMAKE_REQUIRED_LIBRARIES )
 181   if(BLAS_FOUND)
 182     message(STATUS "--> BLAS supplied by user is WORKING, will use ${BLAS_LIBRARIES}.")
 183   else()
 184     message(ERROR "--> BLAS supplied by user is not WORKING, CANNOT USE ${BLAS_LIBRARIES}.")
 185     message(ERROR "-->     Will use REFERENCE BLAS (by default)")
 186     message(ERROR "-->     Or Correct your BLAS_LIBRARIES entry ")
 187     message(ERROR "-->     Or Consider checking USE_OPTIMIZED_BLAS")
 188   endif()
 189
 190 # User did not provide a BLAS Library but specified to search for one
 191 elseif( USE_OPTIMIZED_BLAS )
 192   find_package( BLAS )
 193 endif ()
 194
 195 # Neither user specified or optimized BLAS libraries can be used
 196 if(NOT BLAS_FOUND)
 197   message(STATUS "Using supplied NETLIB BLAS implementation")
 198   add_subdirectory(BLAS)
 199   set( BLAS_LIBRARIES blas )
 200 else()
 201   set( CMAKE_EXE_LINKER_FLAGS
 202     "${CMAKE_EXE_LINKER_FLAGS} ${BLAS_LINKER_FLAGS}"
 203     CACHE STRING "Linker flags for executables" FORCE)
 204   set( CMAKE_MODULE_LINKER_FLAGS
 205     "${CMAKE_MODULE_LINKER_FLAGS} ${BLAS_LINKER_FLAGS}"
 206     CACHE STRING "Linker flags for modules" FORCE)
 207   set( CMAKE_SHARED_LINKER_FLAGS
 208     "${CMAKE_SHARED_LINKER_FLAGS} ${BLAS_LINKER_FLAGS}"
 209     CACHE STRING "Linker flags for shared libs" FORCE)
 210 endif()
 211
 212
 213 # --------------------------------------------------
 214 # CBLAS
 215 option(CBLAS "Build CBLAS" OFF)
 216
 217 if(CBLAS)
 218   add_subdirectory(CBLAS)
 219 endif()
 220
 221 # --------------------------------------------------
 222 # XBLAS
 223
 224 option(USE_XBLAS "Build extended precision (needs XBLAS)" OFF)
 225 if (USE_XBLAS)
 226   find_library(XBLAS_LIBRARY NAMES xblas)
 227 endif()
 228
 229 option(USE_OPTIMIZED_LAPACK "Whether or not to use an optimized LAPACK library instead of included netlib LAPACK" OFF)
 230
 231 # --------------------------------------------------
 232 # LAPACK
 233 # User did not provide a LAPACK Library but specified to search for one
 234 if( USE_OPTIMIZED_LAPACK )
 235   find_package( LAPACK )
 236 endif ()
 237
 238 # Check the usage of the user provided or automatically found LAPACK libraries
 239 if(LAPACK_LIBRARIES)
 240   include(CheckFortranFunctionExists)
 241   set(CMAKE_REQUIRED_LIBRARIES ${LAPACK_LIBRARIES})
 242   # Check if new routine of 3.4.0 is in LAPACK_LIBRARIES
 243   CHECK_FORTRAN_FUNCTION_EXISTS("dgeqrt" LATESTLAPACK_FOUND)
 244   unset( CMAKE_REQUIRED_LIBRARIES )
 245   if(LATESTLAPACK_FOUND)
 246     message(STATUS "--> LAPACK supplied by user is WORKING, will use ${LAPACK_LIBRARIES}.")
 247   else()
 248     message(ERROR "--> LAPACK supplied by user is not WORKING or is older than LAPACK 3.4.0,    CANNOT USE ${LAPACK_LIBRARIES}.")
 249     message(ERROR "-->     Will use REFERENCE LAPACK (by default)")
 250     message(ERROR "-->     Or Correct your LAPACK_LIBRARIES entry ")
 251     message(ERROR "-->     Or Consider checking USE_OPTIMIZED_LAPACK")
 252   endif()
 253 endif ()
 254
 255 # Neither user specified or optimized LAPACK libraries can be used
 256 if(NOT LATESTLAPACK_FOUND)
 257   message(STATUS "Using supplied NETLIB LAPACK implementation")
 258   set( LAPACK_LIBRARIES lapack )
 259   add_subdirectory(SRC)
 260 else()
 261   set( CMAKE_EXE_LINKER_FLAGS
 262     "${CMAKE_EXE_LINKER_FLAGS} ${LAPACK_LINKER_FLAGS}"
 263     CACHE STRING "Linker flags for executables" FORCE)
 264   set( CMAKE_MODULE_LINKER_FLAGS
 265     "${CMAKE_MODULE_LINKER_FLAGS} ${LAPACK_LINKER_FLAGS}"
 266     CACHE STRING "Linker flags for modules" FORCE)
 267   set( CMAKE_SHARED_LINKER_FLAGS
 268     "${CMAKE_SHARED_LINKER_FLAGS} ${LAPACK_LINKER_FLAGS}"
 269     CACHE STRING "Linker flags for shared libs" FORCE)
 270 endif()
 271
 272 message(STATUS "BUILD TESTING : ${BUILD_TESTING}" )
 273 if(BUILD_TESTING)
 274   add_subdirectory(TESTING)
 275 endif()
 276
 277 # --------------------------------------------------
 278 # LAPACKE
 279 option(LAPACKE "Build LAPACKE" OFF)
 280
 281 # LAPACKE has also the interface to some routines from tmglib,
 282 # if LAPACKE_WITH_TMG is selected, we need to add those routines to LAPACKE
 283 option(LAPACKE_WITH_TMG "Build LAPACKE with tmglib routines" OFF)
 284 if (LAPACKE_WITH_TMG)
 285   set(LAPACKE ON)
 286 endif()
 287 if(BUILD_TESTING OR LAPACKE_WITH_TMG) #already included, avoid double inclusion
 288      add_subdirectory(TESTING/MATGEN)
 289 endif()
 290
 291 if(LAPACKE)
 292   add_subdirectory(LAPACKE)
 293 endif()
 294
 295 # --------------------------------------------------
 296 # CPACK Packaging
 297
 298 set(CPACK_PACKAGE_NAME "LAPACK")
 299 set(CPACK_PACKAGE_VENDOR "University of Tennessee, Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd")
 300 set(CPACK_PACKAGE_DESCRIPTION_SUMMARY "LAPACK- Linear Algebra Package")
 301 set(CPACK_PACKAGE_VERSION_MAJOR 3)
 302 set(CPACK_PACKAGE_VERSION_MINOR 5)
 303 set(CPACK_PACKAGE_VERSION_PATCH 0)
 304 set(CPACK_RESOURCE_FILE_LICENSE "${CMAKE_CURRENT_SOURCE_DIR}/LICENSE")
 305 set(CPACK_PACKAGE_INSTALL_DIRECTORY "LAPACK")
 306 if(WIN32 AND NOT UNIX)
 307   # There is a bug in NSI that does not handle full unix paths properly. Make
 308   # sure there is at least one set of four (4) backlasshes.
 309   set(CPACK_NSIS_HELP_LINK "http:\\\\\\\\http://icl.cs.utk.edu/lapack-forum")
 310   set(CPACK_NSIS_URL_INFO_ABOUT "http:\\\\\\\\www.netlib.org/lapack")
 311   set(CPACK_NSIS_CONTACT "lapack@eecs.utk.edu")
 312   set(CPACK_NSIS_MODIFY_PATH ON)
 313   set(CPACK_NSIS_DISPLAY_NAME "LAPACK-${LAPACK_VERSION}")
 314   set(CPACK_PACKAGE_RELOCATABLE "true")
 315 else()
 316   set(CPACK_GENERATOR "TGZ")
 317   set(CPACK_SOURCE_GENERATOR TGZ)
 318   set(CPACK_SOURCE_PACKAGE_FILE_NAME "lapack-${LAPACK_VERSION}" )
 319   set(CPACK_SOURCE_IGNORE_FILES ~$ .svn ${CPACK_SOURCE_IGNORE_FILES} )
 320 endif()
 321 include(CPack)
 322
 323
 324 # --------------------------------------------------
 325
 326 if(NOT BLAS_FOUND)
 327   set(ALL_TARGETS ${ALL_TARGETS} blas)
 328 endif()
 329
 330 if(NOT LATESTLAPACK_FOUND)
 331   set(ALL_TARGETS ${ALL_TARGETS} lapack)
 332 endif()
 333
 334 if(BUILD_TESTING OR LAPACKE_WITH_TMG)
 335   set(ALL_TARGETS ${ALL_TARGETS} tmglib)
 336 endif()
 337
 338 # Export lapack targets, not including lapacke, from the
 339 # install tree, if any.
 340 set(_lapack_config_install_guard_target "")
 341 if(ALL_TARGETS)
 342   install(EXPORT lapack-targets
 343     DESTINATION ${LIBRARY_DIR}/cmake/lapack-${LAPACK_VERSION})
 344
 345   # Choose one of the lapack targets to use as a guard for
 346   # lapack-config.cmake to load targets from the install tree.
 347   list(GET ALL_TARGETS 0 _lapack_config_install_guard_target)
 348 endif()
 349
 350 # Include cblas in targets exported from the build tree.
 351 if(CBLAS)
 352   set(ALL_TARGETS ${ALL_TARGETS} cblas)
 353 endif()
 354
 355 # Include lapacke in targets exported from the build tree.
 356 if(LAPACKE)
 357   set(ALL_TARGETS ${ALL_TARGETS} lapacke)
 358 endif()
 359
 360 # Export lapack and lapacke targets from the build tree, if any.
 361 set(_lapack_config_build_guard_target "")
 362 if(ALL_TARGETS)
 363   export(TARGETS ${ALL_TARGETS} FILE lapack-targets.cmake)
 364
 365   # Choose one of the lapack or lapacke targets to use as a guard
 366   # for lapack-config.cmake to load targets from the build tree.
 367   list(GET ALL_TARGETS 0 _lapack_config_build_guard_target)
 368 endif()
 369
 370 configure_file(${LAPACK_SOURCE_DIR}/CMAKE/lapack-config-build.cmake.in
 371   ${LAPACK_BINARY_DIR}/lapack-config.cmake @ONLY)
 372
 373
 374 configure_file(${CMAKE_CURRENT_SOURCE_DIR}/lapack.pc.in ${CMAKE_CURRENT_BINARY_DIR}/lapack.pc)
 375   install(FILES
 376   ${CMAKE_CURRENT_BINARY_DIR}/lapack.pc
 377   DESTINATION ${PKG_CONFIG_DIR}
 378    )
 379
 380 configure_file(${LAPACK_SOURCE_DIR}/CMAKE/lapack-config-install.cmake.in
 381   ${LAPACK_BINARY_DIR}/CMakeFiles/lapack-config.cmake @ONLY)
 382
 383 include(CMakePackageConfigHelpers)
 384 write_basic_package_version_file(
 385   ${LAPACK_BINARY_DIR}/lapack-config-version.cmake
 386   VERSION ${LAPACK_VERSION}
 387   COMPATIBILITY SameMajorVersion
 388   )
 389
 390 install(FILES
 391   ${LAPACK_BINARY_DIR}/CMakeFiles/lapack-config.cmake
 392   ${LAPACK_BINARY_DIR}/lapack-config-version.cmake
 393   DESTINATION ${LIBRARY_DIR}/cmake/lapack-${LAPACK_VERSION}
 394   )