CMakeLists.txt

   1 # The name of our project is "VULKAN". CMakeLists files in this project can
   2 # refer to the root source directory of the project as ${VULKAN_SOURCE_DIR} and
   3 # to the root binary directory of the project as ${VULKAN_BINARY_DIR}.
   4 cmake_minimum_required(VERSION 2.8.11)
   5
   6 # This must come before the project command.
   7 set(CMAKE_OSX_DEPLOYMENT_TARGET "10.12" CACHE STRING "Minimum OS X deployment version")
   8
   9 project (VULKAN)
  10 # set (CMAKE_VERBOSE_MAKEFILE 1)
  11
  12 # The API_NAME allows renaming builds to avoid conflicts with installed SDKs
  13 # The MAJOR number of the version we're building, used in naming
  14 # <api-name>-<major>.dll (and other files).
  15 set(API_NAME "Vulkan" CACHE STRING "API name to use when building")
  16 set(MAJOR "1")
  17 string(TOLOWER ${API_NAME} API_LOWERCASE)
  18
  19 set(CMAKE_MODULE_PATH ${CMAKE_MODULE_PATH} "${CMAKE_CURRENT_SOURCE_DIR}/cmake")
  20 find_package(PythonInterp 3 REQUIRED)
  21
  22 # If CMAKE 3.7+, use FindVulkan
  23 if (NOT CMAKE_VERSION VERSION_LESS 3.7.0)
  24     message(STATUS "Using find_package to locate Vulkan")
  25     find_package(Vulkan)
  26 endif()
  27
  28 option(USE_CCACHE "Use ccache" OFF)
  29 if (USE_CCACHE)
  30     find_program(CCACHE_FOUND ccache)
  31     if(CCACHE_FOUND)
  32         set_property(GLOBAL PROPERTY RULE_LAUNCH_COMPILE ccache)
  33         set_property(GLOBAL PROPERTY RULE_LAUNCH_LINK ccache)
  34     endif(CCACHE_FOUND)
  35 endif()
  36
  37 if(APPLE)
  38     # CMake versions 3 or later need CMAKE_MACOSX_RPATH defined.
  39     # This avoids the CMP0042 policy message.
  40     set(CMAKE_MACOSX_RPATH 1)
  41     # The "install" target for MacOS fixes up bundles in place.
  42     set(CMAKE_INSTALL_PREFIX ${CMAKE_BINARY_DIR})
  43 endif()
  44
  45 # Enable cmake folders
  46 set_property(GLOBAL PROPERTY USE_FOLDERS ON)
  47 set(LVL_TARGET_FOLDER lvl_cmake_targets)
  48
  49 if(CMAKE_SYSTEM_NAME STREQUAL "Linux" OR CMAKE_SYSTEM_NAME STREQUAL "Darwin")
  50     set(FALLBACK_CONFIG_DIRS "/etc/xdg" CACHE STRING
  51         "Search path to use when XDG_CONFIG_DIRS is unset or empty or the current process is SUID/SGID. Default is freedesktop compliant.")
  52     set(FALLBACK_DATA_DIRS "/usr/local/share:/usr/share" CACHE STRING
  53         "Search path to use when XDG_DATA_DIRS is unset or empty or the current process is SUID/SGID. Default is freedesktop compliant.")
  54 endif()
  55
  56 if(CMAKE_SYSTEM_NAME STREQUAL "Linux")
  57     include(FindPkgConfig)
  58     option(BUILD_WSI_XCB_SUPPORT "Build XCB WSI support" ON)
  59     option(BUILD_WSI_XLIB_SUPPORT "Build Xlib WSI support" ON)
  60     option(BUILD_WSI_WAYLAND_SUPPORT "Build Wayland WSI support" ON)
  61     option(BUILD_WSI_MIR_SUPPORT "Build Mir WSI support" OFF)
  62     set(DEMOS_WSI_SELECTION "XCB" CACHE STRING "Select WSI target for demos (XCB, XLIB, WAYLAND, MIR, DISPLAY)")
  63
  64     if (BUILD_WSI_XCB_SUPPORT)
  65         find_package(XCB REQUIRED)
  66     endif()
  67
  68     if (BUILD_WSI_XLIB_SUPPORT)
  69         find_package(X11 REQUIRED)
  70     endif()
  71
  72     if (BUILD_WSI_WAYLAND_SUPPORT)
  73         find_package(Wayland REQUIRED)
  74         include_directories(${WAYLAND_CLIENT_INCLUDE_DIR})
  75     endif()
  76
  77     if (BUILD_WSI_MIR_SUPPORT)
  78         find_package(Mir REQUIRED)
  79     endif()
  80
  81 endif()
  82
  83 set(SCRIPTS_DIR "${CMAKE_CURRENT_SOURCE_DIR}/scripts")
  84
  85 # Header file for CMake settings
  86 include_directories("${PROJECT_SOURCE_DIR}/include")
  87
  88 if (CMAKE_COMPILER_IS_GNUCC OR CMAKE_C_COMPILER_ID MATCHES "Clang")
  89     set(COMMON_COMPILE_FLAGS "-Wall -Wextra -Wno-unused-parameter -Wno-missing-field-initializers")
  90     set(COMMON_COMPILE_FLAGS "${COMMON_COMPILE_FLAGS} -fno-strict-aliasing -fno-builtin-memcmp")
  91
  92     # For GCC version 7.1 or greater, we need to disable the implicit fallthrough warning since
  93     # there's no consistent way to satisfy all compilers until they all accept the C++17 standard
  94     if (CMAKE_COMPILER_IS_GNUCC AND NOT (CMAKE_CXX_COMPILER_VERSION LESS 7.1))
  95         set(COMMON_COMPILE_FLAGS "${COMMON_COMPILE_FLAGS} -Wimplicit-fallthrough=0")
  96     endif()
  97
  98     if (APPLE)
  99         set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} ${COMMON_COMPILE_FLAGS}")
 100     else()
 101         set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -std=c99 ${COMMON_COMPILE_FLAGS}")
 102     endif()
 103     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} ${COMMON_COMPILE_FLAGS} -std=c++11 -fno-rtti")
 104     if (UNIX)
 105         set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -fvisibility=hidden")
 106         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -fvisibility=hidden")
 107     endif()
 108 endif()
 109
 110 if(WIN32)
 111     # Treat warnings as errors
 112     add_compile_options("$<$<CXX_COMPILER_ID:MSVC>:/WX>")
 113     # Disable RTTI
 114     add_compile_options("$<$<CXX_COMPILER_ID:MSVC>:/GR->")
 115     # Warn about nested declarations
 116     add_compile_options("$<$<CXX_COMPILER_ID:MSVC>:/w34456>")
 117     # Warn about potentially uninitialized variables
 118     add_compile_options("$<$<CXX_COMPILER_ID:MSVC>:/w34701>")
 119     add_compile_options("$<$<CXX_COMPILER_ID:MSVC>:/w34703>")
 120     # Warn about different indirection types.
 121     add_compile_options("$<$<CXX_COMPILER_ID:MSVC>:/w34057>")
 122     # Warn about signed/unsigned mismatch.
 123     add_compile_options("$<$<CXX_COMPILER_ID:MSVC>:/w34245>")
 124 endif()
 125
 126 if(NOT WIN32)
 127     set (BUILDTGT_DIR build)
 128     set (BINDATA_DIR Bin)
 129     set (LIBSOURCE_DIR Lib)
 130 else()
 131     # is WIN32
 132     option(DISABLE_BUILD_PATH_DECORATION "Disable the decoration of the gslang and SPIRV-Tools build path with MSVC build type info" OFF)
 133     option(DISABLE_BUILDTGT_DIR_DECORATION "Disable the decoration of the gslang and SPIRV-Tools build path with target info" OFF)
 134     option(ENABLE_WIN10_ONECORE "Link the loader with OneCore umbrella libraries" OFF)
 135
 136     # For Windows, since 32-bit and 64-bit items can co-exist, we build each in its own build directory.
 137     # 32-bit target data goes in build32, and 64-bit target data goes into build.  So, include/link the
 138     # appropriate data at build time.
 139     if (DISABLE_BUILDTGT_DIR_DECORATION)
 140         set (BUILDTGT_DIR "")
 141         set (BINDATA_DIR "")
 142         set (LIBSOURCE_DIR "")
 143     elseif (CMAKE_CL_64)
 144         set (BUILDTGT_DIR build)
 145         set (BINDATA_DIR Bin)
 146         set (LIBSOURCE_DIR Lib)
 147     else()
 148         set (BUILDTGT_DIR build32)
 149         set (BINDATA_DIR Bin32)
 150         set (LIBSOURCE_DIR Lib32)
 151     endif()
 152 endif()
 153
 154 option(BUILD_DEMOS "Build demos" ON)
 155 option(BUILD_ICD "Build icd" ON)
 156 option(CUSTOM_GLSLANG_BIN_ROOT "Use the user defined GLSLANG_BINARY_ROOT" OFF)
 157 option(CUSTOM_SPIRV_TOOLS_BIN_ROOT "Use the user defined SPIRV_TOOLS*BINARY_ROOT paths" OFF)
 158
 159 #Choose natural default paths for glslang and SPIRV-Tools binaries to support custom definition by the user on the CMake command line or in the GUI
 160 set(GLSLANG_BINARY_ROOT "${CMAKE_BINARY_DIR}/../glslang" CACHE STRING "User defined path to the glslang binaries for this project")
 161 set(SPIRV_TOOLS_BINARY_ROOT "${CMAKE_BINARY_DIR}/../SPIRV-Tools" CACHE STRING "User defined path to the SPIRV-Tools binaries for this project")
 162 set(SPIRV_TOOLS_OPT_BINARY_ROOT "${CMAKE_BINARY_DIR}/../SPIRV-Tools/opt" CACHE STRING "User defined path to the SPIRV-Tools-opt binaries for this project")
 163
 164 # Define a variable for a default root location to the gslang, SPIRV-Tools and other external sources and cache it to allow the user to customize it as needed
 165 set(EXTERNAL_SOURCE_ROOT "${CMAKE_CURRENT_SOURCE_DIR}/external" CACHE STRING "Root path to external sources such as glslang and SPIRV-Tools")
 166
 167
 168 if (WIN32)
 169     if(CUSTOM_GLSLANG_BIN_ROOT)
 170         set(GSLANG_FINAL_BINARY_PATH ${GLSLANG_BINARY_ROOT}/${BUILDTGT_DIR})
 171     else()
 172         set(GSLANG_FINAL_BINARY_PATH "${EXTERNAL_SOURCE_ROOT}/glslang/${BUILDTGT_DIR}")
 173     endif()
 174
 175     if(DISABLE_BUILD_PATH_DECORATION)
 176         set (DEBUG_DECORATION "")
 177         set (RELEASE_DECORATION "")
 178     else()
 179         set (DEBUG_DECORATION "Debug")
 180         set (RELEASE_DECORATION "Release")
 181     endif()
 182
 183     # Take some steps to set up a variable pointing to the final glslang binaries given the variety of input options
 184     set (GLSLANG_SEARCH_PATH "${GSLANG_FINAL_BINARY_PATH}/glslang/${RELEASE_DECORATION}"
 185                              "${GSLANG_FINAL_BINARY_PATH}/glslang/OSDependent/Windows/${RELEASE_DECORATION}"
 186                              "${GSLANG_FINAL_BINARY_PATH}/hlsl/${RELEASE_DECORATION}"
 187                              "${GSLANG_FINAL_BINARY_PATH}/OGLCompilersDLL/${RELEASE_DECORATION}"
 188                              "${GSLANG_FINAL_BINARY_PATH}/SPIRV/${RELEASE_DECORATION}" )
 189
 190     set (GLSLANG_DEBUG_SEARCH_PATH "${GSLANG_FINAL_BINARY_PATH}/glslang/${DEBUG_DECORATION}"
 191                                    "${GSLANG_FINAL_BINARY_PATH}/glslang/OSDependent/Windows/${DEBUG_DECORATION}"
 192                                    "${GSLANG_FINAL_BINARY_PATH}/hlsl/${DEBUG_DECORATION}"
 193                                    "${GSLANG_FINAL_BINARY_PATH}/OGLCompilersDLL/${DEBUG_DECORATION}"
 194                                    "${GSLANG_FINAL_BINARY_PATH}/SPIRV/${DEBUG_DECORATION}")
 195
 196     if(CUSTOM_SPIRV_TOOLS_BIN_ROOT)
 197         set (SPIRV_TOOLS_SEARCH_PATH "${SPIRV_TOOLS_BINARY_ROOT}/${BUILDTGT_DIR}/source/${RELEASE_DECORATION}")
 198         set (SPIRV_TOOLS_DEBUG_SEARCH_PATH "${SPIRV_TOOLS_BINARY_ROOT}/${BUILDTGT_DIR}/source/${DEBUG_DECORATION}")
 199         set (SPIRV_TOOLS_OPT_SEARCH_PATH "${SPIRV_TOOLS_OPT_BINARY_ROOT}/${BUILDTGT_DIR}/source/opt/${RELEASE_DECORATION}")
 200         set (SPIRV_TOOLS_OPT_DEBUG_SEARCH_PATH "${SPIRV_TOOLS_OPT_BINARY_ROOT}/${BUILDTGT_DIR}/source/opt/${DEBUG_DECORATION}")
 201     else()
 202         set (SPIRV_TOOLS_SEARCH_PATH "${EXTERNAL_SOURCE_ROOT}/glslang/${BUILDTGT_DIR}/External/spirv-tools/source/${RELEASE_DECORATION}")
 203         set (SPIRV_TOOLS_DEBUG_SEARCH_PATH "${EXTERNAL_SOURCE_ROOT}/glslang/${BUILDTGT_DIR}/External/spirv-tools/source/${DEBUG_DECORATION}")
 204         set (SPIRV_TOOLS_OPT_SEARCH_PATH "${EXTERNAL_SOURCE_ROOT}/glslang/${BUILDTGT_DIR}/External/spirv-tools/source/opt/${RELEASE_DECORATION}")
 205         set (SPIRV_TOOLS_OPT_DEBUG_SEARCH_PATH "${EXTERNAL_SOURCE_ROOT}/glslang/${BUILDTGT_DIR}/External/spirv-tools/source/opt/${DEBUG_DECORATION}")
 206     endif()
 207 else()
 208     # not WIN32
 209     if(CUSTOM_GLSLANG_BIN_ROOT)
 210         set (GLSLANG_SEARCH_PATH "${GLSLANG_BINARY_ROOT}/install/lib"
 211                                  "${GLSLANG_BINARY_ROOT}/glslang"
 212                                  "${GLSLANG_BINARY_ROOT}/glslang/OSDependent/Unix"
 213                                  "${GLSLANG_BINARY_ROOT}/OGLCompilersDLL"
 214                                  "${GLSLANG_BINARY_ROOT}/SPIRV"
 215                                  "${GLSLANG_BINARY_ROOT}/hlsl"
 216                                  "${GLSLANG_BINARY_ROOT}/StandAlone")
 217     else()
 218         set (GLSLANG_SEARCH_PATH "${EXTERNAL_SOURCE_ROOT}/glslang/${BUILDTGT_DIR}/install/lib" "${CMAKE_SOURCE_DIR}/../x86_64/lib/glslang" )
 219     endif()
 220
 221     if(CUSTOM_SPIRV_TOOLS_BIN_ROOT)
 222         set (SPIRV_TOOLS_SEARCH_PATH "${SPIRV_TOOLS_BINARY_ROOT}/source" )
 223         set (SPIRV_TOOLS_OPT_SEARCH_PATH "${SPIRV_TOOLS_OPT_BINARY_ROOT}/source/opt" )
 224     else()
 225         set (SPIRV_TOOLS_SEARCH_PATH "${EXTERNAL_SOURCE_ROOT}/glslang/${BUILDTGT_DIR}/External/spirv-tools/source" "${CMAKE_SOURCE_DIR}/../x86_64/lib/spirv-tools" )
 226         set (SPIRV_TOOLS_OPT_SEARCH_PATH "${EXTERNAL_SOURCE_ROOT}/glslang/${BUILDTGT_DIR}/External/spirv-tools/source/opt" "${CMAKE_SOURCE_DIR}/../x86_64/lib/spirv-tools" )
 227     endif()
 228 endif()
 229
 230 find_program(GLSLANG_VALIDATOR NAMES glslangValidator
 231              HINTS "${EXTERNAL_SOURCE_ROOT}/glslang/${BUILDTGT_DIR}/install/bin"
 232                    "${GLSLANG_BINARY_ROOT}/StandAlone"
 233                    "${PROJECT_SOURCE_DIR}/external/${BINDATA_DIR}")
 234
 235 find_path(GLSLANG_SPIRV_INCLUDE_DIR SPIRV/spirv.hpp HINTS "${EXTERNAL_SOURCE_ROOT}/glslang"
 236                                                     "${CMAKE_SOURCE_DIR}/../glslang"
 237                                               DOC "Path to SPIRV/spirv.hpp")
 238
 239 find_path(SPIRV_TOOLS_INCLUDE_DIR spirv-tools/libspirv.h HINTS "${EXTERNAL_SOURCE_ROOT}/glslang/External/spirv-tools/include"
 240                                                    "${CMAKE_SOURCE_DIR}/../glslang/External/spirv-tools/include"
 241                                              DOC "Path to spirv-tools/libspirv.h")
 242
 243 find_library(GLSLANG_LIB NAMES glslang
 244              HINTS ${GLSLANG_SEARCH_PATH} )
 245
 246 find_library(OGLCompiler_LIB NAMES OGLCompiler
 247              HINTS ${GLSLANG_SEARCH_PATH} )
 248
 249 find_library(OSDependent_LIB NAMES OSDependent
 250              HINTS ${GLSLANG_SEARCH_PATH} )
 251
 252 find_library(HLSL_LIB NAMES HLSL
 253              HINTS ${GLSLANG_SEARCH_PATH} )
 254
 255 find_library(SPIRV_LIB NAMES SPIRV
 256              HINTS ${GLSLANG_SEARCH_PATH} )
 257
 258 find_library(SPIRV_REMAPPER_LIB NAMES SPVRemapper
 259              HINTS ${GLSLANG_SEARCH_PATH} )
 260
 261 find_library(SPIRV_TOOLS_LIB NAMES SPIRV-Tools
 262              HINTS ${SPIRV_TOOLS_SEARCH_PATH} )
 263
 264 find_library(SPIRV_TOOLS_OPT_LIB NAMES SPIRV-Tools-opt
 265              HINTS ${SPIRV_TOOLS_OPT_SEARCH_PATH} )
 266
 267 find_library(Vulkan_LIBRARY NAMES vulkan-1 vulkan
 268              HINTS ${VK_SDK_PATH} )
 269
 270 if (WIN32)
 271     add_library(glslang         STATIC IMPORTED)
 272     add_library(OGLCompiler     STATIC IMPORTED)
 273     add_library(OSDependent     STATIC IMPORTED)
 274     add_library(HLSL            STATIC IMPORTED)
 275     add_library(SPIRV           STATIC IMPORTED)
 276     add_library(SPVRemapper     STATIC IMPORTED)
 277 #    add_library(Loader          STATIC IMPORTED)
 278     add_library(SPIRV-Tools-opt STATIC IMPORTED)
 279     add_library(SPIRV-Tools     STATIC IMPORTED)
 280
 281     find_library(GLSLANG_DLIB NAMES glslangd
 282                  HINTS ${GLSLANG_DEBUG_SEARCH_PATH} )
 283     find_library(OGLCompiler_DLIB NAMES OGLCompilerd
 284                  HINTS ${GLSLANG_DEBUG_SEARCH_PATH} )
 285     find_library(OSDependent_DLIB NAMES OSDependentd
 286                  HINTS ${GLSLANG_DEBUG_SEARCH_PATH} )
 287     find_library(HLSL_DLIB NAMES HLSLd
 288                  HINTS ${GLSLANG_DEBUG_SEARCH_PATH} )
 289     find_library(SPIRV_DLIB NAMES SPIRVd
 290                  HINTS ${GLSLANG_DEBUG_SEARCH_PATH} )
 291     find_library(SPIRV_REMAPPER_DLIB NAMES SPVRemapperd
 292                  HINTS ${GLSLANG_DEBUG_SEARCH_PATH} )
 293     find_library(SPIRV_TOOLS_DLIB NAMES SPIRV-Toolsd
 294                  HINTS ${SPIRV_TOOLS_DEBUG_SEARCH_PATH} )
 295     find_library(SPIRV_TOOLS_OPT_DLIB NAMES SPIRV-Tools-optd
 296                  HINTS ${SPIRV_TOOLS_OPT_DEBUG_SEARCH_PATH} )
 297
 298     set_target_properties(glslang PROPERTIES
 299                          IMPORTED_LOCATION       "${GLSLANG_LIB}"
 300                          IMPORTED_LOCATION_DEBUG "${GLSLANG_DLIB}")
 301     set_target_properties(OGLCompiler PROPERTIES
 302                          IMPORTED_LOCATION       "${OGLCompiler_LIB}"
 303                          IMPORTED_LOCATION_DEBUG "${OGLCompiler_DLIB}")
 304     set_target_properties(OSDependent PROPERTIES
 305                          IMPORTED_LOCATION       "${OSDependent_LIB}"
 306                          IMPORTED_LOCATION_DEBUG "${OSDependent_DLIB}")
 307     set_target_properties(HLSL PROPERTIES
 308                          IMPORTED_LOCATION       "${HLSL_LIB}"
 309                          IMPORTED_LOCATION_DEBUG "${HLSL_DLIB}")
 310     set_target_properties(SPIRV PROPERTIES
 311                          IMPORTED_LOCATION       "${SPIRV_LIB}"
 312                          IMPORTED_LOCATION_DEBUG "${SPIRV_DLIB}")
 313     set_target_properties(SPVRemapper PROPERTIES
 314                          IMPORTED_LOCATION       "${SPIRV_REMAPPER_LIB}"
 315                          IMPORTED_LOCATION_DEBUG "${SPIRV_REMAPPER_DLIB}")
 316     set_target_properties(SPIRV-Tools PROPERTIES
 317                          IMPORTED_LOCATION       "${SPIRV_TOOLS_LIB}"
 318                          IMPORTED_LOCATION_DEBUG "${SPIRV_TOOLS_DLIB}")
 319     set_target_properties(SPIRV-Tools-opt PROPERTIES
 320                          IMPORTED_LOCATION       "${SPIRV_TOOLS_OPT_LIB}"
 321                          IMPORTED_LOCATION_DEBUG "${SPIRV_TOOLS_OPT_DLIB}")
 322
 323     set (SPIRV_TOOLS_LIBRARIES SPIRV-Tools-opt SPIRV-Tools)
 324     set (GLSLANG_LIBRARIES glslang OGLCompiler OSDependent HLSL SPIRV SPVRemapper ${SPIRV_TOOLS_LIBRARIES})
 325 else ()
 326     # not WIN32
 327     set (SPIRV_TOOLS_LIBRARIES ${SPIRV_TOOLS_OPT_LIB} ${SPIRV_TOOLS_LIB})
 328     set (GLSLANG_LIBRARIES ${GLSLANG_LIB} ${OGLCompiler_LIB} ${OSDependent_LIB} ${HLSL_LIB} ${SPIRV_LIB} ${SPIRV_REMAPPER_LIB} ${SPIRV_TOOLS_LIBRARIES})
 329 endif()
 330
 331 set (PYTHON_CMD ${PYTHON_EXECUTABLE})
 332
 333 # Define macro used for building vkxml generated files
 334 macro(run_vk_xml_generate dependency output)
 335     add_custom_command(OUTPUT ${output}
 336     COMMAND ${PYTHON_CMD} ${SCRIPTS_DIR}/lvl_genvk.py -registry ${SCRIPTS_DIR}/vk.xml ${output}
 337     DEPENDS ${SCRIPTS_DIR}/vk.xml ${SCRIPTS_DIR}/generator.py ${SCRIPTS_DIR}/${dependency} ${SCRIPTS_DIR}/lvl_genvk.py ${SCRIPTS_DIR}/reg.py
 338     )
 339 endmacro()
 340
 341 if(NOT WIN32)
 342     include(GNUInstallDirs)
 343
 344     add_definitions(-DFALLBACK_CONFIG_DIRS="${FALLBACK_CONFIG_DIRS}")
 345     add_definitions(-DFALLBACK_DATA_DIRS="${FALLBACK_DATA_DIRS}")
 346     add_definitions(-DSYSCONFDIR="${CMAKE_INSTALL_FULL_SYSCONFDIR}")
 347
 348     # Make sure /etc is searched by the loader
 349     if(NOT (CMAKE_INSTALL_FULL_SYSCONFDIR STREQUAL "/etc"))
 350         add_definitions(-DEXTRASYSCONFDIR="/etc")
 351     endif()
 352 endif()
 353
 354 if(UNIX)
 355     if(INSTALL_LVL_FILES)
 356         install(DIRECTORY "${PROJECT_SOURCE_DIR}/include/vulkan" DESTINATION ${CMAKE_INSTALL_INCLUDEDIR})
 357     endif()
 358
 359 # uninstall target
 360 configure_file(
 361     "${CMAKE_CURRENT_SOURCE_DIR}/cmake/cmake_uninstall.cmake.in"
 362     "${CMAKE_CURRENT_BINARY_DIR}/cmake_uninstall.cmake"
 363     IMMEDIATE @ONLY)
 364
 365 add_custom_target(uninstall
 366     COMMAND ${CMAKE_COMMAND} -P ${CMAKE_CURRENT_BINARY_DIR}/cmake_uninstall.cmake)
 367 endif()
 368
 369 add_definitions(-DAPI_NAME="${API_NAME}")
 370
 371 if(BUILD_DEMOS)
 372     add_subdirectory(demos)
 373 endif()
 374
 375 if(BUILD_ICD)
 376     add_subdirectory(icd)
 377 endif()