CMakeLists.txt

   1 cmake_minimum_required(VERSION 2.6)
   2 project(LAPACK Fortran)
   3
   4 # Configure the warning and code coverage suppression file
   5 configure_file(
   6   "${LAPACK_SOURCE_DIR}/CTestCustom.cmake.in"
   7   "${LAPACK_BINARY_DIR}/CTestCustom.cmake"
   8   COPYONLY
   9 )
  10
  11 # Add the CMake directory for custon CMake modules
  12 set(CMAKE_MODULE_PATH "${LAPACK_SOURCE_DIR}/CMAKE" ${CMAKE_MODULE_PATH})
  13
  14 if (UNIX)
  15    if ( "${CMAKE_Fortran_COMPILER}" MATCHES "ifort" )
  16   set( CMAKE_Fortran_FLAGS "${CMAKE_Fortran_FLAGS} -fltconsistency -fp_port" )
  17    endif ()
  18 endif ()
  19
  20 macro(lapack_install_library lib)
  21   install(TARGETS ${lib} EXPORT lapack-targets
  22     ARCHIVE DESTINATION lib${LIB_SUFFIX}
  23     LIBRARY DESTINATION lib${LIB_SUFFIX}
  24     RUNTIME DESTINATION bin
  25   )
  26 endmacro()
  27
  28 # --------------------------------------------------
  29 # Testing
  30
  31 enable_testing()
  32 include(CTest)
  33 enable_testing()
  34 # --------------------------------------------------
  35
  36 # Organize output files.  On Windows this also keeps .dll files next
  37 # to the .exe files that need them, making tests easy to run.
  38 set(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${LAPACK_BINARY_DIR}/bin)
  39 set(CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${LAPACK_BINARY_DIR}/lib)
  40 set(CMAKE_LIBRARY_OUTPUT_DIRECTORY ${LAPACK_BINARY_DIR}/lib)
  41
  42 # --------------------------------------------------
  43 # Check for any necessary platform specific compiler flags
  44 include( CheckLAPACKCompilerFlags )
  45 CheckLAPACKCompilerFlags()
  46
  47 # --------------------------------------------------
  48 # Check second function
  49
  50 include(CheckTimeFunction)
  51 set(TIME_FUNC NONE ${TIME_FUNC})
  52 CHECK_TIME_FUNCTION(NONE TIME_FUNC)
  53 CHECK_TIME_FUNCTION(INT_CPU_TIME TIME_FUNC)
  54 CHECK_TIME_FUNCTION(EXT_ETIME TIME_FUNC)
  55 CHECK_TIME_FUNCTION(EXT_ETIME_ TIME_FUNC)
  56 CHECK_TIME_FUNCTION(INT_ETIME TIME_FUNC)
  57 message(STATUS "--> Will use second_${TIME_FUNC}.f and dsecnd_${TIME_FUNC}.f as timing function.")
  58
  59 set(SECOND_SRC  ${LAPACK_SOURCE_DIR}/INSTALL/second_${TIME_FUNC}.f)
  60 set(DSECOND_SRC  ${LAPACK_SOURCE_DIR}/INSTALL/dsecnd_${TIME_FUNC}.f)
  61 set(prefix ${CMAKE_INSTALL_PREFIX})
  62 set(libdir ${CMAKE_INSTALL_PREFIX}/lib${LIB_SUFFIX})
  63 set(PKG_CONFIG_DIR ${libdir}/pkgconfig)
  64
  65 # --------------------------------------------------
  66 # Subdirectories that need to be processed
  67
  68 option(USE_OPTIMIZED_BLAS "Whether or not to use an optimized BLAS library instead of included netlib BLAS" OFF)
  69
  70 # Check the usage of the user provided BLAS libraries
  71 if(BLAS_LIBRAIRIES)
  72   include(CheckFortranFunctionExists)
  73   set(CMAKE_REQUIRED_LIBRARIES ${BLAS_LIBRAIRIES})
  74   CHECK_FORTRAN_FUNCTION_EXISTS("dgemm" BLAS_FOUND)
  75   unset( CMAKE_REQUIRED_LIBRARIES )
  76   if(BLAS_FOUND)
  77     message(STATUS "--> BLAS supplied by user is WORKING, will use ${BLAS_LIBRAIRIES}.")
  78   else(BLAS_FOUND)
  79     message(ERROR "--> BLAS supplied by user is not WORKING, CANNOT USE ${BLAS_LIBRAIRIES}.")
  80     message(ERROR "-->     Will use REFERENCE BLAS (by default)")
  81     message(ERROR "-->     Or Correct your BLAS_LIBRAIRIES entry ")
  82     message(ERROR "-->     Or Consider checking USE_OPTIMIZED_BLAS")
  83   endif(BLAS_FOUND)
  84
  85 # User did not provide a BLAS Library but specified to search for one
  86 elseif( USE_OPTIMIZED_BLAS )
  87   find_package( BLAS )
  88 endif (BLAS_LIBRAIRIES)
  89
  90 # Neither user specified or optimized BLAS libraries can be used
  91 if(NOT BLAS_FOUND)
  92   message(STATUS "Using supplied NETLIB BLAS implementation")
  93   add_subdirectory(BLAS)
  94   set( BLAS_LIBRARIES blas )
  95 else()
  96   set( CMAKE_EXE_LINKER_FLAGS
  97     "${CMAKE_EXE_LINKER_FLAGS} ${BLAS_LINKER_FLAGS}"
  98     CACHE STRING "Linker flags for executables" FORCE)
  99   set( CMAKE_MODULE_LINKER_FLAGS
 100     "${CMAKE_MODULE_LINKER_FLAGS} ${BLAS_LINKER_FLAGS}"
 101     CACHE STRING "Linker flags for modules" FORCE)
 102   set( CMAKE_SHARED_LINKER_FLAGS
 103     "${CMAKE_SHARED_LINKER_FLAGS} ${BLAS_LINKER_FLAGS}"
 104     CACHE STRING "Linker flags for shared libs" FORCE)
 105 endif( NOT BLAS_FOUND )
 106
 107 add_subdirectory(SRC)
 108 if(BUILD_TESTING)
 109   add_subdirectory(TESTING)
 110 endif(BUILD_TESTING)
 111
 112 # --------------------------------------------------
 113 # CPACK Packaging
 114
 115 SET(CPACK_PACKAGE_NAME "LAPACK")
 116 SET(CPACK_PACKAGE_VENDOR "University of Tennessee, Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd")
 117 SET(CPACK_PACKAGE_DESCRIPTION_SUMMARY "LAPACK- Linear Algebra Package")
 118 set(LAPACK_VERSION 3.3.1)
 119 set(CPACK_PACKAGE_VERSION_MAJOR 3)
 120 set(CPACK_PACKAGE_VERSION_MINOR 3)
 121 set(CPACK_PACKAGE_VERSION_PATCH 1)
 122 set(CPACK_RESOURCE_FILE_LICENSE "${CMAKE_CURRENT_SOURCE_DIR}/LICENSE")
 123 SET(CPACK_PACKAGE_INSTALL_DIRECTORY "LAPACK")
 124 IF(WIN32 AND NOT UNIX)
 125   # There is a bug in NSI that does not handle full unix paths properly. Make
 126   # sure there is at least one set of four (4) backlasshes.
 127   SET(CPACK_NSIS_HELP_LINK "http:\\\\\\\\http://icl.cs.utk.edu/lapack-forum")
 128   SET(CPACK_NSIS_URL_INFO_ABOUT "http:\\\\\\\\www.netlib.org/lapack")
 129   SET(CPACK_NSIS_CONTACT "lapack@eecs.utk.edu")
 130   SET(CPACK_NSIS_MODIFY_PATH ON)
 131   SET(CPACK_NSIS_DISPLAY_NAME "LAPACK-${LAPACK_VERSION}")
 132   set(CPACK_PACKAGE_RELOCATABLE "true")
 133 ELSE(WIN32 AND NOT UNIX)
 134   SET(CPACK_GENERATOR "TGZ")
 135   SET(CPACK_SOURCE_GENERATOR TGZ)
 136   SET(CPACK_SOURCE_PACKAGE_FILE_NAME "lapack-${LAPACK_VERSION}" )
 137   SET(CPACK_SOURCE_IGNORE_FILES ~$ .svn ${CPACK_SOURCE_IGNORE_FILES} )
 138 ENDIF(WIN32 AND NOT UNIX)
 139 INCLUDE(CPack)
 140
 141
 142 # --------------------------------------------------
 143 # By default static library
 144 OPTION(BUILD_SHARED_LIBS "Build shared libraries" OFF )
 145 OPTION(BUILD_STATIC_LIBS "Build static libraries" ON )
 146 #OPTION(BUILD_SHARED_LIBS "Build shared libraries" ON )
 147
 148 if( NOT BLAS_FOUND )
 149   export(TARGETS blas lapack FILE lapack-targets.cmake)
 150 else( NOT BLAS_FOUND )
 151   export(TARGETS lapack FILE lapack-targets.cmake)
 152 endif( NOT BLAS_FOUND )
 153 configure_file(${LAPACK_SOURCE_DIR}/CMAKE/lapack-config-version.cmake.in
 154   ${LAPACK_BINARY_DIR}/lapack-config-version.cmake @ONLY)
 155 configure_file(${LAPACK_SOURCE_DIR}/CMAKE/lapack-config-build.cmake.in
 156   ${LAPACK_BINARY_DIR}/lapack-config.cmake @ONLY)
 157
 158 configure_file(${CMAKE_CURRENT_SOURCE_DIR}/lapack.pc.in ${CMAKE_CURRENT_BINARY_DIR}/lapack.pc)
 159  install(FILES
 160   ${CMAKE_CURRENT_BINARY_DIR}/lapack.pc
 161   DESTINATION ${PKG_CONFIG_DIR}
 162    )
 163
 164 configure_file(${LAPACK_SOURCE_DIR}/CMAKE/lapack-config-install.cmake.in
 165   ${LAPACK_BINARY_DIR}/CMakeFiles/lapack-config.cmake @ONLY)
 166 install(FILES
 167   ${LAPACK_BINARY_DIR}/CMakeFiles/lapack-config.cmake
 168   ${LAPACK_BINARY_DIR}/lapack-config-version.cmake
 169   DESTINATION lib/cmake/lapack-${LAPACK_VERSION}
 170   )
 171 install(EXPORT lapack-targets
 172   DESTINATION lib/cmake/lapack-${LAPACK_VERSION})