CMakeLists.txt

   1 # Copyright (c) 2015 The Khronos Group Inc.
   2 #
   3 # Permission is hereby granted, free of charge, to any person obtaining a
   4 # copy of this software and/or associated documentation files (the
   5 # "Materials"), to deal in the Materials without restriction, including
   6 # without limitation the rights to use, copy, modify, merge, publish,
   7 # distribute, sublicense, and/or sell copies of the Materials, and to
   8 # permit persons to whom the Materials are furnished to do so, subject to
   9 # the following conditions:
  10 #
  11 # The above copyright notice and this permission notice shall be included
  12 # in all copies or substantial portions of the Materials.
  13 #
  14 # MODIFICATIONS TO THIS FILE MAY MEAN IT NO LONGER ACCURATELY REFLECTS
  15 # KHRONOS STANDARDS. THE UNMODIFIED, NORMATIVE VERSIONS OF KHRONOS
  16 # SPECIFICATIONS AND HEADER INFORMATION ARE LOCATED AT
  17 #    https://www.khronos.org/registry/
  18 #
  19 # THE MATERIALS ARE PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,
  20 # EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF
  21 # MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.
  22 # IN NO EVENT SHALL THE AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY
  23 # CLAIM, DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION OF CONTRACT,
  24 # TORT OR OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION WITH THE
  25 # MATERIALS OR THE USE OR OTHER DEALINGS IN THE MATERIALS.
  26
  27 cmake_minimum_required(VERSION 2.8)
  28 project(spirv-tools)
  29 set(SPIRV_TOOLS "SPIRV-Tools")
  30
  31 if("${CMAKE_SYSTEM_NAME}" STREQUAL "Linux")
  32   add_definitions(-DSPIRV_LINUX)
  33 elseif("${CMAKE_SYSTEM_NAME}" STREQUAL "Windows")
  34   add_definitions(-DSPIRV_WINDOWS)
  35 elseif("${CMAKE_SYSTEM_NAME}" STREQUAL "Darwin")
  36   add_definitions(-DSPIRV_MAC)
  37 else()
  38   message(FATAL_ERROR "Your platform '${CMAKE_SYSTEM_NAME}' is not supported!")
  39 endif()
  40
  41 if ("${CMAKE_BUILD_TYPE}" STREQUAL "")
  42   message(STATUS "No build type selected, default to Debug")
  43   set(CMAKE_BUILD_TYPE "Debug")
  44 endif()
  45
  46 if(UNIX)
  47   set(SPIRV_WARNINGS -Wall -Wextra -Wno-missing-field-initializers)
  48
  49   option(SPIRV_WARN_EVERYTHING "Enable -Weverything" OFF)
  50   if(${SPIRV_WARN_EVERYTHING})
  51     set(SPIRV_WARNINGS ${SPIRV_WARNINGS}
  52       -Weverything -Wno-c++98-compat -Wno-c++98-compat-pedantic -Wno-padded)
  53   endif()
  54
  55   option(SPIRV_WERROR "Enable error on warning" OFF)
  56   if(${SPIRV_WERROR})
  57     set(SPIRV_WARNINGS ${SPIRV_WARNINGS} -Werror)
  58   endif()
  59 elseif(WIN32)
  60   set(SPIRV_WARNINGS -D_CRT_SECURE_NO_WARNINGS /wd4800)
  61 endif()
  62
  63 option(SPIRV_COLOR_TERMINAL "Enable color terminal output" ON)
  64 if(${SPIRV_COLOR_TERMINAL})
  65   add_definitions(-DSPIRV_COLOR_TERMINAL)
  66 endif()
  67
  68 function(default_compile_options TARGET)
  69   target_compile_options(${TARGET} PRIVATE ${SPIRV_WARNINGS})
  70   if (UNIX)
  71     target_compile_options(${TARGET} PRIVATE
  72       -std=c++11 -fno-exceptions -fno-rtti)
  73     # For good call stacks in profiles, keep the frame pointers.
  74     if(NOT "${SPIRV_PERF}" STREQUAL "")
  75       target_compile_options(${TARGET} PRIVATE -fno-omit-frame-pointer)
  76     endif()
  77     if("${CMAKE_CXX_COMPILER_ID}" STREQUAL "Clang")
  78       target_compile_options(${TARGET} PRIVATE -fcolor-diagnostics)
  79       set(SPIRV_USE_SANITIZER "" CACHE STRING
  80         "Use the clang sanitizer [address|memory|thread|...]")
  81       if(NOT "${SPIRV_USE_SANITIZER}" STREQUAL "")
  82         target_compile_options(${TARGET} PRIVATE
  83           -fsanitize=${SPIRV_USE_SANITIZER})
  84       endif()
  85     endif()
  86   endif()
  87 endfunction()
  88
  89 set(SPIRV_SOURCES
  90   ${CMAKE_CURRENT_SOURCE_DIR}/include/libspirv/libspirv.h
  91   ${CMAKE_CURRENT_SOURCE_DIR}/include/util/bitutils.h
  92   ${CMAKE_CURRENT_SOURCE_DIR}/include/util/hex_float.h
  93   ${CMAKE_CURRENT_SOURCE_DIR}/source/assembly_grammar.h
  94   ${CMAKE_CURRENT_SOURCE_DIR}/source/binary.h
  95   ${CMAKE_CURRENT_SOURCE_DIR}/source/diagnostic.h
  96   ${CMAKE_CURRENT_SOURCE_DIR}/source/endian.h
  97   ${CMAKE_CURRENT_SOURCE_DIR}/source/ext_inst.h
  98   ${CMAKE_CURRENT_SOURCE_DIR}/source/instruction.h
  99   ${CMAKE_CURRENT_SOURCE_DIR}/source/opcode.h
 100   ${CMAKE_CURRENT_SOURCE_DIR}/source/operand.h
 101   ${CMAKE_CURRENT_SOURCE_DIR}/source/print.h
 102   ${CMAKE_CURRENT_SOURCE_DIR}/source/spirv_constant.h
 103   ${CMAKE_CURRENT_SOURCE_DIR}/source/spirv_definition.h
 104   ${CMAKE_CURRENT_SOURCE_DIR}/source/table.h
 105   ${CMAKE_CURRENT_SOURCE_DIR}/source/text.h
 106   ${CMAKE_CURRENT_SOURCE_DIR}/source/text_handler.h
 107   ${CMAKE_CURRENT_SOURCE_DIR}/source/validate.h
 108   ${CMAKE_CURRENT_SOURCE_DIR}/source/assembly_grammar.cpp
 109   ${CMAKE_CURRENT_SOURCE_DIR}/source/binary.cpp
 110   ${CMAKE_CURRENT_SOURCE_DIR}/source/disassemble.cpp
 111   ${CMAKE_CURRENT_SOURCE_DIR}/source/diagnostic.cpp
 112   ${CMAKE_CURRENT_SOURCE_DIR}/source/endian.cpp
 113   ${CMAKE_CURRENT_SOURCE_DIR}/source/ext_inst.cpp
 114   ${CMAKE_CURRENT_SOURCE_DIR}/source/opcode.cpp
 115   ${CMAKE_CURRENT_SOURCE_DIR}/source/operand.cpp
 116   ${CMAKE_CURRENT_SOURCE_DIR}/source/print.cpp
 117   ${CMAKE_CURRENT_SOURCE_DIR}/source/table.cpp
 118   ${CMAKE_CURRENT_SOURCE_DIR}/source/text.cpp
 119   ${CMAKE_CURRENT_SOURCE_DIR}/source/text_handler.cpp
 120   ${CMAKE_CURRENT_SOURCE_DIR}/source/validate.cpp
 121   ${CMAKE_CURRENT_SOURCE_DIR}/source/validate_id.cpp)
 122
 123 add_library(${SPIRV_TOOLS} ${SPIRV_SOURCES})
 124 default_compile_options(${SPIRV_TOOLS})
 125 target_include_directories(${SPIRV_TOOLS} PUBLIC
 126   ${CMAKE_CURRENT_SOURCE_DIR}/include
 127   ${CMAKE_CURRENT_SOURCE_DIR}/external/include)
 128
 129 option(SPIRV_SKIP_EXECUTABLES
 130   "Skip building the executables and tests along with the library" OFF)
 131 set(SPIRV_INSTALL_TARGETS ${SPIRV_TOOLS})
 132 if (NOT ${SPIRV_SKIP_EXECUTABLES})
 133   list(APPEND SPIRV_INSTALL_TARGETS spirv-as spirv-dis spirv-val)
 134
 135   add_executable(spirv-as ${CMAKE_CURRENT_SOURCE_DIR}/tools/as/as.cpp)
 136   default_compile_options(spirv-as)
 137   target_link_libraries(spirv-as PRIVATE ${SPIRV_TOOLS})
 138
 139   add_executable(spirv-dis ${CMAKE_CURRENT_SOURCE_DIR}/tools/dis/dis.cpp)
 140   default_compile_options(spirv-dis)
 141   target_link_libraries(spirv-dis PRIVATE ${SPIRV_TOOLS})
 142
 143   add_executable(spirv-val ${CMAKE_CURRENT_SOURCE_DIR}/tools/val/val.cpp)
 144   default_compile_options(spirv-val)
 145   target_link_libraries(spirv-val PRIVATE ${SPIRV_TOOLS})
 146
 147   set(GMOCK_DIR ${CMAKE_CURRENT_SOURCE_DIR}/external/googletest/googlemock)
 148   if(EXISTS ${GMOCK_DIR})
 149     if(WIN32)
 150       option(gtest_force_shared_crt
 151         "Use shared (DLL) run-time lib even when Google Test is built as static lib."
 152         ON)
 153     endif()
 154
 155     add_subdirectory(${GMOCK_DIR})
 156   endif()
 157   if (TARGET gmock)
 158     message(STATUS "Found Google Mock, building tests.")
 159
 160     set(TEST_SOURCES
 161       ${CMAKE_CURRENT_SOURCE_DIR}/test/TestFixture.h
 162       ${CMAKE_CURRENT_SOURCE_DIR}/test/UnitSPIRV.h
 163
 164       ${CMAKE_CURRENT_SOURCE_DIR}/test/AssemblyContext.cpp
 165       ${CMAKE_CURRENT_SOURCE_DIR}/test/AssemblyFormat.cpp
 166       ${CMAKE_CURRENT_SOURCE_DIR}/test/BinaryDestroy.cpp
 167       ${CMAKE_CURRENT_SOURCE_DIR}/test/BinaryEndianness.cpp
 168       ${CMAKE_CURRENT_SOURCE_DIR}/test/BinaryHeaderGet.cpp
 169       ${CMAKE_CURRENT_SOURCE_DIR}/test/BinaryParse.cpp
 170       ${CMAKE_CURRENT_SOURCE_DIR}/test/BinaryToText.cpp
 171       ${CMAKE_CURRENT_SOURCE_DIR}/test/BinaryToText.Literal.cpp
 172       ${CMAKE_CURRENT_SOURCE_DIR}/test/Comment.cpp
 173       ${CMAKE_CURRENT_SOURCE_DIR}/test/DiagnosticPrint.cpp
 174       ${CMAKE_CURRENT_SOURCE_DIR}/test/DiagnosticStream.cpp
 175       ${CMAKE_CURRENT_SOURCE_DIR}/test/ExtInstGLSLstd450.cpp
 176       ${CMAKE_CURRENT_SOURCE_DIR}/test/ExtInst.OpenCL.std.cpp
 177       ${CMAKE_CURRENT_SOURCE_DIR}/test/FixWord.cpp
 178       ${CMAKE_CURRENT_SOURCE_DIR}/test/GeneratorMagicNumber.cpp
 179       ${CMAKE_CURRENT_SOURCE_DIR}/test/HexFloat.cpp
 180       ${CMAKE_CURRENT_SOURCE_DIR}/test/ImmediateInt.cpp
 181       ${CMAKE_CURRENT_SOURCE_DIR}/test/LibspirvMacros.cpp
 182       ${CMAKE_CURRENT_SOURCE_DIR}/test/NamedId.cpp
 183       ${CMAKE_CURRENT_SOURCE_DIR}/test/OpcodeMake.cpp
 184       ${CMAKE_CURRENT_SOURCE_DIR}/test/OpcodeRequiresCapabilities.cpp
 185       ${CMAKE_CURRENT_SOURCE_DIR}/test/OpcodeSplit.cpp
 186       ${CMAKE_CURRENT_SOURCE_DIR}/test/OpcodeTableGet.cpp
 187       ${CMAKE_CURRENT_SOURCE_DIR}/test/OperandCapabilities.cpp
 188       ${CMAKE_CURRENT_SOURCE_DIR}/test/Operand.cpp
 189       ${CMAKE_CURRENT_SOURCE_DIR}/test/OperandPattern.cpp
 190       ${CMAKE_CURRENT_SOURCE_DIR}/test/TextAdvance.cpp
 191       ${CMAKE_CURRENT_SOURCE_DIR}/test/TextDestroy.cpp
 192       ${CMAKE_CURRENT_SOURCE_DIR}/test/TextLiteral.cpp
 193       ${CMAKE_CURRENT_SOURCE_DIR}/test/TextStartsNewInst.cpp
 194       ${CMAKE_CURRENT_SOURCE_DIR}/test/TextToBinary.Annotation.cpp
 195       ${CMAKE_CURRENT_SOURCE_DIR}/test/TextToBinary.Barrier.cpp
 196       ${CMAKE_CURRENT_SOURCE_DIR}/test/TextToBinary.Constant.cpp
 197       ${CMAKE_CURRENT_SOURCE_DIR}/test/TextToBinary.ControlFlow.cpp
 198       ${CMAKE_CURRENT_SOURCE_DIR}/test/TextToBinary.cpp
 199       ${CMAKE_CURRENT_SOURCE_DIR}/test/TextToBinary.Debug.cpp
 200       ${CMAKE_CURRENT_SOURCE_DIR}/test/TextToBinary.DeviceSideEnqueue.cpp
 201       ${CMAKE_CURRENT_SOURCE_DIR}/test/TextToBinary.Extension.cpp
 202       ${CMAKE_CURRENT_SOURCE_DIR}/test/TextToBinary.Function.cpp
 203       ${CMAKE_CURRENT_SOURCE_DIR}/test/TextToBinary.Group.cpp
 204       ${CMAKE_CURRENT_SOURCE_DIR}/test/TextToBinary.Image.cpp
 205       ${CMAKE_CURRENT_SOURCE_DIR}/test/TextToBinary.Literal.cpp
 206       ${CMAKE_CURRENT_SOURCE_DIR}/test/TextToBinary.Memory.cpp
 207       ${CMAKE_CURRENT_SOURCE_DIR}/test/TextToBinary.Miscellaneous.cpp
 208       ${CMAKE_CURRENT_SOURCE_DIR}/test/TextToBinary.ModeSetting.cpp
 209       ${CMAKE_CURRENT_SOURCE_DIR}/test/TextToBinary.TypeDeclaration.cpp
 210       ${CMAKE_CURRENT_SOURCE_DIR}/test/TextWordGet.cpp
 211       ${CMAKE_CURRENT_SOURCE_DIR}/test/UnitSPIRV.cpp
 212       ${CMAKE_CURRENT_SOURCE_DIR}/test/Validate.cpp
 213       ${CMAKE_CURRENT_SOURCE_DIR}/test/ValidateID.cpp
 214       ${CMAKE_CURRENT_SOURCE_DIR}/test/main.cpp)
 215
 216     add_executable(UnitSPIRV ${TEST_SOURCES})
 217     default_compile_options(UnitSPIRV)
 218     target_include_directories(UnitSPIRV PRIVATE
 219       ${gmock_SOURCE_DIR}/include ${gtest_SOURCE_DIR}/include)
 220     target_link_libraries(UnitSPIRV PRIVATE ${SPIRV_TOOLS} gmock)
 221   else()
 222     message(STATUS "Did not find googletest, tests will not be built."
 223       "To enable tests place googletest in '<spirv-dir>/external/googletest'.")
 224   endif()
 225 endif()
 226
 227 install(TARGETS ${SPIRV_INSTALL_TARGETS}
 228   RUNTIME DESTINATION bin
 229   LIBRARY DESTINATION lib
 230   ARCHIVE DESTINATION lib)
 231
 232 install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/include/libspirv/libspirv.h
 233   DESTINATION include/libspirv/)