CMakeLists.txt

   1 # ----------------------------------------------------------------------------
   2 #  Root CMake file for OpenCV
   3 #
   4 #    From the off-tree build directory, invoke:
   5 #      $ cmake <PATH_TO_OPENCV_ROOT>
   6 #
   7 # ----------------------------------------------------------------------------
   8
   9 # Disable in-source builds to prevent source tree corruption.
  10 if(" ${CMAKE_SOURCE_DIR}" STREQUAL " ${CMAKE_BINARY_DIR}")
  11   message(FATAL_ERROR "
  12 FATAL: In-source builds are not allowed.
  13        You should create a separate directory for build files.
  14 ")
  15 endif()
  16
  17
  18 include(cmake/OpenCVMinDepVersions.cmake)
  19
  20 if(CMAKE_SYSTEM_NAME MATCHES WindowsPhone OR CMAKE_SYSTEM_NAME MATCHES WindowsStore)
  21   cmake_minimum_required(VERSION 3.1 FATAL_ERROR)
  22   #Required to resolve linker error issues due to incompatibility with CMake v3.0+ policies.
  23   #CMake fails to find _fseeko() which leads to subsequent linker error.
  24   #See details here: http://www.cmake.org/Wiki/CMake/Policies
  25   cmake_policy(VERSION 2.8)
  26 else()
  27   cmake_minimum_required(VERSION "${MIN_VER_CMAKE}" FATAL_ERROR)
  28 endif()
  29
  30 #
  31 # Configure CMake policies
  32 #
  33 if(POLICY CMP0026)
  34   cmake_policy(SET CMP0026 NEW)
  35 endif()
  36
  37 if(POLICY CMP0042)
  38   cmake_policy(SET CMP0042 NEW)  # CMake 3.0+ (2.8.12): MacOS "@rpath" in target's install name
  39 endif()
  40
  41 if(POLICY CMP0046)
  42   cmake_policy(SET CMP0046 NEW)  # warn about non-existed dependencies
  43 endif()
  44
  45 if(POLICY CMP0051)
  46   cmake_policy(SET CMP0051 NEW)
  47 endif()
  48
  49 if(POLICY CMP0054)  # CMake 3.1: Only interpret if() arguments as variables or keywords when unquoted.
  50   cmake_policy(SET CMP0054 NEW)
  51 endif()
  52
  53 if(POLICY CMP0056)
  54   cmake_policy(SET CMP0056 NEW)  # try_compile(): link flags
  55 endif()
  56
  57 if(POLICY CMP0066)
  58   cmake_policy(SET CMP0066 NEW)  # CMake 3.7: try_compile(): use per-config flags, like CMAKE_CXX_FLAGS_RELEASE
  59 endif()
  60
  61 if(POLICY CMP0067)
  62   cmake_policy(SET CMP0067 NEW)  # CMake 3.8: try_compile(): honor language standard variables (like C++11)
  63 endif()
  64
  65 if(POLICY CMP0068)
  66   cmake_policy(SET CMP0068 NEW)  # CMake 3.9+: `RPATH` settings on macOS do not affect `install_name`.
  67 endif()
  68
  69 if(POLICY CMP0075)
  70   cmake_policy(SET CMP0075 NEW)  # CMake 3.12+: Include file check macros honor `CMAKE_REQUIRED_LIBRARIES`
  71 endif()
  72
  73 if(POLICY CMP0077)
  74   cmake_policy(SET CMP0077 NEW)  # CMake 3.13+: option() honors normal variables.
  75 endif()
  76
  77 #
  78 # Configure OpenCV CMake hooks
  79 #
  80 include(cmake/OpenCVUtils.cmake)
  81 ocv_cmake_reset_hooks()
  82 ocv_check_environment_variables(OPENCV_CMAKE_HOOKS_DIR)
  83 if(DEFINED OPENCV_CMAKE_HOOKS_DIR)
  84   foreach(__dir ${OPENCV_CMAKE_HOOKS_DIR})
  85     get_filename_component(__dir "${__dir}" ABSOLUTE)
  86     ocv_cmake_hook_register_dir(${__dir})
  87   endforeach()
  88 endif()
  89
  90 ocv_cmake_hook(CMAKE_INIT)
  91
  92 # must go before the project()/enable_language() commands
  93 ocv_update(CMAKE_CONFIGURATION_TYPES "Debug;Release" CACHE STRING "Configs" FORCE)
  94 if(DEFINED CMAKE_BUILD_TYPE)
  95   set_property(CACHE CMAKE_BUILD_TYPE PROPERTY STRINGS "${CMAKE_CONFIGURATION_TYPES}")
  96 endif()
  97
  98 option(ENABLE_PIC "Generate position independent code (necessary for shared libraries)" TRUE)
  99 set(CMAKE_POSITION_INDEPENDENT_CODE ${ENABLE_PIC})
 100
 101 ocv_cmake_hook(PRE_CMAKE_BOOTSTRAP)
 102
 103 # Bootstap CMake system: setup CMAKE_SYSTEM_NAME and other vars
 104 if(OPENCV_WORKAROUND_CMAKE_20989)
 105   set(CMAKE_SYSTEM_PROCESSOR_BACKUP ${CMAKE_SYSTEM_PROCESSOR})
 106 endif()
 107 enable_language(CXX C)
 108 if(OPENCV_WORKAROUND_CMAKE_20989)
 109   set(CMAKE_SYSTEM_PROCESSOR ${CMAKE_SYSTEM_PROCESSOR_BACKUP})
 110 endif()
 111
 112 ocv_cmake_hook(POST_CMAKE_BOOTSTRAP)
 113
 114 if(NOT OPENCV_SKIP_CMAKE_SYSTEM_FILE)
 115   include("cmake/platforms/OpenCV-${CMAKE_SYSTEM_NAME}.cmake" OPTIONAL RESULT_VARIABLE "OPENCV_CMAKE_SYSTEM_FILE")
 116   if(NOT OPENCV_CMAKE_SYSTEM_FILE)
 117     message(STATUS "OpenCV: system-specific configuration file is not found: '${CMAKE_SYSTEM_NAME}'")
 118   endif()
 119 endif()
 120
 121 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)  # https://cmake.org/cmake/help/latest/variable/CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT.html
 122   if(NOT CMAKE_TOOLCHAIN_FILE)
 123     if(WIN32)
 124       set(CMAKE_INSTALL_PREFIX "${CMAKE_BINARY_DIR}/install" CACHE PATH "Installation Directory" FORCE)
 125     else()
 126       set(CMAKE_INSTALL_PREFIX "/usr/local" CACHE PATH "Installation Directory" FORCE)
 127     endif()
 128   else()
 129     # any cross-compiling
 130     set(CMAKE_INSTALL_PREFIX "${CMAKE_BINARY_DIR}/install" CACHE PATH "Installation Directory" FORCE)
 131   endif()
 132 endif()
 133
 134 enable_testing()
 135
 136 project(OpenCV CXX C)
 137
 138 if(MSVC)
 139   set(CMAKE_USE_RELATIVE_PATHS ON CACHE INTERNAL "" FORCE)
 140 endif()
 141
 142 ocv_cmake_eval(DEBUG_PRE ONCE)
 143
 144 ocv_clear_vars(OpenCVModules_TARGETS)
 145
 146 include(cmake/OpenCVDownload.cmake)
 147
 148 set(BUILD_LIST "" CACHE STRING "Build only listed modules (comma-separated, e.g. 'videoio,dnn,ts')")
 149
 150 # ----------------------------------------------------------------------------
 151 # Break in case of popular CMake configuration mistakes
 152 # ----------------------------------------------------------------------------
 153 if(NOT CMAKE_SIZEOF_VOID_P GREATER 0)
 154   message(FATAL_ERROR "CMake fails to determine the bitness of the target platform.
 155   Please check your CMake and compiler installation. If you are cross-compiling then ensure that your CMake toolchain file correctly sets the compiler details.")
 156 endif()
 157
 158 # ----------------------------------------------------------------------------
 159 # Detect compiler and target platform architecture
 160 # ----------------------------------------------------------------------------
 161 include(cmake/OpenCVDetectCXXCompiler.cmake)
 162 ocv_cmake_hook(POST_DETECT_COMPILER)
 163
 164 # Add these standard paths to the search paths for FIND_LIBRARY
 165 # to find libraries from these locations first
 166 if(UNIX AND NOT ANDROID)
 167   if(X86_64 OR CMAKE_SIZEOF_VOID_P EQUAL 8)
 168     if(EXISTS /lib64)
 169       list(APPEND CMAKE_LIBRARY_PATH /lib64)
 170     else()
 171       list(APPEND CMAKE_LIBRARY_PATH /lib)
 172     endif()
 173     if(EXISTS /usr/lib64)
 174       list(APPEND CMAKE_LIBRARY_PATH /usr/lib64)
 175     else()
 176       list(APPEND CMAKE_LIBRARY_PATH /usr/lib)
 177     endif()
 178   elseif(X86 OR CMAKE_SIZEOF_VOID_P EQUAL 4)
 179     if(EXISTS /lib32)
 180       list(APPEND CMAKE_LIBRARY_PATH /lib32)
 181     else()
 182       list(APPEND CMAKE_LIBRARY_PATH /lib)
 183     endif()
 184     if(EXISTS /usr/lib32)
 185       list(APPEND CMAKE_LIBRARY_PATH /usr/lib32)
 186     else()
 187       list(APPEND CMAKE_LIBRARY_PATH /usr/lib)
 188     endif()
 189   endif()
 190 endif()
 191
 192 # Add these standard paths to the search paths for FIND_PATH
 193 # to find include files from these locations first
 194 if(MINGW)
 195   if(EXISTS /mingw)
 196       list(APPEND CMAKE_INCLUDE_PATH /mingw)
 197   endif()
 198   if(EXISTS /mingw32)
 199       list(APPEND CMAKE_INCLUDE_PATH /mingw32)
 200   endif()
 201   if(EXISTS /mingw64)
 202       list(APPEND CMAKE_INCLUDE_PATH /mingw64)
 203   endif()
 204 endif()
 205
 206 # ----------------------------------------------------------------------------
 207 # OpenCV cmake options
 208 # ----------------------------------------------------------------------------
 209
 210 OCV_OPTION(OPENCV_ENABLE_NONFREE "Enable non-free algorithms" OFF)
 211
 212 # 3rd party libs
 213 OCV_OPTION(OPENCV_FORCE_3RDPARTY_BUILD   "Force using 3rdparty code from source" OFF)
 214 OCV_OPTION(BUILD_ZLIB               "Build zlib from source"             (WIN32 OR APPLE OR OPENCV_FORCE_3RDPARTY_BUILD) )
 215 OCV_OPTION(BUILD_TIFF               "Build libtiff from source"          (WIN32 OR ANDROID OR APPLE OR OPENCV_FORCE_3RDPARTY_BUILD) )
 216 OCV_OPTION(BUILD_OPENJPEG           "Build OpenJPEG from source"         (WIN32 OR ANDROID OR APPLE OR OPENCV_FORCE_3RDPARTY_BUILD) )
 217 OCV_OPTION(BUILD_JASPER             "Build libjasper from source"        (WIN32 OR ANDROID OR APPLE OR OPENCV_FORCE_3RDPARTY_BUILD) )
 218 OCV_OPTION(BUILD_JPEG               "Build libjpeg from source"          (WIN32 OR ANDROID OR APPLE OR OPENCV_FORCE_3RDPARTY_BUILD) )
 219 OCV_OPTION(BUILD_PNG                "Build libpng from source"           (WIN32 OR ANDROID OR APPLE OR OPENCV_FORCE_3RDPARTY_BUILD) )
 220 OCV_OPTION(BUILD_OPENEXR            "Build openexr from source"          (((WIN32 OR ANDROID OR APPLE) AND NOT WINRT) OR OPENCV_FORCE_3RDPARTY_BUILD) )
 221 OCV_OPTION(BUILD_WEBP               "Build WebP from source"             (((WIN32 OR ANDROID OR APPLE) AND NOT WINRT) OR OPENCV_FORCE_3RDPARTY_BUILD) )
 222 OCV_OPTION(BUILD_TBB                "Download and build TBB from source" (ANDROID OR OPENCV_FORCE_3RDPARTY_BUILD) )
 223 OCV_OPTION(BUILD_IPP_IW             "Build IPP IW from source"           (NOT MINGW OR OPENCV_FORCE_3RDPARTY_BUILD) IF (X86_64 OR X86) AND NOT WINRT )
 224 OCV_OPTION(BUILD_ITT                "Build Intel ITT from source"
 225     (NOT MINGW OR OPENCV_FORCE_3RDPARTY_BUILD)
 226     IF (X86_64 OR X86 OR ARM OR AARCH64 OR PPC64 OR PPC64LE) AND NOT WINRT AND NOT APPLE_FRAMEWORK
 227 )
 228
 229 # Optional 3rd party components
 230 # ===================================================
 231 OCV_OPTION(WITH_1394 "Include IEEE1394 support" ON
 232   VISIBLE_IF NOT ANDROID AND NOT IOS AND NOT WINRT
 233   VERIFY HAVE_DC1394_2)
 234 OCV_OPTION(WITH_AVFOUNDATION "Use AVFoundation for Video I/O (iOS/Mac)" ON
 235   VISIBLE_IF APPLE
 236   VERIFY HAVE_AVFOUNDATION)
 237 OCV_OPTION(WITH_CAP_IOS "Enable iOS video capture" ON
 238   VISIBLE_IF IOS
 239   VERIFY HAVE_CAP_IOS)
 240 OCV_OPTION(WITH_CAROTENE "Use NVidia carotene acceleration library for ARM platform" ON
 241   VISIBLE_IF (ARM OR AARCH64) AND NOT IOS)
 242 OCV_OPTION(WITH_CPUFEATURES "Use cpufeatures Android library" ON
 243   VISIBLE_IF ANDROID
 244   VERIFY HAVE_CPUFEATURES)
 245 OCV_OPTION(WITH_VTK "Include VTK library support (and build opencv_viz module eiher)" ON
 246   VISIBLE_IF NOT ANDROID AND NOT IOS AND NOT WINRT AND NOT CMAKE_CROSSCOMPILING
 247   VERIFY HAVE_VTK)
 248 OCV_OPTION(WITH_CUDA "Include NVidia Cuda Runtime support" OFF
 249   VISIBLE_IF NOT IOS AND NOT WINRT
 250   VERIFY HAVE_CUDA)
 251 OCV_OPTION(WITH_CUFFT "Include NVidia Cuda Fast Fourier Transform (FFT) library support" WITH_CUDA
 252   VISIBLE_IF WITH_CUDA
 253   VERIFY HAVE_CUFFT)
 254 OCV_OPTION(WITH_CUBLAS "Include NVidia Cuda Basic Linear Algebra Subprograms (BLAS) library support" WITH_CUDA
 255   VISIBLE_IF WITH_CUDA
 256   VERIFY HAVE_CUBLAS)
 257 OCV_OPTION(WITH_CUDNN "Include NVIDIA CUDA Deep Neural Network (cuDNN) library support" WITH_CUDA
 258   VISIBLE_IF WITH_CUDA
 259   VERIFY HAVE_CUDNN)
 260 OCV_OPTION(WITH_NVCUVID "Include NVidia Video Decoding library support" OFF  # disabled, details: https://github.com/opencv/opencv/issues/14850
 261   VISIBLE_IF WITH_CUDA
 262   VERIFY HAVE_NVCUVID)
 263 OCV_OPTION(WITH_EIGEN "Include Eigen2/Eigen3 support" (NOT CV_DISABLE_OPTIMIZATION AND NOT CMAKE_CROSSCOMPILING)
 264   VISIBLE_IF NOT WINRT
 265   VERIFY HAVE_EIGEN)
 266 OCV_OPTION(WITH_FFMPEG "Include FFMPEG support" (NOT ANDROID)
 267   VISIBLE_IF NOT IOS AND NOT WINRT
 268   VERIFY HAVE_FFMPEG)
 269 OCV_OPTION(WITH_GSTREAMER "Include Gstreamer support" ON
 270   VISIBLE_IF NOT ANDROID AND NOT IOS AND NOT WINRT
 271   VERIFY HAVE_GSTREAMER AND GSTREAMER_VERSION VERSION_GREATER "0.99")
 272 OCV_OPTION(WITH_GTK "Include GTK support" ON
 273   VISIBLE_IF UNIX AND NOT APPLE AND NOT ANDROID
 274   VERIFY HAVE_GTK)
 275 OCV_OPTION(WITH_GTK_2_X "Use GTK version 2" OFF
 276   VISIBLE_IF UNIX AND NOT APPLE AND NOT ANDROID
 277   VERIFY HAVE_GTK AND NOT HAVE_GTK3)
 278 OCV_OPTION(WITH_IPP "Include Intel IPP support" (NOT MINGW AND NOT CV_DISABLE_OPTIMIZATION)
 279   VISIBLE_IF (X86_64 OR X86) AND NOT WINRT AND NOT IOS
 280   VERIFY HAVE_IPP)
 281 OCV_OPTION(WITH_HALIDE "Include Halide support" OFF
 282   VISIBLE_IF TRUE
 283   VERIFY HAVE_HALIDE)
 284 OCV_OPTION(WITH_VULKAN "Include Vulkan support" OFF
 285   VISIBLE_IF TRUE
 286   VERIFY HAVE_VULKAN)
 287 OCV_OPTION(WITH_INF_ENGINE "Include Intel Inference Engine support" OFF
 288   VISIBLE_IF TRUE
 289   VERIFY INF_ENGINE_TARGET)
 290 OCV_OPTION(WITH_NGRAPH "Include nGraph support" WITH_INF_ENGINE
 291   VISIBLE_IF TRUE
 292   VERIFY TARGET ngraph::ngraph)
 293 OCV_OPTION(WITH_JASPER "Include JPEG2K support (Jasper)" ON
 294   VISIBLE_IF NOT IOS
 295   VERIFY HAVE_JASPER)
 296 OCV_OPTION(WITH_OPENJPEG "Include JPEG2K support (OpenJPEG)" ON
 297   VISIBLE_IF NOT IOS
 298   VERIFY HAVE_OPENJPEG)
 299 OCV_OPTION(WITH_JPEG "Include JPEG support" ON
 300   VISIBLE_IF TRUE
 301   VERIFY HAVE_JPEG)
 302 OCV_OPTION(WITH_WEBP "Include WebP support" ON
 303   VISIBLE_IF NOT WINRT
 304   VERIFY HAVE_WEBP)
 305 OCV_OPTION(WITH_OPENEXR "Include ILM support via OpenEXR" BUILD_OPENEXR OR NOT CMAKE_CROSSCOMPILING
 306   VISIBLE_IF NOT APPLE_FRAMEWORK AND NOT WINRT
 307   VERIFY HAVE_OPENEXR)
 308 OCV_OPTION(WITH_OPENGL "Include OpenGL support" OFF
 309   VISIBLE_IF NOT ANDROID AND NOT WINRT
 310   VERIFY HAVE_OPENGL)
 311 OCV_OPTION(WITH_OPENVX "Include OpenVX support" OFF
 312   VISIBLE_IF TRUE
 313   VERIFY HAVE_OPENVX)
 314 OCV_OPTION(WITH_OPENNI "Include OpenNI support" OFF
 315   VISIBLE_IF NOT ANDROID AND NOT IOS AND NOT WINRT
 316   VERIFY HAVE_OPENNI)
 317 OCV_OPTION(WITH_OPENNI2 "Include OpenNI2 support" OFF
 318   VISIBLE_IF NOT ANDROID AND NOT IOS AND NOT WINRT
 319   VERIFY HAVE_OPENNI2)
 320 OCV_OPTION(WITH_PNG "Include PNG support" ON
 321   VISIBLE_IF TRUE
 322   VERIFY HAVE_PNG)
 323 OCV_OPTION(WITH_GDCM "Include DICOM support" OFF
 324   VISIBLE_IF TRUE
 325   VERIFY HAVE_GDCM)
 326 OCV_OPTION(WITH_PVAPI "Include Prosilica GigE support" OFF
 327   VISIBLE_IF NOT ANDROID AND NOT IOS AND NOT WINRT
 328   VERIFY HAVE_PVAPI)
 329 OCV_OPTION(WITH_ARAVIS "Include Aravis GigE support" OFF
 330   VISIBLE_IF NOT ANDROID AND NOT IOS AND NOT WINRT AND NOT WIN32
 331   VERIFY HAVE_ARAVIS_API)
 332 OCV_OPTION(WITH_QT "Build with Qt Backend support" OFF
 333   VISIBLE_IF NOT ANDROID AND NOT IOS AND NOT WINRT
 334   VERIFY HAVE_QT)
 335 OCV_OPTION(WITH_WIN32UI "Build with Win32 UI Backend support" ON
 336   VISIBLE_IF WIN32 AND NOT WINRT
 337   VERIFY HAVE_WIN32UI)
 338 OCV_OPTION(WITH_TBB "Include Intel TBB support" OFF
 339   VISIBLE_IF NOT IOS AND NOT WINRT
 340   VERIFY HAVE_TBB)
 341 OCV_OPTION(WITH_HPX "Include Ste||ar Group HPX support" OFF
 342   VISIBLE_IF TRUE
 343   VERIFY HAVE_HPX)
 344 OCV_OPTION(WITH_OPENMP "Include OpenMP support" OFF
 345   VISIBLE_IF TRUE
 346   VERIFY HAVE_OPENMP)
 347 OCV_OPTION(WITH_PTHREADS_PF "Use pthreads-based parallel_for" ON
 348   VISIBLE_IF NOT WIN32 OR MINGW
 349   VERIFY HAVE_PTHREADS_PF)
 350 OCV_OPTION(WITH_TIFF "Include TIFF support" ON
 351   VISIBLE_IF NOT IOS
 352   VERIFY HAVE_TIFF)
 353 OCV_OPTION(WITH_V4L "Include Video 4 Linux support" ON
 354   VISIBLE_IF UNIX AND NOT ANDROID AND NOT APPLE
 355   VERIFY HAVE_CAMV4L OR HAVE_CAMV4L2 OR HAVE_VIDEOIO)
 356 OCV_OPTION(WITH_DSHOW "Build VideoIO with DirectShow support" ON
 357   VISIBLE_IF WIN32 AND NOT ARM AND NOT WINRT
 358   VERIFY HAVE_DSHOW)
 359 OCV_OPTION(WITH_MSMF "Build VideoIO with Media Foundation support" NOT MINGW
 360   VISIBLE_IF WIN32
 361   VERIFY HAVE_MSMF)
 362 OCV_OPTION(WITH_MSMF_DXVA "Enable hardware acceleration in Media Foundation backend" WITH_MSMF
 363   VISIBLE_IF WIN32
 364   VERIFY HAVE_MSMF_DXVA)
 365 OCV_OPTION(WITH_XIMEA "Include XIMEA cameras support" OFF
 366   VISIBLE_IF NOT ANDROID AND NOT WINRT
 367   VERIFY HAVE_XIMEA)
 368 OCV_OPTION(WITH_UEYE "Include UEYE camera support" OFF
 369   VISIBLE_IF NOT ANDROID AND NOT APPLE AND NOT WINRT
 370   VERIFY HAVE_UEYE)
 371 OCV_OPTION(WITH_XINE "Include Xine support (GPL)" OFF
 372   VISIBLE_IF UNIX AND NOT APPLE AND NOT ANDROID
 373   VERIFY HAVE_XINE)
 374 OCV_OPTION(WITH_CLP "Include Clp support (EPL)" OFF
 375   VISIBLE_IF TRUE
 376   VERIFY HAVE_CLP)
 377 OCV_OPTION(WITH_OPENCL "Include OpenCL Runtime support" (NOT ANDROID AND NOT CV_DISABLE_OPTIMIZATION)
 378   VISIBLE_IF NOT IOS AND NOT WINRT
 379   VERIFY HAVE_OPENCL)
 380 OCV_OPTION(WITH_OPENCL_SVM "Include OpenCL Shared Virtual Memory support" OFF
 381   VISIBLE_IF TRUE
 382   VERIFY HAVE_OPENCL_SVM) # experimental
 383 OCV_OPTION(WITH_OPENCLAMDFFT "Include AMD OpenCL FFT library support" ON
 384   VISIBLE_IF NOT ANDROID AND NOT IOS AND NOT WINRT
 385   VERIFY HAVE_CLAMDFFT)
 386 OCV_OPTION(WITH_OPENCLAMDBLAS "Include AMD OpenCL BLAS library support" ON
 387   VISIBLE_IF NOT ANDROID AND NOT IOS AND NOT WINRT
 388   VERIFY HAVE_CLAMDBLAS)
 389 OCV_OPTION(WITH_DIRECTX "Include DirectX support" ON
 390   VISIBLE_IF WIN32 AND NOT WINRT
 391   VERIFY HAVE_DIRECTX)
 392 OCV_OPTION(WITH_OPENCL_D3D11_NV "Include NVIDIA OpenCL D3D11 support" WITH_DIRECTX
 393   VISIBLE_IF WIN32 AND NOT WINRT
 394   VERIFY HAVE_OPENCL_D3D11_NV)
 395 OCV_OPTION(WITH_LIBREALSENSE "Include Intel librealsense support" OFF
 396   VISIBLE_IF NOT WITH_INTELPERC
 397   VERIFY HAVE_LIBREALSENSE)
 398 OCV_OPTION(WITH_VA "Include VA support" (X86_64 OR X86)
 399   VISIBLE_IF UNIX AND NOT APPLE AND NOT ANDROID
 400   VERIFY HAVE_VA)
 401 OCV_OPTION(WITH_VA_INTEL "Include Intel VA-API/OpenCL support" (X86_64 OR X86)
 402   VISIBLE_IF UNIX AND NOT APPLE AND NOT ANDROID
 403   VERIFY HAVE_VA_INTEL)
 404 OCV_OPTION(WITH_MFX "Include Intel Media SDK support" OFF
 405   VISIBLE_IF (UNIX AND NOT ANDROID) OR (WIN32 AND NOT WINRT AND NOT MINGW)
 406   VERIFY HAVE_MFX)
 407 OCV_OPTION(WITH_GDAL "Include GDAL Support" OFF
 408   VISIBLE_IF NOT ANDROID AND NOT IOS AND NOT WINRT
 409   VERIFY HAVE_GDAL)
 410 OCV_OPTION(WITH_GPHOTO2 "Include gPhoto2 library support" OFF
 411   VISIBLE_IF UNIX AND NOT ANDROID AND NOT IOS
 412   VERIFY HAVE_GPHOTO2)
 413 OCV_OPTION(WITH_LAPACK "Include Lapack library support" (NOT CV_DISABLE_OPTIMIZATION)
 414   VISIBLE_IF NOT ANDROID AND NOT IOS
 415   VERIFY HAVE_LAPACK)
 416 OCV_OPTION(WITH_ITT "Include Intel ITT support" ON
 417   VISIBLE_IF NOT APPLE_FRAMEWORK
 418   VERIFY HAVE_ITT)
 419 OCV_OPTION(WITH_PROTOBUF "Enable libprotobuf" ON
 420   VISIBLE_IF TRUE
 421   VERIFY HAVE_PROTOBUF)
 422 OCV_OPTION(WITH_IMGCODEC_HDR "Include HDR support" ON
 423   VISIBLE_IF TRUE
 424   VERIFY HAVE_IMGCODEC_HDR)
 425 OCV_OPTION(WITH_IMGCODEC_SUNRASTER "Include SUNRASTER support" ON
 426   VISIBLE_IF TRUE
 427   VERIFY HAVE_IMGCODEC_SUNRASTER)
 428 OCV_OPTION(WITH_IMGCODEC_PXM "Include PNM (PBM,PGM,PPM) and PAM formats support" ON
 429   VISIBLE_IF TRUE
 430   VERIFY HAVE_IMGCODEC_PXM)
 431 OCV_OPTION(WITH_IMGCODEC_PFM "Include PFM formats support" ON
 432   VISIBLE_IF TRUE
 433   VERIFY HAVE_IMGCODEC_PFM)
 434 OCV_OPTION(WITH_QUIRC "Include library QR-code decoding" ON
 435   VISIBLE_IF TRUE
 436   VERIFY HAVE_QUIRC)
 437 OCV_OPTION(WITH_ANDROID_MEDIANDK "Use Android Media NDK for Video I/O (Android)" (ANDROID_NATIVE_API_LEVEL GREATER 20)
 438   VISIBLE_IF ANDROID
 439   VERIFY HAVE_ANDROID_MEDIANDK)
 440 OCV_OPTION(WITH_ANDROID_NATIVE_CAMERA "Use Android NDK for Camera I/O (Android)" (ANDROID_NATIVE_API_LEVEL GREATER 23)
 441   VISIBLE_IF ANDROID
 442   VERIFY HAVE_ANDROID_NATIVE_CAMERA)
 443 OCV_OPTION(WITH_TENGINE "Include Arm Inference Tengine support" OFF
 444   VISIBLE_IF (ARM OR AARCH64) AND (UNIX OR ANDROID) AND NOT IOS
 445   VERIFY HAVE_TENGINE)
 446 OCV_OPTION(WITH_ONNX "Include Microsoft ONNX Runtime support" OFF
 447   VISIBLE_IF TRUE
 448   VERIFY HAVE_ONNX)
 449
 450 # OpenCV build components
 451 # ===================================================
 452 OCV_OPTION(BUILD_SHARED_LIBS        "Build shared libraries (.dll/.so) instead of static ones (.lib/.a)" NOT (ANDROID OR APPLE_FRAMEWORK) )
 453 OCV_OPTION(BUILD_opencv_apps        "Build utility applications (used for example to train classifiers)" (NOT ANDROID AND NOT WINRT) IF (NOT APPLE_FRAMEWORK) )
 454 OCV_OPTION(BUILD_opencv_js          "Build JavaScript bindings by Emscripten" OFF )
 455 OCV_OPTION(BUILD_ANDROID_PROJECTS   "Build Android projects providing .apk files" ON  IF ANDROID )
 456 OCV_OPTION(BUILD_ANDROID_EXAMPLES   "Build examples for Android platform"         ON  IF ANDROID )
 457 OCV_OPTION(BUILD_DOCS               "Create build rules for OpenCV Documentation" OFF  IF (NOT WINRT AND NOT APPLE_FRAMEWORK))
 458 OCV_OPTION(BUILD_EXAMPLES           "Build all examples"                          OFF )
 459 OCV_OPTION(BUILD_PACKAGE            "Enables 'make package_source' command"       ON  IF NOT WINRT)
 460 OCV_OPTION(BUILD_PERF_TESTS         "Build performance tests"                     NOT INSTALL_CREATE_DISTRIB  IF (NOT APPLE_FRAMEWORK) )
 461 OCV_OPTION(BUILD_TESTS              "Build accuracy & regression tests"           NOT INSTALL_CREATE_DISTRIB  IF (NOT APPLE_FRAMEWORK) )
 462 OCV_OPTION(BUILD_WITH_DEBUG_INFO    "Include debug info into release binaries ('OFF' means default settings)" OFF )
 463 OCV_OPTION(BUILD_WITH_STATIC_CRT    "Enables use of statically linked CRT for statically linked OpenCV" ON IF MSVC )
 464 OCV_OPTION(BUILD_WITH_DYNAMIC_IPP   "Enables dynamic linking of IPP (only for standalone IPP)" OFF )
 465 OCV_OPTION(BUILD_FAT_JAVA_LIB       "Create Java wrapper exporting all functions of OpenCV library (requires static build of OpenCV modules)" ANDROID IF NOT BUILD_SHARED_LIBS)
 466 OCV_OPTION(BUILD_ANDROID_SERVICE    "Build OpenCV Manager for Google Play" OFF IF ANDROID )
 467 OCV_OPTION(BUILD_CUDA_STUBS         "Build CUDA modules stubs when no CUDA SDK" OFF  IF (NOT APPLE_FRAMEWORK) )
 468 OCV_OPTION(BUILD_JAVA               "Enable Java support"                         (ANDROID OR NOT CMAKE_CROSSCOMPILING)  IF (ANDROID OR (NOT APPLE_FRAMEWORK AND NOT WINRT)) )
 469 OCV_OPTION(BUILD_OBJC               "Enable Objective-C support"                  ON  IF APPLE_FRAMEWORK )
 470
 471 # OpenCV installation options
 472 # ===================================================
 473 OCV_OPTION(INSTALL_CREATE_DISTRIB   "Change install rules to build the distribution package" OFF )
 474 OCV_OPTION(INSTALL_BIN_EXAMPLES     "Install prebuilt examples" WIN32 IF BUILD_EXAMPLES)
 475 OCV_OPTION(INSTALL_C_EXAMPLES       "Install C examples"        OFF )
 476 OCV_OPTION(INSTALL_PYTHON_EXAMPLES  "Install Python examples"   OFF )
 477 OCV_OPTION(INSTALL_ANDROID_EXAMPLES "Install Android examples"  OFF IF ANDROID )
 478 OCV_OPTION(INSTALL_TO_MANGLED_PATHS "Enables mangled install paths, that help with side by side installs." OFF IF (UNIX AND NOT ANDROID AND NOT APPLE_FRAMEWORK AND BUILD_SHARED_LIBS) )
 479 OCV_OPTION(INSTALL_TESTS            "Install accuracy and performance test binaries and test data" OFF)
 480
 481 # OpenCV build options
 482 # ===================================================
 483 OCV_OPTION(ENABLE_CCACHE              "Use ccache"                                               (UNIX AND (CMAKE_GENERATOR MATCHES "Makefile" OR CMAKE_GENERATOR MATCHES "Ninja" OR CMAKE_GENERATOR MATCHES "Xcode")) )
 484 OCV_OPTION(ENABLE_PRECOMPILED_HEADERS "Use precompiled headers"                                  MSVC IF (MSVC OR (NOT IOS AND NOT CMAKE_CROSSCOMPILING) ) )
 485 OCV_OPTION(ENABLE_SOLUTION_FOLDERS    "Solution folder in Visual Studio or in other IDEs"        (MSVC_IDE OR CMAKE_GENERATOR MATCHES Xcode) )
 486 OCV_OPTION(ENABLE_PROFILING           "Enable profiling in the GCC compiler (Add flags: -g -pg)" OFF  IF CV_GCC )
 487 OCV_OPTION(ENABLE_COVERAGE            "Enable coverage collection with  GCov"                    OFF  IF CV_GCC )
 488 OCV_OPTION(OPENCV_ENABLE_MEMORY_SANITIZER "Better support for memory/address sanitizers"         OFF)
 489 OCV_OPTION(ENABLE_OMIT_FRAME_POINTER  "Enable -fomit-frame-pointer for GCC"                      ON   IF CV_GCC )
 490 OCV_OPTION(ENABLE_POWERPC             "Enable PowerPC for GCC"                                   ON   IF (CV_GCC AND CMAKE_SYSTEM_PROCESSOR MATCHES powerpc.*) )
 491 OCV_OPTION(ENABLE_FAST_MATH           "Enable compiler options for fast math optimizations on FP computations (not recommended)" OFF)
 492 if(NOT IOS AND (NOT ANDROID OR OPENCV_ANDROID_USE_LEGACY_FLAGS) AND CMAKE_CROSSCOMPILING)  # Use CPU_BASELINE instead
 493 OCV_OPTION(ENABLE_NEON                "Enable NEON instructions"                                 (NEON OR ANDROID_ARM_NEON OR AARCH64) IF (CV_GCC OR CV_CLANG) AND (ARM OR AARCH64 OR IOS) )
 494 OCV_OPTION(ENABLE_VFPV3               "Enable VFPv3-D32 instructions"                            OFF  IF (CV_GCC OR CV_CLANG) AND (ARM OR AARCH64 OR IOS) )
 495 endif()
 496 OCV_OPTION(ENABLE_NOISY_WARNINGS      "Show all warnings even if they are too noisy"             OFF )
 497 OCV_OPTION(OPENCV_WARNINGS_ARE_ERRORS "Treat warnings as errors"                                 OFF )
 498 OCV_OPTION(ANDROID_EXAMPLES_WITH_LIBS "Build binaries of Android examples with native libraries" OFF  IF ANDROID )
 499 OCV_OPTION(ENABLE_IMPL_COLLECTION     "Collect implementation data on function call"             OFF )
 500 OCV_OPTION(ENABLE_INSTRUMENTATION     "Instrument functions to collect calls trace and performance" OFF )
 501 OCV_OPTION(ENABLE_GNU_STL_DEBUG       "Enable GNU STL Debug mode (defines _GLIBCXX_DEBUG)"       OFF IF CV_GCC )
 502 OCV_OPTION(ENABLE_BUILD_HARDENING     "Enable hardening of the resulting binaries (against security attacks, detects memory corruption, etc)" OFF)
 503 OCV_OPTION(ENABLE_LTO                 "Enable Link Time Optimization" OFF IF CV_GCC OR MSVC)
 504 OCV_OPTION(ENABLE_THIN_LTO            "Enable Thin LTO" OFF IF CV_CLANG)
 505 OCV_OPTION(GENERATE_ABI_DESCRIPTOR    "Generate XML file for abi_compliance_checker tool" OFF IF UNIX)
 506 OCV_OPTION(OPENCV_GENERATE_PKGCONFIG  "Generate .pc file for pkg-config build tool (deprecated)" OFF)
 507 OCV_OPTION(CV_ENABLE_INTRINSICS       "Use intrinsic-based optimized code" ON )
 508 OCV_OPTION(CV_DISABLE_OPTIMIZATION    "Disable explicit optimized code (dispatched code/intrinsics/loop unrolling/etc)" OFF )
 509 OCV_OPTION(CV_TRACE                   "Enable OpenCV code trace" ON)
 510 OCV_OPTION(OPENCV_GENERATE_SETUPVARS  "Generate setup_vars* scripts" ON IF (NOT ANDROID AND NOT APPLE_FRAMEWORK) )
 511 OCV_OPTION(ENABLE_CONFIG_VERIFICATION "Fail build if actual configuration doesn't match requested (WITH_XXX != HAVE_XXX)" OFF)
 512 OCV_OPTION(OPENCV_ENABLE_MEMALIGN     "Enable posix_memalign or memalign usage" ON)
 513 OCV_OPTION(OPENCV_DISABLE_FILESYSTEM_SUPPORT "Disable filesystem support" OFF)
 514
 515 OCV_OPTION(ENABLE_PYLINT              "Add target with Pylint checks"                            (BUILD_DOCS OR BUILD_EXAMPLES) IF (NOT CMAKE_CROSSCOMPILING AND NOT APPLE_FRAMEWORK) )
 516 OCV_OPTION(ENABLE_FLAKE8              "Add target with Python flake8 checker"                    (BUILD_DOCS OR BUILD_EXAMPLES) IF (NOT CMAKE_CROSSCOMPILING AND NOT APPLE_FRAMEWORK) )
 517
 518 if(ENABLE_IMPL_COLLECTION)
 519   add_definitions(-DCV_COLLECT_IMPL_DATA)
 520 endif()
 521
 522 if(OPENCV_DISABLE_FILESYSTEM_SUPPORT)
 523   add_definitions(-DOPENCV_HAVE_FILESYSTEM_SUPPORT=0)
 524 endif()
 525
 526 set(OPENCV_MATHJAX_RELPATH "https://cdnjs.cloudflare.com/ajax/libs/mathjax/2.7.0" CACHE STRING "URI to a MathJax installation")
 527
 528 # ----------------------------------------------------------------------------
 529 #  Get actual OpenCV version number from sources
 530 # ----------------------------------------------------------------------------
 531 include(cmake/OpenCVVersion.cmake)
 532
 533 ocv_cmake_hook(POST_OPTIONS)
 534
 535 # ----------------------------------------------------------------------------
 536 #  Build & install layouts
 537 # ----------------------------------------------------------------------------
 538
 539 if(OPENCV_TEST_DATA_PATH)
 540   get_filename_component(OPENCV_TEST_DATA_PATH ${OPENCV_TEST_DATA_PATH} ABSOLUTE)
 541 endif()
 542
 543 # Save libs and executables in the same place
 544 set(EXECUTABLE_OUTPUT_PATH "${CMAKE_BINARY_DIR}/bin" CACHE PATH "Output directory for applications")
 545
 546 if(ANDROID)
 547   set(LIBRARY_OUTPUT_PATH                "${OpenCV_BINARY_DIR}/lib/${ANDROID_NDK_ABI_NAME}")
 548   ocv_update(3P_LIBRARY_OUTPUT_PATH      "${OpenCV_BINARY_DIR}/3rdparty/lib/${ANDROID_NDK_ABI_NAME}")
 549 else()
 550   set(LIBRARY_OUTPUT_PATH                "${OpenCV_BINARY_DIR}/lib")
 551   ocv_update(3P_LIBRARY_OUTPUT_PATH      "${OpenCV_BINARY_DIR}/3rdparty/lib")
 552 endif()
 553
 554 if(ANDROID)
 555   if(ANDROID_ABI MATCHES "NEON")
 556     set(ENABLE_NEON ON)
 557   endif()
 558   if(ANDROID_ABI MATCHES "VFPV3")
 559     set(ENABLE_VFPV3 ON)
 560   endif()
 561 endif()
 562
 563 if(WIN32)
 564   # Postfix of DLLs:
 565   ocv_update(OPENCV_DLLVERSION "${OPENCV_VERSION_MAJOR}${OPENCV_VERSION_MINOR}${OPENCV_VERSION_PATCH}")
 566   ocv_update(OPENCV_DEBUG_POSTFIX d)
 567 else()
 568   # Postfix of so's:
 569   ocv_update(OPENCV_DLLVERSION "")
 570   ocv_update(OPENCV_DEBUG_POSTFIX "")
 571 endif()
 572
 573 if(DEFINED CMAKE_DEBUG_POSTFIX)
 574   set(OPENCV_DEBUG_POSTFIX "${CMAKE_DEBUG_POSTFIX}")
 575 endif()
 576
 577 if((INSTALL_CREATE_DISTRIB AND BUILD_SHARED_LIBS AND NOT DEFINED BUILD_opencv_world) OR APPLE_FRAMEWORK)
 578   set(BUILD_opencv_world ON CACHE INTERNAL "")
 579 endif()
 580
 581 include(cmake/OpenCVInstallLayout.cmake)
 582
 583 # ----------------------------------------------------------------------------
 584 #  Path for build/platform -specific headers
 585 # ----------------------------------------------------------------------------
 586 ocv_update(OPENCV_CONFIG_FILE_INCLUDE_DIR "${CMAKE_BINARY_DIR}/" CACHE PATH "Where to create the platform-dependant cvconfig.h")
 587 ocv_include_directories(${OPENCV_CONFIG_FILE_INCLUDE_DIR})
 588
 589 # ----------------------------------------------------------------------------
 590 #  Path for additional modules
 591 # ----------------------------------------------------------------------------
 592 set(OPENCV_EXTRA_MODULES_PATH "" CACHE PATH "Where to look for additional OpenCV modules (can be ;-separated list of paths)")
 593
 594 # ----------------------------------------------------------------------------
 595 #  Autodetect if we are in a GIT repository
 596 # ----------------------------------------------------------------------------
 597 find_host_package(Git QUIET)
 598
 599 if(NOT DEFINED OPENCV_VCSVERSION AND GIT_FOUND)
 600   ocv_git_describe(OPENCV_VCSVERSION "${OpenCV_SOURCE_DIR}")
 601 elseif(NOT DEFINED OPENCV_VCSVERSION)
 602   # We don't have git:
 603   set(OPENCV_VCSVERSION "unknown")
 604 endif()
 605
 606
 607 # ----------------------------------------------------------------------------
 608 # OpenCV compiler and linker options
 609 # ----------------------------------------------------------------------------
 610 # In case of Makefiles if the user does not setup CMAKE_BUILD_TYPE, assume it's Release:
 611 if(CMAKE_GENERATOR MATCHES "Makefiles|Ninja" AND "${CMAKE_BUILD_TYPE}" STREQUAL "")
 612   set(CMAKE_BUILD_TYPE Release)
 613 endif()
 614
 615 ocv_cmake_hook(POST_CMAKE_BUILD_OPTIONS)
 616
 617 # --- Python Support ---
 618 if(NOT IOS)
 619   include(cmake/OpenCVDetectPython.cmake)
 620 endif()
 621
 622 include(cmake/OpenCVCompilerOptions.cmake)
 623
 624 ocv_cmake_hook(POST_COMPILER_OPTIONS)
 625
 626 # ----------------------------------------------------------------------------
 627 #       CHECK FOR SYSTEM LIBRARIES, OPTIONS, ETC..
 628 # ----------------------------------------------------------------------------
 629 if(UNIX)
 630   if(NOT APPLE_FRAMEWORK OR OPENCV_ENABLE_PKG_CONFIG)
 631     if(CMAKE_CROSSCOMPILING AND NOT DEFINED ENV{PKG_CONFIG_LIBDIR} AND NOT DEFINED ENV{PKG_CONFIG_SYSROOT_DIR}
 632         AND NOT OPENCV_ENABLE_PKG_CONFIG
 633     )
 634       if(NOT PkgConfig_FOUND)
 635         message(STATUS "OpenCV disables pkg-config to avoid using of host libraries. Consider using PKG_CONFIG_LIBDIR to specify target SYSROOT")
 636       elseif(OPENCV_SKIP_PKG_CONFIG_WARNING)
 637         message(WARNING "pkg-config is enabled in cross-compilation mode without defining of PKG_CONFIG_LIBDIR environment variable. This may lead to misconfigured host-based dependencies.")
 638       endif()
 639     elseif(OPENCV_DISABLE_PKG_CONFIG)
 640       if(PkgConfig_FOUND)
 641         message(WARNING "OPENCV_DISABLE_PKG_CONFIG flag has no effect")
 642       endif()
 643     else()
 644       find_package(PkgConfig QUIET)
 645     endif()
 646   endif()
 647   include(CheckFunctionExists)
 648   include(CheckIncludeFile)
 649   include(CheckSymbolExists)
 650
 651   if(NOT APPLE)
 652     CHECK_INCLUDE_FILE(pthread.h HAVE_PTHREAD)
 653     if(ANDROID)
 654       set(OPENCV_LINKER_LIBS ${OPENCV_LINKER_LIBS} dl m log)
 655     elseif(CMAKE_SYSTEM_NAME MATCHES "FreeBSD|NetBSD|DragonFly|OpenBSD|Haiku")
 656       set(OPENCV_LINKER_LIBS ${OPENCV_LINKER_LIBS} m pthread)
 657     elseif(EMSCRIPTEN)
 658       # no need to link to system libs with emscripten
 659     elseif(QNXNTO)
 660       # no need to link to system libs with QNX
 661     else()
 662       set(OPENCV_LINKER_LIBS ${OPENCV_LINKER_LIBS} dl m pthread rt)
 663     endif()
 664   else()
 665     set(HAVE_PTHREAD 1)
 666   endif()
 667
 668   if(OPENCV_ENABLE_MEMALIGN)
 669     CHECK_SYMBOL_EXISTS(posix_memalign stdlib.h HAVE_POSIX_MEMALIGN)
 670     CHECK_INCLUDE_FILE(malloc.h HAVE_MALLOC_H)
 671     if(HAVE_MALLOC_H)
 672       CHECK_SYMBOL_EXISTS(memalign malloc.h HAVE_MEMALIGN)
 673     endif()
 674     # TODO:
 675     # - std::aligned_alloc() C++17 / C11
 676   endif()
 677 elseif(WIN32)
 678   include(CheckIncludeFile)
 679   include(CheckSymbolExists)
 680
 681   if(OPENCV_ENABLE_MEMALIGN)
 682     CHECK_INCLUDE_FILE(malloc.h HAVE_MALLOC_H)
 683     if(HAVE_MALLOC_H)
 684       CHECK_SYMBOL_EXISTS(_aligned_malloc malloc.h HAVE_WIN32_ALIGNED_MALLOC)
 685     endif()
 686   endif()
 687 endif()
 688
 689 include(cmake/OpenCVPCHSupport.cmake)
 690 include(cmake/OpenCVModule.cmake)
 691
 692 # ----------------------------------------------------------------------------
 693 #  Detect endianness of build platform
 694 # ----------------------------------------------------------------------------
 695
 696 if(IOS)
 697   # test_big_endian needs try_compile, which doesn't work for iOS
 698   # http://public.kitware.com/Bug/view.php?id=12288
 699   set(WORDS_BIGENDIAN 0)
 700 else()
 701   include(TestBigEndian)
 702   test_big_endian(WORDS_BIGENDIAN)
 703 endif()
 704
 705 # ----------------------------------------------------------------------------
 706 #  Detect 3rd-party libraries
 707 # ----------------------------------------------------------------------------
 708
 709 if(ANDROID AND WITH_CPUFEATURES)
 710   add_subdirectory(3rdparty/cpufeatures)
 711   set(HAVE_CPUFEATURES 1)
 712 endif()
 713
 714 include(cmake/OpenCVFindFrameworks.cmake)
 715
 716 include(cmake/OpenCVFindLibsGrfmt.cmake)
 717 include(cmake/OpenCVFindLibsGUI.cmake)
 718 include(cmake/OpenCVFindLibsVideo.cmake)
 719 include(cmake/OpenCVFindLibsPerf.cmake)
 720 include(cmake/OpenCVFindLAPACK.cmake)
 721 include(cmake/OpenCVFindProtobuf.cmake)
 722 if(WITH_TENGINE)
 723   include(cmake/OpenCVFindTengine.cmake)
 724 endif()
 725
 726 # ----------------------------------------------------------------------------
 727 #  Detect other 3rd-party libraries/tools
 728 # ----------------------------------------------------------------------------
 729
 730 # --- Java Support ---
 731 if(BUILD_JAVA)
 732   if(ANDROID)
 733     include(cmake/android/OpenCVDetectAndroidSDK.cmake)
 734   else()
 735     include(cmake/OpenCVDetectApacheAnt.cmake)
 736     find_package(JNI)
 737   endif()
 738 endif()
 739
 740 if(ENABLE_PYLINT AND PYTHON_DEFAULT_AVAILABLE)
 741   include(cmake/OpenCVPylint.cmake)
 742 endif()
 743 if(ENABLE_FLAKE8 AND PYTHON_DEFAULT_AVAILABLE)
 744   find_package(Flake8 QUIET)
 745   if(NOT FLAKE8_FOUND OR NOT FLAKE8_EXECUTABLE)
 746     include("${CMAKE_CURRENT_LIST_DIR}/cmake/FindFlake8.cmake")
 747   endif()
 748   if(FLAKE8_FOUND)
 749     list(APPEND OPENCV_FLAKE8_EXCLUDES ".git" "__pycache__" "config.py" "*.config.py" "config-*.py")
 750     list(APPEND OPENCV_FLAKE8_EXCLUDES "svgfig.py")  # 3rdparty
 751     if(NOT PYTHON3_VERSION_STRING VERSION_GREATER 3.6)
 752       # Python 3.6+ (PEP 526): variable annotations (type hints)
 753       list(APPEND OPENCV_FLAKE8_EXCLUDES "samples/dnn/dnn_model_runner/dnn_conversion/common/test/configs")
 754     endif()
 755     string(REPLACE ";" "," OPENCV_FLAKE8_EXCLUDES_STR "${OPENCV_FLAKE8_EXCLUDES}")
 756     add_custom_target(check_flake8
 757         COMMAND "${FLAKE8_EXECUTABLE}" . --count --select=E9,E901,E999,F821,F822,F823 --show-source --statistics --exclude='${OPENCV_FLAKE8_EXCLUDES_STR}'
 758         WORKING_DIRECTORY "${OpenCV_SOURCE_DIR}"
 759         COMMENT "Running flake8"
 760     )
 761   endif()
 762 endif()
 763
 764
 765 if(ANDROID AND ANDROID_EXECUTABLE AND ANT_EXECUTABLE AND (ANT_VERSION VERSION_GREATER 1.7) AND (ANDROID_TOOLS_Pkg_Revision GREATER 13))
 766   SET(CAN_BUILD_ANDROID_PROJECTS TRUE)
 767 else()
 768   SET(CAN_BUILD_ANDROID_PROJECTS FALSE)
 769 endif()
 770
 771 # --- OpenCL ---
 772 if(WITH_OPENCL)
 773   include(cmake/OpenCVDetectOpenCL.cmake)
 774 endif()
 775
 776 # --- Halide ---
 777 if(WITH_HALIDE)
 778   include(cmake/OpenCVDetectHalide.cmake)
 779 endif()
 780
 781 # --- VkCom ---
 782 if(WITH_VULKAN)
 783   include(cmake/OpenCVDetectVulkan.cmake)
 784 endif()
 785
 786 # --- Inference Engine ---
 787 if(WITH_INF_ENGINE)
 788   include(cmake/OpenCVDetectInferenceEngine.cmake)
 789 endif()
 790
 791 # --- DirectX ---
 792 if(WITH_DIRECTX)
 793   include(cmake/OpenCVDetectDirectX.cmake)
 794 endif()
 795
 796 if(WITH_VTK)
 797   include(cmake/OpenCVDetectVTK.cmake)
 798 endif()
 799
 800 if(WITH_OPENVX)
 801   include(cmake/FindOpenVX.cmake)
 802 endif()
 803
 804 if(WITH_QUIRC)
 805   add_subdirectory(3rdparty/quirc)
 806   set(HAVE_QUIRC TRUE)
 807 endif()
 808
 809 if(WITH_ONNX)
 810   include(cmake/FindONNX.cmake)
 811 endif()
 812
 813 # ----------------------------------------------------------------------------
 814 # OpenCV HAL
 815 # ----------------------------------------------------------------------------
 816 set(_hal_includes "")
 817 macro(ocv_hal_register HAL_LIBRARIES_VAR HAL_HEADERS_VAR HAL_INCLUDE_DIRS_VAR)
 818   # 1. libraries
 819   foreach (l ${${HAL_LIBRARIES_VAR}})
 820     if(NOT TARGET ${l})
 821       get_filename_component(l "${l}" ABSOLUTE)
 822     endif()
 823     list(APPEND OPENCV_HAL_LINKER_LIBS ${l})
 824   endforeach()
 825   # 2. headers
 826   foreach (h ${${HAL_HEADERS_VAR}})
 827     set(_hal_includes "${_hal_includes}\n#include \"${h}\"")
 828   endforeach()
 829   # 3. include paths
 830   ocv_include_directories(${${HAL_INCLUDE_DIRS_VAR}})
 831 endmacro()
 832
 833 if(NOT DEFINED OpenCV_HAL)
 834   set(OpenCV_HAL "OpenCV_HAL")
 835 endif()
 836
 837 if(HAVE_OPENVX)
 838   if(NOT ";${OpenCV_HAL};" MATCHES ";openvx;")
 839     set(OpenCV_HAL "openvx;${OpenCV_HAL}")
 840   endif()
 841 endif()
 842
 843 if(WITH_CAROTENE)
 844   ocv_debug_message(STATUS "Enable carotene acceleration")
 845   if(NOT ";${OpenCV_HAL};" MATCHES ";carotene;")
 846     set(OpenCV_HAL "carotene;${OpenCV_HAL}")
 847   endif()
 848 endif()
 849
 850 foreach(hal ${OpenCV_HAL})
 851   if(hal STREQUAL "carotene")
 852     if(";${CPU_BASELINE_FINAL};" MATCHES ";NEON;")
 853       add_subdirectory(3rdparty/carotene/hal)
 854       ocv_hal_register(CAROTENE_HAL_LIBRARIES CAROTENE_HAL_HEADERS CAROTENE_HAL_INCLUDE_DIRS)
 855       list(APPEND OpenCV_USED_HAL "carotene (ver ${CAROTENE_HAL_VERSION})")
 856     else()
 857       message(STATUS "Carotene: NEON is not available, disabling carotene...")
 858     endif()
 859   elseif(hal STREQUAL "openvx")
 860     add_subdirectory(3rdparty/openvx)
 861     ocv_hal_register(OPENVX_HAL_LIBRARIES OPENVX_HAL_HEADERS OPENVX_HAL_INCLUDE_DIRS)
 862     list(APPEND OpenCV_USED_HAL "openvx (ver ${OPENVX_HAL_VERSION})")
 863   else()
 864     ocv_debug_message(STATUS "OpenCV HAL: ${hal} ...")
 865     ocv_clear_vars(OpenCV_HAL_LIBRARIES OpenCV_HAL_HEADERS OpenCV_HAL_INCLUDE_DIRS)
 866     find_package(${hal} NO_MODULE QUIET)
 867     if(${hal}_FOUND)
 868       ocv_hal_register(OpenCV_HAL_LIBRARIES OpenCV_HAL_HEADERS OpenCV_HAL_INCLUDE_DIRS)
 869       list(APPEND OpenCV_USED_HAL "${hal} (ver ${${hal}_VERSION})")
 870     endif()
 871   endif()
 872 endforeach()
 873 configure_file("${OpenCV_SOURCE_DIR}/cmake/templates/custom_hal.hpp.in" "${CMAKE_BINARY_DIR}/custom_hal.hpp" @ONLY)
 874 unset(_hal_includes)
 875
 876
 877 # ----------------------------------------------------------------------------
 878 # Code trace support
 879 # ----------------------------------------------------------------------------
 880 if(CV_TRACE)
 881   include(cmake/OpenCVDetectTrace.cmake)
 882 endif()
 883
 884 ocv_cmake_hook(POST_DETECT_DEPENDECIES)  # typo, deprecated (2019-06)
 885 ocv_cmake_hook(POST_DETECT_DEPENDENCIES)
 886
 887 # ----------------------------------------------------------------------------
 888 # Solution folders:
 889 # ----------------------------------------------------------------------------
 890 if(ENABLE_SOLUTION_FOLDERS)
 891   set_property(GLOBAL PROPERTY USE_FOLDERS ON)
 892   set_property(GLOBAL PROPERTY PREDEFINED_TARGETS_FOLDER "CMakeTargets")
 893 endif()
 894
 895 # Extra OpenCV targets: uninstall, package_source, perf, etc.
 896 include(cmake/OpenCVExtraTargets.cmake)
 897
 898 # ----------------------------------------------------------------------------
 899 # Process subdirectories
 900 # ----------------------------------------------------------------------------
 901
 902 # opencv.hpp and legacy headers
 903 add_subdirectory(include)
 904
 905 # Enable compiler options for OpenCV modules/apps/samples only (ignore 3rdparty)
 906 ocv_add_modules_compiler_options()
 907
 908 # OpenCV modules
 909 add_subdirectory(modules)
 910
 911 # Generate targets for documentation
 912 add_subdirectory(doc)
 913
 914 # various data that is used by cv libraries and/or demo applications.
 915 add_subdirectory(data)
 916
 917 # extra applications
 918 if(BUILD_opencv_apps)
 919   add_subdirectory(apps)
 920 endif()
 921
 922 # examples
 923 if(BUILD_EXAMPLES OR BUILD_ANDROID_EXAMPLES OR INSTALL_ANDROID_EXAMPLES OR INSTALL_PYTHON_EXAMPLES OR INSTALL_C_EXAMPLES)
 924   add_subdirectory(samples)
 925 endif()
 926
 927 if(ANDROID)
 928   add_subdirectory(platforms/android/service)
 929 endif()
 930
 931 # ----------------------------------------------------------------------------
 932 # Finalization: generate configuration-based files
 933 # ----------------------------------------------------------------------------
 934
 935 ocv_cmake_hook(PRE_FINALIZE)
 936
 937 # Generate platform-dependent and configuration-dependent headers
 938 include(cmake/OpenCVGenHeaders.cmake)
 939
 940 # Generate opencv.pc for pkg-config command
 941 if(OPENCV_GENERATE_PKGCONFIG)
 942   include(cmake/OpenCVGenPkgconfig.cmake)
 943 endif()
 944
 945 # Generate OpenCV.mk for ndk-build (Android build tool)
 946 include(cmake/OpenCVGenAndroidMK.cmake)
 947
 948 # Generate OpenCVConfig.cmake and OpenCVConfig-version.cmake for cmake projects
 949 include(cmake/OpenCVGenConfig.cmake)
 950
 951 # Generate Info.plist for the IOS framework
 952 if(APPLE_FRAMEWORK)
 953   include(cmake/OpenCVGenInfoPlist.cmake)
 954 endif()
 955
 956 # Generate ABI descriptor
 957 include(cmake/OpenCVGenABI.cmake)
 958
 959 # Generate environment setup file
 960 if(INSTALL_TESTS AND OPENCV_TEST_DATA_PATH)
 961   if(ANDROID)
 962     get_filename_component(TEST_PATH ${OPENCV_TEST_INSTALL_PATH} DIRECTORY)
 963     configure_file("${CMAKE_CURRENT_SOURCE_DIR}/cmake/templates/opencv_run_all_tests_android.sh.in"
 964                    "${CMAKE_BINARY_DIR}/unix-install/opencv_run_all_tests.sh" @ONLY)
 965     install(PROGRAMS "${CMAKE_BINARY_DIR}/unix-install/opencv_run_all_tests.sh"
 966             DESTINATION ./ COMPONENT tests)
 967   elseif(WIN32)
 968     configure_file("${CMAKE_CURRENT_SOURCE_DIR}/cmake/templates/opencv_run_all_tests_windows.cmd.in"
 969                    "${CMAKE_BINARY_DIR}/win-install/opencv_run_all_tests.cmd" @ONLY)
 970     install(PROGRAMS "${CMAKE_BINARY_DIR}/win-install/opencv_run_all_tests.cmd"
 971             DESTINATION ${OPENCV_TEST_INSTALL_PATH} COMPONENT tests)
 972   elseif(UNIX)
 973     configure_file("${CMAKE_CURRENT_SOURCE_DIR}/cmake/templates/opencv_run_all_tests_unix.sh.in"
 974                    "${CMAKE_BINARY_DIR}/unix-install/opencv_run_all_tests.sh" @ONLY)
 975     install(PROGRAMS "${CMAKE_BINARY_DIR}/unix-install/opencv_run_all_tests.sh"
 976             DESTINATION ${OPENCV_TEST_INSTALL_PATH} COMPONENT tests)
 977   endif()
 978 endif()
 979
 980 if(NOT OPENCV_README_FILE)
 981   if(ANDROID)
 982     set(OPENCV_README_FILE ${CMAKE_CURRENT_SOURCE_DIR}/platforms/android/README.android)
 983   endif()
 984 endif()
 985
 986 if(NOT OPENCV_LICENSE_FILE)
 987   set(OPENCV_LICENSE_FILE ${CMAKE_CURRENT_SOURCE_DIR}/LICENSE)
 988 endif()
 989
 990 # for UNIX it does not make sense as LICENSE and readme will be part of the package automatically
 991 if(ANDROID OR NOT UNIX)
 992   install(FILES ${OPENCV_LICENSE_FILE}
 993         PERMISSIONS OWNER_READ OWNER_WRITE GROUP_READ WORLD_READ
 994         DESTINATION ./ COMPONENT libs)
 995   if(OPENCV_README_FILE)
 996     install(FILES ${OPENCV_README_FILE}
 997             PERMISSIONS OWNER_READ OWNER_WRITE GROUP_READ WORLD_READ
 998             DESTINATION ./ COMPONENT libs)
 999   endif()
1000 endif()
1001
1002 if(COMMAND ocv_pylint_finalize)
1003   ocv_pylint_add_directory(${CMAKE_CURRENT_LIST_DIR}/modules/python/test)
1004   ocv_pylint_add_directory(${CMAKE_CURRENT_LIST_DIR}/samples/python)
1005   ocv_pylint_add_directory(${CMAKE_CURRENT_LIST_DIR}/samples/dnn)
1006   ocv_pylint_add_directory_recurse(${CMAKE_CURRENT_LIST_DIR}/samples/python/tutorial_code)
1007   ocv_pylint_finalize()
1008 endif()
1009 if(TARGET check_pylint)
1010   message(STATUS "Registered 'check_pylint' target: using ${PYLINT_EXECUTABLE} (ver: ${PYLINT_VERSION}), checks: ${PYLINT_TOTAL_TARGETS}")
1011 endif()
1012 if(TARGET check_flake8)
1013   message(STATUS "Registered 'check_flake8' target: using ${FLAKE8_EXECUTABLE} (ver: ${FLAKE8_VERSION})")
1014 endif()
1015
1016 if(OPENCV_GENERATE_SETUPVARS)
1017   include(cmake/OpenCVGenSetupVars.cmake)
1018 endif()
1019
1020 # ----------------------------------------------------------------------------
1021 # Summary:
1022 # ----------------------------------------------------------------------------
1023 status("")
1024 status("General configuration for OpenCV ${OPENCV_VERSION} =====================================")
1025 if(OPENCV_VCSVERSION)
1026   status("  Version control:" ${OPENCV_VCSVERSION})
1027 endif()
1028 if(OPENCV_EXTRA_MODULES_PATH AND NOT BUILD_INFO_SKIP_EXTRA_MODULES)
1029   set(__dump_extra_header OFF)
1030   foreach(p ${OPENCV_EXTRA_MODULES_PATH})
1031     if(EXISTS ${p})
1032       if(NOT __dump_extra_header)
1033         set(__dump_extra_header ON)
1034         status("")
1035         status("  Extra modules:")
1036       else()
1037         status("")
1038       endif()
1039       ocv_git_describe(EXTRA_MODULES_VCSVERSION "${p}")
1040       status("    Location (extra):" ${p})
1041       status("    Version control (extra):" ${EXTRA_MODULES_VCSVERSION})
1042     endif()
1043   endforeach()
1044   unset(__dump_extra_header)
1045 endif()
1046
1047 # ========================== build platform ==========================
1048 status("")
1049 status("  Platform:")
1050 if(NOT DEFINED OPENCV_TIMESTAMP
1051     AND NOT BUILD_INFO_SKIP_TIMESTAMP
1052 )
1053   string(TIMESTAMP OPENCV_TIMESTAMP "" UTC)
1054   set(OPENCV_TIMESTAMP "${OPENCV_TIMESTAMP}" CACHE STRING "Timestamp of OpenCV build configuration" FORCE)
1055 endif()
1056 if(OPENCV_TIMESTAMP)
1057   status("    Timestamp:"      ${OPENCV_TIMESTAMP})
1058 endif()
1059 status("    Host:"             ${CMAKE_HOST_SYSTEM_NAME} ${CMAKE_HOST_SYSTEM_VERSION} ${CMAKE_HOST_SYSTEM_PROCESSOR})
1060 if(CMAKE_CROSSCOMPILING)
1061   status("    Target:"         ${CMAKE_SYSTEM_NAME} ${CMAKE_SYSTEM_VERSION} ${CMAKE_SYSTEM_PROCESSOR})
1062 endif()
1063 status("    CMake:"            ${CMAKE_VERSION})
1064 status("    CMake generator:"  ${CMAKE_GENERATOR})
1065 status("    CMake build tool:" ${CMAKE_BUILD_TOOL})
1066 if(MSVC)
1067   status("    MSVC:"           ${MSVC_VERSION})
1068 endif()
1069 if(CMAKE_GENERATOR MATCHES Xcode)
1070   status("    Xcode:"          ${XCODE_VERSION})
1071 endif()
1072 if(CMAKE_GENERATOR MATCHES "Xcode|Visual Studio|Multi-Config")
1073   status("    Configuration:"  ${CMAKE_CONFIGURATION_TYPES})
1074 else()
1075   status("    Configuration:"  ${CMAKE_BUILD_TYPE})
1076 endif()
1077
1078
1079 # ========================= CPU code generation mode =========================
1080 status("")
1081 status("  CPU/HW features:")
1082 status("    Baseline:"  "${CPU_BASELINE_FINAL}")
1083 if(NOT CPU_BASELINE STREQUAL CPU_BASELINE_FINAL)
1084   status("      requested:"  "${CPU_BASELINE}")
1085 endif()
1086 if(CPU_BASELINE_REQUIRE)
1087   status("      required:"  "${CPU_BASELINE_REQUIRE}")
1088 endif()
1089 if(CPU_BASELINE_DISABLE)
1090   status("      disabled:"  "${CPU_BASELINE_DISABLE}")
1091 endif()
1092 if(CPU_DISPATCH_FINAL OR CPU_DISPATCH)
1093   status("    Dispatched code generation:"  "${CPU_DISPATCH_FINAL}")
1094   if(NOT CPU_DISPATCH STREQUAL CPU_DISPATCH_FINAL)
1095     status("      requested:"  "${CPU_DISPATCH}")
1096   endif()
1097   if(CPU_DISPATCH_REQUIRE)
1098     status("      required:"  "${CPU_DISPATCH_REQUIRE}")
1099   endif()
1100   foreach(OPT ${CPU_DISPATCH_FINAL})
1101     status("      ${OPT} (${CPU_${OPT}_USAGE_COUNT} files):"  "+ ${CPU_DISPATCH_${OPT}_INCLUDED}")
1102   endforeach()
1103 endif()
1104
1105 # ========================== C/C++ options ==========================
1106 if(CMAKE_CXX_COMPILER_VERSION)
1107   set(OPENCV_COMPILER_STR "${CMAKE_CXX_COMPILER} ${CMAKE_CXX_COMPILER_ARG1} (ver ${CMAKE_CXX_COMPILER_VERSION})")
1108 else()
1109   set(OPENCV_COMPILER_STR "${CMAKE_CXX_COMPILER} ${CMAKE_CXX_COMPILER_ARG1}")
1110 endif()
1111 string(STRIP "${OPENCV_COMPILER_STR}" OPENCV_COMPILER_STR)
1112
1113 status("")
1114 status("  C/C++:")
1115 status("    Built as dynamic libs?:" BUILD_SHARED_LIBS THEN YES ELSE NO)
1116 if(DEFINED CMAKE_CXX_STANDARD AND CMAKE_CXX_STANDARD)
1117   status("    C++ standard:"           "${CMAKE_CXX_STANDARD}")
1118 endif()
1119 status("    C++ Compiler:"           ${OPENCV_COMPILER_STR})
1120 status("    C++ flags (Release):"    ${CMAKE_CXX_FLAGS} ${CMAKE_CXX_FLAGS_RELEASE})
1121 status("    C++ flags (Debug):"      ${CMAKE_CXX_FLAGS} ${CMAKE_CXX_FLAGS_DEBUG})
1122 status("    C Compiler:"             ${CMAKE_C_COMPILER} ${CMAKE_C_COMPILER_ARG1})
1123 status("    C flags (Release):"      ${CMAKE_C_FLAGS} ${CMAKE_C_FLAGS_RELEASE})
1124 status("    C flags (Debug):"        ${CMAKE_C_FLAGS} ${CMAKE_C_FLAGS_DEBUG})
1125 if(WIN32)
1126   status("    Linker flags (Release):" ${CMAKE_EXE_LINKER_FLAGS} ${CMAKE_EXE_LINKER_FLAGS_RELEASE})
1127   status("    Linker flags (Debug):"   ${CMAKE_EXE_LINKER_FLAGS} ${CMAKE_EXE_LINKER_FLAGS_DEBUG})
1128 else()
1129   status("    Linker flags (Release):" ${CMAKE_SHARED_LINKER_FLAGS} ${CMAKE_SHARED_LINKER_FLAGS_RELEASE})
1130   status("    Linker flags (Debug):"   ${CMAKE_SHARED_LINKER_FLAGS} ${CMAKE_SHARED_LINKER_FLAGS_DEBUG})
1131 endif()
1132 status("    ccache:"                  OPENCV_COMPILER_IS_CCACHE THEN YES ELSE NO)
1133 status("    Precompiled headers:"     PCHSupport_FOUND AND ENABLE_PRECOMPILED_HEADERS THEN YES ELSE NO)
1134
1135 if(OPENCV_DISABLE_FILESYSTEM_SUPPORT)
1136   status("    Filesystem support is disabled")
1137 endif()
1138
1139 # ========================== Dependencies ============================
1140 ocv_get_all_libs(deps_modules deps_extra deps_3rdparty)
1141 status("    Extra dependencies:" ${deps_extra})
1142 status("    3rdparty dependencies:" ${deps_3rdparty})
1143
1144 # ========================== OpenCV modules ==========================
1145 status("")
1146 status("  OpenCV modules:")
1147 set(OPENCV_MODULES_BUILD_ST "")
1148 foreach(the_module ${OPENCV_MODULES_BUILD})
1149   if(NOT OPENCV_MODULE_${the_module}_CLASS STREQUAL "INTERNAL" OR the_module STREQUAL "opencv_ts")
1150     list(APPEND OPENCV_MODULES_BUILD_ST "${the_module}")
1151   endif()
1152 endforeach()
1153 string(REPLACE "opencv_" "" OPENCV_MODULES_BUILD_ST          "${OPENCV_MODULES_BUILD_ST}")
1154 string(REPLACE "opencv_" "" OPENCV_MODULES_DISABLED_USER_ST  "${OPENCV_MODULES_DISABLED_USER}")
1155 string(REPLACE "opencv_" "" OPENCV_MODULES_DISABLED_AUTO_ST  "${OPENCV_MODULES_DISABLED_AUTO}")
1156 string(REPLACE "opencv_" "" OPENCV_MODULES_DISABLED_FORCE_ST "${OPENCV_MODULES_DISABLED_FORCE}")
1157 list(SORT OPENCV_MODULES_BUILD_ST)
1158 list(SORT OPENCV_MODULES_DISABLED_USER_ST)
1159 list(SORT OPENCV_MODULES_DISABLED_AUTO_ST)
1160 list(SORT OPENCV_MODULES_DISABLED_FORCE_ST)
1161 status("    To be built:"            OPENCV_MODULES_BUILD          THEN ${OPENCV_MODULES_BUILD_ST}          ELSE "-")
1162 status("    Disabled:"               OPENCV_MODULES_DISABLED_USER  THEN ${OPENCV_MODULES_DISABLED_USER_ST}  ELSE "-")
1163 status("    Disabled by dependency:" OPENCV_MODULES_DISABLED_AUTO  THEN ${OPENCV_MODULES_DISABLED_AUTO_ST}  ELSE "-")
1164 status("    Unavailable:"            OPENCV_MODULES_DISABLED_FORCE THEN ${OPENCV_MODULES_DISABLED_FORCE_ST} ELSE "-")
1165
1166 ocv_build_features_string(apps_status
1167   IF BUILD_TESTS AND HAVE_opencv_ts THEN "tests"
1168   IF BUILD_PERF_TESTS AND HAVE_opencv_ts THEN "perf_tests"
1169   IF BUILD_EXAMPLES THEN "examples"
1170   IF BUILD_opencv_apps THEN "apps"
1171   IF BUILD_ANDROID_SERVICE THEN "android_service"
1172   IF (BUILD_ANDROID_EXAMPLES OR INSTALL_ANDROID_EXAMPLES) AND CAN_BUILD_ANDROID_PROJECTS THEN "android_examples"
1173   ELSE "-")
1174 status("    Applications:" "${apps_status}")
1175 ocv_build_features_string(docs_status
1176     IF TARGET doxygen_cpp THEN "doxygen"
1177     IF TARGET doxygen_python THEN "python"
1178     IF TARGET doxygen_javadoc THEN "javadoc"
1179     IF BUILD_opencv_js OR DEFINED OPENCV_JS_LOCATION THEN "js"
1180     ELSE "NO"
1181 )
1182 status("    Documentation:" "${docs_status}")
1183 status("    Non-free algorithms:" OPENCV_ENABLE_NONFREE THEN "YES" ELSE "NO")
1184
1185 # ========================== Android details ==========================
1186 if(ANDROID)
1187   status("")
1188   if(DEFINED ANDROID_NDK_REVISION)
1189     set(__msg "${ANDROID_NDK} (ver ${ANDROID_NDK_REVISION})")
1190   else()
1191     set(__msg "location: ${ANDROID_NDK}")
1192   endif()
1193   status("  Android NDK: " ${__msg})
1194   status("    Android ABI:" ${ANDROID_ABI})
1195   if(BUILD_WITH_STANDALONE_TOOLCHAIN)
1196     status("    NDK toolchain:" "standalone: ${ANDROID_STANDALONE_TOOLCHAIN}")
1197   elseif(BUILD_WITH_ANDROID_NDK OR DEFINED ANDROID_TOOLCHAIN_NAME)
1198     status("    NDK toolchain:" "${ANDROID_TOOLCHAIN_NAME}")
1199   endif()
1200   status("    STL type:" ${ANDROID_STL})
1201   status("    Native API level:" ${ANDROID_NATIVE_API_LEVEL})
1202
1203   if(BUILD_ANDROID_PROJECTS)
1204     status("  Android SDK: " "${ANDROID_SDK} (tools: ${ANDROID_SDK_TOOLS_VERSION} build tools: ${ANDROID_SDK_BUILD_TOOLS_VERSION})")
1205     if(ANDROID_EXECUTABLE)
1206       status("    android tool:"  "${ANDROID_EXECUTABLE}")
1207     endif()
1208   else()
1209     status("  Android SDK: " "not used, projects are not built")
1210   endif()
1211   if(DEFINED ANDROID_SDK_COMPATIBLE_TARGET)
1212     status("    SDK target:" "${ANDROID_SDK_COMPATIBLE_TARGET}")
1213   endif()
1214   if(DEFINED ANDROID_PROJECTS_BUILD_TYPE)
1215     if(ANDROID_PROJECTS_BUILD_TYPE STREQUAL "ANT")
1216       status("    Projects build scripts:" "Ant/Eclipse compatible")
1217     elseif(ANDROID_PROJECTS_BUILD_TYPE STREQUAL "ANT")
1218       status("    Projects build scripts:" "Gradle")
1219     endif()
1220   endif()
1221 endif()
1222
1223 # ================== Windows RT features ==================
1224 if(WIN32)
1225 status("")
1226 status("  Windows RT support:" WINRT THEN YES ELSE NO)
1227   if(WINRT)
1228     status("    Building for Microsoft platform: " ${CMAKE_SYSTEM_NAME})
1229     status("    Building for architectures: " ${CMAKE_VS_EFFECTIVE_PLATFORMS})
1230     status("    Building for version: " ${CMAKE_SYSTEM_VERSION})
1231     if (DEFINED ENABLE_WINRT_MODE_NATIVE)
1232       status("    Building for C++ without CX extensions")
1233     endif()
1234   endif()
1235 endif(WIN32)
1236
1237 # ========================== GUI ==========================
1238 status("")
1239 status("  GUI: ")
1240
1241 if(WITH_QT OR HAVE_QT)
1242   if(HAVE_QT5)
1243     status("    QT:" "YES (ver ${Qt5Core_VERSION_STRING})")
1244     status("      QT OpenGL support:" HAVE_QT_OPENGL THEN "YES (${Qt5OpenGL_LIBRARIES} ${Qt5OpenGL_VERSION_STRING})" ELSE NO)
1245   elseif(HAVE_QT)
1246     status("    QT:" "YES (ver ${QT_VERSION_MAJOR}.${QT_VERSION_MINOR}.${QT_VERSION_PATCH} ${QT_EDITION})")
1247     status("      QT OpenGL support:" HAVE_QT_OPENGL THEN "YES (${QT_QTOPENGL_LIBRARY})" ELSE NO)
1248   else()
1249     status("    QT:" "NO")
1250   endif()
1251 endif()
1252
1253 if(WITH_WIN32UI)
1254   status("    Win32 UI:" HAVE_WIN32UI THEN YES ELSE NO)
1255 endif()
1256
1257 if(HAVE_COCOA)  # APPLE
1258   status("    Cocoa:"  YES)
1259 endif()
1260
1261 if(WITH_GTK OR HAVE_GTK)
1262   if(HAVE_GTK3)
1263     status("    GTK+:" "YES (ver ${GTK3_VERSION})")
1264   elseif(HAVE_GTK)
1265     status("    GTK+:" "YES (ver ${GTK2_VERSION})")
1266   else()
1267     status("    GTK+:" "NO")
1268   endif()
1269   if(HAVE_GTK)
1270     status(  "      GThread :" HAVE_GTHREAD THEN "YES (ver ${GTHREAD_VERSION})" ELSE NO)
1271     status(  "      GtkGlExt:" HAVE_GTKGLEXT THEN "YES (ver ${GTKGLEXT_VERSION})" ELSE NO)
1272   endif()
1273 endif()
1274
1275 if(WITH_OPENGL OR HAVE_OPENGL)
1276   status("    OpenGL support:" HAVE_OPENGL THEN "YES (${OPENGL_LIBRARIES})" ELSE NO)
1277 endif()
1278
1279 if(WITH_VTK OR HAVE_VTK)
1280   status("    VTK support:" HAVE_VTK THEN "YES (ver ${VTK_VERSION})" ELSE NO)
1281 endif()
1282
1283 # ========================== MEDIA IO ==========================
1284 status("")
1285 status("  Media I/O: ")
1286 status("    ZLib:"   ZLIB_FOUND THEN "${ZLIB_LIBRARIES} (ver ${ZLIB_VERSION_STRING})" ELSE "build (ver ${ZLIB_VERSION_STRING})")
1287
1288 if(WITH_JPEG OR HAVE_JPEG)
1289   if(NOT HAVE_JPEG)
1290     status("    JPEG:" NO)
1291   elseif(BUILD_JPEG)
1292     status("    JPEG:" "build-${JPEG_LIBRARY} (ver ${JPEG_LIB_VERSION})")
1293   else()
1294     status("    JPEG:" "${JPEG_LIBRARY} (ver ${JPEG_LIB_VERSION})")
1295   endif()
1296 endif()
1297
1298 if(WITH_WEBP OR HAVE_WEBP)
1299   status("    WEBP:" WEBP_FOUND THEN "${WEBP_LIBRARY} (ver ${WEBP_VERSION})" ELSE "build (ver ${WEBP_VERSION})")
1300 endif()
1301
1302 if(WITH_PNG OR HAVE_PNG)
1303   status("    PNG:"  PNG_FOUND  THEN "${PNG_LIBRARY} (ver ${PNG_VERSION})" ELSE "build (ver ${PNG_VERSION})")
1304 endif()
1305
1306 if(WITH_TIFF OR HAVE_TIFF)
1307   status("    TIFF:" TIFF_FOUND THEN "${TIFF_LIBRARY} (ver ${TIFF_VERSION} / ${TIFF_VERSION_STRING})" ELSE "build (ver ${TIFF_VERSION} - ${TIFF_VERSION_STRING})")
1308 endif()
1309
1310 if(HAVE_OPENJPEG)
1311   status("    JPEG 2000:" OpenJPEG_FOUND
1312       THEN "OpenJPEG (ver ${OPENJPEG_MAJOR_VERSION}.${OPENJPEG_MINOR_VERSION}.${OPENJPEG_BUILD_VERSION})"
1313       ELSE "build (ver ${OPENJPEG_VERSION})"
1314   )
1315 elseif(HAVE_JASPER)
1316   status("    JPEG 2000:" JASPER_FOUND THEN "${JASPER_LIBRARY} (ver ${JASPER_VERSION_STRING})" ELSE "build Jasper (ver ${JASPER_VERSION_STRING})")
1317 elseif(WITH_OPENJPEG OR WITH_JASPER)
1318   status("    JPEG 2000:" "NO")
1319 endif()
1320
1321 if(WITH_OPENEXR OR HAVE_OPENEXR)
1322   if(HAVE_OPENEXR)
1323     status("    OpenEXR:" OPENEXR_FOUND THEN "${OPENEXR_LIBRARIES} (ver ${OPENEXR_VERSION})" ELSE "build (ver ${OPENEXR_VERSION})")
1324   else()
1325     status("    OpenEXR:" "NO")
1326   endif()
1327 endif()
1328
1329 if(WITH_GDAL OR HAVE_GDAL)
1330   status("    GDAL:" HAVE_GDAL THEN "YES (${GDAL_LIBRARY})" ELSE "NO")
1331 endif()
1332
1333 if(WITH_GDCM OR HAVE_GDCM)
1334   status("    GDCM:" HAVE_GDCM THEN "YES (${GDCM_VERSION})" ELSE "NO")
1335 endif()
1336
1337 if(WITH_IMGCODEC_HDR OR DEFINED HAVE_IMGCODEC_HDR)
1338   status("    HDR:" HAVE_IMGCODEC_HDR THEN "YES" ELSE "NO")
1339 endif()
1340
1341 if(WITH_IMGCODEC_SUNRASTER OR DEFINED HAVE_IMGCODEC_SUNRASTER)
1342   status("    SUNRASTER:" HAVE_IMGCODEC_SUNRASTER THEN "YES" ELSE "NO")
1343 endif()
1344
1345 if(WITH_IMGCODEC_PXM OR DEFINED HAVE_IMGCODEC_PXM)
1346   status("    PXM:" HAVE_IMGCODEC_PXM THEN "YES" ELSE "NO")
1347 endif()
1348
1349 if(WITH_IMGCODEC_PFM OR DEFINED HAVE_IMGCODEC_PFM)
1350   status("    PFM:" HAVE_IMGCODEC_PFM THEN "YES" ELSE "NO")
1351 endif()
1352
1353 # ========================== VIDEO IO ==========================
1354 status("")
1355 status("  Video I/O:")
1356
1357 if(WITH_1394 OR HAVE_DC1394_2)
1358   status("    DC1394:" HAVE_DC1394_2 THEN "YES (${DC1394_2_VERSION})" ELSE NO)
1359 endif()
1360
1361 if(WITH_FFMPEG OR HAVE_FFMPEG)
1362   if(OPENCV_FFMPEG_USE_FIND_PACKAGE)
1363     status("    FFMPEG:"       HAVE_FFMPEG         THEN "YES (find_package)"                       ELSE "NO (find_package)")
1364   elseif(WIN32)
1365     status("    FFMPEG:"       HAVE_FFMPEG         THEN "YES (prebuilt binaries)"                  ELSE NO)
1366   else()
1367     status("    FFMPEG:"       HAVE_FFMPEG         THEN YES ELSE NO)
1368   endif()
1369   status("      avcodec:"      FFMPEG_libavcodec_VERSION    THEN "YES (${FFMPEG_libavcodec_VERSION})"    ELSE NO)
1370   status("      avformat:"     FFMPEG_libavformat_VERSION   THEN "YES (${FFMPEG_libavformat_VERSION})"   ELSE NO)
1371   status("      avutil:"       FFMPEG_libavutil_VERSION     THEN "YES (${FFMPEG_libavutil_VERSION})"     ELSE NO)
1372   status("      swscale:"      FFMPEG_libswscale_VERSION    THEN "YES (${FFMPEG_libswscale_VERSION})"    ELSE NO)
1373   status("      avresample:"   FFMPEG_libavresample_VERSION THEN "YES (${FFMPEG_libavresample_VERSION})" ELSE NO)
1374 endif()
1375
1376 if(WITH_GSTREAMER OR HAVE_GSTREAMER)
1377   status("    GStreamer:" HAVE_GSTREAMER THEN "YES (${GSTREAMER_VERSION})" ELSE NO)
1378 endif()
1379
1380 if(WITH_OPENNI2 OR HAVE_OPENNI2)
1381   status("    OpenNI2:"        HAVE_OPENNI2    THEN "YES (${OPENNI2_VERSION})" ELSE NO)
1382 endif()
1383
1384 if(WITH_PVAPI OR HAVE_PVAPI)
1385   status("    PvAPI:" HAVE_PVAPI THEN YES ELSE NO)
1386 endif()
1387
1388 if(WITH_ARAVIS OR HAVE_ARAVIS_API)
1389   status("    Aravis SDK:" HAVE_ARAVIS_API THEN "YES (${ARAVIS_VERSION})" ELSE NO)
1390 endif()
1391
1392 if(WITH_AVFOUNDATION OR HAVE_AVFOUNDATION)
1393   status("    AVFoundation:" HAVE_AVFOUNDATION THEN YES ELSE NO)
1394 endif()
1395
1396 if(HAVE_CAP_IOS)
1397   status("    iOS capture:" YES)
1398 endif()
1399
1400 if(WITH_V4L OR HAVE_V4L)
1401   ocv_build_features_string(v4l_status
1402     IF HAVE_CAMV4L2 THEN "linux/videodev2.h"
1403     IF HAVE_VIDEOIO THEN "sys/videoio.h"
1404     ELSE "NO")
1405   status("    v4l/v4l2:" HAVE_V4L THEN "YES (${v4l_status})" ELSE NO)
1406 endif()
1407
1408 if(WITH_DSHOW OR HAVE_DSHOW)
1409   status("    DirectShow:" HAVE_DSHOW THEN YES ELSE NO)
1410 endif()
1411
1412 if(WITH_MSMF OR HAVE_MSMF)
1413   status("    Media Foundation:" HAVE_MSMF THEN YES ELSE NO)
1414   status("      DXVA:" HAVE_MSMF_DXVA THEN YES ELSE NO)
1415 endif()
1416
1417 if(WITH_XIMEA OR HAVE_XIMEA)
1418   status("    XIMEA:" HAVE_XIMEA THEN YES ELSE NO)
1419 endif()
1420
1421 if(WITH_UEYE OR HAVE_UEYE)
1422   status("    uEye:" HAVE_UEYE THEN YES ELSE NO)
1423 endif()
1424
1425 if(WITH_XINE OR HAVE_XINE)
1426   status("    Xine:"           HAVE_XINE           THEN "YES (ver ${XINE_VERSION})"     ELSE NO)
1427 endif()
1428
1429 if(WITH_LIBREALSENSE OR HAVE_LIBREALSENSE)
1430   status("    Intel RealSense:" HAVE_LIBREALSENSE THEN "YES (${LIBREALSENSE_VERSION})" ELSE NO)
1431 endif()
1432
1433 if(WITH_MFX OR HAVE_MFX)
1434   if(HAVE_MFX)
1435     if(MFX_LIBRARY)
1436       set(__details " (${MFX_LIBRARY})")
1437     elseif(MFX_LIBRARIES)
1438       set(__details " (${MFX_LIBRARIES})")
1439     else()
1440       set(__details " (unknown)")
1441     endif()
1442   endif()
1443   status("    Intel Media SDK:" HAVE_MFX      THEN "YES${__details}" ELSE NO)
1444 endif()
1445
1446 if(WITH_GPHOTO2 OR HAVE_GPHOTO2)
1447   status("    gPhoto2:"        HAVE_GPHOTO2        THEN "YES"                                 ELSE NO)
1448 endif()
1449
1450 # Order is similar to CV_PARALLEL_FRAMEWORK in core/src/parallel.cpp
1451 ocv_build_features_string(parallel_status EXCLUSIVE
1452   IF HAVE_TBB THEN "TBB (ver ${TBB_VERSION_MAJOR}.${TBB_VERSION_MINOR} interface ${TBB_INTERFACE_VERSION})"
1453   IF HAVE_HPX THEN "HPX"
1454   IF HAVE_OPENMP THEN "OpenMP"
1455   IF HAVE_GCD THEN "GCD"
1456   IF WINRT OR HAVE_CONCURRENCY THEN "Concurrency"
1457   IF HAVE_PTHREADS_PF THEN "pthreads"
1458   ELSE "none")
1459 status("")
1460 status("  Parallel framework:" "${parallel_status}")
1461
1462 if(CV_TRACE OR OPENCV_TRACE)
1463   ocv_build_features_string(trace_status EXCLUSIVE
1464     IF HAVE_ITT THEN "with Intel ITT"
1465     ELSE "built-in")
1466   status("")
1467   status("  Trace: " OPENCV_TRACE THEN "YES (${trace_status})" ELSE NO)
1468 endif()
1469
1470 # ========================== Other third-party libraries ==========================
1471 status("")
1472 status("  Other third-party libraries:")
1473
1474 if(WITH_IPP AND HAVE_IPP)
1475   status("    Intel IPP:" "${IPP_VERSION_STR} [${IPP_VERSION_MAJOR}.${IPP_VERSION_MINOR}.${IPP_VERSION_BUILD}]")
1476   status("           at:" "${IPP_ROOT_DIR}")
1477   if(NOT HAVE_IPP_ICV)
1478     status("       linked:" BUILD_WITH_DYNAMIC_IPP THEN "dynamic" ELSE "static")
1479   endif()
1480   if(HAVE_IPP_IW)
1481     if(BUILD_IPP_IW)
1482       status("    Intel IPP IW:" "sources (${IW_VERSION_MAJOR}.${IW_VERSION_MINOR}.${IW_VERSION_UPDATE})")
1483     else()
1484       status("    Intel IPP IW:" "binaries (${IW_VERSION_MAJOR}.${IW_VERSION_MINOR}.${IW_VERSION_UPDATE})")
1485     endif()
1486     status("              at:" "${IPP_IW_PATH}")
1487   else()
1488     status("    Intel IPP IW:"   NO)
1489   endif()
1490 endif()
1491
1492 if(WITH_VA OR HAVE_VA)
1493   status("    VA:"            HAVE_VA          THEN "YES" ELSE NO)
1494 endif()
1495
1496 if(WITH_TENGINE OR HAVE_TENGINE)
1497   status("    Tengine:"      HAVE_TENGINE     THEN "YES (${TENGINE_LIBRARIES})" ELSE NO)
1498 endif()
1499
1500 if(WITH_LAPACK OR HAVE_LAPACK)
1501   status("    Lapack:"      HAVE_LAPACK     THEN "YES (${LAPACK_LIBRARIES})" ELSE NO)
1502 endif()
1503
1504 if(WITH_HALIDE OR HAVE_HALIDE)
1505   status("    Halide:"     HAVE_HALIDE      THEN "YES (${HALIDE_LIBRARIES} ${HALIDE_INCLUDE_DIRS})" ELSE NO)
1506 endif()
1507
1508 if(WITH_INF_ENGINE OR INF_ENGINE_TARGET)
1509   if(INF_ENGINE_TARGET)
1510     list(GET INF_ENGINE_TARGET 0 ie_target)
1511     set(__msg "YES (${INF_ENGINE_RELEASE} / ${INF_ENGINE_VERSION})")
1512     get_target_property(_lib ${ie_target} IMPORTED_LOCATION)
1513     get_target_property(_lib_imp_rel ${ie_target} IMPORTED_IMPLIB_RELEASE)
1514     get_target_property(_lib_imp_dbg ${ie_target} IMPORTED_IMPLIB_DEBUG)
1515     get_target_property(_lib_rel ${ie_target} IMPORTED_LOCATION_RELEASE)
1516     get_target_property(_lib_dbg ${ie_target} IMPORTED_LOCATION_DEBUG)
1517     ocv_build_features_string(_lib
1518       IF _lib THEN "${_lib}"
1519       IF _lib_imp_rel AND _lib_imp_dbg THEN "${_lib_imp_rel} / ${_lib_imp_dbg}"
1520       IF _lib_rel AND _lib_dbg THEN "${_lib_rel} / ${_lib_dbg}"
1521       IF _lib_rel  THEN "${_lib_rel}"
1522       IF _lib_dbg  THEN "${_lib_dbg}"
1523       ELSE "unknown"
1524     )
1525     get_target_property(_inc ${ie_target} INTERFACE_INCLUDE_DIRECTORIES)
1526     status("    Inference Engine:" "${__msg}")
1527     status("        * libs:" "${_lib}")
1528     status("        * includes:" "${_inc}")
1529   else()
1530     status("    Inference Engine:"     "NO")
1531   endif()
1532 endif()
1533 if(WITH_NGRAPH OR HAVE_NGRAPH)
1534   if(HAVE_NGRAPH)
1535     set(__target ngraph::ngraph)
1536     set(__msg "YES (${ngraph_VERSION})")
1537     get_target_property(_lib ${__target} IMPORTED_LOCATION)
1538     get_target_property(_lib_imp_rel ${__target} IMPORTED_IMPLIB_RELEASE)
1539     get_target_property(_lib_imp_dbg ${__target} IMPORTED_IMPLIB_DEBUG)
1540     get_target_property(_lib_rel ${__target} IMPORTED_LOCATION_RELEASE)
1541     get_target_property(_lib_dbg ${__target} IMPORTED_LOCATION_DEBUG)
1542     ocv_build_features_string(_lib
1543       IF _lib THEN "${_lib}"
1544       IF _lib_imp_rel AND _lib_imp_dbg THEN "${_lib_imp_rel} / ${_lib_imp_dbg}"
1545       IF _lib_rel AND _lib_dbg THEN "${_lib_rel} / ${_lib_dbg}"
1546       IF _lib_rel  THEN "${_lib_rel}"
1547       IF _lib_dbg  THEN "${_lib_dbg}"
1548       ELSE "unknown"
1549     )
1550     get_target_property(_inc ${__target} INTERFACE_INCLUDE_DIRECTORIES)
1551     status("    nGraph:" "${__msg}")
1552     status("        * libs:" "${_lib}")
1553     status("        * includes:" "${_inc}")
1554   else()
1555     status("    nGraph:"     "NO")
1556   endif()
1557 endif()
1558
1559 if(WITH_EIGEN OR HAVE_EIGEN)
1560   status("    Eigen:"      HAVE_EIGEN       THEN "YES (ver ${EIGEN_WORLD_VERSION}.${EIGEN_MAJOR_VERSION}.${EIGEN_MINOR_VERSION})" ELSE NO)
1561 endif()
1562
1563 if(WITH_OPENVX OR HAVE_OPENVX)
1564   status("    OpenVX:"     HAVE_OPENVX      THEN "YES (${OPENVX_LIBRARIES})" ELSE "NO")
1565 endif()
1566
1567 status("    Custom HAL:" OpenCV_USED_HAL  THEN "YES (${OpenCV_USED_HAL})" ELSE "NO")
1568
1569 foreach(s ${CUSTOM_STATUS})
1570   status(${CUSTOM_STATUS_${s}})
1571 endforeach()
1572
1573 if(WITH_CUDA OR HAVE_CUDA)
1574   ocv_build_features_string(cuda_features
1575     IF HAVE_CUFFT THEN "CUFFT"
1576     IF HAVE_CUBLAS THEN "CUBLAS"
1577     IF HAVE_NVCUVID THEN "NVCUVID"
1578     IF CUDA_FAST_MATH THEN "FAST_MATH"
1579     ELSE "no extra features")
1580   status("")
1581   status("  NVIDIA CUDA:" HAVE_CUDA THEN "YES (ver ${CUDA_VERSION_STRING}, ${cuda_features})" ELSE NO)
1582   if(HAVE_CUDA)
1583     status("    NVIDIA GPU arch:"      ${OPENCV_CUDA_ARCH_BIN})
1584     status("    NVIDIA PTX archs:"     ${OPENCV_CUDA_ARCH_PTX})
1585   endif()
1586  endif()
1587
1588  if(WITH_CUDNN OR HAVE_CUDNN)
1589     status("")
1590     status("  cuDNN:" HAVE_CUDNN THEN "YES (ver ${CUDNN_VERSION})" ELSE NO)
1591 endif()
1592
1593 if(WITH_VULKAN OR HAVE_VULKAN)
1594   status("")
1595   status("  Vulkan:"     HAVE_VULKAN THEN "YES" ELSE "NO")
1596   if(HAVE_VULKAN)
1597     status("    Include path:"  VULKAN_INCLUDE_DIRS THEN "${VULKAN_INCLUDE_DIRS}" ELSE "NO")
1598     status("    Link libraries:" VULKAN_LIBRARIES THEN "${VULKAN_LIBRARIES}" ELSE "Dynamic load")
1599   endif()
1600 endif()
1601
1602 if(WITH_OPENCL OR HAVE_OPENCL)
1603   ocv_build_features_string(opencl_features
1604     IF HAVE_OPENCL_SVM THEN "SVM"
1605     IF HAVE_CLAMDFFT THEN "AMDFFT"
1606     IF HAVE_CLAMDBLAS THEN "AMDBLAS"
1607     IF HAVE_OPENCL_D3D11_NV THEN "NVD3D11"
1608     IF HAVE_VA_INTEL THEN "INTELVA"
1609     ELSE "no extra features")
1610   status("")
1611   status("  OpenCL:"     HAVE_OPENCL   THEN   "YES (${opencl_features})" ELSE "NO")
1612   if(HAVE_OPENCL)
1613     status("    Include path:"  OPENCL_INCLUDE_DIRS THEN "${OPENCL_INCLUDE_DIRS}" ELSE "NO")
1614     status("    Link libraries:"       OPENCL_LIBRARIES THEN "${OPENCL_LIBRARIES}" ELSE "Dynamic load")
1615   endif()
1616 endif()
1617
1618 if(WITH_ONNX OR HAVE_ONNX)
1619   status("")
1620   status("  ONNX:"     HAVE_ONNX THEN "YES" ELSE "NO")
1621   if(HAVE_ONNX)
1622     status("    Include path:"  ONNX_INCLUDE_DIR THEN "${ONNX_INCLUDE_DIR}" ELSE "NO")
1623     status("    Link libraries:" ONNX_LIBRARIES THEN "${ONNX_LIBRARIES}" ELSE "NO")
1624   endif()
1625 endif()
1626
1627 # ========================== python ==========================
1628 if(BUILD_opencv_python2)
1629   status("")
1630   status("  Python 2:")
1631   status("    Interpreter:"     PYTHON2INTERP_FOUND  THEN "${PYTHON2_EXECUTABLE} (ver ${PYTHON2_VERSION_STRING})"       ELSE NO)
1632   if(PYTHON2LIBS_VERSION_STRING)
1633     status("    Libraries:"   HAVE_opencv_python2  THEN  "${PYTHON2_LIBRARIES} (ver ${PYTHON2LIBS_VERSION_STRING})"   ELSE NO)
1634   else()
1635     status("    Libraries:"   HAVE_opencv_python2  THEN  "${PYTHON2_LIBRARIES}"                                      ELSE NO)
1636   endif()
1637   status("    numpy:"         PYTHON2_NUMPY_INCLUDE_DIRS THEN "${PYTHON2_NUMPY_INCLUDE_DIRS} (ver ${PYTHON2_NUMPY_VERSION})" ELSE "NO (Python wrappers can not be generated)")
1638   status("    install path:"  HAVE_opencv_python2  THEN "${__INSTALL_PATH_PYTHON2}"                            ELSE "-")
1639 endif()
1640
1641 if(BUILD_opencv_python3)
1642   status("")
1643   status("  Python 3:")
1644   status("    Interpreter:"     PYTHON3INTERP_FOUND  THEN "${PYTHON3_EXECUTABLE} (ver ${PYTHON3_VERSION_STRING})"       ELSE NO)
1645   if(PYTHON3LIBS_VERSION_STRING)
1646     status("    Libraries:"   HAVE_opencv_python3  THEN  "${PYTHON3_LIBRARIES} (ver ${PYTHON3LIBS_VERSION_STRING})"   ELSE NO)
1647   else()
1648     status("    Libraries:"   HAVE_opencv_python3  THEN  "${PYTHON3_LIBRARIES}"                                      ELSE NO)
1649   endif()
1650   status("    numpy:"         PYTHON3_NUMPY_INCLUDE_DIRS THEN "${PYTHON3_NUMPY_INCLUDE_DIRS} (ver ${PYTHON3_NUMPY_VERSION})" ELSE "NO (Python3 wrappers can not be generated)")
1651   status("    install path:"  HAVE_opencv_python3  THEN "${__INSTALL_PATH_PYTHON3}"                            ELSE "-")
1652 endif()
1653
1654 status("")
1655 status("  Python (for build):"  PYTHON_DEFAULT_AVAILABLE THEN "${PYTHON_DEFAULT_EXECUTABLE}" ELSE NO)
1656
1657 # ========================== java ==========================
1658 if(BUILD_JAVA)
1659   status("")
1660   status("  Java:"            BUILD_FAT_JAVA_LIB  THEN "export all functions"                                      ELSE "")
1661   status("    ant:"           ANT_EXECUTABLE      THEN "${ANT_EXECUTABLE} (ver ${ANT_VERSION})"                    ELSE NO)
1662   if(NOT ANDROID)
1663     status("    JNI:"         JNI_INCLUDE_DIRS    THEN "${JNI_INCLUDE_DIRS}"                                       ELSE NO)
1664   endif()
1665   status("    Java wrappers:" HAVE_opencv_java                                                            THEN YES ELSE NO)
1666   status("    Java tests:"    BUILD_TESTS AND opencv_test_java_BINARY_DIR                                 THEN YES ELSE NO)
1667 endif()
1668
1669 # ========================== Objective-C =======================
1670 if(BUILD_OBJC)
1671   status("")
1672   status("  Objective-C wrappers:" HAVE_opencv_objc                                                       THEN YES ELSE NO)
1673 endif()
1674
1675 ocv_cmake_hook(STATUS_DUMP_EXTRA)
1676
1677 # ========================== auxiliary ==========================
1678 status("")
1679 status("  Install to:" "${CMAKE_INSTALL_PREFIX}")
1680 status("-----------------------------------------------------------------")
1681 status("")
1682
1683
1684 ocv_finalize_status()
1685
1686 if(ENABLE_CONFIG_VERIFICATION)
1687   ocv_verify_config()
1688 endif()
1689
1690 if(HAVE_CUDA AND COMMAND CUDA_BUILD_CLEAN_TARGET)
1691   CUDA_BUILD_CLEAN_TARGET()
1692 endif()
1693
1694 ocv_cmake_hook(POST_FINALIZE)
1695
1696 # ----------------------------------------------------------------------------
1697 # CPack stuff
1698 # ----------------------------------------------------------------------------
1699
1700 include(cmake/OpenCVPackaging.cmake)
1701
1702 # This should be the last command
1703 ocv_cmake_dump_vars("" TOFILE "CMakeVars.txt")
1704 ocv_cmake_eval(DEBUG_POST ONCE)