CMakeLists.txt

   1 cmake_minimum_required(VERSION 2.6)
   2
   3 project(libwebsockets)
   4
   5 set(PACKAGE "libwebsockets")
   6 set(CPACK_PACKAGE_NAME "${PACKAGE}")
   7 set(CPACK_PACKAGE_VERSION_MAJOR "1")
   8 set(CPACK_PACKAGE_VERSION_MINOR "3")
   9 set(CPACK_PACKAGE_VERSION "${CPACK_PACKAGE_VERSION_MAJOR}.${CPACK_PACKAGE_VERSION_MINOR}")
  10 set(CPACK_PACKAGE_VENDOR "andy@warmcat.com")
  11 set(CPACK_PACKAGE_DESCRIPTION_SUMMARY "${PACKAGE} ${PACKAGE_VERSION}")
  12 set(SOVERSION "4.0.0")
  13 set(CPACK_SOURCE_GENERATOR "TGZ")
  14 set(CPACK_SOURCE_PACKAGE_FILE_NAME "${CPACK_PACKAGE_NAME}-${CPACK_PACKAGE_VERSION}")
  15 set(VERSION "${CPACK_PACKAGE_VERSION}")
  16
  17 set(LWS_LIBRARY_VERSION ${CPACK_PACKAGE_VERSION})
  18 set(CMAKE_MODULE_PATH ${CMAKE_MODULE_PATH} "${PROJECT_SOURCE_DIR}/cmake/")
  19
  20 message(STATUS "CMAKE_TOOLCHAIN_FILE='${CMAKE_TOOLCHAIN_FILE}'")
  21
  22 # Try to find the current Git hash.
  23 find_package(Git)
  24 if(GIT_EXECUTABLE)
  25         execute_process(
  26     WORKING_DIRECTORY "${CMAKE_CURRENT_SOURCE_DIR}"
  27     COMMAND "${GIT_EXECUTABLE}" log -n 1 --pretty=%h
  28     OUTPUT_VARIABLE GIT_HASH
  29     OUTPUT_STRIP_TRAILING_WHITESPACE
  30     )
  31
  32     set(LWS_BUILD_HASH ${GIT_HASH})
  33     message("Git commit hash: ${LWS_BUILD_HASH}")
  34 endif()
  35
  36 option(LWS_WITH_SSL "Include SSL support (default OpenSSL, CyaSSL if LWS_USE_CYASSL is set)" ON)
  37 option(LWS_SSL_CLIENT_USE_OS_CA_CERTS "SSL support should make use of OS installed CA root certs" ON)
  38 option(LWS_USE_EXTERNAL_ZLIB "Search the system for ZLib instead of using the included one (on Windows)" OFF)
  39 option(LWS_USE_CYASSL "Use CyaSSL replacement for OpenSSL. When settings this, you also need to specify LWS_CYASSL_LIB and LWS_CYASSL_INCLUDE_DIRS" OFF)
  40 option(LWS_WITHOUT_BUILTIN_GETIFADDRS "Don't use BSD getifaddrs implementation from libwebsockets if it is missing (this will result in a compilation error) ... Default is your libc provides it. On some systems such as uclibc it doesn't exist." OFF)
  41 option(LWS_WITHOUT_CLIENT "Don't build the client part of the library" OFF)
  42 option(LWS_WITHOUT_SERVER "Don't build the server part of the library" OFF)
  43 #option(LWS_WITH_LIBCRYPTO "Use libcrypto MD5 and SHA1 implementations" ON)
  44 option(LWS_LINK_TESTAPPS_DYNAMIC "Link the test apps to the shared version of the library. Default is to link statically" OFF)
  45 option(LWS_WITHOUT_TESTAPPS "Don't build the libwebsocket-test-apps" OFF)
  46 option(LWS_WITHOUT_TEST_SERVER "Don't build the test server" OFF)
  47 option(LWS_WITHOUT_TEST_SERVER_EXTPOLL "Don't build the test server version that uses external poll" OFF)
  48 option(LWS_WITHOUT_TEST_PING "Don't build the ping test application" OFF)
  49 option(LWS_WITHOUT_TEST_CLIENT "Don't build the client test application" OFF)
  50 option(LWS_WITHOUT_TEST_FRAGGLE "Don't build the ping test application" OFF)
  51 option(LWS_WITHOUT_DEBUG "Don't compile debug related code" OFF)
  52 option(LWS_WITHOUT_EXTENSIONS "Don't compile with extensions" OFF)
  53 option(LWS_WITH_LATENCY "Build latency measuring code into the library" OFF)
  54 option(LWS_WITHOUT_DAEMONIZE "Don't build the daemonization api" OFF)
  55
  56 # Allow the user to override installation directories.
  57 set(LWS_INSTALL_LIB_DIR       lib CACHE PATH "Installation directory for libraries")
  58 set(LWS_INSTALL_BIN_DIR       bin CACHE PATH "Installation directory for executables")
  59 set(LWS_INSTALL_INCLUDE_DIR   include CACHE PATH "Installation directory for header files")
  60 set(LWS_INSTALL_EXAMPLES_DIR  bin CACHE PATH "Installation directory for example files")
  61
  62 if (LWS_WITHOUT_CLIENT AND LWS_WITHOUT_SERVER)
  63         message(FATAL_ERROR "Makes no sense to compile without both client or server.")
  64 endif()
  65
  66 # The base dir where the test-apps look for the SSL certs.
  67 set(LWS_OPENSSL_CLIENT_CERTS ../share CACHE PATH "Server SSL certificate directory")
  68 if (WIN32)
  69         set(LWS_OPENSSL_CLIENT_CERTS . CACHE PATH "Client SSL certificate directory")
  70 else()
  71         set(LWS_OPENSSL_CLIENT_CERTS /etc/pki/tls/certs/ CACHE PATH "Client SSL certificate directory")
  72 endif()
  73
  74 set(LWS_CYASSL_LIB CACHE PATH "Path to the CyaSSL library")
  75 set(LWS_CYASSL_INCLUDE_DIRS CACHE PATH "Path to the CyaSSL include directory")
  76
  77 if (LWS_USE_CYASSL)
  78         if ("${LWS_CYASSL_LIB}" STREQUAL "" OR "${LWS_CYASSL_INCLUDE_DIRS}" STREQUAL "")
  79                 message(FATAL_ERROR "You must set LWS_CYASSL_LIB and LWS_CYASSL_INCLUDE_DIRS when LWS_USE_CYASSL is turned on")
  80         endif()
  81         set(USE_CYASSL 1)
  82 endif()
  83
  84 if (LWS_WITHOUT_EXTENSIONS)
  85         set(LWS_NO_EXTENSIONS 1)
  86 endif()
  87
  88 if (LWS_WITH_SSL)
  89         set(LWS_OPENSSL_SUPPORT 1)
  90 endif()
  91
  92 if (LWS_SSL_CLIENT_USE_OS_CA_CERTS)
  93         set(LWS_SSL_CLIENT_USE_OS_CA_CERTS 1)
  94 endif()
  95
  96 if (LWS_WITH_LATENCY)
  97         set(LWS_LATENCY 1)
  98 endif()
  99
 100 if (LWS_WITHOUT_DAEMONIZE OR WIN32)
 101         set(LWS_NO_DAEMONIZE 1)
 102 endif()
 103
 104 if (LWS_WITHOUT_SERVER)
 105         set(LWS_NO_SERVER 1)
 106 endif()
 107
 108 if (LWS_WITHOUT_CLIENT)
 109         set(LWS_NO_CLIENT 1)
 110 endif()
 111
 112 if (LWS_WITHOUT_DEBUG)
 113         set(_DEBUG 0)
 114 else()
 115         set(_DEBUG 1)
 116 endif()
 117
 118 if (MINGW)
 119         set(LWS_MINGW_SUPPORT 1)
 120 endif()
 121
 122 include_directories("${PROJECT_BINARY_DIR}")
 123
 124 include(CheckCSourceCompiles)
 125
 126 # Check for different inline keyword versions.
 127 foreach(KEYWORD "inline" "__inline__" "__inline")
 128         set(CMAKE_REQUIRED_DEFINITIONS "-DKEYWORD=${KEYWORD}")
 129         CHECK_C_SOURCE_COMPILES(
 130                 "
 131                 #include <stdio.h>
 132                 KEYWORD void a() {}
 133                 int main(int argc, char **argv) { a(); return 0; }
 134                 " HAVE_${KEYWORD})
 135 endforeach()
 136
 137 if (NOT HAVE_inline)
 138         if (HAVE___inline__)
 139                 set(inline __inline__)
 140         elseif(HAVE___inline)
 141                 set(inline __inline)
 142         endif()
 143 endif()
 144
 145 # Put the libaries and binaries that get built into directories at the
 146 # top of the build tree rather than in hard-to-find leaf directories.
 147 SET(CMAKE_RUNTIME_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin")
 148 SET(CMAKE_LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/lib")
 149 SET(CMAKE_ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/lib")
 150
 151 # Put absolute path of dynamic libraries into the object code. Some
 152 # architectures, notably Mac OS X, need this.
 153 SET(CMAKE_INSTALL_NAME_DIR "${CMAKE_INSTALL_PREFIX}/${LWS_INSTALL_LIB_DIR}${LIB_SUFFIX}")
 154
 155 # So we can include the CMake generated config file only when
 156 # building with CMAKE.
 157 add_definitions(-DCMAKE_BUILD)
 158
 159 include(CheckFunctionExists)
 160 include(CheckIncludeFile)
 161 include(CheckIncludeFiles)
 162 include(CheckLibraryExists)
 163 include(CheckTypeSize)
 164
 165 CHECK_FUNCTION_EXISTS(bzero HAVE_BZERO)
 166 CHECK_FUNCTION_EXISTS(fork HAVE_FORK)
 167 CHECK_FUNCTION_EXISTS(getenv HAVE_GETENV)
 168 CHECK_FUNCTION_EXISTS(malloc HAVE_MALLOC)
 169 CHECK_FUNCTION_EXISTS(memset HAVE_MEMSET)
 170 CHECK_FUNCTION_EXISTS(realloc HAVE_REALLOC)
 171 CHECK_FUNCTION_EXISTS(socket HAVE_SOCKET)
 172 CHECK_FUNCTION_EXISTS(strerror HAVE_STRERROR)
 173 CHECK_FUNCTION_EXISTS(vfork HAVE_VFORK)
 174 CHECK_FUNCTION_EXISTS(getifaddrs HAVE_GETIFADDRS)
 175
 176 if (NOT HAVE_GETIFADDRS)
 177         if (LWS_WITHOUT_BUILTIN_GETIFADDRS)
 178                 message(FATAL_ERROR "No getifaddrs was found on the system. Turn off the LWS_WITHOUT_BUILTIN_GETIFADDRS compile option to use the supplied BSD version.")
 179         endif()
 180
 181         set(LWS_BUILTIN_GETIFADDRS 1)
 182 endif()
 183
 184 CHECK_INCLUDE_FILE(dlfcn.h HAVE_DLFCN_H)
 185 CHECK_INCLUDE_FILE(fcntl.h HAVE_FCNTL_H)
 186 CHECK_INCLUDE_FILE(inttypes.h HAVE_INTTYPES_H)
 187 CHECK_INCLUDE_FILE(memory.h HAVE_MEMORY_H)
 188 CHECK_INCLUDE_FILE(netinet/in.h HAVE_NETINET_IN_H)
 189 CHECK_INCLUDE_FILE(stdint.h HAVE_STDINT_H)
 190 CHECK_INCLUDE_FILE(stdlib.h HAVE_STDLIB_H)
 191 CHECK_INCLUDE_FILE(strings.h HAVE_STRINGS_H)
 192 CHECK_INCLUDE_FILE(string.h HAVE_STRING_H)
 193 CHECK_INCLUDE_FILE(sys/prctl.h HAVE_SYS_PRCTL_H)
 194 CHECK_INCLUDE_FILE(sys/socket.h HAVE_SYS_SOCKET_H)
 195 CHECK_INCLUDE_FILE(sys/stat.h HAVE_SYS_STAT_H)
 196 CHECK_INCLUDE_FILE(sys/types.h HAVE_SYS_TYPES_H)
 197 CHECK_INCLUDE_FILE(unistd.h HAVE_UNISTD_H)
 198 CHECK_INCLUDE_FILE(vfork.h HAVE_VFORK_H)
 199 CHECK_INCLUDE_FILE(zlib.h HAVE_ZLIB_H)
 200
 201 # TODO: These can be tested if they actually work also...
 202 set(HAVE_WORKING_FORK HAVE_FORK)
 203 set(HAVE_WORKING_VFORK HAVE_VFORK)
 204
 205 CHECK_INCLUDE_FILES("stdlib.h;stdarg.h;string.h;float.h" STDC_HEADERS)
 206
 207 CHECK_TYPE_SIZE(pid_t PID_T_SIZE)
 208 CHECK_TYPE_SIZE(size_t SIZE_T_SIZE)
 209
 210 if (NOT PID_T_SIZE)
 211         set(pid_t int)
 212 endif()
 213
 214 if (NOT SIZE_T_SIZE)
 215         set(size_t "unsigned int")
 216 endif()
 217
 218 if (NOT HAVE_MALLOC)
 219         set(malloc rpl_malloc)
 220 endif()
 221
 222 if (NOT HAVE_REALLOC)
 223         set(realloc rpl_realloc)
 224 endif()
 225
 226 # Generate the config.h that includes all the compilation settings.
 227 configure_file(
 228        "${PROJECT_SOURCE_DIR}/config.h.cmake"
 229        "${PROJECT_BINARY_DIR}/lws_config.h")
 230
 231 if (MSVC)
 232         # Turn off stupid microsoft security warnings.
 233         add_definitions(-D_CRT_SECURE_NO_DEPRECATE -D_CRT_NONSTDC_NO_DEPRECATE)
 234 endif(MSVC)
 235
 236 include_directories("${PROJECT_SOURCE_DIR}/lib")
 237
 238 # Group headers and sources.
 239 # Some IDEs use this for nicer file structure.
 240 set(HDR_PRIVATE
 241         lib/private-libwebsockets.h
 242         "${PROJECT_BINARY_DIR}/lws_config.h"
 243         )
 244
 245 set(HDR_PUBLIC
 246         "${PROJECT_SOURCE_DIR}/lib/libwebsockets.h"
 247         )
 248
 249 set(SOURCES
 250         lib/base64-decode.c
 251         lib/handshake.c
 252         lib/libwebsockets.c
 253         lib/output.c
 254         lib/parsers.c
 255         lib/sha-1.c
 256         )
 257
 258 if (NOT LWS_WITHOUT_CLIENT)
 259         list(APPEND SOURCES
 260                 lib/client.c
 261                 lib/client-handshake.c
 262                 lib/client-parser.c
 263                 )
 264 endif()
 265
 266 if (NOT LWS_WITHOUT_SERVER)
 267         list(APPEND SOURCES
 268                 lib/server.c
 269                 lib/server-handshake.c
 270                 )
 271 endif()
 272
 273 if (NOT LWS_WITHOUT_EXTENSIONS)
 274         list(APPEND HDR_PRIVATE
 275                 lib/extension-deflate-frame.h
 276                 lib/extension-deflate-stream.h
 277                 )
 278
 279         list(APPEND SOURCES
 280                 lib/extension.c
 281                 lib/extension-deflate-frame.c
 282                 lib/extension-deflate-stream.c
 283                 )
 284 endif()
 285
 286 # Add helper files for Windows.
 287 if (WIN32)
 288         set(WIN32_HELPERS_PATH win32port/win32helpers)
 289
 290         list(APPEND HDR_PUBLIC
 291                 ${WIN32_HELPERS_PATH}/websock-w32.h
 292                 )
 293         if (NOT MINGW)
 294                 list(APPEND SOURCES
 295                         ${WIN32_HELPERS_PATH}/websock-w32.c
 296                         )
 297         endif()
 298         include_directories(${WIN32_HELPERS_PATH})
 299 else(WIN32)
 300         # Unix.
 301         if (NOT LWS_WITHOUT_DAEMONIZE)
 302                 list(APPEND SOURCES
 303                         lib/daemonize.c
 304                         )
 305         endif()
 306 endif(WIN32)
 307
 308 if (UNIX)
 309         if (NOT HAVE_GETIFADDRS)
 310                 list(APPEND HDR_PRIVATE lib/getifaddrs.h)
 311                 list(APPEND SOURCES lib/getifaddrs.c)
 312         endif()
 313 endif(UNIX)
 314
 315
 316 if (CMAKE_COMPILER_IS_GNUCC OR CMAKE_COMPILER_IS_GNUCXX)
 317     if (UNIX)
 318         set( CMAKE_C_FLAGS "-Wall -Werror -O4 -fvisibility=hidden ${CMAKE_C_FLAGS}" )
 319     else(UNIX)
 320         set( CMAKE_C_FLAGS "-Wall -O4 -fvisibility=hidden ${CMAKE_C_FLAGS}" )
 321     endif(UNIX)
 322 endif ()
 323
 324 source_group("Headers Private"  FILES ${HDR_PRIVATE})
 325 source_group("Headers Public"   FILES ${HDR_PUBLIC})
 326 source_group("Sources"          FILES ${SOURCES})
 327
 328 #
 329 # Create the lib.
 330 #
 331 add_library(websockets STATIC
 332                         ${HDR_PRIVATE}
 333                         ${HDR_PUBLIC}
 334                         ${SOURCES})
 335 add_library(websockets_shared SHARED
 336                         ${HDR_PRIVATE}
 337                         ${HDR_PUBLIC}
 338                         ${SOURCES})
 339
 340 if (WIN32)
 341         # On Windows libs have the same file ending (.lib)
 342         # for both static and shared libraries, so we
 343         # need a unique name for the static one.
 344         set_target_properties(websockets
 345                 PROPERTIES
 346                 OUTPUT_NAME websockets_static)
 347
 348         # Compile as DLL (export function declarations)
 349         set_property(
 350                 TARGET websockets_shared
 351                 PROPERTY COMPILE_DEFINITIONS
 352                 LWS_DLL
 353                 LWS_INTERNAL
 354                 )
 355 endif(WIN32)
 356
 357 # We want the shared lib to be named "libwebsockets"
 358 # not "libwebsocket_shared".
 359 set_target_properties(websockets_shared
 360                 PROPERTIES
 361                 OUTPUT_NAME websockets)
 362
 363 # Set the so version of the lib.
 364 # Equivalent to LDFLAGS=-version-info x:x:x
 365 if(CMAKE_COMPILER_IS_GNUCC OR CMAKE_COMPILER_IS_GNUCXX)
 366         foreach(lib websockets websockets_shared)
 367                 set_target_properties(${lib}
 368                         PROPERTIES
 369                         SOVERSION ${SOVERSION})
 370         endforeach()
 371 endif()
 372
 373 set(LIB_LIST)
 374
 375 #
 376 # Find libraries.
 377 #
 378
 379 #
 380 # ZLIB (Only needed for deflate extensions).
 381 #
 382 if (NOT LWS_WITHOUT_EXTENSIONS)
 383         if (WIN32 AND NOT LWS_USE_EXTERNAL_ZLIB)
 384                 message("Using included Zlib version")
 385
 386                 # Compile ZLib if needed.
 387                 set(WIN32_ZLIB_PATH "win32port/zlib")
 388                 set(ZLIB_SRCS
 389                         ${WIN32_ZLIB_PATH}/adler32.c
 390                         ${WIN32_ZLIB_PATH}/compress.c
 391                         ${WIN32_ZLIB_PATH}/crc32.c
 392                         ${WIN32_ZLIB_PATH}/deflate.c
 393                         ${WIN32_ZLIB_PATH}/gzclose.c
 394                         ${WIN32_ZLIB_PATH}/gzio.c
 395                         ${WIN32_ZLIB_PATH}/gzlib.c
 396                         ${WIN32_ZLIB_PATH}/gzread.c
 397                         ${WIN32_ZLIB_PATH}/gzwrite.c
 398                         ${WIN32_ZLIB_PATH}/infback.c
 399                         ${WIN32_ZLIB_PATH}/inffast.c
 400                         ${WIN32_ZLIB_PATH}/inflate.c
 401                         ${WIN32_ZLIB_PATH}/inftrees.c
 402                         ${WIN32_ZLIB_PATH}/trees.c
 403                         ${WIN32_ZLIB_PATH}/uncompr.c
 404                         ${WIN32_ZLIB_PATH}/zutil.c
 405                 )
 406
 407                 # Create the library.
 408                 add_library(ZLIB STATIC ${ZLIB_SRCS})
 409
 410                 # Set the same variables as find_package would.
 411                 set(ZLIB_INCLUDE_DIRS ${WIN32_ZLIB_PATH})
 412                 get_property(ZLIB_LIBRARIES TARGET ZLIB PROPERTY LOCATION)
 413                 set(ZLIB_FOUND 1)
 414         else()
 415                 find_package(ZLIB REQUIRED)
 416         endif()
 417
 418         # Make sure ZLib is compiled before the libs.
 419         foreach (lib websockets websockets_shared)
 420                 add_dependencies(${lib} ZLIB)
 421         endforeach()
 422
 423         message("ZLib include dirs: ${ZLIB_INCLUDE_DIRS}")
 424         message("ZLib libraries: ${ZLIB_LIBRARIES}")
 425         include_directories(${ZLIB_INCLUDE_DIRS})
 426         list(APPEND LIB_LIST ${ZLIB_LIBRARIES})
 427 endif(NOT LWS_WITHOUT_EXTENSIONS)
 428
 429 #
 430 # OpenSSL
 431 #
 432 if (LWS_WITH_SSL)
 433         message("Compiling with SSL support")
 434
 435         if (LWS_USE_CYASSL)
 436                 # Use CyaSSL as OpenSSL replacement.
 437                 # TODO: Add a find_package command for this also.
 438                 message("CyaSSL include dir: ${LWS_CYASSL_INCLUDE_DIRS}")
 439                 message("CyaSSL libraries: ${LWS_CYASSL_LIB}")
 440
 441                 # Additional to the root directory we need to include
 442                 # the cyassl/ subdirectory which contains the OpenSSL
 443                 # compatability layer headers.
 444                 foreach(inc ${LWS_CYASSL_INCLUDE_DIRS})
 445                         include_directories("${inc}" "${inc}/cyassl")
 446                 endforeach()
 447
 448                 list(APPEND LIB_LIST "${LWS_CYASSL_LIB}")
 449         else()
 450                 # TODO: Add support for STATIC also.
 451                 find_package(OpenSSL REQUIRED)
 452
 453                 message("OpenSSL include dir: ${OPENSSL_INCLUDE_DIR}")
 454                 message("OpenSSL libraries: ${OPENSSL_LIBRARIES}")
 455
 456                 include_directories("${OPENSSL_INCLUDE_DIR}")
 457                 list(APPEND LIB_LIST ${OPENSSL_LIBRARIES})
 458         endif()
 459 endif(LWS_WITH_SSL)
 460
 461 #
 462 # Platform specific libs.
 463 #
 464 if (WINCE)
 465         list(APPEND LIB_LIST ws2.lib)
 466 elseif (WIN32)
 467         list(APPEND LIB_LIST ws2_32.lib)
 468 endif()
 469
 470 if (UNIX)
 471         list(APPEND LIB_LIST m)
 472 endif()
 473
 474 # Setup the linking for all libs.
 475 foreach (lib websockets websockets_shared)
 476         target_link_libraries(${lib} ${LIB_LIST})
 477 endforeach()
 478
 479 #
 480 # Test applications
 481 #
 482 set(TEST_APP_LIST)
 483 if (NOT LWS_WITHOUT_TESTAPPS)
 484         #
 485         # Helper function for adding a test app.
 486         #
 487         macro(create_test_app TEST_NAME MAIN_SRC WIN32_SRCS WIN32_HDRS)
 488
 489                 set(TEST_SRCS ${MAIN_SRC})
 490                 set(TEST_HDR)
 491
 492                 if (WIN32)
 493                         list(APPEND TEST_SRCS
 494                                 ${WIN32_HELPERS_PATH}/getopt.c
 495                                 ${WIN32_HELPERS_PATH}/getopt_long.c
 496                                 ${WIN32_HELPERS_PATH}/gettimeofday.c
 497                                 ${WIN32_SRCS})
 498
 499                         list(APPEND TEST_HDR
 500                                 ${WIN32_HELPERS_PATH}/getopt.h
 501                                 ${WIN32_HELPERS_PATH}/gettimeofday.h
 502                                 ${WIN32_HDRS})
 503                 endif(WIN32)
 504
 505                 source_group("Headers Private"   FILES ${TEST_HDR})
 506                 source_group("Sources"   FILES ${TEST_SRCS})
 507                 add_executable(${TEST_NAME} ${TEST_SRCS} ${TEST_HDR})
 508
 509                 if (LWS_LINK_TESTAPPS_DYNAMIC)
 510                         target_link_libraries(${TEST_NAME} websockets_shared)
 511                         add_dependencies(${TEST_NAME} websockets_shared)
 512                 else(LWS_LINK_TESTAPPS_DYNAMIC)
 513                         target_link_libraries(${TEST_NAME} websockets)
 514                         add_dependencies(${TEST_NAME} websockets)
 515                 endif(LWS_LINK_TESTAPPS_DYNAMIC)
 516
 517                 # Set test app specific defines.
 518                 set_property(TARGET ${TEST_NAME}
 519                                         PROPERTY COMPILE_DEFINITIONS
 520                                                 INSTALL_DATADIR="${CMAKE_INSTALL_PREFIX}/share"
 521                                         )
 522
 523                 # Prefix the binary names with libwebsockets.
 524                 set_target_properties(${TEST_NAME}
 525                         PROPERTIES
 526                         OUTPUT_NAME libwebsockets-${TEST_NAME})
 527
 528                 # Add to the list of tests.
 529                 list(APPEND TEST_APP_LIST ${TEST_NAME})
 530         endmacro()
 531
 532         if (LWS_WITH_SSL AND NOT LWS_USE_CYASSL)
 533                 message("Searching for OpenSSL executable and dlls")
 534                 find_package(OpenSSLbins)
 535                 message("OpenSSL executable: ${OPENSSL_EXECUTABLE}")
 536         endif()
 537
 538         if (NOT LWS_WITHOUT_SERVER)
 539                 #
 540                 # test-server
 541                 #
 542                 if (NOT LWS_WITHOUT_TEST_SERVER)
 543                         create_test_app(test-server
 544                                 "test-server/test-server.c"
 545                                 ""
 546                                 "${WIN32_HELPERS_PATH}/netdb.h;${WIN32_HELPERS_PATH}/strings.h;${WIN32_HELPERS_PATH}/unistd.h;${WIN32_HELPERS_PATH}/websock-w32.h")
 547                 endif()
 548
 549                 #
 550                 # test-server-extpoll
 551                 #
 552                 if (NOT LWS_WITHOUT_TEST_SERVER_EXTPOLL)
 553                         create_test_app(test-server-extpoll
 554                                 "test-server/test-server.c"
 555                                 "win32port/win32helpers/websock-w32.c"
 556                                 "${WIN32_HELPERS_PATH}/netdb.h;${WIN32_HELPERS_PATH}/strings.h;${WIN32_HELPERS_PATH}/unistd.h;${WIN32_HELPERS_PATH}/websock-w32.h")
 557                         # Set defines for this executable only.
 558                         set_property(
 559                                 TARGET test-server-extpoll
 560                                 PROPERTY COMPILE_DEFINITIONS
 561                                         EXTERNAL_POLL
 562                                         INSTALL_DATADIR="${CMAKE_INSTALL_PREFIX}/share"
 563                                 )
 564
 565                         # We need to link against winsock code.
 566                         if (WIN32)
 567                                 target_link_libraries(test-server-extpoll ws2_32.lib)
 568                         endif(WIN32)
 569                 endif()
 570
 571                 # Data files for running the test server.
 572                 set(TEST_SERVER_DATA
 573                         "${PROJECT_SOURCE_DIR}/test-server/favicon.ico"
 574                         "${PROJECT_SOURCE_DIR}/test-server/leaf.jpg"
 575                         "${PROJECT_SOURCE_DIR}/test-server/libwebsockets.org-logo.png"
 576                         "${PROJECT_SOURCE_DIR}/test-server/test.html")
 577
 578                 # Generate self-signed SSL certs for the test-server.
 579                 if (LWS_WITH_SSL AND OPENSSL_EXECUTABLE AND NOT LWS_WITHOUT_TEST_SERVER)
 580                         message("Generating SSL Certificates for the test-server...")
 581
 582                         set(TEST_SERVER_SSL_KEY "${PROJECT_BINARY_DIR}/libwebsockets-test-server.key.pem")
 583                         set(TEST_SERVER_SSL_CERT "${PROJECT_BINARY_DIR}/libwebsockets-test-server.pem")
 584
 585                         if (WIN32)
 586                                 file(WRITE "${PROJECT_BINARY_DIR}/openssl_input.txt"
 587                                         "GB\n"
 588                                         "Erewhon\n"
 589                                         "All around\n"
 590                                         "libwebsockets-test\n"
 591                                         "localhost\n"
 592                                         "none@invalid.org\n\n"
 593                                         )
 594
 595                                 # The "type" command is a bit picky with paths.
 596                                 file(TO_NATIVE_PATH "${PROJECT_BINARY_DIR}/openssl_input.txt" OPENSSL_INPUT_WIN_PATH)
 597                                 message("OPENSSL_INPUT_WIN_PATH = ${OPENSSL_INPUT_WIN_PATH}")
 598                                 message("cmd = \"${OPENSSL_EXECUTABLE}\" req -new -newkey rsa:1024 -days 10000 -nodes -x509 -keyout \"${TEST_SERVER_SSL_KEY}\" -out \"${TEST_SERVER_SSL_CERT}\"")
 599
 600                                 execute_process(
 601                                         COMMAND cmd /c type "${OPENSSL_INPUT_WIN_PATH}"
 602                                         COMMAND "${OPENSSL_EXECUTABLE}" req -new -newkey rsa:1024 -days 10000 -nodes -x509 -keyout "${TEST_SERVER_SSL_KEY}" -out "${TEST_SERVER_SSL_CERT}"
 603                                         RESULT_VARIABLE OPENSSL_RETURN_CODE)
 604
 605                                 message("\n")
 606
 607                                 if (OPENSSL_RETURN_CODE)
 608                                         message(WARNING "!!! Failed to generate SSL certificate for Test Server using cmd.exe !!!:\nOpenSSL return code = ${OPENSSL_RETURN_CODE}")
 609                                 else()
 610                                         message("SUCCSESFULLY generated SSL certificate")
 611                                 endif()
 612                         else()
 613                                 # Unix.
 614                                 execute_process(
 615                                         COMMAND printf "GB\\nErewhon\\nAll around\\nlibwebsockets-test\\n\\nlocalhost\\nnone@invalid.org\\n"
 616                                         COMMAND "${OPENSSL_EXECUTABLE}"
 617                                                 req -new -newkey rsa:1024 -days 10000 -nodes -x509 -keyout "${TEST_SERVER_SSL_KEY}" -out "${TEST_SERVER_SSL_CERT}"
 618                                         RESULT_VARIABLE OPENSSL_RETURN_CODE)
 619
 620                                 if (OPENSSL_RETURN_CODE)
 621                                         message(WARNING "!!! Failed to generate SSL certificate for Test Server!!!:\nOpenSSL return code = ${OPENSSL_RETURN_CODE}")
 622                                 else()
 623                                         message("SUCCSESFULLY generated SSL certificate")
 624                                 endif()
 625                         endif()
 626
 627                         list(APPEND TEST_SERVER_DATA
 628                                 "${TEST_SERVER_SSL_KEY}"
 629                                 "${TEST_SERVER_SSL_CERT}")
 630                 endif()
 631
 632                 add_custom_command(TARGET test-server
 633                                                 POST_BUILD
 634                                                 COMMAND "${CMAKE_COMMAND}" -E make_directory "$<TARGET_FILE_DIR:test-server>/../share/libwebsockets-test-server")
 635
 636                 # Copy the file needed to run the server so that the test apps can
 637                 # reach them from their default output location
 638                 foreach (TEST_FILE ${TEST_SERVER_DATA})
 639                         if (EXISTS ${TEST_FILE})
 640                                 add_custom_command(TARGET test-server
 641                                                         POST_BUILD
 642                                                         COMMAND "${CMAKE_COMMAND}" -E copy "${TEST_FILE}" "$<TARGET_FILE_DIR:test-server>/../share/libwebsockets-test-server" VERBATIM)
 643                         endif()
 644                 endforeach()
 645         endif(NOT LWS_WITHOUT_SERVER)
 646
 647         if (NOT LWS_WITHOUT_CLIENT)
 648                 #
 649                 # test-client
 650                 #
 651                 if (NOT LWS_WITHOUT_TEST_CLIENT)
 652                         create_test_app(test-client
 653                                 "test-server/test-client.c"
 654                                 ""
 655                                 "")
 656                 endif()
 657
 658                 #
 659                 # test-fraggle
 660                 #
 661                 if (NOT LWS_WITHOUT_TEST_FRAGGLE)
 662                         create_test_app(test-fraggle
 663                                 "test-server/test-fraggle.c"
 664                                 ""
 665                                 "${WIN32_HELPERS_PATH}/unistd.h;${WIN32_HELPERS_PATH}/sys/time.h")
 666                 endif()
 667
 668                 #
 669                 # test-ping
 670                 #
 671                 if (NOT LWS_WITHOUT_TEST_PING)
 672                         create_test_app(test-ping
 673                                 "test-server/test-ping.c"
 674                                 ""
 675                                 "${WIN32_HELPERS_PATH}/unistd.h;${WIN32_HELPERS_PATH}/sys/time.h")
 676                 endif()
 677                 #
 678                 # test-echo
 679                 #
 680                 if (NOT WITHOUT_TEST_ECHO)
 681                         create_test_app(test-echo
 682                                 "test-server/test-echo.c"
 683                                 ""
 684                                 "${WIN32_HELPERS_PATH}/unistd.h;${WIN32_HELPERS_PATH}/sys/time.h")
 685                 endif()
 686
 687         endif(NOT LWS_WITHOUT_CLIENT)
 688
 689         #
 690         # Copy OpenSSL dlls to the output directory on Windows.
 691         # (Otherwise we'll get an error when trying to run)
 692         #
 693         if (WIN32 AND LWS_WITH_SSL AND NOT LWS_USE_CYASSL)
 694                 if(OPENSSL_BIN_FOUND)
 695                         message("OpenSSL dlls found:")
 696                         message("  Libeay: ${LIBEAY_BIN}")
 697                         message("  SSLeay: ${SSLEAY_BIN}")
 698
 699                         foreach(TARGET_BIN ${TEST_APP_LIST})
 700                                 add_custom_command(TARGET ${TARGET_BIN}
 701                                         POST_BUILD
 702                                         COMMAND "${CMAKE_COMMAND}" -E copy "${LIBEAY_BIN}" "$<TARGET_FILE_DIR:${TARGET_BIN}>" VERBATIM)
 703
 704                                 add_custom_command(TARGET ${TARGET_BIN}
 705                                         POST_BUILD
 706                                         COMMAND "${CMAKE_COMMAND}" -E copy "${SSLEAY_BIN}" "$<TARGET_FILE_DIR:${TARGET_BIN}>" VERBATIM)
 707                         endforeach()
 708                 endif()
 709         endif()
 710 endif(NOT LWS_WITHOUT_TESTAPPS)
 711
 712 if (UNIX)
 713         # Generate documentation.
 714         # TODO: Fix this on Windows.
 715         message("Generating API documentation")
 716         file(GLOB C_FILES "${PROJECT_SOURCE_DIR}/lib/*.c")
 717         execute_process(COMMAND "${CMAKE_COMMAND}" -E make_directory "${PROJECT_BINARY_DIR}/doc/")
 718
 719         execute_process(
 720                 COMMAND "${PROJECT_SOURCE_DIR}/scripts/kernel-doc" -html ${C_FILES} ${HDR_PUBLIC}
 721                 OUTPUT_FILE "${PROJECT_BINARY_DIR}/doc/libwebsockets-api-doc.html"
 722                 ERROR_QUIET)
 723
 724         execute_process(
 725                 COMMAND "${PROJECT_SOURCE_DIR}/scripts/kernel-doc" -text ${C_FILES} ${HDR_PUBLIC}
 726                 OUTPUT_FILE "${PROJECT_BINARY_DIR}/doc/libwebsockets-api-doc.txt"
 727                 ERROR_QUIET)
 728
 729 # Generate and install pkgconfig.
 730 # (This is not indented, because the tabs will be part of the output)
 731 file(WRITE "${PROJECT_BINARY_DIR}/libwebsockets.pc"
 732 "prefix=\"${CMAKE_INSTALL_PREFIX}\"
 733 exec_prefix=\${prefix}
 734 libdir=\${exec_prefix}/lib${LIB_SUFFIX}
 735 includedir=\${prefix}/include
 736
 737 Name: libwebsockets
 738 Description: Websockets server and client library
 739 Version: ${CPACK_PACKAGE_VERSION_MAJOR}.${CPACK_PACKAGE_VERSION_MINOR}
 740
 741 Libs: -L\${libdir} -lwebsockets
 742 Cflags: -I\${includedir}"
 743 )
 744
 745         install(FILES "${PROJECT_BINARY_DIR}/libwebsockets.pc"
 746                 DESTINATION lib${LIB_SUFFIX}/pkgconfig)
 747 endif(UNIX)
 748
 749 #
 750 # Installation preparations.
 751 #
 752
 753 if(WIN32 AND NOT CYGWIN)
 754   set(DEF_INSTALL_CMAKE_DIR cmake)
 755 else()
 756   set(DEF_INSTALL_CMAKE_DIR lib/cmake/libwebsockets)
 757 endif()
 758
 759 set(LWS_INSTALL_CMAKE_DIR ${DEF_INSTALL_CMAKE_DIR} CACHE PATH "Installation directory for CMake files")
 760
 761 # Export targets (This is used for other CMake projects to easily find the libraries and include files).
 762 export(TARGETS websockets websockets_shared
 763         FILE "${PROJECT_BINARY_DIR}/LibwebsocketsTargets.cmake")
 764 export(PACKAGE libwebsockets)
 765
 766 # Generate the config file for the build-tree.
 767 set(LWS__INCLUDE_DIRS
 768     "${PROJECT_SOURCE_DIR}/lib"
 769     "${PROJECT_BINARY_DIR}")
 770 set(LIBWEBSOCKETS_INCLUDE_DIRS ${LWS__INCLUDE_DIRS} CACHE PATH "Libwebsockets include directories")
 771 configure_file(${PROJECT_SOURCE_DIR}/cmake/LibwebsocketsConfig.cmake.in
 772                 ${PROJECT_BINARY_DIR}/LibwebsocketsConfig.cmake
 773                 @ONLY)
 774
 775 # Generate the config file for the installation tree.
 776 get_filename_component(LWS_ABSOLUTE_INSTALL_CMAKE_DIR ${LWS_INSTALL_CMAKE_DIR} ABSOLUTE)
 777 get_filename_component(LWS_ABSOLUTE_INSTALL_INCLUDE_DIR ${LWS_INSTALL_INCLUDE_DIR} ABSOLUTE)
 778 file(RELATIVE_PATH
 779     REL_INCLUDE_DIR
 780     "${LWS_ABSOLUTE_INSTALL_CMAKE_DIR}"
 781     "${LWS_ABSOLUTE_INSTALL_INCLUDE_DIR}") # Calculate the relative directory from the cmake dir.
 782
 783 # Note the EVENT_CMAKE_DIR is defined in JanssonConfig.cmake.in,
 784 # we escape it here so it's evaluated when it is included instead
 785 # so that the include dirs are given relative to where the
 786 # config file is located.
 787 set(LWS__INCLUDE_DIRS
 788     "\${LWS_CMAKE_DIR}/${REL_INCLUDE_DIR}")
 789 configure_file(${PROJECT_SOURCE_DIR}/cmake/LibwebsocketsConfig.cmake.in
 790                 ${PROJECT_BINARY_DIR}${CMAKE_FILES_DIRECTORY}/LibwebsocketsConfig.cmake
 791                 @ONLY)
 792
 793 # Generate version info for both build-tree and install-tree.
 794 configure_file(${PROJECT_SOURCE_DIR}/cmake/LibwebsocketsConfigVersion.cmake.in
 795                 ${PROJECT_BINARY_DIR}/LibwebsocketsConfigVersion.cmake
 796                 @ONLY)
 797
 798 set_target_properties(websockets websockets_shared
 799                                         PROPERTIES PUBLIC_HEADER "${HDR_PUBLIC}")
 800
 801 #
 802 # Installation.
 803 #
 804
 805 # Install libs and headers.
 806 install(TARGETS websockets websockets_shared
 807                 EXPORT LibwebsocketsTargets
 808                 LIBRARY DESTINATION "${LWS_INSTALL_LIB_DIR}${LIB_SUFFIX}" COMPONENT libraries
 809                 ARCHIVE DESTINATION "${LWS_INSTALL_LIB_DIR}${LIB_SUFFIX}" COMPONENT libraries
 810                 RUNTIME DESTINATION "${LWS_INSTALL_BIN_DIR}" COMPONENT libraries # Windows DLLs
 811                 PUBLIC_HEADER DESTINATION "${LWS_INSTALL_INCLUDE_DIR}" COMPONENT dev)
 812 set(CPACK_COMPONENT_LIBRARIES_DISPLAY_NAME "Libraries")
 813 set(CPACK_COMPONENT_DEV_DISPLAY_NAME "Development files")
 814
 815 # Install test apps.
 816 if (NOT LWS_WITHOUT_TESTAPPS AND NOT LWS_WITHOUT_CLIENT)
 817         install(TARGETS test-client ${TEST_APP_LIST}
 818                         RUNTIME DESTINATION ${LWS_INSTALL_EXAMPLES_DIR}
 819                         COMPONENT examples)
 820         set(CPACK_COMPONENT_EXAMPLES_DISPLAY_NAME "Example files")
 821 endif()
 822
 823 # Programs shared files used by the test-server.
 824 if (NOT LWS_WITHOUT_TESTAPPS AND NOT LWS_WITHOUT_SERVER)
 825         install(FILES ${TEST_SERVER_DATA}
 826                         DESTINATION share/libwebsockets-test-server
 827                         COMPONENT examples)
 828 endif()
 829
 830 # Install exports for the install-tree.
 831 install(EXPORT LibwebsocketsTargets
 832                 DESTINATION "${LWS_INSTALL_CMAKE_DIR}" COMPONENT dev)
 833
 834 # build subdir is not part of sources
 835 set(CPACK_SOURCE_IGNORE_FILES $(CPACK_SOURCE_IGNORE_FILES) ".git" "build" "tgz" "tar.gz")
 836
 837 # Most people are more used to "make dist" compared to "make package_source"
 838 add_custom_target(dist COMMAND "${CMAKE_MAKE_PROGRAM}" package_source)
 839
 840 include(UseRPMTools)
 841 if (RPMTools_FOUND)
 842         RPMTools_ADD_RPM_TARGETS(libwebsockets libwebsockets.spec)
 843 endif()
 844
 845 message("---------------------------------------------------------------------")
 846 message("  Settings:  (For more help do cmake -LH <srcpath>")
 847 message("---------------------------------------------------------------------")
 848 message(" LWS_WITH_SSL = ${LWS_WITH_SSL}  (SSL Support)")
 849 message(" LWS_SSL_CLIENT_USE_OS_CA_CERTS = ${LWS_SSL_CLIENT_USE_OS_CA_CERTS}")
 850 message(" LWS_USE_CYASSL = ${LWS_USE_CYASSL} (CyaSSL replacement for OpenSSL)")
 851 if (LWS_USE_CYASSL)
 852         message("   LWS_CYASSL_LIB = ${LWS_CYASSL_LIB}")
 853         message("   LWS_CYASSL_INCLUDE_DIRS = ${LWS_CYASSL_INCLUDE_DIRS}")
 854 endif()
 855 message(" LWS_WITHOUT_BUILTIN_GETIFADDRS = ${LWS_WITHOUT_BUILTIN_GETIFADDRS}")
 856 message(" LWS_WITHOUT_CLIENT = ${LWS_WITHOUT_CLIENT}")
 857 message(" LWS_WITHOUT_SERVER = ${LWS_WITHOUT_SERVER}")
 858 message(" LWS_LINK_TESTAPPS_DYNAMIC = ${LWS_LINK_TESTAPPS_DYNAMIC}")
 859 message(" LWS_WITHOUT_TESTAPPS = ${LWS_WITHOUT_TESTAPPS}")
 860 message(" LWS_WITHOUT_TEST_SERVER = ${LWS_WITHOUT_TEST_SERVER}")
 861 message(" LWS_WITHOUT_TEST_SERVER_EXTPOLL = ${LWS_WITHOUT_TEST_SERVER_EXTPOLL}")
 862 message(" LWS_WITHOUT_TEST_PING = ${LWS_WITHOUT_TEST_PING}")
 863 message(" LWS_WITHOUT_TEST_CLIENT = ${LWS_WITHOUT_TEST_CLIENT}")
 864 message(" LWS_WITHOUT_TEST_FRAGGLE = ${LWS_WITHOUT_TEST_FRAGGLE}")
 865 message(" LWS_WITHOUT_DEBUG = ${LWS_WITHOUT_DEBUG}")
 866 message(" LWS_WITHOUT_EXTENSIONS = ${LWS_WITHOUT_EXTENSIONS}")
 867 message(" LWS_WITH_LATENCY = ${LWS_WITH_LATENCY}")
 868 message(" LWS_WITHOUT_DAEMONIZE = ${LWS_WITHOUT_DAEMONIZE}")
 869 message("---------------------------------------------------------------------")
 870
 871 # These will be available to parent projects including libwebsockets using add_subdirectory()
 872 set(LIBWEBSOCKETS_LIBRARIES websocket websockets_shared CACHE STRING "Libwebsocket libraries")
 873 set(LIBWEBSOCKETS_LIBRARIES_STATIC websocket CACHE STRING "Libwebsocket static library")
 874 set(LIBWEBSOCKETS_LIBRARIES_SHARED websockets_shared CACHE STRING "Libwebsocket shared library")
 875
 876 # This must always be last!
 877 include(CPack)