CMakeLists.txt

   1 cmake_minimum_required(VERSION 2.8.11)
   2
   3 # This must come before the project command.
   4 set(CMAKE_OSX_DEPLOYMENT_TARGET "10.12" CACHE STRING "Minimum OS X deployment version")
   5
   6 project(Vulkan-Tools)
   7
   8 set(CMAKE_MODULE_PATH ${CMAKE_MODULE_PATH} "${CMAKE_CURRENT_SOURCE_DIR}/cmake")
   9
  10 option(BUILD_CUBE "Build cube" ON)
  11 option(BUILD_VULKANINFO "Build vulkaninfo" ON)
  12 option(BUILD_ICD "Build icd" ON)
  13 # Installing the Mock ICD to system directories is probably not desired since
  14 # this ICD is not a very complete implementation.
  15 # Require the user to ask that it be installed if they really want it.
  16 option(INSTALL_ICD "Install icd" OFF)
  17
  18 # Enable IDE GUI folders
  19 set_property(GLOBAL PROPERTY USE_FOLDERS ON)
  20 # "Helper" targets that don't have interesting source code should set their FOLDER property to this
  21 set(TOOLS_TARGET_FOLDER "Helper Targets")
  22
  23 # Find Vulkan Headers and Loader
  24 # Search order:
  25 #  User-supplied CMAKE_PREFIX_PATH containing paths to the header and/or loader install dirs
  26 #  CMake options VULKAN_HEADERS_INSTALL_DIR and/or VULKAN_LOADER_INSTALL_DIR
  27 #  Env vars VULKAN_HEADERS_INSTALL_DIR and/or VULKAN_LOADER_INSTALL_DIR
  28 #  Fallback to FindVulkan operation using SDK install or system installed components.
  29 set(VULKAN_HEADERS_INSTALL_DIR "HEADERS-NOTFOUND" CACHE PATH "Absolute path to a Vulkan-Headers install directory")
  30 set(VULKAN_LOADER_INSTALL_DIR "LOADER-NOTFOUND" CACHE PATH "Absolute path to a Vulkan-Loader install directory")
  31 set(CMAKE_PREFIX_PATH ${CMAKE_PREFIX_PATH};${VULKAN_HEADERS_INSTALL_DIR};${VULKAN_LOADER_INSTALL_DIR};
  32                        $ENV{VULKAN_HEADERS_INSTALL_DIR};$ENV{VULKAN_LOADER_INSTALL_DIR})
  33 message(STATUS "Using find_package to locate Vulkan")
  34 find_package(Vulkan)
  35 # "Vulkan::Vulkan" on macOS causes the framework to be linked to the app instead of an individual library
  36 set(LIBVK "Vulkan::Vulkan")
  37 message(STATUS "Vulkan FOUND = ${Vulkan_FOUND}")
  38 message(STATUS "Vulkan Include = ${Vulkan_INCLUDE_DIR}")
  39 message(STATUS "Vulkan Lib = ${Vulkan_LIBRARY}")
  40
  41 # Install-related settings
  42 include(GNUInstallDirs)
  43 # Set a better default install location for Windows only if the user did not provide one.
  44 if (CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT AND WIN32)
  45     set (CMAKE_INSTALL_PREFIX "${CMAKE_BINARY_DIR}/install" CACHE PATH "default install path" FORCE )
  46 endif()
  47
  48 # uninstall target
  49 if (NOT TARGET uninstall)
  50     configure_file(
  51         "${CMAKE_CURRENT_SOURCE_DIR}/cmake/cmake_uninstall.cmake.in"
  52         "${CMAKE_CURRENT_BINARY_DIR}/cmake_uninstall.cmake"
  53         IMMEDIATE @ONLY)
  54
  55     add_custom_target(uninstall
  56         COMMAND ${CMAKE_COMMAND} -P ${CMAKE_CURRENT_BINARY_DIR}/cmake_uninstall.cmake)
  57     set_target_properties(uninstall PROPERTIES FOLDER ${TOOLS_TARGET_FOLDER})
  58 endif()
  59
  60 if(APPLE)
  61     # CMake versions 3 or later need CMAKE_MACOSX_RPATH defined.
  62     # This avoids the CMP0042 policy message.
  63     set(CMAKE_MACOSX_RPATH 1)
  64     # The "install" target for MacOS fixes up bundles in place.
  65     set(CMAKE_INSTALL_PREFIX ${CMAKE_BINARY_DIR})
  66 endif()
  67
  68 if (CMAKE_COMPILER_IS_GNUCC OR CMAKE_C_COMPILER_ID MATCHES "Clang")
  69     set(COMMON_COMPILE_FLAGS "-Wall -Wextra -Wno-unused-parameter -Wno-missing-field-initializers")
  70     set(COMMON_COMPILE_FLAGS "${COMMON_COMPILE_FLAGS} -fno-strict-aliasing -fno-builtin-memcmp")
  71
  72     # For GCC version 7.1 or greater, we need to disable the implicit fallthrough warning since
  73     # there's no consistent way to satisfy all compilers until they all accept the C++17 standard
  74     if (CMAKE_COMPILER_IS_GNUCC AND NOT (CMAKE_CXX_COMPILER_VERSION LESS 7.1))
  75         set(COMMON_COMPILE_FLAGS "${COMMON_COMPILE_FLAGS} -Wimplicit-fallthrough=0")
  76     endif()
  77
  78     if (APPLE)
  79         set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} ${COMMON_COMPILE_FLAGS}")
  80     else()
  81         set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -std=c99 ${COMMON_COMPILE_FLAGS}")
  82     endif()
  83     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} ${COMMON_COMPILE_FLAGS} -std=c++11 -fno-rtti")
  84     if (UNIX)
  85         set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -fvisibility=hidden")
  86         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -fvisibility=hidden")
  87     endif()
  88 endif()
  89
  90 if(APPLE)
  91     include(mac_common.cmake)
  92 endif()
  93 if(BUILD_CUBE)
  94     add_subdirectory(cube)
  95 endif()
  96 if(BUILD_VULKANINFO)
  97     add_subdirectory(vulkaninfo)
  98 endif()
  99 if(BUILD_ICD)
 100     add_subdirectory(icd)
 101 endif()