CMakeLists.txt

   1 # The name of our project is "VULKAN". CMakeLists files in this project can
   2 # refer to the root source directory of the project as ${VULKAN_SOURCE_DIR} and
   3 # to the root binary directory of the project as ${VULKAN_BINARY_DIR}.
   4 cmake_minimum_required(VERSION 2.8.11)
   5 project (VULKAN)
   6 # set (CMAKE_VERBOSE_MAKEFILE 1)
   7
   8 # The API_NAME allows renaming builds to avoid conflicts with installed SDKs
   9 # The MAJOR number of the version we're building, used in naming
  10 # <api-name>-<major>.dll (and other files).
  11 set(API_NAME "Vulkan" CACHE STRING "API name to use when building")
  12 set(MAJOR "1")
  13 string(TOLOWER ${API_NAME} API_LOWERCASE)
  14
  15 set(CMAKE_MODULE_PATH ${CMAKE_MODULE_PATH} "${CMAKE_CURRENT_SOURCE_DIR}/cmake")
  16 find_package(PythonInterp 3 REQUIRED)
  17
  18 if(CMAKE_SYSTEM_NAME STREQUAL "Linux")
  19     set(FALLBACK_CONFIG_DIRS "/etc/xdg" CACHE STRING
  20         "Search path to use when XDG_CONFIG_DIRS is unset or empty or the current process is SUID/SGID. Default is freedesktop compliant.")
  21     set(FALLBACK_DATA_DIRS "/usr/local/share:/usr/share" CACHE STRING
  22         "Search path to use when XDG_DATA_DIRS is unset or empty or the current process is SUID/SGID. Default is freedesktop compliant.")
  23
  24     include(FindPkgConfig)
  25     option(BUILD_WSI_XCB_SUPPORT "Build XCB WSI support" ON)
  26     option(BUILD_WSI_XLIB_SUPPORT "Build Xlib WSI support" ON)
  27     option(BUILD_WSI_WAYLAND_SUPPORT "Build Wayland WSI support" ON)
  28     option(BUILD_WSI_MIR_SUPPORT "Build Mir WSI support" OFF)
  29     set(DEMOS_WSI_SELECTION "XCB" CACHE STRING "Select WSI target for demos (XCB, XLIB, WAYLAND, MIR, DISPLAY)")
  30
  31     if (BUILD_WSI_XCB_SUPPORT)
  32         find_package(XCB REQUIRED)
  33     endif()
  34
  35     if (BUILD_WSI_XLIB_SUPPORT)
  36         find_package(X11 REQUIRED)
  37     endif()
  38
  39     if (BUILD_WSI_WAYLAND_SUPPORT)
  40         find_package(Wayland REQUIRED)
  41         include_directories(${WAYLAND_CLIENT_INCLUDE_DIR})
  42     endif()
  43
  44     if (BUILD_WSI_MIR_SUPPORT)
  45         find_package(Mir REQUIRED)
  46     endif()
  47
  48     # This option can be used to suppress the installation of artifacts from the
  49     # Vulkan-LoaderAndValidationLayers repo while running "make install" for the
  50     # VulkanTools and VulkanSamples repos.  This can be used to prevent the
  51     # overwriting of LVL artifacts when installing these downstream repos.
  52     option(INSTALL_LVL_FILES "Install content from LoaderAndValidationLayers repo" ON)
  53 endif()
  54
  55 set(SCRIPTS_DIR "${CMAKE_CURRENT_SOURCE_DIR}/scripts")
  56
  57 # Header file for CMake settings
  58 include_directories("${PROJECT_SOURCE_DIR}/include")
  59
  60 if (CMAKE_COMPILER_IS_GNUCC OR CMAKE_C_COMPILER_ID MATCHES "Clang")
  61     set(COMMON_COMPILE_FLAGS "-Wall -Wextra -Wno-unused-parameter -Wno-missing-field-initializers")
  62     set(COMMON_COMPILE_FLAGS "${COMMON_COMPILE_FLAGS} -fno-strict-aliasing -fno-builtin-memcmp")
  63
  64     # For GCC version 7.1 or greater, we need to disable the implicit fallthrough warning since
  65     # there's no consistent way to satisfy all compilers until they all accept the C++17 standard
  66     if (CMAKE_COMPILER_IS_GNUCC AND NOT (CMAKE_CXX_COMPILER_VERSION LESS 7.1))
  67         set(COMMON_COMPILE_FLAGS "${COMMON_COMPILE_FLAGS} -Wimplicit-fallthrough=0")
  68     endif()
  69
  70     set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -std=c99 ${COMMON_COMPILE_FLAGS}")
  71     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} ${COMMON_COMPILE_FLAGS} -std=c++11 -fno-rtti")
  72     if (UNIX)
  73         set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -fvisibility=hidden")
  74         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -fvisibility=hidden")
  75     endif()
  76 endif()
  77
  78 if(WIN32)
  79     # Treat warnings as errors
  80     add_compile_options("$<$<CXX_COMPILER_ID:MSVC>:/WX>")
  81     # Disable RTTI
  82     add_compile_options("$<$<CXX_COMPILER_ID:MSVC>:/GR->")
  83     # Warn about nested declarations
  84     add_compile_options("$<$<CXX_COMPILER_ID:MSVC>:/w34456>")
  85     # Warn about potentially uninitialized variables
  86     add_compile_options("$<$<CXX_COMPILER_ID:MSVC>:/w34701>")
  87     add_compile_options("$<$<CXX_COMPILER_ID:MSVC>:/w34703>")
  88
  89     if (NOT MSVC_VERSION LESS 1900)
  90         # Enable control flow guard
  91         message(STATUS "Building with control flow guard")
  92         add_compile_options("$<$<CXX_COMPILER_ID:MSVC>:/guard:cf>")
  93         set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} /guard:cf")
  94         set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} /guard:cf")
  95     endif()
  96 endif()
  97
  98 if(NOT WIN32)
  99     set (BUILDTGT_DIR build)
 100     set (BINDATA_DIR Bin)
 101     set (LIBSOURCE_DIR Lib)
 102 else()
 103     option(DISABLE_BUILD_PATH_DECORATION "Disable the decoration of the gslang and SPIRV-Tools build path with MSVC build type info" OFF)
 104     option(DISABLE_BUILDTGT_DIR_DECORATION "Disable the decoration of the gslang and SPIRV-Tools build path with target info" OFF)
 105
 106     # For Windows, since 32-bit and 64-bit items can co-exist, we build each in its own build directory.
 107     # 32-bit target data goes in build32, and 64-bit target data goes into build.  So, include/link the
 108     # appropriate data at build time.
 109     if (DISABLE_BUILDTGT_DIR_DECORATION)
 110         set (BUILDTGT_DIR "")
 111         set (BINDATA_DIR "")
 112         set (LIBSOURCE_DIR "")
 113     elseif (CMAKE_CL_64)
 114         set (BUILDTGT_DIR build)
 115         set (BINDATA_DIR Bin)
 116         set (LIBSOURCE_DIR Lib)
 117     else()
 118         set (BUILDTGT_DIR build32)
 119         set (BINDATA_DIR Bin32)
 120         set (LIBSOURCE_DIR Lib32)
 121     endif()
 122 endif()
 123
 124 option(BUILD_LOADER "Build loader" ON)
 125 option(BUILD_TESTS "Build tests" ON)
 126 option(BUILD_LAYERS "Build layers" ON)
 127 option(BUILD_DEMOS "Build demos" ON)
 128 option(BUILD_VKJSON "Build vkjson" ON)
 129 option(CUSTOM_GLSLANG_BIN_ROOT "Use the user defined GLSLANG_BINARY_ROOT" OFF)
 130 option(CUSTOM_SPIRV_TOOLS_BIN_ROOT "Use the user defined SPIRV_TOOLS_BINARY_ROOT" OFF)
 131
 132 #Choose natural default paths for glslang and SPIRV-Tools binaries to support custom definition by the user on the CMake command line or in the GUI
 133 set(GLSLANG_BINARY_ROOT "${CMAKE_BINARY_DIR}/../glslang" CACHE STRING "User defined path to the glslang binaries for this project")
 134 set(SPIRV_TOOLS_BINARY_ROOT "${CMAKE_BINARY_DIR}/../SPIRV-Tools" CACHE STRING "User defined path to the SPIRV-Tools binaries for this project")
 135
 136 # Define a variable for a default root location to the gslang, SPIRV-Tools and other external sources and cache it to allow the user to customize it as needed
 137 set(EXTERNAL_SOURCE_ROOT "${CMAKE_SOURCE_DIR}/external" CACHE STRING "Root path to external sources such as glslang and SPIRV-Tools")
 138
 139
 140 if (WIN32)
 141     if(CUSTOM_GLSLANG_BIN_ROOT)
 142         set(GSLANG_FINAL_BINARY_PATH ${GLSLANG_BINARY_ROOT}/${BUILDTGT_DIR})
 143     else()
 144         set(GSLANG_FINAL_BINARY_PATH "${EXTERNAL_SOURCE_ROOT}/glslang/${BUILDTGT_DIR}")
 145     endif()
 146
 147     if(DISABLE_BUILD_PATH_DECORATION)
 148         set (DEBUG_DECORATION "")
 149         set (RELEASE_DECORATION "")
 150     else()
 151         set (DEBUG_DECORATION "Debug")
 152         set (RELEASE_DECORATION "Release")
 153     endif()
 154
 155     # Take some steps to set up a variable pointing to the final glslang binaries given the variety of input options
 156     set (GLSLANG_SEARCH_PATH "${GSLANG_FINAL_BINARY_PATH}/glslang/${RELEASE_DECORATION}"
 157                              "${GSLANG_FINAL_BINARY_PATH}/glslang/OSDependent/Windows/${RELEASE_DECORATION}"
 158                              "${GSLANG_FINAL_BINARY_PATH}/hlsl/${RELEASE_DECORATION}"
 159                              "${GSLANG_FINAL_BINARY_PATH}/OGLCompilersDLL/${RELEASE_DECORATION}"
 160                              "${GSLANG_FINAL_BINARY_PATH}/SPIRV/${RELEASE_DECORATION}" )
 161
 162     set (GLSLANG_DEBUG_SEARCH_PATH "${GSLANG_FINAL_BINARY_PATH}/glslang/${DEBUG_DECORATION}"
 163                                    "${GSLANG_FINAL_BINARY_PATH}/glslang/OSDependent/Windows/${DEBUG_DECORATION}"
 164                                    "${GSLANG_FINAL_BINARY_PATH}/hlsl/${DEBUG_DECORATION}"
 165                                    "${GSLANG_FINAL_BINARY_PATH}/OGLCompilersDLL/${DEBUG_DECORATION}"
 166                                    "${GSLANG_FINAL_BINARY_PATH}/SPIRV/${DEBUG_DECORATION}")
 167
 168     if(CUSTOM_SPIRV_TOOLS_BIN_ROOT)
 169         set (SPIRV_TOOLS_SEARCH_PATH "${SPIRV_TOOLS_BINARY_ROOT}/${BUILDTGT_DIR}/source/${RELEASE_DECORATION}")
 170         set (SPIRV_TOOLS_DEBUG_SEARCH_PATH "${SPIRV_TOOLS_BINARY_ROOT}/${BUILDTGT_DIR}/source/${DEBUG_DECORATION}")
 171     else()
 172         set (SPIRV_TOOLS_SEARCH_PATH "${EXTERNAL_SOURCE_ROOT}/spirv-tools/${BUILDTGT_DIR}/source/${RELEASE_DECORATION}")
 173         set (SPIRV_TOOLS_DEBUG_SEARCH_PATH "${EXTERNAL_SOURCE_ROOT}/spirv-tools/${BUILDTGT_DIR}/source/${DEBUG_DECORATION}")
 174     endif()
 175 else()
 176     #non windows
 177     if(CUSTOM_GLSLANG_BIN_ROOT)
 178         set (GLSLANG_SEARCH_PATH "${GLSLANG_BINARY_ROOT}/install/lib"
 179                                  "${GLSLANG_BINARY_ROOT}/glslang"
 180                                  "${GLSLANG_BINARY_ROOT}/glslang/OSDependent/Unix"
 181                                  "${GLSLANG_BINARY_ROOT}/OGLCompilersDLL"
 182                                  "${GLSLANG_BINARY_ROOT}/SPIRV"
 183                                  "${GLSLANG_BINARY_ROOT}/hlsl"
 184                                  "${GLSLANG_BINARY_ROOT}/StandAlone")
 185     else()
 186         set (GLSLANG_SEARCH_PATH "${EXTERNAL_SOURCE_ROOT}/glslang/${BUILDTGT_DIR}/install/lib" "${CMAKE_SOURCE_DIR}/../x86_64/lib/glslang" )
 187     endif()
 188
 189     if(CUSTOM_SPIRV_TOOLS_BIN_ROOT)
 190         set (SPIRV_TOOLS_SEARCH_PATH "${SPIRV_TOOLS_BINARY_ROOT}/source" )
 191     else()
 192         set (SPIRV_TOOLS_SEARCH_PATH "${EXTERNAL_SOURCE_ROOT}/spirv-tools/${BUILDTGT_DIR}/source" "${CMAKE_SOURCE_DIR}/../x86_64/lib/spirv-tools" )
 193     endif()
 194 endif()
 195
 196 find_program(GLSLANG_VALIDATOR NAMES glslangValidator
 197              HINTS "${CMAKE_SOURCE_DIR}/external/glslang/${BUILDTGT_DIR}/install/bin"
 198                    "${GLSLANG_BINARY_ROOT}/StandAlone"
 199                    "${PROJECT_SOURCE_DIR}/external/${BINDATA_DIR}")
 200
 201 find_path(GLSLANG_SPIRV_INCLUDE_DIR SPIRV/spirv.hpp HINTS "${EXTERNAL_SOURCE_ROOT}/glslang"
 202                                                     "${CMAKE_SOURCE_DIR}/../glslang"
 203                                               DOC "Path to SPIRV/spirv.hpp")
 204
 205 find_path(SPIRV_TOOLS_INCLUDE_DIR spirv-tools/libspirv.h HINTS "${EXTERNAL_SOURCE_ROOT}/spirv-tools/include"
 206                                                    "${EXTERNAL_SOURCE_ROOT}/SPIRV-Tools/include"
 207                                                    "${CMAKE_SOURCE_DIR}/../spirv-tools/include"
 208                                                    "${CMAKE_SOURCE_DIR}/../SPIRV-Tools/include"
 209                                                    "${EXTERNAL_SOURCE_ROOT}/source/spirv-tools/external/include"
 210                                              DOC "Path to spirv-tools/libspirv.h")
 211
 212 find_library(GLSLANG_LIB NAMES glslang
 213              HINTS ${GLSLANG_SEARCH_PATH} )
 214
 215 find_library(OGLCompiler_LIB NAMES OGLCompiler
 216              HINTS ${GLSLANG_SEARCH_PATH} )
 217
 218 find_library(OSDependent_LIB NAMES OSDependent
 219              HINTS ${GLSLANG_SEARCH_PATH} )
 220
 221 find_library(HLSL_LIB NAMES HLSL
 222              HINTS ${GLSLANG_SEARCH_PATH} )
 223
 224 find_library(SPIRV_LIB NAMES SPIRV
 225              HINTS ${GLSLANG_SEARCH_PATH} )
 226
 227 find_library(SPIRV_REMAPPER_LIB NAMES SPVRemapper
 228              HINTS ${GLSLANG_SEARCH_PATH} )
 229
 230 find_library(SPIRV_TOOLS_LIB NAMES SPIRV-Tools
 231              HINTS ${SPIRV_TOOLS_SEARCH_PATH} )
 232
 233 if (WIN32)
 234     add_library(glslang     STATIC IMPORTED)
 235     add_library(OGLCompiler STATIC IMPORTED)
 236     add_library(OSDependent STATIC IMPORTED)
 237     add_library(HLSL        STATIC IMPORTED)
 238     add_library(SPIRV       STATIC IMPORTED)
 239     add_library(SPVRemapper       STATIC IMPORTED)
 240     add_library(Loader      STATIC IMPORTED)
 241     add_library(SPIRV-Tools STATIC IMPORTED)
 242
 243     find_library(GLSLANG_DLIB NAMES glslangd
 244                  HINTS ${GLSLANG_DEBUG_SEARCH_PATH} )
 245     find_library(OGLCompiler_DLIB NAMES OGLCompilerd
 246                  HINTS ${GLSLANG_DEBUG_SEARCH_PATH} )
 247     find_library(OSDependent_DLIB NAMES OSDependentd
 248                  HINTS ${GLSLANG_DEBUG_SEARCH_PATH} )
 249     find_library(HLSL_DLIB NAMES HLSLd
 250                  HINTS ${GLSLANG_DEBUG_SEARCH_PATH} )
 251     find_library(SPIRV_DLIB NAMES SPIRVd
 252                  HINTS ${GLSLANG_DEBUG_SEARCH_PATH} )
 253     find_library(SPIRV_REMAPPER_DLIB NAMES SPVRemapperd
 254                  HINTS ${GLSLANG_DEBUG_SEARCH_PATH} )
 255     find_library(SPIRV_TOOLS_DLIB NAMES SPIRV-Tools
 256                  HINTS ${SPIRV_TOOLS_DEBUG_SEARCH_PATH} )
 257
 258     set_target_properties(glslang PROPERTIES
 259                          IMPORTED_LOCATION       "${GLSLANG_LIB}"
 260                          IMPORTED_LOCATION_DEBUG "${GLSLANG_DLIB}")
 261     set_target_properties(OGLCompiler PROPERTIES
 262                          IMPORTED_LOCATION       "${OGLCompiler_LIB}"
 263                          IMPORTED_LOCATION_DEBUG "${OGLCompiler_DLIB}")
 264     set_target_properties(OSDependent PROPERTIES
 265                          IMPORTED_LOCATION       "${OSDependent_LIB}"
 266                          IMPORTED_LOCATION_DEBUG "${OSDependent_DLIB}")
 267     set_target_properties(HLSL PROPERTIES
 268                          IMPORTED_LOCATION       "${HLSL_LIB}"
 269                          IMPORTED_LOCATION_DEBUG "${HLSL_DLIB}")
 270     set_target_properties(SPIRV PROPERTIES
 271                          IMPORTED_LOCATION       "${SPIRV_LIB}"
 272                          IMPORTED_LOCATION_DEBUG "${SPIRV_DLIB}")
 273     set_target_properties(SPVRemapper PROPERTIES
 274                          IMPORTED_LOCATION       "${SPIRV_REMAPPER_LIB}"
 275                          IMPORTED_LOCATION_DEBUG "${SPIRV_REMAPPER_DLIB}")
 276     set_target_properties(SPIRV-Tools PROPERTIES
 277                          IMPORTED_LOCATION       "${SPIRV_TOOLS_LIB}"
 278                          IMPORTED_LOCATION_DEBUG "${SPIRV_TOOLS_DLIB}")
 279
 280     set (GLSLANG_LIBRARIES glslang OGLCompiler OSDependent HLSL SPIRV SPVRemapper)
 281     set (SPIRV_TOOLS_LIBRARIES SPIRV-Tools)
 282 else ()
 283     set (GLSLANG_LIBRARIES ${GLSLANG_LIB} ${OGLCompiler_LIB} ${OSDependent_LIB} ${HLSL_LIB} ${SPIRV_LIB} ${SPIRV_REMAPPER_LIB})
 284     set (SPIRV_TOOLS_LIBRARIES ${SPIRV_TOOLS_LIB})
 285 endif()
 286
 287 set (PYTHON_CMD ${PYTHON_EXECUTABLE})
 288
 289 # Define macro used for building vkxml generated files
 290 macro(run_vk_xml_generate dependency output)
 291     add_custom_command(OUTPUT ${output}
 292     COMMAND ${PYTHON_CMD} ${SCRIPTS_DIR}/lvl_genvk.py -registry ${SCRIPTS_DIR}/vk.xml ${output}
 293     DEPENDS ${SCRIPTS_DIR}/vk.xml ${SCRIPTS_DIR}/generator.py ${SCRIPTS_DIR}/${dependency} ${SCRIPTS_DIR}/lvl_genvk.py ${SCRIPTS_DIR}/reg.py
 294     )
 295 endmacro()
 296
 297 # Custom target for generated vulkan helper file dependencies
 298 add_custom_target(generate_helper_files DEPENDS
 299     vk_enum_string_helper.h
 300     vk_struct_size_helper.h
 301     vk_struct_size_helper.c
 302     vk_safe_struct.h
 303     vk_safe_struct.cpp
 304     vk_object_types.h
 305     vk_layer_dispatch_table.h
 306     vk_dispatch_table_helper.h
 307     vk_extension_helper.h
 308     )
 309
 310 # Rules to build generated helper files
 311 run_vk_xml_generate(loader_extension_generator.py vk_layer_dispatch_table.h)
 312 run_vk_xml_generate(dispatch_table_helper_generator.py vk_dispatch_table_helper.h)
 313 run_vk_xml_generate(helper_file_generator.py vk_safe_struct.h)
 314 run_vk_xml_generate(helper_file_generator.py vk_safe_struct.cpp)
 315 run_vk_xml_generate(helper_file_generator.py vk_struct_size_helper.h)
 316 run_vk_xml_generate(helper_file_generator.py vk_struct_size_helper.c)
 317 run_vk_xml_generate(helper_file_generator.py vk_enum_string_helper.h)
 318 run_vk_xml_generate(helper_file_generator.py vk_object_types.h)
 319 run_vk_xml_generate(helper_file_generator.py vk_extension_helper.h)
 320
 321 if(NOT WIN32)
 322     include(GNUInstallDirs)
 323
 324     add_definitions(-DFALLBACK_CONFIG_DIRS="${FALLBACK_CONFIG_DIRS}")
 325     add_definitions(-DFALLBACK_DATA_DIRS="${FALLBACK_DATA_DIRS}")
 326     add_definitions(-DSYSCONFDIR="${CMAKE_INSTALL_FULL_SYSCONFDIR}")
 327
 328     # Make sure /etc is searched by the loader
 329     if(NOT (CMAKE_INSTALL_FULL_SYSCONFDIR STREQUAL "/etc"))
 330         add_definitions(-DEXTRASYSCONFDIR="/etc")
 331     endif()
 332 endif()
 333
 334 if(UNIX)
 335     if(INSTALL_LVL_FILES)
 336         install(DIRECTORY "${PROJECT_SOURCE_DIR}/include/vulkan" DESTINATION ${CMAKE_INSTALL_INCLUDEDIR})
 337         install(FILES "${CMAKE_CURRENT_BINARY_DIR}/vk_layer_dispatch_table.h" DESTINATION "${CMAKE_INSTALL_INCLUDEDIR}/vulkan")
 338     endif()
 339
 340 # uninstall target
 341 configure_file(
 342     "${CMAKE_CURRENT_SOURCE_DIR}/cmake/cmake_uninstall.cmake.in"
 343     "${CMAKE_CURRENT_BINARY_DIR}/cmake_uninstall.cmake"
 344     IMMEDIATE @ONLY)
 345
 346 add_custom_target(uninstall
 347     COMMAND ${CMAKE_COMMAND} -P ${CMAKE_CURRENT_BINARY_DIR}/cmake_uninstall.cmake)
 348 endif()
 349
 350 add_definitions(-DAPI_NAME="${API_NAME}")
 351
 352 # loader: Generic VULKAN ICD loader
 353 # tests: VULKAN tests
 354 if(BUILD_LOADER)
 355     add_subdirectory(loader)
 356 endif()
 357
 358 if(BUILD_TESTS)
 359     add_subdirectory(tests)
 360 endif()
 361
 362 if(BUILD_LAYERS)
 363     add_subdirectory(layers)
 364 endif()
 365
 366 if(BUILD_DEMOS)
 367     add_subdirectory(demos)
 368 endif()
 369
 370 if(BUILD_VKJSON)
 371     add_subdirectory(libs/vkjson)
 372 endif()