CMakeLists.txt

   1 # ----------------------------------------------------------------------------
   2 #  Root CMake file for OpenCV
   3 #
   4 #    From the off-tree build directory, invoke:
   5 #      $ cmake <PATH_TO_OPENCV_ROOT>
   6 #
   7 #
   8 #   - OCT-2008: Initial version <joseluisblancoc@gmail.com>
   9 #
  10 # ----------------------------------------------------------------------------
  11
  12 set(CMAKE_ALLOW_LOOSE_LOOP_CONSTRUCTS true)
  13
  14 # --------------------------------------------------------------
  15 # Indicate CMake 2.7 and above that we don't want to mix relative
  16 #  and absolute paths in linker lib lists.
  17 # Run "cmake --help-policy CMP0003" for more information.
  18 # --------------------------------------------------------------
  19 if(COMMAND cmake_policy)
  20   cmake_policy(SET CMP0003 NEW)
  21 endif()
  22
  23 # Following block can broke build in case of cross-compilng
  24 # but CMAKE_CROSSCOMPILING variable will be set only on project(OpenCV) command
  25 # so we will try to detect crosscompiling by presense of CMAKE_TOOLCHAIN_FILE
  26 if(NOT CMAKE_TOOLCHAIN_FILE)
  27   # it _must_ go before project(OpenCV) in order to work
  28   if(WIN32)
  29     set(CMAKE_INSTALL_PREFIX "${CMAKE_BINARY_DIR}/install" CACHE PATH "Installation Directory")
  30   else()
  31     set(CMAKE_INSTALL_PREFIX "/usr/local" CACHE PATH "Installation Directory")
  32   endif()
  33
  34   if(MSVC)
  35     set(CMAKE_USE_RELATIVE_PATHS ON CACHE INTERNAL "" FORCE)
  36   endif()
  37 else(NOT CMAKE_TOOLCHAIN_FILE)
  38   #Android: set output folder to ${CMAKE_BINARY_DIR}
  39   set( LIBRARY_OUTPUT_PATH_ROOT ${CMAKE_BINARY_DIR} CACHE PATH "root for library output, set this to change where android libs are compiled to" )
  40 endif(NOT CMAKE_TOOLCHAIN_FILE)
  41
  42 # --------------------------------------------------------------
  43 # Top level OpenCV project
  44 # --------------------------------------------------------------
  45 if(NOT IOS)
  46   cmake_minimum_required(VERSION 2.6.3)
  47 else()
  48   cmake_minimum_required(VERSION 2.8)
  49 endif()
  50
  51 project(OpenCV)
  52
  53 set(CMAKE_CONFIGURATION_TYPES "Debug;Release" CACHE STRING "Configs" FORCE)
  54 if(DEFINED CMAKE_BUILD_TYPE AND CMAKE_VERSION VERSION_GREATER "2.8")
  55   set_property( CACHE CMAKE_BUILD_TYPE PROPERTY STRINGS ${CMAKE_CONFIGURATION_TYPES} )
  56 endif()
  57
  58 set(CMAKE_C_FLAGS_MINSIZEREL "" CACHE INTERNAL "" FORCE)
  59 set(CMAKE_C_FLAGS_RELWITHDEBINFO "" CACHE INTERNAL "" FORCE)
  60 set(CMAKE_CXX_FLAGS_MINSIZEREL "" CACHE INTERNAL "" FORCE)
  61 set(CMAKE_CXX_FLAGS_RELWITHDEBINFO "" CACHE INTERNAL "" FORCE)
  62 set(CMAKE_EXE_LINKER_FLAGS_MINSIZEREL "" CACHE INTERNAL "" FORCE)
  63 set(CMAKE_EXE_LINKER_FLAGS_RELWITHDEBINFO "" CACHE INTERNAL "" FORCE)
  64 set(CMAKE_MODULE_LINKER_FLAGS_MINSIZEREL "" CACHE INTERNAL "" FORCE)
  65 set(CMAKE_MODULE_LINKER_FLAGS_RELWITHDEBINFO "" CACHE INTERNAL "" FORCE)
  66 set(CMAKE_SHARED_LINKER_FLAGS_MINSIZEREL "" CACHE INTERNAL "" FORCE)
  67 set(CMAKE_SHARED_LINKER_FLAGS_RELWITHDEBINFO "" CACHE INTERNAL "" FORCE)
  68
  69 include(cmake/OpenCVUtils.cmake REQUIRED)
  70
  71 # ----------------------------------------------------------------------------
  72 # Detect compiler and target platform architecture
  73 # ----------------------------------------------------------------------------
  74 include(cmake/OpenCVDetectCXXCompiler.cmake REQUIRED)
  75
  76 # Add these standard paths to the search paths for FIND_LIBRARY
  77 # to find libraries from these locations first
  78 if(UNIX AND NOT ANDROID)
  79   if(X86_64 OR CMAKE_SIZEOF_VOID_P EQUAL 8)
  80     if(EXISTS /lib64)
  81       list(APPEND CMAKE_LIBRARY_PATH /lib64)
  82     else()
  83       list(APPEND CMAKE_LIBRARY_PATH /lib)
  84     endif()
  85     if(EXISTS /usr/lib64)
  86       list(APPEND CMAKE_LIBRARY_PATH /usr/lib64)
  87     else()
  88       list(APPEND CMAKE_LIBRARY_PATH /usr/lib)
  89     endif()
  90   elseif(X86 OR CMAKE_SIZEOF_VOID_P EQUAL 4)
  91     if(EXISTS /lib32)
  92       list(APPEND CMAKE_LIBRARY_PATH /lib32)
  93     else()
  94       list(APPEND CMAKE_LIBRARY_PATH /lib)
  95     endif()
  96     if(EXISTS /usr/lib32)
  97       list(APPEND CMAKE_LIBRARY_PATH /usr/lib32)
  98     else()
  99       list(APPEND CMAKE_LIBRARY_PATH /usr/lib)
 100     endif()
 101   endif()
 102 endif()
 103
 104
 105 # ----------------------------------------------------------------------------
 106 # OpenCV cmake options
 107 # ----------------------------------------------------------------------------
 108
 109 # Optional 3rd party components
 110 # ===================================================
 111 OCV_OPTION(WITH_1394           "Include IEEE1394 support"                    ON   IF (UNIX AND NOT ANDROID AND NOT IOS) )
 112 OCV_OPTION(WITH_AVFOUNDATION   "Use AVFoundation for Video I/O"              ON   IF IOS)
 113 OCV_OPTION(WITH_CARBON         "Use Carbon for UI instead of Cocoa"          OFF  IF APPLE )
 114 OCV_OPTION(WITH_CUBLAS         "Include NVidia Cuda Basic Linear Algebra Subprograms (BLAS) library support" OFF IF (CMAKE_VERSION VERSION_GREATER "2.8" AND NOT ANDROID AND NOT IOS) )
 115 OCV_OPTION(WITH_CUDA           "Include NVidia Cuda Runtime support"         ON   IF (CMAKE_VERSION VERSION_GREATER "2.8" AND NOT ANDROID AND NOT IOS) )
 116 OCV_OPTION(WITH_CUFFT          "Include NVidia Cuda Fast Fourier Transform (FFT) library support"            ON  IF (CMAKE_VERSION VERSION_GREATER "2.8" AND NOT ANDROID AND NOT IOS) )
 117 OCV_OPTION(WITH_EIGEN          "Include Eigen2/Eigen3 support"               ON)
 118 OCV_OPTION(WITH_FFMPEG         "Include FFMPEG support"                      ON   IF (UNIX AND NOT ANDROID AND NOT IOS) )
 119 OCV_OPTION(WITH_GSTREAMER      "Include Gstreamer support"                   ON   IF (UNIX AND NOT APPLE AND NOT ANDROID AND NOT IOS) )
 120 OCV_OPTION(WITH_GTK            "Include GTK support"                         ON   IF (UNIX AND NOT APPLE AND NOT ANDROID AND NOT IOS) )
 121 OCV_OPTION(WITH_IPP            "Include Intel IPP support"                   OFF  IF (MSVC OR X86 OR X86_64) )
 122 OCV_OPTION(WITH_JASPER         "Include JPEG2K support"                      ON   IF (NOT IOS) )
 123 OCV_OPTION(WITH_JPEG           "Include JPEG support"                        ON   IF (NOT IOS) )
 124 OCV_OPTION(WITH_OPENEXR        "Include ILM support via OpenEXR"             ON   IF (NOT IOS) )
 125 OCV_OPTION(WITH_OPENGL         "Include OpenGL support"                      OFF  IF (NOT ANDROID AND NOT IOS) )
 126 OCV_OPTION(WITH_OPENNI         "Include OpenNI support"                      OFF  IF (NOT ANDROID AND NOT IOS) )
 127 OCV_OPTION(WITH_PNG            "Include PNG support"                         ON   IF (NOT IOS) )
 128 OCV_OPTION(WITH_PVAPI          "Include Prosilica GigE support"              ON   IF (UNIX AND NOT ANDROID AND NOT IOS) )
 129 OCV_OPTION(WITH_QT             "Build with Qt Backend support"               OFF  IF (NOT ANDROID AND NOT IOS) )
 130 OCV_OPTION(WITH_QUICKTIME      "Use QuickTime for Video I/O insted of QTKit" OFF  IF APPLE )
 131 OCV_OPTION(WITH_TBB            "Include Intel TBB support"                   OFF  IF (NOT IOS) )
 132 OCV_OPTION(WITH_TIFF           "Include TIFF support"                        ON   IF (NOT IOS) )
 133 OCV_OPTION(WITH_UNICAP         "Include Unicap support (GPL)"                OFF  IF (UNIX AND NOT APPLE AND NOT ANDROID AND NOT IOS) )
 134 OCV_OPTION(WITH_V4L            "Include Video 4 Linux support"               ON   IF (UNIX AND NOT APPLE AND NOT ANDROID AND NOT IOS) )
 135 OCV_OPTION(WITH_VIDEOINPUT     "Build HighGUI with DirectShow support"       ON   IF WIN32 )
 136 OCV_OPTION(WITH_XIMEA          "Include XIMEA cameras support"               OFF  IF WIN32 )
 137 OCV_OPTION(WITH_XINE           "Include Xine support (GPL)"                  OFF  IF (UNIX AND NOT APPLE AND NOT ANDROID AND NOT IOS) )
 138
 139 # OpenCV build components
 140 # ===================================================
 141 OCV_OPTION(BUILD_SHARED_LIBS        "Build shared libraries (.dll/.so) instead of static ones (.lib/.a)" NOT (ANDROID OR IOS) )
 142 OCV_OPTION(BUILD_ANDROID_EXAMPLES   "Build examples for Android platform"         ON  IF ANDROID )
 143 OCV_OPTION(BUILD_DOCS               "Create build rules for OpenCV Documentation" ON )
 144 OCV_OPTION(BUILD_EXAMPLES           "Build all examples"                          OFF )
 145 OCV_OPTION(BUILD_PACKAGE            "Enables 'make package_source' command"       ON )
 146 OCV_OPTION(BUILD_PERF_TESTS         "Build performance tests"                     ON  IF (NOT IOS) )
 147 OCV_OPTION(BUILD_TESTS              "Build accuracy & regression tests"           ON  IF (NOT IOS) )
 148 OCV_OPTION(BUILD_WITH_DEBUG_INFO    "Include debug info into debug libs"          ON )
 149 OCV_OPTION(BUILD_WITH_STATIC_CRT    "Enables use of staticaly linked CRT for staticaly linked OpenCV" ON IF MSVC )
 150
 151 # 3rdparty libs
 152 OCV_OPTION(BUILD_ZLIB               "Build zlib from source instead of installed in the system"      WIN32 OR IOS )
 153
 154 if(WIN32 OR ANDROID)
 155     set(OPENCV_BUILD_3RDPARTY_LIBS TRUE  CACHE INTERNAL "Build 3rd party libraries")
 156 else()
 157     # Build 3rdparty libraries under unix
 158     set(OPENCV_BUILD_3RDPARTY_LIBS FALSE CACHE BOOL "Build 3rd party libraries")
 159 endif()
 160
 161 # OpenCV installation options
 162 # ===================================================
 163 OCV_OPTION(INSTALL_C_EXAMPLES       "Install C examples"        OFF )
 164 OCV_OPTION(INSTALL_PYTHON_EXAMPLES  "Install Python examples"   OFF )
 165 OCV_OPTION(INSTALL_ANDROID_EXAMPLES "Install Android examples"  OFF  IF ANDROID )
 166 OCV_OPTION(INSTALL_TO_MANGLED_PATHS "Enables mangled install paths, that help with side by side installs." OFF IF (UNIX AND NOT ANDROID AND NOT IOS AND BUILD_SHARED_LIBS) )
 167
 168 # OpenCV build options
 169 # ===================================================
 170 OCV_OPTION(ENABLE_PRECOMPILED_HEADERS "Use precompiled headers"                                  ON   IF (NOT IOS) )
 171 OCV_OPTION(ENABLE_SOLUTION_FOLDERS    "Solution folder in Visual Studio or in other IDEs"        OFF  IF (CMAKE_VERSION VERSION_GREATER "2.8.0") )
 172 OCV_OPTION(ENABLE_PROFILING           "Enable profiling in the GCC compiler (Add flags: -g -pg)" OFF  IF CMAKE_COMPILER_IS_GNUCXX )
 173 OCV_OPTION(ENABLE_OMIT_FRAME_POINTER  "Enable -fomit-frame-pointer for GCC"                      ON   IF CMAKE_COMPILER_IS_GNUCXX )
 174 OCV_OPTION(ENABLE_POWERPC             "Enable PowerPC for GCC"                                   ON   IF (CMAKE_COMPILER_IS_GNUCXX AND CMAKE_SYSTEM_PROCESSOR MATCHES powerpc.*) )
 175 OCV_OPTION(ENABLE_FAST_MATH           "Enable -ffast-math (not recommended for GCC 4.6.x)"       OFF  IF (CMAKE_COMPILER_IS_GNUCXX AND (X86 OR X86_64)) )
 176 OCV_OPTION(ENABLE_SSE                 "Enable SSE instructions"                                  ON   IF (MSVC OR CMAKE_COMPILER_IS_GNUCXX AND (X86 OR X86_64)) )
 177 OCV_OPTION(ENABLE_SSE2                "Enable SSE2 instructions"                                 ON   IF (MSVC OR CMAKE_COMPILER_IS_GNUCXX AND (X86 OR X86_64)) )
 178 OCV_OPTION(ENABLE_SSE3                "Enable SSE3 instructions"                                 OFF  IF (CV_ICC OR CMAKE_COMPILER_IS_GNUCXX AND (X86 OR X86_64)) )
 179 OCV_OPTION(ENABLE_SSSE3               "Enable SSSE3 instructions"                                OFF  IF (CMAKE_COMPILER_IS_GNUCXX AND (X86 OR X86_64)) )
 180 OCV_OPTION(ENABLE_SSE41               "Enable SSE4.1 instructions"                               OFF  IF (CV_ICC OR CMAKE_COMPILER_IS_GNUCXX AND (X86 OR X86_64)) )
 181 OCV_OPTION(ENABLE_SSE42               "Enable SSE4.2 instructions"                               OFF  IF (CMAKE_COMPILER_IS_GNUCXX AND (X86 OR X86_64)) )
 182 OCV_OPTION(OPENCV_WARNINGS_ARE_ERRORS "Treat warnings as errors"                                 OFF )
 183
 184 # uncategorized options
 185 # ===================================================
 186 OCV_OPTION(CMAKE_VERBOSE "Verbose mode" OFF )
 187
 188 # backward compatibility
 189 # ===================================================
 190 include(cmake/OpenCVLegacyOptions.cmake OPTIONAL)
 191
 192
 193 # ----------------------------------------------------------------------------
 194 #  Get actual OpenCV version number from sources
 195 # ----------------------------------------------------------------------------
 196 include(cmake/OpenCVVersion.cmake REQUIRED)
 197
 198
 199 # ----------------------------------------------------------------------------
 200 #  Build & install layouts
 201 # ----------------------------------------------------------------------------
 202
 203 # Save libs and executables in the same place
 204 set(LIBRARY_OUTPUT_PATH "${CMAKE_BINARY_DIR}/lib" CACHE PATH "Output directory for libraries" )
 205 set(EXECUTABLE_OUTPUT_PATH "${CMAKE_BINARY_DIR}/bin" CACHE PATH "Output directory for applications" )
 206
 207 if(ANDROID OR WIN32)
 208     set(OPENCV_DOC_INSTALL_PATH doc)
 209 elseif(INSTALL_TO_MANGLED_PATHS)
 210     set(OPENCV_DOC_INSTALL_PATH share/OpenCV-${OPENCV_VERSION}/doc)
 211 else()
 212     set(OPENCV_DOC_INSTALL_PATH share/OpenCV/doc)
 213 endif()
 214
 215 if(ANDROID)
 216     set(OPENCV_LIB_INSTALL_PATH libs/${ANDROID_NDK_ABI_NAME})
 217 else()
 218     set(OPENCV_LIB_INSTALL_PATH lib${LIB_SUFFIX})
 219 endif()
 220
 221 set(CMAKE_INSTALL_RPATH "${CMAKE_INSTALL_PREFIX}/${OPENCV_LIB_INSTALL_PATH}")
 222 set(CMAKE_INSTALL_RPATH_USE_LINK_PATH TRUE)
 223
 224 set(OPENCV_INCLUDE_PREFIX include)
 225 if(INSTALL_TO_MANGLED_PATHS)
 226   set(OPENCV_INCLUDE_PREFIX include/opencv-${OPENCV_VERSION})
 227 endif()
 228
 229 if(WIN32)
 230   # Postfix of DLLs:
 231   set(OPENCV_DLLVERSION "${OPENCV_VERSION_MAJOR}${OPENCV_VERSION_MINOR}${OPENCV_VERSION_PATCH}")
 232   set(OPENCV_DEBUG_POSTFIX d)
 233 else()
 234   # Postfix of so's:
 235   set(OPENCV_DLLVERSION "")
 236   set(OPENCV_DEBUG_POSTFIX "")
 237 endif()
 238
 239 if(DEFINED CMAKE_DEBUG_POSTFIX)
 240   set(OPENCV_DEBUG_POSTFIX "${CMAKE_DEBUG_POSTFIX}")
 241 endif()
 242
 243 if(CMAKE_VERBOSE)
 244   set(CMAKE_VERBOSE_MAKEFILE 1)
 245 endif()
 246
 247
 248 # ----------------------------------------------------------------------------
 249 #  Path for build/platform -specific headers
 250 # ----------------------------------------------------------------------------
 251 set(OPENCV_CONFIG_FILE_INCLUDE_DIR "${CMAKE_BINARY_DIR}/" CACHE PATH "Where to create the platform-dependant cvconfig.h")
 252 add_definitions(-DHAVE_CVCONFIG_H)
 253 include_directories(${OPENCV_CONFIG_FILE_INCLUDE_DIR})
 254
 255
 256 # ----------------------------------------------------------------------------
 257 # Use statically or dynamically linked CRT?
 258 # Default: dynamic
 259 # ----------------------------------------------------------------------------
 260 if(MSVC)
 261   include(cmake/OpenCVCRTLinkage.cmake REQUIRED)
 262 endif(MSVC)
 263
 264
 265 # ----------------------------------------------------------------------------
 266 #  Autodetect if we are in a SVN repository
 267 # ----------------------------------------------------------------------------
 268 find_host_program(SVNVERSION_PATH svnversion)
 269 mark_as_advanced(force SVNVERSION_PATH)
 270 if(SVNVERSION_PATH)
 271     message(STATUS "Extracting svn version, please wait...")
 272     execute_process(COMMAND ${SVNVERSION_PATH} -n ${OpenCV_SOURCE_DIR} OUTPUT_VARIABLE SVNVERSION_RESULT)
 273
 274     if(SVNVERSION_RESULT MATCHES "exported")
 275         # This is NOT a svn repository:
 276         set(OPENCV_SVNVERSION "")
 277         message(STATUS "SVNVERSION: exported")
 278     else()
 279         set(OPENCV_SVNVERSION " svn:${SVNVERSION_RESULT}")
 280         message(STATUS "SVNVERSION: ${OPENCV_SVNVERSION}")
 281     endif()
 282 else()
 283     # We don't have svnversion:
 284     set(OPENCV_SVNVERSION "")
 285 endif()
 286
 287
 288 # ----------------------------------------------------------------------------
 289 #       CHECK FOR SYSTEM LIBRARIES, OPTIONS, ETC..
 290 # ----------------------------------------------------------------------------
 291 if(UNIX)
 292   include(cmake/OpenCVFindPkgConfig.cmake OPTIONAL)
 293   include(CheckFunctionExists)
 294   include(CheckIncludeFile)
 295 endif()
 296
 297 include(cmake/OpenCVPCHSupport.cmake REQUIRED)
 298 include(cmake/OpenCVModule.cmake REQUIRED)
 299
 300 if(ANDROID)
 301   include(cmake/OpenCVAndroidProject.cmake REQUIRED)
 302 endif()
 303
 304
 305 # ----------------------------------------------------------------------------
 306 #  Detect 3rd-party tools and libraries
 307 # ----------------------------------------------------------------------------
 308
 309 #Graphic libraries
 310 set(HAVE_OPENGL 0)
 311 if(UNIX)
 312     if(NOT APPLE)
 313       if(WITH_GTK)
 314         CHECK_MODULE(gtk+-2.0 HAVE_GTK)
 315         CHECK_MODULE(gthread-2.0 HAVE_GTHREAD)
 316         if(WITH_OPENGL)
 317             CHECK_MODULE(gtkglext-1.0 HAVE_GTKGLEXT)
 318             if(HAVE_GTKGLEXT)
 319                 find_package(OpenGL QUIET)
 320                 if(OPENGL_FOUND)
 321                     set(HAVE_OPENGL 1)
 322                     set(OPENCV_LINKER_LIBS ${OPENCV_LINKER_LIBS} ${OPENGL_LIBRARIES})
 323                     include_directories(${OPENGL_INCLUDE_DIR})
 324                 endif()
 325             endif()
 326         endif()
 327       else()
 328         set(HAVE_GTK FALSE)
 329         set(HAVE_GTHREAD FALSE)
 330       endif()
 331       if(WITH_GSTREAMER)
 332         CHECK_MODULE(gstreamer-base-0.10 HAVE_GSTREAMER)
 333         CHECK_MODULE(gstreamer-app-0.10 HAVE_GSTREAMER)
 334         CHECK_MODULE(gstreamer-video-0.10 HAVE_GSTREAMER)
 335       else()
 336         set(HAVE_GSTREAMER FALSE)
 337       endif()
 338     endif()
 339
 340     if(WITH_UNICAP)
 341       CHECK_MODULE(libunicap HAVE_UNICAP_)
 342       CHECK_MODULE(libucil HAVE_UNICAP_UCIL)
 343       if(HAVE_UNICAP_ AND HAVE_UNICAP_UCIL)
 344         set(HAVE_UNICAP 1)
 345       endif()
 346     else()
 347       set(HAVE_UNICAP FALSE)
 348     endif()
 349
 350     if(WITH_PVAPI)
 351       find_path(PVAPI_INCLUDE_PATH "PvApi.h"
 352                 PATHS "/usr/local/include" "/usr/include"
 353                 DOC "The path to PvAPI header")
 354       if(PVAPI_INCLUDE_PATH)
 355         set(HAVE_PVAPI 1)
 356       endif()
 357     endif()
 358
 359     set(HAVE_FFMPEG 0)
 360     if(WITH_FFMPEG)
 361       CHECK_MODULE(libavcodec HAVE_FFMPEG_CODEC)
 362       CHECK_MODULE(libavformat HAVE_FFMPEG_FORMAT)
 363       CHECK_MODULE(libavutil HAVE_FFMPEG_UTIL)
 364       CHECK_MODULE(libswscale HAVE_FFMPEG_SWSCALE)
 365       CHECK_INCLUDE_FILE(libavformat/avformat.h HAVE_GENTOO_FFMPEG)
 366       CHECK_INCLUDE_FILE(ffmpeg/avformat.h HAVE_FFMPEG_FFMPEG)
 367       if(NOT HAVE_GENTOO_FFMPEG AND NOT HAVE_FFMPEG_FFMPEG)
 368         if(EXISTS /usr/include/ffmpeg/libavformat/avformat.h OR HAVE_FFMPEG_SWSCALE)
 369           set(HAVE_GENTOO_FFMPEG 1)
 370         endif()
 371       endif()
 372       if(HAVE_FFMPEG_CODEC AND HAVE_FFMPEG_FORMAT AND HAVE_FFMPEG_UTIL)
 373         if(HAVE_FFMPEG_SWSCALE OR NOT HAVE_GENTOO_FFMPEG)
 374             set(HAVE_FFMPEG 1)
 375         endif()
 376       endif()
 377       # Find the bzip2 library because it is required on some systems
 378       FIND_LIBRARY(BZIP2_LIBRARIES NAMES bz2 bzip2)
 379       if(NOT BZIP2_LIBRARIES)
 380         # Do an other trial
 381         FIND_FILE(BZIP2_LIBRARIES NAMES libbz2.so.1 PATHS /lib)
 382       endif()
 383     endif()
 384
 385     if(WITH_1394)
 386       CHECK_MODULE(libdc1394-2 HAVE_DC1394_2)
 387       if(NOT HAVE_DC1394_2)
 388         CHECK_MODULE(libdc1394 HAVE_DC1394)
 389       endif()
 390     else()
 391       set(HAVE_DC1394_2 FALSE)
 392       set(HAVE_DC1394 FALSE)
 393     endif()
 394
 395     if(NOT APPLE)
 396         CHECK_INCLUDE_FILE(alloca.h HAVE_ALLOCA_H)
 397         CHECK_FUNCTION_EXISTS(alloca HAVE_ALLOCA)
 398         CHECK_INCLUDE_FILE(unistd.h HAVE_UNISTD_H)
 399         CHECK_INCLUDE_FILE(pthread.h HAVE_LIBPTHREAD)
 400
 401         if(WITH_XINE)
 402             CHECK_MODULE(libxine HAVE_XINE)
 403         else()
 404             set(HAVE_XINE FALSE)
 405         endif()
 406         if(WITH_V4L)
 407             CHECK_MODULE(libv4l1 HAVE_LIBV4L)
 408             CHECK_INCLUDE_FILE(linux/videodev.h HAVE_CAMV4L)
 409             CHECK_INCLUDE_FILE(linux/videodev2.h HAVE_CAMV4L2)
 410         else()
 411             set(HAVE_LIBV4L FALSE)
 412             set(HAVE_CAMV4L FALSE)
 413             set(HAVE_CAMV4L2 FALSE)
 414         endif()
 415
 416         if(ANDROID)
 417             set(OPENCV_LINKER_LIBS dl m log)
 418         elseif(${CMAKE_SYSTEM_NAME} MATCHES "FreeBSD" OR ${CMAKE_SYSTEM_NAME} MATCHES "NetBSD")
 419             set(OPENCV_LINKER_LIBS m pthread)
 420         else()
 421             set(OPENCV_LINKER_LIBS dl m pthread rt)
 422         endif()
 423     else()
 424         add_definitions(-DHAVE_ALLOCA -DHAVE_ALLOCA_H -DHAVE_LIBPTHREAD -DHAVE_UNISTD_H)
 425     endif()
 426 endif()
 427 if (UNIX OR WIN32)
 428     if(NOT OPENCV_BUILD_3RDPARTY_LIBS)
 429         message(STATUS "NOT OPENCV_BUILD_3RDPARTY_LIBS **************************************************")
 430         if(WITH_PNG)
 431             include(FindPNG)
 432             if(PNG_FOUND)
 433                 CHECK_INCLUDE_FILE(${PNG_PNG_INCLUDE_DIR}/png.h HAVE_PNG_H)
 434                 CHECK_INCLUDE_FILE(${PNG_PNG_INCLUDE_DIR}/libpng/png.h HAVE_LIBPNG_PNG_H)
 435             endif()
 436         else()
 437             set(PNG_FOUND FALSE)
 438         endif()
 439         if(WITH_TIFF)
 440             include(FindTIFF)
 441         else()
 442             set(TIFF_FOUND FALSE)
 443         endif()
 444         if(WITH_JASPER)
 445             include(FindJasper)
 446         else()
 447             set(JASPER_FOUND FALSE)
 448         endif()
 449         if(WITH_JPEG)
 450             include(FindJPEG)
 451         else()
 452             set(JPEG_FOUND FALSE)
 453         endif()
 454     endif()
 455 endif()
 456
 457 if(WITH_PNG AND NOT PNG_FOUND)
 458     set(PNG_LIBRARIES libpng)
 459 endif()
 460
 461 if(WITH_JPEG AND NOT JPEG_FOUND)
 462     set(JPEG_LIBRARIES libjpeg)
 463 endif()
 464
 465 if(WITH_TIFF AND NOT TIFF_FOUND)
 466     set(TIFF_LIBRARIES libtiff)
 467 endif()
 468
 469 if(WITH_JASPER AND NOT JASPER_FOUND)
 470     set(JASPER_LIBRARIES libjasper)
 471 endif()
 472
 473 ################### zlib - always required
 474 if(NOT BUILD_ZLIB)
 475   if(ANDROID)
 476     set(ZLIB_FOUND TRUE)
 477     set(ZLIB_LIBRARY z)
 478     set(ZLIB_INCLUDE_DIR "")
 479   else()
 480     include(FindZLIB)
 481   endif()
 482 else()
 483   set(ZLIB_FOUND FALSE)
 484 endif()
 485
 486 if(NOT ZLIB_FOUND)
 487   set(ZLIB_LIBRARY zlib)
 488   add_subdirectory(3rdparty/zlib)
 489   set(ZLIB_INCLUDE_DIR "${OpenCV_SOURCE_DIR}/3rdparty/zlib" "${${ZLIB_LIBRARY}_BINARY_DIR}")
 490 endif()
 491
 492 ################### OpenEXR
 493 if(WITH_OPENEXR)
 494   include(cmake/OpenCVFindOpenEXR.cmake)
 495 endif()
 496
 497 #################### LATEX for dpf documentation ##################
 498 if(BUILD_DOCS)
 499   include(cmake/OpenCVFindLATEX.cmake REQUIRED)
 500 endif()
 501
 502 ########################## Python Support #########################
 503 include(cmake/OpenCVDetectPython.cmake REQUIRED)
 504
 505 ########################### Java Support ##########################
 506 # current implementation of Java wrappers generator requires python at build time
 507 if((NOT DEFINED BUILD_opencv_java OR BUILD_opencv_java) AND PYTHON_EXECUTABLE)
 508   if(ANDROID)
 509     include(cmake/OpenCVDetectAndroidSDK.cmake REQUIRED)
 510   endif()
 511   include(cmake/OpenCVDetectApacheAnt.cmake REQUIRED)
 512
 513   if(ANDROID_EXECUTABLE AND ANT_EXECUTABLE AND (ANT_VERSION VERSION_GREATER 1.7) AND (ANDROID_SDK_TARGET_LEVEL GREATER 7))
 514     SET(CAN_BUILD_ANDROID_PROJECTS TRUE)
 515   else()
 516     SET(CAN_BUILD_ANDROID_PROJECTS FALSE)
 517   endif()
 518 endif()
 519
 520 if(BUILD_ANDROID_EXAMPLES AND NOT CAN_BUILD_ANDROID_PROJECTS)
 521   if(HAVE_opencv_java)
 522     message(WARNING "Android examples are chosen for build, but required SDK tools are not found.")
 523   endif()
 524   unset(BUILD_ANDROID_EXAMPLES CACHE)
 525 endif()
 526
 527 ############################### QT ################################
 528 set(HAVE_QT 0)
 529 set(HAVE_QT_OPENGL 0)
 530
 531 if(WITH_QT)
 532   find_package(Qt4)
 533   if(QT4_FOUND)
 534     set(HAVE_QT 1)
 535     add_definitions(-DHAVE_QT) #We need to define te macro this way, using cvconfig.h.cmake does not work
 536
 537     if(WITH_OPENGL)
 538       find_package (OpenGL QUIET)
 539       if(QT_QTOPENGL_FOUND AND OPENGL_FOUND)
 540         set(HAVE_OPENGL 1)
 541         set(HAVE_QT_OPENGL 1)
 542         add_definitions(-DHAVE_QT_OPENGL)
 543         set(OPENCV_LINKER_LIBS ${OPENCV_LINKER_LIBS} ${OPENGL_LIBRARIES})
 544       endif()
 545     endif()
 546   endif()
 547 endif()
 548
 549 ############################### TBB ################################
 550 if(WITH_TBB)
 551   include(cmake/OpenCVDetectTBB.cmake REQUIRED)
 552 endif()
 553
 554 ############################ Intel IPP #############################
 555 set(IPP_FOUND)
 556
 557 if(WITH_IPP)
 558   include(cmake/OpenCVFindIPP.cmake)
 559 endif()
 560
 561 if(IPP_FOUND)
 562   add_definitions(-DHAVE_IPP)
 563   include_directories(${IPP_INCLUDE_DIRS})
 564   link_directories(${IPP_LIBRARY_DIRS})
 565   set(OPENCV_LINKER_LIBS ${OPENCV_LINKER_LIBS} ${IPP_LIBRARIES})
 566 endif()
 567
 568 ############################### CUDA ################################
 569 if(WITH_CUDA)
 570   include(cmake/OpenCVDetectCUDA.cmake REQUIRED)
 571 endif()
 572
 573 ############################### OpenNI ################################
 574 set(HAVE_OPENNI FALSE)
 575 set(HAVE_OPENNI_PRIME_SENSOR_MODULE FALSE)
 576
 577 if(WITH_OPENNI)
 578   include(cmake/OpenCVFindOpenNI.cmake)
 579 endif()
 580
 581 ############################### XIMEA ################################
 582 set(HAVE_XIMEA FALSE)
 583
 584 if(WITH_XIMEA)
 585   include(cmake/OpenCVFindXimea.cmake)
 586 endif()
 587
 588 if(XIMEA_FOUND)
 589   set(HAVE_XIMEA TRUE)
 590 endif()
 591
 592 ############################## Eigen ##############################
 593 if(WITH_EIGEN)
 594   find_path(EIGEN_INCLUDE_PATH "Eigen/Core"
 595             PATHS "/usr/local/include/eigen2" "/opt/include/eigen2" "/usr/include/eigen2"
 596                   "/usr/local/include/eigen3" "/opt/include/eigen3" "/usr/include/eigen3"
 597             DOC "The path to Eigen2/Eigen3 headers")
 598   if(EIGEN_INCLUDE_PATH)
 599     include_directories(${EIGEN_INCLUDE_PATH})
 600     set(HAVE_EIGEN 1)
 601   endif()
 602 endif()
 603
 604 ################## Extra HighGUI libs on Windows ###################
 605 if(WIN32)
 606   set(HIGHGUI_LIBRARIES ${HIGHGUI_LIBRARIES} comctl32 gdi32 ole32)
 607
 608   if(WITH_VIDEOINPUT)
 609     set(HAVE_VIDEOINPUT 1)
 610   endif()
 611
 612   if(MSVC)
 613     set(HIGHGUI_LIBRARIES ${HIGHGUI_LIBRARIES} vfw32)
 614   endif()
 615
 616   if(MINGW)
 617     if(MINGW64)
 618       set(HIGHGUI_LIBRARIES ${HIGHGUI_LIBRARIES} msvfw32 avifil32 avicap32 winmm)
 619     else()
 620       set(HIGHGUI_LIBRARIES ${HIGHGUI_LIBRARIES} vfw32 winmm)
 621     endif()
 622   endif()
 623
 624   if(WITH_OPENGL AND NOT HAVE_QT_OPENGL)
 625     find_package(OpenGL QUIET)
 626
 627     if(OPENGL_FOUND)
 628       set(HAVE_OPENGL 1)
 629       set(OPENCV_LINKER_LIBS ${OPENCV_LINKER_LIBS} ${OPENGL_LIBRARIES})
 630       include_directories(${OPENGL_INCLUDE_DIR})
 631     endif()
 632   endif()
 633 endif()
 634
 635 # ----------------------------------------------------------------------------
 636 # OpenCV compiler and linker options
 637 # ----------------------------------------------------------------------------
 638 include(cmake/OpenCVCompilerOptions.cmake REQUIRED)
 639
 640 # In case of Makefiles if the user does not setup CMAKE_BUILD_TYPE, assume it's Release:
 641 if(CMAKE_GENERATOR MATCHES "Makefiles" AND "${CMAKE_BUILD_TYPE}" STREQUAL "")
 642   set(CMAKE_BUILD_TYPE Release)
 643 endif()
 644
 645 # ----------------------------------------------------------------------------
 646 # Solution folders:
 647 # ----------------------------------------------------------------------------
 648 if(ENABLE_SOLUTION_FOLDERS)
 649   set_property(GLOBAL PROPERTY USE_FOLDERS ON)
 650   set_property(GLOBAL PROPERTY PREDEFINED_TARGETS_FOLDER "CMakeTargets")
 651 endif()
 652
 653 # Extra OpenCV targets: uninstall, package_source, perf, etc.
 654 include(cmake/OpenCVExtraTargets.cmake REQUIRED)
 655
 656 # ----------------------------------------------------------------------------
 657 # Process subdirectories
 658 # ----------------------------------------------------------------------------
 659
 660 # opencv.hpp and legacy headers
 661 add_subdirectory(include)
 662
 663 # OpenCV modules
 664 add_subdirectory(modules)
 665
 666 # Generate targets for documentation
 667 add_subdirectory(doc)
 668
 669 # various data that is used by cv libraries and/or demo applications.
 670 add_subdirectory(data)
 671
 672 # 3rdparty libraries on-board
 673 add_subdirectory(3rdparty)
 674
 675 # extra applications
 676 add_subdirectory(apps)
 677
 678 # examples
 679 if(BUILD_EXAMPLES OR BUILD_ANDROID_EXAMPLES OR INSTALL_PYTHON_EXAMPLES)
 680   add_subdirectory(samples)
 681 endif()
 682
 683 # ----------------------------------------------------------------------------
 684 # Finalization: generate configuration-based files
 685 # ----------------------------------------------------------------------------
 686 ocv_track_build_dependencies()
 687
 688 # Generate platform-dependent and configuration-dependent headers
 689 include(cmake/OpenCVGenHeaders.cmake REQUIRED)
 690
 691 # Generate opencv.pc for pkg-config command
 692 include(cmake/OpenCVGenPkgconfig.cmake REQUIRED)
 693
 694 # Generate OpenCV.mk for ndk-build (Android build tool)
 695 include(cmake/OpenCVGenAndroidMK.cmake REQUIRED)
 696
 697 # Generate OpenCVСonfig.cmake and OpenCVConfig-version.cmake for cmake projects
 698 include(cmake/OpenCVGenConfig.cmake REQUIRED)
 699
 700 # ----------------------------------------------------------------------------
 701 # Summary:
 702 # ----------------------------------------------------------------------------
 703 status("")
 704 status("General configuration for OpenCV ${OPENCV_VERSION} =====================================")
 705
 706 #build platform
 707 status("")
 708 status("  Platform:")
 709 status("    Host:"             ${CMAKE_HOST_SYSTEM_NAME} ${CMAKE_HOST_SYSTEM_VERSION} ${CMAKE_HOST_SYSTEM_PROCESSOR})
 710 status("    Target:"           ${CMAKE_SYSTEM_NAME} ${CMAKE_SYSTEM_VERSION} ${CMAKE_SYSTEM_PROCESSOR})
 711 status("    CMake:"            ${CMAKE_VERSION})
 712 status("    CMake generator:"  ${CMAKE_GENERATOR})
 713 status("    CMake build tool:" ${CMAKE_BUILD_TOOL})
 714 if(MSVC)
 715   status("    MSVC:"           ${MSVC_VERSION})
 716 endif()
 717 if(CMAKE_GENERATOR MATCHES Xcode)
 718   status("    Xcode:"          ${XCODE_VERSION})
 719 endif()
 720
 721 # C/C++ options
 722 status("")
 723 status("  C++:")
 724 status("    Built as dynamic libs?:" BUILD_SHARED_LIBS THEN YES ELSE NO)
 725 status("    C++ Compiler:"           CMAKE_COMPILER    THEN "${CMAKE_COMPILER}" ELSE "${CMAKE_CXX_COMPILER}")
 726 status("    C++ flags (Release):"    ${CMAKE_CXX_FLAGS} ${CMAKE_CXX_FLAGS_RELEASE})
 727 status("    C++ flags (Debug):"      ${CMAKE_CXX_FLAGS} ${CMAKE_CXX_FLAGS_DEBUG})
 728 if(WIN32)
 729   status("    Linker flags (Release):" ${CMAKE_EXE_LINKER_FLAGS} ${CMAKE_EXE_LINKER_FLAGS_RELEASE})
 730   status("    Linker flags (Debug):"   ${CMAKE_EXE_LINKER_FLAGS} ${CMAKE_EXE_LINKER_FLAGS_DEBUG})
 731 else()
 732   status("    Linker flags (Release):" ${CMAKE_SHARED_LINKER_FLAGS} ${CMAKE_SHARED_LINKER_FLAGS_RELEASE})
 733   status("    Linker flags (Debug):"   ${CMAKE_SHARED_LINKER_FLAGS} ${CMAKE_SHARED_LINKER_FLAGS_DEBUG})
 734 endif()
 735
 736 # OpenCV modules
 737 status("")
 738 status("  OpenCV modules:")
 739 string(REPLACE "opencv_" "" OPENCV_MODULES_BUILD_ST          "${OPENCV_MODULES_BUILD}")
 740 string(REPLACE "opencv_" "" OPENCV_MODULES_DISABLED_USER_ST  "${OPENCV_MODULES_DISABLED_USER}")
 741 string(REPLACE "opencv_" "" OPENCV_MODULES_DISABLED_AUTO_ST  "${OPENCV_MODULES_DISABLED_AUTO}")
 742 string(REPLACE "opencv_" "" OPENCV_MODULES_DISABLED_FORCE_ST "${OPENCV_MODULES_DISABLED_FORCE}")
 743 status("    To be built:"            OPENCV_MODULES_BUILD          THEN ${OPENCV_MODULES_BUILD_ST}          ELSE "-")
 744 status("    Disabled by user:"       OPENCV_MODULES_DISABLED_USER  THEN ${OPENCV_MODULES_DISABLED_USER_ST}  ELSE "-")
 745 status("    Disabled by dependency:" OPENCV_MODULES_DISABLED_AUTO  THEN ${OPENCV_MODULES_DISABLED_AUTO_ST}  ELSE "-")
 746 status("    Unavailable:"            OPENCV_MODULES_DISABLED_FORCE THEN ${OPENCV_MODULES_DISABLED_FORCE_ST} ELSE "-")
 747
 748 # Android extra
 749 if(ANDROID)
 750   status("")
 751   status("  Android: ")
 752   status("    Android ABI:" ${ANDROID_ABI})
 753   status("    Native API level:" android-${ANDROID_NATIVE_API_LEVEL})
 754   status("    SDK target:" "${ANDROID_SDK_TARGET}")
 755   if(BUILD_WITH_ANDROID_NDK)
 756     status("    Android NDK:" "${ANDROID_NDK} (toolchain: ${ANDROID_TOOLCHAIN_NAME})")
 757   elseif(BUILD_WITH_STANDALONE_TOOLCHAIN)
 758     status("    Android toolchain:" "${ANDROID_STANDALONE_TOOLCHAIN}")
 759   endif()
 760   status("    android tool:"  ANDROID_EXECUTABLE  THEN "${ANDROID_EXECUTABLE} (${ANDROID_TOOLS_Pkg_Desc})" ELSE NO)
 761   status("    ant:"           ANT_EXECUTABLE      THEN "${ANT_EXECUTABLE} (ver ${ANT_VERSION})"            ELSE NO)
 762 endif()
 763
 764 #YV
 765 status("")
 766 status("  GUI: ")
 767
 768 if (HAVE_QT)
 769   status("    QT 4.x:"            HAVE_QT        THEN YES ELSE NO)
 770   status("    QT OpenGL support:" HAVE_QT_OPENGL THEN YES ELSE NO)
 771 else()
 772   if(WIN32)
 773     status("    Win32 UI:" YES)
 774   else()
 775     if(APPLE)
 776       if(WITH_CARBON)
 777         status("    Carbon:" YES)
 778       else()
 779         status("    Cocoa:"  YES)
 780       endif()
 781     else()
 782       status("    GTK+ 2.x:" HAVE_GTK      THEN YES ELSE NO)
 783       status("    GThread :" HAVE_GTHREAD  THEN YES ELSE NO)
 784       status("    GtkGlExt:" HAVE_GTKGLEXT THEN YES ELSE NO)
 785     endif()
 786   endif()
 787 endif()
 788
 789 status("    OpenGL support:" HAVE_OPENGL THEN YES ELSE NO)
 790
 791 # media
 792 status("")
 793 status("  Media I/O: ")
 794 status("    ZLib:"      ZLIB_FOUND                         THEN "${ZLIB_FOUND} - ${ZLIB_LIBRARY}"   ELSE build)
 795 status("    JPEG:"      NOT WITH_JPEG OR JPEG_FOUND        THEN ${JPEG_FOUND}   ELSE build)
 796 status("    PNG:"       NOT WITH_PNG OR PNG_FOUND          THEN ${PNG_FOUND}    ELSE build)
 797 status("    TIFF:"      NOT WITH_TIFF OR TIFF_FOUND        THEN ${TIFF_FOUND}   ELSE build)
 798 status("    JPEG 2000:" NOT WITH_JASPER OR JASPER_FOUND    THEN ${JASPER_FOUND} ELSE build)
 799 status("    OpenEXR:"   WITH_OPENEXR AND OPENEXR_FOUND     THEN YES             ELSE NO)
 800
 801 status("    OpenNI:"    HAVE_OPENNI                        THEN YES             ELSE NO)
 802 status("    OpenNI PrimeSensor Modules:"
 803                         HAVE_OPENNI_PRIME_SENSOR_MODULE    THEN YES             ELSE NO)
 804 if(WIN32)
 805   status("    XIMEA:"     HAVE_XIMEA  THEN YES ELSE NO)
 806 endif()
 807
 808 # video
 809 status("")
 810 if(UNIX AND NOT APPLE)
 811   status("  Video I/O:")
 812   status("    DC1394 1.x:"     HAVE_DC1394         THEN YES ELSE NO)
 813   status("    DC1394 2.x:"     HAVE_DC1394_2       THEN YES ELSE NO)
 814   status("    FFMPEG:"         HAVE_FFMPEG         THEN YES ELSE NO)
 815   status("      codec:"        HAVE_FFMPEG_CODEC   THEN YES ELSE NO)
 816   status("      format:"       HAVE_FFMPEG_FORMAT  THEN YES ELSE NO)
 817   status("      util:"         HAVE_FFMPEG_UTIL    THEN YES ELSE NO)
 818   status("      swscale:"      HAVE_FFMPEG_SWSCALE THEN YES ELSE NO)
 819   status("      gentoo-style:" HAVE_GENTOO_FFMPEG  THEN YES ELSE NO)
 820   status("    GStreamer:"      HAVE_GSTREAMER      THEN YES ELSE NO)
 821   status("    UniCap:"         HAVE_UNICAP         THEN YES ELSE NO)
 822   status("    PvAPI:"          HAVE_PVAPI          THEN YES ELSE NO)
 823   status("    V4L/V4L2:"       HAVE_LIBV4L         THEN "Using libv4l" ELSE ${HAVE_CAMV4L}/${HAVE_CAMV4L2})
 824   status("    Xine:"           HAVE_XINE           THEN YES ELSE NO)
 825
 826   if(ANDROID)
 827     if(HAVE_opencv_androidcamera)
 828       status("    AndroidNativeCamera:" BUILD_ANDROID_CAMERA_WRAPPER THEN "YES, build for Android ${ANDROID_VERSION}" ELSE "YES, use prebuilt libraries")
 829     else()
 830       status("    AndroidNativeCamera:" "NO (native camera requires Android API level 8 or higher)")
 831     endif()
 832   endif()
 833 elseif(APPLE)
 834   if(NOT IOS)
 835     status("  Video I/O:"    WITH_QUICKTIME      THEN QuickTime ELSE QTKit)
 836   else()
 837     status("  Video I/O: AVFoundation")
 838   endif()
 839 elseif(WIN32)
 840   status("  Video I/O:"        HAVE_VIDEOINPUT     THEN DirectShow ELSE NO)
 841 endif()
 842
 843 # Other third-party libraries
 844 status("")
 845 status("  Other third-party libraries:")
 846
 847 if(WITH_IPP AND IPP_FOUND)
 848   status("    Use IPP:" "${IPP_LATEST_VERSION_STR} [${IPP_LATEST_VERSION_MAJOR}.${IPP_LATEST_VERSION_MINOR}.${IPP_LATEST_VERSION_BUILD}]")
 849   status("         at:" "${IPP_ROOT_DIR}")
 850 else()
 851   status("    Use IPP:"   WITH_IPP AND NOT IPP_FOUND THEN "IPP not found" ELSE NO)
 852 endif()
 853
 854 status("    Use TBB:"   HAVE_TBB   THEN YES ELSE NO)
 855 status("    Use Cuda:"  HAVE_CUDA  THEN YES ELSE NO)
 856 status("    Use Eigen:" HAVE_EIGEN THEN YES ELSE NO)
 857
 858 status("")
 859 status("  Python interpreter:"  PYTHON_EXECUTABLE        THEN "${PYTHON_EXECUTABLE} (ver ${PYTHON_VERSION_MAJOR_MINOR})" ELSE NO)
 860 # interfaces to other languages
 861 status("")
 862 status("  Interfaces:")
 863 status("    Python:"              HAVE_opencv_python THEN YES ELSE NO)
 864 status("    Python numpy:"        PYTHON_USE_NUMPY THEN YES ELSE "NO (Python wrappers will not be generated)")
 865 if(ANDROID)
 866   status("    Java:" HAVE_opencv_java THEN YES ELSE NO)
 867 endif()
 868
 869 # documentation
 870 status("")
 871 status("  Documentation:")
 872 status("    Sphinx:"              HAVE_SPHINX              THEN "${SPHINX_BUILD} (ver ${SPHINX_VERSION})" ELSE NO)
 873 status("    PdfLaTeX compiler:"   PDFLATEX_COMPILER        THEN "${PDFLATEX_COMPILER}" ELSE NO)
 874 if(BUILD_DOCS AND HAVE_SPHINX)
 875   status("    Build Documentation:" PDFLATEX_COMPILER    THEN YES ELSE "YES (only HTML without math expressions)")
 876 else()
 877   status("    Build Documentation:" NO)
 878 endif()
 879
 880 # samples and tests
 881 status("")
 882 status("  Tests and samples:")
 883 status("    Tests:"             BUILD_TESTS       THEN YES ELSE NO)
 884 status("    Performance tests:" BUILD_PERF_TESTS  THEN YES ELSE NO)
 885 status("    Examples:"          BUILD_EXAMPLES    THEN YES ELSE NO)
 886
 887 if(ANDROID)
 888   status("    Android tests:"    BUILD_TESTS AND CAN_BUILD_ANDROID_PROJECTS THEN YES ELSE NO)
 889   status("    Android examples:" BUILD_ANDROID_EXAMPLES                     THEN YES ELSE NO)
 890 endif()
 891
 892 #auxiliary
 893 status("")
 894 status("  Install path:" "${CMAKE_INSTALL_PREFIX}")
 895 status("")
 896 status("  cvconfig.h is in:" "${OPENCV_CONFIG_FILE_INCLUDE_DIR}")
 897 status("-----------------------------------------------------------------")
 898 status("")
 899
 900 # ----------------------------------------------------------------------------
 901 # Warn in the case of in-source build
 902 # ----------------------------------------------------------------------------
 903 if("${CMAKE_CURRENT_SOURCE_DIR}" STREQUAL "${CMAKE_CURRENT_BINARY_DIR}")
 904   message(WARNING "The source directory is the same as binary directory. \"make clean\" may damage the source tree")
 905 endif()
 906