CMakeLists.txt

   1 # Verify minimum required version
   2 cmake_minimum_required(VERSION 2.8.12)
   3
   4 if(CMAKE_VERSION VERSION_EQUAL 3.0 OR CMAKE_VERSION VERSION_GREATER 3.0)
   5     cmake_policy(SET CMP0042 NEW)
   6 endif()
   7
   8 # Set the project name
   9 project(CoreCLR)
  10
  11 # Include cmake functions
  12 include(functions.cmake)
  13
  14 # Include global configure settings
  15 include(configure.cmake)
  16
  17 if (WIN32)
  18   message(STATUS "VS_PLATFORM_TOOLSET is ${CMAKE_VS_PLATFORM_TOOLSET}")
  19   message(STATUS "VS_PLATFORM_NAME is ${CMAKE_VS_PLATFORM_NAME}")
  20 endif (WIN32)
  21
  22 # Set commonly used directory names
  23 set(CLR_DIR ${CMAKE_CURRENT_SOURCE_DIR})
  24 set(VM_DIR ${CMAKE_CURRENT_SOURCE_DIR}/src/vm)
  25 set(GENERATED_INCLUDE_DIR ${CMAKE_CURRENT_BINARY_DIR}/src/inc)
  26 set(GENERATED_EVENTING_DIR ${CMAKE_CURRENT_BINARY_DIR}/eventing)
  27 set(VERSION_FILE_PATH "${CMAKE_BINARY_DIR}/version.cpp")
  28 set(PAL_REDEFINES_FILE ${CMAKE_CURRENT_SOURCE_DIR}/src/dlls/mscordac/palredefines.S)
  29
  30 set(CORECLR_SET_RPATH ON)
  31 if(CORECLR_SET_RPATH)
  32     # Enable @rpath support for shared libraries.
  33     set(MACOSX_RPATH ON)
  34 endif(CORECLR_SET_RPATH)
  35
  36 OPTION(CLR_CMAKE_ENABLE_CODE_COVERAGE "Enable code coverage" OFF)
  37 OPTION(CLR_CMAKE_WARNINGS_ARE_ERRORS "Warnings are errors" ON)
  38
  39 # Ensure that python is present
  40 find_program(PYTHON NAMES python2.7 python2 python)
  41 if (PYTHON STREQUAL "PYTHON-NOTFOUND")
  42     message(FATAL_ERROR "PYTHON not found: Please install Python 2.7.9 or later from https://www.python.org/downloads/")
  43 endif()
  44
  45 # Ensure other tools are present
  46 if (WIN32)
  47     if(CLR_CMAKE_HOST_ARCH STREQUAL arm)
  48
  49       # Confirm that Windows SDK is present
  50       if(NOT DEFINED CMAKE_VS_WINDOWS_TARGET_PLATFORM_VERSION OR CMAKE_VS_WINDOWS_TARGET_PLATFORM_VERSION STREQUAL "" )
  51               message(FATAL_ERROR "Windows SDK is required for the Arm32 build.")
  52       else()
  53               message("Using Windows SDK version ${CMAKE_VS_WINDOWS_TARGET_PLATFORM_VERSION}")
  54       endif()
  55
  56       # Explicitly specify the assembler to be used for Arm32 compile
  57       if($ENV{__VSVersion} STREQUAL "vs2015")
  58         file(TO_CMAKE_PATH "$ENV{VCINSTALLDIR}\\bin\\x86_arm\\armasm.exe" CMAKE_ASM_COMPILER)
  59       else()
  60         file(TO_CMAKE_PATH "$ENV{VCToolsInstallDir}\\bin\\HostX86\\arm\\armasm.exe" CMAKE_ASM_COMPILER)
  61       endif()
  62
  63       set(CMAKE_ASM_MASM_COMPILER ${CMAKE_ASM_COMPILER})
  64       message("CMAKE_ASM_MASM_COMPILER explicitly set to: ${CMAKE_ASM_MASM_COMPILER}")
  65
  66       # Enable generic assembly compilation to avoid CMake generate VS proj files that explicitly
  67       # use ml[64].exe as the assembler.
  68       enable_language(ASM)
  69     else()
  70       enable_language(ASM_MASM)
  71     endif()
  72
  73     # Ensure that MC is present
  74     find_program(MC mc)
  75     if (MC STREQUAL "MC-NOTFOUND")
  76         message(FATAL_ERROR "MC not found")
  77     endif()
  78
  79     if (CLR_CMAKE_HOST_ARCH STREQUAL arm64)
  80       # CMAKE_CXX_COMPILER will default to the compiler installed with
  81       # Visual studio. Overwrite it to the compiler on the path.
  82       # TODO, remove when cmake generator supports Arm64 as a target.
  83       find_program(PATH_CXX_COMPILER cl)
  84       set(CMAKE_CXX_COMPILER ${PATH_CXX_COMPILER})
  85       message("Overwriting the CMAKE_CXX_COMPILER.")
  86       message(CMAKE_CXX_COMPILER found:${CMAKE_CXX_COMPILER})
  87     endif()
  88
  89 else (WIN32)
  90     enable_language(ASM)
  91
  92     # Ensure that awk is present
  93     find_program(AWK awk)
  94     if (AWK STREQUAL "AWK-NOTFOUND")
  95         message(FATAL_ERROR "AWK not found")
  96     endif()
  97
  98     # Try to locate the paxctl tool. Failure to find it is not fatal,
  99     # but the generated executables won't work on a system where PAX is set
 100     # to prevent applications to create executable memory mappings.
 101     find_program(PAXCTL paxctl)
 102
 103     if (CMAKE_SYSTEM_NAME STREQUAL Darwin)
 104
 105       # Ensure that dsymutil and strip are present
 106       find_program(DSYMUTIL dsymutil)
 107       if (DSYMUTIL STREQUAL "DSYMUTIL-NOTFOUND")
 108           message(FATAL_ERROR "dsymutil not found")
 109       endif()
 110
 111       find_program(STRIP strip)
 112       if (STRIP STREQUAL "STRIP-NOTFOUND")
 113           message(FATAL_ERROR "strip not found")
 114       endif()
 115
 116     else (CMAKE_SYSTEM_NAME STREQUAL Darwin)
 117
 118       # Ensure that objcopy is present
 119       if (CLR_UNIX_CROSS_BUILD AND NOT DEFINED CLR_CROSS_COMPONENTS_BUILD)
 120         if (CMAKE_SYSTEM_PROCESSOR STREQUAL armv7l OR CMAKE_SYSTEM_PROCESSOR STREQUAL aarch64 OR CMAKE_SYSTEM_PROCESSOR STREQUAL arm)
 121           find_program(OBJCOPY ${TOOLCHAIN}-objcopy)
 122         elseif(CMAKE_SYSTEM_PROCESSOR STREQUAL i686)
 123           find_program(OBJCOPY objcopy)
 124         else()
 125           clr_unknown_arch()
 126         endif()
 127       else()
 128         find_program(OBJCOPY objcopy)
 129       endif()
 130
 131       if (OBJCOPY STREQUAL "OBJCOPY-NOTFOUND")
 132           message(FATAL_ERROR "objcopy not found")
 133       endif()
 134
 135     endif (CMAKE_SYSTEM_NAME STREQUAL Darwin)
 136 endif(WIN32)
 137
 138 #----------------------------------------
 139 # Detect and set platform variable names
 140 #     - for non-windows build platform & architecture is detected using inbuilt CMAKE variables and cross target component configure
 141 #     - for windows we use the passed in parameter to CMAKE to determine build arch
 142 #----------------------------------------
 143 if(CMAKE_SYSTEM_NAME STREQUAL Linux)
 144     set(CLR_CMAKE_PLATFORM_UNIX 1)
 145     if(CLR_CROSS_COMPONENTS_BUILD)
 146         # CMAKE_HOST_SYSTEM_PROCESSOR returns the value of `uname -p` on host.
 147         if(CMAKE_HOST_SYSTEM_PROCESSOR STREQUAL x86_64 OR CMAKE_HOST_SYSTEM_PROCESSOR STREQUAL amd64)
 148             if(CLR_CMAKE_TARGET_ARCH STREQUAL "arm")
 149                 set(CLR_CMAKE_PLATFORM_UNIX_X86 1)
 150             else()
 151                 set(CLR_CMAKE_PLATFORM_UNIX_AMD64 1)
 152             endif()
 153         elseif(CMAKE_HOST_SYSTEM_PROCESSOR STREQUAL i686)
 154             set(CLR_CMAKE_PLATFORM_UNIX_X86 1)
 155         else()
 156             clr_unknown_arch()
 157         endif()
 158     else()
 159         # CMAKE_SYSTEM_PROCESSOR returns the value of `uname -p` on target.
 160         # For the AMD/Intel 64bit architecture two different strings are common.
 161         # Linux and Darwin identify it as "x86_64" while FreeBSD and netbsd uses the
 162         # "amd64" string. Accept either of the two here.
 163         if(CMAKE_SYSTEM_PROCESSOR STREQUAL x86_64 OR CMAKE_SYSTEM_PROCESSOR STREQUAL amd64)
 164             set(CLR_CMAKE_PLATFORM_UNIX_AMD64 1)
 165         elseif(CMAKE_SYSTEM_PROCESSOR STREQUAL armv7l)
 166             set(CLR_CMAKE_PLATFORM_UNIX_ARM 1)
 167         elseif(CMAKE_SYSTEM_PROCESSOR STREQUAL arm)
 168             set(CLR_CMAKE_PLATFORM_UNIX_ARM 1)
 169         elseif(CMAKE_SYSTEM_PROCESSOR STREQUAL aarch64)
 170             set(CLR_CMAKE_PLATFORM_UNIX_ARM64 1)
 171         elseif(CMAKE_SYSTEM_PROCESSOR STREQUAL i686)
 172             set(CLR_CMAKE_PLATFORM_UNIX_X86 1)
 173         else()
 174             clr_unknown_arch()
 175         endif()
 176     endif()
 177     set(CLR_CMAKE_PLATFORM_LINUX 1)
 178
 179     # Detect Linux ID
 180     if(DEFINED CLR_CMAKE_LINUX_ID)
 181         if(CLR_CMAKE_LINUX_ID STREQUAL ubuntu)
 182             set(CLR_CMAKE_TARGET_UBUNTU_LINUX 1)
 183         elseif(CLR_CMAKE_LINUX_ID STREQUAL tizen)
 184             set(CLR_CMAKE_TARGET_TIZEN_LINUX 1)
 185         elseif(CLR_CMAKE_LINUX_ID STREQUAL alpine)
 186             set(CLR_CMAKE_PLATFORM_ALPINE_LINUX 1)
 187         endif()
 188         if(CLR_CMAKE_LINUX_ID STREQUAL ubuntu)
 189             set(CLR_CMAKE_PLATFORM_UBUNTU_LINUX 1)
 190         endif()
 191     endif(DEFINED CLR_CMAKE_LINUX_ID)
 192 endif(CMAKE_SYSTEM_NAME STREQUAL Linux)
 193
 194 if(CMAKE_SYSTEM_NAME STREQUAL Darwin)
 195   set(CLR_CMAKE_PLATFORM_UNIX 1)
 196   set(CLR_CMAKE_PLATFORM_UNIX_AMD64 1)
 197   set(CLR_CMAKE_PLATFORM_DARWIN 1)
 198   if(CMAKE_VERSION VERSION_LESS "3.4.0")
 199     set(CMAKE_ASM_COMPILE_OBJECT "${CMAKE_C_COMPILER} <FLAGS> <DEFINES> -o <OBJECT> -c <SOURCE>")
 200   else()
 201     set(CMAKE_ASM_COMPILE_OBJECT "${CMAKE_C_COMPILER} <FLAGS> <DEFINES> <INCLUDES> -o <OBJECT> -c <SOURCE>")
 202   endif(CMAKE_VERSION VERSION_LESS "3.4.0")
 203 endif(CMAKE_SYSTEM_NAME STREQUAL Darwin)
 204
 205 if(CMAKE_SYSTEM_NAME STREQUAL FreeBSD)
 206   set(CLR_CMAKE_PLATFORM_UNIX 1)
 207   set(CLR_CMAKE_PLATFORM_UNIX_AMD64 1)
 208   set(CLR_CMAKE_PLATFORM_FREEBSD 1)
 209 endif(CMAKE_SYSTEM_NAME STREQUAL FreeBSD)
 210
 211 if(CMAKE_SYSTEM_NAME STREQUAL OpenBSD)
 212   set(CLR_CMAKE_PLATFORM_UNIX 1)
 213   set(CLR_CMAKE_PLATFORM_UNIX_AMD64 1)
 214   set(CLR_CMAKE_PLATFORM_OPENBSD 1)
 215 endif(CMAKE_SYSTEM_NAME STREQUAL OpenBSD)
 216
 217 if(CMAKE_SYSTEM_NAME STREQUAL NetBSD)
 218   set(CLR_CMAKE_PLATFORM_UNIX 1)
 219   set(CLR_CMAKE_PLATFORM_UNIX_AMD64 1)
 220   set(CLR_CMAKE_PLATFORM_NETBSD 1)
 221 endif(CMAKE_SYSTEM_NAME STREQUAL NetBSD)
 222
 223 if(CMAKE_SYSTEM_NAME STREQUAL SunOS)
 224   set(CLR_CMAKE_PLATFORM_UNIX 1)
 225   EXECUTE_PROCESS(
 226     COMMAND isainfo -n
 227     OUTPUT_VARIABLE SUNOS_NATIVE_INSTRUCTION_SET
 228     )
 229   if(SUNOS_NATIVE_INSTRUCTION_SET MATCHES "amd64")
 230     set(CLR_CMAKE_PLATFORM_UNIX_AMD64 1)
 231     set(CMAKE_SYSTEM_PROCESSOR "amd64")
 232   else()
 233     clr_unknown_arch()
 234   endif()
 235   set(CLR_CMAKE_PLATFORM_SUNOS 1)
 236 endif(CMAKE_SYSTEM_NAME STREQUAL SunOS)
 237
 238 #--------------------------------------------
 239 # This repo builds two set of binaries
 240 # 1. binaries which execute on target arch machine
 241 #        - for such binaries host architecture & target architecture are same
 242 #        - eg. coreclr.dll
 243 # 2. binaries which execute on host machine but target another architecture
 244 #        - host architecture is different from target architecture
 245 #        - eg. crossgen.exe - runs on x64 machine and generates nis targeting arm64
 246 #        - for complete list of such binaries refer to file crosscomponents.cmake
 247 #-------------------------------------------------------------
 248 # Set HOST architecture variables
 249 if(CLR_CMAKE_PLATFORM_UNIX_ARM)
 250     set(CLR_CMAKE_PLATFORM_ARCH_ARM 1)
 251     set(CLR_CMAKE_HOST_ARCH "arm")
 252 elseif(CLR_CMAKE_PLATFORM_UNIX_ARM64)
 253     set(CLR_CMAKE_PLATFORM_ARCH_ARM64 1)
 254     set(CLR_CMAKE_HOST_ARCH "arm64")
 255 elseif(CLR_CMAKE_PLATFORM_UNIX_AMD64)
 256     set(CLR_CMAKE_PLATFORM_ARCH_AMD64 1)
 257     set(CLR_CMAKE_HOST_ARCH "x64")
 258 elseif(CLR_CMAKE_PLATFORM_UNIX_X86)
 259     set(CLR_CMAKE_PLATFORM_ARCH_I386 1)
 260     set(CLR_CMAKE_HOST_ARCH "x86")
 261 elseif(WIN32)
 262     # CLR_CMAKE_HOST_ARCH is passed in as param to cmake
 263     if (CLR_CMAKE_HOST_ARCH STREQUAL x64)
 264         set(CLR_CMAKE_PLATFORM_ARCH_AMD64 1)
 265     elseif(CLR_CMAKE_HOST_ARCH STREQUAL x86)
 266         set(CLR_CMAKE_PLATFORM_ARCH_I386 1)
 267     elseif(CLR_CMAKE_HOST_ARCH STREQUAL arm)
 268         set(CLR_CMAKE_PLATFORM_ARCH_ARM 1)
 269     elseif(CLR_CMAKE_HOST_ARCH STREQUAL arm64)
 270         set(CLR_CMAKE_PLATFORM_ARCH_ARM64 1)
 271     else()
 272         clr_unknown_arch()
 273     endif()
 274 endif()
 275
 276 # Set TARGET architecture variables
 277 # Target arch will be a cmake param (optional) for both windows as well as non-windows build
 278 # if target arch is not specified then host & target are same
 279 if(NOT DEFINED CLR_CMAKE_TARGET_ARCH OR CLR_CMAKE_TARGET_ARCH STREQUAL "" )
 280   set(CLR_CMAKE_TARGET_ARCH ${CLR_CMAKE_HOST_ARCH})
 281 endif()
 282
 283 # Set target architecture variables
 284 if (CLR_CMAKE_TARGET_ARCH STREQUAL x64)
 285     set(CLR_CMAKE_TARGET_ARCH_AMD64 1)
 286   elseif(CLR_CMAKE_TARGET_ARCH STREQUAL x86)
 287     set(CLR_CMAKE_TARGET_ARCH_I386 1)
 288   elseif(CLR_CMAKE_TARGET_ARCH STREQUAL arm64)
 289     set(CLR_CMAKE_TARGET_ARCH_ARM64 1)
 290   elseif(CLR_CMAKE_TARGET_ARCH STREQUAL arm)
 291     set(CLR_CMAKE_TARGET_ARCH_ARM 1)
 292   else()
 293     clr_unknown_arch()
 294 endif()
 295
 296 # check if host & target arch combination are valid
 297 if(NOT(CLR_CMAKE_TARGET_ARCH STREQUAL CLR_CMAKE_HOST_ARCH))
 298     if(NOT((CLR_CMAKE_PLATFORM_ARCH_AMD64 AND CLR_CMAKE_TARGET_ARCH_ARM64) OR (CLR_CMAKE_PLATFORM_ARCH_I386 AND CLR_CMAKE_TARGET_ARCH_ARM)))
 299         message(FATAL_ERROR "Invalid host and target arch combination")
 300     endif()
 301 endif()
 302
 303 #-----------------------------------------------------
 304 # Initialize Cmake compiler flags and other variables
 305 #-----------------------------------------------------
 306
 307 if (CMAKE_CONFIGURATION_TYPES) # multi-configuration generator?
 308     set(CMAKE_CONFIGURATION_TYPES "Debug;Checked;Release;RelWithDebInfo" CACHE STRING "" FORCE)
 309 endif (CMAKE_CONFIGURATION_TYPES)
 310
 311 set(CMAKE_C_FLAGS_CHECKED ${CLR_C_FLAGS_CHECKED_INIT} CACHE STRING "Flags used by the compiler during checked builds.")
 312 set(CMAKE_CXX_FLAGS_CHECKED ${CLR_CXX_FLAGS_CHECKED_INIT} CACHE STRING "Flags used by the compiler during checked builds.")
 313 set(CMAKE_EXE_LINKER_FLAGS_CHECKED "")
 314 set(CMAKE_SHARED_LINKER_FLAGS_CHECKED "")
 315
 316 set(CMAKE_CXX_STANDARD_LIBRARIES "") # do not link against standard win32 libs i.e. kernel32, uuid, user32, etc.
 317
 318 if (WIN32)
 319   # For multi-configuration toolset (as Visual Studio)
 320   # set the different configuration defines.
 321   foreach (Config DEBUG CHECKED RELEASE RELWITHDEBINFO)
 322     foreach (Definition IN LISTS CLR_DEFINES_${Config}_INIT)
 323       set_property(DIRECTORY APPEND PROPERTY COMPILE_DEFINITIONS $<$<CONFIG:${Config}>:${Definition}>)
 324     endforeach (Definition)
 325   endforeach (Config)
 326
 327   set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} /GUARD:CF")
 328   set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} /GUARD:CF")
 329
 330   # Linker flags
 331   #
 332   set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} /MANIFEST:NO") #Do not create Side-by-Side Assembly Manifest
 333
 334   if (CLR_CMAKE_PLATFORM_ARCH_ARM)
 335     set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} /SUBSYSTEM:WINDOWS,6.02") #windows subsystem - arm minimum is 6.02
 336   elseif(CLR_CMAKE_PLATFORM_ARCH_ARM64)
 337     set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} /SUBSYSTEM:WINDOWS,6.03") #windows subsystem - arm64 minimum is 6.03
 338   else ()
 339     set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} /SUBSYSTEM:WINDOWS,6.01") #windows subsystem
 340   endif ()
 341
 342   set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} /LARGEADDRESSAWARE") # can handle addresses larger than 2 gigabytes
 343   set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} /NXCOMPAT") #Compatible with Data Execution Prevention
 344   set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} /DYNAMICBASE") #Use address space layout randomization
 345   set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} /PDBCOMPRESS") #shrink pdb size
 346   set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} /DEBUG")
 347   set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} /IGNORE:4197,4013,4254,4070,4221")
 348
 349   set(CMAKE_STATIC_LINKER_FLAGS "${CMAKE_STATIC_LINKER_FLAGS} /IGNORE:4221")
 350
 351   set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} /DEBUG /PDBCOMPRESS")
 352   set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} /STACK:1572864")
 353
 354   # Temporarily disable incremental link due to incremental linking CFG bug crashing crossgen.
 355   # See https://github.com/dotnet/coreclr/issues/12592
 356   # This has been fixed in VS 2017 Update 5 but we're keeping this around until everyone is off
 357   # the versions that have the bug. The bug manifests itself as a bad crash.
 358   set(NO_INCREMENTAL_LINKER_FLAGS "/INCREMENTAL:NO")
 359
 360   # Debug build specific flags
 361   set(CMAKE_SHARED_LINKER_FLAGS_DEBUG "/NOVCFEATURE ${NO_INCREMENTAL_LINKER_FLAGS}")
 362   set(CMAKE_EXE_LINKER_FLAGS_DEBUG "${NO_INCREMENTAL_LINKER_FLAGS}")
 363
 364   # Checked build specific flags
 365   set(CMAKE_SHARED_LINKER_FLAGS_CHECKED "${CMAKE_SHARED_LINKER_FLAGS_CHECKED} /OPT:REF /OPT:NOICF /NOVCFEATURE ${NO_INCREMENTAL_LINKER_FLAGS}")
 366   set(CMAKE_STATIC_LINKER_FLAGS_CHECKED "${CMAKE_STATIC_LINKER_FLAGS_CHECKED}")
 367   set(CMAKE_EXE_LINKER_FLAGS_CHECKED "${CMAKE_EXE_LINKER_FLAGS_CHECKED} /OPT:REF /OPT:NOICF ${NO_INCREMENTAL_LINKER_FLAGS}")
 368
 369   # Release build specific flags
 370   set(CMAKE_SHARED_LINKER_FLAGS_RELEASE "${CMAKE_SHARED_LINKER_FLAGS_RELEASE} /LTCG /OPT:REF /OPT:ICF ${NO_INCREMENTAL_LINKER_FLAGS}")
 371   set(CMAKE_STATIC_LINKER_FLAGS_RELEASE "${CMAKE_STATIC_LINKER_FLAGS_RELEASE} /LTCG")
 372   set(CMAKE_EXE_LINKER_FLAGS_RELEASE "${CMAKE_EXE_LINKER_FLAGS_RELEASE} /LTCG /OPT:REF /OPT:ICF ${NO_INCREMENTAL_LINKER_FLAGS}")
 373
 374   # ReleaseWithDebugInfo build specific flags
 375   set(CMAKE_SHARED_LINKER_FLAGS_RELWITHDEBINFO "${CMAKE_SHARED_LINKER_FLAGS_RELWITHDEBINFO} /LTCG /OPT:REF /OPT:ICF ${NO_INCREMENTAL_LINKER_FLAGS}")
 376   set(CMAKE_STATIC_LINKER_FLAGS_RELWITHDEBINFO "${CMAKE_STATIC_LINKER_FLAGS_RELWITHDEBINFO} /LTCG")
 377   set(CMAKE_EXE_LINKER_FLAGS_RELWITHDEBINFO "${CMAKE_EXE_LINKER_FLAGS_RELWITHDEBINFO} /LTCG /OPT:REF /OPT:ICF ${NO_INCREMENTAL_LINKER_FLAGS}")
 378
 379   # Temporary until cmake has VS generators for arm64
 380   if(CLR_CMAKE_PLATFORM_ARCH_ARM64)
 381     set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} /machine:arm64")
 382     set(CMAKE_STATIC_LINKER_FLAGS "${CMAKE_STATIC_LINKER_FLAGS} /machine:arm64")
 383     set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} /machine:arm64")
 384   endif(CLR_CMAKE_PLATFORM_ARCH_ARM64)
 385
 386   # Force uCRT to be dynamically linked for Release build
 387   set(CMAKE_SHARED_LINKER_FLAGS_RELEASE "${CMAKE_SHARED_LINKER_FLAGS_RELEASE} /NODEFAULTLIB:libucrt.lib /DEFAULTLIB:ucrt.lib")
 388   set(CMAKE_EXE_LINKER_FLAGS_RELEASE "${CMAKE_EXE_LINKER_FLAGS_RELEASE} /NODEFAULTLIB:libucrt.lib /DEFAULTLIB:ucrt.lib")
 389   set(CMAKE_SHARED_LINKER_FLAGS_RELWITHDEBINFO "${CMAKE_SHARED_LINKER_FLAGS_RELWITHDEBINFO} /NODEFAULTLIB:libucrt.lib /DEFAULTLIB:ucrt.lib")
 390   set(CMAKE_EXE_LINKER_FLAGS_RELWITHDEBINFO "${CMAKE_EXE_LINKER_FLAGS_RELWITHDEBINFO} /NODEFAULTLIB:libucrt.lib /DEFAULTLIB:ucrt.lib")
 391
 392 elseif (CLR_CMAKE_PLATFORM_UNIX)
 393   # Set the values to display when interactively configuring CMAKE_BUILD_TYPE
 394   set_property(CACHE CMAKE_BUILD_TYPE PROPERTY STRINGS "DEBUG;CHECKED;RELEASE;RELWITHDEBINFO")
 395
 396   # Use uppercase CMAKE_BUILD_TYPE for the string comparisons below
 397   string(TOUPPER ${CMAKE_BUILD_TYPE} UPPERCASE_CMAKE_BUILD_TYPE)
 398
 399   # For single-configuration toolset
 400   # set the different configuration defines.
 401   if (UPPERCASE_CMAKE_BUILD_TYPE STREQUAL DEBUG)
 402     # First DEBUG
 403     set_property(DIRECTORY  PROPERTY COMPILE_DEFINITIONS ${CLR_DEFINES_DEBUG_INIT})
 404   elseif (UPPERCASE_CMAKE_BUILD_TYPE STREQUAL CHECKED)
 405     # Then CHECKED
 406     set_property(DIRECTORY PROPERTY COMPILE_DEFINITIONS ${CLR_DEFINES_CHECKED_INIT})
 407   elseif (UPPERCASE_CMAKE_BUILD_TYPE STREQUAL RELEASE)
 408     # Then RELEASE
 409     set_property(DIRECTORY PROPERTY COMPILE_DEFINITIONS ${CLR_DEFINES_RELEASE_INIT})
 410   elseif (UPPERCASE_CMAKE_BUILD_TYPE STREQUAL RELWITHDEBINFO)
 411     # And then RELWITHDEBINFO
 412     set_property(DIRECTORY APPEND PROPERTY COMPILE_DEFINITIONS ${CLR_DEFINES_RELWITHDEBINFO_INIT})
 413   else ()
 414     message(FATAL_ERROR "Unknown build type! Set CMAKE_BUILD_TYPE to DEBUG, CHECKED, RELEASE, or RELWITHDEBINFO!")
 415   endif ()
 416
 417   # set the CLANG sanitizer flags for debug build
 418   if(UPPERCASE_CMAKE_BUILD_TYPE STREQUAL DEBUG OR UPPERCASE_CMAKE_BUILD_TYPE STREQUAL CHECKED)
 419     # obtain settings from running enablesanitizers.sh
 420     string(FIND "$ENV{DEBUG_SANITIZERS}" "asan" __ASAN_POS)
 421     string(FIND "$ENV{DEBUG_SANITIZERS}" "ubsan" __UBSAN_POS)
 422     if ((${__ASAN_POS} GREATER -1) OR (${__UBSAN_POS} GREATER -1))
 423       set(CLR_SANITIZE_CXX_FLAGS "${CLR_SANITIZE_CXX_FLAGS} -fsanitize-blacklist=${CMAKE_CURRENT_SOURCE_DIR}/sanitizerblacklist.txt -fsanitize=")
 424       set(CLR_SANITIZE_LINK_FLAGS "${CLR_SANITIZE_LINK_FLAGS} -fsanitize=")
 425       if (${__ASAN_POS} GREATER -1)
 426         set(CLR_SANITIZE_CXX_FLAGS "${CLR_SANITIZE_CXX_FLAGS}address,")
 427         set(CLR_SANITIZE_LINK_FLAGS "${CLR_SANITIZE_LINK_FLAGS}address,")
 428         add_definitions(-DHAS_ASAN)
 429         message("Address Sanitizer (asan) enabled")
 430       endif ()
 431       if (${__UBSAN_POS} GREATER -1)
 432         # all sanitizier flags are enabled except alignment (due to heavy use of __unaligned modifier)
 433         set(CLR_SANITIZE_CXX_FLAGS "${CLR_SANITIZE_CXX_FLAGS}bool,bounds,enum,float-cast-overflow,float-divide-by-zero,function,integer,nonnull-attribute,null,object-size,return,returns-nonnull-attribute,shift,unreachable,vla-bound,vptr")
 434         set(CLR_SANITIZE_LINK_FLAGS "${CLR_SANITIZE_LINK_FLAGS}undefined")
 435         message("Undefined Behavior Sanitizer (ubsan) enabled")
 436       endif ()
 437
 438       # -fdata-sections -ffunction-sections: each function has own section instead of one per .o file (needed for --gc-sections)
 439       # -fPIC: enable Position Independent Code normally just for shared libraries but required when linking with address sanitizer
 440       # -O1: optimization level used instead of -O0 to avoid compile error "invalid operand for inline asm constraint"
 441       set(CMAKE_CXX_FLAGS_DEBUG "${CMAKE_CXX_FLAGS_DEBUG} ${CLR_SANITIZE_CXX_FLAGS} -fdata-sections -ffunction-sections -fPIC -O1")
 442       set(CMAKE_CXX_FLAGS_CHECKED "${CMAKE_CXX_FLAGS_CHECKED} ${CLR_SANITIZE_CXX_FLAGS} -fdata-sections -ffunction-sections -fPIC -O1")
 443
 444       set(CMAKE_EXE_LINKER_FLAGS_DEBUG "${CMAKE_EXE_LINKER_FLAGS_DEBUG} ${CLR_SANITIZE_LINK_FLAGS}")
 445       set(CMAKE_EXE_LINKER_FLAGS_CHECKED "${CMAKE_EXE_LINKER_FLAGS_CHECKED} ${CLR_SANITIZE_LINK_FLAGS}")
 446
 447       # -Wl and --gc-sections: drop unused sections\functions (similar to Windows /Gy function-level-linking)
 448       set(CMAKE_SHARED_LINKER_FLAGS_DEBUG "${CMAKE_SHARED_LINKER_FLAGS_DEBUG} ${CLR_SANITIZE_LINK_FLAGS} -Wl,--gc-sections")
 449       set(CMAKE_SHARED_LINKER_FLAGS_CHECKED "${CMAKE_SHARED_LINKER_FLAGS_CHECKED} ${CLR_SANITIZE_LINK_FLAGS} -Wl,--gc-sections")
 450     endif ()
 451   endif(UPPERCASE_CMAKE_BUILD_TYPE STREQUAL DEBUG OR UPPERCASE_CMAKE_BUILD_TYPE STREQUAL CHECKED)
 452 endif(WIN32)
 453
 454 # CLR_ADDITIONAL_LINKER_FLAGS - used for passing additional arguments to linker
 455 # CLR_ADDITIONAL_COMPILER_OPTIONS - used for passing additional arguments to compiler
 456 #
 457 # For example:
 458 #       ./build-native.sh cmakeargs "-DCLR_ADDITIONAL_COMPILER_OPTIONS=<...>" cmakeargs "-DCLR_ADDITIONAL_LINKER_FLAGS=<...>"
 459 #
 460 if(CLR_CMAKE_PLATFORM_UNIX)
 461     set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} ${CLR_ADDITIONAL_LINKER_FLAGS}")
 462     set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} ${CLR_ADDITIONAL_LINKER_FLAGS}" )
 463     add_compile_options(${CLR_ADDITIONAL_COMPILER_OPTIONS})
 464 endif(CLR_CMAKE_PLATFORM_UNIX)
 465
 466 if(CLR_CMAKE_PLATFORM_LINUX)
 467   set(CMAKE_ASM_FLAGS "${CMAKE_ASM_FLAGS} -Wa,--noexecstack")
 468   set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} -Wl,--build-id=sha1")
 469   set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -Wl,--build-id=sha1")
 470 endif(CLR_CMAKE_PLATFORM_LINUX)
 471
 472 #------------------------------------
 473 # Definitions (for platform)
 474 #-----------------------------------
 475 if (CLR_CMAKE_PLATFORM_ARCH_AMD64)
 476   add_definitions(-D_AMD64_)
 477   add_definitions(-D_WIN64)
 478   add_definitions(-DAMD64)
 479   add_definitions(-DBIT64=1)
 480 elseif (CLR_CMAKE_PLATFORM_ARCH_I386)
 481   add_definitions(-D_X86_)
 482 elseif (CLR_CMAKE_PLATFORM_ARCH_ARM)
 483   add_definitions(-D_ARM_)
 484   add_definitions(-DARM)
 485 elseif (CLR_CMAKE_PLATFORM_ARCH_ARM64)
 486   add_definitions(-D_ARM64_)
 487   add_definitions(-DARM64)
 488   add_definitions(-D_WIN64)
 489   add_definitions(-DBIT64=1)
 490 else ()
 491   clr_unknown_arch()
 492 endif ()
 493
 494 if (CLR_CMAKE_PLATFORM_UNIX)
 495   if(CLR_CMAKE_PLATFORM_LINUX)
 496     if(CLR_CMAKE_PLATFORM_UNIX_AMD64)
 497       message("Detected Linux x86_64")
 498       add_definitions(-DLINUX64)
 499     elseif(CLR_CMAKE_PLATFORM_UNIX_ARM)
 500       message("Detected Linux ARM")
 501       add_definitions(-DLINUX32)
 502     elseif(CLR_CMAKE_PLATFORM_UNIX_ARM64)
 503       message("Detected Linux ARM64")
 504       add_definitions(-DLINUX64)
 505     elseif(CLR_CMAKE_PLATFORM_UNIX_X86)
 506       message("Detected Linux i686")
 507       add_definitions(-DLINUX32)
 508     else()
 509       clr_unknown_arch()
 510     endif()
 511   endif(CLR_CMAKE_PLATFORM_LINUX)
 512 endif(CLR_CMAKE_PLATFORM_UNIX)
 513
 514 if (CLR_CMAKE_PLATFORM_UNIX)
 515   add_definitions(-DPLATFORM_UNIX=1)
 516
 517   if(CLR_CMAKE_PLATFORM_DARWIN)
 518     message("Detected OSX x86_64")
 519   endif(CLR_CMAKE_PLATFORM_DARWIN)
 520
 521   if(CLR_CMAKE_PLATFORM_FREEBSD)
 522     message("Detected FreeBSD amd64")
 523   endif(CLR_CMAKE_PLATFORM_FREEBSD)
 524
 525   if(CLR_CMAKE_PLATFORM_NETBSD)
 526     message("Detected NetBSD amd64")
 527   endif(CLR_CMAKE_PLATFORM_NETBSD)
 528 endif(CLR_CMAKE_PLATFORM_UNIX)
 529
 530 if (WIN32)
 531   # Define the CRT lib references that link into Desktop imports
 532   set(STATIC_MT_CRT_LIB  "libcmt$<$<OR:$<CONFIG:Debug>,$<CONFIG:Checked>>:d>.lib")
 533   set(STATIC_MT_VCRT_LIB  "libvcruntime$<$<OR:$<CONFIG:Debug>,$<CONFIG:Checked>>:d>.lib")
 534   set(STATIC_MT_CPP_LIB  "libcpmt$<$<OR:$<CONFIG:Debug>,$<CONFIG:Checked>>:d>.lib")
 535 endif(WIN32)
 536
 537 # Architecture specific files folder name
 538 if (CLR_CMAKE_TARGET_ARCH_AMD64)
 539     set(ARCH_SOURCES_DIR amd64)
 540 elseif (CLR_CMAKE_TARGET_ARCH_ARM64)
 541     set(ARCH_SOURCES_DIR arm64)
 542 elseif (CLR_CMAKE_TARGET_ARCH_ARM)
 543     set(ARCH_SOURCES_DIR arm)
 544 elseif (CLR_CMAKE_TARGET_ARCH_I386)
 545     set(ARCH_SOURCES_DIR i386)
 546 else ()
 547     clr_unknown_arch()
 548 endif ()
 549
 550 #--------------------------------------
 551 # Compile Options
 552 #--------------------------------------
 553 include(compileoptions.cmake)
 554
 555 #----------------------------------------------------
 556 # Cross target Component build specific configuration
 557 #----------------------------------------------------
 558 if(CLR_CROSS_COMPONENTS_BUILD)
 559   include(crosscomponents.cmake)
 560 endif(CLR_CROSS_COMPONENTS_BUILD)
 561
 562 #-------------------
 563 # Enable PGO support
 564 #-------------------
 565 include(pgosupport.cmake)
 566
 567 #-----------------------------------------
 568 # Add Projects
 569 #     - project which require platform header not clr's
 570 #     - do not depend on clr's compile definitions
 571 #-----------------------------------------
 572 if(CLR_CMAKE_PLATFORM_UNIX AND NOT DEFINED CLR_CROSS_COMPONENTS_BUILD)
 573     add_subdirectory(src/corefx)
 574 endif()
 575
 576 if(CLR_CMAKE_PLATFORM_UNIX)
 577     add_subdirectory(src/ToolBox/SOS/lldbplugin)
 578     add_subdirectory(src/pal)
 579     add_subdirectory(src/coreclr/hosts)
 580     add_subdirectory(src/ildasm/unixcoreclrloader)
 581 endif(CLR_CMAKE_PLATFORM_UNIX)
 582
 583 # Add this subdir. We install the headers for the jit.
 584 add_subdirectory(src/pal/prebuilt/inc)
 585
 586 add_subdirectory(src/debug/debug-pal)
 587
 588 if(WIN32)
 589   add_subdirectory(src/gc/sample)
 590 endif()
 591
 592 # Above projects do not build with these compile options
 593 # All of the compiler options are specified in file compileoptions.cmake
 594 # Do not add any new options here. They should be added in compileoptions.cmake
 595 if(WIN32)
 596   add_compile_options(/FIWarningControl.h) # force include of WarningControl.h
 597   add_compile_options(/Zl) # omit default library name in .OBJ
 598 endif(WIN32)
 599
 600 #------------------------------
 601 # Add Test Directory
 602 #------------------------------
 603 if(CLR_CMAKE_BUILD_TESTS)
 604   add_subdirectory(tests)
 605 endif(CLR_CMAKE_BUILD_TESTS)
 606
 607 #--------------------------------
 608 # Definition directives
 609 #  - all clr specific compile definitions should be included in this file
 610 #  - all clr specific feature variable should also be added in this file
 611 #----------------------------------
 612 include(clrdefinitions.cmake)
 613
 614 #-------------------------------------
 615 # Include directory directives
 616 #-------------------------------------
 617 # Include the basic prebuilt headers - required for getting fileversion resource details.
 618 include_directories("src/pal/prebuilt/inc")
 619 include_directories("bin/obj")
 620
 621 if(FEATURE_STANDALONE_GC)
 622   add_definitions(-DFEATURE_STANDALONE_GC)
 623   add_subdirectory(src/gc)
 624 endif(FEATURE_STANDALONE_GC)
 625
 626 if (CLR_CMAKE_PLATFORM_UNIX)
 627   include_directories("src/pal/inc")
 628   include_directories("src/pal/inc/rt")
 629   include_directories("src/pal/src/safecrt")
 630 endif (CLR_CMAKE_PLATFORM_UNIX)
 631
 632 # Microsoft.Dotnet.BuildTools.Coreclr version
 633 set(BuildToolsVersion "1.0.4-prerelease")
 634 set(BuildToolsDir "${CLR_CMAKE_PACKAGES_DIR}/Microsoft.DotNet.BuildTools.CoreCLR/${BuildToolsVersion}")
 635
 636 #------------------------------
 637 # Add Product Directory
 638 #------------------------------
 639 add_subdirectory(src)
 640
 641 include(definitionsconsistencycheck.cmake)