CMakeLists.txt

   1 # ----------------------------------------------------------------------------
   2 #  Root CMake file for OpenCV
   3 #
   4 #    From the off-tree build directory, invoke:
   5 #      $ cmake <PATH_TO_OPENCV_ROOT>
   6 #
   7 # ----------------------------------------------------------------------------
   8
   9 # Disable in-source builds to prevent source tree corruption.
  10 if(" ${CMAKE_SOURCE_DIR}" STREQUAL " ${CMAKE_BINARY_DIR}")
  11   message(FATAL_ERROR "
  12 FATAL: In-source builds are not allowed.
  13        You should create a separate directory for build files.
  14 ")
  15 endif()
  16
  17
  18 include(cmake/OpenCVMinDepVersions.cmake)
  19
  20 if(CMAKE_GENERATOR MATCHES Xcode AND XCODE_VERSION VERSION_GREATER 4.3)
  21   cmake_minimum_required(VERSION 3.0 FATAL_ERROR)
  22 elseif(CMAKE_SYSTEM_NAME MATCHES WindowsPhone OR CMAKE_SYSTEM_NAME MATCHES WindowsStore)
  23   cmake_minimum_required(VERSION 3.1 FATAL_ERROR)
  24   #Required to resolve linker error issues due to incompatibility with CMake v3.0+ policies.
  25   #CMake fails to find _fseeko() which leads to subsequent linker error.
  26   #See details here: http://www.cmake.org/Wiki/CMake/Policies
  27   cmake_policy(VERSION 2.8)
  28 else()
  29   cmake_minimum_required(VERSION "${MIN_VER_CMAKE}" FATAL_ERROR)
  30 endif()
  31
  32 option(ENABLE_PIC "Generate position independent code (necessary for shared libraries)" TRUE)
  33 set(CMAKE_POSITION_INDEPENDENT_CODE ${ENABLE_PIC})
  34
  35 # Following block can break build in case of cross-compiling
  36 # but CMAKE_CROSSCOMPILING variable will be set only on project(OpenCV) command
  37 # so we will try to detect cross-compiling by the presence of CMAKE_TOOLCHAIN_FILE
  38 if(NOT DEFINED CMAKE_INSTALL_PREFIX)
  39   if(NOT CMAKE_TOOLCHAIN_FILE)
  40     # it _must_ go before project(OpenCV) in order to work
  41     if(WIN32)
  42       set(CMAKE_INSTALL_PREFIX "${CMAKE_BINARY_DIR}/install" CACHE PATH "Installation Directory")
  43     else()
  44       set(CMAKE_INSTALL_PREFIX "/usr/local" CACHE PATH "Installation Directory")
  45     endif()
  46   else()
  47     #Android: set output folder to ${CMAKE_BINARY_DIR}
  48     set(LIBRARY_OUTPUT_PATH_ROOT ${CMAKE_BINARY_DIR} CACHE PATH "root for library output, set this to change where android libs are compiled to" )
  49     # any cross-compiling
  50     set(CMAKE_INSTALL_PREFIX "${CMAKE_BINARY_DIR}/install" CACHE PATH "Installation Directory")
  51   endif()
  52 endif()
  53
  54 if(CMAKE_SYSTEM_NAME MATCHES WindowsPhone OR CMAKE_SYSTEM_NAME MATCHES WindowsStore)
  55   set(WINRT TRUE)
  56 endif()
  57
  58 if(WINRT)
  59   add_definitions(-DWINRT -DNO_GETENV)
  60
  61   # Making definitions available to other configurations and
  62   # to filter dependency restrictions at compile time.
  63   if(CMAKE_SYSTEM_NAME MATCHES WindowsPhone)
  64     set(WINRT_PHONE TRUE)
  65     add_definitions(-DWINRT_PHONE)
  66   elseif(CMAKE_SYSTEM_NAME MATCHES WindowsStore)
  67     set(WINRT_STORE TRUE)
  68     add_definitions(-DWINRT_STORE)
  69   endif()
  70
  71   if(CMAKE_SYSTEM_VERSION MATCHES 10)
  72     set(WINRT_10 TRUE)
  73     add_definitions(-DWINRT_10)
  74   elseif(CMAKE_SYSTEM_VERSION MATCHES 8.1)
  75     set(WINRT_8_1 TRUE)
  76     add_definitions(-DWINRT_8_1)
  77   elseif(CMAKE_SYSTEM_VERSION MATCHES 8.0)
  78     set(WINRT_8_0 TRUE)
  79     add_definitions(-DWINRT_8_0)
  80   endif()
  81 endif()
  82
  83 if(POLICY CMP0026)
  84   cmake_policy(SET CMP0026 NEW)
  85 endif()
  86
  87 if(POLICY CMP0042)
  88   cmake_policy(SET CMP0042 NEW)
  89 endif()
  90
  91 if(POLICY CMP0046)
  92   cmake_policy(SET CMP0046 NEW)
  93 endif()
  94
  95 if(POLICY CMP0051)
  96   cmake_policy(SET CMP0051 NEW)
  97 endif()
  98
  99 if(POLICY CMP0054)  # CMake 3.1: Only interpret if() arguments as variables or keywords when unquoted.
 100   cmake_policy(SET CMP0054 NEW)
 101 endif()
 102
 103 if(POLICY CMP0056)
 104   cmake_policy(SET CMP0056 NEW)
 105 endif()
 106
 107 if(POLICY CMP0067)
 108   cmake_policy(SET CMP0067 NEW)
 109 endif()
 110
 111 include(cmake/OpenCVUtils.cmake)
 112 ocv_cmake_reset_hooks()
 113 ocv_check_environment_variables(OPENCV_CMAKE_HOOKS_DIR)
 114 if(DEFINED OPENCV_CMAKE_HOOKS_DIR)
 115   foreach(__dir ${OPENCV_CMAKE_HOOKS_DIR})
 116     get_filename_component(__dir "${__dir}" ABSOLUTE)
 117     ocv_cmake_hook_register_dir(${__dir})
 118   endforeach()
 119 endif()
 120
 121 ocv_cmake_hook(CMAKE_INIT)
 122
 123 # must go before the project command
 124 ocv_update(CMAKE_CONFIGURATION_TYPES "Debug;Release" CACHE STRING "Configs" FORCE)
 125 if(DEFINED CMAKE_BUILD_TYPE)
 126   set_property( CACHE CMAKE_BUILD_TYPE PROPERTY STRINGS ${CMAKE_CONFIGURATION_TYPES} )
 127 endif()
 128
 129 enable_testing()
 130
 131 project(OpenCV CXX C)
 132
 133 if(MSVC)
 134   set(CMAKE_USE_RELATIVE_PATHS ON CACHE INTERNAL "" FORCE)
 135 endif()
 136
 137 ocv_cmake_eval(DEBUG_PRE ONCE)
 138
 139 ocv_clear_vars(OpenCVModules_TARGETS)
 140
 141 include(cmake/OpenCVDownload.cmake)
 142
 143 set(BUILD_LIST "" CACHE STRING "Build only listed modules (comma-separated, e.g. 'videoio,dnn,ts')")
 144
 145 # ----------------------------------------------------------------------------
 146 # Break in case of popular CMake configuration mistakes
 147 # ----------------------------------------------------------------------------
 148 if(NOT CMAKE_SIZEOF_VOID_P GREATER 0)
 149   message(FATAL_ERROR "CMake fails to determine the bitness of the target platform.
 150   Please check your CMake and compiler installation. If you are cross-compiling then ensure that your CMake toolchain file correctly sets the compiler details.")
 151 endif()
 152
 153 # ----------------------------------------------------------------------------
 154 # Detect compiler and target platform architecture
 155 # ----------------------------------------------------------------------------
 156 OCV_OPTION(ENABLE_CXX11 "Enable C++11 compilation mode" "${OPENCV_CXX11}")
 157 include(cmake/OpenCVDetectCXXCompiler.cmake)
 158 ocv_cmake_hook(POST_DETECT_COMPILER)
 159
 160 # Add these standard paths to the search paths for FIND_LIBRARY
 161 # to find libraries from these locations first
 162 if(UNIX AND NOT ANDROID)
 163   if(X86_64 OR CMAKE_SIZEOF_VOID_P EQUAL 8)
 164     if(EXISTS /lib64)
 165       list(APPEND CMAKE_LIBRARY_PATH /lib64)
 166     else()
 167       list(APPEND CMAKE_LIBRARY_PATH /lib)
 168     endif()
 169     if(EXISTS /usr/lib64)
 170       list(APPEND CMAKE_LIBRARY_PATH /usr/lib64)
 171     else()
 172       list(APPEND CMAKE_LIBRARY_PATH /usr/lib)
 173     endif()
 174   elseif(X86 OR CMAKE_SIZEOF_VOID_P EQUAL 4)
 175     if(EXISTS /lib32)
 176       list(APPEND CMAKE_LIBRARY_PATH /lib32)
 177     else()
 178       list(APPEND CMAKE_LIBRARY_PATH /lib)
 179     endif()
 180     if(EXISTS /usr/lib32)
 181       list(APPEND CMAKE_LIBRARY_PATH /usr/lib32)
 182     else()
 183       list(APPEND CMAKE_LIBRARY_PATH /usr/lib)
 184     endif()
 185   endif()
 186 endif()
 187
 188 # Add these standard paths to the search paths for FIND_PATH
 189 # to find include files from these locations first
 190 if(MINGW)
 191   if(EXISTS /mingw)
 192       list(APPEND CMAKE_INCLUDE_PATH /mingw)
 193   endif()
 194   if(EXISTS /mingw32)
 195       list(APPEND CMAKE_INCLUDE_PATH /mingw32)
 196   endif()
 197   if(EXISTS /mingw64)
 198       list(APPEND CMAKE_INCLUDE_PATH /mingw64)
 199   endif()
 200 endif()
 201
 202 # ----------------------------------------------------------------------------
 203 # OpenCV cmake options
 204 # ----------------------------------------------------------------------------
 205
 206 OCV_OPTION(OPENCV_ENABLE_NONFREE "Enable non-free algorithms" OFF)
 207
 208 # 3rd party libs
 209 OCV_OPTION(BUILD_ZLIB               "Build zlib from source"             WIN32 OR APPLE)
 210 OCV_OPTION(BUILD_TIFF               "Build libtiff from source"          WIN32 OR ANDROID OR APPLE)
 211 OCV_OPTION(BUILD_JASPER             "Build libjasper from source"        WIN32 OR ANDROID OR APPLE)
 212 OCV_OPTION(BUILD_JPEG               "Build libjpeg from source"          WIN32 OR ANDROID OR APPLE)
 213 OCV_OPTION(BUILD_PNG                "Build libpng from source"           WIN32 OR ANDROID OR APPLE)
 214 OCV_OPTION(BUILD_OPENEXR            "Build openexr from source"          (WIN32 OR ANDROID OR APPLE) AND NOT WINRT)
 215 OCV_OPTION(BUILD_WEBP               "Build WebP from source"             (WIN32 OR ANDROID OR APPLE) AND NOT WINRT)
 216 OCV_OPTION(BUILD_TBB                "Download and build TBB from source" ANDROID )
 217 OCV_OPTION(BUILD_IPP_IW             "Build IPP IW from source"           NOT MINGW IF (X86_64 OR X86) AND NOT WINRT )
 218 OCV_OPTION(BUILD_ITT                "Build Intel ITT from source"        NOT MINGW IF (X86_64 OR X86) AND NOT WINRT AND NOT APPLE_FRAMEWORK )
 219
 220 # Optional 3rd party components
 221 # ===================================================
 222 OCV_OPTION(WITH_1394           "Include IEEE1394 support"                    ON   IF (NOT ANDROID AND NOT IOS AND NOT WINRT) )
 223 OCV_OPTION(WITH_AVFOUNDATION   "Use AVFoundation for Video I/O (iOS/Mac)"    ON   IF APPLE)
 224 OCV_OPTION(WITH_CARBON         "Use Carbon for UI instead of Cocoa"          OFF  IF APPLE )
 225 OCV_OPTION(WITH_CAROTENE       "Use NVidia carotene acceleration library for ARM platform"                   ON  IF (ARM OR AARCH64) AND NOT IOS AND NOT (CMAKE_VERSION VERSION_LESS "2.8.11"))
 226 OCV_OPTION(WITH_CPUFEATURES    "Use cpufeatures Android library"             ON   IF ANDROID)
 227 OCV_OPTION(WITH_VTK            "Include VTK library support (and build opencv_viz module eiher)"             ON  IF (NOT ANDROID AND NOT IOS AND NOT WINRT AND NOT CMAKE_CROSSCOMPILING) )
 228 OCV_OPTION(WITH_CUDA           "Include NVidia Cuda Runtime support"                                         OFF IF (NOT IOS AND NOT WINRT) )
 229 OCV_OPTION(WITH_CUFFT          "Include NVidia Cuda Fast Fourier Transform (FFT) library support"            ON  IF (NOT IOS AND NOT WINRT) )
 230 OCV_OPTION(WITH_CUBLAS         "Include NVidia Cuda Basic Linear Algebra Subprograms (BLAS) library support" ON IF (NOT IOS AND NOT WINRT) )
 231 OCV_OPTION(WITH_NVCUVID        "Include NVidia Video Decoding library support"                               ON IF (NOT IOS AND NOT APPLE) )
 232 OCV_OPTION(WITH_EIGEN          "Include Eigen2/Eigen3 support"               (NOT CV_DISABLE_OPTIMIZATION)       IF (NOT WINRT AND NOT CMAKE_CROSSCOMPILING) )
 233 OCV_OPTION(WITH_VFW            "Include Video for Windows support"           ON   IF WIN32 )
 234 OCV_OPTION(WITH_FFMPEG         "Include FFMPEG support"                      ON   IF (NOT ANDROID AND NOT IOS AND NOT WINRT) )
 235 OCV_OPTION(WITH_GSTREAMER      "Include Gstreamer support"                   ON   IF (NOT ANDROID AND NOT IOS AND NOT WINRT) )
 236 OCV_OPTION(WITH_GSTREAMER_0_10 "Enable Gstreamer 0.10 support (instead of 1.x)"                              OFF )
 237 OCV_OPTION(WITH_GTK            "Include GTK support"                         ON   IF (UNIX AND NOT APPLE AND NOT ANDROID) )
 238 OCV_OPTION(WITH_GTK_2_X        "Use GTK version 2"                           OFF  IF (UNIX AND NOT APPLE AND NOT ANDROID) )
 239 OCV_OPTION(WITH_IPP            "Include Intel IPP support"                   (NOT MINGW AND NOT CV_DISABLE_OPTIMIZATION)  IF (X86_64 OR X86) AND NOT WINRT AND NOT IOS )
 240 OCV_OPTION(WITH_HALIDE         "Include Halide support"                      OFF)
 241 OCV_OPTION(WITH_INF_ENGINE     "Include Intel Inference Engine support"      OFF)
 242 OCV_OPTION(WITH_JASPER         "Include JPEG2K support"                      ON   IF (NOT IOS) )
 243 OCV_OPTION(WITH_JPEG           "Include JPEG support"                        ON)
 244 OCV_OPTION(WITH_WEBP           "Include WebP support"                        ON   IF (NOT WINRT) )
 245 OCV_OPTION(WITH_OPENEXR        "Include ILM support via OpenEXR"             ON   IF (NOT IOS AND NOT WINRT) )
 246 OCV_OPTION(WITH_OPENGL         "Include OpenGL support"                      OFF  IF (NOT ANDROID AND NOT WINRT) )
 247 OCV_OPTION(WITH_OPENVX         "Include OpenVX support"                      OFF)
 248 OCV_OPTION(WITH_OPENNI         "Include OpenNI support"                      OFF  IF (NOT ANDROID AND NOT IOS AND NOT WINRT) )
 249 OCV_OPTION(WITH_OPENNI2        "Include OpenNI2 support"                     OFF  IF (NOT ANDROID AND NOT IOS AND NOT WINRT) )
 250 OCV_OPTION(WITH_PNG            "Include PNG support"                         ON)
 251 OCV_OPTION(WITH_GDCM           "Include DICOM support"                       OFF)
 252 OCV_OPTION(WITH_PVAPI          "Include Prosilica GigE support"              OFF   IF (NOT ANDROID AND NOT IOS AND NOT WINRT) )
 253 OCV_OPTION(WITH_GIGEAPI        "Include Smartek GigE support"                OFF   IF (NOT ANDROID AND NOT IOS AND NOT WINRT) )
 254 OCV_OPTION(WITH_ARAVIS         "Include Aravis GigE support"                 OFF   IF (NOT ANDROID AND NOT IOS AND NOT WINRT AND NOT WIN32) )
 255 OCV_OPTION(WITH_QT             "Build with Qt Backend support"               OFF  IF (NOT ANDROID AND NOT IOS AND NOT WINRT) )
 256 OCV_OPTION(WITH_WIN32UI        "Build with Win32 UI Backend support"         ON   IF WIN32 AND NOT WINRT)
 257 OCV_OPTION(WITH_QUICKTIME      "Use QuickTime for Video I/O"                 OFF  IF APPLE )
 258 OCV_OPTION(WITH_QTKIT          "Use QTKit Video I/O backend"                 OFF  IF APPLE )
 259 OCV_OPTION(WITH_TBB            "Include Intel TBB support"                   OFF  IF (NOT IOS AND NOT WINRT) )
 260 OCV_OPTION(WITH_OPENMP         "Include OpenMP support"                      OFF)
 261 OCV_OPTION(WITH_CSTRIPES       "Include C= support"                          OFF  IF (WIN32 AND NOT WINRT)  )
 262 OCV_OPTION(WITH_PTHREADS_PF    "Use pthreads-based parallel_for"             ON   IF (NOT WIN32 OR MINGW) )
 263 OCV_OPTION(WITH_TIFF           "Include TIFF support"                        ON   IF (NOT IOS) )
 264 OCV_OPTION(WITH_UNICAP         "Include Unicap support (GPL)"                OFF  IF (UNIX AND NOT APPLE AND NOT ANDROID) )
 265 OCV_OPTION(WITH_V4L            "Include Video 4 Linux support"               ON   IF (UNIX AND NOT ANDROID AND NOT APPLE) )
 266 OCV_OPTION(WITH_LIBV4L         "Use libv4l for Video 4 Linux support"        OFF  IF (UNIX AND NOT ANDROID AND NOT APPLE) )
 267 OCV_OPTION(WITH_DSHOW          "Build VideoIO with DirectShow support"       ON   IF (WIN32 AND NOT ARM AND NOT WINRT) )
 268 OCV_OPTION(WITH_MSMF           "Build VideoIO with Media Foundation support" ON  IF WIN32 )
 269 OCV_OPTION(WITH_XIMEA          "Include XIMEA cameras support"               OFF  IF (NOT ANDROID AND NOT WINRT) )
 270 OCV_OPTION(WITH_XINE           "Include Xine support (GPL)"                  OFF  IF (UNIX AND NOT APPLE AND NOT ANDROID) )
 271 OCV_OPTION(WITH_CLP            "Include Clp support (EPL)"                   OFF)
 272 OCV_OPTION(WITH_OPENCL         "Include OpenCL Runtime support"              (NOT ANDROID AND NOT CV_DISABLE_OPTIMIZATION)  IF (NOT IOS AND NOT WINRT) )
 273 OCV_OPTION(WITH_OPENCL_SVM     "Include OpenCL Shared Virtual Memory support" OFF ) # experimental
 274 OCV_OPTION(WITH_OPENCLAMDFFT   "Include AMD OpenCL FFT library support"      ON   IF (NOT ANDROID AND NOT IOS AND NOT WINRT) )
 275 OCV_OPTION(WITH_OPENCLAMDBLAS  "Include AMD OpenCL BLAS library support"     ON   IF (NOT ANDROID AND NOT IOS AND NOT WINRT) )
 276 OCV_OPTION(WITH_DIRECTX        "Include DirectX support"                     ON   IF (WIN32 AND NOT WINRT) )
 277 OCV_OPTION(WITH_INTELPERC      "Include Intel Perceptual Computing support"  OFF  IF (WIN32 AND NOT WINRT) )
 278 OCV_OPTION(WITH_VA             "Include VA support"                          OFF  IF (UNIX AND NOT ANDROID) )
 279 OCV_OPTION(WITH_VA_INTEL       "Include Intel VA-API/OpenCL support"         OFF  IF (UNIX AND NOT ANDROID) )
 280 OCV_OPTION(WITH_MFX            "Include Intel Media SDK support"             OFF   IF ((UNIX AND NOT ANDROID) OR (WIN32 AND NOT WINRT AND NOT MINGW)) )
 281 OCV_OPTION(WITH_GDAL           "Include GDAL Support"                        OFF  IF (NOT ANDROID AND NOT IOS AND NOT WINRT) )
 282 OCV_OPTION(WITH_GPHOTO2        "Include gPhoto2 library support"             OFF  IF (UNIX AND NOT ANDROID AND NOT IOS) )
 283 OCV_OPTION(WITH_LAPACK         "Include Lapack library support"              (NOT CV_DISABLE_OPTIMIZATION)  IF (NOT ANDROID AND NOT IOS) )
 284 OCV_OPTION(WITH_ITT            "Include Intel ITT support"                   ON   IF (NOT APPLE_FRAMEWORK) )
 285 OCV_OPTION(WITH_PROTOBUF       "Enable libprotobuf"                          ON )
 286 OCV_OPTION(WITH_IMGCODEC_HDR   "Include HDR support"                         ON)
 287 OCV_OPTION(WITH_IMGCODEC_SUNRASTER "Include SUNRASTER support"               ON)
 288 OCV_OPTION(WITH_IMGCODEC_PXM   "Include PNM (PBM,PGM,PPM) and PAM formats support" ON)
 289 OCV_OPTION(WITH_QUIRC          "Include library QR-code decoding"            ON)
 290
 291 # OpenCV build components
 292 # ===================================================
 293 OCV_OPTION(BUILD_SHARED_LIBS        "Build shared libraries (.dll/.so) instead of static ones (.lib/.a)" NOT (ANDROID OR APPLE_FRAMEWORK) )
 294 OCV_OPTION(BUILD_opencv_apps        "Build utility applications (used for example to train classifiers)" (NOT ANDROID AND NOT WINRT) IF (NOT APPLE_FRAMEWORK) )
 295 OCV_OPTION(BUILD_opencv_js          "Build JavaScript bindings by Emscripten" OFF )
 296 OCV_OPTION(BUILD_ANDROID_PROJECTS   "Build Android projects providing .apk files" ON  IF ANDROID )
 297 OCV_OPTION(BUILD_ANDROID_EXAMPLES   "Build examples for Android platform"         ON  IF ANDROID )
 298 OCV_OPTION(BUILD_DOCS               "Create build rules for OpenCV Documentation" OFF  IF (NOT WINRT AND NOT APPLE_FRAMEWORK))
 299 OCV_OPTION(BUILD_EXAMPLES           "Build all examples"                          OFF )
 300 OCV_OPTION(BUILD_PACKAGE            "Enables 'make package_source' command"       ON  IF NOT WINRT)
 301 OCV_OPTION(BUILD_PERF_TESTS         "Build performance tests"                     ON  IF (NOT APPLE_FRAMEWORK) )
 302 OCV_OPTION(BUILD_TESTS              "Build accuracy & regression tests"           ON  IF (NOT APPLE_FRAMEWORK) )
 303 OCV_OPTION(BUILD_WITH_DEBUG_INFO    "Include debug info into release binaries ('OFF' means default settings)" OFF )
 304 OCV_OPTION(BUILD_WITH_STATIC_CRT    "Enables use of statically linked CRT for statically linked OpenCV" ON IF MSVC )
 305 OCV_OPTION(BUILD_WITH_DYNAMIC_IPP   "Enables dynamic linking of IPP (only for standalone IPP)" OFF )
 306 OCV_OPTION(BUILD_FAT_JAVA_LIB       "Create Java wrapper exporting all functions of OpenCV library (requires static build of OpenCV modules)" ANDROID IF NOT BUILD_SHARED_LIBS)
 307 OCV_OPTION(BUILD_ANDROID_SERVICE    "Build OpenCV Manager for Google Play" OFF IF ANDROID )
 308 OCV_OPTION(BUILD_CUDA_STUBS         "Build CUDA modules stubs when no CUDA SDK" OFF  IF (NOT APPLE_FRAMEWORK) )
 309 OCV_OPTION(BUILD_JAVA               "Enable Java support"                         (ANDROID OR NOT CMAKE_CROSSCOMPILING)  IF (ANDROID OR (NOT APPLE_FRAMEWORK AND NOT WINRT)) )
 310
 311 # OpenCV installation options
 312 # ===================================================
 313 OCV_OPTION(INSTALL_CREATE_DISTRIB   "Change install rules to build the distribution package" OFF )
 314 OCV_OPTION(INSTALL_C_EXAMPLES       "Install C examples"        OFF )
 315 OCV_OPTION(INSTALL_PYTHON_EXAMPLES  "Install Python examples"   OFF )
 316 OCV_OPTION(INSTALL_ANDROID_EXAMPLES "Install Android examples"  OFF IF ANDROID )
 317 OCV_OPTION(INSTALL_TO_MANGLED_PATHS "Enables mangled install paths, that help with side by side installs." OFF IF (UNIX AND NOT ANDROID AND NOT APPLE_FRAMEWORK AND BUILD_SHARED_LIBS) )
 318 OCV_OPTION(INSTALL_TESTS            "Install accuracy and performance test binaries and test data" OFF)
 319
 320 # OpenCV build options
 321 # ===================================================
 322 OCV_OPTION(ENABLE_CCACHE              "Use ccache"                                               (UNIX AND NOT IOS AND (CMAKE_GENERATOR MATCHES "Makefile" OR CMAKE_GENERATOR MATCHES "Ninja")) )
 323 OCV_OPTION(ENABLE_PRECOMPILED_HEADERS "Use precompiled headers"                                  ON IF (MSVC OR (NOT IOS AND NOT CMAKE_CROSSCOMPILING) ) )
 324 OCV_OPTION(ENABLE_SOLUTION_FOLDERS    "Solution folder in Visual Studio or in other IDEs"        (MSVC_IDE OR CMAKE_GENERATOR MATCHES Xcode) )
 325 OCV_OPTION(ENABLE_PROFILING           "Enable profiling in the GCC compiler (Add flags: -g -pg)" OFF  IF CV_GCC )
 326 OCV_OPTION(ENABLE_COVERAGE            "Enable coverage collection with  GCov"                    OFF  IF CV_GCC )
 327 OCV_OPTION(ENABLE_OMIT_FRAME_POINTER  "Enable -fomit-frame-pointer for GCC"                      ON   IF CV_GCC )
 328 OCV_OPTION(ENABLE_POWERPC             "Enable PowerPC for GCC"                                   ON   IF (CV_GCC AND CMAKE_SYSTEM_PROCESSOR MATCHES powerpc.*) )
 329 OCV_OPTION(ENABLE_VSX                 "Enable POWER8 and above VSX (64-bit little-endian)"       ON   IF ((CV_GCC OR CV_CLANG) AND PPC64LE) )
 330 OCV_OPTION(ENABLE_FAST_MATH           "Enable -ffast-math (not recommended for GCC 4.6.x)"       OFF  IF (CV_GCC AND (X86 OR X86_64)) )
 331 if(NOT IOS)  # Use CPU_BASELINE instead
 332 OCV_OPTION(ENABLE_NEON                "Enable NEON instructions"                                 (NEON OR ANDROID_ARM_NEON OR AARCH64) IF (CV_GCC OR CV_CLANG) AND (ARM OR AARCH64 OR IOS) )
 333 OCV_OPTION(ENABLE_VFPV3               "Enable VFPv3-D32 instructions"                            OFF  IF (CV_GCC OR CV_CLANG) AND (ARM OR AARCH64 OR IOS) )
 334 endif()
 335 OCV_OPTION(ENABLE_NOISY_WARNINGS      "Show all warnings even if they are too noisy"             OFF )
 336 OCV_OPTION(OPENCV_WARNINGS_ARE_ERRORS "Treat warnings as errors"                                 OFF )
 337 OCV_OPTION(ANDROID_EXAMPLES_WITH_LIBS "Build binaries of Android examples with native libraries" OFF  IF ANDROID )
 338 OCV_OPTION(ENABLE_IMPL_COLLECTION     "Collect implementation data on function call"             OFF )
 339 OCV_OPTION(ENABLE_INSTRUMENTATION     "Instrument functions to collect calls trace and performance" OFF )
 340 OCV_OPTION(ENABLE_GNU_STL_DEBUG       "Enable GNU STL Debug mode (defines _GLIBCXX_DEBUG)"       OFF IF ((NOT CMAKE_VERSION VERSION_LESS "2.8.11") AND CV_GCC) )
 341 OCV_OPTION(ENABLE_BUILD_HARDENING     "Enable hardening of the resulting binaries (against security attacks, detects memory corruption, etc)" OFF)
 342 OCV_OPTION(ENABLE_LTO                 "Enable Link Time Optimization" OFF IF CV_GCC OR MSVC)
 343 OCV_OPTION(ENABLE_THIN_LTO            "Enable Thin LTO" OFF IF CV_CLANG)
 344 OCV_OPTION(GENERATE_ABI_DESCRIPTOR    "Generate XML file for abi_compliance_checker tool" OFF IF UNIX)
 345 OCV_OPTION(CV_ENABLE_INTRINSICS       "Use intrinsic-based optimized code" ON )
 346 OCV_OPTION(CV_DISABLE_OPTIMIZATION    "Disable explicit optimized code (dispatched code/intrinsics/loop unrolling/etc)" OFF )
 347 OCV_OPTION(CV_TRACE                   "Enable OpenCV code trace" ON)
 348
 349 OCV_OPTION(ENABLE_PYLINT              "Add target with Pylint checks"                            (BUILD_DOCS OR BUILD_EXAMPLES) IF (NOT CMAKE_CROSSCOMPILING AND NOT APPLE_FRAMEWORK) )
 350 OCV_OPTION(ENABLE_FLAKE8              "Add target with Python flake8 checker"                    (BUILD_DOCS OR BUILD_EXAMPLES) IF (NOT CMAKE_CROSSCOMPILING AND NOT APPLE_FRAMEWORK) )
 351
 352 if(ENABLE_IMPL_COLLECTION)
 353   add_definitions(-DCV_COLLECT_IMPL_DATA)
 354 endif()
 355
 356
 357 # ----------------------------------------------------------------------------
 358 #  Get actual OpenCV version number from sources
 359 # ----------------------------------------------------------------------------
 360 include(cmake/OpenCVVersion.cmake)
 361
 362 ocv_cmake_hook(POST_OPTIONS)
 363
 364 # ----------------------------------------------------------------------------
 365 #  Build & install layouts
 366 # ----------------------------------------------------------------------------
 367
 368 # Save libs and executables in the same place
 369 set(EXECUTABLE_OUTPUT_PATH "${CMAKE_BINARY_DIR}/bin" CACHE PATH "Output directory for applications")
 370
 371 if(ANDROID)
 372   if(ANDROID_ABI MATCHES "NEON")
 373     set(ENABLE_NEON ON)
 374   endif()
 375   if(ANDROID_ABI MATCHES "VFPV3")
 376     set(ENABLE_VFPV3 ON)
 377   endif()
 378 endif()
 379
 380 if(ANDROID OR WIN32)
 381   ocv_update(OPENCV_DOC_INSTALL_PATH doc)
 382 else()
 383   ocv_update(OPENCV_DOC_INSTALL_PATH share/OpenCV/doc)
 384 endif()
 385
 386 if(WIN32 AND CMAKE_HOST_SYSTEM_NAME MATCHES Windows)
 387   if(DEFINED OpenCV_RUNTIME AND DEFINED OpenCV_ARCH)
 388     ocv_update(OpenCV_INSTALL_BINARIES_PREFIX "${OpenCV_ARCH}/${OpenCV_RUNTIME}/")
 389   else()
 390     message(STATUS "Can't detect runtime and/or arch")
 391     ocv_update(OpenCV_INSTALL_BINARIES_PREFIX "")
 392   endif()
 393 elseif(ANDROID)
 394   ocv_update(OpenCV_INSTALL_BINARIES_PREFIX "sdk/native/")
 395 else()
 396   ocv_update(OpenCV_INSTALL_BINARIES_PREFIX "")
 397 endif()
 398
 399 if(ANDROID)
 400   ocv_update(OPENCV_SAMPLES_BIN_INSTALL_PATH "${OpenCV_INSTALL_BINARIES_PREFIX}samples/${ANDROID_NDK_ABI_NAME}")
 401 else()
 402   ocv_update(OPENCV_SAMPLES_BIN_INSTALL_PATH "${OpenCV_INSTALL_BINARIES_PREFIX}samples")
 403 endif()
 404
 405 if(ANDROID)
 406   ocv_update(OPENCV_BIN_INSTALL_PATH "${OpenCV_INSTALL_BINARIES_PREFIX}bin/${ANDROID_NDK_ABI_NAME}")
 407 else()
 408   ocv_update(OPENCV_BIN_INSTALL_PATH "${OpenCV_INSTALL_BINARIES_PREFIX}bin")
 409 endif()
 410
 411 if(NOT OPENCV_TEST_INSTALL_PATH)
 412   ocv_update(OPENCV_TEST_INSTALL_PATH "${OPENCV_BIN_INSTALL_PATH}")
 413 endif()
 414
 415 if (OPENCV_TEST_DATA_PATH)
 416   get_filename_component(OPENCV_TEST_DATA_PATH ${OPENCV_TEST_DATA_PATH} ABSOLUTE)
 417 endif()
 418
 419 if(ANDROID)
 420   ocv_update(OPENCV_TEST_DATA_INSTALL_PATH "sdk/etc/testdata")
 421 elseif(WIN32)
 422   ocv_update(OPENCV_TEST_DATA_INSTALL_PATH "testdata")
 423 else()
 424   ocv_update(OPENCV_TEST_DATA_INSTALL_PATH "share/OpenCV/testdata")
 425 endif()
 426
 427 if(ANDROID)
 428   set(LIBRARY_OUTPUT_PATH                "${OpenCV_BINARY_DIR}/lib/${ANDROID_NDK_ABI_NAME}")
 429   ocv_update(3P_LIBRARY_OUTPUT_PATH      "${OpenCV_BINARY_DIR}/3rdparty/lib/${ANDROID_NDK_ABI_NAME}")
 430   ocv_update(OPENCV_LIB_INSTALL_PATH     sdk/native/libs/${ANDROID_NDK_ABI_NAME})
 431   ocv_update(OPENCV_LIB_ARCHIVE_INSTALL_PATH sdk/native/staticlibs/${ANDROID_NDK_ABI_NAME})
 432   ocv_update(OPENCV_3P_LIB_INSTALL_PATH  sdk/native/3rdparty/libs/${ANDROID_NDK_ABI_NAME})
 433   ocv_update(OPENCV_CONFIG_INSTALL_PATH  sdk/native/jni)
 434   ocv_update(OPENCV_INCLUDE_INSTALL_PATH sdk/native/jni/include)
 435   ocv_update(OPENCV_SAMPLES_SRC_INSTALL_PATH samples/native)
 436   ocv_update(OPENCV_OTHER_INSTALL_PATH   sdk/etc)
 437 else()
 438   set(LIBRARY_OUTPUT_PATH                "${OpenCV_BINARY_DIR}/lib")
 439   ocv_update(3P_LIBRARY_OUTPUT_PATH      "${OpenCV_BINARY_DIR}/3rdparty/lib${LIB_SUFFIX}")
 440
 441   if(WIN32 AND CMAKE_HOST_SYSTEM_NAME MATCHES Windows)
 442     if(OpenCV_STATIC)
 443       ocv_update(OPENCV_LIB_INSTALL_PATH   "${OpenCV_INSTALL_BINARIES_PREFIX}staticlib${LIB_SUFFIX}")
 444     else()
 445       ocv_update(OPENCV_LIB_INSTALL_PATH   "${OpenCV_INSTALL_BINARIES_PREFIX}lib${LIB_SUFFIX}")
 446     endif()
 447     ocv_update(OPENCV_3P_LIB_INSTALL_PATH  "${OpenCV_INSTALL_BINARIES_PREFIX}staticlib${LIB_SUFFIX}")
 448     ocv_update(OPENCV_SAMPLES_SRC_INSTALL_PATH    samples)
 449     ocv_update(OPENCV_JAR_INSTALL_PATH java)
 450     ocv_update(OPENCV_OTHER_INSTALL_PATH   etc)
 451     ocv_update(OPENCV_CONFIG_INSTALL_PATH  ".")
 452   else()
 453     include(GNUInstallDirs)
 454     ocv_update(OPENCV_LIB_INSTALL_PATH     ${CMAKE_INSTALL_LIBDIR}${LIB_SUFFIX})
 455     ocv_update(OPENCV_3P_LIB_INSTALL_PATH  share/OpenCV/3rdparty/${OPENCV_LIB_INSTALL_PATH})
 456     ocv_update(OPENCV_SAMPLES_SRC_INSTALL_PATH    share/OpenCV/samples)
 457     ocv_update(OPENCV_JAR_INSTALL_PATH share/OpenCV/java)
 458     ocv_update(OPENCV_OTHER_INSTALL_PATH   share/OpenCV)
 459
 460     if(NOT DEFINED OPENCV_CONFIG_INSTALL_PATH)
 461       math(EXPR SIZEOF_VOID_P_BITS "8 * ${CMAKE_SIZEOF_VOID_P}")
 462       if(LIB_SUFFIX AND NOT SIZEOF_VOID_P_BITS EQUAL LIB_SUFFIX)
 463         ocv_update(OPENCV_CONFIG_INSTALL_PATH ${CMAKE_INSTALL_LIBDIR}${LIB_SUFFIX}/cmake/opencv)
 464       else()
 465         ocv_update(OPENCV_CONFIG_INSTALL_PATH share/OpenCV)
 466       endif()
 467     endif()
 468   endif()
 469   ocv_update(OPENCV_INCLUDE_INSTALL_PATH "include")
 470 endif()
 471
 472 ocv_update(CMAKE_INSTALL_RPATH "${CMAKE_INSTALL_PREFIX}/${OPENCV_LIB_INSTALL_PATH}")
 473 set(CMAKE_INSTALL_RPATH_USE_LINK_PATH TRUE)
 474
 475 if(INSTALL_TO_MANGLED_PATHS)
 476   set(OPENCV_INCLUDE_INSTALL_PATH ${OPENCV_INCLUDE_INSTALL_PATH}/opencv-${OPENCV_VERSION})
 477   foreach(v
 478       OPENCV_3P_LIB_INSTALL_PATH
 479       OPENCV_SAMPLES_SRC_INSTALL_PATH
 480       OPENCV_CONFIG_INSTALL_PATH
 481       OPENCV_DOC_INSTALL_PATH
 482       OPENCV_JAR_INSTALL_PATH
 483       OPENCV_TEST_DATA_INSTALL_PATH
 484       OPENCV_OTHER_INSTALL_PATH
 485     )
 486     string(REPLACE "OpenCV" "OpenCV-${OPENCV_VERSION}" ${v} "${${v}}")
 487     string(REPLACE "opencv" "opencv-${OPENCV_VERSION}" ${v} "${${v}}")
 488   endforeach()
 489 endif()
 490
 491 if(ANDROID)
 492   ocv_update(OPENCV_JNI_INSTALL_PATH "${OPENCV_LIB_INSTALL_PATH}")
 493 elseif(INSTALL_CREATE_DISTRIB)
 494   ocv_update(OPENCV_JNI_INSTALL_PATH "${OPENCV_JAR_INSTALL_PATH}/${OpenCV_ARCH}")
 495 else()
 496   ocv_update(OPENCV_JNI_INSTALL_PATH "${OPENCV_JAR_INSTALL_PATH}")
 497 endif()
 498 ocv_update(OPENCV_JNI_BIN_INSTALL_PATH "${OPENCV_JNI_INSTALL_PATH}")
 499
 500 if(NOT OPENCV_LIB_ARCHIVE_INSTALL_PATH)
 501   set(OPENCV_LIB_ARCHIVE_INSTALL_PATH ${OPENCV_LIB_INSTALL_PATH})
 502 endif()
 503
 504 if(WIN32)
 505   # Postfix of DLLs:
 506   set(OPENCV_DLLVERSION "${OPENCV_VERSION_MAJOR}${OPENCV_VERSION_MINOR}${OPENCV_VERSION_PATCH}")
 507   set(OPENCV_DEBUG_POSTFIX d)
 508 else()
 509   # Postfix of so's:
 510   set(OPENCV_DLLVERSION "")
 511   set(OPENCV_DEBUG_POSTFIX "")
 512 endif()
 513
 514 if(DEFINED CMAKE_DEBUG_POSTFIX)
 515   set(OPENCV_DEBUG_POSTFIX "${CMAKE_DEBUG_POSTFIX}")
 516 endif()
 517
 518 if((INSTALL_CREATE_DISTRIB AND BUILD_SHARED_LIBS AND NOT DEFINED BUILD_opencv_world) OR APPLE_FRAMEWORK)
 519   set(BUILD_opencv_world ON CACHE INTERNAL "")
 520 endif()
 521
 522 # ----------------------------------------------------------------------------
 523 #  Path for build/platform -specific headers
 524 # ----------------------------------------------------------------------------
 525 ocv_update(OPENCV_CONFIG_FILE_INCLUDE_DIR "${CMAKE_BINARY_DIR}/" CACHE PATH "Where to create the platform-dependant cvconfig.h")
 526 ocv_include_directories(${OPENCV_CONFIG_FILE_INCLUDE_DIR})
 527
 528 # ----------------------------------------------------------------------------
 529 #  Path for additional modules
 530 # ----------------------------------------------------------------------------
 531 set(OPENCV_EXTRA_MODULES_PATH "" CACHE PATH "Where to look for additional OpenCV modules (can be ;-separated list of paths)")
 532
 533 # ----------------------------------------------------------------------------
 534 #  Autodetect if we are in a GIT repository
 535 # ----------------------------------------------------------------------------
 536 find_host_package(Git QUIET)
 537
 538 if(NOT DEFINED OPENCV_VCSVERSION AND GIT_FOUND)
 539   ocv_git_describe(OPENCV_VCSVERSION "${OpenCV_SOURCE_DIR}")
 540 elseif(NOT DEFINED OPENCV_VCSVERSION)
 541   # We don't have git:
 542   set(OPENCV_VCSVERSION "unknown")
 543 endif()
 544
 545
 546 # ----------------------------------------------------------------------------
 547 # OpenCV compiler and linker options
 548 # ----------------------------------------------------------------------------
 549 # In case of Makefiles if the user does not setup CMAKE_BUILD_TYPE, assume it's Release:
 550 if(CMAKE_GENERATOR MATCHES "Makefiles|Ninja" AND "${CMAKE_BUILD_TYPE}" STREQUAL "")
 551   set(CMAKE_BUILD_TYPE Release)
 552 endif()
 553
 554 ocv_cmake_hook(POST_CMAKE_BUILD_OPTIONS)
 555
 556 # --- Python Support ---
 557 if(NOT IOS)
 558   include(cmake/OpenCVDetectPython.cmake)
 559 endif()
 560
 561 include(cmake/OpenCVCompilerOptions.cmake)
 562
 563 ocv_cmake_hook(POST_COMPILER_OPTIONS)
 564
 565 # ----------------------------------------------------------------------------
 566 #       CHECK FOR SYSTEM LIBRARIES, OPTIONS, ETC..
 567 # ----------------------------------------------------------------------------
 568 if(UNIX)
 569   if(NOT APPLE_FRAMEWORK OR OPENCV_ENABLE_PKG_CONFIG)
 570     if(CMAKE_CROSSCOMPILING AND NOT DEFINED ENV{PKG_CONFIG_LIBDIR}
 571         AND NOT OPENCV_ENABLE_PKG_CONFIG
 572     )
 573       if(NOT PkgConfig_FOUND)
 574         message(STATUS "OpenCV disables pkg-config to avoid using of host libraries. Consider using PKG_CONFIG_LIBDIR to specify target SYSROOT")
 575       elseif(OPENCV_SKIP_PKG_CONFIG_WARNING)
 576         message(WARNING "pkg-config is enabled in cross-compilation mode without defining of PKG_CONFIG_LIBDIR environment variable. This may lead to misconfigured host-based dependencies.")
 577       endif()
 578     elseif(OPENCV_DISABLE_PKG_CONFIG)
 579       if(PkgConfig_FOUND)
 580         message(WARNING "OPENCV_DISABLE_PKG_CONFIG flag has no effect")
 581       endif()
 582     else()
 583       find_package(PkgConfig QUIET)
 584     endif()
 585   endif()
 586   include(CheckFunctionExists)
 587   include(CheckIncludeFile)
 588   include(CheckSymbolExists)
 589
 590   if(NOT APPLE)
 591     CHECK_INCLUDE_FILE(pthread.h HAVE_PTHREAD)
 592     if(ANDROID)
 593       set(OPENCV_LINKER_LIBS ${OPENCV_LINKER_LIBS} dl m log)
 594     elseif(${CMAKE_SYSTEM_NAME} MATCHES "FreeBSD|NetBSD|DragonFly|OpenBSD|Haiku")
 595       set(OPENCV_LINKER_LIBS ${OPENCV_LINKER_LIBS} m pthread)
 596     elseif(EMSCRIPTEN)
 597       # no need to link to system libs with emscripten
 598     else()
 599       set(OPENCV_LINKER_LIBS ${OPENCV_LINKER_LIBS} dl m pthread rt)
 600     endif()
 601   else()
 602     set(HAVE_PTHREAD 1)
 603   endif()
 604
 605   CHECK_SYMBOL_EXISTS(posix_memalign stdlib.h HAVE_POSIX_MEMALIGN)
 606   CHECK_INCLUDE_FILE(malloc.h HAVE_MALLOC_H)
 607   if(HAVE_MALLOC_H)
 608     CHECK_SYMBOL_EXISTS(memalign malloc.h HAVE_MEMALIGN)
 609   endif()
 610 endif()
 611
 612 include(cmake/OpenCVPCHSupport.cmake)
 613 include(cmake/OpenCVModule.cmake)
 614
 615 # ----------------------------------------------------------------------------
 616 #  Detect endianness of build platform
 617 # ----------------------------------------------------------------------------
 618
 619 if(IOS)
 620   # test_big_endian needs try_compile, which doesn't work for iOS
 621   # http://public.kitware.com/Bug/view.php?id=12288
 622   set(WORDS_BIGENDIAN 0)
 623 else()
 624   include(TestBigEndian)
 625   test_big_endian(WORDS_BIGENDIAN)
 626 endif()
 627
 628 # ----------------------------------------------------------------------------
 629 #  Detect 3rd-party libraries
 630 # ----------------------------------------------------------------------------
 631
 632 if(ANDROID AND WITH_CPUFEATURES)
 633   add_subdirectory(3rdparty/cpufeatures)
 634   set(HAVE_CPUFEATURES 1)
 635 endif()
 636
 637 include(cmake/OpenCVFindLibsGrfmt.cmake)
 638 include(cmake/OpenCVFindLibsGUI.cmake)
 639 include(cmake/OpenCVFindLibsVideo.cmake)
 640 include(cmake/OpenCVFindLibsPerf.cmake)
 641 include(cmake/OpenCVFindLAPACK.cmake)
 642 include(cmake/OpenCVFindProtobuf.cmake)
 643
 644 # ----------------------------------------------------------------------------
 645 #  Detect other 3rd-party libraries/tools
 646 # ----------------------------------------------------------------------------
 647
 648 # --- Java Support ---
 649 if(BUILD_JAVA)
 650   if(ANDROID)
 651     include(cmake/android/OpenCVDetectAndroidSDK.cmake)
 652   else()
 653     include(cmake/OpenCVDetectApacheAnt.cmake)
 654     find_package(JNI)
 655   endif()
 656 endif()
 657
 658 if(ENABLE_PYLINT AND PYTHON_DEFAULT_AVAILABLE)
 659   include(cmake/OpenCVPylint.cmake)
 660 endif()
 661 if(ENABLE_FLAKE8 AND PYTHON_DEFAULT_AVAILABLE)
 662   find_package(Flake8 QUIET)
 663   if(NOT FLAKE8_FOUND OR NOT FLAKE8_EXECUTABLE)
 664     include("${CMAKE_CURRENT_LIST_DIR}/cmake/FindFlake8.cmake")
 665   endif()
 666   if(FLAKE8_FOUND)
 667     add_custom_target(check_flake8
 668         COMMAND "${FLAKE8_EXECUTABLE}" . --count --select=E9,E901,E999,F821,F822,F823 --show-source --statistics --exclude='.git,__pycache__,*.config.py,svgfig.py'
 669         WORKING_DIRECTORY "${OpenCV_SOURCE_DIR}"
 670         COMMENT "Running flake8"
 671     )
 672   endif()
 673 endif()
 674
 675
 676 if(ANDROID AND ANDROID_EXECUTABLE AND ANT_EXECUTABLE AND (ANT_VERSION VERSION_GREATER 1.7) AND (ANDROID_TOOLS_Pkg_Revision GREATER 13))
 677   SET(CAN_BUILD_ANDROID_PROJECTS TRUE)
 678 else()
 679   SET(CAN_BUILD_ANDROID_PROJECTS FALSE)
 680 endif()
 681
 682 # --- OpenCL ---
 683 if(WITH_OPENCL)
 684   include(cmake/OpenCVDetectOpenCL.cmake)
 685 endif()
 686
 687 # --- Halide ---
 688 if(WITH_HALIDE)
 689   include(cmake/OpenCVDetectHalide.cmake)
 690 endif()
 691
 692 # --- Inference Engine ---
 693 if(WITH_INF_ENGINE)
 694   include(cmake/OpenCVDetectInferenceEngine.cmake)
 695 endif()
 696
 697 # --- DirectX ---
 698 if(WITH_DIRECTX)
 699   include(cmake/OpenCVDetectDirectX.cmake)
 700 endif()
 701
 702 if(WITH_VTK)
 703   include(cmake/OpenCVDetectVTK.cmake)
 704 endif()
 705
 706 if(WITH_OPENVX)
 707   include(cmake/FindOpenVX.cmake)
 708 endif()
 709
 710 if(WITH_QUIRC)
 711   add_subdirectory(3rdparty/quirc)
 712   set(HAVE_QUIRC TRUE)
 713 endif()
 714 # ----------------------------------------------------------------------------
 715 # OpenCV HAL
 716 # ----------------------------------------------------------------------------
 717 set(_hal_includes "")
 718 macro(ocv_hal_register HAL_LIBRARIES_VAR HAL_HEADERS_VAR HAL_INCLUDE_DIRS_VAR)
 719   # 1. libraries
 720   foreach (l ${${HAL_LIBRARIES_VAR}})
 721     if(NOT TARGET ${l})
 722       get_filename_component(l "${l}" ABSOLUTE)
 723     endif()
 724     list(APPEND OPENCV_HAL_LINKER_LIBS ${l})
 725   endforeach()
 726   # 2. headers
 727   foreach (h ${${HAL_HEADERS_VAR}})
 728     set(_hal_includes "${_hal_includes}\n#include \"${h}\"")
 729   endforeach()
 730   # 3. include paths
 731   ocv_include_directories(${${HAL_INCLUDE_DIRS_VAR}})
 732 endmacro()
 733
 734 if(NOT DEFINED OpenCV_HAL)
 735   set(OpenCV_HAL "OpenCV_HAL")
 736 endif()
 737
 738 if(HAVE_OPENVX)
 739   if(NOT ";${OpenCV_HAL};" MATCHES ";openvx;")
 740     set(OpenCV_HAL "openvx;${OpenCV_HAL}")
 741   endif()
 742 endif()
 743
 744 if(WITH_CAROTENE)
 745   ocv_debug_message(STATUS "Enable carotene acceleration")
 746   if(NOT ";${OpenCV_HAL};" MATCHES ";carotene;")
 747     set(OpenCV_HAL "carotene;${OpenCV_HAL}")
 748   endif()
 749 endif()
 750
 751 foreach(hal ${OpenCV_HAL})
 752   if(hal STREQUAL "carotene")
 753     add_subdirectory(3rdparty/carotene/hal)
 754     ocv_hal_register(CAROTENE_HAL_LIBRARIES CAROTENE_HAL_HEADERS CAROTENE_HAL_INCLUDE_DIRS)
 755     list(APPEND OpenCV_USED_HAL "carotene (ver ${CAROTENE_HAL_VERSION})")
 756   elseif(hal STREQUAL "openvx")
 757     add_subdirectory(3rdparty/openvx)
 758     ocv_hal_register(OPENVX_HAL_LIBRARIES OPENVX_HAL_HEADERS OPENVX_HAL_INCLUDE_DIRS)
 759     list(APPEND OpenCV_USED_HAL "openvx (ver ${OPENVX_HAL_VERSION})")
 760   else()
 761     ocv_debug_message(STATUS "OpenCV HAL: ${hal} ...")
 762     ocv_clear_vars(OpenCV_HAL_LIBRARIES OpenCV_HAL_HEADERS OpenCV_HAL_INCLUDE_DIRS)
 763     find_package(${hal} NO_MODULE QUIET)
 764     if(${hal}_FOUND)
 765       ocv_hal_register(OpenCV_HAL_LIBRARIES OpenCV_HAL_HEADERS OpenCV_HAL_INCLUDE_DIRS)
 766       list(APPEND OpenCV_USED_HAL "${hal} (ver ${${hal}_VERSION})")
 767     endif()
 768   endif()
 769 endforeach()
 770 configure_file("${OpenCV_SOURCE_DIR}/cmake/templates/custom_hal.hpp.in" "${CMAKE_BINARY_DIR}/custom_hal.hpp" @ONLY)
 771 unset(_hal_includes)
 772
 773
 774 # ----------------------------------------------------------------------------
 775 # Add CUDA libraries (needed for apps/tools, samples)
 776 # ----------------------------------------------------------------------------
 777 if(HAVE_CUDA)
 778   set(OPENCV_LINKER_LIBS ${OPENCV_LINKER_LIBS} ${CUDA_LIBRARIES} ${CUDA_npp_LIBRARY})
 779   if(HAVE_CUBLAS)
 780     set(OPENCV_LINKER_LIBS ${OPENCV_LINKER_LIBS} ${CUDA_cublas_LIBRARY})
 781   endif()
 782   if(HAVE_CUFFT)
 783     set(OPENCV_LINKER_LIBS ${OPENCV_LINKER_LIBS} ${CUDA_cufft_LIBRARY})
 784   endif()
 785   foreach(p ${CUDA_LIBS_PATH})
 786     if(MSVC AND CMAKE_GENERATOR MATCHES "Ninja|JOM")
 787       set(OPENCV_LINKER_LIBS ${OPENCV_LINKER_LIBS} ${CMAKE_LIBRARY_PATH_FLAG}"${p}")
 788     else()
 789       set(OPENCV_LINKER_LIBS ${OPENCV_LINKER_LIBS} ${CMAKE_LIBRARY_PATH_FLAG}${p})
 790     endif()
 791   endforeach()
 792 endif()
 793
 794
 795 # ----------------------------------------------------------------------------
 796 # Code trace support
 797 # ----------------------------------------------------------------------------
 798 if(CV_TRACE)
 799   include(cmake/OpenCVDetectTrace.cmake)
 800 endif()
 801
 802 ocv_cmake_hook(POST_DETECT_DEPENDECIES)
 803
 804 # ----------------------------------------------------------------------------
 805 # Solution folders:
 806 # ----------------------------------------------------------------------------
 807 if(ENABLE_SOLUTION_FOLDERS)
 808   set_property(GLOBAL PROPERTY USE_FOLDERS ON)
 809   set_property(GLOBAL PROPERTY PREDEFINED_TARGETS_FOLDER "CMakeTargets")
 810 endif()
 811
 812 # Extra OpenCV targets: uninstall, package_source, perf, etc.
 813 include(cmake/OpenCVExtraTargets.cmake)
 814
 815 # ----------------------------------------------------------------------------
 816 # Process subdirectories
 817 # ----------------------------------------------------------------------------
 818
 819 # opencv.hpp and legacy headers
 820 add_subdirectory(include)
 821
 822 # Enable compiler options for OpenCV modules/apps/samples only (ignore 3rdparty)
 823 ocv_add_modules_compiler_options()
 824
 825 # OpenCV modules
 826 add_subdirectory(modules)
 827
 828 # Generate targets for documentation
 829 add_subdirectory(doc)
 830
 831 # various data that is used by cv libraries and/or demo applications.
 832 add_subdirectory(data)
 833
 834 # extra applications
 835 if(BUILD_opencv_apps)
 836   add_subdirectory(apps)
 837 endif()
 838
 839 # examples
 840 if(BUILD_EXAMPLES OR BUILD_ANDROID_EXAMPLES OR INSTALL_PYTHON_EXAMPLES OR INSTALL_C_EXAMPLES)
 841   add_subdirectory(samples)
 842 endif()
 843
 844 if(ANDROID)
 845   add_subdirectory(platforms/android/service)
 846 endif()
 847
 848 # ----------------------------------------------------------------------------
 849 # Finalization: generate configuration-based files
 850 # ----------------------------------------------------------------------------
 851
 852 ocv_cmake_hook(PRE_FINALIZE)
 853
 854 # Generate platform-dependent and configuration-dependent headers
 855 include(cmake/OpenCVGenHeaders.cmake)
 856
 857 # Generate opencv.pc for pkg-config command
 858 if(NOT OPENCV_SKIP_PKGCONFIG_GENERATION
 859     AND NOT CMAKE_GENERATOR MATCHES "Xcode")
 860   include(cmake/OpenCVGenPkgconfig.cmake)
 861 endif()
 862
 863 # Generate OpenCV.mk for ndk-build (Android build tool)
 864 include(cmake/OpenCVGenAndroidMK.cmake)
 865
 866 # Generate OpenCVConfig.cmake and OpenCVConfig-version.cmake for cmake projects
 867 include(cmake/OpenCVGenConfig.cmake)
 868
 869 # Generate Info.plist for the IOS framework
 870 if(APPLE_FRAMEWORK)
 871   include(cmake/OpenCVGenInfoPlist.cmake)
 872 endif()
 873
 874 # Generate ABI descriptor
 875 include(cmake/OpenCVGenABI.cmake)
 876
 877 # Generate environment setup file
 878 if(INSTALL_TESTS AND OPENCV_TEST_DATA_PATH)
 879   if(ANDROID)
 880     get_filename_component(TEST_PATH ${OPENCV_TEST_INSTALL_PATH} DIRECTORY)
 881     configure_file("${CMAKE_CURRENT_SOURCE_DIR}/cmake/templates/opencv_run_all_tests_android.sh.in"
 882                    "${CMAKE_BINARY_DIR}/unix-install/opencv_run_all_tests.sh" @ONLY)
 883     install(PROGRAMS "${CMAKE_BINARY_DIR}/unix-install/opencv_run_all_tests.sh"
 884             DESTINATION ./ COMPONENT tests)
 885   elseif(WIN32)
 886     configure_file("${CMAKE_CURRENT_SOURCE_DIR}/cmake/templates/opencv_run_all_tests_windows.cmd.in"
 887                    "${CMAKE_BINARY_DIR}/win-install/opencv_run_all_tests.cmd" @ONLY)
 888     install(PROGRAMS "${CMAKE_BINARY_DIR}/win-install/opencv_run_all_tests.cmd"
 889             DESTINATION ${OPENCV_TEST_INSTALL_PATH} COMPONENT tests)
 890   elseif(UNIX)
 891     configure_file("${CMAKE_CURRENT_SOURCE_DIR}/cmake/templates/opencv_run_all_tests_unix.sh.in"
 892                    "${CMAKE_BINARY_DIR}/unix-install/opencv_run_all_tests.sh" @ONLY)
 893     install(PROGRAMS "${CMAKE_BINARY_DIR}/unix-install/opencv_run_all_tests.sh"
 894             DESTINATION ${OPENCV_TEST_INSTALL_PATH} COMPONENT tests)
 895   endif()
 896 endif()
 897
 898 if(NOT OPENCV_README_FILE)
 899   if(ANDROID)
 900     set(OPENCV_README_FILE ${CMAKE_CURRENT_SOURCE_DIR}/platforms/android/README.android)
 901   endif()
 902 endif()
 903
 904 if(NOT OPENCV_LICENSE_FILE)
 905   set(OPENCV_LICENSE_FILE ${CMAKE_CURRENT_SOURCE_DIR}/LICENSE)
 906 endif()
 907
 908 # for UNIX it does not make sense as LICENSE and readme will be part of the package automatically
 909 if(ANDROID OR NOT UNIX)
 910   install(FILES ${OPENCV_LICENSE_FILE}
 911         PERMISSIONS OWNER_READ GROUP_READ WORLD_READ
 912         DESTINATION ./ COMPONENT libs)
 913   if(OPENCV_README_FILE)
 914     install(FILES ${OPENCV_README_FILE}
 915             PERMISSIONS OWNER_READ GROUP_READ WORLD_READ
 916             DESTINATION ./ COMPONENT libs)
 917   endif()
 918 endif()
 919
 920 if(COMMAND ocv_pylint_finalize)
 921   ocv_pylint_add_directory(${CMAKE_CURRENT_LIST_DIR}/modules/python/test)
 922   ocv_pylint_add_directory(${CMAKE_CURRENT_LIST_DIR}/samples/python)
 923   ocv_pylint_add_directory(${CMAKE_CURRENT_LIST_DIR}/samples/dnn)
 924   ocv_pylint_add_directory_recurse(${CMAKE_CURRENT_LIST_DIR}/samples/python/tutorial_code)
 925   ocv_pylint_finalize()
 926 endif()
 927
 928 # ----------------------------------------------------------------------------
 929 # Summary:
 930 # ----------------------------------------------------------------------------
 931 status("")
 932 status("General configuration for OpenCV ${OPENCV_VERSION} =====================================")
 933 if(OPENCV_VCSVERSION)
 934   status("  Version control:" ${OPENCV_VCSVERSION})
 935 endif()
 936 if(OPENCV_EXTRA_MODULES_PATH AND NOT BUILD_INFO_SKIP_EXTRA_MODULES)
 937   set(__dump_extra_header OFF)
 938   foreach(p ${OPENCV_EXTRA_MODULES_PATH})
 939     if(EXISTS ${p})
 940       if(NOT __dump_extra_header)
 941         set(__dump_extra_header ON)
 942         status("")
 943         status("  Extra modules:")
 944       else()
 945         status("")
 946       endif()
 947       ocv_git_describe(EXTRA_MODULES_VCSVERSION "${p}")
 948       status("    Location (extra):" ${p})
 949       status("    Version control (extra):" ${EXTRA_MODULES_VCSVERSION})
 950     endif()
 951   endforeach()
 952   unset(__dump_extra_header)
 953 endif()
 954
 955 # ========================== build platform ==========================
 956 status("")
 957 status("  Platform:")
 958 if(NOT DEFINED OPENCV_TIMESTAMP
 959     AND NOT CMAKE_VERSION VERSION_LESS 2.8.11
 960     AND NOT BUILD_INFO_SKIP_TIMESTAMP
 961 )
 962   string(TIMESTAMP OPENCV_TIMESTAMP "" UTC)
 963   set(OPENCV_TIMESTAMP "${OPENCV_TIMESTAMP}" CACHE STRING "Timestamp of OpenCV build configuration" FORCE)
 964 endif()
 965 if(OPENCV_TIMESTAMP)
 966   status("    Timestamp:"      ${OPENCV_TIMESTAMP})
 967 endif()
 968 status("    Host:"             ${CMAKE_HOST_SYSTEM_NAME} ${CMAKE_HOST_SYSTEM_VERSION} ${CMAKE_HOST_SYSTEM_PROCESSOR})
 969 if(CMAKE_CROSSCOMPILING)
 970   status("    Target:"         ${CMAKE_SYSTEM_NAME} ${CMAKE_SYSTEM_VERSION} ${CMAKE_SYSTEM_PROCESSOR})
 971 endif()
 972 status("    CMake:"            ${CMAKE_VERSION})
 973 status("    CMake generator:"  ${CMAKE_GENERATOR})
 974 status("    CMake build tool:" ${CMAKE_BUILD_TOOL})
 975 if(MSVC)
 976   status("    MSVC:"           ${MSVC_VERSION})
 977 endif()
 978 if(CMAKE_GENERATOR MATCHES Xcode)
 979   status("    Xcode:"          ${XCODE_VERSION})
 980 endif()
 981 if(NOT CMAKE_GENERATOR MATCHES "Xcode|Visual Studio")
 982   status("    Configuration:"  ${CMAKE_BUILD_TYPE})
 983 endif()
 984
 985
 986 # ========================= CPU code generation mode =========================
 987 status("")
 988 status("  CPU/HW features:")
 989 status("    Baseline:"  "${CPU_BASELINE_FINAL}")
 990 if(NOT CPU_BASELINE STREQUAL CPU_BASELINE_FINAL)
 991   status("      requested:"  "${CPU_BASELINE}")
 992 endif()
 993 if(CPU_BASELINE_REQUIRE)
 994   status("      required:"  "${CPU_BASELINE_REQUIRE}")
 995 endif()
 996 if(CPU_BASELINE_DISABLE)
 997   status("      disabled:"  "${CPU_BASELINE_DISABLE}")
 998 endif()
 999 if(CPU_DISPATCH_FINAL OR CPU_DISPATCH)
1000   status("    Dispatched code generation:"  "${CPU_DISPATCH_FINAL}")
1001   if(NOT CPU_DISPATCH STREQUAL CPU_DISPATCH_FINAL)
1002     status("      requested:"  "${CPU_DISPATCH}")
1003   endif()
1004   if(CPU_DISPATCH_REQUIRE)
1005     status("      required:"  "${CPU_DISPATCH_REQUIRE}")
1006   endif()
1007   foreach(OPT ${CPU_DISPATCH_FINAL})
1008     status("      ${OPT} (${CPU_${OPT}_USAGE_COUNT} files):"  "+ ${CPU_DISPATCH_${OPT}_INCLUDED}")
1009   endforeach()
1010 endif()
1011
1012 # ========================== C/C++ options ==========================
1013 if(CMAKE_CXX_COMPILER_VERSION)
1014   set(OPENCV_COMPILER_STR "${CMAKE_CXX_COMPILER} ${CMAKE_CXX_COMPILER_ARG1} (ver ${CMAKE_CXX_COMPILER_VERSION})")
1015 else()
1016   set(OPENCV_COMPILER_STR "${CMAKE_CXX_COMPILER} ${CMAKE_CXX_COMPILER_ARG1}")
1017 endif()
1018 string(STRIP "${OPENCV_COMPILER_STR}" OPENCV_COMPILER_STR)
1019
1020 status("")
1021 status("  C/C++:")
1022 status("    Built as dynamic libs?:" BUILD_SHARED_LIBS THEN YES ELSE NO)
1023 if(ENABLE_CXX11 OR HAVE_CXX11)
1024 status("    C++11:" HAVE_CXX11 THEN YES ELSE NO)
1025 endif()
1026 status("    C++ Compiler:"           ${OPENCV_COMPILER_STR})
1027 status("    C++ flags (Release):"    ${CMAKE_CXX_FLAGS} ${CMAKE_CXX_FLAGS_RELEASE})
1028 status("    C++ flags (Debug):"      ${CMAKE_CXX_FLAGS} ${CMAKE_CXX_FLAGS_DEBUG})
1029 status("    C Compiler:"             ${CMAKE_C_COMPILER} ${CMAKE_C_COMPILER_ARG1})
1030 status("    C flags (Release):"      ${CMAKE_C_FLAGS} ${CMAKE_C_FLAGS_RELEASE})
1031 status("    C flags (Debug):"        ${CMAKE_C_FLAGS} ${CMAKE_C_FLAGS_DEBUG})
1032 if(WIN32)
1033   status("    Linker flags (Release):" ${CMAKE_EXE_LINKER_FLAGS} ${CMAKE_EXE_LINKER_FLAGS_RELEASE})
1034   status("    Linker flags (Debug):"   ${CMAKE_EXE_LINKER_FLAGS} ${CMAKE_EXE_LINKER_FLAGS_DEBUG})
1035 else()
1036   status("    Linker flags (Release):" ${CMAKE_SHARED_LINKER_FLAGS} ${CMAKE_SHARED_LINKER_FLAGS_RELEASE})
1037   status("    Linker flags (Debug):"   ${CMAKE_SHARED_LINKER_FLAGS} ${CMAKE_SHARED_LINKER_FLAGS_DEBUG})
1038 endif()
1039 status("    ccache:"                  OPENCV_COMPILER_IS_CCACHE THEN YES ELSE NO)
1040 status("    Precompiled headers:"     PCHSupport_FOUND AND ENABLE_PRECOMPILED_HEADERS THEN YES ELSE NO)
1041
1042 # ========================== Dependencies ============================
1043 ocv_get_all_libs(deps_modules deps_extra deps_3rdparty)
1044 status("    Extra dependencies:" ${deps_extra})
1045 status("    3rdparty dependencies:" ${deps_3rdparty})
1046
1047 # ========================== OpenCV modules ==========================
1048 status("")
1049 status("  OpenCV modules:")
1050 string(REPLACE "opencv_" "" OPENCV_MODULES_BUILD_ST          "${OPENCV_MODULES_BUILD}")
1051 string(REPLACE "opencv_" "" OPENCV_MODULES_DISABLED_USER_ST  "${OPENCV_MODULES_DISABLED_USER}")
1052 string(REPLACE "opencv_" "" OPENCV_MODULES_DISABLED_AUTO_ST  "${OPENCV_MODULES_DISABLED_AUTO}")
1053 string(REPLACE "opencv_" "" OPENCV_MODULES_DISABLED_FORCE_ST "${OPENCV_MODULES_DISABLED_FORCE}")
1054 list(SORT OPENCV_MODULES_BUILD_ST)
1055 list(SORT OPENCV_MODULES_DISABLED_USER_ST)
1056 list(SORT OPENCV_MODULES_DISABLED_AUTO_ST)
1057 list(SORT OPENCV_MODULES_DISABLED_FORCE_ST)
1058 status("    To be built:"            OPENCV_MODULES_BUILD          THEN ${OPENCV_MODULES_BUILD_ST}          ELSE "-")
1059 status("    Disabled:"               OPENCV_MODULES_DISABLED_USER  THEN ${OPENCV_MODULES_DISABLED_USER_ST}  ELSE "-")
1060 status("    Disabled by dependency:" OPENCV_MODULES_DISABLED_AUTO  THEN ${OPENCV_MODULES_DISABLED_AUTO_ST}  ELSE "-")
1061 status("    Unavailable:"            OPENCV_MODULES_DISABLED_FORCE THEN ${OPENCV_MODULES_DISABLED_FORCE_ST} ELSE "-")
1062
1063 ocv_build_features_string(apps_status
1064   IF BUILD_TESTS AND HAVE_opencv_ts THEN "tests"
1065   IF BUILD_PERF_TESTS AND HAVE_opencv_ts THEN "perf_tests"
1066   IF BUILD_EXAMPLES THEN "examples"
1067   IF BUILD_opencv_apps THEN "apps"
1068   IF BUILD_ANDROID_SERVICE THEN "android_service"
1069   IF BUILD_ANDROID_EXAMPLES AND CAN_BUILD_ANDROID_PROJECTS THEN "android_examples"
1070   ELSE "-")
1071 status("    Applications:" "${apps_status}")
1072 ocv_build_features_string(docs_status
1073     IF TARGET doxygen_cpp THEN "doxygen"
1074     IF TARGET doxygen_python THEN "python"
1075     IF TARGET doxygen_javadoc THEN "javadoc"
1076     IF BUILD_opencv_js OR DEFINED OPENCV_JS_LOCATION THEN "js"
1077     ELSE "NO"
1078 )
1079 status("    Documentation:" "${docs_status}")
1080 status("    Non-free algorithms:" OPENCV_ENABLE_NONFREE THEN "YES" ELSE "NO")
1081
1082 # ========================== Android details ==========================
1083 if(ANDROID)
1084   status("")
1085   if(DEFINED ANDROID_NDK_REVISION)
1086     set(__msg "${ANDROID_NDK} (ver ${ANDROID_NDK_REVISION})")
1087   else()
1088     set(__msg "location: ${ANDROID_NDK}")
1089   endif()
1090   status("  Android NDK: " ${__msg})
1091   status("    Android ABI:" ${ANDROID_ABI})
1092   if(BUILD_WITH_STANDALONE_TOOLCHAIN)
1093     status("    NDK toolchain:" "standalone: ${ANDROID_STANDALONE_TOOLCHAIN}")
1094   elseif(BUILD_WITH_ANDROID_NDK OR DEFINED ANDROID_TOOLCHAIN_NAME)
1095     status("    NDK toolchain:" "${ANDROID_TOOLCHAIN_NAME}")
1096   endif()
1097   status("    STL type:" ${ANDROID_STL})
1098   status("    Native API level:" ${ANDROID_NATIVE_API_LEVEL})
1099
1100   if(BUILD_ANDROID_PROJECTS)
1101     status("  Android SDK: " "${ANDROID_SDK} (tools: ${ANDROID_SDK_TOOLS_VERSION} build tools: ${ANDROID_SDK_BUILD_TOOLS_VERSION})")
1102     if(ANDROID_EXECUTABLE)
1103       status("    android tool:"  "${ANDROID_EXECUTABLE}")
1104     endif()
1105   else()
1106     status("  Android SDK: " "not used, projects are not built")
1107   endif()
1108   if(DEFINED ANDROID_SDK_COMPATIBLE_TARGET)
1109     status("    SDK target:" "${ANDROID_SDK_COMPATIBLE_TARGET}")
1110   endif()
1111   if(DEFINED ANDROID_PROJECTS_BUILD_TYPE)
1112     if(ANDROID_PROJECTS_BUILD_TYPE STREQUAL "ANT")
1113       status("    Projects build scripts:" "Ant/Eclipse compatible")
1114     elseif(ANDROID_PROJECTS_BUILD_TYPE STREQUAL "ANT")
1115       status("    Projects build scripts:" "Gradle")
1116     endif()
1117   endif()
1118 endif()
1119
1120 # ================== Windows RT features ==================
1121 if(WIN32)
1122 status("")
1123 status("  Windows RT support:" WINRT THEN YES ELSE NO)
1124   if(WINRT)
1125     status("    Building for Microsoft platform: " ${CMAKE_SYSTEM_NAME})
1126     status("    Building for architectures: " ${CMAKE_VS_EFFECTIVE_PLATFORMS})
1127     status("    Building for version: " ${CMAKE_SYSTEM_VERSION})
1128     if (DEFINED ENABLE_WINRT_MODE_NATIVE)
1129       status("    Building for C++ without CX extensions")
1130     endif()
1131   endif()
1132 endif(WIN32)
1133
1134 # ========================== GUI ==========================
1135 status("")
1136 status("  GUI: ")
1137
1138 if(WITH_QT OR HAVE_QT)
1139   if(HAVE_QT5)
1140     status("    QT:" "YES (ver ${Qt5Core_VERSION_STRING})")
1141     status("      QT OpenGL support:" HAVE_QT_OPENGL THEN "YES (${Qt5OpenGL_LIBRARIES} ${Qt5OpenGL_VERSION_STRING})" ELSE NO)
1142   elseif(HAVE_QT)
1143     status("    QT:" "YES (ver ${QT_VERSION_MAJOR}.${QT_VERSION_MINOR}.${QT_VERSION_PATCH} ${QT_EDITION})")
1144     status("      QT OpenGL support:" HAVE_QT_OPENGL THEN "YES (${QT_QTOPENGL_LIBRARY})" ELSE NO)
1145   else()
1146     status("    QT:" "NO")
1147   endif()
1148 endif()
1149
1150 if(WITH_WIN32UI)
1151   status("    Win32 UI:" HAVE_WIN32UI THEN YES ELSE NO)
1152 endif()
1153
1154 if(APPLE)
1155   if(WITH_CARBON)
1156     status("    Carbon:" YES)
1157   else()
1158     status("    Cocoa:"  YES)
1159   endif()
1160 endif()
1161
1162 if(WITH_GTK OR HAVE_GTK)
1163   if(HAVE_GTK3)
1164     status("    GTK+:" "YES (ver ${ALIASOF_gtk+-3.0_VERSION})")
1165   elseif(HAVE_GTK)
1166     status("    GTK+:" "YES (ver ${ALIASOF_gtk+-2.0_VERSION})")
1167   else()
1168     status("    GTK+:" "NO")
1169   endif()
1170   if(HAVE_GTK)
1171     status(  "      GThread :" HAVE_GTHREAD THEN "YES (ver ${ALIASOF_gthread-2.0_VERSION})" ELSE NO)
1172     status(  "      GtkGlExt:" HAVE_GTKGLEXT THEN "YES (ver ${ALIASOF_gtkglext-1.0_VERSION})" ELSE NO)
1173   endif()
1174 endif()
1175
1176 if(WITH_OPENGL OR HAVE_OPENGL)
1177   status("    OpenGL support:" HAVE_OPENGL THEN "YES (${OPENGL_LIBRARIES})" ELSE NO)
1178 endif()
1179
1180 if(WITH_VTK OR HAVE_VTK)
1181   status("    VTK support:" HAVE_VTK THEN "YES (ver ${VTK_VERSION})" ELSE NO)
1182 endif()
1183
1184 # ========================== MEDIA IO ==========================
1185 status("")
1186 status("  Media I/O: ")
1187 status("    ZLib:"   ZLIB_FOUND THEN "${ZLIB_LIBRARIES} (ver ${ZLIB_VERSION_STRING})" ELSE "build (ver ${ZLIB_VERSION_STRING})")
1188
1189 if(WITH_JPEG OR HAVE_JPEG)
1190   if(NOT HAVE_JPEG)
1191     status("    JPEG:" NO)
1192   elseif(BUILD_JPEG)
1193     status("    JPEG:" "build-${JPEG_LIBRARY} (ver ${JPEG_LIB_VERSION})")
1194   else()
1195     status("    JPEG:" "${JPEG_LIBRARY} (ver ${JPEG_LIB_VERSION})")
1196   endif()
1197 endif()
1198
1199 if(WITH_WEBP OR HAVE_WEBP)
1200   status("    WEBP:" WEBP_FOUND THEN "${WEBP_LIBRARY} (ver ${WEBP_VERSION})" ELSE "build (ver ${WEBP_VERSION})")
1201 endif()
1202
1203 if(WITH_PNG OR HAVE_PNG)
1204   status("    PNG:"  PNG_FOUND  THEN "${PNG_LIBRARY} (ver ${PNG_VERSION})" ELSE "build (ver ${PNG_VERSION})")
1205 endif()
1206
1207 if(WITH_TIFF OR HAVE_TIFF)
1208   status("    TIFF:" TIFF_FOUND THEN "${TIFF_LIBRARY} (ver ${TIFF_VERSION} / ${TIFF_VERSION_STRING})" ELSE "build (ver ${TIFF_VERSION} - ${TIFF_VERSION_STRING})")
1209 endif()
1210
1211 if(WITH_JASPER OR HAVE_JASPER)
1212   status("    JPEG 2000:" JASPER_FOUND THEN "${JASPER_LIBRARY} (ver ${JASPER_VERSION_STRING})" ELSE "build (ver ${JASPER_VERSION_STRING})")
1213 endif()
1214
1215 if(WITH_OPENEXR OR HAVE_OPENEXR)
1216   status("    OpenEXR:" OPENEXR_FOUND THEN "${OPENEXR_LIBRARIES} (ver ${OPENEXR_VERSION})" ELSE "build (ver ${OPENEXR_VERSION})")
1217 endif()
1218
1219 if(WITH_GDAL OR HAVE_GDAL)
1220   status("    GDAL:" HAVE_GDAL THEN "YES (${GDAL_LIBRARY})" ELSE "NO")
1221 endif()
1222
1223 if(WITH_GDCM OR HAVE_GDCM)
1224   status("    GDCM:" HAVE_GDCM THEN "YES (ver ${GDCM_VERSION})" ELSE "NO")
1225 endif()
1226
1227 if(WITH_IMGCODEC_HDR OR DEFINED HAVE_IMGCODEC_HDR)
1228   status("    HDR:" HAVE_IMGCODEC_HDR THEN "YES" ELSE "NO")
1229 endif()
1230
1231 if(WITH_IMGCODEC_SUNRASTER OR DEFINED HAVE_IMGCODEC_SUNRASTER)
1232   status("    SUNRASTER:" HAVE_IMGCODEC_SUNRASTER THEN "YES" ELSE "NO")
1233 endif()
1234
1235 if(WITH_IMGCODEC_PXM OR DEFINED HAVE_IMGCODEC_PXM)
1236   status("    PXM:" HAVE_IMGCODEC_PXM THEN "YES" ELSE "NO")
1237 endif()
1238
1239 # ========================== VIDEO IO ==========================
1240 status("")
1241 status("  Video I/O:")
1242
1243 if(WITH_VFW OR HAVE_VFW)
1244   status("    Video for Windows:" HAVE_VFW         THEN YES                                        ELSE NO)
1245 endif()
1246
1247 if(WITH_1394 OR HAVE_DC1394)
1248   if (HAVE_DC1394_2)
1249     status("    DC1394:" "YES (ver ${ALIASOF_libdc1394-2_VERSION})")
1250   elseif (HAVE_DC1394)
1251     status("    DC1394:" "YES (ver ${ALIASOF_libdc1394_VERSION})")
1252   else()
1253     status("    DC1394:" "NO")
1254   endif()
1255 endif()
1256
1257 if(WITH_FFMPEG OR HAVE_FFMPEG)
1258   if(OPENCV_FFMPEG_USE_FIND_PACKAGE)
1259     status("    FFMPEG:"       HAVE_FFMPEG         THEN "YES (find_package)"                       ELSE "NO (find_package)")
1260   elseif(WIN32)
1261     status("    FFMPEG:"       HAVE_FFMPEG         THEN "YES (prebuilt binaries)"                  ELSE NO)
1262   else()
1263     status("    FFMPEG:"       HAVE_FFMPEG         THEN YES ELSE NO)
1264   endif()
1265   status("      avcodec:"      FFMPEG_libavcodec_FOUND    THEN "YES (ver ${FFMPEG_libavcodec_VERSION})"    ELSE NO)
1266   status("      avformat:"     FFMPEG_libavformat_FOUND   THEN "YES (ver ${FFMPEG_libavformat_VERSION})"   ELSE NO)
1267   status("      avutil:"       FFMPEG_libavutil_FOUND     THEN "YES (ver ${FFMPEG_libavutil_VERSION})"     ELSE NO)
1268   status("      swscale:"      FFMPEG_libswscale_FOUND    THEN "YES (ver ${FFMPEG_libswscale_VERSION})"    ELSE NO)
1269   status("      avresample:"   FFMPEG_libavresample_FOUND THEN "YES (ver ${FFMPEG_libavresample_VERSION})" ELSE NO)
1270 endif()
1271
1272 if(WITH_GSTREAMER OR HAVE_GSTREAMER)
1273   status("    GStreamer:"      HAVE_GSTREAMER      THEN ""                                         ELSE NO)
1274   if(HAVE_GSTREAMER)
1275     status("      base:"       "YES (ver ${GSTREAMER_BASE_VERSION})")
1276     status("      video:"      "YES (ver ${GSTREAMER_VIDEO_VERSION})")
1277     status("      app:"        "YES (ver ${GSTREAMER_APP_VERSION})")
1278     status("      riff:"       "YES (ver ${GSTREAMER_RIFF_VERSION})")
1279     status("      pbutils:"    "YES (ver ${GSTREAMER_PBUTILS_VERSION})")
1280   endif(HAVE_GSTREAMER)
1281 endif()
1282
1283 if(WITH_OPENNI OR HAVE_OPENNI)
1284   status("    OpenNI:"         HAVE_OPENNI         THEN "YES (ver ${OPENNI_VERSION_STRING}, build ${OPENNI_VERSION_BUILD})" ELSE NO)
1285   status("    OpenNI PrimeSensor Modules:" HAVE_OPENNI_PRIME_SENSOR_MODULE THEN "YES (${OPENNI_PRIME_SENSOR_MODULE})"      ELSE NO)
1286 endif()
1287
1288 if(WITH_OPENNI2 OR HAVE_OPENNI2)
1289   status("    OpenNI2:"        HAVE_OPENNI2    THEN "YES (ver ${OPENNI2_VERSION_STRING}, build ${OPENNI2_VERSION_BUILD})" ELSE NO)
1290 endif()
1291
1292 if(WITH_PVAPI OR HAVE_PVAPI)
1293   status("    PvAPI:"          HAVE_PVAPI          THEN YES                                        ELSE NO)
1294 endif()
1295
1296 if(WITH_GIGEAPI OR HAVE_GIGE_API)
1297   status("    GigEVisionSDK:"  HAVE_GIGE_API       THEN YES                                        ELSE NO)
1298 endif()
1299
1300 if(WITH_ARAVIS OR HAVE_ARAVIS_API)
1301   status("    Aravis SDK:"     HAVE_ARAVIS_API     THEN "YES (${ARAVIS_LIBRARIES})"                ELSE NO)
1302 endif()
1303
1304 if(APPLE)
1305   status("    AVFoundation:"   HAVE_AVFOUNDATION   THEN YES                                        ELSE NO)
1306   if(WITH_QUICKTIME OR HAVE_QUICKTIME)
1307     status("    QuickTime:"      HAVE_QUICKTIME      THEN YES                                        ELSE NO)
1308   endif()
1309   if(WITH_QTKIT OR HAVE_QTKIT)
1310     status("    QTKit:"          HAVE_QTKIT          THEN "YES (deprecated)"                         ELSE NO)
1311   endif()
1312 endif()
1313
1314 if(WITH_UNICAP OR HAVE_UNICAP)
1315   status("    UniCap:"         HAVE_UNICAP         THEN "YES (ver ${ALIASOF_libunicap_VERSION})"   ELSE NO)
1316   status("    UniCap ucil:"    HAVE_UNICAP_UCIL    THEN "YES (ver ${ALIASOF_libucil_VERSION})"     ELSE NO)
1317 endif()
1318
1319 if(WITH_V4L OR WITH_LIBV4L OR HAVE_LIBV4L OR HAVE_CAMV4L OR HAVE_CAMV4L2 OR HAVE_VIDEOIO)
1320   status("    libv4l/libv4l2:" HAVE_LIBV4L THEN "${ALIASOF_libv4l1_VERSION} / ${ALIASOF_libv4l2_VERSION}" ELSE "NO")
1321   ocv_build_features_string(v4l_status
1322     IF HAVE_CAMV4L THEN "linux/videodev.h"
1323     IF HAVE_CAMV4L2 THEN "linux/videodev2.h"
1324     IF HAVE_VIDEOIO THEN "sys/videoio.h"
1325     ELSE "NO")
1326   status("    v4l/v4l2:" "${v4l_status}")
1327 endif()
1328
1329 if(WITH_DSHOW OR HAVE_DSHOW)
1330   status("    DirectShow:"     HAVE_DSHOW     THEN YES                                        ELSE NO)
1331 endif()
1332
1333 if(WITH_MSMF OR HAVE_MSMF)
1334   status("    Media Foundation:" HAVE_MSMF    THEN YES                                        ELSE NO)
1335 endif()
1336
1337 if(WITH_XIMEA OR HAVE_XIMEA)
1338   status("    XIMEA:"          HAVE_XIMEA          THEN YES                                        ELSE NO)
1339 endif()
1340
1341 if(WITH_XINE OR HAVE_XINE)
1342   status("    Xine:"           HAVE_XINE           THEN "YES (ver ${ALIASOF_libxine_VERSION})"     ELSE NO)
1343 endif()
1344
1345 if(WITH_INTELPERC OR HAVE_INTELPERC)
1346   status("    Intel PerC:"     HAVE_INTELPERC      THEN "YES"                                 ELSE NO)
1347 endif()
1348
1349 if(WITH_MFX OR HAVE_MFX)
1350   status("    Intel Media SDK:" HAVE_MFX      THEN "YES (${MFX_LIBRARY})" ELSE NO)
1351 endif()
1352
1353 if(WITH_GPHOTO2 OR HAVE_GPHOTO2)
1354   status("    gPhoto2:"        HAVE_GPHOTO2        THEN "YES"                                 ELSE NO)
1355 endif()
1356
1357 # Order is similar to CV_PARALLEL_FRAMEWORK in core/src/parallel.cpp
1358 ocv_build_features_string(parallel_status EXCLUSIVE
1359   IF HAVE_TBB THEN "TBB (ver ${TBB_VERSION_MAJOR}.${TBB_VERSION_MINOR} interface ${TBB_INTERFACE_VERSION})"
1360   IF HAVE_CSTRIPES THEN "C="
1361   IF HAVE_OPENMP THEN "OpenMP"
1362   IF HAVE_GCD THEN "GCD"
1363   IF WINRT OR HAVE_CONCURRENCY THEN "Concurrency"
1364   IF HAVE_PTHREADS_PF THEN "pthreads"
1365   ELSE "none")
1366 status("")
1367 status("  Parallel framework:" "${parallel_status}")
1368
1369 if(CV_TRACE OR OPENCV_TRACE)
1370   ocv_build_features_string(trace_status EXCLUSIVE
1371     IF HAVE_ITT THEN "with Intel ITT"
1372     ELSE "built-in")
1373   status("")
1374   status("  Trace: " OPENCV_TRACE THEN "YES (${trace_status})" ELSE NO)
1375 endif()
1376
1377 # ========================== Other third-party libraries ==========================
1378 status("")
1379 status("  Other third-party libraries:")
1380
1381 if(WITH_IPP AND HAVE_IPP)
1382   status("    Intel IPP:" "${IPP_VERSION_STR} [${IPP_VERSION_MAJOR}.${IPP_VERSION_MINOR}.${IPP_VERSION_BUILD}]")
1383   status("           at:" "${IPP_ROOT_DIR}")
1384   if(NOT HAVE_IPP_ICV)
1385     status("       linked:" BUILD_WITH_DYNAMIC_IPP THEN "dynamic" ELSE "static")
1386   endif()
1387   if(HAVE_IPP_IW)
1388     if(BUILD_IPP_IW)
1389       status("    Intel IPP IW:" "sources (${IW_VERSION_MAJOR}.${IW_VERSION_MINOR}.${IW_VERSION_UPDATE})")
1390     else()
1391       status("    Intel IPP IW:" "binaries (${IW_VERSION_MAJOR}.${IW_VERSION_MINOR}.${IW_VERSION_UPDATE})")
1392     endif()
1393     status("              at:" "${IPP_IW_PATH}")
1394   else()
1395     status("    Intel IPP IW:"   NO)
1396   endif()
1397 endif()
1398
1399 if(WITH_VA OR HAVE_VA)
1400   status("    VA:"            HAVE_VA          THEN "YES" ELSE NO)
1401 endif()
1402
1403 if(WITH_VA_INTEL OR HAVE_VA_INTEL)
1404   status("    Intel VA-API/OpenCL:"  HAVE_VA_INTEL       THEN "YES (OpenCL: ${VA_INTEL_IOCL_ROOT})" ELSE NO)
1405 endif()
1406
1407 if(WITH_LAPACK OR HAVE_LAPACK)
1408   status("    Lapack:"      HAVE_LAPACK     THEN "YES (${LAPACK_LIBRARIES})" ELSE NO)
1409 endif()
1410
1411 if(WITH_HALIDE OR HAVE_HALIDE)
1412   status("    Halide:"     HAVE_HALIDE      THEN "YES (${HALIDE_LIBRARIES} ${HALIDE_INCLUDE_DIRS})" ELSE NO)
1413 endif()
1414
1415 if(WITH_INF_ENGINE OR INF_ENGINE_TARGET)
1416   if(INF_ENGINE_TARGET)
1417     set(__msg "YES (${INF_ENGINE_RELEASE} / ${INF_ENGINE_VERSION})")
1418     get_target_property(_lib ${INF_ENGINE_TARGET} IMPORTED_LOCATION)
1419     if(NOT _lib)
1420       get_target_property(_lib_rel ${INF_ENGINE_TARGET} IMPORTED_IMPLIB_RELEASE)
1421       get_target_property(_lib_dbg ${INF_ENGINE_TARGET} IMPORTED_IMPLIB_DEBUG)
1422       set(_lib "${_lib_rel} / ${_lib_dbg}")
1423     endif()
1424     get_target_property(_inc ${INF_ENGINE_TARGET} INTERFACE_INCLUDE_DIRECTORIES)
1425     status("    Inference Engine:" "${__msg}")
1426     status("                libs:" "${_lib}")
1427     status("            includes:" "${_inc}")
1428   else()
1429     status("    Inference Engine:"     "NO")
1430   endif()
1431 endif()
1432
1433 if(WITH_EIGEN OR HAVE_EIGEN)
1434   status("    Eigen:"      HAVE_EIGEN       THEN "YES (ver ${EIGEN_WORLD_VERSION}.${EIGEN_MAJOR_VERSION}.${EIGEN_MINOR_VERSION})" ELSE NO)
1435 endif()
1436
1437 if(WITH_OPENVX OR HAVE_OPENVX)
1438   status("    OpenVX:"     HAVE_OPENVX      THEN "YES (${OPENVX_LIBRARIES})" ELSE "NO")
1439 endif()
1440
1441 status("    Custom HAL:" OpenCV_USED_HAL  THEN "YES (${OpenCV_USED_HAL})" ELSE "NO")
1442
1443 foreach(s ${CUSTOM_STATUS})
1444   status(${CUSTOM_STATUS_${s}})
1445 endforeach()
1446
1447 if(WITH_CUDA OR HAVE_CUDA)
1448   ocv_build_features_string(cuda_features
1449     IF HAVE_CUFFT THEN "CUFFT"
1450     IF HAVE_CUBLAS THEN "CUBLAS"
1451     IF HAVE_NVCUVID THEN "NVCUVID"
1452     IF CUDA_FAST_MATH THEN "FAST_MATH"
1453     ELSE "no extra features")
1454   status("")
1455   status("  NVIDIA CUDA:" HAVE_CUDA THEN "YES (ver ${CUDA_VERSION_STRING}, ${cuda_features})" ELSE NO)
1456   if(HAVE_CUDA)
1457     status("    NVIDIA GPU arch:"      ${OPENCV_CUDA_ARCH_BIN})
1458     status("    NVIDIA PTX archs:"     ${OPENCV_CUDA_ARCH_PTX})
1459   endif()
1460 endif()
1461
1462 if(WITH_OPENCL OR HAVE_OPENCL)
1463   ocv_build_features_string(opencl_features
1464     IF HAVE_OPENCL_SVM THEN "SVM"
1465     IF HAVE_CLAMDFFT THEN "AMDFFT"
1466     IF HAVE_CLAMDBLAS THEN "AMDBLAS"
1467     ELSE "no extra features")
1468   status("")
1469   status("  OpenCL:"     HAVE_OPENCL   THEN   "YES (${opencl_features})" ELSE "NO")
1470   if(HAVE_OPENCL)
1471     status("    Include path:"  OPENCL_INCLUDE_DIRS THEN "${OPENCL_INCLUDE_DIRS}" ELSE "NO")
1472     status("    Link libraries:"       OPENCL_LIBRARIES THEN "${OPENCL_LIBRARIES}" ELSE "Dynamic load")
1473   endif()
1474 endif()
1475
1476 # ========================== python ==========================
1477 if(BUILD_opencv_python2)
1478   status("")
1479   status("  Python 2:")
1480   status("    Interpreter:"     PYTHON2INTERP_FOUND  THEN "${PYTHON2_EXECUTABLE} (ver ${PYTHON2_VERSION_STRING})"       ELSE NO)
1481   if(PYTHON2LIBS_VERSION_STRING)
1482     status("    Libraries:"   HAVE_opencv_python2  THEN  "${PYTHON2_LIBRARIES} (ver ${PYTHON2LIBS_VERSION_STRING})"   ELSE NO)
1483   else()
1484     status("    Libraries:"   HAVE_opencv_python2  THEN  "${PYTHON2_LIBRARIES}"                                      ELSE NO)
1485   endif()
1486   status("    numpy:"         PYTHON2_NUMPY_INCLUDE_DIRS THEN "${PYTHON2_NUMPY_INCLUDE_DIRS} (ver ${PYTHON2_NUMPY_VERSION})" ELSE "NO (Python wrappers can not be generated)")
1487   status("    packages path:" PYTHON2_EXECUTABLE         THEN "${PYTHON2_PACKAGES_PATH}"                                    ELSE "-")
1488 endif()
1489
1490 if(BUILD_opencv_python3)
1491   status("")
1492   status("  Python 3:")
1493   status("    Interpreter:"     PYTHON3INTERP_FOUND  THEN "${PYTHON3_EXECUTABLE} (ver ${PYTHON3_VERSION_STRING})"       ELSE NO)
1494   if(PYTHON3LIBS_VERSION_STRING)
1495     status("    Libraries:"   HAVE_opencv_python3  THEN  "${PYTHON3_LIBRARIES} (ver ${PYTHON3LIBS_VERSION_STRING})"   ELSE NO)
1496   else()
1497     status("    Libraries:"   HAVE_opencv_python3  THEN  "${PYTHON3_LIBRARIES}"                                      ELSE NO)
1498   endif()
1499   status("    numpy:"         PYTHON3_NUMPY_INCLUDE_DIRS THEN "${PYTHON3_NUMPY_INCLUDE_DIRS} (ver ${PYTHON3_NUMPY_VERSION})" ELSE "NO (Python3 wrappers can not be generated)")
1500   status("    packages path:" PYTHON3_EXECUTABLE         THEN "${PYTHON3_PACKAGES_PATH}"                                    ELSE "-")
1501 endif()
1502
1503 status("")
1504 status("  Python (for build):"  PYTHON_DEFAULT_AVAILABLE THEN "${PYTHON_DEFAULT_EXECUTABLE}" ELSE NO)
1505 if(PYLINT_FOUND AND PYLINT_EXECUTABLE)
1506   status("    Pylint:"  PYLINT_FOUND THEN "${PYLINT_EXECUTABLE} (ver: ${PYLINT_VERSION}, checks: ${PYLINT_TOTAL_TARGETS})" ELSE NO)
1507 endif()
1508 if(FLAKE8_FOUND AND FLAKE8_EXECUTABLE)
1509   status("    Flake8:"  FLAKE8_FOUND THEN "${FLAKE8_EXECUTABLE} (ver: ${FLAKE8_VERSION})" ELSE NO)
1510 endif()
1511
1512 # ========================== java ==========================
1513 if(BUILD_JAVA OR BUILD_opencv_java)
1514   status("")
1515   status("  Java:"            BUILD_FAT_JAVA_LIB  THEN "export all functions"                                      ELSE "")
1516   status("    ant:"           ANT_EXECUTABLE      THEN "${ANT_EXECUTABLE} (ver ${ANT_VERSION})"                    ELSE NO)
1517   if(NOT ANDROID)
1518     status("    JNI:"         JNI_INCLUDE_DIRS    THEN "${JNI_INCLUDE_DIRS}"                                       ELSE NO)
1519   endif()
1520   status("    Java wrappers:" HAVE_opencv_java                                                            THEN YES ELSE NO)
1521   status("    Java tests:"    BUILD_TESTS AND opencv_test_java_BINARY_DIR                                 THEN YES ELSE NO)
1522 endif()
1523
1524 ocv_cmake_hook(STATUS_DUMP_EXTRA)
1525
1526 # ========================== auxiliary ==========================
1527 status("")
1528 status("  Install to:" "${CMAKE_INSTALL_PREFIX}")
1529 status("-----------------------------------------------------------------")
1530 status("")
1531
1532
1533 ocv_finalize_status()
1534
1535 ocv_cmake_hook(POST_FINALIZE)
1536
1537 # ----------------------------------------------------------------------------
1538 # CPack stuff
1539 # ----------------------------------------------------------------------------
1540
1541 include(cmake/OpenCVPackaging.cmake)
1542
1543 # This should be the last command
1544 ocv_cmake_dump_vars("" TOFILE "CMakeVars.txt")
1545 ocv_cmake_eval(DEBUG_POST ONCE)