CMakeLists.txt

   1 # The name of our project is "VULKAN". CMakeLists files in this project can
   2 # refer to the root source directory of the project as ${VULKAN_SOURCE_DIR} and
   3 # to the root binary directory of the project as ${VULKAN_BINARY_DIR}.
   4 cmake_minimum_required(VERSION 2.8.11)
   5 project (VULKAN)
   6 # set (CMAKE_VERBOSE_MAKEFILE 1)
   7
   8 # The API_NAME allows renaming builds to avoid conflicts with installed SDKs
   9 # The MAJOR number of the version we're building, used in naming
  10 # <api-name>-<major>.dll (and other files).
  11 set(API_NAME "Vulkan" CACHE STRING "API name to use when building")
  12 set(MAJOR "1")
  13 string(TOLOWER ${API_NAME} API_LOWERCASE)
  14
  15 set(CMAKE_MODULE_PATH ${CMAKE_MODULE_PATH} "${CMAKE_CURRENT_SOURCE_DIR}/cmake")
  16 find_package(PythonInterp 3 REQUIRED)
  17
  18 option(USE_CCACHE "Use ccache" OFF)
  19 if (USE_CCACHE)
  20     find_program(CCACHE_FOUND ccache)
  21     if(CCACHE_FOUND)
  22         set_property(GLOBAL PROPERTY RULE_LAUNCH_COMPILE ccache)
  23         set_property(GLOBAL PROPERTY RULE_LAUNCH_LINK ccache)
  24     endif(CCACHE_FOUND)
  25 endif()
  26
  27 if(CMAKE_SYSTEM_NAME STREQUAL "Linux")
  28     set(FALLBACK_CONFIG_DIRS "/etc/xdg" CACHE STRING
  29         "Search path to use when XDG_CONFIG_DIRS is unset or empty or the current process is SUID/SGID. Default is freedesktop compliant.")
  30     set(FALLBACK_DATA_DIRS "/usr/local/share:/usr/share" CACHE STRING
  31         "Search path to use when XDG_DATA_DIRS is unset or empty or the current process is SUID/SGID. Default is freedesktop compliant.")
  32
  33     include(FindPkgConfig)
  34     option(BUILD_WSI_XCB_SUPPORT "Build XCB WSI support" ON)
  35     option(BUILD_WSI_XLIB_SUPPORT "Build Xlib WSI support" ON)
  36     option(BUILD_WSI_WAYLAND_SUPPORT "Build Wayland WSI support" ON)
  37     option(BUILD_WSI_MIR_SUPPORT "Build Mir WSI support" OFF)
  38     set(DEMOS_WSI_SELECTION "XCB" CACHE STRING "Select WSI target for demos (XCB, XLIB, WAYLAND, MIR, DISPLAY)")
  39
  40     if (BUILD_WSI_XCB_SUPPORT)
  41         find_package(XCB REQUIRED)
  42     endif()
  43
  44     if (BUILD_WSI_XLIB_SUPPORT)
  45         find_package(X11 REQUIRED)
  46     endif()
  47
  48     if (BUILD_WSI_WAYLAND_SUPPORT)
  49         find_package(Wayland REQUIRED)
  50         include_directories(${WAYLAND_CLIENT_INCLUDE_DIR})
  51     endif()
  52
  53     if (BUILD_WSI_MIR_SUPPORT)
  54         find_package(Mir REQUIRED)
  55     endif()
  56
  57     # This option can be used to suppress the installation of artifacts from the
  58     # Vulkan-LoaderAndValidationLayers repo while running "make install" for the
  59     # VulkanTools and VulkanSamples repos.  This can be used to prevent the
  60     # overwriting of LVL artifacts when installing these downstream repos.
  61     option(INSTALL_LVL_FILES "Install content from LoaderAndValidationLayers repo" ON)
  62 endif()
  63
  64 set(SCRIPTS_DIR "${CMAKE_CURRENT_SOURCE_DIR}/scripts")
  65
  66 # Header file for CMake settings
  67 include_directories("${PROJECT_SOURCE_DIR}/include")
  68
  69 if (CMAKE_COMPILER_IS_GNUCC OR CMAKE_C_COMPILER_ID MATCHES "Clang")
  70     set(COMMON_COMPILE_FLAGS "-Wall -Wextra -Wno-unused-parameter -Wno-missing-field-initializers")
  71     set(COMMON_COMPILE_FLAGS "${COMMON_COMPILE_FLAGS} -fno-strict-aliasing -fno-builtin-memcmp")
  72
  73     # For GCC version 7.1 or greater, we need to disable the implicit fallthrough warning since
  74     # there's no consistent way to satisfy all compilers until they all accept the C++17 standard
  75     if (CMAKE_COMPILER_IS_GNUCC AND NOT (CMAKE_CXX_COMPILER_VERSION LESS 7.1))
  76         set(COMMON_COMPILE_FLAGS "${COMMON_COMPILE_FLAGS} -Wimplicit-fallthrough=0")
  77     endif()
  78
  79     set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -std=c99 ${COMMON_COMPILE_FLAGS}")
  80     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} ${COMMON_COMPILE_FLAGS} -std=c++11 -fno-rtti")
  81     if (UNIX)
  82         set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -fvisibility=hidden")
  83         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -fvisibility=hidden")
  84     endif()
  85 endif()
  86
  87 if(WIN32)
  88     # Treat warnings as errors
  89     add_compile_options("$<$<CXX_COMPILER_ID:MSVC>:/WX>")
  90     # Disable RTTI
  91     add_compile_options("$<$<CXX_COMPILER_ID:MSVC>:/GR->")
  92     # Warn about nested declarations
  93     add_compile_options("$<$<CXX_COMPILER_ID:MSVC>:/w34456>")
  94     # Warn about potentially uninitialized variables
  95     add_compile_options("$<$<CXX_COMPILER_ID:MSVC>:/w34701>")
  96     add_compile_options("$<$<CXX_COMPILER_ID:MSVC>:/w34703>")
  97 endif()
  98
  99 if(NOT WIN32)
 100     set (BUILDTGT_DIR build)
 101     set (BINDATA_DIR Bin)
 102     set (LIBSOURCE_DIR Lib)
 103 else()
 104     # is WIN32
 105     option(DISABLE_BUILD_PATH_DECORATION "Disable the decoration of the gslang and SPIRV-Tools build path with MSVC build type info" OFF)
 106     option(DISABLE_BUILDTGT_DIR_DECORATION "Disable the decoration of the gslang and SPIRV-Tools build path with target info" OFF)
 107
 108     # For Windows, since 32-bit and 64-bit items can co-exist, we build each in its own build directory.
 109     # 32-bit target data goes in build32, and 64-bit target data goes into build.  So, include/link the
 110     # appropriate data at build time.
 111     if (DISABLE_BUILDTGT_DIR_DECORATION)
 112         set (BUILDTGT_DIR "")
 113         set (BINDATA_DIR "")
 114         set (LIBSOURCE_DIR "")
 115     elseif (CMAKE_CL_64)
 116         set (BUILDTGT_DIR build)
 117         set (BINDATA_DIR Bin)
 118         set (LIBSOURCE_DIR Lib)
 119     else()
 120         set (BUILDTGT_DIR build32)
 121         set (BINDATA_DIR Bin32)
 122         set (LIBSOURCE_DIR Lib32)
 123     endif()
 124 endif()
 125
 126 option(BUILD_LOADER "Build loader" ON)
 127 option(BUILD_TESTS "Build tests" ON)
 128 option(BUILD_LAYERS "Build layers" ON)
 129 option(BUILD_DEMOS "Build demos" ON)
 130 option(BUILD_VKJSON "Build vkjson" ON)
 131 option(BUILD_ICD "Build icd" ON)
 132 option(CUSTOM_GLSLANG_BIN_ROOT "Use the user defined GLSLANG_BINARY_ROOT" OFF)
 133 option(CUSTOM_SPIRV_TOOLS_BIN_ROOT "Use the user defined SPIRV_TOOLS*BINARY_ROOT paths" OFF)
 134
 135 #Choose natural default paths for glslang and SPIRV-Tools binaries to support custom definition by the user on the CMake command line or in the GUI
 136 set(GLSLANG_BINARY_ROOT "${CMAKE_BINARY_DIR}/../glslang" CACHE STRING "User defined path to the glslang binaries for this project")
 137 set(SPIRV_TOOLS_BINARY_ROOT "${CMAKE_BINARY_DIR}/../SPIRV-Tools" CACHE STRING "User defined path to the SPIRV-Tools binaries for this project")
 138 set(SPIRV_TOOLS_OPT_BINARY_ROOT "${CMAKE_BINARY_DIR}/../SPIRV-Tools/opt" CACHE STRING "User defined path to the SPIRV-Tools-opt binaries for this project")
 139
 140 # Define a variable for a default root location to the gslang, SPIRV-Tools and other external sources and cache it to allow the user to customize it as needed
 141 set(EXTERNAL_SOURCE_ROOT "${CMAKE_SOURCE_DIR}/external" CACHE STRING "Root path to external sources such as glslang and SPIRV-Tools")
 142
 143
 144 if (WIN32)
 145     if(CUSTOM_GLSLANG_BIN_ROOT)
 146         set(GSLANG_FINAL_BINARY_PATH ${GLSLANG_BINARY_ROOT}/${BUILDTGT_DIR})
 147     else()
 148         set(GSLANG_FINAL_BINARY_PATH "${EXTERNAL_SOURCE_ROOT}/glslang/${BUILDTGT_DIR}")
 149     endif()
 150
 151     if(DISABLE_BUILD_PATH_DECORATION)
 152         set (DEBUG_DECORATION "")
 153         set (RELEASE_DECORATION "")
 154     else()
 155         set (DEBUG_DECORATION "Debug")
 156         set (RELEASE_DECORATION "Release")
 157     endif()
 158
 159     # Take some steps to set up a variable pointing to the final glslang binaries given the variety of input options
 160     set (GLSLANG_SEARCH_PATH "${GSLANG_FINAL_BINARY_PATH}/glslang/${RELEASE_DECORATION}"
 161                              "${GSLANG_FINAL_BINARY_PATH}/glslang/OSDependent/Windows/${RELEASE_DECORATION}"
 162                              "${GSLANG_FINAL_BINARY_PATH}/hlsl/${RELEASE_DECORATION}"
 163                              "${GSLANG_FINAL_BINARY_PATH}/OGLCompilersDLL/${RELEASE_DECORATION}"
 164                              "${GSLANG_FINAL_BINARY_PATH}/SPIRV/${RELEASE_DECORATION}" )
 165
 166     set (GLSLANG_DEBUG_SEARCH_PATH "${GSLANG_FINAL_BINARY_PATH}/glslang/${DEBUG_DECORATION}"
 167                                    "${GSLANG_FINAL_BINARY_PATH}/glslang/OSDependent/Windows/${DEBUG_DECORATION}"
 168                                    "${GSLANG_FINAL_BINARY_PATH}/hlsl/${DEBUG_DECORATION}"
 169                                    "${GSLANG_FINAL_BINARY_PATH}/OGLCompilersDLL/${DEBUG_DECORATION}"
 170                                    "${GSLANG_FINAL_BINARY_PATH}/SPIRV/${DEBUG_DECORATION}")
 171
 172     if(CUSTOM_SPIRV_TOOLS_BIN_ROOT)
 173         set (SPIRV_TOOLS_SEARCH_PATH "${SPIRV_TOOLS_BINARY_ROOT}/${BUILDTGT_DIR}/source/${RELEASE_DECORATION}")
 174         set (SPIRV_TOOLS_DEBUG_SEARCH_PATH "${SPIRV_TOOLS_BINARY_ROOT}/${BUILDTGT_DIR}/source/${DEBUG_DECORATION}")
 175         set (SPIRV_TOOLS_OPT_SEARCH_PATH "${SPIRV_TOOLS_OPT_BINARY_ROOT}/${BUILDTGT_DIR}/source/opt/${RELEASE_DECORATION}")
 176         set (SPIRV_TOOLS_OPT_DEBUG_SEARCH_PATH "${SPIRV_TOOLS_OPT_BINARY_ROOT}/${BUILDTGT_DIR}/source/opt/${DEBUG_DECORATION}")
 177     else()
 178         set (SPIRV_TOOLS_SEARCH_PATH "${EXTERNAL_SOURCE_ROOT}/spirv-tools/${BUILDTGT_DIR}/source/${RELEASE_DECORATION}")
 179         set (SPIRV_TOOLS_DEBUG_SEARCH_PATH "${EXTERNAL_SOURCE_ROOT}/spirv-tools/${BUILDTGT_DIR}/source/${DEBUG_DECORATION}")
 180         set (SPIRV_TOOLS_OPT_SEARCH_PATH "${EXTERNAL_SOURCE_ROOT}/spirv-tools/${BUILDTGT_DIR}/source/opt/${RELEASE_DECORATION}")
 181         set (SPIRV_TOOLS_OPT_DEBUG_SEARCH_PATH "${EXTERNAL_SOURCE_ROOT}/spirv-tools/${BUILDTGT_DIR}/source/opt/${DEBUG_DECORATION}")
 182     endif()
 183 else()
 184     # not WIN32
 185     if(CUSTOM_GLSLANG_BIN_ROOT)
 186         set (GLSLANG_SEARCH_PATH "${GLSLANG_BINARY_ROOT}/install/lib"
 187                                  "${GLSLANG_BINARY_ROOT}/glslang"
 188                                  "${GLSLANG_BINARY_ROOT}/glslang/OSDependent/Unix"
 189                                  "${GLSLANG_BINARY_ROOT}/OGLCompilersDLL"
 190                                  "${GLSLANG_BINARY_ROOT}/SPIRV"
 191                                  "${GLSLANG_BINARY_ROOT}/hlsl"
 192                                  "${GLSLANG_BINARY_ROOT}/StandAlone")
 193     else()
 194         set (GLSLANG_SEARCH_PATH "${EXTERNAL_SOURCE_ROOT}/glslang/${BUILDTGT_DIR}/install/lib" "${CMAKE_SOURCE_DIR}/../x86_64/lib/glslang" )
 195     endif()
 196
 197     if(CUSTOM_SPIRV_TOOLS_BIN_ROOT)
 198         set (SPIRV_TOOLS_SEARCH_PATH "${SPIRV_TOOLS_BINARY_ROOT}/source" )
 199         set (SPIRV_TOOLS_OPT_SEARCH_PATH "${SPIRV_TOOLS_OPT_BINARY_ROOT}/source/opt" )
 200     else()
 201         set (SPIRV_TOOLS_SEARCH_PATH "${EXTERNAL_SOURCE_ROOT}/spirv-tools/${BUILDTGT_DIR}/source" "${CMAKE_SOURCE_DIR}/../x86_64/lib/spirv-tools" )
 202         set (SPIRV_TOOLS_OPT_SEARCH_PATH "${EXTERNAL_SOURCE_ROOT}/spirv-tools/${BUILDTGT_DIR}/source/opt" "${CMAKE_SOURCE_DIR}/../x86_64/lib/spirv-tools" )
 203     endif()
 204 endif()
 205
 206 find_program(GLSLANG_VALIDATOR NAMES glslangValidator
 207              HINTS "${CMAKE_SOURCE_DIR}/external/glslang/${BUILDTGT_DIR}/install/bin"
 208                    "${GLSLANG_BINARY_ROOT}/StandAlone"
 209                    "${PROJECT_SOURCE_DIR}/external/${BINDATA_DIR}")
 210
 211 find_path(GLSLANG_SPIRV_INCLUDE_DIR SPIRV/spirv.hpp HINTS "${EXTERNAL_SOURCE_ROOT}/glslang"
 212                                                     "${CMAKE_SOURCE_DIR}/../glslang"
 213                                               DOC "Path to SPIRV/spirv.hpp")
 214
 215 find_path(SPIRV_TOOLS_INCLUDE_DIR spirv-tools/libspirv.h HINTS "${EXTERNAL_SOURCE_ROOT}/spirv-tools/include"
 216                                                    "${EXTERNAL_SOURCE_ROOT}/SPIRV-Tools/include"
 217                                                    "${CMAKE_SOURCE_DIR}/../spirv-tools/include"
 218                                                    "${CMAKE_SOURCE_DIR}/../SPIRV-Tools/include"
 219                                                    "${EXTERNAL_SOURCE_ROOT}/source/spirv-tools/external/include"
 220                                              DOC "Path to spirv-tools/libspirv.h")
 221
 222 find_library(GLSLANG_LIB NAMES glslang
 223              HINTS ${GLSLANG_SEARCH_PATH} )
 224
 225 find_library(OGLCompiler_LIB NAMES OGLCompiler
 226              HINTS ${GLSLANG_SEARCH_PATH} )
 227
 228 find_library(OSDependent_LIB NAMES OSDependent
 229              HINTS ${GLSLANG_SEARCH_PATH} )
 230
 231 find_library(HLSL_LIB NAMES HLSL
 232              HINTS ${GLSLANG_SEARCH_PATH} )
 233
 234 find_library(SPIRV_LIB NAMES SPIRV
 235              HINTS ${GLSLANG_SEARCH_PATH} )
 236
 237 find_library(SPIRV_REMAPPER_LIB NAMES SPVRemapper
 238              HINTS ${GLSLANG_SEARCH_PATH} )
 239
 240 find_library(SPIRV_TOOLS_LIB NAMES SPIRV-Tools
 241              HINTS ${SPIRV_TOOLS_SEARCH_PATH} )
 242
 243 find_library(SPIRV_TOOLS_OPT_LIB NAMES SPIRV-Tools-opt
 244              HINTS ${SPIRV_TOOLS_OPT_SEARCH_PATH} )
 245
 246 if (WIN32)
 247     add_library(glslang         STATIC IMPORTED)
 248     add_library(OGLCompiler     STATIC IMPORTED)
 249     add_library(OSDependent     STATIC IMPORTED)
 250     add_library(HLSL            STATIC IMPORTED)
 251     add_library(SPIRV           STATIC IMPORTED)
 252     add_library(SPVRemapper     STATIC IMPORTED)
 253     add_library(Loader          STATIC IMPORTED)
 254     add_library(SPIRV-Tools-opt STATIC IMPORTED)
 255     add_library(SPIRV-Tools     STATIC IMPORTED)
 256
 257     find_library(GLSLANG_DLIB NAMES glslangd
 258                  HINTS ${GLSLANG_DEBUG_SEARCH_PATH} )
 259     find_library(OGLCompiler_DLIB NAMES OGLCompilerd
 260                  HINTS ${GLSLANG_DEBUG_SEARCH_PATH} )
 261     find_library(OSDependent_DLIB NAMES OSDependentd
 262                  HINTS ${GLSLANG_DEBUG_SEARCH_PATH} )
 263     find_library(HLSL_DLIB NAMES HLSLd
 264                  HINTS ${GLSLANG_DEBUG_SEARCH_PATH} )
 265     find_library(SPIRV_DLIB NAMES SPIRVd
 266                  HINTS ${GLSLANG_DEBUG_SEARCH_PATH} )
 267     find_library(SPIRV_REMAPPER_DLIB NAMES SPVRemapperd
 268                  HINTS ${GLSLANG_DEBUG_SEARCH_PATH} )
 269     find_library(SPIRV_TOOLS_DLIB NAMES SPIRV-Tools
 270                  HINTS ${SPIRV_TOOLS_DEBUG_SEARCH_PATH} )
 271     find_library(SPIRV_TOOLS_OPT_DLIB NAMES SPIRV-Tools-opt
 272                  HINTS ${SPIRV_TOOLS_OPT_DEBUG_SEARCH_PATH} )
 273
 274     set_target_properties(glslang PROPERTIES
 275                          IMPORTED_LOCATION       "${GLSLANG_LIB}"
 276                          IMPORTED_LOCATION_DEBUG "${GLSLANG_DLIB}")
 277     set_target_properties(OGLCompiler PROPERTIES
 278                          IMPORTED_LOCATION       "${OGLCompiler_LIB}"
 279                          IMPORTED_LOCATION_DEBUG "${OGLCompiler_DLIB}")
 280     set_target_properties(OSDependent PROPERTIES
 281                          IMPORTED_LOCATION       "${OSDependent_LIB}"
 282                          IMPORTED_LOCATION_DEBUG "${OSDependent_DLIB}")
 283     set_target_properties(HLSL PROPERTIES
 284                          IMPORTED_LOCATION       "${HLSL_LIB}"
 285                          IMPORTED_LOCATION_DEBUG "${HLSL_DLIB}")
 286     set_target_properties(SPIRV PROPERTIES
 287                          IMPORTED_LOCATION       "${SPIRV_LIB}"
 288                          IMPORTED_LOCATION_DEBUG "${SPIRV_DLIB}")
 289     set_target_properties(SPVRemapper PROPERTIES
 290                          IMPORTED_LOCATION       "${SPIRV_REMAPPER_LIB}"
 291                          IMPORTED_LOCATION_DEBUG "${SPIRV_REMAPPER_DLIB}")
 292     set_target_properties(SPIRV-Tools PROPERTIES
 293                          IMPORTED_LOCATION       "${SPIRV_TOOLS_LIB}"
 294                          IMPORTED_LOCATION_DEBUG "${SPIRV_TOOLS_DLIB}")
 295     set_target_properties(SPIRV-Tools-opt PROPERTIES
 296                          IMPORTED_LOCATION       "${SPIRV_TOOLS_OPT_LIB}"
 297                          IMPORTED_LOCATION_DEBUG "${SPIRV_TOOLS_OPT_DLIB}")
 298
 299     set (SPIRV_TOOLS_LIBRARIES SPIRV-Tools-opt SPIRV-Tools)
 300     set (GLSLANG_LIBRARIES glslang OGLCompiler OSDependent HLSL SPIRV SPVRemapper ${SPIRV_TOOLS_LIBRARIES})
 301 else ()
 302     # not WIN32
 303     set (SPIRV_TOOLS_LIBRARIES ${SPIRV_TOOLS_OPT_LIB} ${SPIRV_TOOLS_LIB})
 304     set (GLSLANG_LIBRARIES ${GLSLANG_LIB} ${OGLCompiler_LIB} ${OSDependent_LIB} ${HLSL_LIB} ${SPIRV_LIB} ${SPIRV_REMAPPER_LIB} ${SPIRV_TOOLS_LIBRARIES})
 305 endif()
 306
 307 set (PYTHON_CMD ${PYTHON_EXECUTABLE})
 308
 309 # Define macro used for building vkxml generated files
 310 macro(run_vk_xml_generate dependency output)
 311     add_custom_command(OUTPUT ${output}
 312     COMMAND ${PYTHON_CMD} ${SCRIPTS_DIR}/lvl_genvk.py -registry ${SCRIPTS_DIR}/vk.xml ${output}
 313     DEPENDS ${SCRIPTS_DIR}/vk.xml ${SCRIPTS_DIR}/generator.py ${SCRIPTS_DIR}/${dependency} ${SCRIPTS_DIR}/lvl_genvk.py ${SCRIPTS_DIR}/reg.py
 314     )
 315 endmacro()
 316
 317 # Custom target for generated vulkan helper file dependencies
 318 add_custom_target(generate_helper_files DEPENDS
 319     vk_enum_string_helper.h
 320     vk_struct_size_helper.h
 321     vk_struct_size_helper.c
 322     vk_safe_struct.h
 323     vk_safe_struct.cpp
 324     vk_object_types.h
 325     vk_layer_dispatch_table.h
 326     vk_dispatch_table_helper.h
 327     vk_extension_helper.h
 328     vk_typemap_helper.h
 329     )
 330
 331 # Rules to build generated helper files
 332 run_vk_xml_generate(loader_extension_generator.py vk_layer_dispatch_table.h)
 333 run_vk_xml_generate(dispatch_table_helper_generator.py vk_dispatch_table_helper.h)
 334 run_vk_xml_generate(helper_file_generator.py vk_safe_struct.h)
 335 run_vk_xml_generate(helper_file_generator.py vk_safe_struct.cpp)
 336 run_vk_xml_generate(helper_file_generator.py vk_struct_size_helper.h)
 337 run_vk_xml_generate(helper_file_generator.py vk_struct_size_helper.c)
 338 run_vk_xml_generate(helper_file_generator.py vk_enum_string_helper.h)
 339 run_vk_xml_generate(helper_file_generator.py vk_object_types.h)
 340 run_vk_xml_generate(helper_file_generator.py vk_extension_helper.h)
 341 run_vk_xml_generate(helper_file_generator.py vk_typemap_helper.h)
 342
 343 if(NOT WIN32)
 344     include(GNUInstallDirs)
 345
 346     add_definitions(-DFALLBACK_CONFIG_DIRS="${FALLBACK_CONFIG_DIRS}")
 347     add_definitions(-DFALLBACK_DATA_DIRS="${FALLBACK_DATA_DIRS}")
 348     add_definitions(-DSYSCONFDIR="${CMAKE_INSTALL_FULL_SYSCONFDIR}")
 349
 350     # Make sure /etc is searched by the loader
 351     if(NOT (CMAKE_INSTALL_FULL_SYSCONFDIR STREQUAL "/etc"))
 352         add_definitions(-DEXTRASYSCONFDIR="/etc")
 353     endif()
 354 endif()
 355
 356 if(UNIX)
 357     if(INSTALL_LVL_FILES)
 358         install(DIRECTORY "${PROJECT_SOURCE_DIR}/include/vulkan" DESTINATION ${CMAKE_INSTALL_INCLUDEDIR})
 359         install(FILES "${CMAKE_CURRENT_BINARY_DIR}/vk_layer_dispatch_table.h" DESTINATION "${CMAKE_INSTALL_INCLUDEDIR}/vulkan")
 360     endif()
 361
 362 # uninstall target
 363 configure_file(
 364     "${CMAKE_CURRENT_SOURCE_DIR}/cmake/cmake_uninstall.cmake.in"
 365     "${CMAKE_CURRENT_BINARY_DIR}/cmake_uninstall.cmake"
 366     IMMEDIATE @ONLY)
 367
 368 add_custom_target(uninstall
 369     COMMAND ${CMAKE_COMMAND} -P ${CMAKE_CURRENT_BINARY_DIR}/cmake_uninstall.cmake)
 370 endif()
 371
 372 add_definitions(-DAPI_NAME="${API_NAME}")
 373
 374 # loader: Generic VULKAN ICD loader
 375 # tests: VULKAN tests
 376 if(BUILD_LOADER)
 377     add_subdirectory(loader)
 378 endif()
 379
 380 if(BUILD_TESTS)
 381     add_subdirectory(tests)
 382 endif()
 383
 384 if(BUILD_LAYERS)
 385     add_subdirectory(layers)
 386 endif()
 387
 388 if(BUILD_DEMOS)
 389     add_subdirectory(demos)
 390 endif()
 391
 392 if(BUILD_VKJSON)
 393     add_subdirectory(libs/vkjson)
 394 endif()
 395
 396 if(BUILD_ICD)
 397     add_subdirectory(icd)
 398 endif()