CMakeLists.txt

   1 cmake_minimum_required(VERSION 2.8.9)
   2 project(heaptrack)
   3 enable_testing()
   4
   5 if(NOT CMAKE_BUILD_TYPE)
   6   message(STATUS "Setting build type to 'RelWithDebInfo' as none was specified.")
   7   set(CMAKE_BUILD_TYPE RelWithDebInfo CACHE STRING "Choose the type of build." FORCE)
   8 endif()
   9
  10 set(HEAPTRACK_VERSION_MAJOR 0)
  11 set(HEAPTRACK_VERSION_MINOR 1)
  12 set(HEAPTRACK_VERSION_PATCH 0)
  13 set(HEAPTRACK_LIB_VERSION 1.0.0)
  14 set(HEAPTRACK_LIB_SOVERSION 1)
  15
  16 find_package(Boost 1.41.0 REQUIRED COMPONENTS iostreams program_options)
  17 find_package(Threads REQUIRED)
  18 find_package(Qt5 5.2.0 NO_MODULE OPTIONAL_COMPONENTS Widgets)
  19 find_package(ECM 1.0.0 NO_MODULE)
  20 find_package(ZLIB REQUIRED)
  21 include(FeatureSummary)
  22
  23 if(Qt5_FOUND AND ECM_FOUND)
  24     set(CMAKE_MODULE_PATH ${CMAKE_MODULE_PATH} ${ECM_MODULE_PATH} ${ECM_KDE_MODULE_DIR})
  25     find_package(KF5 OPTIONAL_COMPONENTS CoreAddons I18n ItemModels ThreadWeaver ConfigWidgets)
  26     find_package(KChart "2.6.0")
  27     set_package_properties(KChart PROPERTIES TYPE RECOMMENDED PURPOSE "Required for the heaptrack_gui executable. Get it from the kdiagram module.")
  28     if (KF5_FOUND AND KChart_FOUND)
  29         add_subdirectory(gui)
  30     endif()
  31 endif()
  32
  33 set(CMAKE_INSTALL_RPATH_USE_LINK_PATH TRUE)
  34
  35 set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -std=c++11 -Wall -Wpedantic")
  36
  37 add_subdirectory(3rdparty)
  38
  39 check_library_exists (${LIBUNWIND_LIBRARY} unw_backtrace "" HAVE_UNW_BACKTRACE)
  40 if (NOT HAVE_UNW_BACKTRACE)
  41     message(FATAL_ERROR "Your libunwind version is apparently too old and does not have the unw_backtrace function.")
  42 endif()
  43
  44 check_library_exists (${LIBUNWIND_LIBRARY} _ULx86_64_set_cache_size "" HAVE_UNW_SET_CACHE_SIZE)
  45
  46 include (CheckCXXSourceCompiles)
  47 check_cxx_source_compiles(
  48     "#include <unordered_map>
  49     #include <atomic>
  50     thread_local int tls;
  51     int main() { return 0; }"
  52     HAVE_CXX11_SUPPORT)
  53
  54 if (NOT HAVE_CXX11_SUPPORT)
  55     message(FATAL_ERROR "Your compiler is too old and does not support the required C++11 features.")
  56 endif()
  57
  58 check_cxx_source_compiles(
  59     "#include <stdio_ext.h>
  60     #include <fcntl.h>
  61     #include <dlfcn.h>
  62     #include <link.h>
  63     int main() { return 0; }"
  64     HAVE_LINUX_HEADERS)
  65
  66 if (NOT HAVE_LINUX_HEADERS)
  67     message(FATAL_ERROR "You are missing some Linux headers required to compile heaptrack.")
  68 endif()
  69
  70 add_subdirectory(tests)
  71
  72 include_directories(
  73     ${CMAKE_CURRENT_BINARY_DIR}
  74     ${Boost_INCLUDE_DIRS}
  75     3rdparty/
  76     ${LIBUNWIND_INCLUDE_DIR}
  77     ${ZLIB_INCLUDE_DIRS}
  78 )
  79
  80 if (CMAKE_BUILD_TYPE STREQUAL "Debug")
  81     set(HEAPTRACK_DEBUG_BUILD 1)
  82 else()
  83     set(HEAPTRACK_DEBUG_BUILD 0)
  84 endif()
  85
  86 configure_file(config.h.cmake ${CMAKE_CURRENT_BINARY_DIR}/config.h)
  87
  88 add_library(heaptrack_preload MODULE heaptrack_preload.cpp libheaptrack.cpp)
  89 target_link_libraries(heaptrack_preload LINK_PRIVATE ${CMAKE_DL_LIBS} ${CMAKE_THREAD_LIBS_INIT} backtrace rt)
  90 set_target_properties(heaptrack_preload PROPERTIES VERSION ${HEAPTRACK_LIB_VERSION} SOVERSION ${HEAPTRACK_LIB_SOVERSION})
  91 add_library(heaptrack_inject MODULE heaptrack_inject.cpp libheaptrack.cpp)
  92 target_link_libraries(heaptrack_inject LINK_PRIVATE ${CMAKE_DL_LIBS} ${CMAKE_THREAD_LIBS_INIT} backtrace rt)
  93 set_target_properties(heaptrack_inject PROPERTIES VERSION ${HEAPTRACK_LIB_VERSION} SOVERSION ${HEAPTRACK_LIB_SOVERSION})
  94
  95 add_executable(heaptrack_interpret heaptrack_interpret.cpp)
  96 target_link_libraries(heaptrack_interpret backtrace)
  97
  98 add_library(sharedprint STATIC accumulatedtracedata.cpp)
  99 target_link_libraries(sharedprint LINK_PUBLIC ${Boost_LIBRARIES} ${ZLIB_LIBRARIES})
 100 add_executable(heaptrack_print heaptrack_print.cpp)
 101 target_link_libraries(heaptrack_print LINK_PRIVATE sharedprint)
 102
 103 set(BIN_INSTALL_DIR "bin")
 104 set(LIB_SUFFIX "" CACHE STRING "Define suffix of directory name (32/64)")
 105 set(LIB_INSTALL_DIR "lib${LIB_SUFFIX}")
 106 set(LIBEXEC_INSTALL_DIR "${LIB_INSTALL_DIR}/heaptrack/libexec")
 107
 108 file(RELATIVE_PATH LIBEXEC_REL_PATH
 109     "${CMAKE_INSTALL_PREFIX}/${BIN_INSTALL_DIR}"
 110     "${CMAKE_INSTALL_PREFIX}/${LIBEXEC_INSTALL_DIR}")
 111
 112 file(RELATIVE_PATH LIB_REL_PATH
 113     "${CMAKE_INSTALL_PREFIX}/${BIN_INSTALL_DIR}"
 114     "${CMAKE_INSTALL_PREFIX}/${LIB_INSTALL_DIR}/heaptrack")
 115
 116 configure_file(heaptrack.sh.cmake ${CMAKE_CURRENT_BINARY_DIR}/heaptrack @ONLY)
 117
 118 install(TARGETS heaptrack_print RUNTIME DESTINATION ${BIN_INSTALL_DIR})
 119 install(PROGRAMS ${CMAKE_CURRENT_BINARY_DIR}/heaptrack DESTINATION ${BIN_INSTALL_DIR})
 120 install(TARGETS heaptrack_interpret RUNTIME DESTINATION ${LIBEXEC_INSTALL_DIR})
 121 install(TARGETS heaptrack_inject LIBRARY DESTINATION ${LIB_INSTALL_DIR}/heaptrack/)
 122 install(TARGETS heaptrack_preload LIBRARY DESTINATION ${LIB_INSTALL_DIR}/heaptrack/)
 123
 124 feature_summary(WHAT ALL FATAL_ON_MISSING_REQUIRED_PACKAGES)