CMakeLists.txt

   1 # The name of our project is "VULKAN". CMakeLists files in this project can
   2 # refer to the root source directory of the project as ${VULKAN_SOURCE_DIR} and
   3 # to the root binary directory of the project as ${VULKAN_BINARY_DIR}.
   4 cmake_minimum_required(VERSION 2.8.11)
   5 project (VULKAN)
   6 # set (CMAKE_VERBOSE_MAKEFILE 1)
   7
   8 # The API_NAME allows renaming builds to avoid conflicts with installed SDKs
   9 # The MAJOR number of the version we're building, used in naming
  10 # <api-name>-<major>.dll (and other files).
  11 set(API_NAME "Vulkan" CACHE STRING "API name to use when building")
  12 set(MAJOR "1")
  13 string(TOLOWER ${API_NAME} API_LOWERCASE)
  14
  15 set(CMAKE_MODULE_PATH ${CMAKE_MODULE_PATH} "${CMAKE_CURRENT_SOURCE_DIR}/cmake")
  16 find_package(PythonInterp 3 REQUIRED)
  17
  18 if(CMAKE_SYSTEM_NAME STREQUAL "Linux")
  19     include(FindPkgConfig)
  20     option(BUILD_WSI_XCB_SUPPORT "Build XCB WSI support" ON)
  21     option(BUILD_WSI_XLIB_SUPPORT "Build Xlib WSI support" ON)
  22     option(BUILD_WSI_WAYLAND_SUPPORT "Build Wayland WSI support" ON)
  23     option(BUILD_WSI_MIR_SUPPORT "Build Mir WSI support" ON)
  24     set(DEMOS_WSI_SELECTION "XCB" CACHE STRING "Select WSI target for demos (XCB, XLIB, WAYLAND, MIR, DISPLAY)")
  25
  26     if (BUILD_WSI_XCB_SUPPORT)
  27         find_package(XCB REQUIRED)
  28     endif()
  29
  30     if (BUILD_WSI_XLIB_SUPPORT)
  31         find_package(X11 REQUIRED)
  32     endif()
  33
  34     if (BUILD_WSI_WAYLAND_SUPPORT)
  35         find_package(Wayland REQUIRED)
  36         include_directories(${WAYLAND_CLIENT_INCLUDE_DIR})
  37     endif()
  38
  39     if (BUILD_WSI_MIR_SUPPORT)
  40         find_package(Mir REQUIRED)
  41     endif()
  42 endif()
  43
  44 set(SCRIPTS_DIR "${CMAKE_CURRENT_SOURCE_DIR}/scripts")
  45
  46 # Header file for CMake settings
  47 include_directories("${PROJECT_SOURCE_DIR}/include")
  48
  49 if (CMAKE_COMPILER_IS_GNUCC OR CMAKE_C_COMPILER_ID MATCHES "Clang")
  50     set(COMMON_COMPILE_FLAGS "-Wall -Wextra -Wno-unused-parameter -Wno-missing-field-initializers")
  51     set(COMMON_COMPILE_FLAGS "${COMMON_COMPILE_FLAGS} -fno-strict-aliasing -fno-builtin-memcmp")
  52     set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -std=c99 ${COMMON_COMPILE_FLAGS}")
  53     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} ${COMMON_COMPILE_FLAGS} -std=c++11 -fno-rtti")
  54     if (UNIX)
  55         set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -fvisibility=hidden")
  56         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -fvisibility=hidden")
  57     endif()
  58 endif()
  59
  60 if(WIN32)
  61     # Treat warnings as errors
  62     add_compile_options("$<$<CXX_COMPILER_ID:MSVC>:/WX>")
  63     # Disable RTTI
  64     add_compile_options("$<$<CXX_COMPILER_ID:MSVC>:/GR->")
  65     # Warn about nested declarations
  66     add_compile_options("$<$<CXX_COMPILER_ID:MSVC>:/w34456>")
  67 endif()
  68
  69 if(NOT WIN32)
  70     set (BUILDTGT_DIR build)
  71     set (BINDATA_DIR Bin)
  72     set (LIBSOURCE_DIR Lib)
  73 else()
  74     option(DISABLE_BUILD_PATH_DECORATION "Disable the decoration of the gslang and SPIRV-Tools build path with MSVC build type info" OFF)
  75     option(DISABLE_BUILDTGT_DIR_DECORATION "Disable the decoration of the gslang and SPIRV-Tools build path with target info" OFF)
  76
  77     # For Windows, since 32-bit and 64-bit items can co-exist, we build each in its own build directory.
  78     # 32-bit target data goes in build32, and 64-bit target data goes into build.  So, include/link the
  79     # appropriate data at build time.
  80     if (DISABLE_BUILDTGT_DIR_DECORATION)
  81         set (BUILDTGT_DIR "")
  82         set (BINDATA_DIR "")
  83         set (LIBSOURCE_DIR "")
  84     elseif (CMAKE_CL_64)
  85         set (BUILDTGT_DIR build)
  86         set (BINDATA_DIR Bin)
  87         set (LIBSOURCE_DIR Lib)
  88     else()
  89         set (BUILDTGT_DIR build32)
  90         set (BINDATA_DIR Bin32)
  91         set (LIBSOURCE_DIR Lib32)
  92     endif()
  93 endif()
  94
  95 option(BUILD_LOADER "Build loader" ON)
  96 option(BUILD_TESTS "Build tests" ON)
  97 option(BUILD_LAYERS "Build layers" ON)
  98 option(BUILD_DEMOS "Build demos" ON)
  99 option(BUILD_VKJSON "Build vkjson" ON)
 100 option(CUSTOM_GLSLANG_BIN_ROOT "Use the user defined GLSLANG_BINARY_ROOT" OFF)
 101 option(CUSTOM_SPIRV_TOOLS_BIN_ROOT "Use the user defined SPIRV_TOOLS_BINARY_ROOT" OFF)
 102
 103 #Choose natural default paths for glslang and SPIRV-Tools binaries to support custom definition by the user on the CMake command line or in the GUI
 104 set(GLSLANG_BINARY_ROOT "${CMAKE_BINARY_DIR}/../glslang" CACHE STRING "User defined path to the glslang binaries for this project")
 105 set(SPIRV_TOOLS_BINARY_ROOT "${CMAKE_BINARY_DIR}/../SPIRV-Tools" CACHE STRING "User defined path to the SPIRV-Tools binaries for this project")
 106
 107 # Define a variable for a default root location to the gslang, SPIRV-Tools and other external sources and cache it to allow the user to customize it as needed
 108 set(EXTERNAL_SOURCE_ROOT "${CMAKE_SOURCE_DIR}/external" CACHE STRING "Root path to external sources such as glslang and SPIRV-Tools")
 109
 110
 111 if (WIN32)
 112     if(CUSTOM_GLSLANG_BIN_ROOT)
 113         set(GSLANG_FINAL_BINARY_PATH ${GLSLANG_BINARY_ROOT}/${BUILDTGT_DIR})
 114     else()
 115         set(GSLANG_FINAL_BINARY_PATH "${EXTERNAL_SOURCE_ROOT}/glslang/${BUILDTGT_DIR}")
 116     endif()
 117
 118     if(DISABLE_BUILD_PATH_DECORATION)
 119         set (DEBUG_DECORATION "")
 120         set (RELEASE_DECORATION "")
 121     else()
 122         set (DEBUG_DECORATION "Debug")
 123         set (RELEASE_DECORATION "Release")
 124     endif()
 125
 126     # Take some steps to set up a variable pointing to the final glslang binaries given the variety of input options
 127     set (GLSLANG_SEARCH_PATH "${GSLANG_FINAL_BINARY_PATH}/glslang/${RELEASE_DECORATION}"
 128                              "${GSLANG_FINAL_BINARY_PATH}/glslang/OSDependent/Windows/${RELEASE_DECORATION}"
 129                              "${GSLANG_FINAL_BINARY_PATH}/hlsl/${RELEASE_DECORATION}"
 130                              "${GSLANG_FINAL_BINARY_PATH}/OGLCompilersDLL/${RELEASE_DECORATION}"
 131                              "${GSLANG_FINAL_BINARY_PATH}/SPIRV/${RELEASE_DECORATION}" )
 132
 133     set (GLSLANG_DEBUG_SEARCH_PATH "${GSLANG_FINAL_BINARY_PATH}/glslang/${DEBUG_DECORATION}"
 134                                    "${GSLANG_FINAL_BINARY_PATH}/glslang/OSDependent/Windows/${DEBUG_DECORATION}"
 135                                    "${GSLANG_FINAL_BINARY_PATH}/hlsl/${DEBUG_DECORATION}"
 136                                    "${GSLANG_FINAL_BINARY_PATH}/OGLCompilersDLL/${DEBUG_DECORATION}"
 137                                    "${GSLANG_FINAL_BINARY_PATH}/SPIRV/${DEBUG_DECORATION}")
 138
 139     if(CUSTOM_SPIRV_TOOLS_BIN_ROOT)
 140         set (SPIRV_TOOLS_SEARCH_PATH "${SPIRV_TOOLS_BINARY_ROOT}/${BUILDTGT_DIR}/source/${RELEASE_DECORATION}")
 141         set (SPIRV_TOOLS_DEBUG_SEARCH_PATH "${SPIRV_TOOLS_BINARY_ROOT}/${BUILDTGT_DIR}/source/${DEBUG_DECORATION}")
 142     else()
 143         set (SPIRV_TOOLS_SEARCH_PATH "${EXTERNAL_SOURCE_ROOT}/spirv-tools/${BUILDTGT_DIR}/source/${RELEASE_DECORATION}")
 144         set (SPIRV_TOOLS_DEBUG_SEARCH_PATH "${EXTERNAL_SOURCE_ROOT}/spirv-tools/${BUILDTGT_DIR}/source/${DEBUG_DECORATION}")
 145     endif()
 146 else()
 147     #non windows
 148     if(CUSTOM_GLSLANG_BIN_ROOT)
 149         set (GLSLANG_SEARCH_PATH "${GLSLANG_BINARY_ROOT}/install/lib"
 150                                  "${GLSLANG_BINARY_ROOT}/glslang"
 151                                  "${GLSLANG_BINARY_ROOT}/glslang/OSDependent/Unix"
 152                                  "${GLSLANG_BINARY_ROOT}/OGLCompilersDLL"
 153                                  "${GLSLANG_BINARY_ROOT}/SPIRV"
 154                                  "${GLSLANG_BINARY_ROOT}/hlsl"
 155                                  "${GLSLANG_BINARY_ROOT}/StandAlone")
 156     else()
 157         set (GLSLANG_SEARCH_PATH "${EXTERNAL_SOURCE_ROOT}/glslang/${BUILDTGT_DIR}/install/lib" "${CMAKE_SOURCE_DIR}/../x86_64/lib/glslang" )
 158     endif()
 159
 160     if(CUSTOM_SPIRV_TOOLS_BIN_ROOT)
 161         set (SPIRV_TOOLS_SEARCH_PATH "${SPIRV_TOOLS_BINARY_ROOT}/source" )
 162     else()
 163         set (SPIRV_TOOLS_SEARCH_PATH "${EXTERNAL_SOURCE_ROOT}/spirv-tools/${BUILDTGT_DIR}/source" "${CMAKE_SOURCE_DIR}/../x86_64/lib/spirv-tools" )
 164     endif()
 165 endif()
 166
 167 find_program(GLSLANG_VALIDATOR NAMES glslangValidator
 168              HINTS "${CMAKE_SOURCE_DIR}/external/glslang/${BUILDTGT_DIR}/install/bin"
 169                    "${GLSLANG_BINARY_ROOT}/StandAlone"
 170                    "${PROJECT_SOURCE_DIR}/external/${BINDATA_DIR}")
 171
 172 find_path(GLSLANG_SPIRV_INCLUDE_DIR SPIRV/spirv.hpp HINTS "${EXTERNAL_SOURCE_ROOT}/glslang"
 173                                                     "${CMAKE_SOURCE_DIR}/../glslang"
 174                                               DOC "Path to SPIRV/spirv.hpp")
 175
 176 find_path(SPIRV_TOOLS_INCLUDE_DIR spirv-tools/libspirv.h HINTS "${EXTERNAL_SOURCE_ROOT}/spirv-tools/include"
 177                                                    "${EXTERNAL_SOURCE_ROOT}/SPIRV-Tools/include"
 178                                                    "${CMAKE_SOURCE_DIR}/../spirv-tools/include"
 179                                                    "${CMAKE_SOURCE_DIR}/../SPIRV-Tools/include"
 180                                                    "${EXTERNAL_SOURCE_ROOT}/source/spirv-tools/external/include"
 181                                              DOC "Path to spirv-tools/libspirv.h")
 182
 183 find_library(GLSLANG_LIB NAMES glslang
 184              HINTS ${GLSLANG_SEARCH_PATH} )
 185
 186 find_library(OGLCompiler_LIB NAMES OGLCompiler
 187              HINTS ${GLSLANG_SEARCH_PATH} )
 188
 189 find_library(OSDependent_LIB NAMES OSDependent
 190              HINTS ${GLSLANG_SEARCH_PATH} )
 191
 192 find_library(HLSL_LIB NAMES HLSL
 193              HINTS ${GLSLANG_SEARCH_PATH} )
 194
 195 find_library(SPIRV_LIB NAMES SPIRV
 196              HINTS ${GLSLANG_SEARCH_PATH} )
 197
 198 find_library(SPIRV_REMAPPER_LIB NAMES SPVRemapper
 199              HINTS ${GLSLANG_SEARCH_PATH} )
 200
 201 find_library(SPIRV_TOOLS_LIB NAMES SPIRV-Tools
 202              HINTS ${SPIRV_TOOLS_SEARCH_PATH} )
 203
 204 if (WIN32)
 205     add_library(glslang     STATIC IMPORTED)
 206     add_library(OGLCompiler STATIC IMPORTED)
 207     add_library(OSDependent STATIC IMPORTED)
 208     add_library(HLSL        STATIC IMPORTED)
 209     add_library(SPIRV       STATIC IMPORTED)
 210     add_library(SPVRemapper       STATIC IMPORTED)
 211     add_library(Loader      STATIC IMPORTED)
 212     add_library(SPIRV-Tools STATIC IMPORTED)
 213
 214     find_library(GLSLANG_DLIB NAMES glslangd
 215                  HINTS ${GLSLANG_DEBUG_SEARCH_PATH} )
 216     find_library(OGLCompiler_DLIB NAMES OGLCompilerd
 217                  HINTS ${GLSLANG_DEBUG_SEARCH_PATH} )
 218     find_library(OSDependent_DLIB NAMES OSDependentd
 219                  HINTS ${GLSLANG_DEBUG_SEARCH_PATH} )
 220     find_library(HLSL_DLIB NAMES HLSLd
 221                  HINTS ${GLSLANG_DEBUG_SEARCH_PATH} )
 222     find_library(SPIRV_DLIB NAMES SPIRVd
 223                  HINTS ${GLSLANG_DEBUG_SEARCH_PATH} )
 224     find_library(SPIRV_REMAPPER_DLIB NAMES SPVRemapperd
 225                  HINTS ${GLSLANG_DEBUG_SEARCH_PATH} )
 226     find_library(SPIRV_TOOLS_DLIB NAMES SPIRV-Tools
 227                  HINTS ${SPIRV_TOOLS_DEBUG_SEARCH_PATH} )
 228
 229     set_target_properties(glslang PROPERTIES
 230                          IMPORTED_LOCATION       "${GLSLANG_LIB}"
 231                          IMPORTED_LOCATION_DEBUG "${GLSLANG_DLIB}")
 232     set_target_properties(OGLCompiler PROPERTIES
 233                          IMPORTED_LOCATION       "${OGLCompiler_LIB}"
 234                          IMPORTED_LOCATION_DEBUG "${OGLCompiler_DLIB}")
 235     set_target_properties(OSDependent PROPERTIES
 236                          IMPORTED_LOCATION       "${OSDependent_LIB}"
 237                          IMPORTED_LOCATION_DEBUG "${OSDependent_DLIB}")
 238     set_target_properties(HLSL PROPERTIES
 239                          IMPORTED_LOCATION       "${HLSL_LIB}"
 240                          IMPORTED_LOCATION_DEBUG "${HLSL_DLIB}")
 241     set_target_properties(SPIRV PROPERTIES
 242                          IMPORTED_LOCATION       "${SPIRV_LIB}"
 243                          IMPORTED_LOCATION_DEBUG "${SPIRV_DLIB}")
 244     set_target_properties(SPVRemapper PROPERTIES
 245                          IMPORTED_LOCATION       "${SPIRV_REMAPPER_LIB}"
 246                          IMPORTED_LOCATION_DEBUG "${SPIRV_REMAPPER_DLIB}")
 247     set_target_properties(SPIRV-Tools PROPERTIES
 248                          IMPORTED_LOCATION       "${SPIRV_TOOLS_LIB}"
 249                          IMPORTED_LOCATION_DEBUG "${SPIRV_TOOLS_DLIB}")
 250
 251     set (GLSLANG_LIBRARIES glslang OGLCompiler OSDependent HLSL SPIRV SPVRemapper)
 252     set (SPIRV_TOOLS_LIBRARIES SPIRV-Tools)
 253 else ()
 254     set (GLSLANG_LIBRARIES ${GLSLANG_LIB} ${OGLCompiler_LIB} ${OSDependent_LIB} ${HLSL_LIB} ${SPIRV_LIB} ${SPIRV_REMAPPER_LIB})
 255     set (SPIRV_TOOLS_LIBRARIES ${SPIRV_TOOLS_LIB})
 256 endif()
 257
 258 set (PYTHON_CMD ${PYTHON_EXECUTABLE})
 259
 260 # Define macro used for building vkxml generated files
 261 macro(run_vk_xml_generate dependency output)
 262     add_custom_command(OUTPUT ${output}
 263     COMMAND ${PYTHON_CMD} ${SCRIPTS_DIR}/lvl_genvk.py -registry ${SCRIPTS_DIR}/vk.xml ${output}
 264     DEPENDS ${SCRIPTS_DIR}/vk.xml ${SCRIPTS_DIR}/generator.py ${SCRIPTS_DIR}/${dependency} ${SCRIPTS_DIR}/lvl_genvk.py ${SCRIPTS_DIR}/reg.py
 265     )
 266 endmacro()
 267
 268 # Custom target for generated vulkan helper file dependencies
 269 add_custom_target(generate_helper_files DEPENDS
 270     vk_dispatch_table_helper.h
 271     vk_enum_string_helper.h
 272     vk_struct_size_helper.h
 273     vk_struct_size_helper.c
 274     vk_safe_struct.h
 275     vk_safe_struct.cpp
 276     )
 277
 278 # Rules to build generated helper files
 279 run_vk_xml_generate(helper_file_generator.py vk_safe_struct.h)
 280 run_vk_xml_generate(helper_file_generator.py vk_safe_struct.cpp)
 281 run_vk_xml_generate(helper_file_generator.py vk_struct_size_helper.h)
 282 run_vk_xml_generate(helper_file_generator.py vk_struct_size_helper.c)
 283 run_vk_xml_generate(helper_file_generator.py vk_enum_string_helper.h)
 284 run_vk_xml_generate(dispatch_table_generator.py vk_dispatch_table_helper.h)
 285
 286 if(NOT WIN32)
 287     include(GNUInstallDirs)
 288
 289     add_definitions(-DSYSCONFDIR="${CMAKE_INSTALL_FULL_SYSCONFDIR}")
 290     # Make sure /etc is searched by the loader
 291     if(NOT (CMAKE_INSTALL_FULL_SYSCONFDIR STREQUAL "/etc"))
 292         add_definitions(-DEXTRASYSCONFDIR="/etc")
 293     endif()
 294 endif()
 295
 296 if(UNIX)
 297     install(DIRECTORY "${PROJECT_SOURCE_DIR}/include/vulkan" DESTINATION ${CMAKE_INSTALL_INCLUDEDIR})
 298 endif()
 299
 300 # loader: Generic VULKAN ICD loader
 301 # tests: VULKAN tests
 302 if(BUILD_LOADER)
 303     add_subdirectory(loader)
 304 endif()
 305
 306 if(BUILD_TESTS)
 307     add_subdirectory(tests)
 308 endif()
 309
 310 if(BUILD_LAYERS)
 311     add_subdirectory(layers)
 312 endif()
 313
 314 if(BUILD_DEMOS)
 315     add_subdirectory(demos)
 316 endif()
 317
 318 if(BUILD_VKJSON)
 319     add_subdirectory(libs/vkjson)
 320 endif()