CMakeLists.txt

   1 # ----------------------------------------------------------------------------
   2 #  Root CMake file for OpenCV
   3 #
   4 #    From the off-tree build directory, invoke:
   5 #      $ cmake <PATH_TO_OPENCV_ROOT>
   6 #
   7 # ----------------------------------------------------------------------------
   8
   9 # Disable in-source builds to prevent source tree corruption.
  10 if(" ${CMAKE_SOURCE_DIR}" STREQUAL " ${CMAKE_BINARY_DIR}")
  11   message(FATAL_ERROR "
  12 FATAL: In-source builds are not allowed.
  13        You should create a separate directory for build files.
  14 ")
  15 endif()
  16
  17
  18 include(cmake/OpenCVMinDepVersions.cmake)
  19
  20 if(CMAKE_GENERATOR MATCHES Xcode AND XCODE_VERSION VERSION_GREATER 4.3)
  21   cmake_minimum_required(VERSION 3.0 FATAL_ERROR)
  22 elseif(CMAKE_SYSTEM_NAME MATCHES WindowsPhone OR CMAKE_SYSTEM_NAME MATCHES WindowsStore)
  23   cmake_minimum_required(VERSION 3.1 FATAL_ERROR)
  24   #Required to resolve linker error issues due to incompatibility with CMake v3.0+ policies.
  25   #CMake fails to find _fseeko() which leads to subsequent linker error.
  26   #See details here: http://www.cmake.org/Wiki/CMake/Policies
  27   cmake_policy(VERSION 2.8)
  28 else()
  29   cmake_minimum_required(VERSION "${MIN_VER_CMAKE}" FATAL_ERROR)
  30 endif()
  31
  32 #
  33 # Configure CMake policies
  34 #
  35 if(POLICY CMP0026)
  36   cmake_policy(SET CMP0026 NEW)
  37 endif()
  38
  39 if(POLICY CMP0042)
  40   cmake_policy(SET CMP0042 NEW)  # CMake 3.0+ (2.8.12): MacOS "@rpath" in target's install name
  41 endif()
  42
  43 if(POLICY CMP0046)
  44   cmake_policy(SET CMP0046 NEW)  # warn about non-existed dependencies
  45 endif()
  46
  47 if(POLICY CMP0051)
  48   cmake_policy(SET CMP0051 NEW)
  49 endif()
  50
  51 if(POLICY CMP0054)  # CMake 3.1: Only interpret if() arguments as variables or keywords when unquoted.
  52   cmake_policy(SET CMP0054 NEW)
  53 endif()
  54
  55 if(POLICY CMP0056)
  56   cmake_policy(SET CMP0056 NEW)  # try_compile(): link flags
  57 endif()
  58
  59 if(POLICY CMP0066)
  60   cmake_policy(SET CMP0066 NEW)  # CMake 3.7: try_compile(): use per-config flags, like CMAKE_CXX_FLAGS_RELEASE
  61 endif()
  62
  63 if(POLICY CMP0067)
  64   cmake_policy(SET CMP0067 NEW)  # CMake 3.8: try_compile(): honor language standard variables (like C++11)
  65 endif()
  66
  67 if(POLICY CMP0068)
  68   cmake_policy(SET CMP0068 NEW)  # CMake 3.9+: `RPATH` settings on macOS do not affect `install_name`.
  69 endif()
  70
  71 if(POLICY CMP0075)
  72   cmake_policy(SET CMP0075 NEW)  # CMake 3.12+: Include file check macros honor `CMAKE_REQUIRED_LIBRARIES`
  73 endif()
  74
  75 if(POLICY CMP0077)
  76   cmake_policy(SET CMP0077 NEW)  # CMake 3.13+: option() honors normal variables.
  77 endif()
  78
  79 #
  80 # Configure OpenCV CMake hooks
  81 #
  82 include(cmake/OpenCVUtils.cmake)
  83 ocv_cmake_reset_hooks()
  84 ocv_check_environment_variables(OPENCV_CMAKE_HOOKS_DIR)
  85 if(DEFINED OPENCV_CMAKE_HOOKS_DIR)
  86   foreach(__dir ${OPENCV_CMAKE_HOOKS_DIR})
  87     get_filename_component(__dir "${__dir}" ABSOLUTE)
  88     ocv_cmake_hook_register_dir(${__dir})
  89   endforeach()
  90 endif()
  91
  92 ocv_cmake_hook(CMAKE_INIT)
  93
  94 # must go before the project()/enable_language() commands
  95 ocv_update(CMAKE_CONFIGURATION_TYPES "Debug;Release" CACHE STRING "Configs" FORCE)
  96 if(DEFINED CMAKE_BUILD_TYPE)
  97   set_property(CACHE CMAKE_BUILD_TYPE PROPERTY STRINGS "${CMAKE_CONFIGURATION_TYPES}")
  98 endif()
  99
 100 option(ENABLE_PIC "Generate position independent code (necessary for shared libraries)" TRUE)
 101 set(CMAKE_POSITION_INDEPENDENT_CODE ${ENABLE_PIC})
 102
 103 ocv_cmake_hook(PRE_CMAKE_BOOTSTRAP)
 104
 105 # Bootstap CMake system: setup CMAKE_SYSTEM_NAME and other vars
 106 enable_language(CXX C)
 107
 108 ocv_cmake_hook(POST_CMAKE_BOOTSTRAP)
 109
 110 if(NOT OPENCV_SKIP_CMAKE_SYSTEM_FILE)
 111   include("cmake/platforms/OpenCV-${CMAKE_SYSTEM_NAME}.cmake" OPTIONAL RESULT_VARIABLE "OPENCV_CMAKE_SYSTEM_FILE")
 112   if(NOT OPENCV_CMAKE_SYSTEM_FILE)
 113     message(STATUS "OpenCV: system-specific configuration file is not found: '${CMAKE_SYSTEM_NAME}'")
 114   endif()
 115 endif()
 116
 117 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)  # https://cmake.org/cmake/help/latest/variable/CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT.html
 118   if(NOT CMAKE_TOOLCHAIN_FILE)
 119     if(WIN32)
 120       set(CMAKE_INSTALL_PREFIX "${CMAKE_BINARY_DIR}/install" CACHE PATH "Installation Directory" FORCE)
 121     else()
 122       set(CMAKE_INSTALL_PREFIX "/usr/local" CACHE PATH "Installation Directory" FORCE)
 123     endif()
 124   else()
 125     # any cross-compiling
 126     set(CMAKE_INSTALL_PREFIX "${CMAKE_BINARY_DIR}/install" CACHE PATH "Installation Directory" FORCE)
 127   endif()
 128 endif()
 129
 130 enable_testing()
 131
 132 project(OpenCV CXX C)
 133
 134 if(MSVC)
 135   set(CMAKE_USE_RELATIVE_PATHS ON CACHE INTERNAL "" FORCE)
 136 endif()
 137
 138 ocv_cmake_eval(DEBUG_PRE ONCE)
 139
 140 ocv_clear_vars(OpenCVModules_TARGETS)
 141
 142 include(cmake/OpenCVDownload.cmake)
 143
 144 set(BUILD_LIST "" CACHE STRING "Build only listed modules (comma-separated, e.g. 'videoio,dnn,ts')")
 145
 146 # ----------------------------------------------------------------------------
 147 # Break in case of popular CMake configuration mistakes
 148 # ----------------------------------------------------------------------------
 149 if(NOT CMAKE_SIZEOF_VOID_P GREATER 0)
 150   message(FATAL_ERROR "CMake fails to determine the bitness of the target platform.
 151   Please check your CMake and compiler installation. If you are cross-compiling then ensure that your CMake toolchain file correctly sets the compiler details.")
 152 endif()
 153
 154 # ----------------------------------------------------------------------------
 155 # Detect compiler and target platform architecture
 156 # ----------------------------------------------------------------------------
 157 include(cmake/OpenCVDetectCXXCompiler.cmake)
 158 ocv_cmake_hook(POST_DETECT_COMPILER)
 159
 160 # Add these standard paths to the search paths for FIND_LIBRARY
 161 # to find libraries from these locations first
 162 if(UNIX AND NOT ANDROID)
 163   if(X86_64 OR CMAKE_SIZEOF_VOID_P EQUAL 8)
 164     if(EXISTS /lib64)
 165       list(APPEND CMAKE_LIBRARY_PATH /lib64)
 166     else()
 167       list(APPEND CMAKE_LIBRARY_PATH /lib)
 168     endif()
 169     if(EXISTS /usr/lib64)
 170       list(APPEND CMAKE_LIBRARY_PATH /usr/lib64)
 171     else()
 172       list(APPEND CMAKE_LIBRARY_PATH /usr/lib)
 173     endif()
 174   elseif(X86 OR CMAKE_SIZEOF_VOID_P EQUAL 4)
 175     if(EXISTS /lib32)
 176       list(APPEND CMAKE_LIBRARY_PATH /lib32)
 177     else()
 178       list(APPEND CMAKE_LIBRARY_PATH /lib)
 179     endif()
 180     if(EXISTS /usr/lib32)
 181       list(APPEND CMAKE_LIBRARY_PATH /usr/lib32)
 182     else()
 183       list(APPEND CMAKE_LIBRARY_PATH /usr/lib)
 184     endif()
 185   endif()
 186 endif()
 187
 188 # Add these standard paths to the search paths for FIND_PATH
 189 # to find include files from these locations first
 190 if(MINGW)
 191   if(EXISTS /mingw)
 192       list(APPEND CMAKE_INCLUDE_PATH /mingw)
 193   endif()
 194   if(EXISTS /mingw32)
 195       list(APPEND CMAKE_INCLUDE_PATH /mingw32)
 196   endif()
 197   if(EXISTS /mingw64)
 198       list(APPEND CMAKE_INCLUDE_PATH /mingw64)
 199   endif()
 200 endif()
 201
 202 # ----------------------------------------------------------------------------
 203 # OpenCV cmake options
 204 # ----------------------------------------------------------------------------
 205
 206 OCV_OPTION(OPENCV_ENABLE_NONFREE "Enable non-free algorithms" OFF)
 207
 208 # 3rd party libs
 209 OCV_OPTION(OPENCV_FORCE_3RDPARTY_BUILD   "Force using 3rdparty code from source" OFF)
 210 OCV_OPTION(BUILD_ZLIB               "Build zlib from source"             (WIN32 OR APPLE OR OPENCV_FORCE_3RDPARTY_BUILD) )
 211 OCV_OPTION(BUILD_TIFF               "Build libtiff from source"          (WIN32 OR ANDROID OR APPLE OR OPENCV_FORCE_3RDPARTY_BUILD) )
 212 OCV_OPTION(BUILD_JASPER             "Build libjasper from source"        (WIN32 OR ANDROID OR APPLE OR OPENCV_FORCE_3RDPARTY_BUILD) )
 213 OCV_OPTION(BUILD_JPEG               "Build libjpeg from source"          (WIN32 OR ANDROID OR APPLE OR OPENCV_FORCE_3RDPARTY_BUILD) )
 214 OCV_OPTION(BUILD_PNG                "Build libpng from source"           (WIN32 OR ANDROID OR APPLE OR OPENCV_FORCE_3RDPARTY_BUILD) )
 215 OCV_OPTION(BUILD_OPENEXR            "Build openexr from source"          (((WIN32 OR ANDROID OR APPLE) AND NOT WINRT) OR OPENCV_FORCE_3RDPARTY_BUILD) )
 216 OCV_OPTION(BUILD_WEBP               "Build WebP from source"             (((WIN32 OR ANDROID OR APPLE) AND NOT WINRT) OR OPENCV_FORCE_3RDPARTY_BUILD) )
 217 OCV_OPTION(BUILD_TBB                "Download and build TBB from source" (ANDROID OR OPENCV_FORCE_3RDPARTY_BUILD) )
 218 OCV_OPTION(BUILD_IPP_IW             "Build IPP IW from source"           (NOT MINGW OR OPENCV_FORCE_3RDPARTY_BUILD) IF (X86_64 OR X86) AND NOT WINRT )
 219 OCV_OPTION(BUILD_ITT                "Build Intel ITT from source"
 220     (NOT MINGW OR OPENCV_FORCE_3RDPARTY_BUILD)
 221     IF (X86_64 OR X86 OR ARM OR AARCH64 OR PPC64 OR PPC64LE) AND NOT WINRT AND NOT APPLE_FRAMEWORK
 222 )
 223
 224 # Optional 3rd party components
 225 # ===================================================
 226 OCV_OPTION(WITH_1394 "Include IEEE1394 support" ON
 227   VISIBLE_IF NOT ANDROID AND NOT IOS AND NOT WINRT
 228   VERIFY HAVE_DC1394_2)
 229 OCV_OPTION(WITH_AVFOUNDATION "Use AVFoundation for Video I/O (iOS/Mac)" ON
 230   VISIBLE_IF APPLE
 231   VERIFY HAVE_AVFOUNDATION)
 232 OCV_OPTION(WITH_CAP_IOS "Enable iOS video capture" ON
 233   VISIBLE_IF IOS
 234   VERIFY HAVE_CAP_IOS)
 235 OCV_OPTION(WITH_CAROTENE "Use NVidia carotene acceleration library for ARM platform" ON
 236   VISIBLE_IF (ARM OR AARCH64) AND NOT IOS AND NOT (CMAKE_VERSION VERSION_LESS "2.8.11"))
 237 OCV_OPTION(WITH_CPUFEATURES "Use cpufeatures Android library" ON
 238   VISIBLE_IF ANDROID
 239   VERIFY HAVE_CPUFEATURES)
 240 OCV_OPTION(WITH_VTK "Include VTK library support (and build opencv_viz module eiher)" ON
 241   VISIBLE_IF NOT ANDROID AND NOT IOS AND NOT WINRT AND NOT CMAKE_CROSSCOMPILING
 242   VERIFY HAVE_VTK)
 243 OCV_OPTION(WITH_CUDA "Include NVidia Cuda Runtime support" OFF
 244   VISIBLE_IF NOT IOS AND NOT WINRT
 245   VERIFY HAVE_CUDA)
 246 OCV_OPTION(WITH_CUFFT "Include NVidia Cuda Fast Fourier Transform (FFT) library support" WITH_CUDA
 247   VISIBLE_IF WITH_CUDA
 248   VERIFY HAVE_CUFFT)
 249 OCV_OPTION(WITH_CUBLAS "Include NVidia Cuda Basic Linear Algebra Subprograms (BLAS) library support" WITH_CUDA
 250   VISIBLE_IF WITH_CUDA
 251   VERIFY HAVE_CUBLAS)
 252 OCV_OPTION(WITH_CUDNN "Include NVIDIA CUDA Deep Neural Network (cuDNN) library support" WITH_CUDA
 253   VISIBLE_IF WITH_CUDA
 254   VERIFY HAVE_CUDNN)
 255 OCV_OPTION(WITH_NVCUVID "Include NVidia Video Decoding library support" OFF  # disabled, details: https://github.com/opencv/opencv/issues/14850
 256   VISIBLE_IF WITH_CUDA
 257   VERIFY HAVE_NVCUVID)
 258 OCV_OPTION(WITH_EIGEN "Include Eigen2/Eigen3 support" (NOT CV_DISABLE_OPTIMIZATION AND NOT CMAKE_CROSSCOMPILING)
 259   VISIBLE_IF NOT WINRT
 260   VERIFY HAVE_EIGEN)
 261 OCV_OPTION(WITH_FFMPEG "Include FFMPEG support" (NOT ANDROID)
 262   VISIBLE_IF NOT IOS AND NOT WINRT
 263   VERIFY HAVE_FFMPEG)
 264 OCV_OPTION(WITH_GSTREAMER "Include Gstreamer support" ON
 265   VISIBLE_IF NOT ANDROID AND NOT IOS AND NOT WINRT
 266   VERIFY HAVE_GSTREAMER AND GSTREAMER_VERSION VERSION_GREATER "0.99")
 267 OCV_OPTION(WITH_GTK "Include GTK support" ON
 268   VISIBLE_IF UNIX AND NOT APPLE AND NOT ANDROID
 269   VERIFY HAVE_GTK)
 270 OCV_OPTION(WITH_GTK_2_X "Use GTK version 2" OFF
 271   VISIBLE_IF UNIX AND NOT APPLE AND NOT ANDROID
 272   VERIFY HAVE_GTK AND NOT HAVE_GTK3)
 273 OCV_OPTION(WITH_IPP "Include Intel IPP support" (NOT MINGW AND NOT CV_DISABLE_OPTIMIZATION)
 274   VISIBLE_IF (X86_64 OR X86) AND NOT WINRT AND NOT IOS
 275   VERIFY HAVE_IPP)
 276 OCV_OPTION(WITH_HALIDE "Include Halide support" OFF
 277   VISIBLE_IF TRUE
 278   VERIFY HAVE_HALIDE)
 279 OCV_OPTION(WITH_VULKAN "Include Vulkan support" OFF
 280   VISIBLE_IF TRUE
 281   VERIFY HAVE_VULKAN)
 282 OCV_OPTION(WITH_INF_ENGINE "Include Intel Inference Engine support" OFF
 283   VISIBLE_IF TRUE
 284   VERIFY INF_ENGINE_TARGET)
 285 OCV_OPTION(WITH_NGRAPH "Include nGraph support" WITH_INF_ENGINE
 286   VISIBLE_IF TRUE
 287   VERIFY TARGET ngraph::ngraph)
 288 OCV_OPTION(WITH_JASPER "Include JPEG2K support" ON
 289   VISIBLE_IF NOT IOS
 290   VERIFY HAVE_JASPER)
 291 OCV_OPTION(WITH_JPEG "Include JPEG support" ON
 292   VISIBLE_IF TRUE
 293   VERIFY HAVE_JPEG)
 294 OCV_OPTION(WITH_WEBP "Include WebP support" ON
 295   VISIBLE_IF NOT WINRT
 296   VERIFY HAVE_WEBP)
 297 OCV_OPTION(WITH_OPENEXR "Include ILM support via OpenEXR" BUILD_OPENEXR OR NOT CMAKE_CROSSCOMPILING
 298   VISIBLE_IF NOT APPLE_FRAMEWORK AND NOT WINRT
 299   VERIFY HAVE_OPENEXR)
 300 OCV_OPTION(WITH_OPENGL "Include OpenGL support" OFF
 301   VISIBLE_IF NOT ANDROID AND NOT WINRT
 302   VERIFY HAVE_OPENGL)
 303 OCV_OPTION(WITH_OPENVX "Include OpenVX support" OFF
 304   VISIBLE_IF TRUE
 305   VERIFY HAVE_OPENVX)
 306 OCV_OPTION(WITH_OPENNI "Include OpenNI support" OFF
 307   VISIBLE_IF NOT ANDROID AND NOT IOS AND NOT WINRT
 308   VERIFY HAVE_OPENNI)
 309 OCV_OPTION(WITH_OPENNI2 "Include OpenNI2 support" OFF
 310   VISIBLE_IF NOT ANDROID AND NOT IOS AND NOT WINRT
 311   VERIFY HAVE_OPENNI2)
 312 OCV_OPTION(WITH_PNG "Include PNG support" ON
 313   VISIBLE_IF TRUE
 314   VERIFY HAVE_PNG)
 315 OCV_OPTION(WITH_GDCM "Include DICOM support" OFF
 316   VISIBLE_IF TRUE
 317   VERIFY HAVE_GDCM)
 318 OCV_OPTION(WITH_PVAPI "Include Prosilica GigE support" OFF
 319   VISIBLE_IF NOT ANDROID AND NOT IOS AND NOT WINRT
 320   VERIFY HAVE_PVAPI)
 321 OCV_OPTION(WITH_ARAVIS "Include Aravis GigE support" OFF
 322   VISIBLE_IF NOT ANDROID AND NOT IOS AND NOT WINRT AND NOT WIN32
 323   VERIFY HAVE_ARAVIS_API)
 324 OCV_OPTION(WITH_QT "Build with Qt Backend support" OFF
 325   VISIBLE_IF NOT ANDROID AND NOT IOS AND NOT WINRT
 326   VERIFY HAVE_QT)
 327 OCV_OPTION(WITH_WIN32UI "Build with Win32 UI Backend support" ON
 328   VISIBLE_IF WIN32 AND NOT WINRT
 329   VERIFY HAVE_WIN32UI)
 330 OCV_OPTION(WITH_TBB "Include Intel TBB support" OFF
 331   VISIBLE_IF NOT IOS AND NOT WINRT
 332   VERIFY HAVE_TBB)
 333 OCV_OPTION(WITH_HPX "Include Ste||ar Group HPX support" OFF
 334   VISIBLE_IF TRUE
 335   VERIFY HAVE_HPX)
 336 OCV_OPTION(WITH_OPENMP "Include OpenMP support" OFF
 337   VISIBLE_IF TRUE
 338   VERIFY HAVE_OPENMP)
 339 OCV_OPTION(WITH_PTHREADS_PF "Use pthreads-based parallel_for" ON
 340   VISIBLE_IF NOT WIN32 OR MINGW
 341   VERIFY HAVE_PTHREADS_PF)
 342 OCV_OPTION(WITH_TIFF "Include TIFF support" ON
 343   VISIBLE_IF NOT IOS
 344   VERIFY HAVE_TIFF)
 345 OCV_OPTION(WITH_V4L "Include Video 4 Linux support" ON
 346   VISIBLE_IF UNIX AND NOT ANDROID AND NOT APPLE
 347   VERIFY HAVE_CAMV4L OR HAVE_CAMV4L2 OR HAVE_VIDEOIO)
 348 OCV_OPTION(WITH_DSHOW "Build VideoIO with DirectShow support" ON
 349   VISIBLE_IF WIN32 AND NOT ARM AND NOT WINRT
 350   VERIFY HAVE_DSHOW)
 351 OCV_OPTION(WITH_MSMF "Build VideoIO with Media Foundation support" NOT MINGW
 352   VISIBLE_IF WIN32
 353   VERIFY HAVE_MSMF)
 354 OCV_OPTION(WITH_MSMF_DXVA "Enable hardware acceleration in Media Foundation backend" WITH_MSMF
 355   VISIBLE_IF WIN32
 356   VERIFY HAVE_MSMF_DXVA)
 357 OCV_OPTION(WITH_XIMEA "Include XIMEA cameras support" OFF
 358   VISIBLE_IF NOT ANDROID AND NOT WINRT
 359   VERIFY HAVE_XIMEA)
 360 OCV_OPTION(WITH_XINE "Include Xine support (GPL)" OFF
 361   VISIBLE_IF UNIX AND NOT APPLE AND NOT ANDROID
 362   VERIFY HAVE_XINE)
 363 OCV_OPTION(WITH_CLP "Include Clp support (EPL)" OFF
 364   VISIBLE_IF TRUE
 365   VERIFY HAVE_CLP)
 366 OCV_OPTION(WITH_OPENCL "Include OpenCL Runtime support" (NOT ANDROID AND NOT CV_DISABLE_OPTIMIZATION)
 367   VISIBLE_IF NOT IOS AND NOT WINRT
 368   VERIFY HAVE_OPENCL)
 369 OCV_OPTION(WITH_OPENCL_SVM "Include OpenCL Shared Virtual Memory support" OFF
 370   VISIBLE_IF TRUE
 371   VERIFY HAVE_OPENCL_SVM) # experimental
 372 OCV_OPTION(WITH_OPENCLAMDFFT "Include AMD OpenCL FFT library support" ON
 373   VISIBLE_IF NOT ANDROID AND NOT IOS AND NOT WINRT
 374   VERIFY HAVE_CLAMDFFT)
 375 OCV_OPTION(WITH_OPENCLAMDBLAS "Include AMD OpenCL BLAS library support" ON
 376   VISIBLE_IF NOT ANDROID AND NOT IOS AND NOT WINRT
 377   VERIFY HAVE_CLAMDBLAS)
 378 OCV_OPTION(WITH_DIRECTX "Include DirectX support" ON
 379   VISIBLE_IF WIN32 AND NOT WINRT
 380   VERIFY HAVE_DIRECTX)
 381 OCV_OPTION(WITH_OPENCL_D3D11_NV "Include NVIDIA OpenCL D3D11 support" WITH_DIRECTX
 382   VISIBLE_IF WIN32 AND NOT WINRT
 383   VERIFY HAVE_OPENCL_D3D11_NV)
 384 OCV_OPTION(WITH_LIBREALSENSE "Include Intel librealsense support" OFF
 385   VISIBLE_IF NOT WITH_INTELPERC
 386   VERIFY HAVE_LIBREALSENSE)
 387 OCV_OPTION(WITH_VA "Include VA support" OFF
 388   VISIBLE_IF UNIX AND NOT ANDROID
 389   VERIFY HAVE_VA)
 390 OCV_OPTION(WITH_VA_INTEL "Include Intel VA-API/OpenCL support" OFF
 391   VISIBLE_IF UNIX AND NOT ANDROID
 392   VERIFY HAVE_VA_INTEL)
 393 OCV_OPTION(WITH_MFX "Include Intel Media SDK support" OFF
 394   VISIBLE_IF (UNIX AND NOT ANDROID) OR (WIN32 AND NOT WINRT AND NOT MINGW)
 395   VERIFY HAVE_MFX)
 396 OCV_OPTION(WITH_GDAL "Include GDAL Support" OFF
 397   VISIBLE_IF NOT ANDROID AND NOT IOS AND NOT WINRT
 398   VERIFY HAVE_GDAL)
 399 OCV_OPTION(WITH_GPHOTO2 "Include gPhoto2 library support" OFF
 400   VISIBLE_IF UNIX AND NOT ANDROID AND NOT IOS
 401   VERIFY HAVE_GPHOTO2)
 402 OCV_OPTION(WITH_LAPACK "Include Lapack library support" (NOT CV_DISABLE_OPTIMIZATION)
 403   VISIBLE_IF NOT ANDROID AND NOT IOS
 404   VERIFY HAVE_LAPACK)
 405 OCV_OPTION(WITH_ITT "Include Intel ITT support" ON
 406   VISIBLE_IF NOT APPLE_FRAMEWORK
 407   VERIFY HAVE_ITT)
 408 OCV_OPTION(WITH_PROTOBUF "Enable libprotobuf" ON
 409   VISIBLE_IF TRUE
 410   VERIFY HAVE_PROTOBUF)
 411 OCV_OPTION(WITH_IMGCODEC_HDR "Include HDR support" ON
 412   VISIBLE_IF TRUE
 413   VERIFY HAVE_IMGCODEC_HDR)
 414 OCV_OPTION(WITH_IMGCODEC_SUNRASTER "Include SUNRASTER support" ON
 415   VISIBLE_IF TRUE
 416   VERIFY HAVE_IMGCODEC_SUNRASTER)
 417 OCV_OPTION(WITH_IMGCODEC_PXM "Include PNM (PBM,PGM,PPM) and PAM formats support" ON
 418   VISIBLE_IF TRUE
 419   VERIFY HAVE_IMGCODEC_PXM)
 420 OCV_OPTION(WITH_IMGCODEC_PFM "Include PFM formats support" ON
 421   VISIBLE_IF TRUE
 422   VERIFY HAVE_IMGCODEC_PFM)
 423 OCV_OPTION(WITH_QUIRC "Include library QR-code decoding" ON
 424   VISIBLE_IF TRUE
 425   VERIFY HAVE_QUIRC)
 426 OCV_OPTION(WITH_ANDROID_MEDIANDK "Use Android Media NDK for Video I/O (Android)" (ANDROID_NATIVE_API_LEVEL GREATER 20)
 427   VISIBLE_IF ANDROID
 428   VERIFY HAVE_ANDROID_MEDIANDK)
 429 OCV_OPTION(WITH_TENGINE "Include Arm Inference Tengine support" OFF
 430   VISIBLE_IF (ARM OR AARCH64) AND (UNIX OR ANDROID) AND NOT IOS
 431   VERIFY HAVE_TENGINE)
 432
 433 # OpenCV build components
 434 # ===================================================
 435 OCV_OPTION(BUILD_SHARED_LIBS        "Build shared libraries (.dll/.so) instead of static ones (.lib/.a)" NOT (ANDROID OR APPLE_FRAMEWORK) )
 436 OCV_OPTION(BUILD_opencv_apps        "Build utility applications (used for example to train classifiers)" (NOT ANDROID AND NOT WINRT) IF (NOT APPLE_FRAMEWORK) )
 437 OCV_OPTION(BUILD_opencv_js          "Build JavaScript bindings by Emscripten" OFF )
 438 OCV_OPTION(BUILD_ANDROID_PROJECTS   "Build Android projects providing .apk files" ON  IF ANDROID )
 439 OCV_OPTION(BUILD_ANDROID_EXAMPLES   "Build examples for Android platform"         ON  IF ANDROID )
 440 OCV_OPTION(BUILD_DOCS               "Create build rules for OpenCV Documentation" OFF  IF (NOT WINRT AND NOT APPLE_FRAMEWORK))
 441 OCV_OPTION(BUILD_EXAMPLES           "Build all examples"                          OFF )
 442 OCV_OPTION(BUILD_PACKAGE            "Enables 'make package_source' command"       ON  IF NOT WINRT)
 443 OCV_OPTION(BUILD_PERF_TESTS         "Build performance tests"                     NOT INSTALL_CREATE_DISTRIB  IF (NOT APPLE_FRAMEWORK) )
 444 OCV_OPTION(BUILD_TESTS              "Build accuracy & regression tests"           NOT INSTALL_CREATE_DISTRIB  IF (NOT APPLE_FRAMEWORK) )
 445 OCV_OPTION(BUILD_WITH_DEBUG_INFO    "Include debug info into release binaries ('OFF' means default settings)" OFF )
 446 OCV_OPTION(BUILD_WITH_STATIC_CRT    "Enables use of statically linked CRT for statically linked OpenCV" ON IF MSVC )
 447 OCV_OPTION(BUILD_WITH_DYNAMIC_IPP   "Enables dynamic linking of IPP (only for standalone IPP)" OFF )
 448 OCV_OPTION(BUILD_FAT_JAVA_LIB       "Create Java wrapper exporting all functions of OpenCV library (requires static build of OpenCV modules)" ANDROID IF NOT BUILD_SHARED_LIBS)
 449 OCV_OPTION(BUILD_ANDROID_SERVICE    "Build OpenCV Manager for Google Play" OFF IF ANDROID )
 450 OCV_OPTION(BUILD_CUDA_STUBS         "Build CUDA modules stubs when no CUDA SDK" OFF  IF (NOT APPLE_FRAMEWORK) )
 451 OCV_OPTION(BUILD_JAVA               "Enable Java support"                         (ANDROID OR NOT CMAKE_CROSSCOMPILING)  IF (ANDROID OR (NOT APPLE_FRAMEWORK AND NOT WINRT)) )
 452
 453 # OpenCV installation options
 454 # ===================================================
 455 OCV_OPTION(INSTALL_CREATE_DISTRIB   "Change install rules to build the distribution package" OFF )
 456 OCV_OPTION(INSTALL_C_EXAMPLES       "Install C examples"        OFF )
 457 OCV_OPTION(INSTALL_PYTHON_EXAMPLES  "Install Python examples"   OFF )
 458 OCV_OPTION(INSTALL_ANDROID_EXAMPLES "Install Android examples"  OFF IF ANDROID )
 459 OCV_OPTION(INSTALL_TO_MANGLED_PATHS "Enables mangled install paths, that help with side by side installs." OFF IF (UNIX AND NOT ANDROID AND NOT APPLE_FRAMEWORK AND BUILD_SHARED_LIBS) )
 460 OCV_OPTION(INSTALL_TESTS            "Install accuracy and performance test binaries and test data" OFF)
 461
 462 # OpenCV build options
 463 # ===================================================
 464 OCV_OPTION(ENABLE_CCACHE              "Use ccache"                                               (UNIX AND NOT IOS AND (CMAKE_GENERATOR MATCHES "Makefile" OR CMAKE_GENERATOR MATCHES "Ninja")) )
 465 OCV_OPTION(ENABLE_PRECOMPILED_HEADERS "Use precompiled headers"                                  MSVC IF (MSVC OR (NOT IOS AND NOT CMAKE_CROSSCOMPILING) ) )
 466 OCV_OPTION(ENABLE_SOLUTION_FOLDERS    "Solution folder in Visual Studio or in other IDEs"        (MSVC_IDE OR CMAKE_GENERATOR MATCHES Xcode) )
 467 OCV_OPTION(ENABLE_PROFILING           "Enable profiling in the GCC compiler (Add flags: -g -pg)" OFF  IF CV_GCC )
 468 OCV_OPTION(ENABLE_COVERAGE            "Enable coverage collection with  GCov"                    OFF  IF CV_GCC )
 469 OCV_OPTION(OPENCV_ENABLE_MEMORY_SANITIZER "Better support for memory/address sanitizers"         OFF)
 470 OCV_OPTION(ENABLE_OMIT_FRAME_POINTER  "Enable -fomit-frame-pointer for GCC"                      ON   IF CV_GCC )
 471 OCV_OPTION(ENABLE_POWERPC             "Enable PowerPC for GCC"                                   ON   IF (CV_GCC AND CMAKE_SYSTEM_PROCESSOR MATCHES powerpc.*) )
 472 OCV_OPTION(ENABLE_FAST_MATH           "Enable compiler options for fast math optimizations on FP computations (not recommended)" OFF)
 473 if(NOT IOS AND (NOT ANDROID OR OPENCV_ANDROID_USE_LEGACY_FLAGS))  # Use CPU_BASELINE instead
 474 OCV_OPTION(ENABLE_NEON                "Enable NEON instructions"                                 (NEON OR ANDROID_ARM_NEON OR AARCH64) IF (CV_GCC OR CV_CLANG) AND (ARM OR AARCH64 OR IOS) )
 475 OCV_OPTION(ENABLE_VFPV3               "Enable VFPv3-D32 instructions"                            OFF  IF (CV_GCC OR CV_CLANG) AND (ARM OR AARCH64 OR IOS) )
 476 endif()
 477 OCV_OPTION(ENABLE_NOISY_WARNINGS      "Show all warnings even if they are too noisy"             OFF )
 478 OCV_OPTION(OPENCV_WARNINGS_ARE_ERRORS "Treat warnings as errors"                                 OFF )
 479 OCV_OPTION(ANDROID_EXAMPLES_WITH_LIBS "Build binaries of Android examples with native libraries" OFF  IF ANDROID )
 480 OCV_OPTION(ENABLE_IMPL_COLLECTION     "Collect implementation data on function call"             OFF )
 481 OCV_OPTION(ENABLE_INSTRUMENTATION     "Instrument functions to collect calls trace and performance" OFF )
 482 OCV_OPTION(ENABLE_GNU_STL_DEBUG       "Enable GNU STL Debug mode (defines _GLIBCXX_DEBUG)"       OFF IF ((NOT CMAKE_VERSION VERSION_LESS "2.8.11") AND CV_GCC) )
 483 OCV_OPTION(ENABLE_BUILD_HARDENING     "Enable hardening of the resulting binaries (against security attacks, detects memory corruption, etc)" OFF)
 484 OCV_OPTION(ENABLE_LTO                 "Enable Link Time Optimization" OFF IF CV_GCC OR MSVC)
 485 OCV_OPTION(ENABLE_THIN_LTO            "Enable Thin LTO" OFF IF CV_CLANG)
 486 OCV_OPTION(GENERATE_ABI_DESCRIPTOR    "Generate XML file for abi_compliance_checker tool" OFF IF UNIX)
 487 OCV_OPTION(OPENCV_GENERATE_PKGCONFIG  "Generate .pc file for pkg-config build tool (deprecated)" OFF)
 488 OCV_OPTION(CV_ENABLE_INTRINSICS       "Use intrinsic-based optimized code" ON )
 489 OCV_OPTION(CV_DISABLE_OPTIMIZATION    "Disable explicit optimized code (dispatched code/intrinsics/loop unrolling/etc)" OFF )
 490 OCV_OPTION(CV_TRACE                   "Enable OpenCV code trace" ON)
 491 OCV_OPTION(OPENCV_GENERATE_SETUPVARS  "Generate setup_vars* scripts" ON IF (NOT ANDROID AND NOT APPLE_FRAMEWORK) )
 492 OCV_OPTION(ENABLE_CONFIG_VERIFICATION "Fail build if actual configuration doesn't match requested (WITH_XXX != HAVE_XXX)" OFF)
 493 OCV_OPTION(OPENCV_ENABLE_MEMALIGN     "Enable posix_memalign or memalign usage" ON)
 494
 495 OCV_OPTION(ENABLE_PYLINT              "Add target with Pylint checks"                            (BUILD_DOCS OR BUILD_EXAMPLES) IF (NOT CMAKE_CROSSCOMPILING AND NOT APPLE_FRAMEWORK) )
 496 OCV_OPTION(ENABLE_FLAKE8              "Add target with Python flake8 checker"                    (BUILD_DOCS OR BUILD_EXAMPLES) IF (NOT CMAKE_CROSSCOMPILING AND NOT APPLE_FRAMEWORK) )
 497
 498 if(ENABLE_IMPL_COLLECTION)
 499   add_definitions(-DCV_COLLECT_IMPL_DATA)
 500 endif()
 501
 502 set(OPENCV_MATHJAX_RELPATH "https://cdnjs.cloudflare.com/ajax/libs/mathjax/2.7.0" CACHE STRING "URI to a MathJax installation")
 503
 504 # ----------------------------------------------------------------------------
 505 #  Get actual OpenCV version number from sources
 506 # ----------------------------------------------------------------------------
 507 include(cmake/OpenCVVersion.cmake)
 508
 509 ocv_cmake_hook(POST_OPTIONS)
 510
 511 # ----------------------------------------------------------------------------
 512 #  Build & install layouts
 513 # ----------------------------------------------------------------------------
 514
 515 if(OPENCV_TEST_DATA_PATH)
 516   get_filename_component(OPENCV_TEST_DATA_PATH ${OPENCV_TEST_DATA_PATH} ABSOLUTE)
 517 endif()
 518
 519 # Save libs and executables in the same place
 520 set(EXECUTABLE_OUTPUT_PATH "${CMAKE_BINARY_DIR}/bin" CACHE PATH "Output directory for applications")
 521
 522 if(ANDROID)
 523   set(LIBRARY_OUTPUT_PATH                "${OpenCV_BINARY_DIR}/lib/${ANDROID_NDK_ABI_NAME}")
 524   ocv_update(3P_LIBRARY_OUTPUT_PATH      "${OpenCV_BINARY_DIR}/3rdparty/lib/${ANDROID_NDK_ABI_NAME}")
 525 else()
 526   set(LIBRARY_OUTPUT_PATH                "${OpenCV_BINARY_DIR}/lib")
 527   ocv_update(3P_LIBRARY_OUTPUT_PATH      "${OpenCV_BINARY_DIR}/3rdparty/lib")
 528 endif()
 529
 530 if(ANDROID)
 531   if(ANDROID_ABI MATCHES "NEON")
 532     set(ENABLE_NEON ON)
 533   endif()
 534   if(ANDROID_ABI MATCHES "VFPV3")
 535     set(ENABLE_VFPV3 ON)
 536   endif()
 537 endif()
 538
 539 if(WIN32)
 540   # Postfix of DLLs:
 541   ocv_update(OPENCV_DLLVERSION "${OPENCV_VERSION_MAJOR}${OPENCV_VERSION_MINOR}${OPENCV_VERSION_PATCH}")
 542   ocv_update(OPENCV_DEBUG_POSTFIX d)
 543 else()
 544   # Postfix of so's:
 545   ocv_update(OPENCV_DLLVERSION "")
 546   ocv_update(OPENCV_DEBUG_POSTFIX "")
 547 endif()
 548
 549 if(DEFINED CMAKE_DEBUG_POSTFIX)
 550   set(OPENCV_DEBUG_POSTFIX "${CMAKE_DEBUG_POSTFIX}")
 551 endif()
 552
 553 if((INSTALL_CREATE_DISTRIB AND BUILD_SHARED_LIBS AND NOT DEFINED BUILD_opencv_world) OR APPLE_FRAMEWORK)
 554   set(BUILD_opencv_world ON CACHE INTERNAL "")
 555 endif()
 556
 557 include(cmake/OpenCVInstallLayout.cmake)
 558
 559 # ----------------------------------------------------------------------------
 560 #  Path for build/platform -specific headers
 561 # ----------------------------------------------------------------------------
 562 ocv_update(OPENCV_CONFIG_FILE_INCLUDE_DIR "${CMAKE_BINARY_DIR}/" CACHE PATH "Where to create the platform-dependant cvconfig.h")
 563 ocv_include_directories(${OPENCV_CONFIG_FILE_INCLUDE_DIR})
 564
 565 # ----------------------------------------------------------------------------
 566 #  Path for additional modules
 567 # ----------------------------------------------------------------------------
 568 set(OPENCV_EXTRA_MODULES_PATH "" CACHE PATH "Where to look for additional OpenCV modules (can be ;-separated list of paths)")
 569
 570 # ----------------------------------------------------------------------------
 571 #  Autodetect if we are in a GIT repository
 572 # ----------------------------------------------------------------------------
 573 find_host_package(Git QUIET)
 574
 575 if(NOT DEFINED OPENCV_VCSVERSION AND GIT_FOUND)
 576   ocv_git_describe(OPENCV_VCSVERSION "${OpenCV_SOURCE_DIR}")
 577 elseif(NOT DEFINED OPENCV_VCSVERSION)
 578   # We don't have git:
 579   set(OPENCV_VCSVERSION "unknown")
 580 endif()
 581
 582
 583 # ----------------------------------------------------------------------------
 584 # OpenCV compiler and linker options
 585 # ----------------------------------------------------------------------------
 586 # In case of Makefiles if the user does not setup CMAKE_BUILD_TYPE, assume it's Release:
 587 if(CMAKE_GENERATOR MATCHES "Makefiles|Ninja" AND "${CMAKE_BUILD_TYPE}" STREQUAL "")
 588   set(CMAKE_BUILD_TYPE Release)
 589 endif()
 590
 591 ocv_cmake_hook(POST_CMAKE_BUILD_OPTIONS)
 592
 593 # --- Python Support ---
 594 if(NOT IOS)
 595   include(cmake/OpenCVDetectPython.cmake)
 596 endif()
 597
 598 include(cmake/OpenCVCompilerOptions.cmake)
 599
 600 ocv_cmake_hook(POST_COMPILER_OPTIONS)
 601
 602 # ----------------------------------------------------------------------------
 603 #       CHECK FOR SYSTEM LIBRARIES, OPTIONS, ETC..
 604 # ----------------------------------------------------------------------------
 605 if(UNIX)
 606   if(NOT APPLE_FRAMEWORK OR OPENCV_ENABLE_PKG_CONFIG)
 607     if(CMAKE_CROSSCOMPILING AND NOT DEFINED ENV{PKG_CONFIG_LIBDIR} AND NOT DEFINED ENV{PKG_CONFIG_SYSROOT_DIR}
 608         AND NOT OPENCV_ENABLE_PKG_CONFIG
 609     )
 610       if(NOT PkgConfig_FOUND)
 611         message(STATUS "OpenCV disables pkg-config to avoid using of host libraries. Consider using PKG_CONFIG_LIBDIR to specify target SYSROOT")
 612       elseif(OPENCV_SKIP_PKG_CONFIG_WARNING)
 613         message(WARNING "pkg-config is enabled in cross-compilation mode without defining of PKG_CONFIG_LIBDIR environment variable. This may lead to misconfigured host-based dependencies.")
 614       endif()
 615     elseif(OPENCV_DISABLE_PKG_CONFIG)
 616       if(PkgConfig_FOUND)
 617         message(WARNING "OPENCV_DISABLE_PKG_CONFIG flag has no effect")
 618       endif()
 619     else()
 620       find_package(PkgConfig QUIET)
 621     endif()
 622   endif()
 623   include(CheckFunctionExists)
 624   include(CheckIncludeFile)
 625   include(CheckSymbolExists)
 626
 627   if(NOT APPLE)
 628     CHECK_INCLUDE_FILE(pthread.h HAVE_PTHREAD)
 629     if(ANDROID)
 630       set(OPENCV_LINKER_LIBS ${OPENCV_LINKER_LIBS} dl m log)
 631     elseif(CMAKE_SYSTEM_NAME MATCHES "FreeBSD|NetBSD|DragonFly|OpenBSD|Haiku")
 632       set(OPENCV_LINKER_LIBS ${OPENCV_LINKER_LIBS} m pthread)
 633     elseif(EMSCRIPTEN)
 634       # no need to link to system libs with emscripten
 635     else()
 636       set(OPENCV_LINKER_LIBS ${OPENCV_LINKER_LIBS} dl m pthread rt)
 637     endif()
 638   else()
 639     set(HAVE_PTHREAD 1)
 640   endif()
 641
 642   if(OPENCV_ENABLE_MEMALIGN)
 643     CHECK_SYMBOL_EXISTS(posix_memalign stdlib.h HAVE_POSIX_MEMALIGN)
 644     CHECK_INCLUDE_FILE(malloc.h HAVE_MALLOC_H)
 645     if(HAVE_MALLOC_H)
 646       CHECK_SYMBOL_EXISTS(memalign malloc.h HAVE_MEMALIGN)
 647     endif()
 648     # TODO:
 649     # - _aligned_malloc() on Win32
 650     # - std::aligned_alloc() C++17 / C11
 651   endif()
 652 endif()
 653
 654 include(cmake/OpenCVPCHSupport.cmake)
 655 include(cmake/OpenCVModule.cmake)
 656
 657 # ----------------------------------------------------------------------------
 658 #  Detect endianness of build platform
 659 # ----------------------------------------------------------------------------
 660
 661 if(IOS)
 662   # test_big_endian needs try_compile, which doesn't work for iOS
 663   # http://public.kitware.com/Bug/view.php?id=12288
 664   set(WORDS_BIGENDIAN 0)
 665 else()
 666   include(TestBigEndian)
 667   test_big_endian(WORDS_BIGENDIAN)
 668 endif()
 669
 670 # ----------------------------------------------------------------------------
 671 #  Detect 3rd-party libraries
 672 # ----------------------------------------------------------------------------
 673
 674 if(ANDROID AND WITH_CPUFEATURES)
 675   add_subdirectory(3rdparty/cpufeatures)
 676   set(HAVE_CPUFEATURES 1)
 677 endif()
 678
 679 include(cmake/OpenCVFindFrameworks.cmake)
 680
 681 include(cmake/OpenCVFindLibsGrfmt.cmake)
 682 include(cmake/OpenCVFindLibsGUI.cmake)
 683 include(cmake/OpenCVFindLibsVideo.cmake)
 684 include(cmake/OpenCVFindLibsPerf.cmake)
 685 include(cmake/OpenCVFindLAPACK.cmake)
 686 include(cmake/OpenCVFindProtobuf.cmake)
 687 if(WITH_TENGINE)
 688   include(cmake/OpenCVFindTengine.cmake)
 689 endif()
 690
 691 # ----------------------------------------------------------------------------
 692 #  Detect other 3rd-party libraries/tools
 693 # ----------------------------------------------------------------------------
 694
 695 # --- Java Support ---
 696 if(BUILD_JAVA)
 697   if(ANDROID)
 698     include(cmake/android/OpenCVDetectAndroidSDK.cmake)
 699   else()
 700     include(cmake/OpenCVDetectApacheAnt.cmake)
 701     find_package(JNI)
 702   endif()
 703 endif()
 704
 705 if(ENABLE_PYLINT AND PYTHON_DEFAULT_AVAILABLE)
 706   include(cmake/OpenCVPylint.cmake)
 707 endif()
 708 if(ENABLE_FLAKE8 AND PYTHON_DEFAULT_AVAILABLE)
 709   find_package(Flake8 QUIET)
 710   if(NOT FLAKE8_FOUND OR NOT FLAKE8_EXECUTABLE)
 711     include("${CMAKE_CURRENT_LIST_DIR}/cmake/FindFlake8.cmake")
 712   endif()
 713   if(FLAKE8_FOUND)
 714     add_custom_target(check_flake8
 715         COMMAND "${FLAKE8_EXECUTABLE}" . --count --select=E9,E901,E999,F821,F822,F823 --show-source --statistics --exclude='.git,__pycache__,*.config.py,svgfig.py'
 716         WORKING_DIRECTORY "${OpenCV_SOURCE_DIR}"
 717         COMMENT "Running flake8"
 718     )
 719   endif()
 720 endif()
 721
 722
 723 if(ANDROID AND ANDROID_EXECUTABLE AND ANT_EXECUTABLE AND (ANT_VERSION VERSION_GREATER 1.7) AND (ANDROID_TOOLS_Pkg_Revision GREATER 13))
 724   SET(CAN_BUILD_ANDROID_PROJECTS TRUE)
 725 else()
 726   SET(CAN_BUILD_ANDROID_PROJECTS FALSE)
 727 endif()
 728
 729 # --- OpenCL ---
 730 if(WITH_OPENCL)
 731   include(cmake/OpenCVDetectOpenCL.cmake)
 732 endif()
 733
 734 # --- Halide ---
 735 if(WITH_HALIDE)
 736   include(cmake/OpenCVDetectHalide.cmake)
 737 endif()
 738
 739 # --- VkCom ---
 740 if(WITH_VULKAN)
 741   include(cmake/OpenCVDetectVulkan.cmake)
 742 endif()
 743
 744 # --- Inference Engine ---
 745 if(WITH_INF_ENGINE)
 746   include(cmake/OpenCVDetectInferenceEngine.cmake)
 747 endif()
 748
 749 # --- DirectX ---
 750 if(WITH_DIRECTX)
 751   include(cmake/OpenCVDetectDirectX.cmake)
 752 endif()
 753
 754 if(WITH_VTK)
 755   include(cmake/OpenCVDetectVTK.cmake)
 756 endif()
 757
 758 if(WITH_OPENVX)
 759   include(cmake/FindOpenVX.cmake)
 760 endif()
 761
 762 if(WITH_QUIRC)
 763   add_subdirectory(3rdparty/quirc)
 764   set(HAVE_QUIRC TRUE)
 765 endif()
 766 # ----------------------------------------------------------------------------
 767 # OpenCV HAL
 768 # ----------------------------------------------------------------------------
 769 set(_hal_includes "")
 770 macro(ocv_hal_register HAL_LIBRARIES_VAR HAL_HEADERS_VAR HAL_INCLUDE_DIRS_VAR)
 771   # 1. libraries
 772   foreach (l ${${HAL_LIBRARIES_VAR}})
 773     if(NOT TARGET ${l})
 774       get_filename_component(l "${l}" ABSOLUTE)
 775     endif()
 776     list(APPEND OPENCV_HAL_LINKER_LIBS ${l})
 777   endforeach()
 778   # 2. headers
 779   foreach (h ${${HAL_HEADERS_VAR}})
 780     set(_hal_includes "${_hal_includes}\n#include \"${h}\"")
 781   endforeach()
 782   # 3. include paths
 783   ocv_include_directories(${${HAL_INCLUDE_DIRS_VAR}})
 784 endmacro()
 785
 786 if(NOT DEFINED OpenCV_HAL)
 787   set(OpenCV_HAL "OpenCV_HAL")
 788 endif()
 789
 790 if(HAVE_OPENVX)
 791   if(NOT ";${OpenCV_HAL};" MATCHES ";openvx;")
 792     set(OpenCV_HAL "openvx;${OpenCV_HAL}")
 793   endif()
 794 endif()
 795
 796 if(WITH_CAROTENE)
 797   ocv_debug_message(STATUS "Enable carotene acceleration")
 798   if(NOT ";${OpenCV_HAL};" MATCHES ";carotene;")
 799     set(OpenCV_HAL "carotene;${OpenCV_HAL}")
 800   endif()
 801 endif()
 802
 803 foreach(hal ${OpenCV_HAL})
 804   if(hal STREQUAL "carotene")
 805     if(";${CPU_BASELINE_FINAL};" MATCHES ";NEON;")
 806       add_subdirectory(3rdparty/carotene/hal)
 807       ocv_hal_register(CAROTENE_HAL_LIBRARIES CAROTENE_HAL_HEADERS CAROTENE_HAL_INCLUDE_DIRS)
 808       list(APPEND OpenCV_USED_HAL "carotene (ver ${CAROTENE_HAL_VERSION})")
 809     else()
 810       message(STATUS "Carotene: NEON is not available, disabling carotene...")
 811     endif()
 812   elseif(hal STREQUAL "openvx")
 813     add_subdirectory(3rdparty/openvx)
 814     ocv_hal_register(OPENVX_HAL_LIBRARIES OPENVX_HAL_HEADERS OPENVX_HAL_INCLUDE_DIRS)
 815     list(APPEND OpenCV_USED_HAL "openvx (ver ${OPENVX_HAL_VERSION})")
 816   else()
 817     ocv_debug_message(STATUS "OpenCV HAL: ${hal} ...")
 818     ocv_clear_vars(OpenCV_HAL_LIBRARIES OpenCV_HAL_HEADERS OpenCV_HAL_INCLUDE_DIRS)
 819     find_package(${hal} NO_MODULE QUIET)
 820     if(${hal}_FOUND)
 821       ocv_hal_register(OpenCV_HAL_LIBRARIES OpenCV_HAL_HEADERS OpenCV_HAL_INCLUDE_DIRS)
 822       list(APPEND OpenCV_USED_HAL "${hal} (ver ${${hal}_VERSION})")
 823     endif()
 824   endif()
 825 endforeach()
 826 configure_file("${OpenCV_SOURCE_DIR}/cmake/templates/custom_hal.hpp.in" "${CMAKE_BINARY_DIR}/custom_hal.hpp" @ONLY)
 827 unset(_hal_includes)
 828
 829
 830 # ----------------------------------------------------------------------------
 831 # Code trace support
 832 # ----------------------------------------------------------------------------
 833 if(CV_TRACE)
 834   include(cmake/OpenCVDetectTrace.cmake)
 835 endif()
 836
 837 ocv_cmake_hook(POST_DETECT_DEPENDECIES)  # typo, deprecated (2019-06)
 838 ocv_cmake_hook(POST_DETECT_DEPENDENCIES)
 839
 840 # ----------------------------------------------------------------------------
 841 # Solution folders:
 842 # ----------------------------------------------------------------------------
 843 if(ENABLE_SOLUTION_FOLDERS)
 844   set_property(GLOBAL PROPERTY USE_FOLDERS ON)
 845   set_property(GLOBAL PROPERTY PREDEFINED_TARGETS_FOLDER "CMakeTargets")
 846 endif()
 847
 848 # Extra OpenCV targets: uninstall, package_source, perf, etc.
 849 include(cmake/OpenCVExtraTargets.cmake)
 850
 851 # ----------------------------------------------------------------------------
 852 # Process subdirectories
 853 # ----------------------------------------------------------------------------
 854
 855 # opencv.hpp and legacy headers
 856 add_subdirectory(include)
 857
 858 # Enable compiler options for OpenCV modules/apps/samples only (ignore 3rdparty)
 859 ocv_add_modules_compiler_options()
 860
 861 # OpenCV modules
 862 add_subdirectory(modules)
 863
 864 # Generate targets for documentation
 865 add_subdirectory(doc)
 866
 867 # various data that is used by cv libraries and/or demo applications.
 868 add_subdirectory(data)
 869
 870 # extra applications
 871 if(BUILD_opencv_apps)
 872   add_subdirectory(apps)
 873 endif()
 874
 875 # examples
 876 if(BUILD_EXAMPLES OR BUILD_ANDROID_EXAMPLES OR INSTALL_ANDROID_EXAMPLES OR INSTALL_PYTHON_EXAMPLES OR INSTALL_C_EXAMPLES)
 877   add_subdirectory(samples)
 878 endif()
 879
 880 if(ANDROID)
 881   add_subdirectory(platforms/android/service)
 882 endif()
 883
 884 # ----------------------------------------------------------------------------
 885 # Finalization: generate configuration-based files
 886 # ----------------------------------------------------------------------------
 887
 888 ocv_cmake_hook(PRE_FINALIZE)
 889
 890 # Generate platform-dependent and configuration-dependent headers
 891 include(cmake/OpenCVGenHeaders.cmake)
 892
 893 # Generate opencv.pc for pkg-config command
 894 if(OPENCV_GENERATE_PKGCONFIG)
 895   include(cmake/OpenCVGenPkgconfig.cmake)
 896 endif()
 897
 898 # Generate OpenCV.mk for ndk-build (Android build tool)
 899 include(cmake/OpenCVGenAndroidMK.cmake)
 900
 901 # Generate OpenCVConfig.cmake and OpenCVConfig-version.cmake for cmake projects
 902 include(cmake/OpenCVGenConfig.cmake)
 903
 904 # Generate Info.plist for the IOS framework
 905 if(APPLE_FRAMEWORK)
 906   include(cmake/OpenCVGenInfoPlist.cmake)
 907 endif()
 908
 909 # Generate ABI descriptor
 910 include(cmake/OpenCVGenABI.cmake)
 911
 912 # Generate environment setup file
 913 if(INSTALL_TESTS AND OPENCV_TEST_DATA_PATH)
 914   if(ANDROID)
 915     get_filename_component(TEST_PATH ${OPENCV_TEST_INSTALL_PATH} DIRECTORY)
 916     configure_file("${CMAKE_CURRENT_SOURCE_DIR}/cmake/templates/opencv_run_all_tests_android.sh.in"
 917                    "${CMAKE_BINARY_DIR}/unix-install/opencv_run_all_tests.sh" @ONLY)
 918     install(PROGRAMS "${CMAKE_BINARY_DIR}/unix-install/opencv_run_all_tests.sh"
 919             DESTINATION ./ COMPONENT tests)
 920   elseif(WIN32)
 921     configure_file("${CMAKE_CURRENT_SOURCE_DIR}/cmake/templates/opencv_run_all_tests_windows.cmd.in"
 922                    "${CMAKE_BINARY_DIR}/win-install/opencv_run_all_tests.cmd" @ONLY)
 923     install(PROGRAMS "${CMAKE_BINARY_DIR}/win-install/opencv_run_all_tests.cmd"
 924             DESTINATION ${OPENCV_TEST_INSTALL_PATH} COMPONENT tests)
 925   elseif(UNIX)
 926     configure_file("${CMAKE_CURRENT_SOURCE_DIR}/cmake/templates/opencv_run_all_tests_unix.sh.in"
 927                    "${CMAKE_BINARY_DIR}/unix-install/opencv_run_all_tests.sh" @ONLY)
 928     install(PROGRAMS "${CMAKE_BINARY_DIR}/unix-install/opencv_run_all_tests.sh"
 929             DESTINATION ${OPENCV_TEST_INSTALL_PATH} COMPONENT tests)
 930   endif()
 931 endif()
 932
 933 if(NOT OPENCV_README_FILE)
 934   if(ANDROID)
 935     set(OPENCV_README_FILE ${CMAKE_CURRENT_SOURCE_DIR}/platforms/android/README.android)
 936   endif()
 937 endif()
 938
 939 if(NOT OPENCV_LICENSE_FILE)
 940   set(OPENCV_LICENSE_FILE ${CMAKE_CURRENT_SOURCE_DIR}/LICENSE)
 941 endif()
 942
 943 # for UNIX it does not make sense as LICENSE and readme will be part of the package automatically
 944 if(ANDROID OR NOT UNIX)
 945   install(FILES ${OPENCV_LICENSE_FILE}
 946         PERMISSIONS OWNER_READ GROUP_READ WORLD_READ
 947         DESTINATION ./ COMPONENT libs)
 948   if(OPENCV_README_FILE)
 949     install(FILES ${OPENCV_README_FILE}
 950             PERMISSIONS OWNER_READ GROUP_READ WORLD_READ
 951             DESTINATION ./ COMPONENT libs)
 952   endif()
 953 endif()
 954
 955 if(COMMAND ocv_pylint_finalize)
 956   ocv_pylint_add_directory(${CMAKE_CURRENT_LIST_DIR}/modules/python/test)
 957   ocv_pylint_add_directory(${CMAKE_CURRENT_LIST_DIR}/samples/python)
 958   ocv_pylint_add_directory(${CMAKE_CURRENT_LIST_DIR}/samples/dnn)
 959   ocv_pylint_add_directory_recurse(${CMAKE_CURRENT_LIST_DIR}/samples/python/tutorial_code)
 960   ocv_pylint_finalize()
 961 endif()
 962
 963 if(OPENCV_GENERATE_SETUPVARS)
 964   include(cmake/OpenCVGenSetupVars.cmake)
 965 endif()
 966
 967 # ----------------------------------------------------------------------------
 968 # Summary:
 969 # ----------------------------------------------------------------------------
 970 status("")
 971 status("General configuration for OpenCV ${OPENCV_VERSION} =====================================")
 972 if(OPENCV_VCSVERSION)
 973   status("  Version control:" ${OPENCV_VCSVERSION})
 974 endif()
 975 if(OPENCV_EXTRA_MODULES_PATH AND NOT BUILD_INFO_SKIP_EXTRA_MODULES)
 976   set(__dump_extra_header OFF)
 977   foreach(p ${OPENCV_EXTRA_MODULES_PATH})
 978     if(EXISTS ${p})
 979       if(NOT __dump_extra_header)
 980         set(__dump_extra_header ON)
 981         status("")
 982         status("  Extra modules:")
 983       else()
 984         status("")
 985       endif()
 986       ocv_git_describe(EXTRA_MODULES_VCSVERSION "${p}")
 987       status("    Location (extra):" ${p})
 988       status("    Version control (extra):" ${EXTRA_MODULES_VCSVERSION})
 989     endif()
 990   endforeach()
 991   unset(__dump_extra_header)
 992 endif()
 993
 994 # ========================== build platform ==========================
 995 status("")
 996 status("  Platform:")
 997 if(NOT DEFINED OPENCV_TIMESTAMP
 998     AND NOT CMAKE_VERSION VERSION_LESS 2.8.11
 999     AND NOT BUILD_INFO_SKIP_TIMESTAMP
1000 )
1001   string(TIMESTAMP OPENCV_TIMESTAMP "" UTC)
1002   set(OPENCV_TIMESTAMP "${OPENCV_TIMESTAMP}" CACHE STRING "Timestamp of OpenCV build configuration" FORCE)
1003 endif()
1004 if(OPENCV_TIMESTAMP)
1005   status("    Timestamp:"      ${OPENCV_TIMESTAMP})
1006 endif()
1007 status("    Host:"             ${CMAKE_HOST_SYSTEM_NAME} ${CMAKE_HOST_SYSTEM_VERSION} ${CMAKE_HOST_SYSTEM_PROCESSOR})
1008 if(CMAKE_CROSSCOMPILING)
1009   status("    Target:"         ${CMAKE_SYSTEM_NAME} ${CMAKE_SYSTEM_VERSION} ${CMAKE_SYSTEM_PROCESSOR})
1010 endif()
1011 status("    CMake:"            ${CMAKE_VERSION})
1012 status("    CMake generator:"  ${CMAKE_GENERATOR})
1013 status("    CMake build tool:" ${CMAKE_BUILD_TOOL})
1014 if(MSVC)
1015   status("    MSVC:"           ${MSVC_VERSION})
1016 endif()
1017 if(CMAKE_GENERATOR MATCHES Xcode)
1018   status("    Xcode:"          ${XCODE_VERSION})
1019 endif()
1020 if(NOT CMAKE_GENERATOR MATCHES "Xcode|Visual Studio")
1021   status("    Configuration:"  ${CMAKE_BUILD_TYPE})
1022 endif()
1023
1024
1025 # ========================= CPU code generation mode =========================
1026 status("")
1027 status("  CPU/HW features:")
1028 status("    Baseline:"  "${CPU_BASELINE_FINAL}")
1029 if(NOT CPU_BASELINE STREQUAL CPU_BASELINE_FINAL)
1030   status("      requested:"  "${CPU_BASELINE}")
1031 endif()
1032 if(CPU_BASELINE_REQUIRE)
1033   status("      required:"  "${CPU_BASELINE_REQUIRE}")
1034 endif()
1035 if(CPU_BASELINE_DISABLE)
1036   status("      disabled:"  "${CPU_BASELINE_DISABLE}")
1037 endif()
1038 if(CPU_DISPATCH_FINAL OR CPU_DISPATCH)
1039   status("    Dispatched code generation:"  "${CPU_DISPATCH_FINAL}")
1040   if(NOT CPU_DISPATCH STREQUAL CPU_DISPATCH_FINAL)
1041     status("      requested:"  "${CPU_DISPATCH}")
1042   endif()
1043   if(CPU_DISPATCH_REQUIRE)
1044     status("      required:"  "${CPU_DISPATCH_REQUIRE}")
1045   endif()
1046   foreach(OPT ${CPU_DISPATCH_FINAL})
1047     status("      ${OPT} (${CPU_${OPT}_USAGE_COUNT} files):"  "+ ${CPU_DISPATCH_${OPT}_INCLUDED}")
1048   endforeach()
1049 endif()
1050
1051 # ========================== C/C++ options ==========================
1052 if(CMAKE_CXX_COMPILER_VERSION)
1053   set(OPENCV_COMPILER_STR "${CMAKE_CXX_COMPILER} ${CMAKE_CXX_COMPILER_ARG1} (ver ${CMAKE_CXX_COMPILER_VERSION})")
1054 else()
1055   set(OPENCV_COMPILER_STR "${CMAKE_CXX_COMPILER} ${CMAKE_CXX_COMPILER_ARG1}")
1056 endif()
1057 string(STRIP "${OPENCV_COMPILER_STR}" OPENCV_COMPILER_STR)
1058
1059 status("")
1060 status("  C/C++:")
1061 status("    Built as dynamic libs?:" BUILD_SHARED_LIBS THEN YES ELSE NO)
1062 if(DEFINED CMAKE_CXX_STANDARD AND CMAKE_CXX_STANDARD)
1063   status("    C++ standard:"           "${CMAKE_CXX_STANDARD}")
1064 endif()
1065 status("    C++ Compiler:"           ${OPENCV_COMPILER_STR})
1066 status("    C++ flags (Release):"    ${CMAKE_CXX_FLAGS} ${CMAKE_CXX_FLAGS_RELEASE})
1067 status("    C++ flags (Debug):"      ${CMAKE_CXX_FLAGS} ${CMAKE_CXX_FLAGS_DEBUG})
1068 status("    C Compiler:"             ${CMAKE_C_COMPILER} ${CMAKE_C_COMPILER_ARG1})
1069 status("    C flags (Release):"      ${CMAKE_C_FLAGS} ${CMAKE_C_FLAGS_RELEASE})
1070 status("    C flags (Debug):"        ${CMAKE_C_FLAGS} ${CMAKE_C_FLAGS_DEBUG})
1071 if(WIN32)
1072   status("    Linker flags (Release):" ${CMAKE_EXE_LINKER_FLAGS} ${CMAKE_EXE_LINKER_FLAGS_RELEASE})
1073   status("    Linker flags (Debug):"   ${CMAKE_EXE_LINKER_FLAGS} ${CMAKE_EXE_LINKER_FLAGS_DEBUG})
1074 else()
1075   status("    Linker flags (Release):" ${CMAKE_SHARED_LINKER_FLAGS} ${CMAKE_SHARED_LINKER_FLAGS_RELEASE})
1076   status("    Linker flags (Debug):"   ${CMAKE_SHARED_LINKER_FLAGS} ${CMAKE_SHARED_LINKER_FLAGS_DEBUG})
1077 endif()
1078 status("    ccache:"                  OPENCV_COMPILER_IS_CCACHE THEN YES ELSE NO)
1079 status("    Precompiled headers:"     PCHSupport_FOUND AND ENABLE_PRECOMPILED_HEADERS THEN YES ELSE NO)
1080
1081 # ========================== Dependencies ============================
1082 ocv_get_all_libs(deps_modules deps_extra deps_3rdparty)
1083 status("    Extra dependencies:" ${deps_extra})
1084 status("    3rdparty dependencies:" ${deps_3rdparty})
1085
1086 # ========================== OpenCV modules ==========================
1087 status("")
1088 status("  OpenCV modules:")
1089 set(OPENCV_MODULES_BUILD_ST "")
1090 foreach(the_module ${OPENCV_MODULES_BUILD})
1091   if(NOT OPENCV_MODULE_${the_module}_CLASS STREQUAL "INTERNAL" OR the_module STREQUAL "opencv_ts")
1092     list(APPEND OPENCV_MODULES_BUILD_ST "${the_module}")
1093   endif()
1094 endforeach()
1095 string(REPLACE "opencv_" "" OPENCV_MODULES_BUILD_ST          "${OPENCV_MODULES_BUILD_ST}")
1096 string(REPLACE "opencv_" "" OPENCV_MODULES_DISABLED_USER_ST  "${OPENCV_MODULES_DISABLED_USER}")
1097 string(REPLACE "opencv_" "" OPENCV_MODULES_DISABLED_AUTO_ST  "${OPENCV_MODULES_DISABLED_AUTO}")
1098 string(REPLACE "opencv_" "" OPENCV_MODULES_DISABLED_FORCE_ST "${OPENCV_MODULES_DISABLED_FORCE}")
1099 list(SORT OPENCV_MODULES_BUILD_ST)
1100 list(SORT OPENCV_MODULES_DISABLED_USER_ST)
1101 list(SORT OPENCV_MODULES_DISABLED_AUTO_ST)
1102 list(SORT OPENCV_MODULES_DISABLED_FORCE_ST)
1103 status("    To be built:"            OPENCV_MODULES_BUILD          THEN ${OPENCV_MODULES_BUILD_ST}          ELSE "-")
1104 status("    Disabled:"               OPENCV_MODULES_DISABLED_USER  THEN ${OPENCV_MODULES_DISABLED_USER_ST}  ELSE "-")
1105 status("    Disabled by dependency:" OPENCV_MODULES_DISABLED_AUTO  THEN ${OPENCV_MODULES_DISABLED_AUTO_ST}  ELSE "-")
1106 status("    Unavailable:"            OPENCV_MODULES_DISABLED_FORCE THEN ${OPENCV_MODULES_DISABLED_FORCE_ST} ELSE "-")
1107
1108 ocv_build_features_string(apps_status
1109   IF BUILD_TESTS AND HAVE_opencv_ts THEN "tests"
1110   IF BUILD_PERF_TESTS AND HAVE_opencv_ts THEN "perf_tests"
1111   IF BUILD_EXAMPLES THEN "examples"
1112   IF BUILD_opencv_apps THEN "apps"
1113   IF BUILD_ANDROID_SERVICE THEN "android_service"
1114   IF (BUILD_ANDROID_EXAMPLES OR INSTALL_ANDROID_EXAMPLES) AND CAN_BUILD_ANDROID_PROJECTS THEN "android_examples"
1115   ELSE "-")
1116 status("    Applications:" "${apps_status}")
1117 ocv_build_features_string(docs_status
1118     IF TARGET doxygen_cpp THEN "doxygen"
1119     IF TARGET doxygen_python THEN "python"
1120     IF TARGET doxygen_javadoc THEN "javadoc"
1121     IF BUILD_opencv_js OR DEFINED OPENCV_JS_LOCATION THEN "js"
1122     ELSE "NO"
1123 )
1124 status("    Documentation:" "${docs_status}")
1125 status("    Non-free algorithms:" OPENCV_ENABLE_NONFREE THEN "YES" ELSE "NO")
1126
1127 # ========================== Android details ==========================
1128 if(ANDROID)
1129   status("")
1130   if(DEFINED ANDROID_NDK_REVISION)
1131     set(__msg "${ANDROID_NDK} (ver ${ANDROID_NDK_REVISION})")
1132   else()
1133     set(__msg "location: ${ANDROID_NDK}")
1134   endif()
1135   status("  Android NDK: " ${__msg})
1136   status("    Android ABI:" ${ANDROID_ABI})
1137   if(BUILD_WITH_STANDALONE_TOOLCHAIN)
1138     status("    NDK toolchain:" "standalone: ${ANDROID_STANDALONE_TOOLCHAIN}")
1139   elseif(BUILD_WITH_ANDROID_NDK OR DEFINED ANDROID_TOOLCHAIN_NAME)
1140     status("    NDK toolchain:" "${ANDROID_TOOLCHAIN_NAME}")
1141   endif()
1142   status("    STL type:" ${ANDROID_STL})
1143   status("    Native API level:" ${ANDROID_NATIVE_API_LEVEL})
1144
1145   if(BUILD_ANDROID_PROJECTS)
1146     status("  Android SDK: " "${ANDROID_SDK} (tools: ${ANDROID_SDK_TOOLS_VERSION} build tools: ${ANDROID_SDK_BUILD_TOOLS_VERSION})")
1147     if(ANDROID_EXECUTABLE)
1148       status("    android tool:"  "${ANDROID_EXECUTABLE}")
1149     endif()
1150   else()
1151     status("  Android SDK: " "not used, projects are not built")
1152   endif()
1153   if(DEFINED ANDROID_SDK_COMPATIBLE_TARGET)
1154     status("    SDK target:" "${ANDROID_SDK_COMPATIBLE_TARGET}")
1155   endif()
1156   if(DEFINED ANDROID_PROJECTS_BUILD_TYPE)
1157     if(ANDROID_PROJECTS_BUILD_TYPE STREQUAL "ANT")
1158       status("    Projects build scripts:" "Ant/Eclipse compatible")
1159     elseif(ANDROID_PROJECTS_BUILD_TYPE STREQUAL "ANT")
1160       status("    Projects build scripts:" "Gradle")
1161     endif()
1162   endif()
1163 endif()
1164
1165 # ================== Windows RT features ==================
1166 if(WIN32)
1167 status("")
1168 status("  Windows RT support:" WINRT THEN YES ELSE NO)
1169   if(WINRT)
1170     status("    Building for Microsoft platform: " ${CMAKE_SYSTEM_NAME})
1171     status("    Building for architectures: " ${CMAKE_VS_EFFECTIVE_PLATFORMS})
1172     status("    Building for version: " ${CMAKE_SYSTEM_VERSION})
1173     if (DEFINED ENABLE_WINRT_MODE_NATIVE)
1174       status("    Building for C++ without CX extensions")
1175     endif()
1176   endif()
1177 endif(WIN32)
1178
1179 # ========================== GUI ==========================
1180 status("")
1181 status("  GUI: ")
1182
1183 if(WITH_QT OR HAVE_QT)
1184   if(HAVE_QT5)
1185     status("    QT:" "YES (ver ${Qt5Core_VERSION_STRING})")
1186     status("      QT OpenGL support:" HAVE_QT_OPENGL THEN "YES (${Qt5OpenGL_LIBRARIES} ${Qt5OpenGL_VERSION_STRING})" ELSE NO)
1187   elseif(HAVE_QT)
1188     status("    QT:" "YES (ver ${QT_VERSION_MAJOR}.${QT_VERSION_MINOR}.${QT_VERSION_PATCH} ${QT_EDITION})")
1189     status("      QT OpenGL support:" HAVE_QT_OPENGL THEN "YES (${QT_QTOPENGL_LIBRARY})" ELSE NO)
1190   else()
1191     status("    QT:" "NO")
1192   endif()
1193 endif()
1194
1195 if(WITH_WIN32UI)
1196   status("    Win32 UI:" HAVE_WIN32UI THEN YES ELSE NO)
1197 endif()
1198
1199 if(HAVE_COCOA)  # APPLE
1200   status("    Cocoa:"  YES)
1201 endif()
1202
1203 if(WITH_GTK OR HAVE_GTK)
1204   if(HAVE_GTK3)
1205     status("    GTK+:" "YES (ver ${GTK3_VERSION})")
1206   elseif(HAVE_GTK)
1207     status("    GTK+:" "YES (ver ${GTK2_VERSION})")
1208   else()
1209     status("    GTK+:" "NO")
1210   endif()
1211   if(HAVE_GTK)
1212     status(  "      GThread :" HAVE_GTHREAD THEN "YES (ver ${GTHREAD_VERSION})" ELSE NO)
1213     status(  "      GtkGlExt:" HAVE_GTKGLEXT THEN "YES (ver ${GTKGLEXT_VERSION})" ELSE NO)
1214   endif()
1215 endif()
1216
1217 if(WITH_OPENGL OR HAVE_OPENGL)
1218   status("    OpenGL support:" HAVE_OPENGL THEN "YES (${OPENGL_LIBRARIES})" ELSE NO)
1219 endif()
1220
1221 if(WITH_VTK OR HAVE_VTK)
1222   status("    VTK support:" HAVE_VTK THEN "YES (ver ${VTK_VERSION})" ELSE NO)
1223 endif()
1224
1225 # ========================== MEDIA IO ==========================
1226 status("")
1227 status("  Media I/O: ")
1228 status("    ZLib:"   ZLIB_FOUND THEN "${ZLIB_LIBRARIES} (ver ${ZLIB_VERSION_STRING})" ELSE "build (ver ${ZLIB_VERSION_STRING})")
1229
1230 if(WITH_JPEG OR HAVE_JPEG)
1231   if(NOT HAVE_JPEG)
1232     status("    JPEG:" NO)
1233   elseif(BUILD_JPEG)
1234     status("    JPEG:" "build-${JPEG_LIBRARY} (ver ${JPEG_LIB_VERSION})")
1235   else()
1236     status("    JPEG:" "${JPEG_LIBRARY} (ver ${JPEG_LIB_VERSION})")
1237   endif()
1238 endif()
1239
1240 if(WITH_WEBP OR HAVE_WEBP)
1241   status("    WEBP:" WEBP_FOUND THEN "${WEBP_LIBRARY} (ver ${WEBP_VERSION})" ELSE "build (ver ${WEBP_VERSION})")
1242 endif()
1243
1244 if(WITH_PNG OR HAVE_PNG)
1245   status("    PNG:"  PNG_FOUND  THEN "${PNG_LIBRARY} (ver ${PNG_VERSION})" ELSE "build (ver ${PNG_VERSION})")
1246 endif()
1247
1248 if(WITH_TIFF OR HAVE_TIFF)
1249   status("    TIFF:" TIFF_FOUND THEN "${TIFF_LIBRARY} (ver ${TIFF_VERSION} / ${TIFF_VERSION_STRING})" ELSE "build (ver ${TIFF_VERSION} - ${TIFF_VERSION_STRING})")
1250 endif()
1251
1252 if(WITH_JASPER OR HAVE_JASPER)
1253   status("    JPEG 2000:" JASPER_FOUND THEN "${JASPER_LIBRARY} (ver ${JASPER_VERSION_STRING})" ELSE "build (ver ${JASPER_VERSION_STRING})")
1254 endif()
1255
1256 if(WITH_OPENEXR OR HAVE_OPENEXR)
1257   if(HAVE_OPENEXR)
1258     status("    OpenEXR:" OPENEXR_FOUND THEN "${OPENEXR_LIBRARIES} (ver ${OPENEXR_VERSION})" ELSE "build (ver ${OPENEXR_VERSION})")
1259   else()
1260     status("    OpenEXR:" "NO")
1261   endif()
1262 endif()
1263
1264 if(WITH_GDAL OR HAVE_GDAL)
1265   status("    GDAL:" HAVE_GDAL THEN "YES (${GDAL_LIBRARY})" ELSE "NO")
1266 endif()
1267
1268 if(WITH_GDCM OR HAVE_GDCM)
1269   status("    GDCM:" HAVE_GDCM THEN "YES (${GDCM_VERSION})" ELSE "NO")
1270 endif()
1271
1272 if(WITH_IMGCODEC_HDR OR DEFINED HAVE_IMGCODEC_HDR)
1273   status("    HDR:" HAVE_IMGCODEC_HDR THEN "YES" ELSE "NO")
1274 endif()
1275
1276 if(WITH_IMGCODEC_SUNRASTER OR DEFINED HAVE_IMGCODEC_SUNRASTER)
1277   status("    SUNRASTER:" HAVE_IMGCODEC_SUNRASTER THEN "YES" ELSE "NO")
1278 endif()
1279
1280 if(WITH_IMGCODEC_PXM OR DEFINED HAVE_IMGCODEC_PXM)
1281   status("    PXM:" HAVE_IMGCODEC_PXM THEN "YES" ELSE "NO")
1282 endif()
1283
1284 if(WITH_IMGCODEC_PFM OR DEFINED HAVE_IMGCODEC_PFM)
1285   status("    PFM:" HAVE_IMGCODEC_PFM THEN "YES" ELSE "NO")
1286 endif()
1287
1288 # ========================== VIDEO IO ==========================
1289 status("")
1290 status("  Video I/O:")
1291
1292 if(WITH_1394 OR HAVE_DC1394_2)
1293   status("    DC1394:" HAVE_DC1394_2 THEN "YES (${DC1394_2_VERSION})" ELSE NO)
1294 endif()
1295
1296 if(WITH_FFMPEG OR HAVE_FFMPEG)
1297   if(OPENCV_FFMPEG_USE_FIND_PACKAGE)
1298     status("    FFMPEG:"       HAVE_FFMPEG         THEN "YES (find_package)"                       ELSE "NO (find_package)")
1299   elseif(WIN32)
1300     status("    FFMPEG:"       HAVE_FFMPEG         THEN "YES (prebuilt binaries)"                  ELSE NO)
1301   else()
1302     status("    FFMPEG:"       HAVE_FFMPEG         THEN YES ELSE NO)
1303   endif()
1304   status("      avcodec:"      FFMPEG_libavcodec_VERSION    THEN "YES (${FFMPEG_libavcodec_VERSION})"    ELSE NO)
1305   status("      avformat:"     FFMPEG_libavformat_VERSION   THEN "YES (${FFMPEG_libavformat_VERSION})"   ELSE NO)
1306   status("      avutil:"       FFMPEG_libavutil_VERSION     THEN "YES (${FFMPEG_libavutil_VERSION})"     ELSE NO)
1307   status("      swscale:"      FFMPEG_libswscale_VERSION    THEN "YES (${FFMPEG_libswscale_VERSION})"    ELSE NO)
1308   status("      avresample:"   FFMPEG_libavresample_VERSION THEN "YES (${FFMPEG_libavresample_VERSION})" ELSE NO)
1309 endif()
1310
1311 if(WITH_GSTREAMER OR HAVE_GSTREAMER)
1312   status("    GStreamer:" HAVE_GSTREAMER THEN "YES (${GSTREAMER_VERSION})" ELSE NO)
1313 endif()
1314
1315 if(WITH_OPENNI2 OR HAVE_OPENNI2)
1316   status("    OpenNI2:"        HAVE_OPENNI2    THEN "YES (${OPENNI2_VERSION})" ELSE NO)
1317 endif()
1318
1319 if(WITH_PVAPI OR HAVE_PVAPI)
1320   status("    PvAPI:" HAVE_PVAPI THEN YES ELSE NO)
1321 endif()
1322
1323 if(WITH_ARAVIS OR HAVE_ARAVIS_API)
1324   status("    Aravis SDK:" HAVE_ARAVIS_API THEN "YES (${ARAVIS_VERSION})" ELSE NO)
1325 endif()
1326
1327 if(WITH_AVFOUNDATION OR HAVE_AVFOUNDATION)
1328   status("    AVFoundation:" HAVE_AVFOUNDATION THEN YES ELSE NO)
1329 endif()
1330
1331 if(HAVE_CAP_IOS)
1332   status("    iOS capture:" YES)
1333 endif()
1334
1335 if(WITH_V4L OR HAVE_V4L)
1336   ocv_build_features_string(v4l_status
1337     IF HAVE_CAMV4L2 THEN "linux/videodev2.h"
1338     IF HAVE_VIDEOIO THEN "sys/videoio.h"
1339     ELSE "NO")
1340   status("    v4l/v4l2:" HAVE_V4L THEN "YES (${v4l_status})" ELSE NO)
1341 endif()
1342
1343 if(WITH_DSHOW OR HAVE_DSHOW)
1344   status("    DirectShow:" HAVE_DSHOW THEN YES ELSE NO)
1345 endif()
1346
1347 if(WITH_MSMF OR HAVE_MSMF)
1348   status("    Media Foundation:" HAVE_MSMF THEN YES ELSE NO)
1349   status("      DXVA:" HAVE_MSMF_DXVA THEN YES ELSE NO)
1350 endif()
1351
1352 if(WITH_XIMEA OR HAVE_XIMEA)
1353   status("    XIMEA:" HAVE_XIMEA THEN YES ELSE NO)
1354 endif()
1355
1356 if(WITH_XINE OR HAVE_XINE)
1357   status("    Xine:"           HAVE_XINE           THEN "YES (ver ${XINE_VERSION})"     ELSE NO)
1358 endif()
1359
1360 if(WITH_LIBREALSENSE OR HAVE_LIBREALSENSE)
1361   status("    Intel RealSense:" HAVE_LIBREALSENSE THEN "YES (${LIBREALSENSE_VERSION})" ELSE NO)
1362 endif()
1363
1364 if(WITH_MFX OR HAVE_MFX)
1365   status("    Intel Media SDK:" HAVE_MFX      THEN "YES (${MFX_LIBRARY})" ELSE NO)
1366 endif()
1367
1368 if(WITH_GPHOTO2 OR HAVE_GPHOTO2)
1369   status("    gPhoto2:"        HAVE_GPHOTO2        THEN "YES"                                 ELSE NO)
1370 endif()
1371
1372 # Order is similar to CV_PARALLEL_FRAMEWORK in core/src/parallel.cpp
1373 ocv_build_features_string(parallel_status EXCLUSIVE
1374   IF HAVE_TBB THEN "TBB (ver ${TBB_VERSION_MAJOR}.${TBB_VERSION_MINOR} interface ${TBB_INTERFACE_VERSION})"
1375   IF HAVE_HPX THEN "HPX"
1376   IF HAVE_OPENMP THEN "OpenMP"
1377   IF HAVE_GCD THEN "GCD"
1378   IF WINRT OR HAVE_CONCURRENCY THEN "Concurrency"
1379   IF HAVE_PTHREADS_PF THEN "pthreads"
1380   ELSE "none")
1381 status("")
1382 status("  Parallel framework:" "${parallel_status}")
1383
1384 if(CV_TRACE OR OPENCV_TRACE)
1385   ocv_build_features_string(trace_status EXCLUSIVE
1386     IF HAVE_ITT THEN "with Intel ITT"
1387     ELSE "built-in")
1388   status("")
1389   status("  Trace: " OPENCV_TRACE THEN "YES (${trace_status})" ELSE NO)
1390 endif()
1391
1392 # ========================== Other third-party libraries ==========================
1393 status("")
1394 status("  Other third-party libraries:")
1395
1396 if(WITH_IPP AND HAVE_IPP)
1397   status("    Intel IPP:" "${IPP_VERSION_STR} [${IPP_VERSION_MAJOR}.${IPP_VERSION_MINOR}.${IPP_VERSION_BUILD}]")
1398   status("           at:" "${IPP_ROOT_DIR}")
1399   if(NOT HAVE_IPP_ICV)
1400     status("       linked:" BUILD_WITH_DYNAMIC_IPP THEN "dynamic" ELSE "static")
1401   endif()
1402   if(HAVE_IPP_IW)
1403     if(BUILD_IPP_IW)
1404       status("    Intel IPP IW:" "sources (${IW_VERSION_MAJOR}.${IW_VERSION_MINOR}.${IW_VERSION_UPDATE})")
1405     else()
1406       status("    Intel IPP IW:" "binaries (${IW_VERSION_MAJOR}.${IW_VERSION_MINOR}.${IW_VERSION_UPDATE})")
1407     endif()
1408     status("              at:" "${IPP_IW_PATH}")
1409   else()
1410     status("    Intel IPP IW:"   NO)
1411   endif()
1412 endif()
1413
1414 if(WITH_VA OR HAVE_VA)
1415   status("    VA:"            HAVE_VA          THEN "YES" ELSE NO)
1416 endif()
1417
1418 if(WITH_VA_INTEL OR HAVE_VA_INTEL)
1419   status("    Intel VA-API/OpenCL:"  HAVE_VA_INTEL       THEN "YES (OpenCL: ${VA_INTEL_IOCL_ROOT})" ELSE NO)
1420 endif()
1421
1422 if(WITH_TENGINE OR HAVE_TENGINE)
1423   status("    Tengine:"      HAVE_TENGINE     THEN "YES (${TENGINE_LIBRARIES})" ELSE NO)
1424 endif()
1425
1426 if(WITH_LAPACK OR HAVE_LAPACK)
1427   status("    Lapack:"      HAVE_LAPACK     THEN "YES (${LAPACK_LIBRARIES})" ELSE NO)
1428 endif()
1429
1430 if(WITH_HALIDE OR HAVE_HALIDE)
1431   status("    Halide:"     HAVE_HALIDE      THEN "YES (${HALIDE_LIBRARIES} ${HALIDE_INCLUDE_DIRS})" ELSE NO)
1432 endif()
1433
1434 if(WITH_INF_ENGINE OR INF_ENGINE_TARGET)
1435   if(INF_ENGINE_TARGET)
1436     list(GET INF_ENGINE_TARGET 0 ie_target)
1437     set(__msg "YES (${INF_ENGINE_RELEASE} / ${INF_ENGINE_VERSION})")
1438     get_target_property(_lib ${ie_target} IMPORTED_LOCATION)
1439     get_target_property(_lib_imp_rel ${ie_target} IMPORTED_IMPLIB_RELEASE)
1440     get_target_property(_lib_imp_dbg ${ie_target} IMPORTED_IMPLIB_DEBUG)
1441     get_target_property(_lib_rel ${ie_target} IMPORTED_LOCATION_RELEASE)
1442     get_target_property(_lib_dbg ${ie_target} IMPORTED_LOCATION_DEBUG)
1443     ocv_build_features_string(_lib
1444       IF _lib THEN "${_lib}"
1445       IF _lib_imp_rel AND _lib_imp_dbg THEN "${_lib_imp_rel} / ${_lib_imp_dbg}"
1446       IF _lib_rel AND _lib_dbg THEN "${_lib_rel} / ${_lib_dbg}"
1447       IF _lib_rel  THEN "${_lib_rel}"
1448       IF _lib_dbg  THEN "${_lib_dbg}"
1449       ELSE "unknown"
1450     )
1451     get_target_property(_inc ${ie_target} INTERFACE_INCLUDE_DIRECTORIES)
1452     status("    Inference Engine:" "${__msg}")
1453     status("        * libs:" "${_lib}")
1454     status("        * includes:" "${_inc}")
1455   else()
1456     status("    Inference Engine:"     "NO")
1457   endif()
1458 endif()
1459 if(WITH_NGRAPH OR HAVE_NGRAPH)
1460   if(HAVE_NGRAPH)
1461     set(__target ngraph::ngraph)
1462     set(__msg "YES (${ngraph_VERSION})")
1463     get_target_property(_lib ${__target} IMPORTED_LOCATION)
1464     get_target_property(_lib_imp_rel ${__target} IMPORTED_IMPLIB_RELEASE)
1465     get_target_property(_lib_imp_dbg ${__target} IMPORTED_IMPLIB_DEBUG)
1466     get_target_property(_lib_rel ${__target} IMPORTED_LOCATION_RELEASE)
1467     get_target_property(_lib_dbg ${__target} IMPORTED_LOCATION_DEBUG)
1468     ocv_build_features_string(_lib
1469       IF _lib THEN "${_lib}"
1470       IF _lib_imp_rel AND _lib_imp_dbg THEN "${_lib_imp_rel} / ${_lib_imp_dbg}"
1471       IF _lib_rel AND _lib_dbg THEN "${_lib_rel} / ${_lib_dbg}"
1472       IF _lib_rel  THEN "${_lib_rel}"
1473       IF _lib_dbg  THEN "${_lib_dbg}"
1474       ELSE "unknown"
1475     )
1476     get_target_property(_inc ${__target} INTERFACE_INCLUDE_DIRECTORIES)
1477     status("    nGraph:" "${__msg}")
1478     status("        * libs:" "${_lib}")
1479     status("        * includes:" "${_inc}")
1480   else()
1481     status("    nGraph:"     "NO")
1482   endif()
1483 endif()
1484
1485 if(WITH_EIGEN OR HAVE_EIGEN)
1486   status("    Eigen:"      HAVE_EIGEN       THEN "YES (ver ${EIGEN_WORLD_VERSION}.${EIGEN_MAJOR_VERSION}.${EIGEN_MINOR_VERSION})" ELSE NO)
1487 endif()
1488
1489 if(WITH_OPENVX OR HAVE_OPENVX)
1490   status("    OpenVX:"     HAVE_OPENVX      THEN "YES (${OPENVX_LIBRARIES})" ELSE "NO")
1491 endif()
1492
1493 status("    Custom HAL:" OpenCV_USED_HAL  THEN "YES (${OpenCV_USED_HAL})" ELSE "NO")
1494
1495 foreach(s ${CUSTOM_STATUS})
1496   status(${CUSTOM_STATUS_${s}})
1497 endforeach()
1498
1499 if(WITH_CUDA OR HAVE_CUDA)
1500   ocv_build_features_string(cuda_features
1501     IF HAVE_CUFFT THEN "CUFFT"
1502     IF HAVE_CUBLAS THEN "CUBLAS"
1503     IF HAVE_NVCUVID THEN "NVCUVID"
1504     IF CUDA_FAST_MATH THEN "FAST_MATH"
1505     ELSE "no extra features")
1506   status("")
1507   status("  NVIDIA CUDA:" HAVE_CUDA THEN "YES (ver ${CUDA_VERSION_STRING}, ${cuda_features})" ELSE NO)
1508   if(HAVE_CUDA)
1509     status("    NVIDIA GPU arch:"      ${OPENCV_CUDA_ARCH_BIN})
1510     status("    NVIDIA PTX archs:"     ${OPENCV_CUDA_ARCH_PTX})
1511   endif()
1512  endif()
1513
1514  if(WITH_CUDNN OR HAVE_CUDNN)
1515     status("")
1516     status("  cuDNN:" HAVE_CUDNN THEN "YES (ver ${CUDNN_VERSION})" ELSE NO)
1517 endif()
1518
1519 if(WITH_VULKAN OR HAVE_VULKAN)
1520   status("")
1521   status("  Vulkan:"     HAVE_VULKAN THEN "YES" ELSE "NO")
1522   if(HAVE_VULKAN)
1523     status("    Include path:"  VULKAN_INCLUDE_DIRS THEN "${VULKAN_INCLUDE_DIRS}" ELSE "NO")
1524     status("    Link libraries:" VULKAN_LIBRARIES THEN "${VULKAN_LIBRARIES}" ELSE "Dynamic load")
1525   endif()
1526 endif()
1527
1528 if(WITH_OPENCL OR HAVE_OPENCL)
1529   ocv_build_features_string(opencl_features
1530     IF HAVE_OPENCL_SVM THEN "SVM"
1531     IF HAVE_CLAMDFFT THEN "AMDFFT"
1532     IF HAVE_CLAMDBLAS THEN "AMDBLAS"
1533     IF HAVE_OPENCL_D3D11_NV THEN "NVD3D11"
1534     ELSE "no extra features")
1535   status("")
1536   status("  OpenCL:"     HAVE_OPENCL   THEN   "YES (${opencl_features})" ELSE "NO")
1537   if(HAVE_OPENCL)
1538     status("    Include path:"  OPENCL_INCLUDE_DIRS THEN "${OPENCL_INCLUDE_DIRS}" ELSE "NO")
1539     status("    Link libraries:"       OPENCL_LIBRARIES THEN "${OPENCL_LIBRARIES}" ELSE "Dynamic load")
1540   endif()
1541 endif()
1542
1543 # ========================== python ==========================
1544 if(BUILD_opencv_python2)
1545   status("")
1546   status("  Python 2:")
1547   status("    Interpreter:"     PYTHON2INTERP_FOUND  THEN "${PYTHON2_EXECUTABLE} (ver ${PYTHON2_VERSION_STRING})"       ELSE NO)
1548   if(PYTHON2LIBS_VERSION_STRING)
1549     status("    Libraries:"   HAVE_opencv_python2  THEN  "${PYTHON2_LIBRARIES} (ver ${PYTHON2LIBS_VERSION_STRING})"   ELSE NO)
1550   else()
1551     status("    Libraries:"   HAVE_opencv_python2  THEN  "${PYTHON2_LIBRARIES}"                                      ELSE NO)
1552   endif()
1553   status("    numpy:"         PYTHON2_NUMPY_INCLUDE_DIRS THEN "${PYTHON2_NUMPY_INCLUDE_DIRS} (ver ${PYTHON2_NUMPY_VERSION})" ELSE "NO (Python wrappers can not be generated)")
1554   status("    install path:"  HAVE_opencv_python2  THEN "${__INSTALL_PATH_PYTHON2}"                            ELSE "-")
1555 endif()
1556
1557 if(BUILD_opencv_python3)
1558   status("")
1559   status("  Python 3:")
1560   status("    Interpreter:"     PYTHON3INTERP_FOUND  THEN "${PYTHON3_EXECUTABLE} (ver ${PYTHON3_VERSION_STRING})"       ELSE NO)
1561   if(PYTHON3LIBS_VERSION_STRING)
1562     status("    Libraries:"   HAVE_opencv_python3  THEN  "${PYTHON3_LIBRARIES} (ver ${PYTHON3LIBS_VERSION_STRING})"   ELSE NO)
1563   else()
1564     status("    Libraries:"   HAVE_opencv_python3  THEN  "${PYTHON3_LIBRARIES}"                                      ELSE NO)
1565   endif()
1566   status("    numpy:"         PYTHON3_NUMPY_INCLUDE_DIRS THEN "${PYTHON3_NUMPY_INCLUDE_DIRS} (ver ${PYTHON3_NUMPY_VERSION})" ELSE "NO (Python3 wrappers can not be generated)")
1567   status("    install path:"  HAVE_opencv_python3  THEN "${__INSTALL_PATH_PYTHON3}"                            ELSE "-")
1568 endif()
1569
1570 status("")
1571 status("  Python (for build):"  PYTHON_DEFAULT_AVAILABLE THEN "${PYTHON_DEFAULT_EXECUTABLE}" ELSE NO)
1572 if(PYLINT_FOUND AND PYLINT_EXECUTABLE)
1573   status("    Pylint:"  PYLINT_FOUND THEN "${PYLINT_EXECUTABLE} (ver: ${PYLINT_VERSION}, checks: ${PYLINT_TOTAL_TARGETS})" ELSE NO)
1574 endif()
1575 if(FLAKE8_FOUND AND FLAKE8_EXECUTABLE)
1576   status("    Flake8:"  FLAKE8_FOUND THEN "${FLAKE8_EXECUTABLE} (ver: ${FLAKE8_VERSION})" ELSE NO)
1577 endif()
1578
1579 # ========================== java ==========================
1580 if(BUILD_JAVA)
1581   status("")
1582   status("  Java:"            BUILD_FAT_JAVA_LIB  THEN "export all functions"                                      ELSE "")
1583   status("    ant:"           ANT_EXECUTABLE      THEN "${ANT_EXECUTABLE} (ver ${ANT_VERSION})"                    ELSE NO)
1584   if(NOT ANDROID)
1585     status("    JNI:"         JNI_INCLUDE_DIRS    THEN "${JNI_INCLUDE_DIRS}"                                       ELSE NO)
1586   endif()
1587   status("    Java wrappers:" HAVE_opencv_java                                                            THEN YES ELSE NO)
1588   status("    Java tests:"    BUILD_TESTS AND opencv_test_java_BINARY_DIR                                 THEN YES ELSE NO)
1589 endif()
1590
1591 ocv_cmake_hook(STATUS_DUMP_EXTRA)
1592
1593 # ========================== auxiliary ==========================
1594 status("")
1595 status("  Install to:" "${CMAKE_INSTALL_PREFIX}")
1596 status("-----------------------------------------------------------------")
1597 status("")
1598
1599
1600 ocv_finalize_status()
1601
1602 if(ENABLE_CONFIG_VERIFICATION)
1603   ocv_verify_config()
1604 endif()
1605
1606 ocv_cmake_hook(POST_FINALIZE)
1607
1608 # ----------------------------------------------------------------------------
1609 # CPack stuff
1610 # ----------------------------------------------------------------------------
1611
1612 include(cmake/OpenCVPackaging.cmake)
1613
1614 # This should be the last command
1615 ocv_cmake_dump_vars("" TOFILE "CMakeVars.txt")
1616 ocv_cmake_eval(DEBUG_POST ONCE)