CMakeLists.txt

   1 # ----------------------------------------------------------------------------
   2 #  Root CMake file for OpenCV
   3 #
   4 #    From the off-tree build directory, invoke:
   5 #      $ cmake <PATH_TO_OPENCV_ROOT>
   6 #
   7 # ----------------------------------------------------------------------------
   8
   9 # Disable in-source builds to prevent source tree corruption.
  10 if(" ${CMAKE_SOURCE_DIR}" STREQUAL " ${CMAKE_BINARY_DIR}")
  11   message(FATAL_ERROR "
  12 FATAL: In-source builds are not allowed.
  13        You should create a separate directory for build files.
  14 ")
  15 endif()
  16
  17
  18 include(cmake/OpenCVMinDepVersions.cmake)
  19
  20 if(CMAKE_GENERATOR MATCHES Xcode AND XCODE_VERSION VERSION_GREATER 4.3)
  21   cmake_minimum_required(VERSION 3.0 FATAL_ERROR)
  22 elseif(CMAKE_SYSTEM_NAME MATCHES WindowsPhone OR CMAKE_SYSTEM_NAME MATCHES WindowsStore)
  23   cmake_minimum_required(VERSION 3.1 FATAL_ERROR)
  24   #Required to resolve linker error issues due to incompatibility with CMake v3.0+ policies.
  25   #CMake fails to find _fseeko() which leads to subsequent linker error.
  26   #See details here: http://www.cmake.org/Wiki/CMake/Policies
  27   cmake_policy(VERSION 2.8)
  28 else()
  29   cmake_minimum_required(VERSION "${MIN_VER_CMAKE}" FATAL_ERROR)
  30 endif()
  31
  32 #
  33 # Configure CMake policies
  34 #
  35 if(POLICY CMP0026)
  36   cmake_policy(SET CMP0026 NEW)
  37 endif()
  38
  39 if(POLICY CMP0042)
  40   cmake_policy(SET CMP0042 NEW)  # CMake 3.0+ (2.8.12): MacOS "@rpath" in target's install name
  41 endif()
  42
  43 if(POLICY CMP0046)
  44   cmake_policy(SET CMP0046 NEW)  # warn about non-existed dependencies
  45 endif()
  46
  47 if(POLICY CMP0051)
  48   cmake_policy(SET CMP0051 NEW)
  49 endif()
  50
  51 if(POLICY CMP0054)  # CMake 3.1: Only interpret if() arguments as variables or keywords when unquoted.
  52   cmake_policy(SET CMP0054 NEW)
  53 endif()
  54
  55 if(POLICY CMP0056)
  56   cmake_policy(SET CMP0056 NEW)  # try_compile(): link flags
  57 endif()
  58
  59 if(POLICY CMP0066)
  60   cmake_policy(SET CMP0066 NEW)  # CMake 3.7: try_compile(): use per-config flags, like CMAKE_CXX_FLAGS_RELEASE
  61 endif()
  62
  63 if(POLICY CMP0067)
  64   cmake_policy(SET CMP0067 NEW)  # CMake 3.8: try_compile(): honor language standard variables (like C++11)
  65 endif()
  66
  67 if(POLICY CMP0068)
  68   cmake_policy(SET CMP0068 NEW)  # CMake 3.9+: `RPATH` settings on macOS do not affect `install_name`.
  69 endif()
  70
  71 if(POLICY CMP0075)
  72   cmake_policy(SET CMP0075 NEW)  # CMake 3.12+: Include file check macros honor `CMAKE_REQUIRED_LIBRARIES`
  73 endif()
  74
  75 if(POLICY CMP0077)
  76   cmake_policy(SET CMP0077 NEW)  # CMake 3.13+: option() honors normal variables.
  77 endif()
  78
  79 #
  80 # Configure OpenCV CMake hooks
  81 #
  82 include(cmake/OpenCVUtils.cmake)
  83 ocv_cmake_reset_hooks()
  84 ocv_check_environment_variables(OPENCV_CMAKE_HOOKS_DIR)
  85 if(DEFINED OPENCV_CMAKE_HOOKS_DIR)
  86   foreach(__dir ${OPENCV_CMAKE_HOOKS_DIR})
  87     get_filename_component(__dir "${__dir}" ABSOLUTE)
  88     ocv_cmake_hook_register_dir(${__dir})
  89   endforeach()
  90 endif()
  91
  92 ocv_cmake_hook(CMAKE_INIT)
  93
  94 # must go before the project()/enable_language() commands
  95 ocv_update(CMAKE_CONFIGURATION_TYPES "Debug;Release" CACHE STRING "Configs" FORCE)
  96 if(DEFINED CMAKE_BUILD_TYPE)
  97   set_property(CACHE CMAKE_BUILD_TYPE PROPERTY STRINGS "${CMAKE_CONFIGURATION_TYPES}")
  98 endif()
  99
 100 option(ENABLE_PIC "Generate position independent code (necessary for shared libraries)" TRUE)
 101 set(CMAKE_POSITION_INDEPENDENT_CODE ${ENABLE_PIC})
 102
 103 ocv_cmake_hook(PRE_CMAKE_BOOTSTRAP)
 104
 105 # Bootstap CMake system: setup CMAKE_SYSTEM_NAME and other vars
 106 enable_language(CXX C)
 107
 108 ocv_cmake_hook(POST_CMAKE_BOOTSTRAP)
 109
 110 if(NOT OPENCV_SKIP_CMAKE_SYSTEM_FILE)
 111   include("cmake/platforms/OpenCV-${CMAKE_SYSTEM_NAME}.cmake" OPTIONAL RESULT_VARIABLE "OPENCV_CMAKE_SYSTEM_FILE")
 112   if(NOT OPENCV_CMAKE_SYSTEM_FILE)
 113     message(STATUS "OpenCV: system-specific configuration file is not found: '${CMAKE_SYSTEM_NAME}'")
 114   endif()
 115 endif()
 116
 117 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)  # https://cmake.org/cmake/help/latest/variable/CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT.html
 118   if(NOT CMAKE_TOOLCHAIN_FILE)
 119     if(WIN32)
 120       set(CMAKE_INSTALL_PREFIX "${CMAKE_BINARY_DIR}/install" CACHE PATH "Installation Directory" FORCE)
 121     else()
 122       set(CMAKE_INSTALL_PREFIX "/usr/local" CACHE PATH "Installation Directory" FORCE)
 123     endif()
 124   else()
 125     # any cross-compiling
 126     set(CMAKE_INSTALL_PREFIX "${CMAKE_BINARY_DIR}/install" CACHE PATH "Installation Directory" FORCE)
 127   endif()
 128 endif()
 129
 130 enable_testing()
 131
 132 project(OpenCV CXX C)
 133
 134 if(MSVC)
 135   set(CMAKE_USE_RELATIVE_PATHS ON CACHE INTERNAL "" FORCE)
 136 endif()
 137
 138 ocv_cmake_eval(DEBUG_PRE ONCE)
 139
 140 ocv_clear_vars(OpenCVModules_TARGETS)
 141
 142 include(cmake/OpenCVDownload.cmake)
 143
 144 set(BUILD_LIST "" CACHE STRING "Build only listed modules (comma-separated, e.g. 'videoio,dnn,ts')")
 145
 146 # ----------------------------------------------------------------------------
 147 # Break in case of popular CMake configuration mistakes
 148 # ----------------------------------------------------------------------------
 149 if(NOT CMAKE_SIZEOF_VOID_P GREATER 0)
 150   message(FATAL_ERROR "CMake fails to determine the bitness of the target platform.
 151   Please check your CMake and compiler installation. If you are cross-compiling then ensure that your CMake toolchain file correctly sets the compiler details.")
 152 endif()
 153
 154 # ----------------------------------------------------------------------------
 155 # Detect compiler and target platform architecture
 156 # ----------------------------------------------------------------------------
 157 include(cmake/OpenCVDetectCXXCompiler.cmake)
 158 ocv_cmake_hook(POST_DETECT_COMPILER)
 159
 160 # Add these standard paths to the search paths for FIND_LIBRARY
 161 # to find libraries from these locations first
 162 if(UNIX AND NOT ANDROID)
 163   if(X86_64 OR CMAKE_SIZEOF_VOID_P EQUAL 8)
 164     if(EXISTS /lib64)
 165       list(APPEND CMAKE_LIBRARY_PATH /lib64)
 166     else()
 167       list(APPEND CMAKE_LIBRARY_PATH /lib)
 168     endif()
 169     if(EXISTS /usr/lib64)
 170       list(APPEND CMAKE_LIBRARY_PATH /usr/lib64)
 171     else()
 172       list(APPEND CMAKE_LIBRARY_PATH /usr/lib)
 173     endif()
 174   elseif(X86 OR CMAKE_SIZEOF_VOID_P EQUAL 4)
 175     if(EXISTS /lib32)
 176       list(APPEND CMAKE_LIBRARY_PATH /lib32)
 177     else()
 178       list(APPEND CMAKE_LIBRARY_PATH /lib)
 179     endif()
 180     if(EXISTS /usr/lib32)
 181       list(APPEND CMAKE_LIBRARY_PATH /usr/lib32)
 182     else()
 183       list(APPEND CMAKE_LIBRARY_PATH /usr/lib)
 184     endif()
 185   endif()
 186 endif()
 187
 188 # Add these standard paths to the search paths for FIND_PATH
 189 # to find include files from these locations first
 190 if(MINGW)
 191   if(EXISTS /mingw)
 192       list(APPEND CMAKE_INCLUDE_PATH /mingw)
 193   endif()
 194   if(EXISTS /mingw32)
 195       list(APPEND CMAKE_INCLUDE_PATH /mingw32)
 196   endif()
 197   if(EXISTS /mingw64)
 198       list(APPEND CMAKE_INCLUDE_PATH /mingw64)
 199   endif()
 200 endif()
 201
 202 # ----------------------------------------------------------------------------
 203 # OpenCV cmake options
 204 # ----------------------------------------------------------------------------
 205
 206 OCV_OPTION(OPENCV_ENABLE_NONFREE "Enable non-free algorithms" OFF)
 207
 208 # 3rd party libs
 209 OCV_OPTION(OPENCV_FORCE_3RDPARTY_BUILD   "Force using 3rdparty code from source" OFF)
 210 OCV_OPTION(BUILD_ZLIB               "Build zlib from source"             (WIN32 OR APPLE OR OPENCV_FORCE_3RDPARTY_BUILD) )
 211 OCV_OPTION(BUILD_TIFF               "Build libtiff from source"          (WIN32 OR ANDROID OR APPLE OR OPENCV_FORCE_3RDPARTY_BUILD) )
 212 OCV_OPTION(BUILD_JASPER             "Build libjasper from source"        (WIN32 OR ANDROID OR APPLE OR OPENCV_FORCE_3RDPARTY_BUILD) )
 213 OCV_OPTION(BUILD_JPEG               "Build libjpeg from source"          (WIN32 OR ANDROID OR APPLE OR OPENCV_FORCE_3RDPARTY_BUILD) )
 214 OCV_OPTION(BUILD_PNG                "Build libpng from source"           (WIN32 OR ANDROID OR APPLE OR OPENCV_FORCE_3RDPARTY_BUILD) )
 215 OCV_OPTION(BUILD_OPENEXR            "Build openexr from source"          (((WIN32 OR ANDROID OR APPLE) AND NOT WINRT) OR OPENCV_FORCE_3RDPARTY_BUILD) )
 216 OCV_OPTION(BUILD_WEBP               "Build WebP from source"             (((WIN32 OR ANDROID OR APPLE) AND NOT WINRT) OR OPENCV_FORCE_3RDPARTY_BUILD) )
 217 OCV_OPTION(BUILD_TBB                "Download and build TBB from source" (ANDROID OR OPENCV_FORCE_3RDPARTY_BUILD) )
 218 OCV_OPTION(BUILD_IPP_IW             "Build IPP IW from source"           (NOT MINGW OR OPENCV_FORCE_3RDPARTY_BUILD) IF (X86_64 OR X86) AND NOT WINRT )
 219 OCV_OPTION(BUILD_ITT                "Build Intel ITT from source"
 220     (NOT MINGW OR OPENCV_FORCE_3RDPARTY_BUILD)
 221     IF (X86_64 OR X86 OR ARM OR AARCH64 OR PPC64 OR PPC64LE) AND NOT WINRT AND NOT APPLE_FRAMEWORK
 222 )
 223
 224 # Optional 3rd party components
 225 # ===================================================
 226 OCV_OPTION(WITH_1394 "Include IEEE1394 support" ON
 227   VISIBLE_IF NOT ANDROID AND NOT IOS AND NOT WINRT
 228   VERIFY HAVE_DC1394_2)
 229 OCV_OPTION(WITH_AVFOUNDATION "Use AVFoundation for Video I/O (iOS/Mac)" ON
 230   VISIBLE_IF APPLE
 231   VERIFY HAVE_AVFOUNDATION)
 232 OCV_OPTION(WITH_CAP_IOS "Enable iOS video capture" ON
 233   VISIBLE_IF IOS
 234   VERIFY HAVE_CAP_IOS)
 235 OCV_OPTION(WITH_CAROTENE "Use NVidia carotene acceleration library for ARM platform" ON
 236   VISIBLE_IF (ARM OR AARCH64) AND NOT IOS AND NOT (CMAKE_VERSION VERSION_LESS "2.8.11"))
 237 OCV_OPTION(WITH_CPUFEATURES "Use cpufeatures Android library" ON
 238   VISIBLE_IF ANDROID
 239   VERIFY HAVE_CPUFEATURES)
 240 OCV_OPTION(WITH_VTK "Include VTK library support (and build opencv_viz module eiher)" ON
 241   VISIBLE_IF NOT ANDROID AND NOT IOS AND NOT WINRT AND NOT CMAKE_CROSSCOMPILING
 242   VERIFY HAVE_VTK)
 243 OCV_OPTION(WITH_CUDA "Include NVidia Cuda Runtime support" OFF
 244   VISIBLE_IF NOT IOS AND NOT WINRT
 245   VERIFY HAVE_CUDA)
 246 OCV_OPTION(WITH_CUFFT "Include NVidia Cuda Fast Fourier Transform (FFT) library support" WITH_CUDA
 247   VISIBLE_IF WITH_CUDA
 248   VERIFY HAVE_CUFFT)
 249 OCV_OPTION(WITH_CUBLAS "Include NVidia Cuda Basic Linear Algebra Subprograms (BLAS) library support" WITH_CUDA
 250   VISIBLE_IF WITH_CUDA
 251   VERIFY HAVE_CUBLAS)
 252 OCV_OPTION(WITH_CUDNN "Include NVIDIA CUDA Deep Neural Network (cuDNN) library support" WITH_CUDA
 253   VISIBLE_IF WITH_CUDA
 254   VERIFY HAVE_CUDNN)
 255 OCV_OPTION(WITH_NVCUVID "Include NVidia Video Decoding library support" OFF  # disabled, details: https://github.com/opencv/opencv/issues/14850
 256   VISIBLE_IF WITH_CUDA
 257   VERIFY HAVE_NVCUVID)
 258 OCV_OPTION(WITH_EIGEN "Include Eigen2/Eigen3 support" (NOT CV_DISABLE_OPTIMIZATION AND NOT CMAKE_CROSSCOMPILING)
 259   VISIBLE_IF NOT WINRT
 260   VERIFY HAVE_EIGEN)
 261 OCV_OPTION(WITH_FFMPEG "Include FFMPEG support" (NOT ANDROID)
 262   VISIBLE_IF NOT IOS AND NOT WINRT
 263   VERIFY HAVE_FFMPEG)
 264 OCV_OPTION(WITH_GSTREAMER "Include Gstreamer support" ON
 265   VISIBLE_IF NOT ANDROID AND NOT IOS AND NOT WINRT
 266   VERIFY HAVE_GSTREAMER AND GSTREAMER_VERSION VERSION_GREATER "0.99")
 267 OCV_OPTION(WITH_GTK "Include GTK support" ON
 268   VISIBLE_IF UNIX AND NOT APPLE AND NOT ANDROID
 269   VERIFY HAVE_GTK)
 270 OCV_OPTION(WITH_GTK_2_X "Use GTK version 2" OFF
 271   VISIBLE_IF UNIX AND NOT APPLE AND NOT ANDROID
 272   VERIFY HAVE_GTK AND NOT HAVE_GTK3)
 273 OCV_OPTION(WITH_IPP "Include Intel IPP support" (NOT MINGW AND NOT CV_DISABLE_OPTIMIZATION)
 274   VISIBLE_IF (X86_64 OR X86) AND NOT WINRT AND NOT IOS
 275   VERIFY HAVE_IPP)
 276 OCV_OPTION(WITH_HALIDE "Include Halide support" OFF
 277   VISIBLE_IF TRUE
 278   VERIFY HAVE_HALIDE)
 279 OCV_OPTION(WITH_VULKAN "Include Vulkan support" OFF
 280   VISIBLE_IF TRUE
 281   VERIFY HAVE_VULKAN)
 282 OCV_OPTION(WITH_INF_ENGINE "Include Intel Inference Engine support" OFF
 283   VISIBLE_IF TRUE
 284   VERIFY INF_ENGINE_TARGET)
 285 OCV_OPTION(WITH_NGRAPH "Include nGraph support" WITH_INF_ENGINE
 286   VISIBLE_IF TRUE
 287   VERIFY TARGET ngraph::ngraph)
 288 OCV_OPTION(WITH_JASPER "Include JPEG2K support (Jasper)" ON
 289   VISIBLE_IF NOT IOS
 290   VERIFY HAVE_JASPER)
 291 OCV_OPTION(WITH_OPENJPEG "Include JPEG2K support (OpenJPEG)" ON
 292   VISIBLE_IF NOT IOS
 293   VERIFY HAVE_OPENJPEG)
 294 OCV_OPTION(WITH_JPEG "Include JPEG support" ON
 295   VISIBLE_IF TRUE
 296   VERIFY HAVE_JPEG)
 297 OCV_OPTION(WITH_WEBP "Include WebP support" ON
 298   VISIBLE_IF NOT WINRT
 299   VERIFY HAVE_WEBP)
 300 OCV_OPTION(WITH_OPENEXR "Include ILM support via OpenEXR" BUILD_OPENEXR OR NOT CMAKE_CROSSCOMPILING
 301   VISIBLE_IF NOT APPLE_FRAMEWORK AND NOT WINRT
 302   VERIFY HAVE_OPENEXR)
 303 OCV_OPTION(WITH_OPENGL "Include OpenGL support" OFF
 304   VISIBLE_IF NOT ANDROID AND NOT WINRT
 305   VERIFY HAVE_OPENGL)
 306 OCV_OPTION(WITH_OPENVX "Include OpenVX support" OFF
 307   VISIBLE_IF TRUE
 308   VERIFY HAVE_OPENVX)
 309 OCV_OPTION(WITH_OPENNI "Include OpenNI support" OFF
 310   VISIBLE_IF NOT ANDROID AND NOT IOS AND NOT WINRT
 311   VERIFY HAVE_OPENNI)
 312 OCV_OPTION(WITH_OPENNI2 "Include OpenNI2 support" OFF
 313   VISIBLE_IF NOT ANDROID AND NOT IOS AND NOT WINRT
 314   VERIFY HAVE_OPENNI2)
 315 OCV_OPTION(WITH_PNG "Include PNG support" ON
 316   VISIBLE_IF TRUE
 317   VERIFY HAVE_PNG)
 318 OCV_OPTION(WITH_GDCM "Include DICOM support" OFF
 319   VISIBLE_IF TRUE
 320   VERIFY HAVE_GDCM)
 321 OCV_OPTION(WITH_PVAPI "Include Prosilica GigE support" OFF
 322   VISIBLE_IF NOT ANDROID AND NOT IOS AND NOT WINRT
 323   VERIFY HAVE_PVAPI)
 324 OCV_OPTION(WITH_ARAVIS "Include Aravis GigE support" OFF
 325   VISIBLE_IF NOT ANDROID AND NOT IOS AND NOT WINRT AND NOT WIN32
 326   VERIFY HAVE_ARAVIS_API)
 327 OCV_OPTION(WITH_QT "Build with Qt Backend support" OFF
 328   VISIBLE_IF NOT ANDROID AND NOT IOS AND NOT WINRT
 329   VERIFY HAVE_QT)
 330 OCV_OPTION(WITH_WIN32UI "Build with Win32 UI Backend support" ON
 331   VISIBLE_IF WIN32 AND NOT WINRT
 332   VERIFY HAVE_WIN32UI)
 333 OCV_OPTION(WITH_TBB "Include Intel TBB support" OFF
 334   VISIBLE_IF NOT IOS AND NOT WINRT
 335   VERIFY HAVE_TBB)
 336 OCV_OPTION(WITH_HPX "Include Ste||ar Group HPX support" OFF
 337   VISIBLE_IF TRUE
 338   VERIFY HAVE_HPX)
 339 OCV_OPTION(WITH_OPENMP "Include OpenMP support" OFF
 340   VISIBLE_IF TRUE
 341   VERIFY HAVE_OPENMP)
 342 OCV_OPTION(WITH_PTHREADS_PF "Use pthreads-based parallel_for" ON
 343   VISIBLE_IF NOT WIN32 OR MINGW
 344   VERIFY HAVE_PTHREADS_PF)
 345 OCV_OPTION(WITH_TIFF "Include TIFF support" ON
 346   VISIBLE_IF NOT IOS
 347   VERIFY HAVE_TIFF)
 348 OCV_OPTION(WITH_V4L "Include Video 4 Linux support" ON
 349   VISIBLE_IF UNIX AND NOT ANDROID AND NOT APPLE
 350   VERIFY HAVE_CAMV4L OR HAVE_CAMV4L2 OR HAVE_VIDEOIO)
 351 OCV_OPTION(WITH_DSHOW "Build VideoIO with DirectShow support" ON
 352   VISIBLE_IF WIN32 AND NOT ARM AND NOT WINRT
 353   VERIFY HAVE_DSHOW)
 354 OCV_OPTION(WITH_MSMF "Build VideoIO with Media Foundation support" NOT MINGW
 355   VISIBLE_IF WIN32
 356   VERIFY HAVE_MSMF)
 357 OCV_OPTION(WITH_MSMF_DXVA "Enable hardware acceleration in Media Foundation backend" WITH_MSMF
 358   VISIBLE_IF WIN32
 359   VERIFY HAVE_MSMF_DXVA)
 360 OCV_OPTION(WITH_XIMEA "Include XIMEA cameras support" OFF
 361   VISIBLE_IF NOT ANDROID AND NOT WINRT
 362   VERIFY HAVE_XIMEA)
 363 OCV_OPTION(WITH_XINE "Include Xine support (GPL)" OFF
 364   VISIBLE_IF UNIX AND NOT APPLE AND NOT ANDROID
 365   VERIFY HAVE_XINE)
 366 OCV_OPTION(WITH_CLP "Include Clp support (EPL)" OFF
 367   VISIBLE_IF TRUE
 368   VERIFY HAVE_CLP)
 369 OCV_OPTION(WITH_OPENCL "Include OpenCL Runtime support" (NOT ANDROID AND NOT CV_DISABLE_OPTIMIZATION)
 370   VISIBLE_IF NOT IOS AND NOT WINRT
 371   VERIFY HAVE_OPENCL)
 372 OCV_OPTION(WITH_OPENCL_SVM "Include OpenCL Shared Virtual Memory support" OFF
 373   VISIBLE_IF TRUE
 374   VERIFY HAVE_OPENCL_SVM) # experimental
 375 OCV_OPTION(WITH_OPENCLAMDFFT "Include AMD OpenCL FFT library support" ON
 376   VISIBLE_IF NOT ANDROID AND NOT IOS AND NOT WINRT
 377   VERIFY HAVE_CLAMDFFT)
 378 OCV_OPTION(WITH_OPENCLAMDBLAS "Include AMD OpenCL BLAS library support" ON
 379   VISIBLE_IF NOT ANDROID AND NOT IOS AND NOT WINRT
 380   VERIFY HAVE_CLAMDBLAS)
 381 OCV_OPTION(WITH_DIRECTX "Include DirectX support" ON
 382   VISIBLE_IF WIN32 AND NOT WINRT
 383   VERIFY HAVE_DIRECTX)
 384 OCV_OPTION(WITH_OPENCL_D3D11_NV "Include NVIDIA OpenCL D3D11 support" WITH_DIRECTX
 385   VISIBLE_IF WIN32 AND NOT WINRT
 386   VERIFY HAVE_OPENCL_D3D11_NV)
 387 OCV_OPTION(WITH_LIBREALSENSE "Include Intel librealsense support" OFF
 388   VISIBLE_IF NOT WITH_INTELPERC
 389   VERIFY HAVE_LIBREALSENSE)
 390 OCV_OPTION(WITH_VA "Include VA support" OFF
 391   VISIBLE_IF UNIX AND NOT ANDROID
 392   VERIFY HAVE_VA)
 393 OCV_OPTION(WITH_VA_INTEL "Include Intel VA-API/OpenCL support" OFF
 394   VISIBLE_IF UNIX AND NOT ANDROID
 395   VERIFY HAVE_VA_INTEL)
 396 OCV_OPTION(WITH_MFX "Include Intel Media SDK support" OFF
 397   VISIBLE_IF (UNIX AND NOT ANDROID) OR (WIN32 AND NOT WINRT AND NOT MINGW)
 398   VERIFY HAVE_MFX)
 399 OCV_OPTION(WITH_GDAL "Include GDAL Support" OFF
 400   VISIBLE_IF NOT ANDROID AND NOT IOS AND NOT WINRT
 401   VERIFY HAVE_GDAL)
 402 OCV_OPTION(WITH_GPHOTO2 "Include gPhoto2 library support" OFF
 403   VISIBLE_IF UNIX AND NOT ANDROID AND NOT IOS
 404   VERIFY HAVE_GPHOTO2)
 405 OCV_OPTION(WITH_LAPACK "Include Lapack library support" (NOT CV_DISABLE_OPTIMIZATION)
 406   VISIBLE_IF NOT ANDROID AND NOT IOS
 407   VERIFY HAVE_LAPACK)
 408 OCV_OPTION(WITH_ITT "Include Intel ITT support" ON
 409   VISIBLE_IF NOT APPLE_FRAMEWORK
 410   VERIFY HAVE_ITT)
 411 OCV_OPTION(WITH_PROTOBUF "Enable libprotobuf" ON
 412   VISIBLE_IF TRUE
 413   VERIFY HAVE_PROTOBUF)
 414 OCV_OPTION(WITH_IMGCODEC_HDR "Include HDR support" ON
 415   VISIBLE_IF TRUE
 416   VERIFY HAVE_IMGCODEC_HDR)
 417 OCV_OPTION(WITH_IMGCODEC_SUNRASTER "Include SUNRASTER support" ON
 418   VISIBLE_IF TRUE
 419   VERIFY HAVE_IMGCODEC_SUNRASTER)
 420 OCV_OPTION(WITH_IMGCODEC_PXM "Include PNM (PBM,PGM,PPM) and PAM formats support" ON
 421   VISIBLE_IF TRUE
 422   VERIFY HAVE_IMGCODEC_PXM)
 423 OCV_OPTION(WITH_IMGCODEC_PFM "Include PFM formats support" ON
 424   VISIBLE_IF TRUE
 425   VERIFY HAVE_IMGCODEC_PFM)
 426 OCV_OPTION(WITH_QUIRC "Include library QR-code decoding" ON
 427   VISIBLE_IF TRUE
 428   VERIFY HAVE_QUIRC)
 429 OCV_OPTION(WITH_ANDROID_MEDIANDK "Use Android Media NDK for Video I/O (Android)" (ANDROID_NATIVE_API_LEVEL GREATER 20)
 430   VISIBLE_IF ANDROID
 431   VERIFY HAVE_ANDROID_MEDIANDK)
 432 OCV_OPTION(WITH_TENGINE "Include Arm Inference Tengine support" OFF
 433   VISIBLE_IF (ARM OR AARCH64) AND (UNIX OR ANDROID) AND NOT IOS
 434   VERIFY HAVE_TENGINE)
 435
 436 # OpenCV build components
 437 # ===================================================
 438 OCV_OPTION(BUILD_SHARED_LIBS        "Build shared libraries (.dll/.so) instead of static ones (.lib/.a)" NOT (ANDROID OR APPLE_FRAMEWORK) )
 439 OCV_OPTION(BUILD_opencv_apps        "Build utility applications (used for example to train classifiers)" (NOT ANDROID AND NOT WINRT) IF (NOT APPLE_FRAMEWORK) )
 440 OCV_OPTION(BUILD_opencv_js          "Build JavaScript bindings by Emscripten" OFF )
 441 OCV_OPTION(BUILD_ANDROID_PROJECTS   "Build Android projects providing .apk files" ON  IF ANDROID )
 442 OCV_OPTION(BUILD_ANDROID_EXAMPLES   "Build examples for Android platform"         ON  IF ANDROID )
 443 OCV_OPTION(BUILD_DOCS               "Create build rules for OpenCV Documentation" OFF  IF (NOT WINRT AND NOT APPLE_FRAMEWORK))
 444 OCV_OPTION(BUILD_EXAMPLES           "Build all examples"                          OFF )
 445 OCV_OPTION(BUILD_PACKAGE            "Enables 'make package_source' command"       ON  IF NOT WINRT)
 446 OCV_OPTION(BUILD_PERF_TESTS         "Build performance tests"                     NOT INSTALL_CREATE_DISTRIB  IF (NOT APPLE_FRAMEWORK) )
 447 OCV_OPTION(BUILD_TESTS              "Build accuracy & regression tests"           NOT INSTALL_CREATE_DISTRIB  IF (NOT APPLE_FRAMEWORK) )
 448 OCV_OPTION(BUILD_WITH_DEBUG_INFO    "Include debug info into release binaries ('OFF' means default settings)" OFF )
 449 OCV_OPTION(BUILD_WITH_STATIC_CRT    "Enables use of statically linked CRT for statically linked OpenCV" ON IF MSVC )
 450 OCV_OPTION(BUILD_WITH_DYNAMIC_IPP   "Enables dynamic linking of IPP (only for standalone IPP)" OFF )
 451 OCV_OPTION(BUILD_FAT_JAVA_LIB       "Create Java wrapper exporting all functions of OpenCV library (requires static build of OpenCV modules)" ANDROID IF NOT BUILD_SHARED_LIBS)
 452 OCV_OPTION(BUILD_ANDROID_SERVICE    "Build OpenCV Manager for Google Play" OFF IF ANDROID )
 453 OCV_OPTION(BUILD_CUDA_STUBS         "Build CUDA modules stubs when no CUDA SDK" OFF  IF (NOT APPLE_FRAMEWORK) )
 454 OCV_OPTION(BUILD_JAVA               "Enable Java support"                         (ANDROID OR NOT CMAKE_CROSSCOMPILING)  IF (ANDROID OR (NOT APPLE_FRAMEWORK AND NOT WINRT)) )
 455
 456 # OpenCV installation options
 457 # ===================================================
 458 OCV_OPTION(INSTALL_CREATE_DISTRIB   "Change install rules to build the distribution package" OFF )
 459 OCV_OPTION(INSTALL_C_EXAMPLES       "Install C examples"        OFF )
 460 OCV_OPTION(INSTALL_PYTHON_EXAMPLES  "Install Python examples"   OFF )
 461 OCV_OPTION(INSTALL_ANDROID_EXAMPLES "Install Android examples"  OFF IF ANDROID )
 462 OCV_OPTION(INSTALL_TO_MANGLED_PATHS "Enables mangled install paths, that help with side by side installs." OFF IF (UNIX AND NOT ANDROID AND NOT APPLE_FRAMEWORK AND BUILD_SHARED_LIBS) )
 463 OCV_OPTION(INSTALL_TESTS            "Install accuracy and performance test binaries and test data" OFF)
 464
 465 # OpenCV build options
 466 # ===================================================
 467 OCV_OPTION(ENABLE_CCACHE              "Use ccache"                                               (UNIX AND NOT IOS AND (CMAKE_GENERATOR MATCHES "Makefile" OR CMAKE_GENERATOR MATCHES "Ninja")) )
 468 OCV_OPTION(ENABLE_PRECOMPILED_HEADERS "Use precompiled headers"                                  MSVC IF (MSVC OR (NOT IOS AND NOT CMAKE_CROSSCOMPILING) ) )
 469 OCV_OPTION(ENABLE_SOLUTION_FOLDERS    "Solution folder in Visual Studio or in other IDEs"        (MSVC_IDE OR CMAKE_GENERATOR MATCHES Xcode) )
 470 OCV_OPTION(ENABLE_PROFILING           "Enable profiling in the GCC compiler (Add flags: -g -pg)" OFF  IF CV_GCC )
 471 OCV_OPTION(ENABLE_COVERAGE            "Enable coverage collection with  GCov"                    OFF  IF CV_GCC )
 472 OCV_OPTION(OPENCV_ENABLE_MEMORY_SANITIZER "Better support for memory/address sanitizers"         OFF)
 473 OCV_OPTION(ENABLE_OMIT_FRAME_POINTER  "Enable -fomit-frame-pointer for GCC"                      ON   IF CV_GCC )
 474 OCV_OPTION(ENABLE_POWERPC             "Enable PowerPC for GCC"                                   ON   IF (CV_GCC AND CMAKE_SYSTEM_PROCESSOR MATCHES powerpc.*) )
 475 OCV_OPTION(ENABLE_FAST_MATH           "Enable compiler options for fast math optimizations on FP computations (not recommended)" OFF)
 476 if(NOT IOS AND (NOT ANDROID OR OPENCV_ANDROID_USE_LEGACY_FLAGS))  # Use CPU_BASELINE instead
 477 OCV_OPTION(ENABLE_NEON                "Enable NEON instructions"                                 (NEON OR ANDROID_ARM_NEON OR AARCH64) IF (CV_GCC OR CV_CLANG) AND (ARM OR AARCH64 OR IOS) )
 478 OCV_OPTION(ENABLE_VFPV3               "Enable VFPv3-D32 instructions"                            OFF  IF (CV_GCC OR CV_CLANG) AND (ARM OR AARCH64 OR IOS) )
 479 endif()
 480 OCV_OPTION(ENABLE_NOISY_WARNINGS      "Show all warnings even if they are too noisy"             OFF )
 481 OCV_OPTION(OPENCV_WARNINGS_ARE_ERRORS "Treat warnings as errors"                                 OFF )
 482 OCV_OPTION(ANDROID_EXAMPLES_WITH_LIBS "Build binaries of Android examples with native libraries" OFF  IF ANDROID )
 483 OCV_OPTION(ENABLE_IMPL_COLLECTION     "Collect implementation data on function call"             OFF )
 484 OCV_OPTION(ENABLE_INSTRUMENTATION     "Instrument functions to collect calls trace and performance" OFF )
 485 OCV_OPTION(ENABLE_GNU_STL_DEBUG       "Enable GNU STL Debug mode (defines _GLIBCXX_DEBUG)"       OFF IF ((NOT CMAKE_VERSION VERSION_LESS "2.8.11") AND CV_GCC) )
 486 OCV_OPTION(ENABLE_BUILD_HARDENING     "Enable hardening of the resulting binaries (against security attacks, detects memory corruption, etc)" OFF)
 487 OCV_OPTION(ENABLE_LTO                 "Enable Link Time Optimization" OFF IF CV_GCC OR MSVC)
 488 OCV_OPTION(ENABLE_THIN_LTO            "Enable Thin LTO" OFF IF CV_CLANG)
 489 OCV_OPTION(GENERATE_ABI_DESCRIPTOR    "Generate XML file for abi_compliance_checker tool" OFF IF UNIX)
 490 OCV_OPTION(OPENCV_GENERATE_PKGCONFIG  "Generate .pc file for pkg-config build tool (deprecated)" OFF)
 491 OCV_OPTION(CV_ENABLE_INTRINSICS       "Use intrinsic-based optimized code" ON )
 492 OCV_OPTION(CV_DISABLE_OPTIMIZATION    "Disable explicit optimized code (dispatched code/intrinsics/loop unrolling/etc)" OFF )
 493 OCV_OPTION(CV_TRACE                   "Enable OpenCV code trace" ON)
 494 OCV_OPTION(OPENCV_GENERATE_SETUPVARS  "Generate setup_vars* scripts" ON IF (NOT ANDROID AND NOT APPLE_FRAMEWORK) )
 495 OCV_OPTION(ENABLE_CONFIG_VERIFICATION "Fail build if actual configuration doesn't match requested (WITH_XXX != HAVE_XXX)" OFF)
 496 OCV_OPTION(OPENCV_ENABLE_MEMALIGN     "Enable posix_memalign or memalign usage" ON)
 497
 498 OCV_OPTION(ENABLE_PYLINT              "Add target with Pylint checks"                            (BUILD_DOCS OR BUILD_EXAMPLES) IF (NOT CMAKE_CROSSCOMPILING AND NOT APPLE_FRAMEWORK) )
 499 OCV_OPTION(ENABLE_FLAKE8              "Add target with Python flake8 checker"                    (BUILD_DOCS OR BUILD_EXAMPLES) IF (NOT CMAKE_CROSSCOMPILING AND NOT APPLE_FRAMEWORK) )
 500
 501 if(ENABLE_IMPL_COLLECTION)
 502   add_definitions(-DCV_COLLECT_IMPL_DATA)
 503 endif()
 504
 505 set(OPENCV_MATHJAX_RELPATH "https://cdnjs.cloudflare.com/ajax/libs/mathjax/2.7.0" CACHE STRING "URI to a MathJax installation")
 506
 507 # ----------------------------------------------------------------------------
 508 #  Get actual OpenCV version number from sources
 509 # ----------------------------------------------------------------------------
 510 include(cmake/OpenCVVersion.cmake)
 511
 512 ocv_cmake_hook(POST_OPTIONS)
 513
 514 # ----------------------------------------------------------------------------
 515 #  Build & install layouts
 516 # ----------------------------------------------------------------------------
 517
 518 if(OPENCV_TEST_DATA_PATH)
 519   get_filename_component(OPENCV_TEST_DATA_PATH ${OPENCV_TEST_DATA_PATH} ABSOLUTE)
 520 endif()
 521
 522 # Save libs and executables in the same place
 523 set(EXECUTABLE_OUTPUT_PATH "${CMAKE_BINARY_DIR}/bin" CACHE PATH "Output directory for applications")
 524
 525 if(ANDROID)
 526   set(LIBRARY_OUTPUT_PATH                "${OpenCV_BINARY_DIR}/lib/${ANDROID_NDK_ABI_NAME}")
 527   ocv_update(3P_LIBRARY_OUTPUT_PATH      "${OpenCV_BINARY_DIR}/3rdparty/lib/${ANDROID_NDK_ABI_NAME}")
 528 else()
 529   set(LIBRARY_OUTPUT_PATH                "${OpenCV_BINARY_DIR}/lib")
 530   ocv_update(3P_LIBRARY_OUTPUT_PATH      "${OpenCV_BINARY_DIR}/3rdparty/lib")
 531 endif()
 532
 533 if(ANDROID)
 534   if(ANDROID_ABI MATCHES "NEON")
 535     set(ENABLE_NEON ON)
 536   endif()
 537   if(ANDROID_ABI MATCHES "VFPV3")
 538     set(ENABLE_VFPV3 ON)
 539   endif()
 540 endif()
 541
 542 if(WIN32)
 543   # Postfix of DLLs:
 544   ocv_update(OPENCV_DLLVERSION "${OPENCV_VERSION_MAJOR}${OPENCV_VERSION_MINOR}${OPENCV_VERSION_PATCH}")
 545   ocv_update(OPENCV_DEBUG_POSTFIX d)
 546 else()
 547   # Postfix of so's:
 548   ocv_update(OPENCV_DLLVERSION "")
 549   ocv_update(OPENCV_DEBUG_POSTFIX "")
 550 endif()
 551
 552 if(DEFINED CMAKE_DEBUG_POSTFIX)
 553   set(OPENCV_DEBUG_POSTFIX "${CMAKE_DEBUG_POSTFIX}")
 554 endif()
 555
 556 if((INSTALL_CREATE_DISTRIB AND BUILD_SHARED_LIBS AND NOT DEFINED BUILD_opencv_world) OR APPLE_FRAMEWORK)
 557   set(BUILD_opencv_world ON CACHE INTERNAL "")
 558 endif()
 559
 560 include(cmake/OpenCVInstallLayout.cmake)
 561
 562 # ----------------------------------------------------------------------------
 563 #  Path for build/platform -specific headers
 564 # ----------------------------------------------------------------------------
 565 ocv_update(OPENCV_CONFIG_FILE_INCLUDE_DIR "${CMAKE_BINARY_DIR}/" CACHE PATH "Where to create the platform-dependant cvconfig.h")
 566 ocv_include_directories(${OPENCV_CONFIG_FILE_INCLUDE_DIR})
 567
 568 # ----------------------------------------------------------------------------
 569 #  Path for additional modules
 570 # ----------------------------------------------------------------------------
 571 set(OPENCV_EXTRA_MODULES_PATH "" CACHE PATH "Where to look for additional OpenCV modules (can be ;-separated list of paths)")
 572
 573 # ----------------------------------------------------------------------------
 574 #  Autodetect if we are in a GIT repository
 575 # ----------------------------------------------------------------------------
 576 find_host_package(Git QUIET)
 577
 578 if(NOT DEFINED OPENCV_VCSVERSION AND GIT_FOUND)
 579   ocv_git_describe(OPENCV_VCSVERSION "${OpenCV_SOURCE_DIR}")
 580 elseif(NOT DEFINED OPENCV_VCSVERSION)
 581   # We don't have git:
 582   set(OPENCV_VCSVERSION "unknown")
 583 endif()
 584
 585
 586 # ----------------------------------------------------------------------------
 587 # OpenCV compiler and linker options
 588 # ----------------------------------------------------------------------------
 589 # In case of Makefiles if the user does not setup CMAKE_BUILD_TYPE, assume it's Release:
 590 if(CMAKE_GENERATOR MATCHES "Makefiles|Ninja" AND "${CMAKE_BUILD_TYPE}" STREQUAL "")
 591   set(CMAKE_BUILD_TYPE Release)
 592 endif()
 593
 594 ocv_cmake_hook(POST_CMAKE_BUILD_OPTIONS)
 595
 596 # --- Python Support ---
 597 if(NOT IOS)
 598   include(cmake/OpenCVDetectPython.cmake)
 599 endif()
 600
 601 include(cmake/OpenCVCompilerOptions.cmake)
 602
 603 ocv_cmake_hook(POST_COMPILER_OPTIONS)
 604
 605 # ----------------------------------------------------------------------------
 606 #       CHECK FOR SYSTEM LIBRARIES, OPTIONS, ETC..
 607 # ----------------------------------------------------------------------------
 608 if(UNIX)
 609   if(NOT APPLE_FRAMEWORK OR OPENCV_ENABLE_PKG_CONFIG)
 610     if(CMAKE_CROSSCOMPILING AND NOT DEFINED ENV{PKG_CONFIG_LIBDIR} AND NOT DEFINED ENV{PKG_CONFIG_SYSROOT_DIR}
 611         AND NOT OPENCV_ENABLE_PKG_CONFIG
 612     )
 613       if(NOT PkgConfig_FOUND)
 614         message(STATUS "OpenCV disables pkg-config to avoid using of host libraries. Consider using PKG_CONFIG_LIBDIR to specify target SYSROOT")
 615       elseif(OPENCV_SKIP_PKG_CONFIG_WARNING)
 616         message(WARNING "pkg-config is enabled in cross-compilation mode without defining of PKG_CONFIG_LIBDIR environment variable. This may lead to misconfigured host-based dependencies.")
 617       endif()
 618     elseif(OPENCV_DISABLE_PKG_CONFIG)
 619       if(PkgConfig_FOUND)
 620         message(WARNING "OPENCV_DISABLE_PKG_CONFIG flag has no effect")
 621       endif()
 622     else()
 623       find_package(PkgConfig QUIET)
 624     endif()
 625   endif()
 626   include(CheckFunctionExists)
 627   include(CheckIncludeFile)
 628   include(CheckSymbolExists)
 629
 630   if(NOT APPLE)
 631     CHECK_INCLUDE_FILE(pthread.h HAVE_PTHREAD)
 632     if(ANDROID)
 633       set(OPENCV_LINKER_LIBS ${OPENCV_LINKER_LIBS} dl m log)
 634     elseif(CMAKE_SYSTEM_NAME MATCHES "FreeBSD|NetBSD|DragonFly|OpenBSD|Haiku")
 635       set(OPENCV_LINKER_LIBS ${OPENCV_LINKER_LIBS} m pthread)
 636     elseif(EMSCRIPTEN)
 637       # no need to link to system libs with emscripten
 638     else()
 639       set(OPENCV_LINKER_LIBS ${OPENCV_LINKER_LIBS} dl m pthread rt)
 640     endif()
 641   else()
 642     set(HAVE_PTHREAD 1)
 643   endif()
 644
 645   if(OPENCV_ENABLE_MEMALIGN)
 646     CHECK_SYMBOL_EXISTS(posix_memalign stdlib.h HAVE_POSIX_MEMALIGN)
 647     CHECK_INCLUDE_FILE(malloc.h HAVE_MALLOC_H)
 648     if(HAVE_MALLOC_H)
 649       CHECK_SYMBOL_EXISTS(memalign malloc.h HAVE_MEMALIGN)
 650     endif()
 651     # TODO:
 652     # - _aligned_malloc() on Win32
 653     # - std::aligned_alloc() C++17 / C11
 654   endif()
 655 endif()
 656
 657 include(cmake/OpenCVPCHSupport.cmake)
 658 include(cmake/OpenCVModule.cmake)
 659
 660 # ----------------------------------------------------------------------------
 661 #  Detect endianness of build platform
 662 # ----------------------------------------------------------------------------
 663
 664 if(IOS)
 665   # test_big_endian needs try_compile, which doesn't work for iOS
 666   # http://public.kitware.com/Bug/view.php?id=12288
 667   set(WORDS_BIGENDIAN 0)
 668 else()
 669   include(TestBigEndian)
 670   test_big_endian(WORDS_BIGENDIAN)
 671 endif()
 672
 673 # ----------------------------------------------------------------------------
 674 #  Detect 3rd-party libraries
 675 # ----------------------------------------------------------------------------
 676
 677 if(ANDROID AND WITH_CPUFEATURES)
 678   add_subdirectory(3rdparty/cpufeatures)
 679   set(HAVE_CPUFEATURES 1)
 680 endif()
 681
 682 include(cmake/OpenCVFindFrameworks.cmake)
 683
 684 include(cmake/OpenCVFindLibsGrfmt.cmake)
 685 include(cmake/OpenCVFindLibsGUI.cmake)
 686 include(cmake/OpenCVFindLibsVideo.cmake)
 687 include(cmake/OpenCVFindLibsPerf.cmake)
 688 include(cmake/OpenCVFindLAPACK.cmake)
 689 include(cmake/OpenCVFindProtobuf.cmake)
 690 if(WITH_TENGINE)
 691   include(cmake/OpenCVFindTengine.cmake)
 692 endif()
 693
 694 # ----------------------------------------------------------------------------
 695 #  Detect other 3rd-party libraries/tools
 696 # ----------------------------------------------------------------------------
 697
 698 # --- Java Support ---
 699 if(BUILD_JAVA)
 700   if(ANDROID)
 701     include(cmake/android/OpenCVDetectAndroidSDK.cmake)
 702   else()
 703     include(cmake/OpenCVDetectApacheAnt.cmake)
 704     find_package(JNI)
 705   endif()
 706 endif()
 707
 708 if(ENABLE_PYLINT AND PYTHON_DEFAULT_AVAILABLE)
 709   include(cmake/OpenCVPylint.cmake)
 710 endif()
 711 if(ENABLE_FLAKE8 AND PYTHON_DEFAULT_AVAILABLE)
 712   find_package(Flake8 QUIET)
 713   if(NOT FLAKE8_FOUND OR NOT FLAKE8_EXECUTABLE)
 714     include("${CMAKE_CURRENT_LIST_DIR}/cmake/FindFlake8.cmake")
 715   endif()
 716   if(FLAKE8_FOUND)
 717     add_custom_target(check_flake8
 718         COMMAND "${FLAKE8_EXECUTABLE}" . --count --select=E9,E901,E999,F821,F822,F823 --show-source --statistics --exclude='.git,__pycache__,*.config.py,svgfig.py'
 719         WORKING_DIRECTORY "${OpenCV_SOURCE_DIR}"
 720         COMMENT "Running flake8"
 721     )
 722   endif()
 723 endif()
 724
 725
 726 if(ANDROID AND ANDROID_EXECUTABLE AND ANT_EXECUTABLE AND (ANT_VERSION VERSION_GREATER 1.7) AND (ANDROID_TOOLS_Pkg_Revision GREATER 13))
 727   SET(CAN_BUILD_ANDROID_PROJECTS TRUE)
 728 else()
 729   SET(CAN_BUILD_ANDROID_PROJECTS FALSE)
 730 endif()
 731
 732 # --- OpenCL ---
 733 if(WITH_OPENCL)
 734   include(cmake/OpenCVDetectOpenCL.cmake)
 735 endif()
 736
 737 # --- Halide ---
 738 if(WITH_HALIDE)
 739   include(cmake/OpenCVDetectHalide.cmake)
 740 endif()
 741
 742 # --- VkCom ---
 743 if(WITH_VULKAN)
 744   include(cmake/OpenCVDetectVulkan.cmake)
 745 endif()
 746
 747 # --- Inference Engine ---
 748 if(WITH_INF_ENGINE)
 749   include(cmake/OpenCVDetectInferenceEngine.cmake)
 750 endif()
 751
 752 # --- DirectX ---
 753 if(WITH_DIRECTX)
 754   include(cmake/OpenCVDetectDirectX.cmake)
 755 endif()
 756
 757 if(WITH_VTK)
 758   include(cmake/OpenCVDetectVTK.cmake)
 759 endif()
 760
 761 if(WITH_OPENVX)
 762   include(cmake/FindOpenVX.cmake)
 763 endif()
 764
 765 if(WITH_QUIRC)
 766   add_subdirectory(3rdparty/quirc)
 767   set(HAVE_QUIRC TRUE)
 768 endif()
 769 # ----------------------------------------------------------------------------
 770 # OpenCV HAL
 771 # ----------------------------------------------------------------------------
 772 set(_hal_includes "")
 773 macro(ocv_hal_register HAL_LIBRARIES_VAR HAL_HEADERS_VAR HAL_INCLUDE_DIRS_VAR)
 774   # 1. libraries
 775   foreach (l ${${HAL_LIBRARIES_VAR}})
 776     if(NOT TARGET ${l})
 777       get_filename_component(l "${l}" ABSOLUTE)
 778     endif()
 779     list(APPEND OPENCV_HAL_LINKER_LIBS ${l})
 780   endforeach()
 781   # 2. headers
 782   foreach (h ${${HAL_HEADERS_VAR}})
 783     set(_hal_includes "${_hal_includes}\n#include \"${h}\"")
 784   endforeach()
 785   # 3. include paths
 786   ocv_include_directories(${${HAL_INCLUDE_DIRS_VAR}})
 787 endmacro()
 788
 789 if(NOT DEFINED OpenCV_HAL)
 790   set(OpenCV_HAL "OpenCV_HAL")
 791 endif()
 792
 793 if(HAVE_OPENVX)
 794   if(NOT ";${OpenCV_HAL};" MATCHES ";openvx;")
 795     set(OpenCV_HAL "openvx;${OpenCV_HAL}")
 796   endif()
 797 endif()
 798
 799 if(WITH_CAROTENE)
 800   ocv_debug_message(STATUS "Enable carotene acceleration")
 801   if(NOT ";${OpenCV_HAL};" MATCHES ";carotene;")
 802     set(OpenCV_HAL "carotene;${OpenCV_HAL}")
 803   endif()
 804 endif()
 805
 806 foreach(hal ${OpenCV_HAL})
 807   if(hal STREQUAL "carotene")
 808     if(";${CPU_BASELINE_FINAL};" MATCHES ";NEON;")
 809       add_subdirectory(3rdparty/carotene/hal)
 810       ocv_hal_register(CAROTENE_HAL_LIBRARIES CAROTENE_HAL_HEADERS CAROTENE_HAL_INCLUDE_DIRS)
 811       list(APPEND OpenCV_USED_HAL "carotene (ver ${CAROTENE_HAL_VERSION})")
 812     else()
 813       message(STATUS "Carotene: NEON is not available, disabling carotene...")
 814     endif()
 815   elseif(hal STREQUAL "openvx")
 816     add_subdirectory(3rdparty/openvx)
 817     ocv_hal_register(OPENVX_HAL_LIBRARIES OPENVX_HAL_HEADERS OPENVX_HAL_INCLUDE_DIRS)
 818     list(APPEND OpenCV_USED_HAL "openvx (ver ${OPENVX_HAL_VERSION})")
 819   else()
 820     ocv_debug_message(STATUS "OpenCV HAL: ${hal} ...")
 821     ocv_clear_vars(OpenCV_HAL_LIBRARIES OpenCV_HAL_HEADERS OpenCV_HAL_INCLUDE_DIRS)
 822     find_package(${hal} NO_MODULE QUIET)
 823     if(${hal}_FOUND)
 824       ocv_hal_register(OpenCV_HAL_LIBRARIES OpenCV_HAL_HEADERS OpenCV_HAL_INCLUDE_DIRS)
 825       list(APPEND OpenCV_USED_HAL "${hal} (ver ${${hal}_VERSION})")
 826     endif()
 827   endif()
 828 endforeach()
 829 configure_file("${OpenCV_SOURCE_DIR}/cmake/templates/custom_hal.hpp.in" "${CMAKE_BINARY_DIR}/custom_hal.hpp" @ONLY)
 830 unset(_hal_includes)
 831
 832
 833 # ----------------------------------------------------------------------------
 834 # Code trace support
 835 # ----------------------------------------------------------------------------
 836 if(CV_TRACE)
 837   include(cmake/OpenCVDetectTrace.cmake)
 838 endif()
 839
 840 ocv_cmake_hook(POST_DETECT_DEPENDECIES)  # typo, deprecated (2019-06)
 841 ocv_cmake_hook(POST_DETECT_DEPENDENCIES)
 842
 843 # ----------------------------------------------------------------------------
 844 # Solution folders:
 845 # ----------------------------------------------------------------------------
 846 if(ENABLE_SOLUTION_FOLDERS)
 847   set_property(GLOBAL PROPERTY USE_FOLDERS ON)
 848   set_property(GLOBAL PROPERTY PREDEFINED_TARGETS_FOLDER "CMakeTargets")
 849 endif()
 850
 851 # Extra OpenCV targets: uninstall, package_source, perf, etc.
 852 include(cmake/OpenCVExtraTargets.cmake)
 853
 854 # ----------------------------------------------------------------------------
 855 # Process subdirectories
 856 # ----------------------------------------------------------------------------
 857
 858 # opencv.hpp and legacy headers
 859 add_subdirectory(include)
 860
 861 # Enable compiler options for OpenCV modules/apps/samples only (ignore 3rdparty)
 862 ocv_add_modules_compiler_options()
 863
 864 # OpenCV modules
 865 add_subdirectory(modules)
 866
 867 # Generate targets for documentation
 868 add_subdirectory(doc)
 869
 870 # various data that is used by cv libraries and/or demo applications.
 871 add_subdirectory(data)
 872
 873 # extra applications
 874 if(BUILD_opencv_apps)
 875   add_subdirectory(apps)
 876 endif()
 877
 878 # examples
 879 if(BUILD_EXAMPLES OR BUILD_ANDROID_EXAMPLES OR INSTALL_ANDROID_EXAMPLES OR INSTALL_PYTHON_EXAMPLES OR INSTALL_C_EXAMPLES)
 880   add_subdirectory(samples)
 881 endif()
 882
 883 if(ANDROID)
 884   add_subdirectory(platforms/android/service)
 885 endif()
 886
 887 # ----------------------------------------------------------------------------
 888 # Finalization: generate configuration-based files
 889 # ----------------------------------------------------------------------------
 890
 891 ocv_cmake_hook(PRE_FINALIZE)
 892
 893 # Generate platform-dependent and configuration-dependent headers
 894 include(cmake/OpenCVGenHeaders.cmake)
 895
 896 # Generate opencv.pc for pkg-config command
 897 if(OPENCV_GENERATE_PKGCONFIG)
 898   include(cmake/OpenCVGenPkgconfig.cmake)
 899 endif()
 900
 901 # Generate OpenCV.mk for ndk-build (Android build tool)
 902 include(cmake/OpenCVGenAndroidMK.cmake)
 903
 904 # Generate OpenCVConfig.cmake and OpenCVConfig-version.cmake for cmake projects
 905 include(cmake/OpenCVGenConfig.cmake)
 906
 907 # Generate Info.plist for the IOS framework
 908 if(APPLE_FRAMEWORK)
 909   include(cmake/OpenCVGenInfoPlist.cmake)
 910 endif()
 911
 912 # Generate ABI descriptor
 913 include(cmake/OpenCVGenABI.cmake)
 914
 915 # Generate environment setup file
 916 if(INSTALL_TESTS AND OPENCV_TEST_DATA_PATH)
 917   if(ANDROID)
 918     get_filename_component(TEST_PATH ${OPENCV_TEST_INSTALL_PATH} DIRECTORY)
 919     configure_file("${CMAKE_CURRENT_SOURCE_DIR}/cmake/templates/opencv_run_all_tests_android.sh.in"
 920                    "${CMAKE_BINARY_DIR}/unix-install/opencv_run_all_tests.sh" @ONLY)
 921     install(PROGRAMS "${CMAKE_BINARY_DIR}/unix-install/opencv_run_all_tests.sh"
 922             DESTINATION ./ COMPONENT tests)
 923   elseif(WIN32)
 924     configure_file("${CMAKE_CURRENT_SOURCE_DIR}/cmake/templates/opencv_run_all_tests_windows.cmd.in"
 925                    "${CMAKE_BINARY_DIR}/win-install/opencv_run_all_tests.cmd" @ONLY)
 926     install(PROGRAMS "${CMAKE_BINARY_DIR}/win-install/opencv_run_all_tests.cmd"
 927             DESTINATION ${OPENCV_TEST_INSTALL_PATH} COMPONENT tests)
 928   elseif(UNIX)
 929     configure_file("${CMAKE_CURRENT_SOURCE_DIR}/cmake/templates/opencv_run_all_tests_unix.sh.in"
 930                    "${CMAKE_BINARY_DIR}/unix-install/opencv_run_all_tests.sh" @ONLY)
 931     install(PROGRAMS "${CMAKE_BINARY_DIR}/unix-install/opencv_run_all_tests.sh"
 932             DESTINATION ${OPENCV_TEST_INSTALL_PATH} COMPONENT tests)
 933   endif()
 934 endif()
 935
 936 if(NOT OPENCV_README_FILE)
 937   if(ANDROID)
 938     set(OPENCV_README_FILE ${CMAKE_CURRENT_SOURCE_DIR}/platforms/android/README.android)
 939   endif()
 940 endif()
 941
 942 if(NOT OPENCV_LICENSE_FILE)
 943   set(OPENCV_LICENSE_FILE ${CMAKE_CURRENT_SOURCE_DIR}/LICENSE)
 944 endif()
 945
 946 # for UNIX it does not make sense as LICENSE and readme will be part of the package automatically
 947 if(ANDROID OR NOT UNIX)
 948   install(FILES ${OPENCV_LICENSE_FILE}
 949         PERMISSIONS OWNER_READ OWNER_WRITE GROUP_READ WORLD_READ
 950         DESTINATION ./ COMPONENT libs)
 951   if(OPENCV_README_FILE)
 952     install(FILES ${OPENCV_README_FILE}
 953             PERMISSIONS OWNER_READ OWNER_WRITE GROUP_READ WORLD_READ
 954             DESTINATION ./ COMPONENT libs)
 955   endif()
 956 endif()
 957
 958 if(COMMAND ocv_pylint_finalize)
 959   ocv_pylint_add_directory(${CMAKE_CURRENT_LIST_DIR}/modules/python/test)
 960   ocv_pylint_add_directory(${CMAKE_CURRENT_LIST_DIR}/samples/python)
 961   ocv_pylint_add_directory(${CMAKE_CURRENT_LIST_DIR}/samples/dnn)
 962   ocv_pylint_add_directory_recurse(${CMAKE_CURRENT_LIST_DIR}/samples/python/tutorial_code)
 963   ocv_pylint_finalize()
 964 endif()
 965
 966 if(OPENCV_GENERATE_SETUPVARS)
 967   include(cmake/OpenCVGenSetupVars.cmake)
 968 endif()
 969
 970 # ----------------------------------------------------------------------------
 971 # Summary:
 972 # ----------------------------------------------------------------------------
 973 status("")
 974 status("General configuration for OpenCV ${OPENCV_VERSION} =====================================")
 975 if(OPENCV_VCSVERSION)
 976   status("  Version control:" ${OPENCV_VCSVERSION})
 977 endif()
 978 if(OPENCV_EXTRA_MODULES_PATH AND NOT BUILD_INFO_SKIP_EXTRA_MODULES)
 979   set(__dump_extra_header OFF)
 980   foreach(p ${OPENCV_EXTRA_MODULES_PATH})
 981     if(EXISTS ${p})
 982       if(NOT __dump_extra_header)
 983         set(__dump_extra_header ON)
 984         status("")
 985         status("  Extra modules:")
 986       else()
 987         status("")
 988       endif()
 989       ocv_git_describe(EXTRA_MODULES_VCSVERSION "${p}")
 990       status("    Location (extra):" ${p})
 991       status("    Version control (extra):" ${EXTRA_MODULES_VCSVERSION})
 992     endif()
 993   endforeach()
 994   unset(__dump_extra_header)
 995 endif()
 996
 997 # ========================== build platform ==========================
 998 status("")
 999 status("  Platform:")
1000 if(NOT DEFINED OPENCV_TIMESTAMP
1001     AND NOT CMAKE_VERSION VERSION_LESS 2.8.11
1002     AND NOT BUILD_INFO_SKIP_TIMESTAMP
1003 )
1004   string(TIMESTAMP OPENCV_TIMESTAMP "" UTC)
1005   set(OPENCV_TIMESTAMP "${OPENCV_TIMESTAMP}" CACHE STRING "Timestamp of OpenCV build configuration" FORCE)
1006 endif()
1007 if(OPENCV_TIMESTAMP)
1008   status("    Timestamp:"      ${OPENCV_TIMESTAMP})
1009 endif()
1010 status("    Host:"             ${CMAKE_HOST_SYSTEM_NAME} ${CMAKE_HOST_SYSTEM_VERSION} ${CMAKE_HOST_SYSTEM_PROCESSOR})
1011 if(CMAKE_CROSSCOMPILING)
1012   status("    Target:"         ${CMAKE_SYSTEM_NAME} ${CMAKE_SYSTEM_VERSION} ${CMAKE_SYSTEM_PROCESSOR})
1013 endif()
1014 status("    CMake:"            ${CMAKE_VERSION})
1015 status("    CMake generator:"  ${CMAKE_GENERATOR})
1016 status("    CMake build tool:" ${CMAKE_BUILD_TOOL})
1017 if(MSVC)
1018   status("    MSVC:"           ${MSVC_VERSION})
1019 endif()
1020 if(CMAKE_GENERATOR MATCHES Xcode)
1021   status("    Xcode:"          ${XCODE_VERSION})
1022 endif()
1023 if(NOT CMAKE_GENERATOR MATCHES "Xcode|Visual Studio")
1024   status("    Configuration:"  ${CMAKE_BUILD_TYPE})
1025 endif()
1026
1027
1028 # ========================= CPU code generation mode =========================
1029 status("")
1030 status("  CPU/HW features:")
1031 status("    Baseline:"  "${CPU_BASELINE_FINAL}")
1032 if(NOT CPU_BASELINE STREQUAL CPU_BASELINE_FINAL)
1033   status("      requested:"  "${CPU_BASELINE}")
1034 endif()
1035 if(CPU_BASELINE_REQUIRE)
1036   status("      required:"  "${CPU_BASELINE_REQUIRE}")
1037 endif()
1038 if(CPU_BASELINE_DISABLE)
1039   status("      disabled:"  "${CPU_BASELINE_DISABLE}")
1040 endif()
1041 if(CPU_DISPATCH_FINAL OR CPU_DISPATCH)
1042   status("    Dispatched code generation:"  "${CPU_DISPATCH_FINAL}")
1043   if(NOT CPU_DISPATCH STREQUAL CPU_DISPATCH_FINAL)
1044     status("      requested:"  "${CPU_DISPATCH}")
1045   endif()
1046   if(CPU_DISPATCH_REQUIRE)
1047     status("      required:"  "${CPU_DISPATCH_REQUIRE}")
1048   endif()
1049   foreach(OPT ${CPU_DISPATCH_FINAL})
1050     status("      ${OPT} (${CPU_${OPT}_USAGE_COUNT} files):"  "+ ${CPU_DISPATCH_${OPT}_INCLUDED}")
1051   endforeach()
1052 endif()
1053
1054 # ========================== C/C++ options ==========================
1055 if(CMAKE_CXX_COMPILER_VERSION)
1056   set(OPENCV_COMPILER_STR "${CMAKE_CXX_COMPILER} ${CMAKE_CXX_COMPILER_ARG1} (ver ${CMAKE_CXX_COMPILER_VERSION})")
1057 else()
1058   set(OPENCV_COMPILER_STR "${CMAKE_CXX_COMPILER} ${CMAKE_CXX_COMPILER_ARG1}")
1059 endif()
1060 string(STRIP "${OPENCV_COMPILER_STR}" OPENCV_COMPILER_STR)
1061
1062 status("")
1063 status("  C/C++:")
1064 status("    Built as dynamic libs?:" BUILD_SHARED_LIBS THEN YES ELSE NO)
1065 if(DEFINED CMAKE_CXX_STANDARD AND CMAKE_CXX_STANDARD)
1066   status("    C++ standard:"           "${CMAKE_CXX_STANDARD}")
1067 endif()
1068 status("    C++ Compiler:"           ${OPENCV_COMPILER_STR})
1069 status("    C++ flags (Release):"    ${CMAKE_CXX_FLAGS} ${CMAKE_CXX_FLAGS_RELEASE})
1070 status("    C++ flags (Debug):"      ${CMAKE_CXX_FLAGS} ${CMAKE_CXX_FLAGS_DEBUG})
1071 status("    C Compiler:"             ${CMAKE_C_COMPILER} ${CMAKE_C_COMPILER_ARG1})
1072 status("    C flags (Release):"      ${CMAKE_C_FLAGS} ${CMAKE_C_FLAGS_RELEASE})
1073 status("    C flags (Debug):"        ${CMAKE_C_FLAGS} ${CMAKE_C_FLAGS_DEBUG})
1074 if(WIN32)
1075   status("    Linker flags (Release):" ${CMAKE_EXE_LINKER_FLAGS} ${CMAKE_EXE_LINKER_FLAGS_RELEASE})
1076   status("    Linker flags (Debug):"   ${CMAKE_EXE_LINKER_FLAGS} ${CMAKE_EXE_LINKER_FLAGS_DEBUG})
1077 else()
1078   status("    Linker flags (Release):" ${CMAKE_SHARED_LINKER_FLAGS} ${CMAKE_SHARED_LINKER_FLAGS_RELEASE})
1079   status("    Linker flags (Debug):"   ${CMAKE_SHARED_LINKER_FLAGS} ${CMAKE_SHARED_LINKER_FLAGS_DEBUG})
1080 endif()
1081 status("    ccache:"                  OPENCV_COMPILER_IS_CCACHE THEN YES ELSE NO)
1082 status("    Precompiled headers:"     PCHSupport_FOUND AND ENABLE_PRECOMPILED_HEADERS THEN YES ELSE NO)
1083
1084 # ========================== Dependencies ============================
1085 ocv_get_all_libs(deps_modules deps_extra deps_3rdparty)
1086 status("    Extra dependencies:" ${deps_extra})
1087 status("    3rdparty dependencies:" ${deps_3rdparty})
1088
1089 # ========================== OpenCV modules ==========================
1090 status("")
1091 status("  OpenCV modules:")
1092 set(OPENCV_MODULES_BUILD_ST "")
1093 foreach(the_module ${OPENCV_MODULES_BUILD})
1094   if(NOT OPENCV_MODULE_${the_module}_CLASS STREQUAL "INTERNAL" OR the_module STREQUAL "opencv_ts")
1095     list(APPEND OPENCV_MODULES_BUILD_ST "${the_module}")
1096   endif()
1097 endforeach()
1098 string(REPLACE "opencv_" "" OPENCV_MODULES_BUILD_ST          "${OPENCV_MODULES_BUILD_ST}")
1099 string(REPLACE "opencv_" "" OPENCV_MODULES_DISABLED_USER_ST  "${OPENCV_MODULES_DISABLED_USER}")
1100 string(REPLACE "opencv_" "" OPENCV_MODULES_DISABLED_AUTO_ST  "${OPENCV_MODULES_DISABLED_AUTO}")
1101 string(REPLACE "opencv_" "" OPENCV_MODULES_DISABLED_FORCE_ST "${OPENCV_MODULES_DISABLED_FORCE}")
1102 list(SORT OPENCV_MODULES_BUILD_ST)
1103 list(SORT OPENCV_MODULES_DISABLED_USER_ST)
1104 list(SORT OPENCV_MODULES_DISABLED_AUTO_ST)
1105 list(SORT OPENCV_MODULES_DISABLED_FORCE_ST)
1106 status("    To be built:"            OPENCV_MODULES_BUILD          THEN ${OPENCV_MODULES_BUILD_ST}          ELSE "-")
1107 status("    Disabled:"               OPENCV_MODULES_DISABLED_USER  THEN ${OPENCV_MODULES_DISABLED_USER_ST}  ELSE "-")
1108 status("    Disabled by dependency:" OPENCV_MODULES_DISABLED_AUTO  THEN ${OPENCV_MODULES_DISABLED_AUTO_ST}  ELSE "-")
1109 status("    Unavailable:"            OPENCV_MODULES_DISABLED_FORCE THEN ${OPENCV_MODULES_DISABLED_FORCE_ST} ELSE "-")
1110
1111 ocv_build_features_string(apps_status
1112   IF BUILD_TESTS AND HAVE_opencv_ts THEN "tests"
1113   IF BUILD_PERF_TESTS AND HAVE_opencv_ts THEN "perf_tests"
1114   IF BUILD_EXAMPLES THEN "examples"
1115   IF BUILD_opencv_apps THEN "apps"
1116   IF BUILD_ANDROID_SERVICE THEN "android_service"
1117   IF (BUILD_ANDROID_EXAMPLES OR INSTALL_ANDROID_EXAMPLES) AND CAN_BUILD_ANDROID_PROJECTS THEN "android_examples"
1118   ELSE "-")
1119 status("    Applications:" "${apps_status}")
1120 ocv_build_features_string(docs_status
1121     IF TARGET doxygen_cpp THEN "doxygen"
1122     IF TARGET doxygen_python THEN "python"
1123     IF TARGET doxygen_javadoc THEN "javadoc"
1124     IF BUILD_opencv_js OR DEFINED OPENCV_JS_LOCATION THEN "js"
1125     ELSE "NO"
1126 )
1127 status("    Documentation:" "${docs_status}")
1128 status("    Non-free algorithms:" OPENCV_ENABLE_NONFREE THEN "YES" ELSE "NO")
1129
1130 # ========================== Android details ==========================
1131 if(ANDROID)
1132   status("")
1133   if(DEFINED ANDROID_NDK_REVISION)
1134     set(__msg "${ANDROID_NDK} (ver ${ANDROID_NDK_REVISION})")
1135   else()
1136     set(__msg "location: ${ANDROID_NDK}")
1137   endif()
1138   status("  Android NDK: " ${__msg})
1139   status("    Android ABI:" ${ANDROID_ABI})
1140   if(BUILD_WITH_STANDALONE_TOOLCHAIN)
1141     status("    NDK toolchain:" "standalone: ${ANDROID_STANDALONE_TOOLCHAIN}")
1142   elseif(BUILD_WITH_ANDROID_NDK OR DEFINED ANDROID_TOOLCHAIN_NAME)
1143     status("    NDK toolchain:" "${ANDROID_TOOLCHAIN_NAME}")
1144   endif()
1145   status("    STL type:" ${ANDROID_STL})
1146   status("    Native API level:" ${ANDROID_NATIVE_API_LEVEL})
1147
1148   if(BUILD_ANDROID_PROJECTS)
1149     status("  Android SDK: " "${ANDROID_SDK} (tools: ${ANDROID_SDK_TOOLS_VERSION} build tools: ${ANDROID_SDK_BUILD_TOOLS_VERSION})")
1150     if(ANDROID_EXECUTABLE)
1151       status("    android tool:"  "${ANDROID_EXECUTABLE}")
1152     endif()
1153   else()
1154     status("  Android SDK: " "not used, projects are not built")
1155   endif()
1156   if(DEFINED ANDROID_SDK_COMPATIBLE_TARGET)
1157     status("    SDK target:" "${ANDROID_SDK_COMPATIBLE_TARGET}")
1158   endif()
1159   if(DEFINED ANDROID_PROJECTS_BUILD_TYPE)
1160     if(ANDROID_PROJECTS_BUILD_TYPE STREQUAL "ANT")
1161       status("    Projects build scripts:" "Ant/Eclipse compatible")
1162     elseif(ANDROID_PROJECTS_BUILD_TYPE STREQUAL "ANT")
1163       status("    Projects build scripts:" "Gradle")
1164     endif()
1165   endif()
1166 endif()
1167
1168 # ================== Windows RT features ==================
1169 if(WIN32)
1170 status("")
1171 status("  Windows RT support:" WINRT THEN YES ELSE NO)
1172   if(WINRT)
1173     status("    Building for Microsoft platform: " ${CMAKE_SYSTEM_NAME})
1174     status("    Building for architectures: " ${CMAKE_VS_EFFECTIVE_PLATFORMS})
1175     status("    Building for version: " ${CMAKE_SYSTEM_VERSION})
1176     if (DEFINED ENABLE_WINRT_MODE_NATIVE)
1177       status("    Building for C++ without CX extensions")
1178     endif()
1179   endif()
1180 endif(WIN32)
1181
1182 # ========================== GUI ==========================
1183 status("")
1184 status("  GUI: ")
1185
1186 if(WITH_QT OR HAVE_QT)
1187   if(HAVE_QT5)
1188     status("    QT:" "YES (ver ${Qt5Core_VERSION_STRING})")
1189     status("      QT OpenGL support:" HAVE_QT_OPENGL THEN "YES (${Qt5OpenGL_LIBRARIES} ${Qt5OpenGL_VERSION_STRING})" ELSE NO)
1190   elseif(HAVE_QT)
1191     status("    QT:" "YES (ver ${QT_VERSION_MAJOR}.${QT_VERSION_MINOR}.${QT_VERSION_PATCH} ${QT_EDITION})")
1192     status("      QT OpenGL support:" HAVE_QT_OPENGL THEN "YES (${QT_QTOPENGL_LIBRARY})" ELSE NO)
1193   else()
1194     status("    QT:" "NO")
1195   endif()
1196 endif()
1197
1198 if(WITH_WIN32UI)
1199   status("    Win32 UI:" HAVE_WIN32UI THEN YES ELSE NO)
1200 endif()
1201
1202 if(HAVE_COCOA)  # APPLE
1203   status("    Cocoa:"  YES)
1204 endif()
1205
1206 if(WITH_GTK OR HAVE_GTK)
1207   if(HAVE_GTK3)
1208     status("    GTK+:" "YES (ver ${GTK3_VERSION})")
1209   elseif(HAVE_GTK)
1210     status("    GTK+:" "YES (ver ${GTK2_VERSION})")
1211   else()
1212     status("    GTK+:" "NO")
1213   endif()
1214   if(HAVE_GTK)
1215     status(  "      GThread :" HAVE_GTHREAD THEN "YES (ver ${GTHREAD_VERSION})" ELSE NO)
1216     status(  "      GtkGlExt:" HAVE_GTKGLEXT THEN "YES (ver ${GTKGLEXT_VERSION})" ELSE NO)
1217   endif()
1218 endif()
1219
1220 if(WITH_OPENGL OR HAVE_OPENGL)
1221   status("    OpenGL support:" HAVE_OPENGL THEN "YES (${OPENGL_LIBRARIES})" ELSE NO)
1222 endif()
1223
1224 if(WITH_VTK OR HAVE_VTK)
1225   status("    VTK support:" HAVE_VTK THEN "YES (ver ${VTK_VERSION})" ELSE NO)
1226 endif()
1227
1228 # ========================== MEDIA IO ==========================
1229 status("")
1230 status("  Media I/O: ")
1231 status("    ZLib:"   ZLIB_FOUND THEN "${ZLIB_LIBRARIES} (ver ${ZLIB_VERSION_STRING})" ELSE "build (ver ${ZLIB_VERSION_STRING})")
1232
1233 if(WITH_JPEG OR HAVE_JPEG)
1234   if(NOT HAVE_JPEG)
1235     status("    JPEG:" NO)
1236   elseif(BUILD_JPEG)
1237     status("    JPEG:" "build-${JPEG_LIBRARY} (ver ${JPEG_LIB_VERSION})")
1238   else()
1239     status("    JPEG:" "${JPEG_LIBRARY} (ver ${JPEG_LIB_VERSION})")
1240   endif()
1241 endif()
1242
1243 if(WITH_WEBP OR HAVE_WEBP)
1244   status("    WEBP:" WEBP_FOUND THEN "${WEBP_LIBRARY} (ver ${WEBP_VERSION})" ELSE "build (ver ${WEBP_VERSION})")
1245 endif()
1246
1247 if(WITH_PNG OR HAVE_PNG)
1248   status("    PNG:"  PNG_FOUND  THEN "${PNG_LIBRARY} (ver ${PNG_VERSION})" ELSE "build (ver ${PNG_VERSION})")
1249 endif()
1250
1251 if(WITH_TIFF OR HAVE_TIFF)
1252   status("    TIFF:" TIFF_FOUND THEN "${TIFF_LIBRARY} (ver ${TIFF_VERSION} / ${TIFF_VERSION_STRING})" ELSE "build (ver ${TIFF_VERSION} - ${TIFF_VERSION_STRING})")
1253 endif()
1254
1255 if(HAVE_OPENJPEG)
1256   status("    JPEG 2000:" "OpenJPEG (ver ${OPENJPEG_MAJOR_VERSION}.${OPENJPEG_MINOR_VERSION}.${OPENJPEG_BUILD_VERSION})")
1257 elseif(HAVE_JASPER)
1258   status("    JPEG 2000:" JASPER_FOUND THEN "${JASPER_LIBRARY} (ver ${JASPER_VERSION_STRING})" ELSE "build Jasper (ver ${JASPER_VERSION_STRING})")
1259 elseif(WITH_OPENJPEG OR WITH_JASPER)
1260   status("    JPEG 2000:" "NO")
1261 endif()
1262
1263 if(WITH_OPENEXR OR HAVE_OPENEXR)
1264   if(HAVE_OPENEXR)
1265     status("    OpenEXR:" OPENEXR_FOUND THEN "${OPENEXR_LIBRARIES} (ver ${OPENEXR_VERSION})" ELSE "build (ver ${OPENEXR_VERSION})")
1266   else()
1267     status("    OpenEXR:" "NO")
1268   endif()
1269 endif()
1270
1271 if(WITH_GDAL OR HAVE_GDAL)
1272   status("    GDAL:" HAVE_GDAL THEN "YES (${GDAL_LIBRARY})" ELSE "NO")
1273 endif()
1274
1275 if(WITH_GDCM OR HAVE_GDCM)
1276   status("    GDCM:" HAVE_GDCM THEN "YES (${GDCM_VERSION})" ELSE "NO")
1277 endif()
1278
1279 if(WITH_IMGCODEC_HDR OR DEFINED HAVE_IMGCODEC_HDR)
1280   status("    HDR:" HAVE_IMGCODEC_HDR THEN "YES" ELSE "NO")
1281 endif()
1282
1283 if(WITH_IMGCODEC_SUNRASTER OR DEFINED HAVE_IMGCODEC_SUNRASTER)
1284   status("    SUNRASTER:" HAVE_IMGCODEC_SUNRASTER THEN "YES" ELSE "NO")
1285 endif()
1286
1287 if(WITH_IMGCODEC_PXM OR DEFINED HAVE_IMGCODEC_PXM)
1288   status("    PXM:" HAVE_IMGCODEC_PXM THEN "YES" ELSE "NO")
1289 endif()
1290
1291 if(WITH_IMGCODEC_PFM OR DEFINED HAVE_IMGCODEC_PFM)
1292   status("    PFM:" HAVE_IMGCODEC_PFM THEN "YES" ELSE "NO")
1293 endif()
1294
1295 # ========================== VIDEO IO ==========================
1296 status("")
1297 status("  Video I/O:")
1298
1299 if(WITH_1394 OR HAVE_DC1394_2)
1300   status("    DC1394:" HAVE_DC1394_2 THEN "YES (${DC1394_2_VERSION})" ELSE NO)
1301 endif()
1302
1303 if(WITH_FFMPEG OR HAVE_FFMPEG)
1304   if(OPENCV_FFMPEG_USE_FIND_PACKAGE)
1305     status("    FFMPEG:"       HAVE_FFMPEG         THEN "YES (find_package)"                       ELSE "NO (find_package)")
1306   elseif(WIN32)
1307     status("    FFMPEG:"       HAVE_FFMPEG         THEN "YES (prebuilt binaries)"                  ELSE NO)
1308   else()
1309     status("    FFMPEG:"       HAVE_FFMPEG         THEN YES ELSE NO)
1310   endif()
1311   status("      avcodec:"      FFMPEG_libavcodec_VERSION    THEN "YES (${FFMPEG_libavcodec_VERSION})"    ELSE NO)
1312   status("      avformat:"     FFMPEG_libavformat_VERSION   THEN "YES (${FFMPEG_libavformat_VERSION})"   ELSE NO)
1313   status("      avutil:"       FFMPEG_libavutil_VERSION     THEN "YES (${FFMPEG_libavutil_VERSION})"     ELSE NO)
1314   status("      swscale:"      FFMPEG_libswscale_VERSION    THEN "YES (${FFMPEG_libswscale_VERSION})"    ELSE NO)
1315   status("      avresample:"   FFMPEG_libavresample_VERSION THEN "YES (${FFMPEG_libavresample_VERSION})" ELSE NO)
1316 endif()
1317
1318 if(WITH_GSTREAMER OR HAVE_GSTREAMER)
1319   status("    GStreamer:" HAVE_GSTREAMER THEN "YES (${GSTREAMER_VERSION})" ELSE NO)
1320 endif()
1321
1322 if(WITH_OPENNI2 OR HAVE_OPENNI2)
1323   status("    OpenNI2:"        HAVE_OPENNI2    THEN "YES (${OPENNI2_VERSION})" ELSE NO)
1324 endif()
1325
1326 if(WITH_PVAPI OR HAVE_PVAPI)
1327   status("    PvAPI:" HAVE_PVAPI THEN YES ELSE NO)
1328 endif()
1329
1330 if(WITH_ARAVIS OR HAVE_ARAVIS_API)
1331   status("    Aravis SDK:" HAVE_ARAVIS_API THEN "YES (${ARAVIS_VERSION})" ELSE NO)
1332 endif()
1333
1334 if(WITH_AVFOUNDATION OR HAVE_AVFOUNDATION)
1335   status("    AVFoundation:" HAVE_AVFOUNDATION THEN YES ELSE NO)
1336 endif()
1337
1338 if(HAVE_CAP_IOS)
1339   status("    iOS capture:" YES)
1340 endif()
1341
1342 if(WITH_V4L OR HAVE_V4L)
1343   ocv_build_features_string(v4l_status
1344     IF HAVE_CAMV4L2 THEN "linux/videodev2.h"
1345     IF HAVE_VIDEOIO THEN "sys/videoio.h"
1346     ELSE "NO")
1347   status("    v4l/v4l2:" HAVE_V4L THEN "YES (${v4l_status})" ELSE NO)
1348 endif()
1349
1350 if(WITH_DSHOW OR HAVE_DSHOW)
1351   status("    DirectShow:" HAVE_DSHOW THEN YES ELSE NO)
1352 endif()
1353
1354 if(WITH_MSMF OR HAVE_MSMF)
1355   status("    Media Foundation:" HAVE_MSMF THEN YES ELSE NO)
1356   status("      DXVA:" HAVE_MSMF_DXVA THEN YES ELSE NO)
1357 endif()
1358
1359 if(WITH_XIMEA OR HAVE_XIMEA)
1360   status("    XIMEA:" HAVE_XIMEA THEN YES ELSE NO)
1361 endif()
1362
1363 if(WITH_XINE OR HAVE_XINE)
1364   status("    Xine:"           HAVE_XINE           THEN "YES (ver ${XINE_VERSION})"     ELSE NO)
1365 endif()
1366
1367 if(WITH_LIBREALSENSE OR HAVE_LIBREALSENSE)
1368   status("    Intel RealSense:" HAVE_LIBREALSENSE THEN "YES (${LIBREALSENSE_VERSION})" ELSE NO)
1369 endif()
1370
1371 if(WITH_MFX OR HAVE_MFX)
1372   status("    Intel Media SDK:" HAVE_MFX      THEN "YES (${MFX_LIBRARY})" ELSE NO)
1373 endif()
1374
1375 if(WITH_GPHOTO2 OR HAVE_GPHOTO2)
1376   status("    gPhoto2:"        HAVE_GPHOTO2        THEN "YES"                                 ELSE NO)
1377 endif()
1378
1379 # Order is similar to CV_PARALLEL_FRAMEWORK in core/src/parallel.cpp
1380 ocv_build_features_string(parallel_status EXCLUSIVE
1381   IF HAVE_TBB THEN "TBB (ver ${TBB_VERSION_MAJOR}.${TBB_VERSION_MINOR} interface ${TBB_INTERFACE_VERSION})"
1382   IF HAVE_HPX THEN "HPX"
1383   IF HAVE_OPENMP THEN "OpenMP"
1384   IF HAVE_GCD THEN "GCD"
1385   IF WINRT OR HAVE_CONCURRENCY THEN "Concurrency"
1386   IF HAVE_PTHREADS_PF THEN "pthreads"
1387   ELSE "none")
1388 status("")
1389 status("  Parallel framework:" "${parallel_status}")
1390
1391 if(CV_TRACE OR OPENCV_TRACE)
1392   ocv_build_features_string(trace_status EXCLUSIVE
1393     IF HAVE_ITT THEN "with Intel ITT"
1394     ELSE "built-in")
1395   status("")
1396   status("  Trace: " OPENCV_TRACE THEN "YES (${trace_status})" ELSE NO)
1397 endif()
1398
1399 # ========================== Other third-party libraries ==========================
1400 status("")
1401 status("  Other third-party libraries:")
1402
1403 if(WITH_IPP AND HAVE_IPP)
1404   status("    Intel IPP:" "${IPP_VERSION_STR} [${IPP_VERSION_MAJOR}.${IPP_VERSION_MINOR}.${IPP_VERSION_BUILD}]")
1405   status("           at:" "${IPP_ROOT_DIR}")
1406   if(NOT HAVE_IPP_ICV)
1407     status("       linked:" BUILD_WITH_DYNAMIC_IPP THEN "dynamic" ELSE "static")
1408   endif()
1409   if(HAVE_IPP_IW)
1410     if(BUILD_IPP_IW)
1411       status("    Intel IPP IW:" "sources (${IW_VERSION_MAJOR}.${IW_VERSION_MINOR}.${IW_VERSION_UPDATE})")
1412     else()
1413       status("    Intel IPP IW:" "binaries (${IW_VERSION_MAJOR}.${IW_VERSION_MINOR}.${IW_VERSION_UPDATE})")
1414     endif()
1415     status("              at:" "${IPP_IW_PATH}")
1416   else()
1417     status("    Intel IPP IW:"   NO)
1418   endif()
1419 endif()
1420
1421 if(WITH_VA OR HAVE_VA)
1422   status("    VA:"            HAVE_VA          THEN "YES" ELSE NO)
1423 endif()
1424
1425 if(WITH_VA_INTEL OR HAVE_VA_INTEL)
1426   status("    Intel VA-API/OpenCL:"  HAVE_VA_INTEL       THEN "YES (OpenCL: ${VA_INTEL_IOCL_ROOT})" ELSE NO)
1427 endif()
1428
1429 if(WITH_TENGINE OR HAVE_TENGINE)
1430   status("    Tengine:"      HAVE_TENGINE     THEN "YES (${TENGINE_LIBRARIES})" ELSE NO)
1431 endif()
1432
1433 if(WITH_LAPACK OR HAVE_LAPACK)
1434   status("    Lapack:"      HAVE_LAPACK     THEN "YES (${LAPACK_LIBRARIES})" ELSE NO)
1435 endif()
1436
1437 if(WITH_HALIDE OR HAVE_HALIDE)
1438   status("    Halide:"     HAVE_HALIDE      THEN "YES (${HALIDE_LIBRARIES} ${HALIDE_INCLUDE_DIRS})" ELSE NO)
1439 endif()
1440
1441 if(WITH_INF_ENGINE OR INF_ENGINE_TARGET)
1442   if(INF_ENGINE_TARGET)
1443     list(GET INF_ENGINE_TARGET 0 ie_target)
1444     set(__msg "YES (${INF_ENGINE_RELEASE} / ${INF_ENGINE_VERSION})")
1445     get_target_property(_lib ${ie_target} IMPORTED_LOCATION)
1446     get_target_property(_lib_imp_rel ${ie_target} IMPORTED_IMPLIB_RELEASE)
1447     get_target_property(_lib_imp_dbg ${ie_target} IMPORTED_IMPLIB_DEBUG)
1448     get_target_property(_lib_rel ${ie_target} IMPORTED_LOCATION_RELEASE)
1449     get_target_property(_lib_dbg ${ie_target} IMPORTED_LOCATION_DEBUG)
1450     ocv_build_features_string(_lib
1451       IF _lib THEN "${_lib}"
1452       IF _lib_imp_rel AND _lib_imp_dbg THEN "${_lib_imp_rel} / ${_lib_imp_dbg}"
1453       IF _lib_rel AND _lib_dbg THEN "${_lib_rel} / ${_lib_dbg}"
1454       IF _lib_rel  THEN "${_lib_rel}"
1455       IF _lib_dbg  THEN "${_lib_dbg}"
1456       ELSE "unknown"
1457     )
1458     get_target_property(_inc ${ie_target} INTERFACE_INCLUDE_DIRECTORIES)
1459     status("    Inference Engine:" "${__msg}")
1460     status("        * libs:" "${_lib}")
1461     status("        * includes:" "${_inc}")
1462   else()
1463     status("    Inference Engine:"     "NO")
1464   endif()
1465 endif()
1466 if(WITH_NGRAPH OR HAVE_NGRAPH)
1467   if(HAVE_NGRAPH)
1468     set(__target ngraph::ngraph)
1469     set(__msg "YES (${ngraph_VERSION})")
1470     get_target_property(_lib ${__target} IMPORTED_LOCATION)
1471     get_target_property(_lib_imp_rel ${__target} IMPORTED_IMPLIB_RELEASE)
1472     get_target_property(_lib_imp_dbg ${__target} IMPORTED_IMPLIB_DEBUG)
1473     get_target_property(_lib_rel ${__target} IMPORTED_LOCATION_RELEASE)
1474     get_target_property(_lib_dbg ${__target} IMPORTED_LOCATION_DEBUG)
1475     ocv_build_features_string(_lib
1476       IF _lib THEN "${_lib}"
1477       IF _lib_imp_rel AND _lib_imp_dbg THEN "${_lib_imp_rel} / ${_lib_imp_dbg}"
1478       IF _lib_rel AND _lib_dbg THEN "${_lib_rel} / ${_lib_dbg}"
1479       IF _lib_rel  THEN "${_lib_rel}"
1480       IF _lib_dbg  THEN "${_lib_dbg}"
1481       ELSE "unknown"
1482     )
1483     get_target_property(_inc ${__target} INTERFACE_INCLUDE_DIRECTORIES)
1484     status("    nGraph:" "${__msg}")
1485     status("        * libs:" "${_lib}")
1486     status("        * includes:" "${_inc}")
1487   else()
1488     status("    nGraph:"     "NO")
1489   endif()
1490 endif()
1491
1492 if(WITH_EIGEN OR HAVE_EIGEN)
1493   status("    Eigen:"      HAVE_EIGEN       THEN "YES (ver ${EIGEN_WORLD_VERSION}.${EIGEN_MAJOR_VERSION}.${EIGEN_MINOR_VERSION})" ELSE NO)
1494 endif()
1495
1496 if(WITH_OPENVX OR HAVE_OPENVX)
1497   status("    OpenVX:"     HAVE_OPENVX      THEN "YES (${OPENVX_LIBRARIES})" ELSE "NO")
1498 endif()
1499
1500 status("    Custom HAL:" OpenCV_USED_HAL  THEN "YES (${OpenCV_USED_HAL})" ELSE "NO")
1501
1502 foreach(s ${CUSTOM_STATUS})
1503   status(${CUSTOM_STATUS_${s}})
1504 endforeach()
1505
1506 if(WITH_CUDA OR HAVE_CUDA)
1507   ocv_build_features_string(cuda_features
1508     IF HAVE_CUFFT THEN "CUFFT"
1509     IF HAVE_CUBLAS THEN "CUBLAS"
1510     IF HAVE_NVCUVID THEN "NVCUVID"
1511     IF CUDA_FAST_MATH THEN "FAST_MATH"
1512     ELSE "no extra features")
1513   status("")
1514   status("  NVIDIA CUDA:" HAVE_CUDA THEN "YES (ver ${CUDA_VERSION_STRING}, ${cuda_features})" ELSE NO)
1515   if(HAVE_CUDA)
1516     status("    NVIDIA GPU arch:"      ${OPENCV_CUDA_ARCH_BIN})
1517     status("    NVIDIA PTX archs:"     ${OPENCV_CUDA_ARCH_PTX})
1518   endif()
1519  endif()
1520
1521  if(WITH_CUDNN OR HAVE_CUDNN)
1522     status("")
1523     status("  cuDNN:" HAVE_CUDNN THEN "YES (ver ${CUDNN_VERSION})" ELSE NO)
1524 endif()
1525
1526 if(WITH_VULKAN OR HAVE_VULKAN)
1527   status("")
1528   status("  Vulkan:"     HAVE_VULKAN THEN "YES" ELSE "NO")
1529   if(HAVE_VULKAN)
1530     status("    Include path:"  VULKAN_INCLUDE_DIRS THEN "${VULKAN_INCLUDE_DIRS}" ELSE "NO")
1531     status("    Link libraries:" VULKAN_LIBRARIES THEN "${VULKAN_LIBRARIES}" ELSE "Dynamic load")
1532   endif()
1533 endif()
1534
1535 if(WITH_OPENCL OR HAVE_OPENCL)
1536   ocv_build_features_string(opencl_features
1537     IF HAVE_OPENCL_SVM THEN "SVM"
1538     IF HAVE_CLAMDFFT THEN "AMDFFT"
1539     IF HAVE_CLAMDBLAS THEN "AMDBLAS"
1540     IF HAVE_OPENCL_D3D11_NV THEN "NVD3D11"
1541     ELSE "no extra features")
1542   status("")
1543   status("  OpenCL:"     HAVE_OPENCL   THEN   "YES (${opencl_features})" ELSE "NO")
1544   if(HAVE_OPENCL)
1545     status("    Include path:"  OPENCL_INCLUDE_DIRS THEN "${OPENCL_INCLUDE_DIRS}" ELSE "NO")
1546     status("    Link libraries:"       OPENCL_LIBRARIES THEN "${OPENCL_LIBRARIES}" ELSE "Dynamic load")
1547   endif()
1548 endif()
1549
1550 # ========================== python ==========================
1551 if(BUILD_opencv_python2)
1552   status("")
1553   status("  Python 2:")
1554   status("    Interpreter:"     PYTHON2INTERP_FOUND  THEN "${PYTHON2_EXECUTABLE} (ver ${PYTHON2_VERSION_STRING})"       ELSE NO)
1555   if(PYTHON2LIBS_VERSION_STRING)
1556     status("    Libraries:"   HAVE_opencv_python2  THEN  "${PYTHON2_LIBRARIES} (ver ${PYTHON2LIBS_VERSION_STRING})"   ELSE NO)
1557   else()
1558     status("    Libraries:"   HAVE_opencv_python2  THEN  "${PYTHON2_LIBRARIES}"                                      ELSE NO)
1559   endif()
1560   status("    numpy:"         PYTHON2_NUMPY_INCLUDE_DIRS THEN "${PYTHON2_NUMPY_INCLUDE_DIRS} (ver ${PYTHON2_NUMPY_VERSION})" ELSE "NO (Python wrappers can not be generated)")
1561   status("    install path:"  HAVE_opencv_python2  THEN "${__INSTALL_PATH_PYTHON2}"                            ELSE "-")
1562 endif()
1563
1564 if(BUILD_opencv_python3)
1565   status("")
1566   status("  Python 3:")
1567   status("    Interpreter:"     PYTHON3INTERP_FOUND  THEN "${PYTHON3_EXECUTABLE} (ver ${PYTHON3_VERSION_STRING})"       ELSE NO)
1568   if(PYTHON3LIBS_VERSION_STRING)
1569     status("    Libraries:"   HAVE_opencv_python3  THEN  "${PYTHON3_LIBRARIES} (ver ${PYTHON3LIBS_VERSION_STRING})"   ELSE NO)
1570   else()
1571     status("    Libraries:"   HAVE_opencv_python3  THEN  "${PYTHON3_LIBRARIES}"                                      ELSE NO)
1572   endif()
1573   status("    numpy:"         PYTHON3_NUMPY_INCLUDE_DIRS THEN "${PYTHON3_NUMPY_INCLUDE_DIRS} (ver ${PYTHON3_NUMPY_VERSION})" ELSE "NO (Python3 wrappers can not be generated)")
1574   status("    install path:"  HAVE_opencv_python3  THEN "${__INSTALL_PATH_PYTHON3}"                            ELSE "-")
1575 endif()
1576
1577 status("")
1578 status("  Python (for build):"  PYTHON_DEFAULT_AVAILABLE THEN "${PYTHON_DEFAULT_EXECUTABLE}" ELSE NO)
1579 if(PYLINT_FOUND AND PYLINT_EXECUTABLE)
1580   status("    Pylint:"  PYLINT_FOUND THEN "${PYLINT_EXECUTABLE} (ver: ${PYLINT_VERSION}, checks: ${PYLINT_TOTAL_TARGETS})" ELSE NO)
1581 endif()
1582 if(FLAKE8_FOUND AND FLAKE8_EXECUTABLE)
1583   status("    Flake8:"  FLAKE8_FOUND THEN "${FLAKE8_EXECUTABLE} (ver: ${FLAKE8_VERSION})" ELSE NO)
1584 endif()
1585
1586 # ========================== java ==========================
1587 if(BUILD_JAVA)
1588   status("")
1589   status("  Java:"            BUILD_FAT_JAVA_LIB  THEN "export all functions"                                      ELSE "")
1590   status("    ant:"           ANT_EXECUTABLE      THEN "${ANT_EXECUTABLE} (ver ${ANT_VERSION})"                    ELSE NO)
1591   if(NOT ANDROID)
1592     status("    JNI:"         JNI_INCLUDE_DIRS    THEN "${JNI_INCLUDE_DIRS}"                                       ELSE NO)
1593   endif()
1594   status("    Java wrappers:" HAVE_opencv_java                                                            THEN YES ELSE NO)
1595   status("    Java tests:"    BUILD_TESTS AND opencv_test_java_BINARY_DIR                                 THEN YES ELSE NO)
1596 endif()
1597
1598 ocv_cmake_hook(STATUS_DUMP_EXTRA)
1599
1600 # ========================== auxiliary ==========================
1601 status("")
1602 status("  Install to:" "${CMAKE_INSTALL_PREFIX}")
1603 status("-----------------------------------------------------------------")
1604 status("")
1605
1606
1607 ocv_finalize_status()
1608
1609 if(ENABLE_CONFIG_VERIFICATION)
1610   ocv_verify_config()
1611 endif()
1612
1613 ocv_cmake_hook(POST_FINALIZE)
1614
1615 # ----------------------------------------------------------------------------
1616 # CPack stuff
1617 # ----------------------------------------------------------------------------
1618
1619 include(cmake/OpenCVPackaging.cmake)
1620
1621 # This should be the last command
1622 ocv_cmake_dump_vars("" TOFILE "CMakeVars.txt")
1623 ocv_cmake_eval(DEBUG_POST ONCE)