CMakeLists.txt

   1 cmake_minimum_required(VERSION 2.6)
   2
   3 project(libwebsockets)
   4
   5 set(PACKAGE "libwebsockets")
   6 set(CPACK_PACKAGE_NAME "${PACKAGE}")
   7 set(CPACK_PACKAGE_VERSION_MAJOR "1")
   8 set(CPACK_PACKAGE_VERSION_MINOR "3")
   9 set(CPACK_PACKAGE_VERSION "${CPACK_PACKAGE_VERSION_MAJOR}.${CPACK_PACKAGE_VERSION_MINOR}")
  10 set(CPACK_PACKAGE_VENDOR "andy@warmcat.com")
  11 set(CPACK_PACKAGE_DESCRIPTION_SUMMARY "${PACKAGE} ${PACKAGE_VERSION}")
  12 set(SOVERSION "4.0.0")
  13 set(CPACK_SOURCE_GENERATOR "TGZ")
  14 set(CPACK_SOURCE_PACKAGE_FILE_NAME "${CPACK_PACKAGE_NAME}-${CPACK_PACKAGE_VERSION}")
  15 set(VERSION "${CPACK_PACKAGE_VERSION}")
  16
  17 set(LWS_LIBRARY_VERSION ${CPACK_PACKAGE_VERSION})
  18 set(CMAKE_MODULE_PATH ${CMAKE_MODULE_PATH} "${PROJECT_SOURCE_DIR}/cmake/")
  19
  20 message(STATUS "CMAKE_TOOLCHAIN_FILE='${CMAKE_TOOLCHAIN_FILE}'")
  21
  22 # Try to find the current Git hash.
  23 find_package(Git)
  24 if(GIT_EXECUTABLE)
  25         execute_process(
  26     WORKING_DIRECTORY "${CMAKE_CURRENT_SOURCE_DIR}"
  27     COMMAND "${GIT_EXECUTABLE}" log -n 1 --pretty=%h
  28     OUTPUT_VARIABLE GIT_HASH
  29     OUTPUT_STRIP_TRAILING_WHITESPACE
  30     )
  31
  32     set(LWS_BUILD_HASH ${GIT_HASH})
  33     message("Git commit hash: ${LWS_BUILD_HASH}")
  34 endif()
  35
  36 option(LWS_WITH_SSL "Include SSL support (default OpenSSL, CyaSSL if LWS_USE_CYASSL is set)" ON)
  37 option(LWS_SSL_CLIENT_USE_OS_CA_CERTS "SSL support should make use of OS installed CA root certs" ON)
  38 option(LWS_USE_EXTERNAL_ZLIB "Search the system for ZLib instead of using the included one (on Windows)" OFF)
  39 option(LWS_USE_CYASSL "Use CyaSSL replacement for OpenSSL. When settings this, you also need to specify LWS_CYASSL_LIB and LWS_CYASSL_INCLUDE_DIRS" OFF)
  40 option(LWS_WITHOUT_BUILTIN_GETIFADDRS "Don't use BSD getifaddrs implementation from libwebsockets if it is missing (this will result in a compilation error) ... Default is your libc provides it. On some systems such as uclibc it doesn't exist." OFF)
  41 option(LWS_WITHOUT_CLIENT "Don't build the client part of the library" OFF)
  42 option(LWS_WITHOUT_SERVER "Don't build the server part of the library" OFF)
  43 option(LWS_LINK_TESTAPPS_DYNAMIC "Link the test apps to the shared version of the library. Default is to link statically" OFF)
  44 option(LWS_WITHOUT_TESTAPPS "Don't build the libwebsocket-test-apps" OFF)
  45 option(LWS_WITHOUT_TEST_SERVER "Don't build the test server" OFF)
  46 option(LWS_WITHOUT_TEST_SERVER_EXTPOLL "Don't build the test server version that uses external poll" OFF)
  47 option(LWS_WITHOUT_TEST_PING "Don't build the ping test application" OFF)
  48 option(LWS_WITHOUT_TEST_CLIENT "Don't build the client test application" OFF)
  49 option(LWS_WITHOUT_TEST_FRAGGLE "Don't build the ping test application" OFF)
  50 option(LWS_WITHOUT_DEBUG "Don't compile debug related code" OFF)
  51 option(LWS_WITHOUT_EXTENSIONS "Don't compile with extensions" OFF)
  52 option(LWS_WITH_LATENCY "Build latency measuring code into the library" OFF)
  53 option(LWS_WITHOUT_DAEMONIZE "Don't build the daemonization api" OFF)
  54 option(LWS_WITH_LIBEV "Compile with support for libev" OFF)
  55 option(LWS_IPV6 "Compile with support for ipv6" ON)
  56 option(LWS_WITH_HTTP2 "Compile with support for http2" OFF)
  57
  58 # Allow the user to override installation directories.
  59 set(LWS_INSTALL_LIB_DIR       lib CACHE PATH "Installation directory for libraries")
  60 set(LWS_INSTALL_BIN_DIR       bin CACHE PATH "Installation directory for executables")
  61 set(LWS_INSTALL_INCLUDE_DIR   include CACHE PATH "Installation directory for header files")
  62 set(LWS_INSTALL_EXAMPLES_DIR  bin CACHE PATH "Installation directory for example files")
  63
  64 if (LWS_WITHOUT_CLIENT AND LWS_WITHOUT_SERVER)
  65         message(FATAL_ERROR "Makes no sense to compile without both client or server.")
  66 endif()
  67
  68 # The base dir where the test-apps look for the SSL certs.
  69 set(LWS_OPENSSL_CLIENT_CERTS ../share CACHE PATH "Server SSL certificate directory")
  70 if (WIN32)
  71         set(LWS_OPENSSL_CLIENT_CERTS . CACHE PATH "Client SSL certificate directory")
  72 else()
  73         set(LWS_OPENSSL_CLIENT_CERTS /etc/pki/tls/certs/ CACHE PATH "Client SSL certificate directory")
  74 endif()
  75
  76 set(LWS_CYASSL_LIB CACHE PATH "Path to the CyaSSL library")
  77 set(LWS_CYASSL_INCLUDE_DIRS CACHE PATH "Path to the CyaSSL include directory")
  78
  79 if (LWS_USE_CYASSL)
  80         if ("${LWS_CYASSL_LIB}" STREQUAL "" OR "${LWS_CYASSL_INCLUDE_DIRS}" STREQUAL "")
  81                 message(FATAL_ERROR "You must set LWS_CYASSL_LIB and LWS_CYASSL_INCLUDE_DIRS when LWS_USE_CYASSL is turned on")
  82         endif()
  83         set(USE_CYASSL 1)
  84 endif()
  85
  86 if (LWS_WITHOUT_EXTENSIONS)
  87         set(LWS_NO_EXTENSIONS 1)
  88 endif()
  89
  90 if (LWS_WITH_SSL)
  91         set(LWS_OPENSSL_SUPPORT 1)
  92 endif()
  93
  94 if (LWS_SSL_CLIENT_USE_OS_CA_CERTS)
  95         set(LWS_SSL_CLIENT_USE_OS_CA_CERTS 1)
  96 endif()
  97
  98 if (LWS_WITH_LATENCY)
  99         set(LWS_LATENCY 1)
 100 endif()
 101
 102 if (LWS_WITHOUT_DAEMONIZE OR WIN32)
 103         set(LWS_NO_DAEMONIZE 1)
 104 endif()
 105
 106 if (LWS_WITHOUT_SERVER)
 107         set(LWS_NO_SERVER 1)
 108 endif()
 109
 110 if (LWS_WITHOUT_CLIENT)
 111         set(LWS_NO_CLIENT 1)
 112 endif()
 113
 114 if (LWS_WITHOUT_DEBUG)
 115         set(_DEBUG 0)
 116 else()
 117         set(_DEBUG 1)
 118 endif()
 119
 120 if (LWS_WITH_LIBEV)
 121         set(LWS_USE_LIBEV 1)
 122         set(LWS_NO_EXTERNAL_POLL 1)
 123 endif()
 124
 125 if (LWS_IPV6)
 126         set(LWS_USE_IPV6 1)
 127 endif()
 128
 129 if (LWS_WITH_HTTP2)
 130         set(LWS_USE_HTTP2 1)
 131 endif()
 132
 133 if (MINGW)
 134         set(LWS_MINGW_SUPPORT 1)
 135 endif()
 136
 137 include_directories("${PROJECT_BINARY_DIR}")
 138
 139 include(CheckCSourceCompiles)
 140
 141 # Check for different inline keyword versions.
 142 foreach(KEYWORD "inline" "__inline__" "__inline")
 143         set(CMAKE_REQUIRED_DEFINITIONS "-DKEYWORD=${KEYWORD}")
 144         CHECK_C_SOURCE_COMPILES(
 145                 "
 146                 #include <stdio.h>
 147                 KEYWORD void a() {}
 148                 int main(int argc, char **argv) { a(); return 0; }
 149                 " HAVE_${KEYWORD})
 150 endforeach()
 151
 152 if (NOT HAVE_inline)
 153         if (HAVE___inline__)
 154                 set(inline __inline__)
 155         elseif(HAVE___inline)
 156                 set(inline __inline)
 157         endif()
 158 endif()
 159
 160 # Put the libaries and binaries that get built into directories at the
 161 # top of the build tree rather than in hard-to-find leaf directories.
 162 SET(CMAKE_RUNTIME_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin")
 163 SET(CMAKE_LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/lib")
 164 SET(CMAKE_ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/lib")
 165
 166 # Put absolute path of dynamic libraries into the object code. Some
 167 # architectures, notably Mac OS X, need this.
 168 SET(CMAKE_INSTALL_NAME_DIR "${CMAKE_INSTALL_PREFIX}/${LWS_INSTALL_LIB_DIR}${LIB_SUFFIX}")
 169
 170 # So we can include the CMake generated config file only when
 171 # building with CMAKE.
 172 add_definitions(-DCMAKE_BUILD)
 173
 174 include(CheckFunctionExists)
 175 include(CheckIncludeFile)
 176 include(CheckIncludeFiles)
 177 include(CheckLibraryExists)
 178 include(CheckTypeSize)
 179
 180 CHECK_FUNCTION_EXISTS(bzero HAVE_BZERO)
 181 CHECK_FUNCTION_EXISTS(fork HAVE_FORK)
 182 CHECK_FUNCTION_EXISTS(getenv HAVE_GETENV)
 183 CHECK_FUNCTION_EXISTS(malloc HAVE_MALLOC)
 184 CHECK_FUNCTION_EXISTS(memset HAVE_MEMSET)
 185 CHECK_FUNCTION_EXISTS(realloc HAVE_REALLOC)
 186 CHECK_FUNCTION_EXISTS(socket HAVE_SOCKET)
 187 CHECK_FUNCTION_EXISTS(strerror HAVE_STRERROR)
 188 CHECK_FUNCTION_EXISTS(vfork HAVE_VFORK)
 189 CHECK_FUNCTION_EXISTS(getifaddrs HAVE_GETIFADDRS)
 190
 191 if (NOT HAVE_GETIFADDRS)
 192         if (LWS_WITHOUT_BUILTIN_GETIFADDRS)
 193                 message(FATAL_ERROR "No getifaddrs was found on the system. Turn off the LWS_WITHOUT_BUILTIN_GETIFADDRS compile option to use the supplied BSD version.")
 194         endif()
 195
 196         set(LWS_BUILTIN_GETIFADDRS 1)
 197 endif()
 198
 199 CHECK_INCLUDE_FILE(dlfcn.h HAVE_DLFCN_H)
 200 CHECK_INCLUDE_FILE(fcntl.h HAVE_FCNTL_H)
 201 CHECK_INCLUDE_FILE(inttypes.h HAVE_INTTYPES_H)
 202 CHECK_INCLUDE_FILE(memory.h HAVE_MEMORY_H)
 203 CHECK_INCLUDE_FILE(netinet/in.h HAVE_NETINET_IN_H)
 204 CHECK_INCLUDE_FILE(stdint.h HAVE_STDINT_H)
 205 CHECK_INCLUDE_FILE(stdlib.h HAVE_STDLIB_H)
 206 CHECK_INCLUDE_FILE(strings.h HAVE_STRINGS_H)
 207 CHECK_INCLUDE_FILE(string.h HAVE_STRING_H)
 208 CHECK_INCLUDE_FILE(sys/prctl.h HAVE_SYS_PRCTL_H)
 209 CHECK_INCLUDE_FILE(sys/socket.h HAVE_SYS_SOCKET_H)
 210 CHECK_INCLUDE_FILE(sys/stat.h HAVE_SYS_STAT_H)
 211 CHECK_INCLUDE_FILE(sys/types.h HAVE_SYS_TYPES_H)
 212 CHECK_INCLUDE_FILE(unistd.h HAVE_UNISTD_H)
 213 CHECK_INCLUDE_FILE(vfork.h HAVE_VFORK_H)
 214 CHECK_INCLUDE_FILE(zlib.h HAVE_ZLIB_H)
 215
 216 # TODO: These can be tested if they actually work also...
 217 set(HAVE_WORKING_FORK HAVE_FORK)
 218 set(HAVE_WORKING_VFORK HAVE_VFORK)
 219
 220 CHECK_INCLUDE_FILES("stdlib.h;stdarg.h;string.h;float.h" STDC_HEADERS)
 221
 222 CHECK_TYPE_SIZE(pid_t PID_T_SIZE)
 223 CHECK_TYPE_SIZE(size_t SIZE_T_SIZE)
 224
 225 if (NOT PID_T_SIZE)
 226         set(pid_t int)
 227 endif()
 228
 229 if (NOT SIZE_T_SIZE)
 230         set(size_t "unsigned int")
 231 endif()
 232
 233 if (NOT HAVE_MALLOC)
 234         set(malloc rpl_malloc)
 235 endif()
 236
 237 if (NOT HAVE_REALLOC)
 238         set(realloc rpl_realloc)
 239 endif()
 240
 241 # Generate the config.h that includes all the compilation settings.
 242 configure_file(
 243        "${PROJECT_SOURCE_DIR}/config.h.cmake"
 244        "${PROJECT_BINARY_DIR}/lws_config.h")
 245
 246 if (MSVC)
 247         # Turn off stupid microsoft security warnings.
 248         add_definitions(-D_CRT_SECURE_NO_DEPRECATE -D_CRT_NONSTDC_NO_DEPRECATE)
 249 endif(MSVC)
 250
 251 include_directories("${PROJECT_SOURCE_DIR}/lib")
 252
 253 # Group headers and sources.
 254 # Some IDEs use this for nicer file structure.
 255 set(HDR_PRIVATE
 256         lib/private-libwebsockets.h
 257         "${PROJECT_BINARY_DIR}/lws_config.h"
 258         )
 259
 260 set(HDR_PUBLIC
 261         "${PROJECT_SOURCE_DIR}/lib/libwebsockets.h"
 262         )
 263
 264 set(SOURCES
 265         lib/base64-decode.c
 266         lib/handshake.c
 267         lib/libwebsockets.c
 268         lib/service.c
 269         lib/pollfd.c
 270         lib/output.c
 271         lib/parsers.c
 272         lib/context.c
 273         lib/sha-1.c
 274         )
 275
 276 if (NOT LWS_WITHOUT_CLIENT)
 277         list(APPEND SOURCES
 278                 lib/client.c
 279                 lib/client-handshake.c
 280                 lib/client-parser.c
 281                 )
 282 endif()
 283
 284 if (LWS_WITH_SSL)
 285         list(APPEND SOURCES
 286                 lib/ssl.c
 287                 )
 288 endif()
 289
 290 if (LWS_WITH_HTTP2)
 291         list(APPEND SOURCES
 292                 lib/ssl-http2.c
 293                 )
 294 endif()
 295 # select the active platform files
 296
 297 if (WIN32)
 298         list(APPEND SOURCES
 299                 lib/lws-plat-win.c
 300                 )
 301 else()
 302         list(APPEND SOURCES
 303                 lib/lws-plat-unix.c
 304                 )
 305 endif()
 306
 307 if (NOT LWS_WITHOUT_SERVER)
 308         list(APPEND SOURCES
 309                 lib/server.c
 310                 lib/server-handshake.c
 311                 )
 312 endif()
 313
 314 if (NOT LWS_WITHOUT_EXTENSIONS)
 315         list(APPEND HDR_PRIVATE
 316                 lib/extension-deflate-frame.h
 317                 lib/extension-deflate-stream.h
 318                 )
 319
 320         list(APPEND SOURCES
 321                 lib/extension.c
 322                 lib/extension-deflate-frame.c
 323                 lib/extension-deflate-stream.c
 324                 )
 325 endif()
 326
 327 # Add helper files for Windows.
 328 if (WIN32)
 329         set(WIN32_HELPERS_PATH win32port/win32helpers)
 330         include_directories(${WIN32_HELPERS_PATH})
 331 else(WIN32)
 332         # Unix.
 333         if (NOT LWS_WITHOUT_DAEMONIZE)
 334                 list(APPEND SOURCES
 335                         lib/daemonize.c
 336                         )
 337         endif()
 338 endif(WIN32)
 339
 340 if (UNIX)
 341         if (NOT HAVE_GETIFADDRS)
 342                 list(APPEND HDR_PRIVATE lib/getifaddrs.h)
 343                 list(APPEND SOURCES lib/getifaddrs.c)
 344         endif()
 345 endif(UNIX)
 346
 347
 348 if (CMAKE_COMPILER_IS_GNUCC OR CMAKE_COMPILER_IS_GNUCXX)
 349     if (UNIX)
 350         set( CMAKE_C_FLAGS "-Wall -Werror -O4 -fvisibility=hidden ${CMAKE_C_FLAGS}" )
 351     else(UNIX)
 352         set( CMAKE_C_FLAGS "-Wall -O4 -fvisibility=hidden ${CMAKE_C_FLAGS}" )
 353     endif(UNIX)
 354 endif ()
 355
 356 source_group("Headers Private"  FILES ${HDR_PRIVATE})
 357 source_group("Headers Public"   FILES ${HDR_PUBLIC})
 358 source_group("Sources"          FILES ${SOURCES})
 359
 360 #
 361 # Create the lib.
 362 #
 363 add_library(websockets STATIC
 364                         ${HDR_PRIVATE}
 365                         ${HDR_PUBLIC}
 366                         ${SOURCES})
 367 add_library(websockets_shared SHARED
 368                         ${HDR_PRIVATE}
 369                         ${HDR_PUBLIC}
 370                         ${SOURCES})
 371
 372 if (WIN32)
 373         # On Windows libs have the same file ending (.lib)
 374         # for both static and shared libraries, so we
 375         # need a unique name for the static one.
 376         set_target_properties(websockets
 377                 PROPERTIES
 378                 OUTPUT_NAME websockets_static)
 379
 380         # Compile as DLL (export function declarations)
 381         set_property(
 382                 TARGET websockets_shared
 383                 PROPERTY COMPILE_DEFINITIONS
 384                 LWS_DLL
 385                 LWS_INTERNAL
 386                 )
 387 endif(WIN32)
 388
 389 # We want the shared lib to be named "libwebsockets"
 390 # not "libwebsocket_shared".
 391 set_target_properties(websockets_shared
 392                 PROPERTIES
 393                 OUTPUT_NAME websockets)
 394
 395 # Set the so version of the lib.
 396 # Equivalent to LDFLAGS=-version-info x:x:x
 397 if(CMAKE_COMPILER_IS_GNUCC OR CMAKE_COMPILER_IS_GNUCXX)
 398         foreach(lib websockets websockets_shared)
 399                 set_target_properties(${lib}
 400                         PROPERTIES
 401                         SOVERSION ${SOVERSION})
 402         endforeach()
 403 endif()
 404
 405 set(LIB_LIST)
 406
 407 #
 408 # Find libraries.
 409 #
 410
 411 #
 412 # ZLIB (Only needed for deflate extensions).
 413 #
 414 if (NOT LWS_WITHOUT_EXTENSIONS)
 415         if (WIN32 AND NOT LWS_USE_EXTERNAL_ZLIB)
 416                 message("Using included Zlib version")
 417
 418                 # Compile ZLib if needed.
 419                 set(WIN32_ZLIB_PATH "win32port/zlib")
 420                 set(ZLIB_SRCS
 421                         ${WIN32_ZLIB_PATH}/adler32.c
 422                         ${WIN32_ZLIB_PATH}/compress.c
 423                         ${WIN32_ZLIB_PATH}/crc32.c
 424                         ${WIN32_ZLIB_PATH}/deflate.c
 425                         ${WIN32_ZLIB_PATH}/gzclose.c
 426                         ${WIN32_ZLIB_PATH}/gzio.c
 427                         ${WIN32_ZLIB_PATH}/gzlib.c
 428                         ${WIN32_ZLIB_PATH}/gzread.c
 429                         ${WIN32_ZLIB_PATH}/gzwrite.c
 430                         ${WIN32_ZLIB_PATH}/infback.c
 431                         ${WIN32_ZLIB_PATH}/inffast.c
 432                         ${WIN32_ZLIB_PATH}/inflate.c
 433                         ${WIN32_ZLIB_PATH}/inftrees.c
 434                         ${WIN32_ZLIB_PATH}/trees.c
 435                         ${WIN32_ZLIB_PATH}/uncompr.c
 436                         ${WIN32_ZLIB_PATH}/zutil.c
 437                 )
 438
 439                 # Create the library.
 440                 add_library(ZLIB STATIC ${ZLIB_SRCS})
 441
 442                 # Set the same variables as find_package would.
 443                 set(ZLIB_INCLUDE_DIRS ${WIN32_ZLIB_PATH})
 444                 get_property(ZLIB_LIBRARIES TARGET ZLIB PROPERTY LOCATION)
 445                 set(ZLIB_FOUND 1)
 446         else()
 447                 find_package(ZLIB REQUIRED)
 448         endif()
 449
 450         # Make sure ZLib is compiled before the libs.
 451         foreach (lib websockets websockets_shared)
 452                 add_dependencies(${lib} ZLIB)
 453         endforeach()
 454
 455         message("ZLib include dirs: ${ZLIB_INCLUDE_DIRS}")
 456         message("ZLib libraries: ${ZLIB_LIBRARIES}")
 457         include_directories(${ZLIB_INCLUDE_DIRS})
 458         list(APPEND LIB_LIST ${ZLIB_LIBRARIES})
 459 endif(NOT LWS_WITHOUT_EXTENSIONS)
 460
 461 #
 462 # OpenSSL
 463 #
 464 if (LWS_WITH_SSL)
 465         message("Compiling with SSL support")
 466
 467         if (LWS_USE_CYASSL)
 468                 # Use CyaSSL as OpenSSL replacement.
 469                 # TODO: Add a find_package command for this also.
 470                 message("CyaSSL include dir: ${LWS_CYASSL_INCLUDE_DIRS}")
 471                 message("CyaSSL libraries: ${LWS_CYASSL_LIB}")
 472
 473                 # Additional to the root directory we need to include
 474                 # the cyassl/ subdirectory which contains the OpenSSL
 475                 # compatability layer headers.
 476                 foreach(inc ${LWS_CYASSL_INCLUDE_DIRS})
 477                         include_directories("${inc}" "${inc}/cyassl")
 478                 endforeach()
 479
 480                 list(APPEND LIB_LIST "${LWS_CYASSL_LIB}")
 481         else()
 482                 # TODO: Add support for STATIC also.
 483                 find_package(OpenSSL REQUIRED)
 484
 485                 message("OpenSSL include dir: ${OPENSSL_INCLUDE_DIR}")
 486                 message("OpenSSL libraries: ${OPENSSL_LIBRARIES}")
 487
 488                 include_directories("${OPENSSL_INCLUDE_DIR}")
 489                 list(APPEND LIB_LIST ${OPENSSL_LIBRARIES})
 490
 491                 # Link against dynamic linking functions.
 492                 # (Don't link directly to libdl since it is not needed on all platforms, it's now a part of libc).
 493                 list(APPEND LIB_LIST ${CMAKE_DL_LIBS})
 494         endif()
 495 endif(LWS_WITH_SSL)
 496
 497 if (LWS_WITH_LIBEV)
 498         list(APPEND LIB_LIST "ev")
 499 endif(LWS_WITH_LIBEV)
 500
 501 #
 502 # Platform specific libs.
 503 #
 504 if (WINCE)
 505         list(APPEND LIB_LIST ws2.lib)
 506 elseif (WIN32)
 507         list(APPEND LIB_LIST ws2_32.lib)
 508 endif()
 509
 510 if (UNIX)
 511         list(APPEND LIB_LIST m)
 512 endif()
 513
 514 # Setup the linking for all libs.
 515 foreach (lib websockets websockets_shared)
 516         target_link_libraries(${lib} ${LIB_LIST})
 517 endforeach()
 518
 519 #
 520 # Test applications
 521 #
 522 set(TEST_APP_LIST)
 523 if (NOT LWS_WITHOUT_TESTAPPS)
 524         #
 525         # Helper function for adding a test app.
 526         #
 527         macro(create_test_app TEST_NAME MAIN_SRC)
 528
 529                 set(TEST_SRCS ${MAIN_SRC})
 530                 set(TEST_HDR)
 531
 532                 if (WIN32)
 533                         list(APPEND TEST_SRCS
 534                                 ${WIN32_HELPERS_PATH}/getopt.c
 535                                 ${WIN32_HELPERS_PATH}/getopt_long.c
 536                                 ${WIN32_HELPERS_PATH}/gettimeofday.c
 537                         )
 538
 539                         list(APPEND TEST_HDR
 540                                 ${WIN32_HELPERS_PATH}/getopt.h
 541                                 ${WIN32_HELPERS_PATH}/gettimeofday.h
 542                         )
 543                 endif(WIN32)
 544
 545                 source_group("Headers Private"   FILES ${TEST_HDR})
 546                 source_group("Sources"   FILES ${TEST_SRCS})
 547                 add_executable(${TEST_NAME} ${TEST_SRCS} ${TEST_HDR})
 548
 549                 if (LWS_LINK_TESTAPPS_DYNAMIC)
 550                         target_link_libraries(${TEST_NAME} websockets_shared)
 551                         add_dependencies(${TEST_NAME} websockets_shared)
 552                 else(LWS_LINK_TESTAPPS_DYNAMIC)
 553                         target_link_libraries(${TEST_NAME} websockets)
 554                         add_dependencies(${TEST_NAME} websockets)
 555                 endif(LWS_LINK_TESTAPPS_DYNAMIC)
 556
 557                 # Set test app specific defines.
 558                 set_property(TARGET ${TEST_NAME}
 559                                         PROPERTY COMPILE_DEFINITIONS
 560                                                 INSTALL_DATADIR="${CMAKE_INSTALL_PREFIX}/share"
 561                                         )
 562
 563                 # Prefix the binary names with libwebsockets.
 564                 set_target_properties(${TEST_NAME}
 565                         PROPERTIES
 566                         OUTPUT_NAME libwebsockets-${TEST_NAME})
 567
 568                 # Add to the list of tests.
 569                 list(APPEND TEST_APP_LIST ${TEST_NAME})
 570         endmacro()
 571
 572         if (LWS_WITH_SSL AND NOT LWS_USE_CYASSL)
 573                 message("Searching for OpenSSL executable and dlls")
 574                 find_package(OpenSSLbins)
 575                 message("OpenSSL executable: ${OPENSSL_EXECUTABLE}")
 576         endif()
 577
 578         if (NOT LWS_WITHOUT_SERVER)
 579                 #
 580                 # test-server
 581                 #
 582                 if (NOT LWS_WITHOUT_TEST_SERVER)
 583                         create_test_app(test-server "test-server/test-server.c")
 584                 endif()
 585
 586                 #
 587                 # test-server-extpoll
 588                 #
 589                 if (NOT LWS_WITHOUT_TEST_SERVER_EXTPOLL)
 590                         create_test_app(test-server-extpoll "test-server/test-server.c")
 591                         # Set defines for this executable only.
 592                         set_property(
 593                                 TARGET test-server-extpoll
 594                                 PROPERTY COMPILE_DEFINITIONS
 595                                         EXTERNAL_POLL
 596                                         INSTALL_DATADIR="${CMAKE_INSTALL_PREFIX}/share"
 597                                 )
 598
 599                         # We need to link against winsock code.
 600                         if (WIN32)
 601                                 target_link_libraries(test-server-extpoll ws2_32.lib)
 602                         endif(WIN32)
 603                 endif()
 604
 605                 # Data files for running the test server.
 606                 set(TEST_SERVER_DATA
 607                         "${PROJECT_SOURCE_DIR}/test-server/favicon.ico"
 608                         "${PROJECT_SOURCE_DIR}/test-server/leaf.jpg"
 609                         "${PROJECT_SOURCE_DIR}/test-server/libwebsockets.org-logo.png"
 610                         "${PROJECT_SOURCE_DIR}/test-server/test.html")
 611
 612                 # Generate self-signed SSL certs for the test-server.
 613                 if (LWS_WITH_SSL AND OPENSSL_EXECUTABLE AND NOT LWS_WITHOUT_TEST_SERVER)
 614                         message("Generating SSL Certificates for the test-server...")
 615
 616                         set(TEST_SERVER_SSL_KEY "${PROJECT_BINARY_DIR}/libwebsockets-test-server.key.pem")
 617                         set(TEST_SERVER_SSL_CERT "${PROJECT_BINARY_DIR}/libwebsockets-test-server.pem")
 618
 619                         if (WIN32)
 620                                 file(WRITE "${PROJECT_BINARY_DIR}/openssl_input.txt"
 621                                         "GB\n"
 622                                         "Erewhon\n"
 623                                         "All around\n"
 624                                         "libwebsockets-test\n"
 625                                         "localhost\n"
 626                                         "none@invalid.org\n\n"
 627                                         )
 628
 629                                 # The "type" command is a bit picky with paths.
 630                                 file(TO_NATIVE_PATH "${PROJECT_BINARY_DIR}/openssl_input.txt" OPENSSL_INPUT_WIN_PATH)
 631                                 message("OPENSSL_INPUT_WIN_PATH = ${OPENSSL_INPUT_WIN_PATH}")
 632                                 message("cmd = \"${OPENSSL_EXECUTABLE}\" req -new -newkey rsa:1024 -days 10000 -nodes -x509 -keyout \"${TEST_SERVER_SSL_KEY}\" -out \"${TEST_SERVER_SSL_CERT}\"")
 633
 634                                 execute_process(
 635                                         COMMAND cmd /c type "${OPENSSL_INPUT_WIN_PATH}"
 636                                         COMMAND "${OPENSSL_EXECUTABLE}" req -new -newkey rsa:1024 -days 10000 -nodes -x509 -keyout "${TEST_SERVER_SSL_KEY}" -out "${TEST_SERVER_SSL_CERT}"
 637                                         RESULT_VARIABLE OPENSSL_RETURN_CODE)
 638
 639                                 message("\n")
 640
 641                                 if (OPENSSL_RETURN_CODE)
 642                                         message(WARNING "!!! Failed to generate SSL certificate for Test Server using cmd.exe !!!:\nOpenSSL return code = ${OPENSSL_RETURN_CODE}")
 643                                 else()
 644                                         message("SUCCSESFULLY generated SSL certificate")
 645                                 endif()
 646                         else()
 647                                 # Unix.
 648                                 execute_process(
 649                                         COMMAND printf "GB\\nErewhon\\nAll around\\nlibwebsockets-test\\n\\nlocalhost\\nnone@invalid.org\\n"
 650                                         COMMAND "${OPENSSL_EXECUTABLE}"
 651                                                 req -new -newkey rsa:1024 -days 10000 -nodes -x509 -keyout "${TEST_SERVER_SSL_KEY}" -out "${TEST_SERVER_SSL_CERT}"
 652                                         RESULT_VARIABLE OPENSSL_RETURN_CODE)
 653
 654                                 if (OPENSSL_RETURN_CODE)
 655                                         message(WARNING "!!! Failed to generate SSL certificate for Test Server!!!:\nOpenSSL return code = ${OPENSSL_RETURN_CODE}")
 656                                 else()
 657                                         message("SUCCSESFULLY generated SSL certificate")
 658                                 endif()
 659                         endif()
 660
 661                         list(APPEND TEST_SERVER_DATA
 662                                 "${TEST_SERVER_SSL_KEY}"
 663                                 "${TEST_SERVER_SSL_CERT}")
 664                 endif()
 665
 666                 add_custom_command(TARGET test-server
 667                                                 POST_BUILD
 668                                                 COMMAND "${CMAKE_COMMAND}" -E make_directory "$<TARGET_FILE_DIR:test-server>/../share/libwebsockets-test-server")
 669
 670                 # Copy the file needed to run the server so that the test apps can
 671                 # reach them from their default output location
 672                 foreach (TEST_FILE ${TEST_SERVER_DATA})
 673                         if (EXISTS ${TEST_FILE})
 674                                 add_custom_command(TARGET test-server
 675                                                         POST_BUILD
 676                                                         COMMAND "${CMAKE_COMMAND}" -E copy "${TEST_FILE}" "$<TARGET_FILE_DIR:test-server>/../share/libwebsockets-test-server" VERBATIM)
 677                         endif()
 678                 endforeach()
 679         endif(NOT LWS_WITHOUT_SERVER)
 680
 681         if (NOT LWS_WITHOUT_CLIENT)
 682                 #
 683                 # test-client
 684                 #
 685                 if (NOT LWS_WITHOUT_TEST_CLIENT)
 686                         create_test_app(test-client "test-server/test-client.c")
 687                 endif()
 688
 689                 #
 690                 # test-fraggle
 691                 #
 692                 if (NOT LWS_WITHOUT_TEST_FRAGGLE)
 693                         create_test_app(test-fraggle "test-server/test-fraggle.c")
 694                 endif()
 695
 696                 #
 697                 # test-ping
 698                 #
 699                 if (NOT LWS_WITHOUT_TEST_PING)
 700                         create_test_app(test-ping "test-server/test-ping.c")
 701                 endif()
 702                 #
 703                 # test-echo
 704                 #
 705                 if (NOT WITHOUT_TEST_ECHO)
 706                         create_test_app(test-echo "test-server/test-echo.c")
 707                 endif()
 708
 709         endif(NOT LWS_WITHOUT_CLIENT)
 710
 711         #
 712         # Copy OpenSSL dlls to the output directory on Windows.
 713         # (Otherwise we'll get an error when trying to run)
 714         #
 715         if (WIN32 AND LWS_WITH_SSL AND NOT LWS_USE_CYASSL)
 716                 if(OPENSSL_BIN_FOUND)
 717                         message("OpenSSL dlls found:")
 718                         message("  Libeay: ${LIBEAY_BIN}")
 719                         message("  SSLeay: ${SSLEAY_BIN}")
 720
 721                         foreach(TARGET_BIN ${TEST_APP_LIST})
 722                                 add_custom_command(TARGET ${TARGET_BIN}
 723                                         POST_BUILD
 724                                         COMMAND "${CMAKE_COMMAND}" -E copy "${LIBEAY_BIN}" "$<TARGET_FILE_DIR:${TARGET_BIN}>" VERBATIM)
 725
 726                                 add_custom_command(TARGET ${TARGET_BIN}
 727                                         POST_BUILD
 728                                         COMMAND "${CMAKE_COMMAND}" -E copy "${SSLEAY_BIN}" "$<TARGET_FILE_DIR:${TARGET_BIN}>" VERBATIM)
 729                         endforeach()
 730                 endif()
 731         endif()
 732 endif(NOT LWS_WITHOUT_TESTAPPS)
 733
 734 if (UNIX)
 735         # Generate documentation.
 736         # TODO: Fix this on Windows.
 737         message("Generating API documentation")
 738         file(GLOB C_FILES "${PROJECT_SOURCE_DIR}/lib/*.c")
 739         execute_process(COMMAND "${CMAKE_COMMAND}" -E make_directory "${PROJECT_BINARY_DIR}/doc/")
 740
 741         execute_process(
 742                 COMMAND "${PROJECT_SOURCE_DIR}/scripts/kernel-doc" -html ${C_FILES} ${HDR_PUBLIC}
 743                 OUTPUT_FILE "${PROJECT_BINARY_DIR}/doc/libwebsockets-api-doc.html"
 744                 ERROR_QUIET)
 745
 746         execute_process(
 747                 COMMAND "${PROJECT_SOURCE_DIR}/scripts/kernel-doc" -text ${C_FILES} ${HDR_PUBLIC}
 748                 OUTPUT_FILE "${PROJECT_BINARY_DIR}/doc/libwebsockets-api-doc.txt"
 749                 ERROR_QUIET)
 750
 751 # Generate and install pkgconfig.
 752 # (This is not indented, because the tabs will be part of the output)
 753 file(WRITE "${PROJECT_BINARY_DIR}/libwebsockets.pc"
 754 "prefix=\"${CMAKE_INSTALL_PREFIX}\"
 755 exec_prefix=\${prefix}
 756 libdir=\${exec_prefix}/lib${LIB_SUFFIX}
 757 includedir=\${prefix}/include
 758
 759 Name: libwebsockets
 760 Description: Websockets server and client library
 761 Version: ${CPACK_PACKAGE_VERSION_MAJOR}.${CPACK_PACKAGE_VERSION_MINOR}
 762
 763 Libs: -L\${libdir} -lwebsockets
 764 Cflags: -I\${includedir}"
 765 )
 766
 767         install(FILES "${PROJECT_BINARY_DIR}/libwebsockets.pc"
 768                 DESTINATION lib${LIB_SUFFIX}/pkgconfig)
 769 endif(UNIX)
 770
 771 #
 772 # Installation preparations.
 773 #
 774
 775 if(WIN32 AND NOT CYGWIN)
 776   set(DEF_INSTALL_CMAKE_DIR cmake)
 777 else()
 778   set(DEF_INSTALL_CMAKE_DIR lib/cmake/libwebsockets)
 779 endif()
 780
 781 set(LWS_INSTALL_CMAKE_DIR ${DEF_INSTALL_CMAKE_DIR} CACHE PATH "Installation directory for CMake files")
 782
 783 # Export targets (This is used for other CMake projects to easily find the libraries and include files).
 784 export(TARGETS websockets websockets_shared
 785         FILE "${PROJECT_BINARY_DIR}/LibwebsocketsTargets.cmake")
 786 export(PACKAGE libwebsockets)
 787
 788 # Generate the config file for the build-tree.
 789 set(LWS__INCLUDE_DIRS
 790     "${PROJECT_SOURCE_DIR}/lib"
 791     "${PROJECT_BINARY_DIR}")
 792 set(LIBWEBSOCKETS_INCLUDE_DIRS ${LWS__INCLUDE_DIRS} CACHE PATH "Libwebsockets include directories")
 793 configure_file(${PROJECT_SOURCE_DIR}/cmake/LibwebsocketsConfig.cmake.in
 794                 ${PROJECT_BINARY_DIR}/LibwebsocketsConfig.cmake
 795                 @ONLY)
 796
 797 # Generate the config file for the installation tree.
 798 get_filename_component(LWS_ABSOLUTE_INSTALL_CMAKE_DIR ${LWS_INSTALL_CMAKE_DIR} ABSOLUTE)
 799 get_filename_component(LWS_ABSOLUTE_INSTALL_INCLUDE_DIR ${LWS_INSTALL_INCLUDE_DIR} ABSOLUTE)
 800 file(RELATIVE_PATH
 801     REL_INCLUDE_DIR
 802     "${LWS_ABSOLUTE_INSTALL_CMAKE_DIR}"
 803     "${LWS_ABSOLUTE_INSTALL_INCLUDE_DIR}") # Calculate the relative directory from the cmake dir.
 804
 805 # Note the EVENT_CMAKE_DIR is defined in JanssonConfig.cmake.in,
 806 # we escape it here so it's evaluated when it is included instead
 807 # so that the include dirs are given relative to where the
 808 # config file is located.
 809 set(LWS__INCLUDE_DIRS
 810     "\${LWS_CMAKE_DIR}/${REL_INCLUDE_DIR}")
 811 configure_file(${PROJECT_SOURCE_DIR}/cmake/LibwebsocketsConfig.cmake.in
 812                 ${PROJECT_BINARY_DIR}${CMAKE_FILES_DIRECTORY}/LibwebsocketsConfig.cmake
 813                 @ONLY)
 814
 815 # Generate version info for both build-tree and install-tree.
 816 configure_file(${PROJECT_SOURCE_DIR}/cmake/LibwebsocketsConfigVersion.cmake.in
 817                 ${PROJECT_BINARY_DIR}/LibwebsocketsConfigVersion.cmake
 818                 @ONLY)
 819
 820 set_target_properties(websockets websockets_shared
 821                                         PROPERTIES PUBLIC_HEADER "${HDR_PUBLIC}")
 822
 823 #
 824 # Installation.
 825 #
 826
 827 # Install libs and headers.
 828 install(TARGETS websockets websockets_shared
 829                 EXPORT LibwebsocketsTargets
 830                 LIBRARY DESTINATION "${LWS_INSTALL_LIB_DIR}${LIB_SUFFIX}" COMPONENT libraries
 831                 ARCHIVE DESTINATION "${LWS_INSTALL_LIB_DIR}${LIB_SUFFIX}" COMPONENT libraries
 832                 RUNTIME DESTINATION "${LWS_INSTALL_BIN_DIR}" COMPONENT libraries # Windows DLLs
 833                 PUBLIC_HEADER DESTINATION "${LWS_INSTALL_INCLUDE_DIR}" COMPONENT dev)
 834 set(CPACK_COMPONENT_LIBRARIES_DISPLAY_NAME "Libraries")
 835 set(CPACK_COMPONENT_DEV_DISPLAY_NAME "Development files")
 836
 837 # Install test apps.
 838 if (NOT LWS_WITHOUT_TESTAPPS AND NOT LWS_WITHOUT_CLIENT)
 839         install(TARGETS test-client ${TEST_APP_LIST}
 840                         RUNTIME DESTINATION ${LWS_INSTALL_EXAMPLES_DIR}
 841                         COMPONENT examples)
 842         set(CPACK_COMPONENT_EXAMPLES_DISPLAY_NAME "Example files")
 843 endif()
 844
 845 # Programs shared files used by the test-server.
 846 if (NOT LWS_WITHOUT_TESTAPPS AND NOT LWS_WITHOUT_SERVER)
 847         install(FILES ${TEST_SERVER_DATA}
 848                         DESTINATION share/libwebsockets-test-server
 849                         COMPONENT examples)
 850 endif()
 851
 852 # Install exports for the install-tree.
 853 install(EXPORT LibwebsocketsTargets
 854                 DESTINATION "${LWS_INSTALL_CMAKE_DIR}" COMPONENT dev)
 855
 856 # build subdir is not part of sources
 857 set(CPACK_SOURCE_IGNORE_FILES $(CPACK_SOURCE_IGNORE_FILES) ".git" "build" "tgz" "tar.gz")
 858
 859 # Most people are more used to "make dist" compared to "make package_source"
 860 add_custom_target(dist COMMAND "${CMAKE_MAKE_PROGRAM}" package_source)
 861
 862 include(UseRPMTools)
 863 if (RPMTools_FOUND)
 864         RPMTools_ADD_RPM_TARGETS(libwebsockets libwebsockets.spec)
 865 endif()
 866
 867 message("---------------------------------------------------------------------")
 868 message("  Settings:  (For more help do cmake -LH <srcpath>")
 869 message("---------------------------------------------------------------------")
 870 message(" LWS_WITH_SSL = ${LWS_WITH_SSL}  (SSL Support)")
 871 message(" LWS_SSL_CLIENT_USE_OS_CA_CERTS = ${LWS_SSL_CLIENT_USE_OS_CA_CERTS}")
 872 message(" LWS_USE_CYASSL = ${LWS_USE_CYASSL} (CyaSSL replacement for OpenSSL)")
 873 if (LWS_USE_CYASSL)
 874         message("   LWS_CYASSL_LIB = ${LWS_CYASSL_LIB}")
 875         message("   LWS_CYASSL_INCLUDE_DIRS = ${LWS_CYASSL_INCLUDE_DIRS}")
 876 endif()
 877 message(" LWS_WITHOUT_BUILTIN_GETIFADDRS = ${LWS_WITHOUT_BUILTIN_GETIFADDRS}")
 878 message(" LWS_WITHOUT_CLIENT = ${LWS_WITHOUT_CLIENT}")
 879 message(" LWS_WITHOUT_SERVER = ${LWS_WITHOUT_SERVER}")
 880 message(" LWS_LINK_TESTAPPS_DYNAMIC = ${LWS_LINK_TESTAPPS_DYNAMIC}")
 881 message(" LWS_WITHOUT_TESTAPPS = ${LWS_WITHOUT_TESTAPPS}")
 882 message(" LWS_WITHOUT_TEST_SERVER = ${LWS_WITHOUT_TEST_SERVER}")
 883 message(" LWS_WITHOUT_TEST_SERVER_EXTPOLL = ${LWS_WITHOUT_TEST_SERVER_EXTPOLL}")
 884 message(" LWS_WITHOUT_TEST_PING = ${LWS_WITHOUT_TEST_PING}")
 885 message(" LWS_WITHOUT_TEST_CLIENT = ${LWS_WITHOUT_TEST_CLIENT}")
 886 message(" LWS_WITHOUT_TEST_FRAGGLE = ${LWS_WITHOUT_TEST_FRAGGLE}")
 887 message(" LWS_WITHOUT_DEBUG = ${LWS_WITHOUT_DEBUG}")
 888 message(" LWS_WITHOUT_EXTENSIONS = ${LWS_WITHOUT_EXTENSIONS}")
 889 message(" LWS_WITH_LATENCY = ${LWS_WITH_LATENCY}")
 890 message(" LWS_WITHOUT_DAEMONIZE = ${LWS_WITHOUT_DAEMONIZE}")
 891 message(" LWS_USE_LIBEV = ${LWS_USE_LIBEV}")
 892 message(" LWS_IPV6 = ${LWS_IPV6}")
 893 message(" LWS_WITH_HTTP2 = ${LWS_WITH_HTTP2}")
 894 message("---------------------------------------------------------------------")
 895
 896 # These will be available to parent projects including libwebsockets using add_subdirectory()
 897 set(LIBWEBSOCKETS_LIBRARIES websocket websockets_shared CACHE STRING "Libwebsocket libraries")
 898 set(LIBWEBSOCKETS_LIBRARIES_STATIC websocket CACHE STRING "Libwebsocket static library")
 899 set(LIBWEBSOCKETS_LIBRARIES_SHARED websockets_shared CACHE STRING "Libwebsocket shared library")
 900
 901 # This must always be last!
 902 include(CPack)