CMakeLists.txt

   1 # Require at least version 2.8.12 of CMake
   2 cmake_minimum_required(VERSION 2.8.12)
   3
   4 if(CMAKE_VERSION VERSION_EQUAL 3.0 OR CMAKE_VERSION VERSION_GREATER 3.0)
   5     cmake_policy(SET CMP0042 NEW)
   6 endif()
   7
   8 # Set the project name
   9 project(CoreCLR)
  10
  11 # Include cmake functions
  12 include(functions.cmake)
  13
  14 # Include global configure settings
  15 include(configure.cmake)
  16
  17 if (WIN32)
  18   message(STATUS "VS_PLATFORM_TOOLSET is ${CMAKE_VS_PLATFORM_TOOLSET}")
  19   message(STATUS "VS_PLATFORM_NAME is ${CMAKE_VS_PLATFORM_NAME}")
  20 endif (WIN32)
  21
  22 # Set commonly used directory names
  23 set(CLR_DIR ${CMAKE_CURRENT_SOURCE_DIR})
  24 set(VM_DIR ${CMAKE_CURRENT_SOURCE_DIR}/src/vm)
  25 set(GENERATED_INCLUDE_DIR ${CMAKE_CURRENT_BINARY_DIR}/src/inc)
  26 set(VERSION_FILE_PATH "${CMAKE_BINARY_DIR}/version.cpp")
  27
  28 set(CORECLR_SET_RPATH ON)
  29 if(CORECLR_SET_RPATH)
  30     # Enable @rpath support for shared libraries.
  31     set(MACOSX_RPATH ON)
  32 endif(CORECLR_SET_RPATH)
  33
  34 OPTION(CMAKE_ENABLE_CODE_COVERAGE "Enable code coverage" OFF)
  35
  36 # Ensure that python is present
  37 find_program(PYTHON python)
  38 if (PYTHON STREQUAL "PYTHON-NOTFOUND")
  39     message(FATAL_ERROR "PYTHON not found: Please install Python 2.7.9 or later from https://www.python.org/downloads/")
  40 endif()
  41
  42 # Ensure other tools are present
  43 if (WIN32)
  44     if(CLR_CMAKE_HOST_ARCH STREQUAL arm)
  45
  46       # Confirm that Windows SDK is present
  47       if(NOT DEFINED CMAKE_VS_WINDOWS_TARGET_PLATFORM_VERSION OR CMAKE_VS_WINDOWS_TARGET_PLATFORM_VERSION STREQUAL "" )
  48               message(FATAL_ERROR "Windows SDK is required for the Arm32 build.")
  49       else()
  50               message("Using Windows SDK version ${CMAKE_VS_WINDOWS_TARGET_PLATFORM_VERSION}")
  51       endif()
  52
  53       # Explicitly specify the assembler to be used for Arm32 compile
  54       file(TO_CMAKE_PATH "$ENV{VCINSTALLDIR}\\bin\\x86_arm\\armasm.exe" CMAKE_ASM_COMPILER)
  55
  56       set(CMAKE_ASM_MASM_COMPILER ${CMAKE_ASM_COMPILER})
  57       message("CMAKE_ASM_MASM_COMPILER explicitly set to: ${CMAKE_ASM_MASM_COMPILER}")
  58
  59       # Enable generic assembly compilation to avoid CMake generate VS proj files that explicitly
  60       # use ml[64].exe as the assembler.
  61       enable_language(ASM)
  62     else()
  63       enable_language(ASM_MASM)
  64     endif()
  65
  66     # Ensure that MC is present
  67     find_program(MC mc)
  68     if (MC STREQUAL "MC-NOTFOUND")
  69         message(FATAL_ERROR "MC not found")
  70     endif()
  71
  72     if (CLR_CMAKE_HOST_ARCH STREQUAL arm64)
  73       # CMAKE_CXX_COMPILER will default to the compiler installed with
  74       # Visual studio. Overwrite it to the compiler on the path.
  75       # TODO, remove when cmake generator supports Arm64 as a target.
  76       find_program(PATH_CXX_COMPILER cl)
  77       set(CMAKE_CXX_COMPILER ${PATH_CXX_COMPILER})
  78       message("Overwriting the CMAKE_CXX_COMPILER.")
  79       message(CMAKE_CXX_COMPILER found:${CMAKE_CXX_COMPILER})
  80     endif()
  81
  82 else (WIN32)
  83     enable_language(ASM)
  84
  85     # Ensure that awk is present
  86     find_program(AWK awk)
  87     if (AWK STREQUAL "AWK-NOTFOUND")
  88         message(FATAL_ERROR "AWK not found")
  89     endif()
  90
  91     if (CMAKE_SYSTEM_NAME STREQUAL Darwin)
  92
  93       # Ensure that dsymutil and strip are present
  94       find_program(DSYMUTIL dsymutil)
  95       if (DSYMUTIL STREQUAL "DSYMUTIL-NOTFOUND")
  96           message(FATAL_ERROR "dsymutil not found")
  97       endif()
  98
  99       find_program(STRIP strip)
 100       if (STRIP STREQUAL "STRIP-NOTFOUND")
 101           message(FATAL_ERROR "strip not found")
 102       endif()
 103
 104     else (CMAKE_SYSTEM_NAME STREQUAL Darwin)
 105
 106       # Ensure that objcopy is present
 107       if (CLR_UNIX_CROSS_BUILD AND NOT DEFINED CLR_CROSS_COMPONENTS_BUILD)
 108         if (CMAKE_SYSTEM_PROCESSOR STREQUAL armv7l OR CMAKE_SYSTEM_PROCESSOR STREQUAL aarch64 OR CMAKE_SYSTEM_PROCESSOR STREQUAL arm)
 109           find_program(OBJCOPY ${TOOLCHAIN}-objcopy)
 110         elseif(CMAKE_SYSTEM_PROCESSOR STREQUAL i686)
 111           find_program(OBJCOPY objcopy)
 112         else()
 113           clr_unknown_arch()
 114         endif()
 115       else()
 116         find_program(OBJCOPY objcopy)
 117       endif()
 118
 119       if (OBJCOPY STREQUAL "OBJCOPY-NOTFOUND")
 120           message(FATAL_ERROR "objcopy not found")
 121       endif()
 122
 123     endif (CMAKE_SYSTEM_NAME STREQUAL Darwin)
 124 endif(WIN32)
 125
 126 #----------------------------------------
 127 # Detect and set platform variable names
 128 #     - for non-windows build platform & architecture is detected using inbuilt CMAKE variables and cross target component configure
 129 #     - for windows we use the passed in parameter to CMAKE to determine build arch
 130 #----------------------------------------
 131 if(CMAKE_SYSTEM_NAME STREQUAL Linux)
 132     set(CLR_CMAKE_PLATFORM_UNIX 1)
 133     if(CLR_CROSS_COMPONENTS_BUILD)
 134         # CMAKE_HOST_SYSTEM_PROCESSOR returns the value of `uname -p` on host.
 135         if(CMAKE_HOST_SYSTEM_PROCESSOR STREQUAL x86_64 OR CMAKE_HOST_SYSTEM_PROCESSOR STREQUAL amd64)
 136             if(CLR_CMAKE_TARGET_ARCH STREQUAL "arm")
 137                 set(CLR_CMAKE_PLATFORM_UNIX_X86 1)
 138             else()
 139                 set(CLR_CMAKE_PLATFORM_UNIX_AMD64 1)
 140             endif()
 141         elseif(CMAKE_HOST_SYSTEM_PROCESSOR STREQUAL i686)
 142             set(CLR_CMAKE_PLATFORM_UNIX_X86 1)
 143         else()
 144             clr_unknown_arch()
 145         endif()
 146     else()
 147         # CMAKE_SYSTEM_PROCESSOR returns the value of `uname -p` on target.
 148         # For the AMD/Intel 64bit architecure two different strings are common.
 149         # Linux and Darwin identify it as "x86_64" while FreeBSD and netbsd uses the
 150         # "amd64" string. Accept either of the two here.
 151         if(CMAKE_SYSTEM_PROCESSOR STREQUAL x86_64 OR CMAKE_SYSTEM_PROCESSOR STREQUAL amd64)
 152             set(CLR_CMAKE_PLATFORM_UNIX_AMD64 1)
 153         elseif(CMAKE_SYSTEM_PROCESSOR STREQUAL armv7l)
 154             set(CLR_CMAKE_PLATFORM_UNIX_ARM 1)
 155         elseif(CMAKE_SYSTEM_PROCESSOR STREQUAL arm)
 156             set(CLR_CMAKE_PLATFORM_UNIX_ARM 1)
 157         elseif(CMAKE_SYSTEM_PROCESSOR STREQUAL aarch64)
 158             set(CLR_CMAKE_PLATFORM_UNIX_ARM64 1)
 159         elseif(CMAKE_SYSTEM_PROCESSOR STREQUAL i686)
 160             set(CLR_CMAKE_PLATFORM_UNIX_X86 1)
 161         else()
 162             clr_unknown_arch()
 163         endif()
 164     endif()
 165     set(CLR_CMAKE_PLATFORM_LINUX 1)
 166
 167     # Detect Linux ID
 168     if(DEFINED CLR_CMAKE_LINUX_ID)
 169         if(CLR_CMAKE_LINUX_ID STREQUAL ubuntu)
 170             set(CLR_CMAKE_TARGET_UBUNTU_LINUX 1)
 171         elseif(CLR_CMAKE_LINUX_ID STREQUAL tizen)
 172             set(CLR_CMAKE_TARGET_TIZEN_LINUX 1)
 173         elseif(CLR_CMAKE_LINUX_ID STREQUAL alpine)
 174             set(CLR_CMAKE_PLATFORM_ALPINE_LINUX 1)
 175         endif()
 176         if(CLR_CMAKE_LINUX_ID STREQUAL ubuntu)
 177             set(CLR_CMAKE_PLATFORM_UBUNTU_LINUX 1)
 178         endif()
 179     endif(DEFINED CLR_CMAKE_LINUX_ID)
 180 endif(CMAKE_SYSTEM_NAME STREQUAL Linux)
 181
 182 if(CMAKE_SYSTEM_NAME STREQUAL Darwin)
 183   set(CLR_CMAKE_PLATFORM_UNIX 1)
 184   set(CLR_CMAKE_PLATFORM_UNIX_AMD64 1)
 185   set(CLR_CMAKE_PLATFORM_DARWIN 1)
 186   if(CMAKE_VERSION VERSION_LESS "3.4.0")
 187     set(CMAKE_ASM_COMPILE_OBJECT "${CMAKE_C_COMPILER} <FLAGS> <DEFINES> -o <OBJECT> -c <SOURCE>")
 188   else()
 189     set(CMAKE_ASM_COMPILE_OBJECT "${CMAKE_C_COMPILER} <FLAGS> <DEFINES> <INCLUDES> -o <OBJECT> -c <SOURCE>")
 190   endif(CMAKE_VERSION VERSION_LESS "3.4.0")
 191 endif(CMAKE_SYSTEM_NAME STREQUAL Darwin)
 192
 193 if(CMAKE_SYSTEM_NAME STREQUAL FreeBSD)
 194   set(CLR_CMAKE_PLATFORM_UNIX 1)
 195   set(CLR_CMAKE_PLATFORM_UNIX_AMD64 1)
 196   set(CLR_CMAKE_PLATFORM_FREEBSD 1)
 197 endif(CMAKE_SYSTEM_NAME STREQUAL FreeBSD)
 198
 199 if(CMAKE_SYSTEM_NAME STREQUAL OpenBSD)
 200   set(CLR_CMAKE_PLATFORM_UNIX 1)
 201   set(CLR_CMAKE_PLATFORM_UNIX_AMD64 1)
 202   set(CLR_CMAKE_PLATFORM_OPENBSD 1)
 203 endif(CMAKE_SYSTEM_NAME STREQUAL OpenBSD)
 204
 205 if(CMAKE_SYSTEM_NAME STREQUAL NetBSD)
 206   set(CLR_CMAKE_PLATFORM_UNIX 1)
 207   set(CLR_CMAKE_PLATFORM_UNIX_AMD64 1)
 208   set(CLR_CMAKE_PLATFORM_NETBSD 1)
 209 endif(CMAKE_SYSTEM_NAME STREQUAL NetBSD)
 210
 211 if(CMAKE_SYSTEM_NAME STREQUAL SunOS)
 212   set(CLR_CMAKE_PLATFORM_UNIX 1)
 213   EXECUTE_PROCESS(
 214     COMMAND isainfo -n
 215     OUTPUT_VARIABLE SUNOS_NATIVE_INSTRUCTION_SET
 216     )
 217   if(SUNOS_NATIVE_INSTRUCTION_SET MATCHES "amd64")
 218     set(CLR_CMAKE_PLATFORM_UNIX_AMD64 1)
 219     set(CMAKE_SYSTEM_PROCESSOR "amd64")
 220   else()
 221     clr_unknown_arch()
 222   endif()
 223   set(CLR_CMAKE_PLATFORM_SUNOS 1)
 224 endif(CMAKE_SYSTEM_NAME STREQUAL SunOS)
 225
 226 #--------------------------------------------
 227 # This repo builds two set of binaries
 228 # 1. binaries which execute on target arch machine
 229 #        - for such binaries host architecture & target architecture are same
 230 #        - eg. coreclr.dll
 231 # 2. binaries which execute on host machine but target another architecture
 232 #        - host architecture is different from target architecture
 233 #        - eg. crossgen.exe - runs on x64 machine and generates nis targeting arm64
 234 #        - for complete list of such binaries refer to file crosscomponents.cmake
 235 #-------------------------------------------------------------
 236 # Set HOST architecture variables
 237 if(CLR_CMAKE_PLATFORM_UNIX_ARM)
 238     set(CLR_CMAKE_PLATFORM_ARCH_ARM 1)
 239     set(CLR_CMAKE_HOST_ARCH "arm")
 240 elseif(CLR_CMAKE_PLATFORM_UNIX_ARM64)
 241     set(CLR_CMAKE_PLATFORM_ARCH_ARM64 1)
 242     set(CLR_CMAKE_HOST_ARCH "arm64")
 243 elseif(CLR_CMAKE_PLATFORM_UNIX_AMD64)
 244     set(CLR_CMAKE_PLATFORM_ARCH_AMD64 1)
 245     set(CLR_CMAKE_HOST_ARCH "x64")
 246 elseif(CLR_CMAKE_PLATFORM_UNIX_X86)
 247     set(CLR_CMAKE_PLATFORM_ARCH_I386 1)
 248     set(CLR_CMAKE_HOST_ARCH "x86")
 249 elseif(WIN32)
 250     # CLR_CMAKE_HOST_ARCH is passed in as param to cmake
 251     if (CLR_CMAKE_HOST_ARCH STREQUAL x64)
 252         set(CLR_CMAKE_PLATFORM_ARCH_AMD64 1)
 253     elseif(CLR_CMAKE_HOST_ARCH STREQUAL x86)
 254         set(CLR_CMAKE_PLATFORM_ARCH_I386 1)
 255     elseif(CLR_CMAKE_HOST_ARCH STREQUAL arm)
 256         set(CLR_CMAKE_PLATFORM_ARCH_ARM 1)
 257     elseif(CLR_CMAKE_HOST_ARCH STREQUAL arm64)
 258         set(CLR_CMAKE_PLATFORM_ARCH_ARM64 1)
 259     else()
 260         clr_unknown_arch()
 261     endif()
 262 endif()
 263
 264 # Set TARGET architecture variables
 265 # Target arch will be a cmake param (optional) for both windows as well as non-windows build
 266 # if target arch is not specified then host & target are same
 267 if(NOT DEFINED CLR_CMAKE_TARGET_ARCH OR CLR_CMAKE_TARGET_ARCH STREQUAL "" )
 268   set(CLR_CMAKE_TARGET_ARCH ${CLR_CMAKE_HOST_ARCH})
 269 endif()
 270
 271 # Set target architecture variables
 272 if (CLR_CMAKE_TARGET_ARCH STREQUAL x64)
 273     set(CLR_CMAKE_TARGET_ARCH_AMD64 1)
 274   elseif(CLR_CMAKE_TARGET_ARCH STREQUAL x86)
 275     set(CLR_CMAKE_TARGET_ARCH_I386 1)
 276   elseif(CLR_CMAKE_TARGET_ARCH STREQUAL arm64)
 277     set(CLR_CMAKE_TARGET_ARCH_ARM64 1)
 278   elseif(CLR_CMAKE_TARGET_ARCH STREQUAL arm)
 279     set(CLR_CMAKE_TARGET_ARCH_ARM 1)
 280   else()
 281     clr_unknown_arch()
 282 endif()
 283
 284 # check if host & target arch combination are valid
 285 if(NOT(CLR_CMAKE_TARGET_ARCH STREQUAL CLR_CMAKE_HOST_ARCH))
 286     if(NOT((CLR_CMAKE_PLATFORM_ARCH_AMD64 AND CLR_CMAKE_TARGET_ARCH_ARM64) OR (CLR_CMAKE_PLATFORM_ARCH_I386 AND CLR_CMAKE_TARGET_ARCH_ARM)))
 287         message(FATAL_ERROR "Invalid host and target arch combination")
 288     endif()
 289 endif()
 290
 291 #-----------------------------------------------------
 292 # Initialize Cmake compiler flags and other variables
 293 #-----------------------------------------------------
 294
 295 if (CMAKE_CONFIGURATION_TYPES) # multi-configuration generator?
 296     set(CMAKE_CONFIGURATION_TYPES "Debug;Checked;Release;RelWithDebInfo" CACHE STRING "" FORCE)
 297 endif (CMAKE_CONFIGURATION_TYPES)
 298
 299 set(CMAKE_C_FLAGS_CHECKED ${CLR_C_FLAGS_CHECKED_INIT} CACHE STRING "Flags used by the compiler during checked builds.")
 300 set(CMAKE_CXX_FLAGS_CHECKED ${CLR_CXX_FLAGS_CHECKED_INIT} CACHE STRING "Flags used by the compiler during checked builds.")
 301 set(CMAKE_EXE_LINKER_FLAGS_CHECKED "")
 302 set(CMAKE_SHARED_LINKER_FLAGS_CHECKED "")
 303
 304 set(CMAKE_CXX_STANDARD_LIBRARIES "") # do not link against standard win32 libs i.e. kernel32, uuid, user32, etc.
 305
 306 if (WIN32)
 307   # For multi-configuration toolset (as Visual Studio)
 308   # set the different configuration defines.
 309   foreach (Config DEBUG CHECKED RELEASE RELWITHDEBINFO)
 310     foreach (Definition IN LISTS CLR_DEFINES_${Config}_INIT)
 311       set_property(DIRECTORY APPEND PROPERTY COMPILE_DEFINITIONS $<$<CONFIG:${Config}>:${Definition}>)
 312     endforeach (Definition)
 313   endforeach (Config)
 314
 315   set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} /guard:cf")
 316   set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} /guard:cf")
 317
 318   # Linker flags
 319   #
 320   set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} /MANIFEST:NO") #Do not create Side-by-Side Assembly Manifest
 321
 322   if (CLR_CMAKE_PLATFORM_ARCH_ARM)
 323     set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} /SUBSYSTEM:WINDOWS,6.02") #windows subsystem - arm minimum is 6.02
 324   elseif(CLR_CMAKE_PLATFORM_ARCH_ARM64)
 325     set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} /SUBSYSTEM:WINDOWS,6.03") #windows subsystem - arm64 minimum is 6.03
 326   else ()
 327     set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} /SUBSYSTEM:WINDOWS,6.01") #windows subsystem
 328   endif ()
 329
 330   set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} /LARGEADDRESSAWARE") # can handle addresses larger than 2 gigabytes
 331   set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} /RELEASE") #sets the checksum in the header
 332   set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} /NXCOMPAT") #Compatible with Data Execution Prevention
 333   set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} /DYNAMICBASE") #Use address space layout randomization
 334   set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} /PDBCOMPRESS") #shrink pdb size
 335   set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} /DEBUG")
 336   set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} /IGNORE:4197,4013,4254,4070,4221")
 337
 338   set(CMAKE_STATIC_LINKER_FLAGS "${CMAKE_STATIC_LINKER_FLAGS} /IGNORE:4221")
 339
 340   set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} /DEBUG /PDBCOMPRESS")
 341   set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} /STACK:1572864")
 342
 343   # Debug build specific flags
 344   set(CMAKE_SHARED_LINKER_FLAGS_DEBUG "/NOVCFEATURE ${NO_INCREMENTAL_LINKER_FLAGS}")
 345   set(CMAKE_EXE_LINKER_FLAGS_DEBUG "${NO_INCREMENTAL_LINKER_FLAGS}")
 346
 347   # Checked build specific flags
 348   set(CMAKE_SHARED_LINKER_FLAGS_CHECKED "${CMAKE_SHARED_LINKER_FLAGS_CHECKED} /OPT:REF /OPT:NOICF /NOVCFEATURE ${NO_INCREMENTAL_LINKER_FLAGS}")
 349   set(CMAKE_STATIC_LINKER_FLAGS_CHECKED "${CMAKE_STATIC_LINKER_FLAGS_CHECKED}")
 350   set(CMAKE_EXE_LINKER_FLAGS_CHECKED "${CMAKE_EXE_LINKER_FLAGS_CHECKED} /OPT:REF /OPT:NOICF ${NO_INCREMENTAL_LINKER_FLAGS}")
 351
 352   # Release build specific flags
 353   set(CMAKE_SHARED_LINKER_FLAGS_RELEASE "${CMAKE_SHARED_LINKER_FLAGS_RELEASE} /LTCG /OPT:REF /OPT:ICF ${NO_INCREMENTAL_LINKER_FLAGS}")
 354   set(CMAKE_STATIC_LINKER_FLAGS_RELEASE "${CMAKE_STATIC_LINKER_FLAGS_RELEASE} /LTCG")
 355   set(CMAKE_EXE_LINKER_FLAGS_RELEASE "${CMAKE_EXE_LINKER_FLAGS_RELEASE} /LTCG /OPT:REF /OPT:ICF ${NO_INCREMENTAL_LINKER_FLAGS}")
 356
 357   # ReleaseWithDebugInfo build specific flags
 358   set(CMAKE_SHARED_LINKER_FLAGS_RELWITHDEBINFO "${CMAKE_SHARED_LINKER_FLAGS_RELWITHDEBINFO} /LTCG /OPT:REF /OPT:ICF ${NO_INCREMENTAL_LINKER_FLAGS}")
 359   set(CMAKE_STATIC_LINKER_FLAGS_RELWITHDEBINFO "${CMAKE_STATIC_LINKER_FLAGS_RELWITHDEBINFO} /LTCG")
 360   set(CMAKE_EXE_LINKER_FLAGS_RELWITHDEBINFO "${CMAKE_EXE_LINKER_FLAGS_RELWITHDEBINFO} /LTCG /OPT:REF /OPT:ICF ${NO_INCREMENTAL_LINKER_FLAGS}")
 361
 362   # Temporary until cmake has VS generators for arm64
 363   if(CLR_CMAKE_PLATFORM_ARCH_ARM64)
 364     set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} /machine:arm64")
 365     set(CMAKE_STATIC_LINKER_FLAGS "${CMAKE_STATIC_LINKER_FLAGS} /machine:arm64")
 366     set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} /machine:arm64")
 367   endif(CLR_CMAKE_PLATFORM_ARCH_ARM64)
 368
 369   # Force uCRT to be dynamically linked for Release build
 370   set(CMAKE_SHARED_LINKER_FLAGS_RELEASE "${CMAKE_SHARED_LINKER_FLAGS_RELEASE} /NODEFAULTLIB:libucrt.lib /DEFAULTLIB:ucrt.lib")
 371   set(CMAKE_EXE_LINKER_FLAGS_RELEASE "${CMAKE_EXE_LINKER_FLAGS_RELEASE} /NODEFAULTLIB:libucrt.lib /DEFAULTLIB:ucrt.lib")
 372   set(CMAKE_SHARED_LINKER_FLAGS_RELWITHDEBINFO "${CMAKE_SHARED_LINKER_FLAGS_RELWITHDEBINFO} /NODEFAULTLIB:libucrt.lib /DEFAULTLIB:ucrt.lib")
 373   set(CMAKE_EXE_LINKER_FLAGS_RELWITHDEBINFO "${CMAKE_EXE_LINKER_FLAGS_RELWITHDEBINFO} /NODEFAULTLIB:libucrt.lib /DEFAULTLIB:ucrt.lib")
 374
 375 elseif (CLR_CMAKE_PLATFORM_UNIX)
 376   # Set the values to display when interactively configuring CMAKE_BUILD_TYPE
 377   set_property(CACHE CMAKE_BUILD_TYPE PROPERTY STRINGS "DEBUG;CHECKED;RELEASE;RELWITHDEBINFO")
 378
 379   # Use uppercase CMAKE_BUILD_TYPE for the string comparisons below
 380   string(TOUPPER ${CMAKE_BUILD_TYPE} UPPERCASE_CMAKE_BUILD_TYPE)
 381
 382   # For single-configuration toolset
 383   # set the different configuration defines.
 384   if (UPPERCASE_CMAKE_BUILD_TYPE STREQUAL DEBUG)
 385     # First DEBUG
 386     set_property(DIRECTORY  PROPERTY COMPILE_DEFINITIONS ${CLR_DEFINES_DEBUG_INIT})
 387   elseif (UPPERCASE_CMAKE_BUILD_TYPE STREQUAL CHECKED)
 388     # Then CHECKED
 389     set_property(DIRECTORY PROPERTY COMPILE_DEFINITIONS ${CLR_DEFINES_CHECKED_INIT})
 390   elseif (UPPERCASE_CMAKE_BUILD_TYPE STREQUAL RELEASE)
 391     # Then RELEASE
 392     set_property(DIRECTORY PROPERTY COMPILE_DEFINITIONS ${CLR_DEFINES_RELEASE_INIT})
 393   elseif (UPPERCASE_CMAKE_BUILD_TYPE STREQUAL RELWITHDEBINFO)
 394     # And then RELWITHDEBINFO
 395     set_property(DIRECTORY APPEND PROPERTY COMPILE_DEFINITIONS ${CLR_DEFINES_RELWITHDEBINFO_INIT})
 396   else ()
 397     message(FATAL_ERROR "Unknown build type! Set CMAKE_BUILD_TYPE to DEBUG, CHECKED, RELEASE, or RELWITHDEBINFO!")
 398   endif ()
 399
 400   # set the CLANG sanitizer flags for debug build
 401   if(UPPERCASE_CMAKE_BUILD_TYPE STREQUAL DEBUG OR UPPERCASE_CMAKE_BUILD_TYPE STREQUAL CHECKED)
 402     # obtain settings from running enablesanitizers.sh
 403     string(FIND "$ENV{DEBUG_SANITIZERS}" "asan" __ASAN_POS)
 404     string(FIND "$ENV{DEBUG_SANITIZERS}" "ubsan" __UBSAN_POS)
 405     if ((${__ASAN_POS} GREATER -1) OR (${__UBSAN_POS} GREATER -1))
 406       set(CLR_SANITIZE_CXX_FLAGS "${CLR_SANITIZE_CXX_FLAGS} -fsanitize-blacklist=${CMAKE_CURRENT_SOURCE_DIR}/sanitizerblacklist.txt -fsanitize=")
 407       set(CLR_SANITIZE_LINK_FLAGS "${CLR_SANITIZE_LINK_FLAGS} -fsanitize=")
 408       if (${__ASAN_POS} GREATER -1)
 409         set(CLR_SANITIZE_CXX_FLAGS "${CLR_SANITIZE_CXX_FLAGS}address,")
 410         set(CLR_SANITIZE_LINK_FLAGS "${CLR_SANITIZE_LINK_FLAGS}address,")
 411         message("Address Sanitizer (asan) enabled")
 412       endif ()
 413       if (${__UBSAN_POS} GREATER -1)
 414         # all sanitizier flags are enabled except alignment (due to heavy use of __unaligned modifier)
 415         set(CLR_SANITIZE_CXX_FLAGS "${CLR_SANITIZE_CXX_FLAGS}bool,bounds,enum,float-cast-overflow,float-divide-by-zero,function,integer,nonnull-attribute,null,object-size,return,returns-nonnull-attribute,shift,unreachable,vla-bound,vptr")
 416         set(CLR_SANITIZE_LINK_FLAGS "${CLR_SANITIZE_LINK_FLAGS}undefined")
 417         message("Undefined Behavior Sanitizer (ubsan) enabled")
 418       endif ()
 419
 420       # -fdata-sections -ffunction-sections: each function has own section instead of one per .o file (needed for --gc-sections)
 421       # -fPIC: enable Position Independent Code normally just for shared libraries but required when linking with address sanitizer
 422       # -O1: optimization level used instead of -O0 to avoid compile error "invalid operand for inline asm constraint"
 423       set(CMAKE_CXX_FLAGS_DEBUG "${CMAKE_CXX_FLAGS_DEBUG} ${CLR_SANITIZE_CXX_FLAGS} -fdata-sections -ffunction-sections -fPIC -O1")
 424       set(CMAKE_CXX_FLAGS_CHECKED "${CMAKE_CXX_FLAGS_CHECKED} ${CLR_SANITIZE_CXX_FLAGS} -fdata-sections -ffunction-sections -fPIC -O1")
 425
 426       set(CMAKE_EXE_LINKER_FLAGS_DEBUG "${CMAKE_EXE_LINKER_FLAGS_DEBUG} ${CLR_SANITIZE_LINK_FLAGS}")
 427       set(CMAKE_EXE_LINKER_FLAGS_CHECKED "${CMAKE_EXE_LINKER_FLAGS_CHECKED} ${CLR_SANITIZE_LINK_FLAGS}")
 428
 429       # -Wl and --gc-sections: drop unused sections\functions (similar to Windows /Gy function-level-linking)
 430       set(CMAKE_SHARED_LINKER_FLAGS_DEBUG "${CMAKE_SHARED_LINKER_FLAGS_DEBUG} ${CLR_SANITIZE_LINK_FLAGS} -Wl,--gc-sections")
 431       set(CMAKE_SHARED_LINKER_FLAGS_CHECKED "${CMAKE_SHARED_LINKER_FLAGS_CHECKED} ${CLR_SANITIZE_LINK_FLAGS} -Wl,--gc-sections")
 432     endif ()
 433   endif(UPPERCASE_CMAKE_BUILD_TYPE STREQUAL DEBUG OR UPPERCASE_CMAKE_BUILD_TYPE STREQUAL CHECKED)
 434 endif(WIN32)
 435
 436 if(CLR_CMAKE_PLATFORM_LINUX)
 437   set(CMAKE_ASM_FLAGS "${CMAKE_ASM_FLAGS} -Wa,--noexecstack")
 438   set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} -Wl,--build-id=sha1")
 439   set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -Wl,--build-id=sha1")
 440 endif(CLR_CMAKE_PLATFORM_LINUX)
 441
 442 #------------------------------------
 443 # Definitions (for platform)
 444 #-----------------------------------
 445 if (CLR_CMAKE_PLATFORM_ARCH_AMD64)
 446   add_definitions(-D_AMD64_)
 447   add_definitions(-D_WIN64)
 448   add_definitions(-DAMD64)
 449   add_definitions(-DBIT64=1)
 450 elseif (CLR_CMAKE_PLATFORM_ARCH_I386)
 451   add_definitions(-D_X86_)
 452 elseif (CLR_CMAKE_PLATFORM_ARCH_ARM)
 453   add_definitions(-D_ARM_)
 454   add_definitions(-DARM)
 455 elseif (CLR_CMAKE_PLATFORM_ARCH_ARM64)
 456   add_definitions(-D_ARM64_)
 457   add_definitions(-DARM64)
 458   add_definitions(-D_WIN64)
 459   add_definitions(-DBIT64=1)
 460 else ()
 461   clr_unknown_arch()
 462 endif ()
 463
 464 if (CLR_CMAKE_PLATFORM_UNIX)
 465   if(CLR_CMAKE_PLATFORM_LINUX)
 466     if(CLR_CMAKE_PLATFORM_UNIX_AMD64)
 467       message("Detected Linux x86_64")
 468       add_definitions(-DLINUX64)
 469     elseif(CLR_CMAKE_PLATFORM_UNIX_ARM)
 470       message("Detected Linux ARM")
 471       add_definitions(-DLINUX32)
 472     elseif(CLR_CMAKE_PLATFORM_UNIX_ARM64)
 473       message("Detected Linux ARM64")
 474       add_definitions(-DLINUX64)
 475     elseif(CLR_CMAKE_PLATFORM_UNIX_X86)
 476       message("Detected Linux i686")
 477       add_definitions(-DLINUX32)
 478     else()
 479       clr_unknown_arch()
 480     endif()
 481   endif(CLR_CMAKE_PLATFORM_LINUX)
 482 endif(CLR_CMAKE_PLATFORM_UNIX)
 483
 484 if (CLR_CMAKE_PLATFORM_UNIX)
 485   add_definitions(-DPLATFORM_UNIX=1)
 486
 487   if(CLR_CMAKE_PLATFORM_DARWIN)
 488     message("Detected OSX x86_64")
 489   endif(CLR_CMAKE_PLATFORM_DARWIN)
 490
 491   if(CLR_CMAKE_PLATFORM_FREEBSD)
 492     message("Detected FreeBSD amd64")
 493   endif(CLR_CMAKE_PLATFORM_FREEBSD)
 494
 495   if(CLR_CMAKE_PLATFORM_NETBSD)
 496     message("Detected NetBSD amd64")
 497   endif(CLR_CMAKE_PLATFORM_NETBSD)
 498 endif(CLR_CMAKE_PLATFORM_UNIX)
 499
 500 if (WIN32)
 501   # Define the CRT lib references that link into Desktop imports
 502   set(STATIC_MT_CRT_LIB  "libcmt$<$<OR:$<CONFIG:Debug>,$<CONFIG:Checked>>:d>.lib")
 503   set(STATIC_MT_VCRT_LIB  "libvcruntime$<$<OR:$<CONFIG:Debug>,$<CONFIG:Checked>>:d>.lib")
 504   set(STATIC_MT_CPP_LIB  "libcpmt$<$<OR:$<CONFIG:Debug>,$<CONFIG:Checked>>:d>.lib")
 505
 506   # Define the uCRT lib reference
 507   set(STATIC_UCRT_LIB  "libucrt$<$<OR:$<CONFIG:Debug>,$<CONFIG:Checked>>:d>.lib")
 508   set(DYNAMIC_UCRT_LIB  "ucrt$<$<OR:$<CONFIG:Debug>,$<CONFIG:Checked>>:d>.lib")
 509 endif(WIN32)
 510
 511 # Architecture specific files folder name
 512 if (CLR_CMAKE_TARGET_ARCH_AMD64)
 513     set(ARCH_SOURCES_DIR amd64)
 514 elseif (CLR_CMAKE_TARGET_ARCH_ARM64)
 515     set(ARCH_SOURCES_DIR arm64)
 516 elseif (CLR_CMAKE_TARGET_ARCH_ARM)
 517     set(ARCH_SOURCES_DIR arm)
 518 elseif (CLR_CMAKE_TARGET_ARCH_I386)
 519     set(ARCH_SOURCES_DIR i386)
 520 else ()
 521     clr_unknown_arch()
 522 endif ()
 523
 524 #--------------------------------------
 525 # Compile Options
 526 #--------------------------------------
 527 include(compileoptions.cmake)
 528
 529 #----------------------------------------------------
 530 # Cross target Component build specific configuration
 531 #----------------------------------------------------
 532 if(CLR_CROSS_COMPONENTS_BUILD)
 533   include(crosscomponents.cmake)
 534 endif(CLR_CROSS_COMPONENTS_BUILD)
 535
 536 #-------------------
 537 # Enable PGO support
 538 #-------------------
 539 include(pgosupport.cmake)
 540
 541 #-----------------------------------------
 542 # Add Projects
 543 #     - project which require platform header not clr's
 544 #     - do not depend on clr's compile definitions
 545 #-----------------------------------------
 546 if(CLR_CMAKE_PLATFORM_UNIX AND NOT DEFINED CLR_CROSS_COMPONENTS_BUILD)
 547     add_subdirectory(src/corefx)
 548 endif()
 549
 550 if(CLR_CMAKE_PLATFORM_UNIX)
 551     add_subdirectory(src/ToolBox/SOS/lldbplugin)
 552     add_subdirectory(src/pal)
 553     add_subdirectory(src/coreclr/hosts)
 554     add_subdirectory(src/ildasm/unixcoreclrloader)
 555 endif(CLR_CMAKE_PLATFORM_UNIX)
 556
 557 # Add this subdir. We install the headers for the jit.
 558 add_subdirectory(src/pal/prebuilt/inc)
 559
 560 add_subdirectory(src/debug/debug-pal)
 561
 562 if(WIN32)
 563   add_subdirectory(src/gc/sample)
 564 endif()
 565
 566 # Above projects do not build with these compile options
 567 # All of the compiler options are specified in file compileoptions.cmake
 568 # Do not add any new options here. They shoul be added in compileoptions.cmake
 569 if(WIN32)
 570   add_compile_options(/FIWarningControl.h) # force include of WarningControl.h
 571   add_compile_options(/Zl) # omit default library name in .OBJ
 572 endif(WIN32)
 573
 574 #-------------------------------------
 575 # Include directory directives
 576 #-------------------------------------
 577 # Include the basic prebuilt headers - required for getting fileversion resource details.
 578 include_directories("src/pal/prebuilt/inc")
 579 include_directories("bin/obj")
 580
 581 if(FEATURE_STANDALONE_GC)
 582   add_definitions(-DFEATURE_STANDALONE_GC)
 583
 584   if(CLR_CMAKE_PLATFORM_UNIX)
 585     add_subdirectory(src/gc/unix)
 586   endif(CLR_CMAKE_PLATFORM_UNIX)
 587 endif(FEATURE_STANDALONE_GC)
 588
 589 if (CLR_CMAKE_PLATFORM_UNIX)
 590   include_directories("src/pal/inc")
 591   include_directories("src/pal/inc/rt")
 592   include_directories("src/pal/src/safecrt")
 593 endif (CLR_CMAKE_PLATFORM_UNIX)
 594
 595 #--------------------------------
 596 # Definition directives
 597 #  - all clr specific compile definitions should be included in this file
 598 #  - all clr specific feature variable should also be added in this file
 599 #----------------------------------
 600 include(clrdefinitions.cmake)
 601
 602 # Microsoft.Dotnet.BuildTools.Coreclr version
 603 set(BuildToolsVersion "1.0.4-prerelease")
 604 set(BuildToolsDir "${CLR_DIR}/packages/Microsoft.DotNet.BuildTools.CoreCLR/${BuildToolsVersion}")
 605
 606 #------------------------------
 607 # Add Product Directory
 608 #------------------------------
 609 add_subdirectory(src)
 610
 611 #------------------------------
 612 # Add Test Directory
 613 #------------------------------
 614 if(CLR_CMAKE_BUILD_TESTS)
 615   # remove some definitions for test build
 616   remove_definitions(-D_SECURE_SCL=0)
 617   remove_definitions(-DUNICODE)
 618   remove_definitions(-D_UNICODE)
 619
 620   add_subdirectory(tests)
 621 endif(CLR_CMAKE_BUILD_TESTS)
 622
 623 include(definitionsconsistencycheck.cmake)