CMakeLists.txt

   1 # Copyright (c) 2015-2016 The Khronos Group Inc.
   2 #
   3 # Permission is hereby granted, free of charge, to any person obtaining a
   4 # copy of this software and/or associated documentation files (the
   5 # "Materials"), to deal in the Materials without restriction, including
   6 # without limitation the rights to use, copy, modify, merge, publish,
   7 # distribute, sublicense, and/or sell copies of the Materials, and to
   8 # permit persons to whom the Materials are furnished to do so, subject to
   9 # the following conditions:
  10 #
  11 # The above copyright notice and this permission notice shall be included
  12 # in all copies or substantial portions of the Materials.
  13 #
  14 # MODIFICATIONS TO THIS FILE MAY MEAN IT NO LONGER ACCURATELY REFLECTS
  15 # KHRONOS STANDARDS. THE UNMODIFIED, NORMATIVE VERSIONS OF KHRONOS
  16 # SPECIFICATIONS AND HEADER INFORMATION ARE LOCATED AT
  17 #    https://www.khronos.org/registry/
  18 #
  19 # THE MATERIALS ARE PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,
  20 # EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF
  21 # MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.
  22 # IN NO EVENT SHALL THE AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY
  23 # CLAIM, DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION OF CONTRACT,
  24 # TORT OR OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION WITH THE
  25 # MATERIALS OR THE USE OR OTHER DEALINGS IN THE MATERIALS.
  26
  27 cmake_minimum_required(VERSION 2.8.12)
  28 project(spirv-tools)
  29 enable_testing()
  30 set(SPIRV_TOOLS "SPIRV-Tools")
  31
  32 if("${CMAKE_SYSTEM_NAME}" STREQUAL "Linux")
  33   add_definitions(-DSPIRV_LINUX)
  34 elseif("${CMAKE_SYSTEM_NAME}" STREQUAL "Windows")
  35   add_definitions(-DSPIRV_WINDOWS)
  36 elseif("${CMAKE_SYSTEM_NAME}" STREQUAL "Darwin")
  37   add_definitions(-DSPIRV_MAC)
  38 else()
  39   message(FATAL_ERROR "Your platform '${CMAKE_SYSTEM_NAME}' is not supported!")
  40 endif()
  41
  42 if ("${CMAKE_BUILD_TYPE}" STREQUAL "")
  43   message(STATUS "No build type selected, default to Debug")
  44   set(CMAKE_BUILD_TYPE "Debug")
  45 endif()
  46
  47 option(SPIRV_WERROR "Enable error on warning" ON)
  48 if(UNIX)
  49   set(SPIRV_WARNINGS -Wall -Wextra -Wno-missing-field-initializers)
  50
  51   option(SPIRV_WARN_EVERYTHING "Enable -Weverything" ${SPIRV_WARN_EVERYTHING})
  52   if(${SPIRV_WARN_EVERYTHING})
  53     if("${CMAKE_CXX_COMPILER_ID}" STREQUAL "Clang")
  54       set(SPIRV_WARNINGS ${SPIRV_WARNINGS}
  55         -Weverything -Wno-c++98-compat -Wno-c++98-compat-pedantic -Wno-padded)
  56     elseif("${CMAKE_CXX_COMPILER_ID}" STREQUAL "GNU")
  57       set(SPIRV_WARNINGS ${SPIRV_WARNINGS} -Wpedantic -pedantic-errors)
  58     else()
  59       message(STATUS "Unknown compiler ${CMAKE_CXX_COMPILER_ID}, "
  60                      "so SPIRV_WARN_EVERYTHING has no effect")
  61     endif()
  62   endif()
  63
  64   if(${SPIRV_WERROR})
  65     set(SPIRV_WARNINGS ${SPIRV_WARNINGS} -Werror)
  66   endif()
  67 elseif(WIN32)
  68   set(SPIRV_WARNINGS -D_CRT_SECURE_NO_WARNINGS /wd4800)
  69
  70   if(${SPIRV_WERROR})
  71     set(SPIRV_WARNINGS ${SPIRV_WARNINGS} /WX)
  72   endif()
  73 endif()
  74
  75 option(SPIRV_COLOR_TERMINAL "Enable color terminal output" ON)
  76 if(${SPIRV_COLOR_TERMINAL})
  77   add_definitions(-DSPIRV_COLOR_TERMINAL)
  78 endif()
  79
  80 function(spvtools_default_compile_options TARGET)
  81   target_compile_options(${TARGET} PRIVATE ${SPIRV_WARNINGS})
  82   if (UNIX)
  83     target_compile_options(${TARGET} PRIVATE
  84       -std=c++11 -fno-exceptions -fno-rtti)
  85     target_compile_options(${TARGET} PRIVATE
  86       -Wall -Wextra -Wno-long-long -Wshadow -Wundef -Wconversion
  87       -Wno-sign-conversion)
  88     # For good call stacks in profiles, keep the frame pointers.
  89     if(NOT "${SPIRV_PERF}" STREQUAL "")
  90       target_compile_options(${TARGET} PRIVATE -fno-omit-frame-pointer)
  91     endif()
  92     if("${CMAKE_CXX_COMPILER_ID}" STREQUAL "Clang")
  93       set(SPIRV_USE_SANITIZER "" CACHE STRING
  94         "Use the clang sanitizer [address|memory|thread|...]")
  95       if(NOT "${SPIRV_USE_SANITIZER}" STREQUAL "")
  96         target_compile_options(${TARGET} PRIVATE
  97           -fsanitize=${SPIRV_USE_SANITIZER})
  98       endif()
  99     else()
 100       target_compile_options(${TARGET} PRIVATE
 101          -Wno-missing-field-initializers)
 102     endif()
 103   endif()
 104 endfunction()
 105
 106 if(NOT COMMAND find_host_package)
 107   macro(find_host_package)
 108     find_package(${ARGN})
 109   endmacro()
 110 endif()
 111 if(NOT COMMAND find_host_program)
 112   macro(find_host_program)
 113     find_program(${ARGN})
 114   endmacro()
 115 endif()
 116
 117 find_host_package(PythonInterp)
 118
 119 add_custom_target(spirv-tools-build-version
 120   ${PYTHON_EXECUTABLE}
 121   ${CMAKE_CURRENT_SOURCE_DIR}/utils/update_build_version.py
 122   ${spirv-tools_SOURCE_DIR}
 123   COMMENT "Update build-version.inc in the Spirv-tools build directory (if necessary).")
 124
 125 set(SPIRV_SOURCES
 126   ${CMAKE_CURRENT_SOURCE_DIR}/include/spirv-tools/libspirv.h
 127   ${CMAKE_CURRENT_SOURCE_DIR}/include/spirv/spirv.h
 128   ${CMAKE_CURRENT_SOURCE_DIR}/include/spirv/GLSL.std.450.h
 129   ${CMAKE_CURRENT_SOURCE_DIR}/include/spirv/OpenCL.std.h
 130   ${CMAKE_CURRENT_SOURCE_DIR}/source/util/bitutils.h
 131   ${CMAKE_CURRENT_SOURCE_DIR}/source/util/hex_float.h
 132   ${CMAKE_CURRENT_SOURCE_DIR}/source/assembly_grammar.h
 133   ${CMAKE_CURRENT_SOURCE_DIR}/source/binary.h
 134   ${CMAKE_CURRENT_SOURCE_DIR}/source/diagnostic.h
 135   ${CMAKE_CURRENT_SOURCE_DIR}/source/ext_inst.h
 136   ${CMAKE_CURRENT_SOURCE_DIR}/source/instruction.h
 137   ${CMAKE_CURRENT_SOURCE_DIR}/source/opcode.h
 138   ${CMAKE_CURRENT_SOURCE_DIR}/source/operand.h
 139   ${CMAKE_CURRENT_SOURCE_DIR}/source/print.h
 140   ${CMAKE_CURRENT_SOURCE_DIR}/source/spirv_constant.h
 141   ${CMAKE_CURRENT_SOURCE_DIR}/source/spirv_definition.h
 142   ${CMAKE_CURRENT_SOURCE_DIR}/source/spirv_endian.h
 143   ${CMAKE_CURRENT_SOURCE_DIR}/source/table.h
 144   ${CMAKE_CURRENT_SOURCE_DIR}/source/text.h
 145   ${CMAKE_CURRENT_SOURCE_DIR}/source/text_handler.h
 146   ${CMAKE_CURRENT_SOURCE_DIR}/source/validate.h
 147   ${CMAKE_CURRENT_SOURCE_DIR}/source/assembly_grammar.cpp
 148   ${CMAKE_CURRENT_SOURCE_DIR}/source/binary.cpp
 149   ${CMAKE_CURRENT_SOURCE_DIR}/source/disassemble.cpp
 150   ${CMAKE_CURRENT_SOURCE_DIR}/source/diagnostic.cpp
 151   ${CMAKE_CURRENT_SOURCE_DIR}/source/ext_inst.cpp
 152   ${CMAKE_CURRENT_SOURCE_DIR}/source/instruction.cpp
 153   ${CMAKE_CURRENT_SOURCE_DIR}/source/opcode.cpp
 154   ${CMAKE_CURRENT_SOURCE_DIR}/source/operand.cpp
 155   ${CMAKE_CURRENT_SOURCE_DIR}/source/print.cpp
 156   ${CMAKE_CURRENT_SOURCE_DIR}/source/spirv_endian.cpp
 157   ${CMAKE_CURRENT_SOURCE_DIR}/source/table.cpp
 158   ${CMAKE_CURRENT_SOURCE_DIR}/source/text.cpp
 159   ${CMAKE_CURRENT_SOURCE_DIR}/source/text_handler.cpp
 160   ${CMAKE_CURRENT_SOURCE_DIR}/source/validate.cpp
 161   ${CMAKE_CURRENT_SOURCE_DIR}/source/validate_cfg.cpp
 162   ${CMAKE_CURRENT_SOURCE_DIR}/source/validate_id.cpp
 163   ${CMAKE_CURRENT_SOURCE_DIR}/source/validate_instruction.cpp
 164   ${CMAKE_CURRENT_SOURCE_DIR}/source/validate_layout.cpp
 165   ${CMAKE_CURRENT_SOURCE_DIR}/source/validate_ssa.cpp
 166   ${CMAKE_CURRENT_SOURCE_DIR}/source/validate_types.cpp)
 167
 168 add_library(${SPIRV_TOOLS} ${SPIRV_SOURCES})
 169 spvtools_default_compile_options(${SPIRV_TOOLS})
 170 target_include_directories(${SPIRV_TOOLS} PUBLIC ${CMAKE_CURRENT_SOURCE_DIR}/include)
 171
 172 # Defaults to OFF if the user didn't set it.
 173 option(SPIRV_SKIP_EXECUTABLES
 174        "Skip building the executable and tests along with the library"
 175        ${SPIRV_SKIP_EXECUTABLES})
 176 set(SPIRV_INSTALL_TARGETS ${SPIRV_TOOLS})
 177 if (NOT ${SPIRV_SKIP_EXECUTABLES})
 178   list(APPEND SPIRV_INSTALL_TARGETS spirv-as spirv-dis spirv-val)
 179
 180   add_executable(spirv-as ${CMAKE_CURRENT_SOURCE_DIR}/tools/as/as.cpp)
 181   spvtools_default_compile_options(spirv-as)
 182   target_link_libraries(spirv-as PRIVATE ${SPIRV_TOOLS})
 183   target_include_directories(spirv-as PRIVATE ${CMAKE_CURRENT_BINARY_DIR})
 184   add_dependencies(${SPIRV_TOOLS} spirv-tools-build-version)
 185
 186
 187   add_executable(spirv-dis ${CMAKE_CURRENT_SOURCE_DIR}/tools/dis/dis.cpp)
 188   spvtools_default_compile_options(spirv-dis)
 189   target_link_libraries(spirv-dis PRIVATE ${SPIRV_TOOLS})
 190   target_include_directories(spirv-dis PRIVATE ${CMAKE_CURRENT_BINARY_DIR})
 191   add_dependencies(${SPIRV_TOOLS} spirv-tools-build-version)
 192
 193   add_executable(spirv-val ${CMAKE_CURRENT_SOURCE_DIR}/tools/val/val.cpp)
 194   spvtools_default_compile_options(spirv-val)
 195   target_link_libraries(spirv-val PRIVATE ${SPIRV_TOOLS})
 196   target_include_directories(spirv-val PRIVATE ${CMAKE_CURRENT_BINARY_DIR})
 197   add_dependencies(${SPIRV_TOOLS} spirv-tools-build-version)
 198
 199   # Find gmock if we can. If it's not already configured, then try finding
 200   # it in external/googletest
 201   if (TARGET gmock)
 202     message(STATUS "Google Mock already configured")
 203   else()
 204     set(GMOCK_DIR ${CMAKE_CURRENT_SOURCE_DIR}/external/googletest/googlemock)
 205     if(EXISTS ${GMOCK_DIR})
 206       if(WIN32)
 207         option(gtest_force_shared_crt
 208           "Use shared (DLL) run-time lib even when Google Test is built as static lib."
 209           ON)
 210       endif()
 211       add_subdirectory(${GMOCK_DIR})
 212     endif()
 213   endif()
 214   if (TARGET gmock)
 215     message(STATUS "Found Google Mock, building tests.")
 216
 217     set(TEST_SOURCES
 218       ${CMAKE_CURRENT_SOURCE_DIR}/test/TestFixture.h
 219       ${CMAKE_CURRENT_SOURCE_DIR}/test/UnitSPIRV.h
 220
 221       ${CMAKE_CURRENT_SOURCE_DIR}/test/AssemblyContext.cpp
 222       ${CMAKE_CURRENT_SOURCE_DIR}/test/AssemblyFormat.cpp
 223       ${CMAKE_CURRENT_SOURCE_DIR}/test/BinaryDestroy.cpp
 224       ${CMAKE_CURRENT_SOURCE_DIR}/test/BinaryEndianness.cpp
 225       ${CMAKE_CURRENT_SOURCE_DIR}/test/BinaryHeaderGet.cpp
 226       ${CMAKE_CURRENT_SOURCE_DIR}/test/BinaryParse.cpp
 227       ${CMAKE_CURRENT_SOURCE_DIR}/test/BinaryToText.cpp
 228       ${CMAKE_CURRENT_SOURCE_DIR}/test/BinaryToText.Literal.cpp
 229       ${CMAKE_CURRENT_SOURCE_DIR}/test/Comment.cpp
 230       ${CMAKE_CURRENT_SOURCE_DIR}/test/DiagnosticDestroy.cpp
 231       ${CMAKE_CURRENT_SOURCE_DIR}/test/DiagnosticPrint.cpp
 232       ${CMAKE_CURRENT_SOURCE_DIR}/test/DiagnosticStream.cpp
 233       ${CMAKE_CURRENT_SOURCE_DIR}/test/ExtInstGLSLstd450.cpp
 234       ${CMAKE_CURRENT_SOURCE_DIR}/test/ExtInst.OpenCL.std.cpp
 235       ${CMAKE_CURRENT_SOURCE_DIR}/test/FixWord.cpp
 236       ${CMAKE_CURRENT_SOURCE_DIR}/test/GeneratorMagicNumber.cpp
 237       ${CMAKE_CURRENT_SOURCE_DIR}/test/HexFloat.cpp
 238       ${CMAKE_CURRENT_SOURCE_DIR}/test/ImmediateInt.cpp
 239       ${CMAKE_CURRENT_SOURCE_DIR}/test/LibspirvMacros.cpp
 240       ${CMAKE_CURRENT_SOURCE_DIR}/test/NamedId.cpp
 241       ${CMAKE_CURRENT_SOURCE_DIR}/test/OpcodeMake.cpp
 242       ${CMAKE_CURRENT_SOURCE_DIR}/test/OpcodeRequiresCapabilities.cpp
 243       ${CMAKE_CURRENT_SOURCE_DIR}/test/OpcodeSplit.cpp
 244       ${CMAKE_CURRENT_SOURCE_DIR}/test/OpcodeTableGet.cpp
 245       ${CMAKE_CURRENT_SOURCE_DIR}/test/OperandCapabilities.cpp
 246       ${CMAKE_CURRENT_SOURCE_DIR}/test/Operand.cpp
 247       ${CMAKE_CURRENT_SOURCE_DIR}/test/OperandPattern.cpp
 248       ${CMAKE_CURRENT_SOURCE_DIR}/test/TextAdvance.cpp
 249       ${CMAKE_CURRENT_SOURCE_DIR}/test/TextDestroy.cpp
 250       ${CMAKE_CURRENT_SOURCE_DIR}/test/TextLiteral.cpp
 251       ${CMAKE_CURRENT_SOURCE_DIR}/test/TextStartsNewInst.cpp
 252       ${CMAKE_CURRENT_SOURCE_DIR}/test/TextToBinary.Annotation.cpp
 253       ${CMAKE_CURRENT_SOURCE_DIR}/test/TextToBinary.Barrier.cpp
 254       ${CMAKE_CURRENT_SOURCE_DIR}/test/TextToBinary.Constant.cpp
 255       ${CMAKE_CURRENT_SOURCE_DIR}/test/TextToBinary.ControlFlow.cpp
 256       ${CMAKE_CURRENT_SOURCE_DIR}/test/TextToBinary.cpp
 257       ${CMAKE_CURRENT_SOURCE_DIR}/test/TextToBinary.Debug.cpp
 258       ${CMAKE_CURRENT_SOURCE_DIR}/test/TextToBinary.DeviceSideEnqueue.cpp
 259       ${CMAKE_CURRENT_SOURCE_DIR}/test/TextToBinary.Extension.cpp
 260       ${CMAKE_CURRENT_SOURCE_DIR}/test/TextToBinary.Function.cpp
 261       ${CMAKE_CURRENT_SOURCE_DIR}/test/TextToBinary.Group.cpp
 262       ${CMAKE_CURRENT_SOURCE_DIR}/test/TextToBinary.Image.cpp
 263       ${CMAKE_CURRENT_SOURCE_DIR}/test/TextToBinary.Literal.cpp
 264       ${CMAKE_CURRENT_SOURCE_DIR}/test/TextToBinary.Memory.cpp
 265       ${CMAKE_CURRENT_SOURCE_DIR}/test/TextToBinary.Miscellaneous.cpp
 266       ${CMAKE_CURRENT_SOURCE_DIR}/test/TextToBinary.ModeSetting.cpp
 267       ${CMAKE_CURRENT_SOURCE_DIR}/test/TextToBinary.TypeDeclaration.cpp
 268       ${CMAKE_CURRENT_SOURCE_DIR}/test/TextWordGet.cpp
 269       ${CMAKE_CURRENT_SOURCE_DIR}/test/UnitSPIRV.cpp
 270       ${CMAKE_CURRENT_SOURCE_DIR}/test/ValidateFixtures.cpp
 271       ${CMAKE_CURRENT_SOURCE_DIR}/test/Validate.Capability.cpp
 272       ${CMAKE_CURRENT_SOURCE_DIR}/test/Validate.Layout.cpp
 273       ${CMAKE_CURRENT_SOURCE_DIR}/test/Validate.Storage.cpp
 274       ${CMAKE_CURRENT_SOURCE_DIR}/test/Validate.SSA.cpp
 275       ${CMAKE_CURRENT_SOURCE_DIR}/test/ValidateID.cpp
 276       ${CMAKE_CURRENT_SOURCE_DIR}/test/ValidationState.cpp
 277       ${CMAKE_CURRENT_SOURCE_DIR}/test/Version.cpp
 278       ${CMAKE_CURRENT_SOURCE_DIR}/test/main.cpp)
 279
 280     add_executable(UnitSPIRV ${TEST_SOURCES})
 281     spvtools_default_compile_options(UnitSPIRV)
 282     if(UNIX)
 283       target_compile_options(UnitSPIRV PRIVATE -Wno-undef)
 284     endif()
 285     if(${CMAKE_CXX_COMPILER_ID} STREQUAL "MSVC")
 286       # Disable C4503 "decorated name length exceeded" warning, triggered
 287       # by some heavily templated types.
 288       # We don't care much about that in test code.
 289       # Important to do since we have warnings-as-errors.
 290       target_compile_options(UnitSPIRV PRIVATE /wd4503)
 291     endif()
 292     target_include_directories(UnitSPIRV PRIVATE
 293       ${CMAKE_CURRENT_SOURCE_DIR}
 294       ${gmock_SOURCE_DIR}/include ${gtest_SOURCE_DIR}/include)
 295     target_link_libraries(UnitSPIRV PRIVATE ${SPIRV_TOOLS} gmock)
 296     add_test(NAME spirv-tools-testsuite COMMAND UnitSPIRV)
 297   else()
 298     message(STATUS "Did not find googletest, tests will not be built."
 299       "To enable tests place googletest in '<spirv-dir>/external/googletest'.")
 300   endif()
 301 endif()
 302
 303 install(TARGETS ${SPIRV_INSTALL_TARGETS}
 304   RUNTIME DESTINATION bin
 305   LIBRARY DESTINATION lib
 306   ARCHIVE DESTINATION lib)
 307
 308 install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/include/spirv-tools/libspirv.h
 309   DESTINATION include/spirv-tools/)
 310 # The installation is broken without these header files from the SPIR-V Registry.
 311 # The libspirv.h header includes them.
 312 install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/include/spirv/spirv.h
 313               ${CMAKE_CURRENT_SOURCE_DIR}/include/spirv/GLSL.std.450.h
 314               ${CMAKE_CURRENT_SOURCE_DIR}/include/spirv/OpenCL.std.h
 315   DESTINATION include/spirv/)