CMakeLists.txt

   1 # ----------------------------------------------------------------------------
   2 #  Root CMake file for OpenCV
   3 #
   4 #    From the off-tree build directory, invoke:
   5 #      $ cmake <PATH_TO_OPENCV_ROOT>
   6 #
   7 #
   8 #   - OCT-2008: Initial version <joseluisblancoc@gmail.com>
   9 #
  10 # ----------------------------------------------------------------------------
  11
  12 set(CMAKE_ALLOW_LOOSE_LOOP_CONSTRUCTS true)
  13
  14 # Following block can broke build in case of cross-compilng
  15 # but CMAKE_CROSSCOMPILING variable will be set only on project(OpenCV) command
  16 # so we will try to detect crosscompiling by presense of CMAKE_TOOLCHAIN_FILE
  17 if(NOT CMAKE_TOOLCHAIN_FILE)
  18   # it _must_ go before project(OpenCV) in order to work
  19   if(WIN32)
  20     set(CMAKE_INSTALL_PREFIX "${CMAKE_BINARY_DIR}/install" CACHE PATH "Installation Directory")
  21   else()
  22     set(CMAKE_INSTALL_PREFIX "/usr/local" CACHE PATH "Installation Directory")
  23   endif()
  24 else(NOT CMAKE_TOOLCHAIN_FILE)
  25   #Android: set output folder to ${CMAKE_BINARY_DIR}
  26   set( LIBRARY_OUTPUT_PATH_ROOT ${CMAKE_BINARY_DIR} CACHE PATH "root for library output, set this to change where android libs are compiled to" )
  27   # any crosscompiling
  28   set(CMAKE_INSTALL_PREFIX "${CMAKE_BINARY_DIR}/install" CACHE PATH "Installation Directory")
  29 endif(NOT CMAKE_TOOLCHAIN_FILE)
  30
  31 # --------------------------------------------------------------
  32 # Top level OpenCV project
  33 # --------------------------------------------------------------
  34 if(CMAKE_GENERATOR MATCHES Xcode AND XCODE_VERSION VERSION_GREATER 4.3)
  35   cmake_minimum_required(VERSION 2.8.8)
  36 elseif(IOS)
  37   cmake_minimum_required(VERSION 2.8.0)
  38 else()
  39   cmake_minimum_required(VERSION 2.6.3)
  40 endif()
  41
  42 if(POLICY CMP0017)
  43   cmake_policy(SET CMP0017 NEW)
  44 endif()
  45
  46 if(POLICY CMP0022)
  47   cmake_policy(SET CMP0022 OLD)
  48 endif()
  49
  50 # must go before the project command
  51 set(CMAKE_CONFIGURATION_TYPES "Debug;Release" CACHE STRING "Configs" FORCE)
  52 if(DEFINED CMAKE_BUILD_TYPE AND CMAKE_VERSION VERSION_GREATER "2.8")
  53   set_property( CACHE CMAKE_BUILD_TYPE PROPERTY STRINGS ${CMAKE_CONFIGURATION_TYPES} )
  54 endif()
  55
  56 project(OpenCV CXX C)
  57
  58 if(MSVC)
  59   set(CMAKE_USE_RELATIVE_PATHS ON CACHE INTERNAL "" FORCE)
  60 endif()
  61
  62 include(cmake/OpenCVUtils.cmake)
  63
  64 ocv_clear_vars(OpenCVModules_TARGETS)
  65
  66 # ----------------------------------------------------------------------------
  67 # Break in case of popular CMake configuration mistakes
  68 # ----------------------------------------------------------------------------
  69 if(NOT CMAKE_SIZEOF_VOID_P GREATER 0)
  70   message(FATAL_ERROR "CMake fails to deterimine the bitness of target platform.
  71   Please check your CMake and compiler installation. If you are crosscompiling then ensure that your CMake toolchain file correctly sets the compiler details.")
  72 endif()
  73
  74 # ----------------------------------------------------------------------------
  75 # Detect compiler and target platform architecture
  76 # ----------------------------------------------------------------------------
  77 include(cmake/OpenCVDetectCXXCompiler.cmake)
  78
  79 # Add these standard paths to the search paths for FIND_LIBRARY
  80 # to find libraries from these locations first
  81 if(UNIX AND NOT ANDROID)
  82   if(X86_64 OR CMAKE_SIZEOF_VOID_P EQUAL 8)
  83     if(EXISTS /lib64)
  84       list(APPEND CMAKE_LIBRARY_PATH /lib64)
  85     else()
  86       list(APPEND CMAKE_LIBRARY_PATH /lib)
  87     endif()
  88     if(EXISTS /usr/lib64)
  89       list(APPEND CMAKE_LIBRARY_PATH /usr/lib64)
  90     else()
  91       list(APPEND CMAKE_LIBRARY_PATH /usr/lib)
  92     endif()
  93   elseif(X86 OR CMAKE_SIZEOF_VOID_P EQUAL 4)
  94     if(EXISTS /lib32)
  95       list(APPEND CMAKE_LIBRARY_PATH /lib32)
  96     else()
  97       list(APPEND CMAKE_LIBRARY_PATH /lib)
  98     endif()
  99     if(EXISTS /usr/lib32)
 100       list(APPEND CMAKE_LIBRARY_PATH /usr/lib32)
 101     else()
 102       list(APPEND CMAKE_LIBRARY_PATH /usr/lib)
 103     endif()
 104   endif()
 105 endif()
 106
 107 # Add these standard paths to the search paths for FIND_PATH
 108 # to find include files from these locations first
 109 if(MINGW)
 110   if(EXISTS /mingw)
 111       list(APPEND CMAKE_INCLUDE_PATH /mingw)
 112   endif()
 113   if(EXISTS /mingw32)
 114       list(APPEND CMAKE_INCLUDE_PATH /mingw32)
 115   endif()
 116   if(EXISTS /mingw64)
 117       list(APPEND CMAKE_INCLUDE_PATH /mingw64)
 118   endif()
 119 endif()
 120
 121 # ----------------------------------------------------------------------------
 122 # OpenCV cmake options
 123 # ----------------------------------------------------------------------------
 124
 125 # Optional 3rd party components
 126 # ===================================================
 127 OCV_OPTION(WITH_1394           "Include IEEE1394 support"                    ON   IF (NOT ANDROID AND NOT IOS) )
 128 OCV_OPTION(WITH_AVFOUNDATION   "Use AVFoundation for Video I/O"              ON   IF IOS)
 129 OCV_OPTION(WITH_CARBON         "Use Carbon for UI instead of Cocoa"          OFF  IF APPLE )
 130 OCV_OPTION(WITH_CUDA           "Include NVidia Cuda Runtime support"         ON   IF (CMAKE_VERSION VERSION_GREATER "2.8" AND NOT IOS) )
 131 OCV_OPTION(WITH_CUFFT          "Include NVidia Cuda Fast Fourier Transform (FFT) library support"            ON  IF (CMAKE_VERSION VERSION_GREATER "2.8" AND NOT IOS) )
 132 OCV_OPTION(WITH_CUBLAS         "Include NVidia Cuda Basic Linear Algebra Subprograms (BLAS) library support" OFF IF (CMAKE_VERSION VERSION_GREATER "2.8" AND NOT IOS) )
 133 OCV_OPTION(WITH_NVCUVID        "Include NVidia Video Decoding library support"                               OFF IF (CMAKE_VERSION VERSION_GREATER "2.8" AND NOT ANDROID AND NOT IOS AND NOT APPLE) )
 134 OCV_OPTION(WITH_EIGEN          "Include Eigen2/Eigen3 support"               ON)
 135 OCV_OPTION(WITH_VFW            "Include Video for Windows support"           ON   IF WIN32 )
 136 OCV_OPTION(WITH_FFMPEG         "Include FFMPEG support"                      ON   IF (NOT ANDROID AND NOT IOS))
 137 OCV_OPTION(WITH_GSTREAMER      "Include Gstreamer support"                   ON   IF (UNIX AND NOT APPLE AND NOT ANDROID) )
 138 OCV_OPTION(WITH_GTK            "Include GTK support"                         ON   IF (UNIX AND NOT APPLE AND NOT ANDROID) )
 139 OCV_OPTION(WITH_IMAGEIO        "ImageIO support for OS X"                    OFF  IF APPLE )
 140 OCV_OPTION(WITH_IPP            "Include Intel IPP support"                   OFF  IF (MSVC OR X86 OR X86_64) )
 141 OCV_OPTION(WITH_JASPER         "Include JPEG2K support"                      ON   IF (NOT IOS) )
 142 OCV_OPTION(WITH_JPEG           "Include JPEG support"                        ON)
 143 OCV_OPTION(WITH_OPENEXR        "Include ILM support via OpenEXR"             ON   IF (NOT IOS) )
 144 OCV_OPTION(WITH_OPENGL         "Include OpenGL support"                      OFF  IF (NOT ANDROID AND NOT APPLE) )
 145 OCV_OPTION(WITH_OPENNI         "Include OpenNI support"                      OFF  IF (NOT ANDROID AND NOT IOS) )
 146 OCV_OPTION(WITH_PNG            "Include PNG support"                         ON)
 147 OCV_OPTION(WITH_PVAPI          "Include Prosilica GigE support"              ON   IF (NOT ANDROID AND NOT IOS) )
 148 OCV_OPTION(WITH_GIGEAPI        "Include Smartek GigE support"                ON   IF (NOT ANDROID AND NOT IOS) )
 149 OCV_OPTION(WITH_QT             "Build with Qt Backend support"               OFF  IF (NOT ANDROID AND NOT IOS) )
 150 OCV_OPTION(WITH_WIN32UI        "Build with Win32 UI Backend support"         ON   IF WIN32 )
 151 OCV_OPTION(WITH_QUICKTIME      "Use QuickTime for Video I/O insted of QTKit" OFF  IF APPLE )
 152 OCV_OPTION(WITH_TBB            "Include Intel TBB support"                   OFF  IF (NOT IOS) )
 153 OCV_OPTION(WITH_OPENMP         "Include OpenMP support"                      OFF)
 154 OCV_OPTION(WITH_CSTRIPES       "Include C= support"                          OFF  IF WIN32 )
 155 OCV_OPTION(WITH_TIFF           "Include TIFF support"                        ON   IF (NOT IOS) )
 156 OCV_OPTION(WITH_UNICAP         "Include Unicap support (GPL)"                OFF  IF (UNIX AND NOT APPLE AND NOT ANDROID) )
 157 OCV_OPTION(WITH_V4L            "Include Video 4 Linux support"               ON   IF (UNIX AND NOT ANDROID) )
 158 OCV_OPTION(WITH_LIBV4L         "Use libv4l for Video 4 Linux support"        ON   IF (UNIX AND NOT ANDROID) )
 159 OCV_OPTION(WITH_DSHOW          "Build HighGUI with DirectShow support"       ON   IF (WIN32 AND NOT ARM) )
 160 OCV_OPTION(WITH_MSMF           "Build HighGUI with Media Foundation support" OFF  IF WIN32 )
 161 OCV_OPTION(WITH_XIMEA          "Include XIMEA cameras support"               OFF  IF (NOT ANDROID AND NOT APPLE) )
 162 OCV_OPTION(WITH_XINE           "Include Xine support (GPL)"                  OFF  IF (UNIX AND NOT APPLE AND NOT ANDROID) )
 163 OCV_OPTION(WITH_OPENCL         "Include OpenCL Runtime support"              ON   IF (NOT IOS) )
 164 OCV_OPTION(WITH_OPENCLAMDFFT   "Include AMD OpenCL FFT library support"      ON   IF (NOT ANDROID AND NOT IOS) )
 165 OCV_OPTION(WITH_OPENCLAMDBLAS  "Include AMD OpenCL BLAS library support"     ON   IF (NOT ANDROID AND NOT IOS) )
 166 OCV_OPTION(WITH_INTELPERC      "Include Intel Perceptual Computing support"  OFF  IF WIN32 )
 167
 168 # OpenCV build components
 169 # ===================================================
 170 OCV_OPTION(BUILD_SHARED_LIBS        "Build shared libraries (.dll/.so) instead of static ones (.lib/.a)" NOT (ANDROID OR IOS) )
 171 OCV_OPTION(BUILD_opencv_apps        "Build utility applications (used for example to train classifiers)" (NOT ANDROID) IF (NOT IOS) )
 172 OCV_OPTION(BUILD_ANDROID_EXAMPLES   "Build examples for Android platform"         ON  IF ANDROID )
 173 OCV_OPTION(BUILD_DOCS               "Create build rules for OpenCV Documentation" ON )
 174 OCV_OPTION(BUILD_EXAMPLES           "Build all examples"                          OFF )
 175 OCV_OPTION(BUILD_PACKAGE            "Enables 'make package_source' command"       ON )
 176 OCV_OPTION(BUILD_PERF_TESTS         "Build performance tests"                     ON  IF (NOT IOS) )
 177 OCV_OPTION(BUILD_TESTS              "Build accuracy & regression tests"           ON  IF (NOT IOS) )
 178 OCV_OPTION(BUILD_WITH_DEBUG_INFO    "Include debug info into debug libs (not MSCV only)" ON )
 179 OCV_OPTION(BUILD_WITH_STATIC_CRT    "Enables use of staticaly linked CRT for staticaly linked OpenCV" ON IF MSVC )
 180 OCV_OPTION(BUILD_FAT_JAVA_LIB       "Create fat java wrapper containing the whole OpenCV library" ON IF NOT BUILD_SHARED_LIBS AND CMAKE_COMPILER_IS_GNUCXX )
 181 OCV_OPTION(BUILD_ANDROID_SERVICE    "Build OpenCV Manager for Google Play" OFF IF ANDROID AND ANDROID_SOURCE_TREE )
 182 OCV_OPTION(BUILD_ANDROID_PACKAGE    "Build platform-specific package for Google Play" OFF IF ANDROID )
 183
 184 # 3rd party libs
 185 OCV_OPTION(BUILD_ZLIB               "Build zlib from source"             WIN32 OR APPLE )
 186 OCV_OPTION(BUILD_TIFF               "Build libtiff from source"          WIN32 OR ANDROID OR APPLE )
 187 OCV_OPTION(BUILD_JASPER             "Build libjasper from source"        WIN32 OR ANDROID OR APPLE )
 188 OCV_OPTION(BUILD_JPEG               "Build libjpeg from source"          WIN32 OR ANDROID OR APPLE )
 189 OCV_OPTION(BUILD_PNG                "Build libpng from source"           WIN32 OR ANDROID OR APPLE )
 190 OCV_OPTION(BUILD_OPENEXR            "Build openexr from source"          WIN32 OR ANDROID OR APPLE )
 191 OCV_OPTION(BUILD_TBB                "Download and build TBB from source" ANDROID )
 192
 193 # OpenCV installation options
 194 # ===================================================
 195 OCV_OPTION(INSTALL_CREATE_DISTRIB   "Change install rules to build the distribution package" OFF )
 196 OCV_OPTION(INSTALL_C_EXAMPLES       "Install C examples"        OFF )
 197 OCV_OPTION(INSTALL_PYTHON_EXAMPLES  "Install Python examples"   OFF )
 198 OCV_OPTION(INSTALL_ANDROID_EXAMPLES "Install Android examples"  OFF IF ANDROID )
 199 OCV_OPTION(INSTALL_TO_MANGLED_PATHS "Enables mangled install paths, that help with side by side installs." OFF IF (UNIX AND NOT ANDROID AND NOT IOS AND BUILD_SHARED_LIBS) )
 200
 201
 202 # OpenCV build options
 203 # ===================================================
 204 OCV_OPTION(ENABLE_DYNAMIC_CUDA        "Enabled dynamic CUDA linkage"                             ON   IF ANDROID )
 205 OCV_OPTION(ENABLE_PRECOMPILED_HEADERS "Use precompiled headers"                                  ON   IF (NOT IOS) )
 206 OCV_OPTION(ENABLE_SOLUTION_FOLDERS    "Solution folder in Visual Studio or in other IDEs"        (MSVC_IDE OR CMAKE_GENERATOR MATCHES Xcode) IF (CMAKE_VERSION VERSION_GREATER "2.8.0") )
 207 OCV_OPTION(ENABLE_PROFILING           "Enable profiling in the GCC compiler (Add flags: -g -pg)" OFF  IF CMAKE_COMPILER_IS_GNUCXX )
 208 OCV_OPTION(ENABLE_OMIT_FRAME_POINTER  "Enable -fomit-frame-pointer for GCC"                      ON   IF CMAKE_COMPILER_IS_GNUCXX AND NOT (APPLE AND CMAKE_COMPILER_IS_CLANGCXX) )
 209 OCV_OPTION(ENABLE_POWERPC             "Enable PowerPC for GCC"                                   ON   IF (CMAKE_COMPILER_IS_GNUCXX AND CMAKE_SYSTEM_PROCESSOR MATCHES powerpc.*) )
 210 OCV_OPTION(ENABLE_FAST_MATH           "Enable -ffast-math (not recommended for GCC 4.6.x)"       OFF  IF (CMAKE_COMPILER_IS_GNUCXX AND (X86 OR X86_64)) )
 211 OCV_OPTION(ENABLE_SSE                 "Enable SSE instructions"                                  ON   IF ((MSVC OR CMAKE_COMPILER_IS_GNUCXX) AND (X86 OR X86_64)) )
 212 OCV_OPTION(ENABLE_SSE2                "Enable SSE2 instructions"                                 ON   IF ((MSVC OR CMAKE_COMPILER_IS_GNUCXX) AND (X86 OR X86_64)) )
 213 OCV_OPTION(ENABLE_SSE3                "Enable SSE3 instructions"                                 ON   IF ((CV_ICC OR CMAKE_COMPILER_IS_GNUCXX) AND (X86 OR X86_64)) )
 214 OCV_OPTION(ENABLE_SSSE3               "Enable SSSE3 instructions"                                OFF  IF (CMAKE_COMPILER_IS_GNUCXX AND (X86 OR X86_64)) )
 215 OCV_OPTION(ENABLE_SSE41               "Enable SSE4.1 instructions"                               OFF  IF ((CV_ICC OR CMAKE_COMPILER_IS_GNUCXX) AND (X86 OR X86_64)) )
 216 OCV_OPTION(ENABLE_SSE42               "Enable SSE4.2 instructions"                               OFF  IF (CMAKE_COMPILER_IS_GNUCXX AND (X86 OR X86_64)) )
 217 OCV_OPTION(ENABLE_AVX                 "Enable AVX instructions"                                  OFF  IF ((MSVC OR CMAKE_COMPILER_IS_GNUCXX) AND (X86 OR X86_64)) )
 218 OCV_OPTION(ENABLE_NEON                "Enable NEON instructions"                                 OFF  IF CMAKE_COMPILER_IS_GNUCXX AND ARM )
 219 OCV_OPTION(ENABLE_VFPV3               "Enable VFPv3-D32 instructions"                            OFF  IF CMAKE_COMPILER_IS_GNUCXX AND ARM )
 220 OCV_OPTION(ENABLE_NOISY_WARNINGS      "Show all warnings even if they are too noisy"             OFF )
 221 OCV_OPTION(OPENCV_WARNINGS_ARE_ERRORS "Treat warnings as errors"                                 OFF )
 222 OCV_OPTION(ENABLE_WINRT_MODE          "Build with Windows Runtime support"                       OFF  IF WIN32 )
 223 OCV_OPTION(ENABLE_WINRT_MODE_NATIVE   "Build with Windows Runtime native C++ support"            OFF  IF WIN32 )
 224
 225 # uncategorized options
 226 # ===================================================
 227 OCV_OPTION(CMAKE_VERBOSE "Verbose mode" OFF )
 228
 229 # backward compatibility
 230 # ===================================================
 231 include(cmake/OpenCVLegacyOptions.cmake OPTIONAL)
 232
 233
 234 # ----------------------------------------------------------------------------
 235 #  Get actual OpenCV version number from sources
 236 # ----------------------------------------------------------------------------
 237 include(cmake/OpenCVVersion.cmake)
 238
 239
 240 # ----------------------------------------------------------------------------
 241 #  Build & install layouts
 242 # ----------------------------------------------------------------------------
 243
 244 # Save libs and executables in the same place
 245 set(EXECUTABLE_OUTPUT_PATH "${CMAKE_BINARY_DIR}/bin" CACHE PATH "Output directory for applications" )
 246
 247 if (ANDROID)
 248   if (ANDROID_ABI MATCHES "NEON")
 249     set(ENABLE_NEON ON)
 250   endif()
 251   if (ANDROID_ABI MATCHES "VFPV3")
 252     set(ENABLE_VFPV3 ON)
 253   endif()
 254 endif()
 255
 256 if(ANDROID OR WIN32)
 257   set(OPENCV_DOC_INSTALL_PATH doc)
 258 elseif(INSTALL_TO_MANGLED_PATHS)
 259   set(OPENCV_DOC_INSTALL_PATH share/OpenCV-${OPENCV_VERSION}/doc)
 260 else()
 261   set(OPENCV_DOC_INSTALL_PATH share/OpenCV/doc)
 262 endif()
 263
 264 if(WIN32)
 265   if(DEFINED OpenCV_RUNTIME AND DEFINED OpenCV_ARCH)
 266     set(OpenCV_INSTALL_BINARIES_PREFIX "${OpenCV_ARCH}/${OpenCV_RUNTIME}/")
 267   else()
 268     message(STATUS "Can't detect runtime and/or arch")
 269     set(OpenCV_INSTALL_BINARIES_PREFIX "")
 270   endif()
 271 else()
 272   set(OpenCV_INSTALL_BINARIES_PREFIX "")
 273 endif()
 274
 275 set(OPENCV_SAMPLES_BIN_INSTALL_PATH "${OpenCV_INSTALL_BINARIES_PREFIX}samples")
 276
 277 set(OPENCV_BIN_INSTALL_PATH "${OpenCV_INSTALL_BINARIES_PREFIX}bin")
 278
 279 if(ANDROID)
 280   set(LIBRARY_OUTPUT_PATH         "${OpenCV_BINARY_DIR}/lib/${ANDROID_NDK_ABI_NAME}")
 281   set(3P_LIBRARY_OUTPUT_PATH      "${OpenCV_BINARY_DIR}/3rdparty/lib/${ANDROID_NDK_ABI_NAME}")
 282   set(OPENCV_LIB_INSTALL_PATH     sdk/native/libs/${ANDROID_NDK_ABI_NAME})
 283   set(OPENCV_3P_LIB_INSTALL_PATH  sdk/native/3rdparty/libs/${ANDROID_NDK_ABI_NAME})
 284   set(OPENCV_CONFIG_INSTALL_PATH  sdk/native/jni)
 285   set(OPENCV_INCLUDE_INSTALL_PATH sdk/native/jni/include)
 286 else()
 287   set(LIBRARY_OUTPUT_PATH         "${OpenCV_BINARY_DIR}/lib")
 288   set(3P_LIBRARY_OUTPUT_PATH      "${OpenCV_BINARY_DIR}/3rdparty/lib${LIB_SUFFIX}")
 289   if(WIN32)
 290     if(OpenCV_STATIC)
 291       set(OPENCV_LIB_INSTALL_PATH   "${OpenCV_INSTALL_BINARIES_PREFIX}staticlib${LIB_SUFFIX}")
 292     else()
 293       set(OPENCV_LIB_INSTALL_PATH   "${OpenCV_INSTALL_BINARIES_PREFIX}lib${LIB_SUFFIX}")
 294     endif()
 295     set(OPENCV_3P_LIB_INSTALL_PATH  "${OpenCV_INSTALL_BINARIES_PREFIX}staticlib${LIB_SUFFIX}")
 296   else()
 297     set(OPENCV_LIB_INSTALL_PATH     lib${LIB_SUFFIX})
 298     set(OPENCV_3P_LIB_INSTALL_PATH  share/OpenCV/3rdparty/${OPENCV_LIB_INSTALL_PATH})
 299   endif()
 300   set(OPENCV_INCLUDE_INSTALL_PATH "include")
 301
 302   math(EXPR SIZEOF_VOID_P_BITS "8 * ${CMAKE_SIZEOF_VOID_P}")
 303   if(LIB_SUFFIX AND NOT SIZEOF_VOID_P_BITS EQUAL LIB_SUFFIX)
 304     set(OPENCV_CONFIG_INSTALL_PATH lib${LIB_SUFFIX}/cmake/opencv)
 305   else()
 306     set(OPENCV_CONFIG_INSTALL_PATH share/OpenCV)
 307   endif()
 308 endif()
 309
 310 set(CMAKE_INSTALL_RPATH "${CMAKE_INSTALL_PREFIX}/${OPENCV_LIB_INSTALL_PATH}")
 311 set(CMAKE_INSTALL_RPATH_USE_LINK_PATH TRUE)
 312
 313 if(INSTALL_TO_MANGLED_PATHS)
 314   set(OPENCV_INCLUDE_INSTALL_PATH ${OPENCV_INCLUDE_INSTALL_PATH}/opencv-${OPENCV_VERSION})
 315 endif()
 316
 317 if(WIN32)
 318   # Postfix of DLLs:
 319   set(OPENCV_DLLVERSION "${OPENCV_VERSION_MAJOR}${OPENCV_VERSION_MINOR}${OPENCV_VERSION_PATCH}")
 320   set(OPENCV_DEBUG_POSTFIX d)
 321 else()
 322   # Postfix of so's:
 323   set(OPENCV_DLLVERSION "")
 324   set(OPENCV_DEBUG_POSTFIX "")
 325 endif()
 326
 327 if(DEFINED CMAKE_DEBUG_POSTFIX)
 328   set(OPENCV_DEBUG_POSTFIX "${CMAKE_DEBUG_POSTFIX}")
 329 endif()
 330
 331 if(CMAKE_VERBOSE)
 332   set(CMAKE_VERBOSE_MAKEFILE 1)
 333 endif()
 334
 335
 336 # ----------------------------------------------------------------------------
 337 #  Path for build/platform -specific headers
 338 # ----------------------------------------------------------------------------
 339 set(OPENCV_CONFIG_FILE_INCLUDE_DIR "${CMAKE_BINARY_DIR}/" CACHE PATH "Where to create the platform-dependant cvconfig.h")
 340 ocv_include_directories(${OPENCV_CONFIG_FILE_INCLUDE_DIR})
 341
 342 # ----------------------------------------------------------------------------
 343 #  Path for additional modules
 344 # ----------------------------------------------------------------------------
 345 set(OPENCV_EXTRA_MODULES_PATH "" CACHE PATH "Where to look for additional OpenCV modules")
 346
 347 # ----------------------------------------------------------------------------
 348 #  Autodetect if we are in a GIT repository
 349 # ----------------------------------------------------------------------------
 350
 351 # don't use FindGit because it requires CMake 2.8.2
 352 set(git_names git eg) # eg = easy git
 353 # Prefer .cmd variants on Windows unless running in a Makefile in the MSYS shell
 354 if(CMAKE_HOST_WIN32)
 355   if(NOT CMAKE_GENERATOR MATCHES "MSYS")
 356     set(git_names git.cmd git eg.cmd eg)
 357   endif()
 358 endif()
 359
 360 find_host_program(GIT_EXECUTABLE NAMES ${git_names} PATH_SUFFIXES Git/cmd Git/bin DOC "git command line client")
 361 mark_as_advanced(GIT_EXECUTABLE)
 362
 363 if(GIT_EXECUTABLE)
 364   execute_process(COMMAND ${GIT_EXECUTABLE} describe --tags --always --dirty --match "2.[0-9].[0-9]*"
 365     WORKING_DIRECTORY "${OpenCV_SOURCE_DIR}"
 366     OUTPUT_VARIABLE OPENCV_VCSVERSION
 367     RESULT_VARIABLE GIT_RESULT
 368     ERROR_QUIET
 369     OUTPUT_STRIP_TRAILING_WHITESPACE
 370   )
 371   if(NOT GIT_RESULT EQUAL 0)
 372     set(OPENCV_VCSVERSION "unknown")
 373   endif()
 374 else()
 375   # We don't have git:
 376   set(OPENCV_VCSVERSION "unknown")
 377 endif()
 378
 379
 380 # ----------------------------------------------------------------------------
 381 # OpenCV compiler and linker options
 382 # ----------------------------------------------------------------------------
 383 # In case of Makefiles if the user does not setup CMAKE_BUILD_TYPE, assume it's Release:
 384 if(CMAKE_GENERATOR MATCHES "Makefiles|Ninja" AND "${CMAKE_BUILD_TYPE}" STREQUAL "")
 385   set(CMAKE_BUILD_TYPE Release)
 386 endif()
 387
 388 include(cmake/OpenCVCompilerOptions.cmake)
 389
 390
 391 # ----------------------------------------------------------------------------
 392 # Use statically or dynamically linked CRT?
 393 # Default: dynamic
 394 # ----------------------------------------------------------------------------
 395 if(MSVC)
 396   include(cmake/OpenCVCRTLinkage.cmake)
 397 endif(MSVC)
 398
 399 if(WIN32 AND NOT MINGW)
 400   add_definitions(-D_VARIADIC_MAX=10)
 401 endif(WIN32 AND NOT MINGW)
 402
 403
 404 # ----------------------------------------------------------------------------
 405 #       CHECK FOR SYSTEM LIBRARIES, OPTIONS, ETC..
 406 # ----------------------------------------------------------------------------
 407 if(UNIX)
 408   include(cmake/OpenCVFindPkgConfig.cmake OPTIONAL)
 409   include(CheckFunctionExists)
 410   include(CheckIncludeFile)
 411
 412   if(NOT APPLE)
 413     CHECK_INCLUDE_FILE(pthread.h HAVE_LIBPTHREAD)
 414     if(ANDROID)
 415       set(OPENCV_LINKER_LIBS ${OPENCV_LINKER_LIBS} dl m log)
 416     elseif(${CMAKE_SYSTEM_NAME} MATCHES "FreeBSD|NetBSD|DragonFly")
 417       set(OPENCV_LINKER_LIBS ${OPENCV_LINKER_LIBS} m pthread)
 418     else()
 419       set(OPENCV_LINKER_LIBS ${OPENCV_LINKER_LIBS} dl m pthread rt)
 420     endif()
 421   else()
 422     set(HAVE_LIBPTHREAD YES)
 423   endif()
 424 endif()
 425
 426 include(cmake/OpenCVPCHSupport.cmake)
 427 include(cmake/OpenCVModule.cmake)
 428
 429 # ----------------------------------------------------------------------------
 430 #  Detect 3rd-party libraries
 431 # ----------------------------------------------------------------------------
 432
 433 include(cmake/OpenCVFindLibsGrfmt.cmake)
 434 include(cmake/OpenCVFindLibsGUI.cmake)
 435 include(cmake/OpenCVFindLibsVideo.cmake)
 436 include(cmake/OpenCVFindLibsPerf.cmake)
 437
 438
 439 # ----------------------------------------------------------------------------
 440 #  Detect other 3rd-party libraries/tools
 441 # ----------------------------------------------------------------------------
 442
 443 # --- LATEX for pdf documentation ---
 444 if(BUILD_DOCS)
 445   include(cmake/OpenCVFindLATEX.cmake)
 446 endif(BUILD_DOCS)
 447
 448 # --- Python Support ---
 449 include(cmake/OpenCVDetectPython.cmake)
 450
 451 # --- Java Support ---
 452 include(cmake/OpenCVDetectApacheAnt.cmake)
 453 if(ANDROID)
 454   include(cmake/OpenCVDetectAndroidSDK.cmake)
 455
 456   if(NOT ANDROID_TOOLS_Pkg_Revision GREATER 13)
 457     message(WARNING "OpenCV requires Android SDK tools revision 14 or newer. Otherwise tests and samples will no be compiled.")
 458   endif()
 459 else()
 460   find_package(JNI)
 461 endif()
 462
 463 if(ANDROID AND ANDROID_EXECUTABLE AND ANT_EXECUTABLE AND (ANT_VERSION VERSION_GREATER 1.7) AND (ANDROID_TOOLS_Pkg_Revision GREATER 13))
 464   SET(CAN_BUILD_ANDROID_PROJECTS TRUE)
 465 else()
 466   SET(CAN_BUILD_ANDROID_PROJECTS FALSE)
 467 endif()
 468
 469 # --- OpenCL ---
 470 if(WITH_OPENCL)
 471   include(cmake/OpenCVDetectOpenCL.cmake)
 472 endif()
 473
 474 # ----------------------------------------------------------------------------
 475 # Add CUDA libraries (needed for apps/tools, samples)
 476 # ----------------------------------------------------------------------------
 477 if(NOT HAVE_CUDA)
 478   set(ENABLE_DYNAMIC_CUDA OFF)
 479 endif()
 480
 481 if(HAVE_CUDA AND NOT ENABLE_DYNAMIC_CUDA)
 482   set(OPENCV_LINKER_LIBS ${OPENCV_LINKER_LIBS} ${CUDA_LIBRARIES} ${CUDA_npp_LIBRARY})
 483   if(HAVE_CUBLAS)
 484     set(OPENCV_LINKER_LIBS ${OPENCV_LINKER_LIBS} ${CUDA_cublas_LIBRARY})
 485   endif()
 486   if(HAVE_CUFFT)
 487     set(OPENCV_LINKER_LIBS ${OPENCV_LINKER_LIBS} ${CUDA_cufft_LIBRARY})
 488   endif()
 489 endif()
 490
 491 # ----------------------------------------------------------------------------
 492 # Solution folders:
 493 # ----------------------------------------------------------------------------
 494 if(ENABLE_SOLUTION_FOLDERS)
 495   set_property(GLOBAL PROPERTY USE_FOLDERS ON)
 496   set_property(GLOBAL PROPERTY PREDEFINED_TARGETS_FOLDER "CMakeTargets")
 497 endif()
 498
 499 # Extra OpenCV targets: uninstall, package_source, perf, etc.
 500 include(cmake/OpenCVExtraTargets.cmake)
 501
 502
 503 # ----------------------------------------------------------------------------
 504 # Process subdirectories
 505 # ----------------------------------------------------------------------------
 506
 507 # opencv.hpp and legacy headers
 508 add_subdirectory(include)
 509
 510 # OpenCV modules
 511 add_subdirectory(modules)
 512
 513 # Generate targets for documentation
 514 add_subdirectory(doc)
 515
 516 # various data that is used by cv libraries and/or demo applications.
 517 add_subdirectory(data)
 518
 519 # extra applications
 520 if(BUILD_opencv_apps)
 521   add_subdirectory(apps)
 522 endif()
 523
 524 # examples
 525 if(BUILD_EXAMPLES OR BUILD_ANDROID_EXAMPLES OR INSTALL_PYTHON_EXAMPLES)
 526   add_subdirectory(samples)
 527 endif()
 528
 529 if(ANDROID)
 530   add_subdirectory(platforms/android/service)
 531 endif()
 532
 533 if(BUILD_ANDROID_PACKAGE)
 534   add_subdirectory(platforms/android/package)
 535 endif()
 536
 537 if (ANDROID)
 538   add_subdirectory(platforms/android/libinfo)
 539 endif()
 540
 541 # ----------------------------------------------------------------------------
 542 # Finalization: generate configuration-based files
 543 # ----------------------------------------------------------------------------
 544 ocv_track_build_dependencies()
 545
 546 # Generate platform-dependent and configuration-dependent headers
 547 include(cmake/OpenCVGenHeaders.cmake)
 548
 549 # Generate opencv.pc for pkg-config command
 550 include(cmake/OpenCVGenPkgconfig.cmake)
 551
 552 # Generate OpenCV.mk for ndk-build (Android build tool)
 553 include(cmake/OpenCVGenAndroidMK.cmake)
 554
 555 # Generate OpenCVСonfig.cmake and OpenCVConfig-version.cmake for cmake projects
 556 include(cmake/OpenCVGenConfig.cmake)
 557
 558 # Generate Info.plist for the IOS framework
 559 include(cmake/OpenCVGenInfoPlist.cmake)
 560
 561 # ----------------------------------------------------------------------------
 562 # Summary:
 563 # ----------------------------------------------------------------------------
 564 status("")
 565 status("General configuration for OpenCV ${OPENCV_VERSION} =====================================")
 566 if(OPENCV_VCSVERSION)
 567   status("  Version control:" ${OPENCV_VCSVERSION})
 568 endif()
 569
 570 # ========================== build platform ==========================
 571 status("")
 572 status("  Platform:")
 573 status("    Host:"             ${CMAKE_HOST_SYSTEM_NAME} ${CMAKE_HOST_SYSTEM_VERSION} ${CMAKE_HOST_SYSTEM_PROCESSOR})
 574 if(CMAKE_CROSSCOMPILING)
 575   status("    Target:"         ${CMAKE_SYSTEM_NAME} ${CMAKE_SYSTEM_VERSION} ${CMAKE_SYSTEM_PROCESSOR})
 576 endif()
 577 status("    CMake:"            ${CMAKE_VERSION})
 578 status("    CMake generator:"  ${CMAKE_GENERATOR})
 579 status("    CMake build tool:" ${CMAKE_BUILD_TOOL})
 580 if(MSVC)
 581   status("    MSVC:"           ${MSVC_VERSION})
 582 endif()
 583 if(CMAKE_GENERATOR MATCHES Xcode)
 584   status("    Xcode:"          ${XCODE_VERSION})
 585 endif()
 586 if(NOT CMAKE_GENERATOR MATCHES "Xcode|Visual Studio")
 587   status("    Configuration:"  ${CMAKE_BUILD_TYPE})
 588 endif()
 589
 590 # ========================== C/C++ options ==========================
 591 if(CMAKE_CXX_COMPILER_VERSION)
 592   set(OPENCV_COMPILER_STR "${CMAKE_CXX_COMPILER} ${CMAKE_CXX_COMPILER_ARG1} (ver ${CMAKE_CXX_COMPILER_VERSION})")
 593 elseif(CMAKE_COMPILER_IS_CLANGCXX)
 594   set(OPENCV_COMPILER_STR "${CMAKE_CXX_COMPILER} ${CMAKE_CXX_COMPILER_ARG1} (ver ${CMAKE_CLANG_REGEX_VERSION})")
 595 elseif(CMAKE_COMPILER_IS_GNUCXX)
 596   set(OPENCV_COMPILER_STR "${CMAKE_CXX_COMPILER} ${CMAKE_CXX_COMPILER_ARG1} (ver ${CMAKE_GCC_REGEX_VERSION})")
 597 else()
 598   set(OPENCV_COMPILER_STR "${CMAKE_CXX_COMPILER} ${CMAKE_CXX_COMPILER_ARG1}")
 599 endif()
 600 string(STRIP "${OPENCV_COMPILER_STR}" OPENCV_COMPILER_STR)
 601
 602 status("")
 603 status("  C/C++:")
 604 status("    Built as dynamic libs?:" BUILD_SHARED_LIBS THEN YES ELSE NO)
 605 status("    C++ Compiler:"           ${OPENCV_COMPILER_STR})
 606 status("    C++ flags (Release):"    ${CMAKE_CXX_FLAGS} ${CMAKE_CXX_FLAGS_RELEASE})
 607 status("    C++ flags (Debug):"      ${CMAKE_CXX_FLAGS} ${CMAKE_CXX_FLAGS_DEBUG})
 608 status("    C Compiler:"             ${CMAKE_C_COMPILER} ${CMAKE_C_COMPILER_ARG1})
 609 status("    C flags (Release):"      ${CMAKE_C_FLAGS} ${CMAKE_C_FLAGS_RELEASE})
 610 status("    C flags (Debug):"        ${CMAKE_C_FLAGS} ${CMAKE_C_FLAGS_DEBUG})
 611 if(WIN32)
 612   status("    Linker flags (Release):" ${CMAKE_EXE_LINKER_FLAGS} ${CMAKE_EXE_LINKER_FLAGS_RELEASE})
 613   status("    Linker flags (Debug):"   ${CMAKE_EXE_LINKER_FLAGS} ${CMAKE_EXE_LINKER_FLAGS_DEBUG})
 614 else()
 615   status("    Linker flags (Release):" ${CMAKE_SHARED_LINKER_FLAGS} ${CMAKE_SHARED_LINKER_FLAGS_RELEASE})
 616   status("    Linker flags (Debug):"   ${CMAKE_SHARED_LINKER_FLAGS} ${CMAKE_SHARED_LINKER_FLAGS_DEBUG})
 617 endif()
 618 status("    Precompiled headers:"     PCHSupport_FOUND AND ENABLE_PRECOMPILED_HEADERS THEN YES ELSE NO)
 619
 620 # ========================== OpenCV modules ==========================
 621 status("")
 622 status("  OpenCV modules:")
 623 string(REPLACE "opencv_" "" OPENCV_MODULES_BUILD_ST          "${OPENCV_MODULES_BUILD}")
 624 string(REPLACE "opencv_" "" OPENCV_MODULES_DISABLED_USER_ST  "${OPENCV_MODULES_DISABLED_USER}")
 625 string(REPLACE "opencv_" "" OPENCV_MODULES_DISABLED_FORCE_ST "${OPENCV_MODULES_DISABLED_FORCE}")
 626 set(OPENCV_MODULES_DISABLED_AUTO_ST "")
 627 foreach(m ${OPENCV_MODULES_DISABLED_AUTO})
 628   set(__mdeps "")
 629   foreach(d ${OPENCV_MODULE_${m}_DEPS})
 630     if(d MATCHES "^opencv_" AND NOT HAVE_${d})
 631       list(APPEND __mdeps ${d})
 632     endif()
 633   endforeach()
 634   if(__mdeps)
 635     list(APPEND OPENCV_MODULES_DISABLED_AUTO_ST "${m}(deps: ${__mdeps})")
 636   else()
 637     list(APPEND OPENCV_MODULES_DISABLED_AUTO_ST "${m}")
 638   endif()
 639 endforeach()
 640 string(REPLACE "opencv_" "" OPENCV_MODULES_DISABLED_AUTO_ST  "${OPENCV_MODULES_DISABLED_AUTO_ST}")
 641
 642 status("    To be built:"            OPENCV_MODULES_BUILD          THEN ${OPENCV_MODULES_BUILD_ST}          ELSE "-")
 643 status("    Disabled:"               OPENCV_MODULES_DISABLED_USER  THEN ${OPENCV_MODULES_DISABLED_USER_ST}  ELSE "-")
 644 status("    Disabled by dependency:" OPENCV_MODULES_DISABLED_AUTO  THEN ${OPENCV_MODULES_DISABLED_AUTO_ST}  ELSE "-")
 645 status("    Unavailable:"            OPENCV_MODULES_DISABLED_FORCE THEN ${OPENCV_MODULES_DISABLED_FORCE_ST} ELSE "-")
 646
 647 # ========================== Android details ==========================
 648 if(ANDROID)
 649   status("")
 650   status("  Android: ")
 651   status("    Android ABI:" ${ANDROID_ABI})
 652   status("    STL type:" ${ANDROID_STL})
 653   status("    Native API level:" android-${ANDROID_NATIVE_API_LEVEL})
 654   android_get_compatible_target(android_sdk_target_status ${ANDROID_NATIVE_API_LEVEL} ${ANDROID_SDK_TARGET} 11)
 655   status("    SDK target:" "${android_sdk_target_status}")
 656   if(BUILD_WITH_ANDROID_NDK)
 657     status("    Android NDK:" "${ANDROID_NDK} (toolchain: ${ANDROID_TOOLCHAIN_NAME})")
 658   elseif(BUILD_WITH_STANDALONE_TOOLCHAIN)
 659     status("    Android toolchain:" "${ANDROID_STANDALONE_TOOLCHAIN}")
 660   endif()
 661   status("    android tool:"  ANDROID_EXECUTABLE  THEN "${ANDROID_EXECUTABLE} (${ANDROID_TOOLS_Pkg_Desc})" ELSE NO)
 662   status("    Google Play package:" BUILD_ANDROID_PACKAGE                                         THEN YES ELSE NO)
 663   status("    Android examples:"    BUILD_ANDROID_EXAMPLES AND CAN_BUILD_ANDROID_PROJECTS         THEN YES ELSE NO)
 664 endif()
 665
 666 # ================== Windows RT features ==================
 667 if(WIN32)
 668 status("")
 669     status("  Windows RT support:" HAVE_WINRT THEN YES ELSE NO)
 670     if (ENABLE_WINRT_MODE OR ENABLE_WINRT_MODE_NATIVE)
 671       status("    Windows SDK v8.0:" ${WINDOWS_SDK_PATH})
 672       status("    Visual Studio 2012:" ${VISUAL_STUDIO_PATH})
 673     endif()
 674 endif(WIN32)
 675
 676 # ========================== GUI ==========================
 677 status("")
 678 status("  GUI: ")
 679
 680 if(HAVE_QT5)
 681   status("    QT 5.x:"            HAVE_QT        THEN "YES (ver ${Qt5Core_VERSION_STRING})" ELSE NO)
 682   status("    QT OpenGL support:" HAVE_QT_OPENGL THEN "YES (${Qt5OpenGL_LIBRARIES} ${Qt5OpenGL_VERSION_STRING})" ELSE NO)
 683 elseif(HAVE_QT)
 684   status("    QT 4.x:"            HAVE_QT        THEN "YES (ver ${QT_VERSION_MAJOR}.${QT_VERSION_MINOR}.${QT_VERSION_PATCH} ${QT_EDITION})" ELSE NO)
 685   status("    QT OpenGL support:" HAVE_QT_OPENGL THEN "YES (${QT_QTOPENGL_LIBRARY})" ELSE NO)
 686 else()
 687   if(DEFINED WITH_QT)
 688     status("    QT:" NO)
 689   endif()
 690   if(DEFINED WITH_WIN32UI)
 691     status("    Win32 UI:" HAVE_WIN32UI THEN YES ELSE NO)
 692   else()
 693     if(APPLE)
 694       if(WITH_CARBON)
 695         status("    Carbon:" YES)
 696       else()
 697         status("    Cocoa:"  YES)
 698       endif()
 699     else()
 700       status("    GTK+ 2.x:" HAVE_GTK      THEN "YES (ver ${ALIASOF_gtk+-2.0_VERSION})"     ELSE NO)
 701       status("    GThread :" HAVE_GTHREAD  THEN "YES (ver ${ALIASOF_gthread-2.0_VERSION})"  ELSE NO)
 702       status("    GtkGlExt:" HAVE_GTKGLEXT THEN "YES (ver ${ALIASOF_gtkglext-1.0_VERSION})" ELSE NO)
 703     endif()
 704   endif()
 705 endif()
 706
 707 status("    OpenGL support:" HAVE_OPENGL THEN "YES (${OPENGL_LIBRARIES})" ELSE NO)
 708
 709 # ========================== MEDIA IO ==========================
 710 status("")
 711 status("  Media I/O: ")
 712 status("    ZLib:"         BUILD_ZLIB    THEN "build (ver ${ZLIB_VERSION_STRING})"               ELSE "${ZLIB_LIBRARY} (ver ${ZLIB_VERSION_STRING})")
 713
 714 if(WITH_JPEG)
 715   status("    JPEG:"       JPEG_FOUND    THEN "${JPEG_LIBRARY} (ver ${JPEG_LIB_VERSION})"        ELSE "build (ver ${JPEG_LIB_VERSION})")
 716 else()
 717   status("    JPEG:"       "NO")
 718 endif()
 719 if(WITH_PNG)
 720   status("    PNG:"        PNG_FOUND     THEN "${PNG_LIBRARY} (ver ${PNG_VERSION})"              ELSE "build (ver ${PNG_VERSION})")
 721 else()
 722   status("    PNG:"        "NO")
 723 endif()
 724 if(WITH_TIFF)
 725   if(TIFF_VERSION_STRING AND TIFF_FOUND)
 726     status("    TIFF:"     "${TIFF_LIBRARY} (ver ${TIFF_VERSION} - ${TIFF_VERSION_STRING})")
 727   else()
 728     status("    TIFF:"     TIFF_FOUND    THEN "${TIFF_LIBRARY} (ver ${TIFF_VERSION})"            ELSE "build (ver ${TIFF_VERSION} - ${TIFF_VERSION_STRING})")
 729   endif()
 730 else()
 731   status("    TIFF:"       "NO")
 732 endif()
 733 if(WITH_JASPER)
 734   status("    JPEG 2000:"  JASPER_FOUND  THEN "${JASPER_LIBRARY} (ver ${JASPER_VERSION_STRING})" ELSE "build (ver ${JASPER_VERSION_STRING})")
 735 else()
 736   status("    JPEG 2000:"  "NO")
 737 endif()
 738 if(WITH_OPENEXR)
 739   status("    OpenEXR:"  OPENEXR_FOUND  THEN "${OPENEXR_LIBRARIES} (ver ${OPENEXR_VERSION})" ELSE "build (ver ${OPENEXR_VERSION})")
 740 else()
 741   status("    OpenEXR:"  "NO")
 742 endif()
 743
 744 # ========================== VIDEO IO ==========================
 745 status("")
 746 status("  Video I/O:")
 747
 748 if (DEFINED WITH_VFW)
 749   status("    Video for Windows:" HAVE_VFW         THEN YES                                        ELSE NO)
 750 endif(DEFINED WITH_VFW)
 751
 752 if(DEFINED WITH_1394)
 753   status("    DC1394 1.x:"     HAVE_DC1394         THEN "YES (ver ${ALIASOF_libdc1394_VERSION})"   ELSE NO)
 754   status("    DC1394 2.x:"     HAVE_DC1394_2       THEN "YES (ver ${ALIASOF_libdc1394-2_VERSION})" ELSE NO)
 755 endif(DEFINED WITH_1394)
 756
 757 if(ANDROID)
 758   if(HAVE_opencv_androidcamera)
 759     status("    AndroidNativeCamera:" BUILD_ANDROID_CAMERA_WRAPPER
 760                                                    THEN "YES, build for Android${ANDROID_VERSION}" ELSE "YES, use prebuilt libraries")
 761   else()
 762     status("    AndroidNativeCamera:" "NO (native camera requires Android API level 8 or higher)")
 763   endif()
 764 endif()
 765
 766 if(DEFINED WITH_AVFOUNDATION)
 767   status("    AVFoundation:"   WITH_AVFOUNDATION   THEN YES                                        ELSE NO)
 768 endif(DEFINED WITH_AVFOUNDATION)
 769
 770 if(DEFINED WITH_FFMPEG)
 771   if(WIN32)
 772     status("    FFMPEG:"       WITH_FFMPEG         THEN "YES (prebuilt binaries)"                  ELSE NO)
 773   else()
 774     status("    FFMPEG:"       HAVE_FFMPEG         THEN YES ELSE NO)
 775   endif()
 776   status("      codec:"        HAVE_FFMPEG_CODEC   THEN "YES (ver ${ALIASOF_libavcodec_VERSION})"  ELSE NO)
 777   status("      format:"       HAVE_FFMPEG_FORMAT  THEN "YES (ver ${ALIASOF_libavformat_VERSION})" ELSE NO)
 778   status("      util:"         HAVE_FFMPEG_UTIL    THEN "YES (ver ${ALIASOF_libavutil_VERSION})"   ELSE NO)
 779   status("      swscale:"      HAVE_FFMPEG_SWSCALE THEN "YES (ver ${ALIASOF_libswscale_VERSION})"  ELSE NO)
 780   status("      gentoo-style:" HAVE_GENTOO_FFMPEG  THEN YES                                        ELSE NO)
 781 endif(DEFINED WITH_FFMPEG)
 782
 783 if(DEFINED WITH_GSTREAMER)
 784   status("    GStreamer:"      HAVE_GSTREAMER      THEN ""                                         ELSE NO)
 785   if(HAVE_GSTREAMER)
 786     status("      base:"       "YES (ver ${ALIASOF_gstreamer-base-0.10_VERSION})")
 787     status("      app:"        "YES (ver ${ALIASOF_gstreamer-app-0.10_VERSION})")
 788     status("      video:"      "YES (ver ${ALIASOF_gstreamer-video-0.10_VERSION})")
 789   endif()
 790 endif(DEFINED WITH_GSTREAMER)
 791
 792 if(DEFINED WITH_OPENNI)
 793   status("    OpenNI:"         HAVE_OPENNI         THEN "YES (ver ${OPENNI_VERSION_STRING}, build ${OPENNI_VERSION_BUILD})"
 794                                                                                                    ELSE NO)
 795   status("    OpenNI PrimeSensor Modules:" HAVE_OPENNI_PRIME_SENSOR_MODULE
 796                                                    THEN "YES (${OPENNI_PRIME_SENSOR_MODULE})"      ELSE NO)
 797 endif(DEFINED WITH_OPENNI)
 798
 799 if(DEFINED WITH_PVAPI)
 800   status("    PvAPI:"          HAVE_PVAPI          THEN YES                                        ELSE NO)
 801 endif(DEFINED WITH_PVAPI)
 802
 803 if(DEFINED WITH_GIGEAPI)
 804   status("    GigEVisionSDK:"  HAVE_GIGE_API       THEN YES                                        ELSE NO)
 805 endif(DEFINED WITH_GIGEAPI)
 806
 807 if(DEFINED WITH_QUICKTIME)
 808   status("    QuickTime:"      HAVE_QUICKTIME      THEN YES                                        ELSE NO)
 809   status("    QTKit:"          HAVE_QTKIT          THEN YES                                        ELSE NO)
 810 endif(DEFINED WITH_QUICKTIME)
 811
 812 if(DEFINED WITH_UNICAP)
 813   status("    UniCap:"         HAVE_UNICAP         THEN "YES (ver ${ALIASOF_libunicap_VERSION})"   ELSE NO)
 814   status("    UniCap ucil:"    HAVE_UNICAP_UCIL    THEN "YES (ver ${ALIASOF_libucil_VERSION})"     ELSE NO)
 815 endif(DEFINED WITH_UNICAP)
 816
 817 if(DEFINED WITH_V4L)
 818   if(HAVE_CAMV4L)
 819     set(HAVE_CAMV4L_STR "YES")
 820   else()
 821     set(HAVE_CAMV4L_STR "NO")
 822   endif()
 823   if(HAVE_CAMV4L2)
 824     set(HAVE_CAMV4L2_STR "YES")
 825   elseif(HAVE_VIDEOIO)
 826     set(HAVE_CAMV4L2_STR "YES(videoio)")
 827   else()
 828     set(HAVE_CAMV4L2_STR "NO")
 829   endif()
 830   status("    V4L/V4L2:"       HAVE_LIBV4L         THEN "Using libv4l (ver ${ALIASOF_libv4l1_VERSION})"
 831                                                    ELSE "${HAVE_CAMV4L_STR}/${HAVE_CAMV4L2_STR}")
 832 endif(DEFINED WITH_V4L)
 833
 834 if(DEFINED WITH_DSHOW)
 835   status("    DirectShow:"     HAVE_DSHOW     THEN YES                                        ELSE NO)
 836 endif(DEFINED WITH_DSHOW)
 837
 838 if(DEFINED WITH_MSMF)
 839   status("    Media Foundation:" HAVE_MSMF    THEN YES                                        ELSE NO)
 840 endif(DEFINED WITH_MSMF)
 841
 842 if(DEFINED WITH_XIMEA)
 843   status("    XIMEA:"          HAVE_XIMEA          THEN YES                                        ELSE NO)
 844 endif(DEFINED WITH_XIMEA)
 845
 846 if(DEFINED WITH_XINE)
 847   status("    Xine:"           HAVE_XINE           THEN "YES (ver ${ALIASOF_libxine_VERSION})"     ELSE NO)
 848 endif(DEFINED WITH_XINE)
 849
 850 if(DEFINED WITH_INTELPERC)
 851   status("    Intel PerC:"     HAVE_INTELPERC      THEN "YES"                                 ELSE NO)
 852 endif(DEFINED WITH_INTELPERC)
 853
 854
 855 # ========================== Other third-party libraries ==========================
 856 status("")
 857 status("  Other third-party libraries:")
 858
 859 if(WITH_IPP AND IPP_FOUND)
 860   status("    Use IPP:" "${IPP_LATEST_VERSION_STR} [${IPP_LATEST_VERSION_MAJOR}.${IPP_LATEST_VERSION_MINOR}.${IPP_LATEST_VERSION_BUILD}]")
 861   status("         at:" "${IPP_ROOT_DIR}")
 862 else()
 863   status("    Use IPP:"   WITH_IPP AND NOT IPP_FOUND THEN "IPP not found" ELSE NO)
 864 endif()
 865
 866 status("    Use Eigen:"      HAVE_EIGEN       THEN "YES (ver ${EIGEN_WORLD_VERSION}.${EIGEN_MAJOR_VERSION}.${EIGEN_MINOR_VERSION})" ELSE NO)
 867 status("    Use TBB:"        HAVE_TBB         THEN "YES (ver ${TBB_VERSION_MAJOR}.${TBB_VERSION_MINOR} interface ${TBB_INTERFACE_VERSION})" ELSE NO)
 868 status("    Use OpenMP:"     HAVE_OPENMP      THEN YES ELSE NO)
 869 status("    Use GCD"         HAVE_GCD         THEN YES ELSE NO)
 870 status("    Use Concurrency" HAVE_CONCURRENCY THEN YES ELSE NO)
 871 status("    Use C=:"         HAVE_CSTRIPES    THEN YES ELSE NO)
 872 status("    Use Cuda:"       HAVE_CUDA        THEN "YES (ver ${CUDA_VERSION_STRING})" ELSE NO)
 873 status("    Use OpenCL:"     HAVE_OPENCL      THEN YES ELSE NO)
 874
 875 if(HAVE_CUDA)
 876   status("")
 877   status("  NVIDIA CUDA")
 878
 879   status("    Use CUFFT:"            HAVE_CUFFT   THEN YES ELSE NO)
 880   status("    Use CUBLAS:"           HAVE_CUBLAS  THEN YES ELSE NO)
 881   status("    USE NVCUVID:"          HAVE_NVCUVID THEN YES ELSE NO)
 882   status("    NVIDIA GPU arch:"      ${OPENCV_CUDA_ARCH_BIN})
 883   status("    NVIDIA PTX archs:"     ${OPENCV_CUDA_ARCH_PTX})
 884   status("    Use fast math:"        CUDA_FAST_MATH THEN YES ELSE NO)
 885 endif()
 886
 887 if(HAVE_OPENCL)
 888   status("")
 889   status("  OpenCL:")
 890   if(HAVE_OPENCL_STATIC)
 891     set(__opencl_ver "static")
 892   else()
 893     set(__opencl_ver "dynamic")
 894   endif()
 895   status("    Version:"       ${__opencl_ver})
 896   if(OPENCL_INCLUDE_DIR)
 897     status("    Include path:"       ${OPENCL_INCLUDE_DIRS})
 898   endif()
 899   if(OPENCL_LIBRARIES)
 900     set(__libs "")
 901     foreach(l ${OPENCL_LIBRARIES})
 902       if(TARGET ${l})
 903         get_target_property(p ${l} LOCATION)
 904         if(p MATCHES NOTFOUND)
 905           list(APPEND __libs "${l}")
 906         else()
 907           list(APPEND __libs "${p}")
 908         endif()
 909       else()
 910         list(APPEND __libs "${l}")
 911       endif()
 912     endforeach()
 913     status("    libraries:"          ${__libs})
 914   endif()
 915   status("    Use AMD FFT:"          HAVE_CLAMDFFT  THEN YES ELSE NO)
 916   status("    Use AMD BLAS:"         HAVE_CLAMDBLAS THEN YES ELSE NO)
 917 endif()
 918
 919 # ========================== python ==========================
 920 status("")
 921 status("  Python:")
 922 status("    Interpreter:"     PYTHON_EXECUTABLE   THEN "${PYTHON_EXECUTABLE} (ver ${PYTHON_VERSION_FULL})"         ELSE NO)
 923 if(BUILD_opencv_python)
 924   if(PYTHONLIBS_VERSION_STRING)
 925     status("    Libraries:"   HAVE_opencv_python  THEN  "${PYTHON_LIBRARIES} (ver ${PYTHONLIBS_VERSION_STRING})"   ELSE NO)
 926   else()
 927     status("    Libraries:"   HAVE_opencv_python  THEN  ${PYTHON_LIBRARIES}                                        ELSE NO)
 928   endif()
 929   status("    numpy:"         PYTHON_USE_NUMPY    THEN "${PYTHON_NUMPY_INCLUDE_DIR} (ver ${PYTHON_NUMPY_VERSION})" ELSE "NO (Python wrappers can not be generated)")
 930   status("    packages path:" PYTHON_EXECUTABLE   THEN "${PYTHON_PACKAGES_PATH}"                                   ELSE "-")
 931 endif()
 932
 933 # ========================== java ==========================
 934 status("")
 935 status("  Java:")
 936 status("    ant:"           ANT_EXECUTABLE      THEN "${ANT_EXECUTABLE} (ver ${ANT_VERSION})"                    ELSE NO)
 937 if(NOT ANDROID)
 938   status("    JNI:"         JNI_INCLUDE_DIRS    THEN "${JNI_INCLUDE_DIRS}"                                       ELSE NO)
 939 endif()
 940 status("    Java tests:"    BUILD_TESTS AND (CAN_BUILD_ANDROID_PROJECTS OR HAVE_opencv_java)            THEN YES ELSE NO)
 941
 942 # ========================== documentation ==========================
 943 if(BUILD_DOCS)
 944   status("")
 945   status("  Documentation:")
 946   if(HAVE_SPHINX)
 947     status("    Build Documentation:" PDFLATEX_COMPILER      THEN YES ELSE "YES (only HTML and without math expressions)")
 948   else()
 949     status("    Build Documentation:" NO)
 950   endif()
 951   status("    Sphinx:"              HAVE_SPHINX              THEN "${SPHINX_BUILD} (ver ${SPHINX_VERSION})" ELSE NO)
 952   status("    PdfLaTeX compiler:"   PDFLATEX_COMPILER        THEN "${PDFLATEX_COMPILER}" ELSE NO)
 953 endif()
 954
 955 # ========================== samples and tests ==========================
 956 status("")
 957 status("  Tests and samples:")
 958 status("    Tests:"             BUILD_TESTS AND HAVE_opencv_ts       THEN YES ELSE NO)
 959 status("    Performance tests:" BUILD_PERF_TESTS AND HAVE_opencv_ts  THEN YES ELSE NO)
 960 status("    C/C++ Examples:"    BUILD_EXAMPLES                       THEN YES ELSE NO)
 961
 962 # ========================== auxiliary ==========================
 963 status("")
 964 status("  Install path:" "${CMAKE_INSTALL_PREFIX}")
 965 status("")
 966 status("  cvconfig.h is in:" "${OPENCV_CONFIG_FILE_INCLUDE_DIR}")
 967 status("-----------------------------------------------------------------")
 968 status("")
 969
 970 ocv_finalize_status()
 971
 972 # ----------------------------------------------------------------------------
 973 # Warn in the case of in-source build
 974 # ----------------------------------------------------------------------------
 975 if("${CMAKE_CURRENT_SOURCE_DIR}" STREQUAL "${CMAKE_CURRENT_BINARY_DIR}")
 976   message(WARNING "The source directory is the same as binary directory. \"make clean\" may damage the source tree")
 977 endif()