CMakeLists.txt

   1 # vim:ts=4:sw=4:expandtab:autoindent:
   2 #
   3 # Copyright (C) 1997-2015 by Dimitri van Heesch.
   4 #
   5 # Permission to use, copy, modify, and distribute this software and its
   6 # documentation under the terms of the GNU General Public License is hereby
   7 # granted. No representations are made about the suitability of this software
   8 # for any purpose. It is provided "as is" without express or implied warranty.
   9 # See the GNU General Public License for more details.
  10 #
  11 # Documents produced by Doxygen are derivative works derived from the
  12 # input used in their production; they are not affected by this license.
  13
  14 cmake_minimum_required(VERSION 3.3)
  15 project(doxygen)
  16
  17 option(build_wizard    "Build the GUI frontend for doxygen." OFF)
  18 option(build_app       "Example showing how to embed doxygen in an application." OFF)
  19 option(build_parse     "Parses source code and dumps the dependencies between the code elements." OFF)
  20 option(build_xmlparser "Example showing how to parse doxygen's XML output." OFF)
  21 option(build_search    "Build external search tools (doxysearch and doxyindexer)" OFF)
  22 option(build_doc       "Build user manual (HTML and PDF)" OFF)
  23 option(build_doc_chm   "Build user manual (CHM)" OFF)
  24 option(use_sqlite3     "Add support for sqlite3 output [experimental]." OFF)
  25 if (CMAKE_CXX_COMPILER_ID STREQUAL "Clang")
  26     option(use_libc++  "Use libc++ as C++ standard library." ON)
  27 endif()
  28 option(use_libclang    "Add support for libclang parsing." OFF)
  29 option(static_libclang "Link to a statically compiled version of LLVM/libclang." OFF)
  30 option(win_static      "Link with /MT in stead of /MD on windows" OFF)
  31 option(english_only    "Only compile in support for the English language" OFF)
  32 option(force_qt4       "Forces doxywizard to build using Qt4 even if Qt5 is installed" OFF)
  33 option(enable_coverage "Enable coverage reporting for gcc/clang [development]" OFF)
  34
  35 SET(enlarge_lex_buffers "262144" CACHE INTERNAL "Sets the lex input and read buffers to the specified size")
  36
  37 list(APPEND CMAKE_MODULE_PATH "${CMAKE_SOURCE_DIR}/cmake")
  38 list(APPEND CMAKE_MODULE_PATH "${CMAKE_SOURCE_DIR}/cmake/Sanitizers")
  39 set(TOP "${CMAKE_SOURCE_DIR}")
  40 include(version)
  41
  42 set(sqlite3  "0" CACHE INTERNAL "used in settings.h")
  43 set(clang    "0" CACHE INTERNAL "used in settings.h")
  44 if (use_sqlite3)
  45         set(sqlite3  "1" CACHE INTERNAL "used in settings.h")
  46 endif()
  47
  48 set(MACOS_VERSION_MIN 10.9)
  49 if (use_libclang)
  50         set(clang    "1" CACHE INTERNAL "used in settings.h")
  51         find_package(LLVM CONFIG REQUIRED)
  52         find_package(Clang CONFIG REQUIRED)
  53     if (CMAKE_SYSTEM MATCHES "Darwin")
  54         set(MACOS_VERSION_MIN 10.11)
  55     endif()
  56 endif()
  57
  58 # use C++14 standard for compiling (libclang option requires it)
  59 set(CMAKE_CXX_STANDARD 14)
  60 set(CMAKE_CXX_STANDARD_REQUIRED ON)
  61 set(CMAKE_CXX_EXTENSIONS ON)
  62
  63 if (CMAKE_SYSTEM MATCHES "Darwin")
  64     set(CMAKE_CXX_FLAGS "-Wno-deprecated-register -mmacosx-version-min=${MACOS_VERSION_MIN} ${CMAKE_CXX_FLAGS}")
  65     set(CMAKE_C_FLAGS "-Wno-deprecated-register -mmacosx-version-min=${MACOS_VERSION_MIN} ${CMAKE_C_FLAGS}")
  66     find_library(CORESERVICES_LIB CoreServices)
  67     set(EXTRA_LIBS ${CORESERVICES_LIB})
  68 endif()
  69
  70 if (WIN32)
  71     if ((NOT CMAKE_GENERATOR MATCHES "MinGW Makefiles") AND
  72         (NOT CMAKE_GENERATOR MATCHES "MSYS Makefiles"))
  73         if (NOT ICONV_DIR)
  74           set(ICONV_DIR "${CMAKE_SOURCE_DIR}/winbuild")
  75         endif()
  76         set(CMAKE_REQUIRED_DEFINITIONS "-DLIBICONV_STATIC")
  77         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /bigobj") # needed for language.cpp on 64bit
  78         add_definitions(-DLIBICONV_STATIC -D_CRT_SECURE_NO_WARNINGS)
  79     endif()
  80     if (CMAKE_GENERATOR MATCHES "NMake Makefiles")
  81         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /EHsc")
  82     endif()
  83 endif()
  84
  85 if(POLICY CMP0063)
  86   cmake_policy(SET CMP0063 NEW)
  87 endif()
  88 set(CMAKE_CXX_VISIBILITY_PRESET hidden)
  89 set(CMAKE_C_VISIBILITY_PRESET hidden)
  90 set(CMAKE_VISIBILITY_INLINES_HIDDEN 1)
  91
  92 if (CMAKE_GENERATOR MATCHES "Ninja")
  93   set(LEX_FLAGS )
  94   set(YACC_FLAGS )
  95   set(JAVACC_FLAGS )
  96 else ()
  97   set(LEX_FLAGS $(LEX_FLAGS))
  98   set(YACC_FLAGS $(YACC_FLAGS))
  99   set(JAVACC_FLAGS $(JAVACC_FLAGS))
 100 endif ()
 101
 102 find_program(DOT NAMES dot)
 103 find_package(PythonInterp REQUIRED)
 104 find_package(FLEX REQUIRED)
 105 find_package(BISON REQUIRED)
 106 if (BISON_VERSION VERSION_LESS 2.7)
 107   message(SEND_ERROR "Doxygen requires at least bison version 2.7 (installed: ${BISON_VERSION})")
 108 endif()
 109 find_package(Threads)
 110 find_package(Sanitizers)
 111
 112 if (sqlite3)
 113   find_package(SQLite3 REQUIRED)
 114   if (SQLITE3_VERSION VERSION_LESS 3.9.0)
 115     message(SEND_ERROR "Doxygen requires at least sqlite3 version 3.9.0 (installed: ${SQLITE3_VERSION})")
 116   endif()
 117 endif()
 118
 119 find_package(Iconv REQUIRED)
 120 include_directories(${ICONV_INCLUDE_DIR})
 121
 122
 123 #set(DOXYDOCS ${CMAKE_SOURCE_DIR}/doc CACHE INTERNAL "Path to doxygen docs")
 124 set(DOXYDOCS ${PROJECT_BINARY_DIR}/doc)
 125 set(ENV{DOXYGEN_DOCDIR} ${DOXYDOCS})
 126 set(GENERATED_SRC "${CMAKE_BINARY_DIR}/generated_src" CACHE INTERNAL "Stores generated files")
 127 set(LIBRARY_OUTPUT_PATH ${PROJECT_BINARY_DIR}/lib)
 128 set(EXECUTABLE_OUTPUT_PATH ${PROJECT_BINARY_DIR}/bin)
 129
 130 # place binaries for all build types in the same directory, so we know where to find it
 131 # when running tests or generating docs
 132 set(CMAKE_RUNTIME_OUTPUT_DIRECTORY_DEBUG ${EXECUTABLE_OUTPUT_PATH})
 133 set(CMAKE_RUNTIME_OUTPUT_DIRECTORY_RELEASE ${EXECUTABLE_OUTPUT_PATH})
 134 set(CMAKE_RUNTIME_OUTPUT_DIRECTORY_MINSIZEREL ${EXECUTABLE_OUTPUT_PATH})
 135 set(CMAKE_RUNTIME_OUTPUT_DIRECTORY_RELWITHDEBINFO ${EXECUTABLE_OUTPUT_PATH})
 136
 137 # gather lang codes for translation
 138 file(GLOB lang_files RELATIVE "${CMAKE_SOURCE_DIR}/src" "${CMAKE_SOURCE_DIR}/src/translator_??.h")
 139 if (english_only) # user only wants English
 140   set(lcodes "ENONLY")
 141 else ()
 142   set(lcodes "")
 143   foreach (_lang ${lang_files})
 144     string(REGEX REPLACE "translator_(.*).h" "\\1" _lang_code ${_lang})
 145     string(TOUPPER ${_lang_code} lang_code)
 146     list(APPEND lcodes "${lang_code}")
 147   endforeach()
 148 endif()
 149 set(LANG_CODES ${lcodes} CACHE STRING "List of language codes for which translations should be compiled in")
 150
 151 if (win_static)
 152     set(CompilerFlags
 153         CMAKE_CXX_FLAGS
 154         CMAKE_CXX_FLAGS_DEBUG
 155         CMAKE_CXX_FLAGS_RELEASE
 156         CMAKE_CXX_FLAGS_MINSIZEREL
 157         CMAKE_CXX_FLAGS_RELWITHDEBINFO
 158         CMAKE_C_FLAGS
 159         CMAKE_C_FLAGS_DEBUG
 160         CMAKE_C_FLAGS_RELEASE
 161         CMAKE_C_FLAGS_MINSIZEREL
 162         CMAKE_C_FLAGS_RELWITHDEBINFO)
 163     foreach(CompilerFlag ${CompilerFlags})
 164       string(REPLACE "/MD" "/MT" ${CompilerFlag} "${${CompilerFlag}}")
 165     endforeach()
 166 endif()
 167
 168 include(cmake/CompilerWarnings.cmake)
 169 include(cmake/Coverage.cmake)
 170
 171 add_subdirectory(libmd5)
 172 add_subdirectory(liblodepng)
 173 add_subdirectory(libmscgen)
 174 add_subdirectory(libversion)
 175 add_subdirectory(qtools)
 176 add_subdirectory(vhdlparser)
 177 add_subdirectory(src)
 178
 179 if (build_doc_chm)
 180     if (WIN32)
 181           find_package(HTMLHelp REQUIRED)
 182           set(build_doc ON)
 183     else ()
 184           message(WARNING "CHM documentation generation not supported for this platform, ignoring setting.")
 185           set(build_doc_chm OFF)
 186     endif ()
 187 endif ()
 188
 189 if (build_doc)
 190     add_subdirectory(examples)
 191     add_subdirectory(doc)
 192 endif ()
 193
 194 add_subdirectory(addon)
 195
 196 enable_testing()
 197 add_subdirectory(testing)
 198
 199 include(cmake/packaging.cmake) # set CPACK_xxxx properties
 200 include(CPack)