CMakeLists.txt

   1 PROJECT (libsolv)
   2
   3 CMAKE_MINIMUM_REQUIRED (VERSION 2.4)
   4
   5 OPTION (ENABLE_STATIC "Build a static version of the libraries?" OFF)
   6 OPTION (DISABLE_SHARED "Do not build a shared version of the libraries?" OFF)
   7
   8 OPTION (ENABLE_PERL "Build the perl bindings?" OFF)
   9 OPTION (ENABLE_PYTHON "Build the python bindings?" OFF)
  10 OPTION (ENABLE_RUBY "Build the ruby bindings?" OFF)
  11
  12 OPTION (USE_VENDORDIRS "Install the bindings in vendor directories?" OFF)
  13
  14 OPTION (ENABLE_RPMDB "Build with rpm database support?" OFF)
  15 OPTION (ENABLE_RPMDB_PUBKEY "Build with rpmdb pubkey support?" OFF)
  16 OPTION (ENABLE_RPMDB_BYRPMHEADER "Build with rpmdb Header support?" OFF)
  17 OPTION (ENABLE_RPMMD "Build with rpmmd repository support?" OFF)
  18 OPTION (ENABLE_SUSEREPO "Build with suse repository support?" OFF)
  19 OPTION (ENABLE_COMPS "Build with fedora comps support?" OFF)
  20 OPTION (ENABLE_HELIXREPO "Build with helix repository support?" OFF)
  21 OPTION (ENABLE_DEBIAN "Build with debian database/repository support?" OFF)
  22 OPTION (ENABLE_MDKREPO "Build with mandriva/mageia repository support?" OFF)
  23 OPTION (ENABLE_ARCHREPO "Build with archlinux repository support?" OFF)
  24 OPTION (ENABLE_CUDFREPO "Build with cudf repository support?" OFF)
  25
  26 OPTION (ENABLE_LZMA_COMPRESSION "Build with lzma/xz compression support?" OFF)
  27 OPTION (ENABLE_BZIP2_COMPRESSION "Build with bzip2 compression support?" OFF)
  28
  29 #IF(${CMAKE_MAJOR_VERSION}.${CMAKE_MINOR_VERISION} GREATER 2.4)
  30 #ENDIF(${CMAKE_MAJOR_VERSION}.${CMAKE_MINOR_VERISION} GREATER 2.4)
  31
  32 IF (COMMAND cmake_policy)
  33   # escape preprocessor, see -DVERSION below
  34   CMAKE_POLICY (SET CMP0005 OLD)
  35 ENDIF (COMMAND cmake_policy)
  36
  37 # Library
  38 IF (DEFINED LIB)
  39   SET (LIB_INSTALL_DIR "${CMAKE_INSTALL_PREFIX}/${LIB}")
  40 ELSE (DEFINED  LIB)
  41   IF (CMAKE_SIZEOF_VOID_P MATCHES "8")
  42     SET (LIB_SUFFIX "64")
  43   ENDIF (CMAKE_SIZEOF_VOID_P MATCHES "8")
  44   SET (LIB_INSTALL_DIR "${CMAKE_INSTALL_PREFIX}/lib${LIB_SUFFIX}")
  45 ENDIF (DEFINED  LIB)
  46 MESSAGE (STATUS "Libraries will be installed in ${LIB_INSTALL_DIR}")
  47 SET (BIN_INSTALL_DIR "${CMAKE_INSTALL_PREFIX}/bin")
  48
  49 ####################################################################
  50 # CONFIGURATION                                                    #
  51 ####################################################################
  52
  53 # where to look first for cmake modules, before ${CMAKE_ROOT}/Modules/ is checked
  54 SET (CMAKE_MODULE_PATH ${CMAKE_SOURCE_DIR}/cmake/modules)
  55 INSTALL( FILES ${CMAKE_MODULE_PATH}/FindLibSolv.cmake DESTINATION ${CMAKE_INSTALL_PREFIX}/share/cmake/Modules )
  56
  57 INCLUDE (${CMAKE_SOURCE_DIR}/VERSION.cmake)
  58
  59 SET (have_system x)
  60
  61 IF (FEDORA)
  62 MESSAGE(STATUS "Building for Fedora")
  63 ADD_DEFINITIONS (-DFEDORA)
  64 SET (ENABLE_RPMDB ON)
  65 SET (ENABLE_RPMMD ON)
  66 SET (have_system ${have_system}x)
  67 ENDIF (FEDORA)
  68
  69 IF (DEBIAN)
  70 MESSAGE (STATUS "Building for Debian")
  71 ADD_DEFINITIONS (-DDEBIAN)
  72 SET (ENABLE_DEBIAN ON)
  73 SET (have_system ${have_system}x)
  74 ENDIF (DEBIAN)
  75
  76 IF (SUSE)
  77 MESSAGE (STATUS "Building for SUSE")
  78 ADD_DEFINITIONS (-DSUSE)
  79 SET (ENABLE_RPMDB ON)
  80 SET (ENABLE_RPMDB_PUBKEY ON)
  81 SET (ENABLE_RPMDB_BYRPMHEADER ON)
  82 SET (ENABLE_RPMMD ON)
  83 SET (ENABLE_SUSEREPO ON)
  84 SET (ENABLE_HELIXREPO ON)
  85 SET (have_system ${have_system}x)
  86 ENDIF (SUSE)
  87
  88 IF (ARCHLINUX)
  89 MESSAGE (STATUS "Building for Archlinux")
  90 ADD_DEFINITIONS (-DARCHLINUX)
  91 SET (ENABLE_ARCHREPO ON)
  92 SET (have_system ${have_system}x)
  93 ENDIF (ARCHLINUX)
  94
  95 IF (MANDRIVA)
  96 MESSAGE (STATUS "Building for Mandriva/Mageia")
  97 ADD_DEFINITIONS (-DMANDRIVA)
  98 SET (ENABLE_MDKREPO ON)
  99 SET (have_system ${have_system}x)
 100 ENDIF (MANDRIVA)
 101
 102 IF (${have_system} STREQUAL x)
 103     MESSAGE (STATUS "Building for no system")
 104     ADD_DEFINITIONS (-DNOSYSTEM)
 105 ENDIF (${have_system} STREQUAL x)
 106 IF (${have_system} STRGREATER xx)
 107     MESSAGE (FATAL_ERROR "Can only compile for one system type.")
 108 ENDIF (${have_system} STRGREATER xx)
 109
 110 IF (ENABLE_ARCHREPO)
 111 SET (ENABLE_LZMA_COMPRESSION ON)
 112 ENDIF (ENABLE_ARCHREPO)
 113
 114 FIND_PACKAGE (EXPAT REQUIRED)
 115 FIND_PACKAGE (ZLIB REQUIRED)
 116 IF (ENABLE_LZMA_COMPRESSION)
 117 FIND_PACKAGE (LZMA REQUIRED)
 118 ENDIF (ENABLE_LZMA_COMPRESSION)
 119 IF (ENABLE_BZIP2_COMPRESSION)
 120 FIND_PACKAGE (BZip2 REQUIRED)
 121 ENDIF (ENABLE_BZIP2_COMPRESSION)
 122
 123 IF (RPM5)
 124 MESSAGE (STATUS "Enabling RPM 5 support")
 125 ADD_DEFINITIONS (-DRPM5)
 126 SET (ENABLE_RPMDB ON)
 127 SET (ENABLE_RPMMD ON)
 128 FIND_PACKAGE (PkgConfig REQUIRED)
 129 PKG_CHECK_MODULES (RPM REQUIRED rpm)
 130 INCLUDE_DIRECTORIES (${RPM_INCLUDE_DIRS})
 131 ENDIF (RPM5)
 132
 133 IF (MULTI_SEMANTICS)
 134 MESSAGE (STATUS "Enabling multi dist support")
 135 ADD_DEFINITIONS (-DMULTI_SEMANTICS)
 136 ENDIF (MULTI_SEMANTICS)
 137
 138 INCLUDE (CheckIncludeFile)
 139 IF (ENABLE_RPMDB)
 140   FIND_LIBRARY (RPMDB_LIBRARY NAMES rpmdb)
 141
 142   IF (NOT RPMDB_LIBRARY)
 143     FIND_LIBRARY (RPMDB_LIBRARY NAMES rpm)
 144   ENDIF (NOT RPMDB_LIBRARY)
 145
 146   FIND_LIBRARY (RPMIO_LIBRARY NAMES rpmio)
 147   IF (RPMIO_LIBRARY)
 148     SET(RPMDB_LIBRARY ${RPMIO_LIBRARY} ${RPMDB_LIBRARY})
 149   ENDIF (RPMIO_LIBRARY)
 150
 151   IF (RPM5)
 152     FIND_LIBRARY (RPMMISC_LIBRARY NAMES rpmmisc)
 153     IF (RPMMISC_LIBRARY)
 154       SET (RPMDB_LIBRARY ${RPMMISC_LIBRARY} ${RPMDB_LIBRARY})
 155     ENDIF (RPMMISC_LIBRARY)
 156   ENDIF (RPM5)
 157
 158   IF (RPM5 OR FEDORA)
 159     FIND_LIBRARY (DB_LIBRARY NAMES db)
 160     IF (DB_LIBRARY)
 161       SET (RPMDB_LIBRARY ${DB_LIBRARY} ${RPMDB_LIBRARY})
 162     ENDIF (DB_LIBRARY)
 163   ENDIF (RPM5 OR FEDORA)
 164   CHECK_INCLUDE_FILE(rpm/db.h HAVE_RPM_DB_H)
 165 ENDIF (ENABLE_RPMDB)
 166
 167 INCLUDE (CheckFunctionExists)
 168 INCLUDE (TestBigEndian)
 169
 170 CHECK_FUNCTION_EXISTS (strchrnul HAVE_STRCHRNUL)
 171 CHECK_FUNCTION_EXISTS (fopencookie HAVE_FOPENCOOKIE)
 172 CHECK_FUNCTION_EXISTS (funopen HAVE_FUNOPEN)
 173 TEST_BIG_ENDIAN (WORDS_BIGENDIAN)
 174
 175 # should create config.h with #cmakedefine instead...
 176 FOREACH (VAR HAVE_STRCHRNUL HAVE_FOPENCOOKIE HAVE_FUNOPEN WORDS_BIGENDIAN
 177   HAVE_RPM_DB_H
 178   ENABLE_RPMDB ENABLE_RPMDB_PUBKEY ENABLE_RPMMD ENABLE_SUSEREPO ENABLE_COMPS
 179   ENABLE_HELIXREPO ENABLE_MDKREPO ENABLE_ARCHREPO ENABLE_DEBIAN
 180   ENABLE_LZMA_COMPRESSION ENABLE_BZIP2_COMPRESSION)
 181   IF(${VAR})
 182     ADD_DEFINITIONS (-D${VAR}=1)
 183     SET (SWIG_FLAGS ${SWIG_FLAGS} -D${VAR})
 184   ENDIF (${VAR})
 185 ENDFOREACH (VAR)
 186
 187 SET (PACKAGE "libsolv")
 188 SET (VERSION "${LIBSOLV_MAJOR}.${LIBSOLV_MINOR}.${LIBSOLV_PATCH}")
 189
 190 ADD_DEFINITIONS (-D_FILE_OFFSET_BITS=64)
 191 ADD_DEFINITIONS (-DVERSION=\\\"${VERSION}\\\")
 192 CONFIGURE_FILE (src/solvversion.h.in src/solvversion.h)
 193
 194 SET (CPACK_PACKAGE_DESCRIPTION_SUMMARY "Package dependency solver library")
 195 SET (CPACK_PACKAGE_VENDOR "SUSE")
 196 SET (CPACK_PACKAGE_VERSION_MAJOR ${LIBSOLV_MAJOR})
 197 SET (CPACK_PACKAGE_VERSION_MINOR ${LIBSOLV_MINOR})
 198 SET (CPACK_PACKAGE_VERSION_PATCH ${LIBSOLV_PATCH})
 199 SET (CPACK_GENERATOR "TBZ2")
 200 SET (CPACK_SOURCE_GENERATOR "TBZ2")
 201 SET (CPACK_SOURCE_PACKAGE_FILE_NAME "${PACKAGE}-${VERSION}")
 202 SET (CPACK_SOURCE_TOPLEVEL_TAG "Linux-Source:")
 203 SET (CPACK_TOPLEVEL_TAG "Linux-Source:")
 204
 205 # The following components are regex's to match anywhere (unless anchored)
 206 # in absolute path + filename to find files or directories to be excluded
 207 # from source tarball.
 208 SET (CPACK_SOURCE_IGNORE_FILES
 209 # temporary files
 210 "\\\\.swp$"
 211 # backup files
 212 "~$"
 213 # eclipse files
 214 "\\\\.cdtproject$"
 215 "\\\\.cproject$"
 216 "\\\\.project$"
 217 "\\\\.settings/"
 218 # others
 219 "\\\\.#"
 220 "/#"
 221 "/build/"
 222 "/_build/"
 223 "/\\\\.git/"
 224 # used before
 225 "/\\\\.libs/"
 226 "/\\\\.deps/"
 227 "\\\\.o$"
 228 "\\\\.lo$"
 229 "\\\\.la$"
 230 "Makefile$"
 231 "Makefile\\\\.in$"
 232 # cmake cache files
 233 "DartConfiguration.tcl$"
 234 "CMakeCache.txt"
 235 "CMakeFiles"
 236 "cmake_install.cmake$"
 237 "CMakeLists.txt.auto$"
 238 "CTestTestfile.cmake"
 239 "CPackConfig.cmake$"
 240 "CPackSourceConfig.cmake$"
 241 "libsolv.spec$"
 242 )
 243
 244 INCLUDE(CPack)
 245
 246 ####################################################################
 247 # INCLUDES                                                         #
 248 ####################################################################
 249
 250 #SET (CMAKE_INCLUDE_DIRECTORIES_BEFORE ON)
 251 INCLUDE_DIRECTORIES (${CMAKE_CURRENT_SOURCE_DIR} ${CMAKE_SOURCE_DIR} ${CMAKE_SOURCE_DIR}/src ${CMAKE_SOURCE_DIR}/ext ${CMAKE_CURRENT_BINARY_DIR} ${CMAKE_BINARY_DIR}/src SYSTEM )
 252
 253 ####################################################################
 254
 255 MESSAGE (STATUS "Looking for modules in ${CMAKE_MODULE_PATH}")
 256
 257 set (CMAKE_C_FLAGS     "${CMAKE_C_FLAGS} -Wall -Wl,--as-needed")
 258 set (CMAKE_C_FLAGS_RELEASE "${CMAKE_C_FLAGS} -O3")
 259 set (CMAKE_C_FLAGS_RELWITHDEBINFO "${CMAKE_C_FLAGS} -g -O3")
 260 set (CMAKE_C_FLAGS_DEBUG     "${CMAKE_C_FLAGS} -g3 -O0")
 261
 262 ADD_SUBDIRECTORY (src)
 263 ADD_SUBDIRECTORY (ext)
 264 ADD_SUBDIRECTORY (tools)
 265 IF (ENABLE_PERL OR ENABLE_PYTHON OR ENABLE_RUBY)
 266     ADD_SUBDIRECTORY (bindings)
 267 ENDIF (ENABLE_PERL OR ENABLE_PYTHON OR ENABLE_RUBY)
 268 ADD_SUBDIRECTORY (examples)
 269
 270 MESSAGE (STATUS "Version: ${VERSION}")
 271
 272 ####################################################################
 273 # RPM SPEC                                                         #
 274 ####################################################################
 275
 276 MACRO (SPECFILE)
 277   MESSAGE (STATUS "Writing spec file...")
 278   CONFIGURE_FILE (${CMAKE_SOURCE_DIR}/package/libsolv.spec.in ${CMAKE_BINARY_DIR}/package/libsolv.spec @ONLY)
 279 ENDMACRO (SPECFILE)
 280
 281 SPECFILE ()
 282
 283 SET (AUTOBUILD_COMMAND
 284   COMMAND ${CMAKE_COMMAND} -E remove ${CMAKE_BINARY_DIR}/package/*.tar.bz2
 285   COMMAND mkdir -p _CPack_Packages/${CPACK_TOPLEVEL_TAG}
 286   COMMAND ${CMAKE_MAKE_PROGRAM} package_source
 287   COMMAND ${CMAKE_COMMAND} -E copy ${CPACK_SOURCE_PACKAGE_FILE_NAME}.tar.bz2 ${CMAKE_BINARY_DIR}/package
 288   COMMAND ${CMAKE_COMMAND} -E remove ${CPACK_SOURCE_PACKAGE_FILE_NAME}.tar.bz2
 289   COMMAND ${CMAKE_COMMAND} -E copy "${CMAKE_SOURCE_DIR}/package/libsolv.changes" "${CMAKE_BINARY_DIR}/package/libsolv.changes"
 290 )
 291
 292 ADD_CUSTOM_TARGET (srcpackage
 293   ${AUTOBUILD_COMMAND}
 294 )
 295
 296 ADD_CUSTOM_TARGET (srcpackage_local
 297   ${AUTOBUILD_COMMAND}
 298 )
 299
 300 ENABLE_TESTING()
 301 ADD_SUBDIRECTORY (test)