CMakeLists.txt

   1 # ----------------------------------------------------------------------------
   2 #  Root CMake file for OpenCV
   3 #
   4 #    From the off-tree build directory, invoke:
   5 #      $ cmake <PATH_TO_OPENCV_ROOT>
   6 #
   7 #
   8 #   - OCT-2008: Initial version <joseluisblancoc@gmail.com>
   9 #
  10 # ----------------------------------------------------------------------------
  11
  12 set(CMAKE_ALLOW_LOOSE_LOOP_CONSTRUCTS true)
  13
  14 # --------------------------------------------------------------
  15 # Indicate CMake 2.7 and above that we don't want to mix relative
  16 #  and absolute paths in linker lib lists.
  17 # Run "cmake --help-policy CMP0003" for more information.
  18 # --------------------------------------------------------------
  19 if(COMMAND cmake_policy)
  20   cmake_policy(SET CMP0003 NEW)
  21 endif()
  22
  23 # Following block can broke build in case of cross-compilng
  24 # but CMAKE_CROSSCOMPILING variable will be set only on project(OpenCV) command
  25 # so we will try to detect crosscompiling by presense of CMAKE_TOOLCHAIN_FILE
  26 if(NOT CMAKE_TOOLCHAIN_FILE)
  27   # Add these standard paths to the search paths for FIND_LIBRARY
  28   # to find libraries from these locations first
  29   if(UNIX)
  30     set(CMAKE_LIBRARY_PATH ${CMAKE_LIBRARY_PATH} /lib /usr/lib)
  31   endif()
  32
  33   # it _must_ go before project(OpenCV) in order to work
  34   if(WIN32)
  35     set(CMAKE_INSTALL_PREFIX "${CMAKE_BINARY_DIR}/install" CACHE PATH "Installation Directory")
  36   else()
  37     set(CMAKE_INSTALL_PREFIX "/usr/local" CACHE PATH "Installation Directory")
  38   endif()
  39
  40   if(MSVC)
  41     set(CMAKE_USE_RELATIVE_PATHS ON CACHE INTERNAL "" FORCE)
  42   endif()
  43 else(NOT CMAKE_TOOLCHAIN_FILE)
  44   #Android: set output folder to ${CMAKE_BINARY_DIR}
  45   set( LIBRARY_OUTPUT_PATH_ROOT ${CMAKE_BINARY_DIR} CACHE PATH "root for library output, set this to change where android libs are compiled to" )
  46 endif(NOT CMAKE_TOOLCHAIN_FILE)
  47
  48 # --------------------------------------------------------------
  49 # Top level OpenCV project
  50 # --------------------------------------------------------------
  51 if(NOT IOS)
  52   cmake_minimum_required(VERSION 2.6.3)
  53 else()
  54   cmake_minimum_required(VERSION 2.8)
  55 endif()
  56
  57 project(OpenCV)
  58
  59 set(CMAKE_CONFIGURATION_TYPES "Debug;Release" CACHE STRING "Configs" FORCE)
  60 if(DEFINED CMAKE_BUILD_TYPE AND CMAKE_VERSION VERSION_GREATER "2.8")
  61   set_property( CACHE CMAKE_BUILD_TYPE PROPERTY STRINGS ${CMAKE_CONFIGURATION_TYPES} )
  62 endif()
  63
  64 set(CMAKE_C_FLAGS_MINSIZEREL "" CACHE INTERNAL "" FORCE)
  65 set(CMAKE_C_FLAGS_RELWITHDEBINFO "" CACHE INTERNAL "" FORCE)
  66 set(CMAKE_CXX_FLAGS_MINSIZEREL "" CACHE INTERNAL "" FORCE)
  67 set(CMAKE_CXX_FLAGS_RELWITHDEBINFO "" CACHE INTERNAL "" FORCE)
  68 set(CMAKE_EXE_LINKER_FLAGS_MINSIZEREL "" CACHE INTERNAL "" FORCE)
  69 set(CMAKE_EXE_LINKER_FLAGS_RELWITHDEBINFO "" CACHE INTERNAL "" FORCE)
  70 set(CMAKE_MODULE_LINKER_FLAGS_MINSIZEREL "" CACHE INTERNAL "" FORCE)
  71 set(CMAKE_MODULE_LINKER_FLAGS_RELWITHDEBINFO "" CACHE INTERNAL "" FORCE)
  72 set(CMAKE_SHARED_LINKER_FLAGS_MINSIZEREL "" CACHE INTERNAL "" FORCE)
  73 set(CMAKE_SHARED_LINKER_FLAGS_RELWITHDEBINFO "" CACHE INTERNAL "" FORCE)
  74
  75 set(CMAKE_VERBOSE OFF CACHE BOOL "Verbose mode")
  76 if(CMAKE_VERBOSE)
  77     set(CMAKE_VERBOSE_MAKEFILE 1)
  78 endif()
  79
  80 include(cmake/OpenCVUtils.cmake REQUIRED)
  81
  82 # ----------------------------------------------------------------------------
  83 # Detect compiler and target platform architecture
  84 # ----------------------------------------------------------------------------
  85 include(cmake/OpenCVDetectCXXCompiler.cmake REQUIRED)
  86
  87
  88 # ----------------------------------------------------------------------------
  89 # OpenCV cmake options
  90 # ----------------------------------------------------------------------------
  91
  92 # Optional 3rd party components
  93 # ===================================================
  94 OCV_OPTION(WITH_1394           "Include IEEE1394 support"                    ON   IF (UNIX AND NOT ANDROID AND NOT IOS) )
  95 OCV_OPTION(WITH_AVFOUNDATION   "Use AVFoundation for Video I/O"              ON   IF IOS)
  96 OCV_OPTION(WITH_CARBON         "Use Carbon for UI instead of Cocoa"          OFF  IF APPLE )
  97 OCV_OPTION(WITH_CUBLAS         "Include NVidia Cuda Basic Linear Algebra Subprograms (BLAS) library support" OFF IF (CMAKE_VERSION VERSION_GREATER "2.8" AND NOT ANDROID AND NOT IOS) )
  98 OCV_OPTION(WITH_CUDA           "Include NVidia Cuda Runtime support"         ON   IF (CMAKE_VERSION VERSION_GREATER "2.8" AND NOT ANDROID AND NOT IOS) )
  99 OCV_OPTION(WITH_CUFFT          "Include NVidia Cuda Fast Fourier Transform (FFT) library support"            ON  IF (CMAKE_VERSION VERSION_GREATER "2.8" AND NOT ANDROID AND NOT IOS) )
 100 OCV_OPTION(WITH_EIGEN          "Include Eigen2/Eigen3 support"               ON)
 101 OCV_OPTION(WITH_FFMPEG         "Include FFMPEG support"                      ON   IF (UNIX AND NOT ANDROID AND NOT IOS) )
 102 OCV_OPTION(WITH_GSTREAMER      "Include Gstreamer support"                   ON   IF (UNIX AND NOT APPLE AND NOT ANDROID AND NOT IOS) )
 103 OCV_OPTION(WITH_GTK            "Include GTK support"                         ON   IF (UNIX AND NOT APPLE AND NOT ANDROID AND NOT IOS) )
 104 OCV_OPTION(WITH_IPP            "Include Intel IPP support"                   OFF  IF (MSVC OR X86 OR X86_64) )
 105 OCV_OPTION(WITH_JASPER         "Include JPEG2K support"                      ON   IF (NOT IOS) )
 106 OCV_OPTION(WITH_JPEG           "Include JPEG support"                        ON   IF (NOT IOS) )
 107 OCV_OPTION(WITH_OPENEXR        "Include ILM support via OpenEXR"             ON   IF (NOT IOS) )
 108 OCV_OPTION(WITH_OPENGL         "Include OpenGL support"                      OFF  IF (NOT ANDROID AND NOT IOS) )
 109 OCV_OPTION(WITH_OPENNI         "Include OpenNI support"                      OFF  IF (NOT ANDROID AND NOT IOS) )
 110 OCV_OPTION(WITH_PNG            "Include PNG support"                         ON   IF (NOT IOS) )
 111 OCV_OPTION(WITH_PVAPI          "Include Prosilica GigE support"              ON   IF (UNIX AND NOT ANDROID AND NOT IOS) )
 112 OCV_OPTION(WITH_QT             "Build with Qt Backend support"               OFF  IF (NOT ANDROID AND NOT IOS) )
 113 OCV_OPTION(WITH_QUICKTIME      "Use QuickTime for Video I/O insted of QTKit" OFF  IF APPLE )
 114 OCV_OPTION(WITH_TBB            "Include Intel TBB support"                   OFF  IF (NOT IOS) )
 115 OCV_OPTION(WITH_TIFF           "Include TIFF support"                        ON   IF (NOT IOS) )
 116 OCV_OPTION(WITH_UNICAP         "Include Unicap support (GPL)"                OFF  IF (UNIX AND NOT APPLE AND NOT ANDROID AND NOT IOS) )
 117 OCV_OPTION(WITH_V4L            "Include Video 4 Linux support"               ON   IF (UNIX AND NOT APPLE AND NOT ANDROID AND NOT IOS) )
 118 OCV_OPTION(WITH_VIDEOINPUT     "Build HighGUI with DirectShow support"       ON   IF WIN32 )
 119 OCV_OPTION(WITH_XIMEA          "Include XIMEA cameras support"               OFF  IF WIN32 )
 120 OCV_OPTION(WITH_XINE           "Include Xine support (GPL)"                  OFF  IF (UNIX AND NOT APPLE AND NOT ANDROID AND NOT IOS) )
 121
 122 # OpenCV build components
 123 # ===================================================
 124 if(ANDROID OR IOS)
 125     OCV_OPTION(BUILD_SHARED_LIBS "Build shared libraries (.dll/.so) instead 6of static ones (.lib/.a)" OFF )
 126 else()
 127     OCV_OPTION(BUILD_SHARED_LIBS "Build shared libraries (.dll/.so) instead of static ones (.lib/.a)" ON )
 128 endif()
 129 OCV_OPTION(BUILD_ANDROID_EXAMPLES   "Build examples for Android platform"         ON  IF ANDROID )
 130 OCV_OPTION(BUILD_DOCS               "Create build rules for OpenCV Documentation" ON )
 131 OCV_OPTION(BUILD_EXAMPLES           "Build all examples"                          OFF )
 132 OCV_OPTION(BUILD_PACKAGE            "Enables 'make package_source' command"       ON )
 133 OCV_OPTION(BUILD_PERF_TESTS         "Build performance tests"                     ON  IF (NOT IOS) )
 134 OCV_OPTION(BUILD_TESTS              "Build accuracy & regression tests"           ON  IF (NOT IOS) )
 135 OCV_OPTION(BUILD_WITH_DEBUG_INFO    "Include debug info into debug libs"          ON )
 136 OCV_OPTION(BUILD_WITH_STATIC_CRT    "Enables use of staticaly linked CRT for staticaly linked OpenCV" ON IF MSVC )
 137
 138 if(WIN32 OR ANDROID)
 139     set(OPENCV_BUILD_3RDPARTY_LIBS TRUE  CACHE INTERNAL "Build 3rd party libraries")
 140 else()
 141     # Build 3rdparty libraries under unix
 142     set(OPENCV_BUILD_3RDPARTY_LIBS FALSE CACHE BOOL "Build 3rd party libraries")
 143 endif()
 144
 145 # OpenCV installation options
 146 # ===================================================
 147 OCV_OPTION(INSTALL_C_EXAMPLES       "Install C examples"        OFF )
 148 OCV_OPTION(INSTALL_PYTHON_EXAMPLES  "Install Python examples"   OFF )
 149 OCV_OPTION(INSTALL_ANDROID_EXAMPLES "Install Android examples"  OFF  IF ANDROID )
 150 OCV_OPTION(INSTALL_TO_MANGLED_PATHS "Enables mangled install paths, that help with side by side installs." OFF IF (UNIX AND NOT ANDROID AND NOT IOS AND BUILD_SHARED_LIBS) )
 151
 152 # OpenCV build options
 153 # ===================================================
 154 OCV_OPTION(ENABLE_PRECOMPILED_HEADERS "Use precompiled headers"                                  ON   IF (NOT IOS) )
 155 OCV_OPTION(ENABLE_SOLUTION_FOLDERS    "Solution folder in Visual Studio or in other IDEs"        OFF  IF (CMAKE_VERSION VERSION_GREATER "2.8.0") )
 156 OCV_OPTION(ENABLE_PROFILING           "Enable profiling in the GCC compiler (Add flags: -g -pg)" OFF  IF CMAKE_COMPILER_IS_GNUCXX )
 157 OCV_OPTION(ENABLE_OMIT_FRAME_POINTER  "Enable -fomit-frame-pointer for GCC"                      ON   IF CMAKE_COMPILER_IS_GNUCXX )
 158 OCV_OPTION(ENABLE_POWERPC             "Enable PowerPC for GCC"                                   ON   IF (CMAKE_COMPILER_IS_GNUCXX AND CMAKE_SYSTEM_PROCESSOR MATCHES powerpc.*) )
 159 OCV_OPTION(ENABLE_FAST_MATH           "Enable -ffast-math (not recommended for GCC 4.6.x)"       OFF  IF (CMAKE_COMPILER_IS_GNUCXX AND (X86 OR X86_64)) )
 160 OCV_OPTION(ENABLE_SSE                 "Enable SSE instructions"                                  ON   IF (MSVC OR CMAKE_COMPILER_IS_GNUCXX AND (X86 OR X86_64)) )
 161 OCV_OPTION(ENABLE_SSE2                "Enable SSE2 instructions"                                 ON   IF (MSVC OR CMAKE_COMPILER_IS_GNUCXX AND (X86 OR X86_64)) )
 162 OCV_OPTION(ENABLE_SSE3                "Enable SSE3 instructions"                                 OFF  IF (CV_ICC OR CMAKE_COMPILER_IS_GNUCXX AND (X86 OR X86_64)) )
 163 OCV_OPTION(ENABLE_SSSE3               "Enable SSSE3 instructions"                                OFF  IF (CMAKE_COMPILER_IS_GNUCXX AND (X86 OR X86_64)) )
 164 OCV_OPTION(ENABLE_SSE41               "Enable SSE4.1 instructions"                               OFF  IF (CV_ICC OR CMAKE_COMPILER_IS_GNUCXX AND (X86 OR X86_64)) )
 165 OCV_OPTION(ENABLE_SSE42               "Enable SSE4.2 instructions"                               OFF  IF (CMAKE_COMPILER_IS_GNUCXX AND (X86 OR X86_64)) )
 166 OCV_OPTION(OPENCV_WARNINGS_ARE_ERRORS "Treat warnings as errors"                                 OFF )
 167
 168 include(cmake/OpenCVLegacyOptions.cmake OPTIONAL)
 169
 170 # ----------------------------------------------------------------------------
 171 #  Get actual OpenCV version number from sources
 172 # ----------------------------------------------------------------------------
 173 include(cmake/OpenCVVersion.cmake REQUIRED)
 174
 175
 176 # ----------------------------------------------------------------------------
 177 #  Build & install layouts
 178 # ----------------------------------------------------------------------------
 179
 180 # Save libs and executables in the same place
 181 set(LIBRARY_OUTPUT_PATH "${CMAKE_BINARY_DIR}/lib" CACHE PATH "Output directory for libraries" )
 182 set(EXECUTABLE_OUTPUT_PATH "${CMAKE_BINARY_DIR}/bin" CACHE PATH "Output directory for applications" )
 183
 184 if(ANDROID OR WIN32)
 185     set(OPENCV_DOC_INSTALL_PATH doc)
 186 elseif(INSTALL_TO_MANGLED_PATHS)
 187     set(OPENCV_DOC_INSTALL_PATH share/OpenCV-${OPENCV_VERSION}/doc)
 188 else()
 189     set(OPENCV_DOC_INSTALL_PATH share/OpenCV/doc)
 190 endif()
 191
 192 if(ANDROID)
 193     set(OPENCV_LIB_INSTALL_PATH libs/${ANDROID_NDK_ABI_NAME})
 194 else()
 195     set(OPENCV_LIB_INSTALL_PATH lib${LIB_SUFFIX})
 196 endif()
 197
 198 set(CMAKE_INSTALL_RPATH "${CMAKE_INSTALL_PREFIX}/${OPENCV_LIB_INSTALL_PATH}")
 199 set(CMAKE_INSTALL_RPATH_USE_LINK_PATH TRUE)
 200
 201 set(OPENCV_INCLUDE_PREFIX include)
 202 if(INSTALL_TO_MANGLED_PATHS)
 203   set(OPENCV_INCLUDE_PREFIX include/opencv-${OPENCV_VERSION})
 204 endif()
 205
 206 if(WIN32)
 207   # Postfix of DLLs:
 208   set(OPENCV_DLLVERSION "${OPENCV_VERSION_MAJOR}${OPENCV_VERSION_MINOR}${OPENCV_VERSION_PATCH}")
 209   set(OPENCV_DEBUG_POSTFIX d)
 210 else()
 211   # Postfix of so's:
 212   set(OPENCV_DLLVERSION "")
 213   set(OPENCV_DEBUG_POSTFIX "")
 214 endif()
 215
 216 if(DEFINED CMAKE_DEBUG_POSTFIX)
 217   set(OPENCV_DEBUG_POSTFIX "${CMAKE_DEBUG_POSTFIX}")
 218 endif()
 219
 220
 221 # ----------------------------------------------------------------------------
 222 #  Path for build/platform -specific headers
 223 # ----------------------------------------------------------------------------
 224 set(OPENCV_CONFIG_FILE_INCLUDE_DIR "${CMAKE_BINARY_DIR}/" CACHE PATH "Where to create the platform-dependant cvconfig.h")
 225 add_definitions(-DHAVE_CVCONFIG_H)
 226 include_directories(${OPENCV_CONFIG_FILE_INCLUDE_DIR})
 227
 228
 229 # ----------------------------------------------------------------------------
 230 # Use statically or dynamically linked CRT?
 231 # Default: dynamic
 232 # ----------------------------------------------------------------------------
 233 if(MSVC)
 234   include(cmake/OpenCVCRTLinkage.cmake REQUIRED)
 235 endif(MSVC)
 236
 237
 238 # ----------------------------------------------------------------------------
 239 #  Autodetect if we are in a SVN repository
 240 # ----------------------------------------------------------------------------
 241 find_host_program(SVNVERSION_PATH svnversion)
 242 mark_as_advanced(force SVNVERSION_PATH)
 243 if(SVNVERSION_PATH)
 244     message(STATUS "Extracting svn version, please wait...")
 245     execute_process(COMMAND ${SVNVERSION_PATH} -n ${OpenCV_SOURCE_DIR} OUTPUT_VARIABLE SVNVERSION_RESULT)
 246
 247     if(SVNVERSION_RESULT MATCHES "exported")
 248         # This is NOT a svn repository:
 249         set(OPENCV_SVNVERSION "")
 250         message(STATUS "SVNVERSION: exported")
 251     else()
 252         set(OPENCV_SVNVERSION " svn:${SVNVERSION_RESULT}")
 253         message(STATUS "SVNVERSION: ${OPENCV_SVNVERSION}")
 254     endif()
 255 else()
 256     # We don't have svnversion:
 257     set(OPENCV_SVNVERSION "")
 258 endif()
 259
 260
 261 # ----------------------------------------------------------------------------
 262 #       CHECK FOR SYSTEM LIBRARIES, OPTIONS, ETC..
 263 # ----------------------------------------------------------------------------
 264 if(UNIX)
 265   include(cmake/OpenCVFindPkgConfig.cmake OPTIONAL)
 266   include(CheckFunctionExists)
 267   include(CheckIncludeFile)
 268 endif()
 269
 270 include(cmake/OpenCVPCHSupport.cmake REQUIRED)
 271 include(cmake/OpenCVModule.cmake REQUIRED)
 272
 273 if(ANDROID)
 274   include(cmake/OpenCVAndroidProject.cmake REQUIRED)
 275 endif()
 276
 277
 278 # ----------------------------------------------------------------------------
 279 #  Detect 3rd-party tools and libraries
 280 # ----------------------------------------------------------------------------
 281
 282 #Graphic libraries
 283 set(HAVE_OPENGL 0)
 284 if(UNIX)
 285     if(NOT APPLE)
 286       if(WITH_GTK)
 287         CHECK_MODULE(gtk+-2.0 HAVE_GTK)
 288         CHECK_MODULE(gthread-2.0 HAVE_GTHREAD)
 289         if(WITH_OPENGL)
 290             CHECK_MODULE(gtkglext-1.0 HAVE_GTKGLEXT)
 291             if(HAVE_GTKGLEXT)
 292                 find_package(OpenGL QUIET)
 293                 if(OPENGL_FOUND)
 294                     set(HAVE_OPENGL 1)
 295                     set(OPENCV_LINKER_LIBS ${OPENCV_LINKER_LIBS} ${OPENGL_LIBRARIES})
 296                     include_directories(${OPENGL_INCLUDE_DIR})
 297                 endif()
 298             endif()
 299         endif()
 300       else()
 301         set(HAVE_GTK FALSE)
 302         set(HAVE_GTHREAD FALSE)
 303       endif()
 304       if(WITH_GSTREAMER)
 305         CHECK_MODULE(gstreamer-base-0.10 HAVE_GSTREAMER)
 306         CHECK_MODULE(gstreamer-app-0.10 HAVE_GSTREAMER)
 307         CHECK_MODULE(gstreamer-video-0.10 HAVE_GSTREAMER)
 308       else()
 309         set(HAVE_GSTREAMER FALSE)
 310       endif()
 311     endif()
 312
 313     if(WITH_UNICAP)
 314       CHECK_MODULE(libunicap HAVE_UNICAP_)
 315       CHECK_MODULE(libucil HAVE_UNICAP_UCIL)
 316       if(HAVE_UNICAP_ AND HAVE_UNICAP_UCIL)
 317         set(HAVE_UNICAP 1)
 318       endif()
 319     else()
 320       set(HAVE_UNICAP FALSE)
 321     endif()
 322
 323     if(WITH_PVAPI)
 324       find_path(PVAPI_INCLUDE_PATH "PvApi.h"
 325                 PATHS "/usr/local/include" "/usr/include"
 326                 DOC "The path to PvAPI header")
 327       if(PVAPI_INCLUDE_PATH)
 328         set(HAVE_PVAPI 1)
 329       endif()
 330     endif()
 331
 332     set(HAVE_FFMPEG 0)
 333     if(WITH_FFMPEG)
 334       CHECK_MODULE(libavcodec HAVE_FFMPEG_CODEC)
 335       CHECK_MODULE(libavformat HAVE_FFMPEG_FORMAT)
 336       CHECK_MODULE(libavutil HAVE_FFMPEG_UTIL)
 337       CHECK_MODULE(libswscale HAVE_FFMPEG_SWSCALE)
 338       CHECK_INCLUDE_FILE(libavformat/avformat.h HAVE_GENTOO_FFMPEG)
 339       CHECK_INCLUDE_FILE(ffmpeg/avformat.h HAVE_FFMPEG_FFMPEG)
 340       if(NOT HAVE_GENTOO_FFMPEG AND NOT HAVE_FFMPEG_FFMPEG)
 341         if(EXISTS /usr/include/ffmpeg/libavformat/avformat.h OR HAVE_FFMPEG_SWSCALE)
 342           set(HAVE_GENTOO_FFMPEG 1)
 343         endif()
 344       endif()
 345       if(HAVE_FFMPEG_CODEC AND HAVE_FFMPEG_FORMAT AND HAVE_FFMPEG_UTIL)
 346         if(HAVE_FFMPEG_SWSCALE OR NOT HAVE_GENTOO_FFMPEG)
 347             set(HAVE_FFMPEG 1)
 348         endif()
 349       endif()
 350       # Find the bzip2 library because it is required on some systems
 351       FIND_LIBRARY(BZIP2_LIBRARIES NAMES bz2 bzip2)
 352       if(NOT BZIP2_LIBRARIES)
 353         # Do an other trial
 354         FIND_FILE(BZIP2_LIBRARIES NAMES libbz2.so.1 PATHS /lib)
 355       endif()
 356     endif()
 357
 358     if(WITH_1394)
 359       CHECK_MODULE(libdc1394-2 HAVE_DC1394_2)
 360       if(NOT HAVE_DC1394_2)
 361         CHECK_MODULE(libdc1394 HAVE_DC1394)
 362       endif()
 363     else()
 364       set(HAVE_DC1394_2 FALSE)
 365       set(HAVE_DC1394 FALSE)
 366     endif()
 367
 368     if(NOT APPLE)
 369         CHECK_INCLUDE_FILE(alloca.h HAVE_ALLOCA_H)
 370         CHECK_FUNCTION_EXISTS(alloca HAVE_ALLOCA)
 371         CHECK_INCLUDE_FILE(unistd.h HAVE_UNISTD_H)
 372         CHECK_INCLUDE_FILE(pthread.h HAVE_LIBPTHREAD)
 373
 374         if(WITH_XINE)
 375             CHECK_MODULE(libxine HAVE_XINE)
 376         else()
 377             set(HAVE_XINE FALSE)
 378         endif()
 379         if(WITH_V4L)
 380             CHECK_MODULE(libv4l1 HAVE_LIBV4L)
 381             CHECK_INCLUDE_FILE(linux/videodev.h HAVE_CAMV4L)
 382             CHECK_INCLUDE_FILE(linux/videodev2.h HAVE_CAMV4L2)
 383         else()
 384             set(HAVE_LIBV4L FALSE)
 385             set(HAVE_CAMV4L FALSE)
 386             set(HAVE_CAMV4L2 FALSE)
 387         endif()
 388
 389         if(ANDROID)
 390             set(OPENCV_LINKER_LIBS dl m log)
 391         elseif(${CMAKE_SYSTEM_NAME} MATCHES "FreeBSD" OR ${CMAKE_SYSTEM_NAME} MATCHES "NetBSD")
 392             set(OPENCV_LINKER_LIBS m pthread)
 393         else()
 394             set(OPENCV_LINKER_LIBS dl m pthread rt)
 395         endif()
 396     else()
 397         add_definitions(-DHAVE_ALLOCA -DHAVE_ALLOCA_H -DHAVE_LIBPTHREAD -DHAVE_UNISTD_H)
 398     endif()
 399 endif()
 400 if (UNIX OR WIN32)
 401     if(NOT OPENCV_BUILD_3RDPARTY_LIBS)
 402         message(STATUS "NOT OPENCV_BUILD_3RDPARTY_LIBS **************************************************")
 403         include(FindZLIB)
 404         if(WITH_PNG)
 405             include(FindPNG)
 406             if(PNG_FOUND)
 407                 CHECK_INCLUDE_FILE(${PNG_PNG_INCLUDE_DIR}/png.h HAVE_PNG_H)
 408                 CHECK_INCLUDE_FILE(${PNG_PNG_INCLUDE_DIR}/libpng/png.h HAVE_LIBPNG_PNG_H)
 409             endif()
 410         else()
 411             set(PNG_FOUND FALSE)
 412         endif()
 413         if(WITH_TIFF)
 414             include(FindTIFF)
 415         else()
 416             set(TIFF_FOUND FALSE)
 417         endif()
 418         if(WITH_JASPER)
 419             include(FindJasper)
 420         else()
 421             set(JASPER_FOUND FALSE)
 422         endif()
 423         if(WITH_JPEG)
 424             include(FindJPEG)
 425         else()
 426             set(JPEG_FOUND FALSE)
 427         endif()
 428     endif()
 429 endif()
 430
 431 if(WITH_PNG AND NOT PNG_FOUND)
 432     set(PNG_LIBRARIES libpng)
 433 endif()
 434
 435 if(WITH_JPEG AND NOT JPEG_FOUND)
 436     set(JPEG_LIBRARIES libjpeg)
 437 endif()
 438
 439 if(WITH_TIFF AND NOT TIFF_FOUND)
 440     set(TIFF_LIBRARIES libtiff)
 441 endif()
 442
 443 if(WITH_JASPER AND NOT JASPER_FOUND)
 444     set(JASPER_LIBRARIES libjasper)
 445 endif()
 446
 447 if(NOT ZLIB_FOUND)
 448     set(ZLIB_LIBRARY zlib)
 449 endif()
 450
 451 #message(STATUS "Graphic libraries: ${PNG_LIBRARIES} ${JPEG_LIBRARIES} ${TIFF_LIBRARIES} ${JASPER_LIBRARIES}")
 452
 453 if(WITH_OPENEXR)
 454   include(cmake/OpenCVFindOpenEXR.cmake)
 455 endif()
 456
 457 #################### LATEX for dpf documentation ##################
 458 if(BUILD_DOCS)
 459   include(cmake/OpenCVFindLATEX.cmake REQUIRED)
 460 endif()
 461
 462 ########################## Python Support #########################
 463 include(cmake/OpenCVDetectPython.cmake REQUIRED)
 464
 465 ########################### Java Support ##########################
 466 # current implementation of Java wrappers generator requires python at build time
 467 if((NOT DEFINED BUILD_opencv_java OR BUILD_opencv_java) AND PYTHON_EXECUTABLE)
 468   if(ANDROID)
 469     include(cmake/OpenCVDetectAndroidSDK.cmake REQUIRED)
 470   endif()
 471   include(cmake/OpenCVDetectApacheAnt.cmake REQUIRED)
 472
 473   if(ANDROID_EXECUTABLE AND ANT_EXECUTABLE AND (ANT_VERSION VERSION_GREATER 1.7) AND (ANDROID_SDK_TARGET_LEVEL GREATER 7))
 474     SET(CAN_BUILD_ANDROID_PROJECTS TRUE)
 475   else()
 476     SET(CAN_BUILD_ANDROID_PROJECTS FALSE)
 477   endif()
 478 endif()
 479
 480 if(BUILD_ANDROID_EXAMPLES AND NOT CAN_BUILD_ANDROID_PROJECTS)
 481   if(HAVE_opencv_java)
 482     message(WARNING "Android examples are chosen for build, but required SDK tools are not found.")
 483   endif()
 484   unset(BUILD_ANDROID_EXAMPLES CACHE)
 485 endif()
 486
 487 ############################### QT ################################
 488 set(HAVE_QT 0)
 489 set(HAVE_QT_OPENGL 0)
 490
 491 if(WITH_QT)
 492   find_package(Qt4)
 493   if(QT4_FOUND)
 494     set(HAVE_QT 1)
 495     add_definitions(-DHAVE_QT) #We need to define te macro this way, using cvconfig.h.cmake does not work
 496
 497     if(WITH_OPENGL)
 498       find_package (OpenGL QUIET)
 499       if(QT_QTOPENGL_FOUND AND OPENGL_FOUND)
 500         set(HAVE_OPENGL 1)
 501         set(HAVE_QT_OPENGL 1)
 502         add_definitions(-DHAVE_QT_OPENGL)
 503         set(OPENCV_LINKER_LIBS ${OPENCV_LINKER_LIBS} ${OPENGL_LIBRARIES})
 504       endif()
 505     endif()
 506   endif()
 507 endif()
 508
 509 ############################### TBB ################################
 510 if(WITH_TBB)
 511   include(cmake/OpenCVDetectTBB.cmake REQUIRED)
 512 endif()
 513
 514 ############################ Intel IPP #############################
 515 set(IPP_FOUND)
 516
 517 if(WITH_IPP)
 518   include(cmake/OpenCVFindIPP.cmake)
 519 endif()
 520
 521 if(IPP_FOUND)
 522   add_definitions(-DHAVE_IPP)
 523   include_directories(${IPP_INCLUDE_DIRS})
 524   link_directories(${IPP_LIBRARY_DIRS})
 525   set(OPENCV_LINKER_LIBS ${OPENCV_LINKER_LIBS} ${IPP_LIBRARIES})
 526 endif()
 527
 528 ############################### CUDA ################################
 529 if(WITH_CUDA)
 530   include(cmake/OpenCVDetectCUDA.cmake REQUIRED)
 531 endif()
 532
 533 ############################### OpenNI ################################
 534 set(HAVE_OPENNI FALSE)
 535 set(HAVE_OPENNI_PRIME_SENSOR_MODULE FALSE)
 536
 537 if(WITH_OPENNI)
 538   include(cmake/OpenCVFindOpenNI.cmake)
 539 endif()
 540
 541 ############################### XIMEA ################################
 542 set(HAVE_XIMEA FALSE)
 543
 544 if(WITH_XIMEA)
 545   include(cmake/OpenCVFindXimea.cmake)
 546 endif()
 547
 548 if(XIMEA_FOUND)
 549   set(HAVE_XIMEA TRUE)
 550 endif()
 551
 552 ############################## Eigen ##############################
 553 if(WITH_EIGEN)
 554   find_path(EIGEN_INCLUDE_PATH "Eigen/Core"
 555             PATHS "/usr/local/include/eigen2" "/opt/include/eigen2" "/usr/include/eigen2"
 556                   "/usr/local/include/eigen3" "/opt/include/eigen3" "/usr/include/eigen3"
 557             DOC "The path to Eigen2/Eigen3 headers")
 558   if(EIGEN_INCLUDE_PATH)
 559     include_directories(${EIGEN_INCLUDE_PATH})
 560     set(HAVE_EIGEN 1)
 561   endif()
 562 endif()
 563
 564 ################## Extra HighGUI libs on Windows ###################
 565 if(WIN32)
 566   set(HIGHGUI_LIBRARIES ${HIGHGUI_LIBRARIES} comctl32 gdi32 ole32)
 567
 568   if(WITH_VIDEOINPUT)
 569     set(HAVE_VIDEOINPUT 1)
 570   endif()
 571
 572   if(MSVC)
 573     set(HIGHGUI_LIBRARIES ${HIGHGUI_LIBRARIES} vfw32)
 574   endif()
 575
 576   if(MINGW)
 577     if(MINGW64)
 578       set(HIGHGUI_LIBRARIES ${HIGHGUI_LIBRARIES} msvfw32 avifil32 avicap32 winmm)
 579     else()
 580       set(HIGHGUI_LIBRARIES ${HIGHGUI_LIBRARIES} vfw32 winmm)
 581     endif()
 582   endif()
 583
 584   if(WITH_OPENGL AND NOT HAVE_QT_OPENGL)
 585     find_package(OpenGL QUIET)
 586
 587     if(OPENGL_FOUND)
 588       set(HAVE_OPENGL 1)
 589       set(OPENCV_LINKER_LIBS ${OPENCV_LINKER_LIBS} ${OPENGL_LIBRARIES})
 590       include_directories(${OPENGL_INCLUDE_DIR})
 591     endif()
 592   endif()
 593 endif()
 594
 595 # ----------------------------------------------------------------------------
 596 # OpenCV compiler and linker options
 597 # ----------------------------------------------------------------------------
 598 include(cmake/OpenCVCompilerOptions.cmake REQUIRED)
 599
 600 # In case of Makefiles if the user does not setup CMAKE_BUILD_TYPE, assume it's Release:
 601 if(CMAKE_GENERATOR MATCHES "Makefiles" AND "${CMAKE_BUILD_TYPE}" STREQUAL "")
 602   set(CMAKE_BUILD_TYPE Release)
 603 endif()
 604
 605 # ----------------------------------------------------------------------------
 606 # Solution folders:
 607 # ----------------------------------------------------------------------------
 608 if(ENABLE_SOLUTION_FOLDERS)
 609   set_property(GLOBAL PROPERTY USE_FOLDERS ON)
 610   set_property(GLOBAL PROPERTY PREDEFINED_TARGETS_FOLDER "CMakeTargets")
 611 endif()
 612
 613 # Extra OpenCV targets: uninstall, package_source, perf, etc.
 614 include(cmake/OpenCVExtraTargets.cmake REQUIRED)
 615
 616 # ----------------------------------------------------------------------------
 617 # Process subdirectories
 618 # ----------------------------------------------------------------------------
 619
 620 # opencv.hpp and legacy headers
 621 add_subdirectory(include)
 622
 623 # OpenCV modules
 624 add_subdirectory(modules)
 625
 626 # Generate targets for documentation
 627 add_subdirectory(doc)
 628
 629 # various data that is used by cv libraries and/or demo applications.
 630 add_subdirectory(data)
 631
 632 # 3rdparty libraries on-board
 633 add_subdirectory(3rdparty)
 634
 635 # extra applications
 636 add_subdirectory(apps)
 637
 638 # examples
 639 if(BUILD_EXAMPLES OR BUILD_ANDROID_EXAMPLES OR INSTALL_PYTHON_EXAMPLES)
 640   add_subdirectory(samples)
 641 endif()
 642
 643 # ----------------------------------------------------------------------------
 644 # Finalization: generate configuration-based files
 645 # ----------------------------------------------------------------------------
 646 ocv_track_build_dependencies()
 647
 648 # Generate platform-dependent and configuration-dependent headers
 649 include(cmake/OpenCVGenHeaders.cmake REQUIRED)
 650
 651 # Generate opencv.pc for pkg-config command
 652 include(cmake/OpenCVGenPkgconfig.cmake REQUIRED)
 653
 654 # Generate OpenCV.mk for ndk-build (Android build tool)
 655 include(cmake/OpenCVGenAndroidMK.cmake REQUIRED)
 656
 657 # Generate OpenCVСonfig.cmake and OpenCVConfig-version.cmake for cmake projects
 658 include(cmake/OpenCVGenConfig.cmake REQUIRED)
 659
 660 # ----------------------------------------------------------------------------
 661 # Summary:
 662 # ----------------------------------------------------------------------------
 663 status("")
 664 status("General configuration for opencv ${OPENCV_VERSION} =====================================")
 665 status("")
 666 status("    Built as dynamic libs?:" BUILD_SHARED_LIBS THEN YES ELSE NO)
 667 status("    C++ Compiler:"           CMAKE_COMPILER    THEN "${CMAKE_COMPILER}" ELSE "${CMAKE_CXX_COMPILER}")
 668 status("    C++ flags (Release):"    ${CMAKE_CXX_FLAGS} ${CMAKE_CXX_FLAGS_RELEASE})
 669 status("    C++ flags (Debug):"      ${CMAKE_CXX_FLAGS} ${CMAKE_CXX_FLAGS_DEBUG})
 670 if(WIN32)
 671     status("    Linker flags (Release):" ${CMAKE_EXE_LINKER_FLAGS} ${CMAKE_EXE_LINKER_FLAGS_RELEASE})
 672     status("    Linker flags (Debug):"   ${CMAKE_EXE_LINKER_FLAGS} ${CMAKE_EXE_LINKER_FLAGS_DEBUG})
 673 else()
 674     status("    Linker flags (Release):" ${CMAKE_SHARED_LINKER_FLAGS} ${CMAKE_SHARED_LINKER_FLAGS_RELEASE})
 675     status("    Linker flags (Debug):"   ${CMAKE_SHARED_LINKER_FLAGS} ${CMAKE_SHARED_LINKER_FLAGS_DEBUG})
 676 endif()
 677
 678 status("")
 679 status("  OpenCV modules:")
 680 string(REPLACE "opencv_" "" OPENCV_MODULES_BUILD_ST          "${OPENCV_MODULES_BUILD}")
 681 string(REPLACE "opencv_" "" OPENCV_MODULES_DISABLED_USER_ST  "${OPENCV_MODULES_DISABLED_USER}")
 682 string(REPLACE "opencv_" "" OPENCV_MODULES_DISABLED_AUTO_ST  "${OPENCV_MODULES_DISABLED_AUTO}")
 683 string(REPLACE "opencv_" "" OPENCV_MODULES_DISABLED_FORCE_ST "${OPENCV_MODULES_DISABLED_FORCE}")
 684 status("    To be built:"            OPENCV_MODULES_BUILD          THEN ${OPENCV_MODULES_BUILD_ST}          ELSE "-")
 685 status("    Disabled by user:"       OPENCV_MODULES_DISABLED_USER  THEN ${OPENCV_MODULES_DISABLED_USER_ST}  ELSE "-")
 686 status("    Disabled by dependency:" OPENCV_MODULES_DISABLED_AUTO  THEN ${OPENCV_MODULES_DISABLED_AUTO_ST}  ELSE "-")
 687 status("    Unavailable:"            OPENCV_MODULES_DISABLED_FORCE THEN ${OPENCV_MODULES_DISABLED_FORCE_ST} ELSE "-")
 688
 689
 690 if(ANDROID)
 691     status("")
 692     status("  Android: ")
 693     status("    Android ABI:" ${ANDROID_ABI})
 694     status("    Native API level:" android-${ANDROID_NATIVE_API_LEVEL})
 695     status("    SDK target:" "${ANDROID_SDK_TARGET}")
 696     if(BUILD_WITH_ANDROID_NDK)
 697         status("    Android NDK:" "${ANDROID_NDK} (toolchain: ${ANDROID_TOOLCHAIN_NAME})")
 698     elseif(BUILD_WITH_STANDALONE_TOOLCHAIN)
 699         status("    Android toolchain:" "${ANDROID_STANDALONE_TOOLCHAIN}")
 700     endif()
 701     status("    android tool:"  ANDROID_EXECUTABLE  THEN "${ANDROID_EXECUTABLE} (${ANDROID_TOOLS_Pkg_Desc})" ELSE NO)
 702     status("    ant:"           ANT_EXECUTABLE      THEN "${ANT_EXECUTABLE} (ver ${ANT_VERSION})"            ELSE NO)
 703 endif()
 704
 705 #YV
 706 status("")
 707 status("  GUI: ")
 708
 709 if (HAVE_QT)
 710     status("    QT 4.x:"            HAVE_QT        THEN YES ELSE NO)
 711     status("    QT OpenGL support:" HAVE_QT_OPENGL THEN YES ELSE NO)
 712 else()
 713     if(WIN32)
 714         status("    Win32 UI:" YES)
 715     else()
 716         if(APPLE)
 717             if(WITH_CARBON)
 718                 status("    Carbon:" YES)
 719             else()
 720                 status("    Cocoa:"  YES)
 721             endif()
 722         else()
 723             status("    GTK+ 2.x:" HAVE_GTK      THEN YES ELSE NO)
 724             status("    GThread :" HAVE_GTHREAD  THEN YES ELSE NO)
 725             status("    GtkGlExt:" HAVE_GTKGLEXT THEN YES ELSE NO)
 726         endif()
 727     endif()
 728 endif()
 729
 730 status("    OpenGL support:" HAVE_OPENGL THEN YES ELSE NO)
 731
 732 # media
 733 status("")
 734 status("  Media I/O: ")
 735 status("    ZLib:"      ZLIB_FOUND                         THEN ${ZLIB_FOUND}   ELSE build)
 736 status("    JPEG:"      NOT WITH_JPEG OR JPEG_FOUND        THEN ${JPEG_FOUND}   ELSE build)
 737 status("    PNG:"       NOT WITH_PNG OR PNG_FOUND          THEN ${PNG_FOUND}    ELSE build)
 738 status("    TIFF:"      NOT WITH_TIFF OR TIFF_FOUND        THEN ${TIFF_FOUND}   ELSE build)
 739 status("    JPEG 2000:" NOT WITH_JASPER OR JASPER_FOUND    THEN ${JASPER_FOUND} ELSE build)
 740 status("    OpenEXR:"   WITH_OPENEXR AND OPENEXR_FOUND     THEN YES             ELSE NO)
 741
 742 status("    OpenNI:"    HAVE_OPENNI                        THEN YES             ELSE NO)
 743 status("    OpenNI PrimeSensor Modules:"
 744                         HAVE_OPENNI_PRIME_SENSOR_MODULE    THEN YES             ELSE NO)
 745 if(WIN32)
 746     status("    XIMEA:"     HAVE_XIMEA  THEN YES ELSE NO)
 747 endif()
 748
 749 # video
 750 status("")
 751 if(UNIX AND NOT APPLE)
 752     status("  Video I/O:")
 753     status("    DC1394 1.x:"     HAVE_DC1394         THEN YES ELSE NO)
 754     status("    DC1394 2.x:"     HAVE_DC1394_2       THEN YES ELSE NO)
 755     status("    FFMPEG:"         HAVE_FFMPEG         THEN YES ELSE NO)
 756     status("      codec:"        HAVE_FFMPEG_CODEC   THEN YES ELSE NO)
 757     status("      format:"       HAVE_FFMPEG_FORMAT  THEN YES ELSE NO)
 758     status("      util:"         HAVE_FFMPEG_UTIL    THEN YES ELSE NO)
 759     status("      swscale:"      HAVE_FFMPEG_SWSCALE THEN YES ELSE NO)
 760     status("      gentoo-style:" HAVE_GENTOO_FFMPEG  THEN YES ELSE NO)
 761     status("    GStreamer:"      HAVE_GSTREAMER      THEN YES ELSE NO)
 762     status("    UniCap:"         HAVE_UNICAP         THEN YES ELSE NO)
 763     status("    PvAPI:"          HAVE_PVAPI          THEN YES ELSE NO)
 764     status("    V4L/V4L2:"       HAVE_LIBV4L         THEN "Using libv4l" ELSE ${HAVE_CAMV4L}/${HAVE_CAMV4L2})
 765     status("    Xine:"           HAVE_XINE           THEN YES ELSE NO)
 766
 767     if(ANDROID)
 768         if(HAVE_opencv_androidcamera)
 769             status("    AndroidNativeCamera:" BUILD_ANDROID_CAMERA_WRAPPER THEN "YES, build for Android ${ANDROID_VERSION}" ELSE "YES, use prebuilt libraries")
 770         else()
 771             status("    AndroidNativeCamera:" "NO (native camera requires Android API level 8 or higher)")
 772         endif()
 773     endif()
 774 elseif(APPLE)
 775     if(NOT IOS)
 776         status("  Video I/O:"    WITH_QUICKTIME      THEN QuickTime ELSE QTKit)
 777     else()
 778         status("  Video I/O: AVFoundation")
 779     endif()
 780 elseif(WIN32)
 781     status("  Video I/O:"        HAVE_VIDEOINPUT     THEN DirectShow ELSE NO)
 782 endif()
 783
 784 # Other third-party libraries
 785 status("")
 786 status("  Other third-party libraries:")
 787
 788 if(WITH_IPP AND IPP_FOUND)
 789     status("    Use IPP:" "${IPP_LATEST_VERSION_STR} [${IPP_LATEST_VERSION_MAJOR}.${IPP_LATEST_VERSION_MINOR}.${IPP_LATEST_VERSION_BUILD}]")
 790     status("         at:" "${IPP_ROOT_DIR}")
 791 else()
 792     status("    Use IPP:"   WITH_IPP AND NOT IPP_FOUND THEN "IPP not found" ELSE NO)
 793 endif()
 794
 795 status("    Use TBB:"   HAVE_TBB   THEN YES ELSE NO)
 796 status("    Use Cuda:"  HAVE_CUDA  THEN YES ELSE NO)
 797 status("    Use Eigen:" HAVE_EIGEN THEN YES ELSE NO)
 798
 799 status("")
 800 status("  Python interpreter:"  PYTHON_EXECUTABLE        THEN "${PYTHON_EXECUTABLE} (ver ${PYTHON_VERSION_MAJOR_MINOR})" ELSE NO)
 801 # interfaces to other languages
 802 status("")
 803 status("  Interfaces:")
 804 status("    Python:"              HAVE_opencv_python THEN YES ELSE NO)
 805 status("    Python numpy:"        PYTHON_USE_NUMPY THEN YES ELSE "NO (Python wrappers will not be generated)")
 806 if(ANDROID)
 807     status("    Java:" HAVE_opencv_java THEN YES ELSE NO)
 808 endif()
 809
 810 # documentation
 811 status("")
 812 status("  Documentation:")
 813 status("    Sphinx:"              HAVE_SPHINX              THEN "${SPHINX_BUILD} (ver ${SPHINX_VERSION})" ELSE NO)
 814 status("    PdfLaTeX compiler:"   PDFLATEX_COMPILER        THEN "${PDFLATEX_COMPILER}" ELSE NO)
 815 if(BUILD_DOCS AND HAVE_SPHINX)
 816     status("    Build Documentation:" PDFLATEX_COMPILER    THEN YES ELSE "YES (only HTML without math expressions)")
 817 else()
 818     status("    Build Documentation:" NO)
 819 endif()
 820
 821 # samples and tests
 822 status("")
 823 status("  Tests and samples:")
 824 status("    Tests:"             BUILD_TESTS       THEN YES ELSE NO)
 825 status("    Performance tests:" BUILD_PERF_TESTS  THEN YES ELSE NO)
 826 status("    Examples:"          BUILD_EXAMPLES    THEN YES ELSE NO)
 827
 828 if(ANDROID)
 829    status("    Android tests:"    BUILD_TESTS AND CAN_BUILD_ANDROID_PROJECTS THEN YES ELSE NO)
 830    status("    Android examples:" BUILD_ANDROID_EXAMPLES                     THEN YES ELSE NO)
 831 endif()
 832
 833 #auxiliary
 834 status("")
 835 status("  Install path:" "${CMAKE_INSTALL_PREFIX}")
 836 status("")
 837 status("  cvconfig.h is in:" "${OPENCV_CONFIG_FILE_INCLUDE_DIR}")
 838 status("-----------------------------------------------------------------")
 839 status("")
 840
 841 # ----------------------------------------------------------------------------
 842 # Warn in the case of in-source build
 843 # ----------------------------------------------------------------------------
 844 if("${CMAKE_CURRENT_SOURCE_DIR}" STREQUAL "${CMAKE_CURRENT_BINARY_DIR}")
 845     message(WARNING "The source directory is the same as binary directory. \"make clean\" may damage the source tree")
 846 endif()
 847