CMakeLists.txt

   1 # The name of our project is "VULKAN". CMakeLists files in this project can
   2 # refer to the root source directory of the project as ${VULKAN_SOURCE_DIR} and
   3 # to the root binary directory of the project as ${VULKAN_BINARY_DIR}.
   4 cmake_minimum_required(VERSION 2.8.11)
   5 project (VULKAN)
   6 # set (CMAKE_VERBOSE_MAKEFILE 1)
   7
   8 # The API_NAME allows renaming builds to avoid conflicts with installed SDKs
   9 # The MAJOR number of the version we're building, used in naming
  10 # <api-name>-<major>.dll (and other files).
  11 set(API_NAME "Vulkan" CACHE STRING "API name to use when building")
  12 set(MAJOR "1")
  13 string(TOLOWER ${API_NAME} API_LOWERCASE)
  14
  15 set(CMAKE_MODULE_PATH ${CMAKE_MODULE_PATH} "${CMAKE_CURRENT_SOURCE_DIR}/cmake")
  16 find_package(PythonInterp 3 REQUIRED)
  17
  18 if(CMAKE_SYSTEM_NAME STREQUAL "Linux")
  19     set(FALLBACK_CONFIG_DIRS "/etc/xdg" CACHE STRING
  20         "Search path to use when XDG_CONFIG_DIRS is unset or empty or the current process is SUID/SGID. Default is freedesktop compliant.")
  21     set(FALLBACK_DATA_DIRS "/usr/local/share:/usr/share" CACHE STRING
  22         "Search path to use when XDG_DATA_DIRS is unset or empty or the current process is SUID/SGID. Default is freedesktop compliant.")
  23
  24     include(FindPkgConfig)
  25     option(BUILD_WSI_XCB_SUPPORT "Build XCB WSI support" ON)
  26     option(BUILD_WSI_XLIB_SUPPORT "Build Xlib WSI support" ON)
  27     option(BUILD_WSI_WAYLAND_SUPPORT "Build Wayland WSI support" ON)
  28     option(BUILD_WSI_MIR_SUPPORT "Build Mir WSI support" ON)
  29     set(DEMOS_WSI_SELECTION "XCB" CACHE STRING "Select WSI target for demos (XCB, XLIB, WAYLAND, MIR, DISPLAY)")
  30
  31     if (BUILD_WSI_XCB_SUPPORT)
  32         find_package(XCB REQUIRED)
  33     endif()
  34
  35     if (BUILD_WSI_XLIB_SUPPORT)
  36         find_package(X11 REQUIRED)
  37     endif()
  38
  39     if (BUILD_WSI_WAYLAND_SUPPORT)
  40         find_package(Wayland REQUIRED)
  41     endif()
  42
  43     if (BUILD_WSI_MIR_SUPPORT)
  44         find_package(Mir REQUIRED)
  45     endif()
  46 endif()
  47
  48 set(SCRIPTS_DIR "${CMAKE_CURRENT_SOURCE_DIR}/scripts")
  49
  50 # Header file for CMake settings
  51 include_directories("${PROJECT_SOURCE_DIR}/include")
  52
  53 if (CMAKE_COMPILER_IS_GNUCC OR CMAKE_C_COMPILER_ID MATCHES "Clang")
  54     set(COMMON_COMPILE_FLAGS "-Wall -Wextra -Wno-unused-parameter -Wno-missing-field-initializers")
  55     set(COMMON_COMPILE_FLAGS "${COMMON_COMPILE_FLAGS} -fno-strict-aliasing -fno-builtin-memcmp")
  56     set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -std=c99 ${COMMON_COMPILE_FLAGS}")
  57     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} ${COMMON_COMPILE_FLAGS} -std=c++11 -fno-rtti")
  58     if (UNIX)
  59         set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -fvisibility=hidden")
  60         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -fvisibility=hidden")
  61     endif()
  62 endif()
  63
  64 if(WIN32)
  65     # Treat warnings as errors
  66     add_compile_options("$<$<CXX_COMPILER_ID:MSVC>:/WX>")
  67     # Disable RTTI
  68     add_compile_options("$<$<CXX_COMPILER_ID:MSVC>:/GR->")
  69     # Warn about nested declarations
  70     add_compile_options("$<$<CXX_COMPILER_ID:MSVC>:/w34456>")
  71     # Warn about potentially uninitialized variables
  72     add_compile_options("$<$<CXX_COMPILER_ID:MSVC>:/w34701>")
  73     add_compile_options("$<$<CXX_COMPILER_ID:MSVC>:/w34703>")
  74 endif()
  75
  76 if(NOT WIN32)
  77     set (BUILDTGT_DIR build)
  78     set (BINDATA_DIR Bin)
  79     set (LIBSOURCE_DIR Lib)
  80 else()
  81     option(DISABLE_BUILD_PATH_DECORATION "Disable the decoration of the gslang and SPIRV-Tools build path with MSVC build type info" OFF)
  82     option(DISABLE_BUILDTGT_DIR_DECORATION "Disable the decoration of the gslang and SPIRV-Tools build path with target info" OFF)
  83
  84     # For Windows, since 32-bit and 64-bit items can co-exist, we build each in its own build directory.
  85     # 32-bit target data goes in build32, and 64-bit target data goes into build.  So, include/link the
  86     # appropriate data at build time.
  87     if (DISABLE_BUILDTGT_DIR_DECORATION)
  88         set (BUILDTGT_DIR "")
  89         set (BINDATA_DIR "")
  90         set (LIBSOURCE_DIR "")
  91     elseif (CMAKE_CL_64)
  92         set (BUILDTGT_DIR build)
  93         set (BINDATA_DIR Bin)
  94         set (LIBSOURCE_DIR Lib)
  95     else()
  96         set (BUILDTGT_DIR build32)
  97         set (BINDATA_DIR Bin32)
  98         set (LIBSOURCE_DIR Lib32)
  99     endif()
 100 endif()
 101
 102 option(BUILD_LOADER "Build loader" ON)
 103 option(BUILD_TESTS "Build tests" ON)
 104 option(BUILD_LAYERS "Build layers" ON)
 105 option(BUILD_DEMOS "Build demos" ON)
 106 option(BUILD_VKJSON "Build vkjson" ON)
 107 option(CUSTOM_GLSLANG_BIN_ROOT "Use the user defined GLSLANG_BINARY_ROOT" OFF)
 108 option(CUSTOM_SPIRV_TOOLS_BIN_ROOT "Use the user defined SPIRV_TOOLS_BINARY_ROOT" OFF)
 109
 110 #Choose natural default paths for glslang and SPIRV-Tools binaries to support custom definition by the user on the CMake command line or in the GUI
 111 set(GLSLANG_BINARY_ROOT "${CMAKE_BINARY_DIR}/../glslang" CACHE STRING "User defined path to the glslang binaries for this project")
 112 set(SPIRV_TOOLS_BINARY_ROOT "${CMAKE_BINARY_DIR}/../SPIRV-Tools" CACHE STRING "User defined path to the SPIRV-Tools binaries for this project")
 113
 114 # Define a variable for a default root location to the gslang, SPIRV-Tools and other external sources and cache it to allow the user to customize it as needed
 115 set(EXTERNAL_SOURCE_ROOT "${CMAKE_SOURCE_DIR}/external" CACHE STRING "Root path to external sources such as glslang and SPIRV-Tools")
 116
 117
 118 if (WIN32)
 119     if(CUSTOM_GLSLANG_BIN_ROOT)
 120         set(GSLANG_FINAL_BINARY_PATH ${GLSLANG_BINARY_ROOT}/${BUILDTGT_DIR})
 121     else()
 122         set(GSLANG_FINAL_BINARY_PATH "${EXTERNAL_SOURCE_ROOT}/glslang/${BUILDTGT_DIR}")
 123     endif()
 124
 125     if(DISABLE_BUILD_PATH_DECORATION)
 126         set (DEBUG_DECORATION "")
 127         set (RELEASE_DECORATION "")
 128     else()
 129         set (DEBUG_DECORATION "Debug")
 130         set (RELEASE_DECORATION "Release")
 131     endif()
 132
 133     # Take some steps to set up a variable pointing to the final glslang binaries given the variety of input options
 134     set (GLSLANG_SEARCH_PATH "${GSLANG_FINAL_BINARY_PATH}/glslang/${RELEASE_DECORATION}"
 135                              "${GSLANG_FINAL_BINARY_PATH}/glslang/OSDependent/Windows/${RELEASE_DECORATION}"
 136                              "${GSLANG_FINAL_BINARY_PATH}/hlsl/${RELEASE_DECORATION}"
 137                              "${GSLANG_FINAL_BINARY_PATH}/OGLCompilersDLL/${RELEASE_DECORATION}"
 138                              "${GSLANG_FINAL_BINARY_PATH}/SPIRV/${RELEASE_DECORATION}" )
 139
 140     set (GLSLANG_DEBUG_SEARCH_PATH "${GSLANG_FINAL_BINARY_PATH}/glslang/${DEBUG_DECORATION}"
 141                                    "${GSLANG_FINAL_BINARY_PATH}/glslang/OSDependent/Windows/${DEBUG_DECORATION}"
 142                                    "${GSLANG_FINAL_BINARY_PATH}/hlsl/${DEBUG_DECORATION}"
 143                                    "${GSLANG_FINAL_BINARY_PATH}/OGLCompilersDLL/${DEBUG_DECORATION}"
 144                                    "${GSLANG_FINAL_BINARY_PATH}/SPIRV/${DEBUG_DECORATION}")
 145
 146     if(CUSTOM_SPIRV_TOOLS_BIN_ROOT)
 147         set (SPIRV_TOOLS_SEARCH_PATH "${SPIRV_TOOLS_BINARY_ROOT}/${BUILDTGT_DIR}/source/${RELEASE_DECORATION}")
 148         set (SPIRV_TOOLS_DEBUG_SEARCH_PATH "${SPIRV_TOOLS_BINARY_ROOT}/${BUILDTGT_DIR}/source/${DEBUG_DECORATION}")
 149     else()
 150         set (SPIRV_TOOLS_SEARCH_PATH "${EXTERNAL_SOURCE_ROOT}/spirv-tools/${BUILDTGT_DIR}/source/${RELEASE_DECORATION}")
 151         set (SPIRV_TOOLS_DEBUG_SEARCH_PATH "${EXTERNAL_SOURCE_ROOT}/spirv-tools/${BUILDTGT_DIR}/source/${DEBUG_DECORATION}")
 152     endif()
 153 else()
 154     #non windows
 155     if(CUSTOM_GLSLANG_BIN_ROOT)
 156         set (GLSLANG_SEARCH_PATH "${GLSLANG_BINARY_ROOT}/install/lib"
 157                                  "${GLSLANG_BINARY_ROOT}/glslang"
 158                                  "${GLSLANG_BINARY_ROOT}/glslang/OSDependent/Unix"
 159                                  "${GLSLANG_BINARY_ROOT}/OGLCompilersDLL"
 160                                  "${GLSLANG_BINARY_ROOT}/SPIRV"
 161                                  "${GLSLANG_BINARY_ROOT}/hlsl"
 162                                  "${GLSLANG_BINARY_ROOT}/StandAlone")
 163     else()
 164         set (GLSLANG_SEARCH_PATH "${EXTERNAL_SOURCE_ROOT}/glslang/${BUILDTGT_DIR}/install/lib" "${CMAKE_SOURCE_DIR}/../x86_64/lib/glslang" )
 165     endif()
 166
 167     if(CUSTOM_SPIRV_TOOLS_BIN_ROOT)
 168         set (SPIRV_TOOLS_SEARCH_PATH "${SPIRV_TOOLS_BINARY_ROOT}/source" )
 169     else()
 170         set (SPIRV_TOOLS_SEARCH_PATH "${EXTERNAL_SOURCE_ROOT}/spirv-tools/${BUILDTGT_DIR}/source" "${CMAKE_SOURCE_DIR}/../x86_64/lib/spirv-tools" )
 171     endif()
 172 endif()
 173
 174 find_program(GLSLANG_VALIDATOR NAMES glslangValidator
 175              HINTS "${CMAKE_SOURCE_DIR}/external/glslang/${BUILDTGT_DIR}/install/bin"
 176                    "${GLSLANG_BINARY_ROOT}/StandAlone"
 177                    "${PROJECT_SOURCE_DIR}/external/${BINDATA_DIR}")
 178
 179 find_path(GLSLANG_SPIRV_INCLUDE_DIR SPIRV/spirv.hpp HINTS "${EXTERNAL_SOURCE_ROOT}/glslang"
 180                                                     "${CMAKE_SOURCE_DIR}/../glslang"
 181                                               DOC "Path to SPIRV/spirv.hpp")
 182
 183 find_path(SPIRV_TOOLS_INCLUDE_DIR spirv-tools/libspirv.h HINTS "${EXTERNAL_SOURCE_ROOT}/spirv-tools/include"
 184                                                    "${EXTERNAL_SOURCE_ROOT}/SPIRV-Tools/include"
 185                                                    "${CMAKE_SOURCE_DIR}/../spirv-tools/include"
 186                                                    "${CMAKE_SOURCE_DIR}/../SPIRV-Tools/include"
 187                                                    "${EXTERNAL_SOURCE_ROOT}/source/spirv-tools/external/include"
 188                                              DOC "Path to spirv-tools/libspirv.h")
 189
 190 find_library(GLSLANG_LIB NAMES glslang
 191              HINTS ${GLSLANG_SEARCH_PATH} )
 192
 193 find_library(OGLCompiler_LIB NAMES OGLCompiler
 194              HINTS ${GLSLANG_SEARCH_PATH} )
 195
 196 find_library(OSDependent_LIB NAMES OSDependent
 197              HINTS ${GLSLANG_SEARCH_PATH} )
 198
 199 find_library(HLSL_LIB NAMES HLSL
 200              HINTS ${GLSLANG_SEARCH_PATH} )
 201
 202 find_library(SPIRV_LIB NAMES SPIRV
 203              HINTS ${GLSLANG_SEARCH_PATH} )
 204
 205 find_library(SPIRV_REMAPPER_LIB NAMES SPVRemapper
 206              HINTS ${GLSLANG_SEARCH_PATH} )
 207
 208 find_library(SPIRV_TOOLS_LIB NAMES SPIRV-Tools
 209              HINTS ${SPIRV_TOOLS_SEARCH_PATH} )
 210
 211 if (WIN32)
 212     add_library(glslang     STATIC IMPORTED)
 213     add_library(OGLCompiler STATIC IMPORTED)
 214     add_library(OSDependent STATIC IMPORTED)
 215     add_library(HLSL        STATIC IMPORTED)
 216     add_library(SPIRV       STATIC IMPORTED)
 217     add_library(SPVRemapper       STATIC IMPORTED)
 218     add_library(Loader      STATIC IMPORTED)
 219     add_library(SPIRV-Tools STATIC IMPORTED)
 220
 221     find_library(GLSLANG_DLIB NAMES glslangd
 222                  HINTS ${GLSLANG_DEBUG_SEARCH_PATH} )
 223     find_library(OGLCompiler_DLIB NAMES OGLCompilerd
 224                  HINTS ${GLSLANG_DEBUG_SEARCH_PATH} )
 225     find_library(OSDependent_DLIB NAMES OSDependentd
 226                  HINTS ${GLSLANG_DEBUG_SEARCH_PATH} )
 227     find_library(HLSL_DLIB NAMES HLSLd
 228                  HINTS ${GLSLANG_DEBUG_SEARCH_PATH} )
 229     find_library(SPIRV_DLIB NAMES SPIRVd
 230                  HINTS ${GLSLANG_DEBUG_SEARCH_PATH} )
 231     find_library(SPIRV_REMAPPER_DLIB NAMES SPVRemapperd
 232                  HINTS ${GLSLANG_DEBUG_SEARCH_PATH} )
 233     find_library(SPIRV_TOOLS_DLIB NAMES SPIRV-Tools
 234                  HINTS ${SPIRV_TOOLS_DEBUG_SEARCH_PATH} )
 235
 236     set_target_properties(glslang PROPERTIES
 237                          IMPORTED_LOCATION       "${GLSLANG_LIB}"
 238                          IMPORTED_LOCATION_DEBUG "${GLSLANG_DLIB}")
 239     set_target_properties(OGLCompiler PROPERTIES
 240                          IMPORTED_LOCATION       "${OGLCompiler_LIB}"
 241                          IMPORTED_LOCATION_DEBUG "${OGLCompiler_DLIB}")
 242     set_target_properties(OSDependent PROPERTIES
 243                          IMPORTED_LOCATION       "${OSDependent_LIB}"
 244                          IMPORTED_LOCATION_DEBUG "${OSDependent_DLIB}")
 245     set_target_properties(HLSL PROPERTIES
 246                          IMPORTED_LOCATION       "${HLSL_LIB}"
 247                          IMPORTED_LOCATION_DEBUG "${HLSL_DLIB}")
 248     set_target_properties(SPIRV PROPERTIES
 249                          IMPORTED_LOCATION       "${SPIRV_LIB}"
 250                          IMPORTED_LOCATION_DEBUG "${SPIRV_DLIB}")
 251     set_target_properties(SPVRemapper PROPERTIES
 252                          IMPORTED_LOCATION       "${SPIRV_REMAPPER_LIB}"
 253                          IMPORTED_LOCATION_DEBUG "${SPIRV_REMAPPER_DLIB}")
 254     set_target_properties(SPIRV-Tools PROPERTIES
 255                          IMPORTED_LOCATION       "${SPIRV_TOOLS_LIB}"
 256                          IMPORTED_LOCATION_DEBUG "${SPIRV_TOOLS_DLIB}")
 257
 258     set (GLSLANG_LIBRARIES glslang OGLCompiler OSDependent HLSL SPIRV SPVRemapper)
 259     set (SPIRV_TOOLS_LIBRARIES SPIRV-Tools)
 260 else ()
 261     set (GLSLANG_LIBRARIES ${GLSLANG_LIB} ${OGLCompiler_LIB} ${OSDependent_LIB} ${HLSL_LIB} ${SPIRV_LIB} ${SPIRV_REMAPPER_LIB})
 262     set (SPIRV_TOOLS_LIBRARIES ${SPIRV_TOOLS_LIB})
 263 endif()
 264
 265 set (PYTHON_CMD ${PYTHON_EXECUTABLE})
 266
 267 # Define macro used for building vkxml generated files
 268 macro(run_vk_xml_generate dependency output)
 269     add_custom_command(OUTPUT ${output}
 270     COMMAND ${PYTHON_CMD} ${SCRIPTS_DIR}/lvl_genvk.py -registry ${SCRIPTS_DIR}/vk.xml ${output}
 271     DEPENDS ${SCRIPTS_DIR}/vk.xml ${SCRIPTS_DIR}/generator.py ${SCRIPTS_DIR}/${dependency} ${SCRIPTS_DIR}/lvl_genvk.py ${SCRIPTS_DIR}/reg.py
 272     )
 273 endmacro()
 274
 275 # Custom target for generated vulkan helper file dependencies
 276 add_custom_target(generate_helper_files DEPENDS
 277     vk_enum_string_helper.h
 278     vk_struct_size_helper.h
 279     vk_struct_size_helper.c
 280     vk_safe_struct.h
 281     vk_safe_struct.cpp
 282     vk_layer_dispatch_table.h
 283     vk_dispatch_table_helper.h
 284     )
 285
 286 # Rules to build generated helper files
 287 run_vk_xml_generate(loader_extension_generator.py vk_layer_dispatch_table.h)
 288 run_vk_xml_generate(dispatch_table_helper_generator.py vk_dispatch_table_helper.h)
 289 run_vk_xml_generate(helper_file_generator.py vk_safe_struct.h)
 290 run_vk_xml_generate(helper_file_generator.py vk_safe_struct.cpp)
 291 run_vk_xml_generate(helper_file_generator.py vk_struct_size_helper.h)
 292 run_vk_xml_generate(helper_file_generator.py vk_struct_size_helper.c)
 293 run_vk_xml_generate(helper_file_generator.py vk_enum_string_helper.h)
 294
 295 if(NOT WIN32)
 296     include(GNUInstallDirs)
 297
 298     add_definitions(-DFALLBACK_CONFIG_DIRS="${FALLBACK_CONFIG_DIRS}")
 299     add_definitions(-DFALLBACK_DATA_DIRS="${FALLBACK_DATA_DIRS}")
 300     add_definitions(-DSYSCONFDIR="${CMAKE_INSTALL_FULL_SYSCONFDIR}")
 301
 302     # Make sure /etc is searched by the loader
 303     if(NOT (CMAKE_INSTALL_FULL_SYSCONFDIR STREQUAL "/etc"))
 304         add_definitions(-DEXTRASYSCONFDIR="/etc")
 305     endif()
 306 endif()
 307
 308 if(UNIX)
 309     install(DIRECTORY "${PROJECT_SOURCE_DIR}/include/vulkan" DESTINATION ${CMAKE_INSTALL_INCLUDEDIR})
 310
 311 # uninstall target
 312 configure_file(
 313     "${CMAKE_CURRENT_SOURCE_DIR}/cmake/cmake_uninstall.cmake.in"
 314     "${CMAKE_CURRENT_BINARY_DIR}/cmake_uninstall.cmake"
 315     IMMEDIATE @ONLY)
 316
 317 add_custom_target(uninstall
 318     COMMAND ${CMAKE_COMMAND} -P ${CMAKE_CURRENT_BINARY_DIR}/cmake_uninstall.cmake)
 319 endif()
 320
 321 # loader: Generic VULKAN ICD loader
 322 # tests: VULKAN tests
 323 if(BUILD_LOADER)
 324     add_subdirectory(loader)
 325 endif()
 326
 327 if(BUILD_TESTS)
 328     add_subdirectory(tests)
 329 endif()
 330
 331 if(BUILD_LAYERS)
 332     add_subdirectory(layers)
 333 endif()
 334
 335 if(BUILD_DEMOS)
 336     add_subdirectory(demos)
 337 endif()
 338
 339 if(BUILD_VKJSON)
 340     add_subdirectory(libs/vkjson)
 341 endif()