CMakeLists.txt

   1 # ----------------------------------------------------------------------------
   2 #  Root CMake file for OpenCV
   3 #
   4 #    From the off-tree build directory, invoke:
   5 #      $ cmake <PATH_TO_OPENCV_ROOT>
   6 #
   7 # ----------------------------------------------------------------------------
   8
   9 # Disable in-source builds to prevent source tree corruption.
  10 if(" ${CMAKE_SOURCE_DIR}" STREQUAL " ${CMAKE_BINARY_DIR}")
  11   message(FATAL_ERROR "
  12 FATAL: In-source builds are not allowed.
  13        You should create a separate directory for build files.
  14 ")
  15 endif()
  16
  17
  18 include(cmake/OpenCVMinDepVersions.cmake)
  19
  20 if(CMAKE_GENERATOR MATCHES Xcode AND XCODE_VERSION VERSION_GREATER 4.3)
  21   cmake_minimum_required(VERSION 3.0 FATAL_ERROR)
  22 elseif(CMAKE_SYSTEM_NAME MATCHES WindowsPhone OR CMAKE_SYSTEM_NAME MATCHES WindowsStore)
  23   cmake_minimum_required(VERSION 3.1 FATAL_ERROR)
  24   #Required to resolve linker error issues due to incompatibility with CMake v3.0+ policies.
  25   #CMake fails to find _fseeko() which leads to subsequent linker error.
  26   #See details here: http://www.cmake.org/Wiki/CMake/Policies
  27   cmake_policy(VERSION 2.8)
  28 else()
  29   cmake_minimum_required(VERSION "${MIN_VER_CMAKE}" FATAL_ERROR)
  30 endif()
  31
  32 set(CMAKE_POSITION_INDEPENDENT_CODE TRUE)
  33
  34 # Following block can break build in case of cross-compilng
  35 # but CMAKE_CROSSCOMPILING variable will be set only on project(OpenCV) command
  36 # so we will try to detect cross-compiling by presense of CMAKE_TOOLCHAIN_FILE
  37 if(NOT DEFINED CMAKE_INSTALL_PREFIX)
  38   if(NOT CMAKE_TOOLCHAIN_FILE)
  39     # it _must_ go before project(OpenCV) in order to work
  40     if(WIN32)
  41       set(CMAKE_INSTALL_PREFIX "${CMAKE_BINARY_DIR}/install" CACHE PATH "Installation Directory")
  42     else()
  43       set(CMAKE_INSTALL_PREFIX "/usr/local" CACHE PATH "Installation Directory")
  44     endif()
  45   else(NOT CMAKE_TOOLCHAIN_FILE)
  46     #Android: set output folder to ${CMAKE_BINARY_DIR}
  47     set( LIBRARY_OUTPUT_PATH_ROOT ${CMAKE_BINARY_DIR} CACHE PATH "root for library output, set this to change where android libs are compiled to" )
  48     # any cross-compiling
  49     set(CMAKE_INSTALL_PREFIX "${CMAKE_BINARY_DIR}/install" CACHE PATH "Installation Directory")
  50   endif(NOT CMAKE_TOOLCHAIN_FILE)
  51 endif()
  52
  53 if(CMAKE_SYSTEM_NAME MATCHES WindowsPhone OR CMAKE_SYSTEM_NAME MATCHES WindowsStore)
  54   set(WINRT TRUE)
  55 endif(CMAKE_SYSTEM_NAME MATCHES WindowsPhone OR CMAKE_SYSTEM_NAME MATCHES WindowsStore)
  56
  57 if(WINRT)
  58   add_definitions(-DWINRT -DNO_GETENV)
  59
  60   # Making definitions available to other configurations and
  61   # to filter dependency restrictions at compile time.
  62   if(CMAKE_SYSTEM_NAME MATCHES WindowsPhone)
  63     set(WINRT_PHONE TRUE)
  64     add_definitions(-DWINRT_PHONE)
  65   elseif(CMAKE_SYSTEM_NAME MATCHES WindowsStore)
  66     set(WINRT_STORE TRUE)
  67     add_definitions(-DWINRT_STORE)
  68   endif()
  69
  70   if(CMAKE_SYSTEM_VERSION MATCHES 10)
  71     set(WINRT_10 TRUE)
  72     add_definitions(-DWINRT_10)
  73   elseif(CMAKE_SYSTEM_VERSION MATCHES 8.1)
  74     set(WINRT_8_1 TRUE)
  75     add_definitions(-DWINRT_8_1)
  76   elseif(CMAKE_SYSTEM_VERSION MATCHES 8.0)
  77     set(WINRT_8_0 TRUE)
  78     add_definitions(-DWINRT_8_0)
  79   endif()
  80 endif()
  81
  82 if(POLICY CMP0026)
  83   cmake_policy(SET CMP0026 NEW)
  84 endif()
  85
  86 if(POLICY CMP0042)
  87   cmake_policy(SET CMP0042 NEW)
  88 endif()
  89
  90 if(POLICY CMP0046)
  91   cmake_policy(SET CMP0046 NEW)
  92 endif()
  93
  94 if(POLICY CMP0051)
  95   cmake_policy(SET CMP0051 NEW)
  96 endif()
  97
  98 if(POLICY CMP0056)
  99   cmake_policy(SET CMP0056 NEW)
 100 endif()
 101
 102 if(POLICY CMP0067)
 103   cmake_policy(SET CMP0067 NEW)
 104 endif()
 105
 106 include(cmake/OpenCVUtils.cmake)
 107
 108 # must go before the project command
 109 ocv_update(CMAKE_CONFIGURATION_TYPES "Debug;Release" CACHE STRING "Configs" FORCE)
 110 if(DEFINED CMAKE_BUILD_TYPE)
 111   set_property( CACHE CMAKE_BUILD_TYPE PROPERTY STRINGS ${CMAKE_CONFIGURATION_TYPES} )
 112 endif()
 113
 114 enable_testing()
 115
 116 project(OpenCV CXX C)
 117
 118 if(MSVC)
 119   set(CMAKE_USE_RELATIVE_PATHS ON CACHE INTERNAL "" FORCE)
 120 endif()
 121
 122 ocv_cmake_eval(DEBUG_PRE ONCE)
 123
 124 ocv_clear_vars(OpenCVModules_TARGETS)
 125
 126 include(cmake/OpenCVDownload.cmake)
 127
 128 # ----------------------------------------------------------------------------
 129 # Break in case of popular CMake configuration mistakes
 130 # ----------------------------------------------------------------------------
 131 if(NOT CMAKE_SIZEOF_VOID_P GREATER 0)
 132   message(FATAL_ERROR "CMake fails to determine the bitness of the target platform.
 133   Please check your CMake and compiler installation. If you are cross-compiling then ensure that your CMake toolchain file correctly sets the compiler details.")
 134 endif()
 135
 136 # ----------------------------------------------------------------------------
 137 # Detect compiler and target platform architecture
 138 # ----------------------------------------------------------------------------
 139 OCV_OPTION(ENABLE_CXX11 "Enable C++11 compilation mode" "${OPENCV_CXX11}")
 140 include(cmake/OpenCVDetectCXXCompiler.cmake)
 141
 142 # Add these standard paths to the search paths for FIND_LIBRARY
 143 # to find libraries from these locations first
 144 if(UNIX AND NOT ANDROID)
 145   if(X86_64 OR CMAKE_SIZEOF_VOID_P EQUAL 8)
 146     if(EXISTS /lib64)
 147       list(APPEND CMAKE_LIBRARY_PATH /lib64)
 148     else()
 149       list(APPEND CMAKE_LIBRARY_PATH /lib)
 150     endif()
 151     if(EXISTS /usr/lib64)
 152       list(APPEND CMAKE_LIBRARY_PATH /usr/lib64)
 153     else()
 154       list(APPEND CMAKE_LIBRARY_PATH /usr/lib)
 155     endif()
 156   elseif(X86 OR CMAKE_SIZEOF_VOID_P EQUAL 4)
 157     if(EXISTS /lib32)
 158       list(APPEND CMAKE_LIBRARY_PATH /lib32)
 159     else()
 160       list(APPEND CMAKE_LIBRARY_PATH /lib)
 161     endif()
 162     if(EXISTS /usr/lib32)
 163       list(APPEND CMAKE_LIBRARY_PATH /usr/lib32)
 164     else()
 165       list(APPEND CMAKE_LIBRARY_PATH /usr/lib)
 166     endif()
 167   endif()
 168 endif()
 169
 170 # Add these standard paths to the search paths for FIND_PATH
 171 # to find include files from these locations first
 172 if(MINGW)
 173   if(EXISTS /mingw)
 174       list(APPEND CMAKE_INCLUDE_PATH /mingw)
 175   endif()
 176   if(EXISTS /mingw32)
 177       list(APPEND CMAKE_INCLUDE_PATH /mingw32)
 178   endif()
 179   if(EXISTS /mingw64)
 180       list(APPEND CMAKE_INCLUDE_PATH /mingw64)
 181   endif()
 182 endif()
 183
 184 # ----------------------------------------------------------------------------
 185 # OpenCV cmake options
 186 # ----------------------------------------------------------------------------
 187
 188 OCV_OPTION(OPENCV_ENABLE_NONFREE "Enable non-free algorithms" OFF)
 189
 190 # 3rd party libs
 191 OCV_OPTION(BUILD_ZLIB               "Build zlib from source"             WIN32 OR APPLE)
 192 OCV_OPTION(BUILD_TIFF               "Build libtiff from source"          WIN32 OR ANDROID OR APPLE)
 193 OCV_OPTION(BUILD_JASPER             "Build libjasper from source"        WIN32 OR ANDROID OR APPLE)
 194 OCV_OPTION(BUILD_JPEG               "Build libjpeg from source"          WIN32 OR ANDROID OR APPLE)
 195 OCV_OPTION(BUILD_PNG                "Build libpng from source"           WIN32 OR ANDROID OR APPLE)
 196 OCV_OPTION(BUILD_OPENEXR            "Build openexr from source"          (WIN32 OR ANDROID OR APPLE) AND NOT WINRT)
 197 OCV_OPTION(BUILD_TBB                "Download and build TBB from source" ANDROID )
 198 OCV_OPTION(BUILD_IPP_IW             "Build IPP IW from source"           NOT MINGW IF (X86_64 OR X86) AND NOT WINRT )
 199 OCV_OPTION(BUILD_ITT                "Build Intel ITT from source"        NOT MINGW IF (X86_64 OR X86) AND NOT WINRT AND NOT APPLE_FRAMEWORK )
 200
 201 # Optional 3rd party components
 202 # ===================================================
 203 OCV_OPTION(WITH_1394           "Include IEEE1394 support"                    ON   IF (NOT ANDROID AND NOT IOS AND NOT WINRT) )
 204 OCV_OPTION(WITH_AVFOUNDATION   "Use AVFoundation for Video I/O (iOS/Mac)"    ON   IF APPLE)
 205 OCV_OPTION(WITH_CARBON         "Use Carbon for UI instead of Cocoa"          OFF  IF APPLE )
 206 OCV_OPTION(WITH_CAROTENE       "Use NVidia carotene acceleration library for ARM platform"                   ON  IF (ARM OR AARCH64) AND NOT IOS AND NOT (CMAKE_VERSION VERSION_LESS "2.8.11"))
 207 OCV_OPTION(WITH_CPUFEATURES    "Use cpufeatures Android library"             ON   IF ANDROID)
 208 OCV_OPTION(WITH_VTK            "Include VTK library support (and build opencv_viz module eiher)"             ON  IF (NOT ANDROID AND NOT IOS AND NOT WINRT AND NOT CMAKE_CROSSCOMPILING) )
 209 OCV_OPTION(WITH_CUDA           "Include NVidia Cuda Runtime support"                                         ON  IF (NOT IOS AND NOT WINRT) )
 210 OCV_OPTION(WITH_CUFFT          "Include NVidia Cuda Fast Fourier Transform (FFT) library support"            ON  IF (NOT IOS AND NOT WINRT) )
 211 OCV_OPTION(WITH_CUBLAS         "Include NVidia Cuda Basic Linear Algebra Subprograms (BLAS) library support" ON IF (NOT IOS AND NOT WINRT) )
 212 OCV_OPTION(WITH_NVCUVID        "Include NVidia Video Decoding library support"                               ON IF (NOT IOS AND NOT APPLE) )
 213 OCV_OPTION(WITH_EIGEN          "Include Eigen2/Eigen3 support"               (NOT CV_DISABLE_OPTIMIZATION)       IF (NOT WINRT AND NOT CMAKE_CROSSCOMPILING) )
 214 OCV_OPTION(WITH_VFW            "Include Video for Windows support"           ON   IF WIN32 )
 215 OCV_OPTION(WITH_FFMPEG         "Include FFMPEG support"                      ON   IF (NOT ANDROID AND NOT IOS AND NOT WINRT) )
 216 OCV_OPTION(WITH_GSTREAMER      "Include Gstreamer support"                   ON   IF (NOT ANDROID AND NOT IOS AND NOT WINRT) )
 217 OCV_OPTION(WITH_GSTREAMER_0_10 "Enable Gstreamer 0.10 support (instead of 1.x)"                              OFF )
 218 OCV_OPTION(WITH_GTK            "Include GTK support"                         ON   IF (UNIX AND NOT APPLE AND NOT ANDROID) )
 219 OCV_OPTION(WITH_GTK_2_X        "Use GTK version 2"                           OFF  IF (UNIX AND NOT APPLE AND NOT ANDROID) )
 220 OCV_OPTION(WITH_IPP            "Include Intel IPP support"                   (NOT MINGW AND NOT CV_DISABLE_OPTIMIZATION)  IF (X86_64 OR X86) AND NOT WINRT AND NOT IOS )
 221 OCV_OPTION(WITH_HALIDE         "Include Halide support"                      OFF)
 222 OCV_OPTION(WITH_JASPER         "Include JPEG2K support"                      ON   IF (NOT IOS) )
 223 OCV_OPTION(WITH_JPEG           "Include JPEG support"                        ON)
 224 OCV_OPTION(WITH_WEBP           "Include WebP support"                        ON   IF (NOT WINRT) )
 225 OCV_OPTION(WITH_OPENEXR        "Include ILM support via OpenEXR"             ON   IF (NOT IOS AND NOT WINRT) )
 226 OCV_OPTION(WITH_OPENGL         "Include OpenGL support"                      OFF  IF (NOT ANDROID AND NOT WINRT) )
 227 OCV_OPTION(WITH_OPENVX         "Include OpenVX support"                      OFF)
 228 OCV_OPTION(WITH_OPENNI         "Include OpenNI support"                      OFF  IF (NOT ANDROID AND NOT IOS AND NOT WINRT) )
 229 OCV_OPTION(WITH_OPENNI2        "Include OpenNI2 support"                     OFF  IF (NOT ANDROID AND NOT IOS AND NOT WINRT) )
 230 OCV_OPTION(WITH_PNG            "Include PNG support"                         ON)
 231 OCV_OPTION(WITH_GDCM           "Include DICOM support"                       OFF)
 232 OCV_OPTION(WITH_PVAPI          "Include Prosilica GigE support"              OFF   IF (NOT ANDROID AND NOT IOS AND NOT WINRT) )
 233 OCV_OPTION(WITH_GIGEAPI        "Include Smartek GigE support"                OFF   IF (NOT ANDROID AND NOT IOS AND NOT WINRT) )
 234 OCV_OPTION(WITH_ARAVIS         "Include Aravis GigE support"                 OFF   IF (NOT ANDROID AND NOT IOS AND NOT WINRT AND NOT WIN32) )
 235 OCV_OPTION(WITH_QT             "Build with Qt Backend support"               OFF  IF (NOT ANDROID AND NOT IOS AND NOT WINRT) )
 236 OCV_OPTION(WITH_WIN32UI        "Build with Win32 UI Backend support"         ON   IF WIN32 AND NOT WINRT)
 237 OCV_OPTION(WITH_QUICKTIME      "Use QuickTime for Video I/O"                 OFF  IF APPLE )
 238 OCV_OPTION(WITH_QTKIT          "Use QTKit Video I/O backend"                 OFF  IF APPLE )
 239 OCV_OPTION(WITH_TBB            "Include Intel TBB support"                   OFF  IF (NOT IOS AND NOT WINRT) )
 240 OCV_OPTION(WITH_OPENMP         "Include OpenMP support"                      OFF)
 241 OCV_OPTION(WITH_CSTRIPES       "Include C= support"                          OFF  IF (WIN32 AND NOT WINRT)  )
 242 OCV_OPTION(WITH_PTHREADS_PF    "Use pthreads-based parallel_for"             ON   IF (NOT WIN32 OR MINGW) )
 243 OCV_OPTION(WITH_TIFF           "Include TIFF support"                        ON   IF (NOT IOS) )
 244 OCV_OPTION(WITH_UNICAP         "Include Unicap support (GPL)"                OFF  IF (UNIX AND NOT APPLE AND NOT ANDROID) )
 245 OCV_OPTION(WITH_V4L            "Include Video 4 Linux support"               ON   IF (UNIX AND NOT ANDROID AND NOT APPLE) )
 246 OCV_OPTION(WITH_LIBV4L         "Use libv4l for Video 4 Linux support"        OFF  IF (UNIX AND NOT ANDROID AND NOT APPLE) )
 247 OCV_OPTION(WITH_DSHOW          "Build VideoIO with DirectShow support"       ON   IF (WIN32 AND NOT ARM AND NOT WINRT) )
 248 OCV_OPTION(WITH_MSMF           "Build VideoIO with Media Foundation support" OFF  IF WIN32 )
 249 OCV_OPTION(WITH_XIMEA          "Include XIMEA cameras support"               OFF  IF (NOT ANDROID AND NOT WINRT) )
 250 OCV_OPTION(WITH_XINE           "Include Xine support (GPL)"                  OFF  IF (UNIX AND NOT APPLE AND NOT ANDROID) )
 251 OCV_OPTION(WITH_CLP            "Include Clp support (EPL)"                   OFF)
 252 OCV_OPTION(WITH_OPENCL         "Include OpenCL Runtime support"              (NOT ANDROID AND NOT CV_DISABLE_OPTIMIZATION)  IF (NOT IOS AND NOT WINRT) )
 253 OCV_OPTION(WITH_OPENCL_SVM     "Include OpenCL Shared Virtual Memory support" OFF ) # experimental
 254 OCV_OPTION(WITH_OPENCLAMDFFT   "Include AMD OpenCL FFT library support"      ON   IF (NOT ANDROID AND NOT IOS AND NOT WINRT) )
 255 OCV_OPTION(WITH_OPENCLAMDBLAS  "Include AMD OpenCL BLAS library support"     ON   IF (NOT ANDROID AND NOT IOS AND NOT WINRT) )
 256 OCV_OPTION(WITH_DIRECTX        "Include DirectX support"                     ON   IF (WIN32 AND NOT WINRT) )
 257 OCV_OPTION(WITH_INTELPERC      "Include Intel Perceptual Computing support"  OFF  IF (WIN32 AND NOT WINRT) )
 258 OCV_OPTION(WITH_MATLAB         "Include Matlab support"                      ON   IF (NOT ANDROID AND NOT IOS AND NOT WINRT))
 259 OCV_OPTION(WITH_VA             "Include VA support"                          OFF  IF (UNIX AND NOT ANDROID) )
 260 OCV_OPTION(WITH_VA_INTEL       "Include Intel VA-API/OpenCL support"         OFF  IF (UNIX AND NOT ANDROID) )
 261 OCV_OPTION(WITH_MFX            "Include Intel Media SDK support"             OFF   IF ((UNIX AND NOT ANDROID) OR (WIN32 AND NOT WINRT AND NOT MINGW)) )
 262 OCV_OPTION(WITH_GDAL           "Include GDAL Support"                        OFF  IF (NOT ANDROID AND NOT IOS AND NOT WINRT) )
 263 OCV_OPTION(WITH_GPHOTO2        "Include gPhoto2 library support"             ON   IF (UNIX AND NOT ANDROID AND NOT IOS) )
 264 OCV_OPTION(WITH_LAPACK         "Include Lapack library support"              (NOT CV_DISABLE_OPTIMIZATION)  IF (NOT ANDROID AND NOT IOS) )
 265 OCV_OPTION(WITH_ITT            "Include Intel ITT support"                   ON   IF (NOT APPLE_FRAMEWORK) )
 266
 267 # OpenCV build components
 268 # ===================================================
 269 OCV_OPTION(BUILD_SHARED_LIBS        "Build shared libraries (.dll/.so) instead of static ones (.lib/.a)" NOT (ANDROID OR APPLE_FRAMEWORK) )
 270 OCV_OPTION(BUILD_opencv_apps        "Build utility applications (used for example to train classifiers)" (NOT ANDROID AND NOT WINRT) IF (NOT APPLE_FRAMEWORK) )
 271 OCV_OPTION(BUILD_opencv_js          "Build JavaScript bindings by Emscripten" OFF )
 272 OCV_OPTION(BUILD_ANDROID_EXAMPLES   "Build examples for Android platform"         ON  IF ANDROID )
 273 OCV_OPTION(BUILD_DOCS               "Create build rules for OpenCV Documentation" ON  IF (NOT WINRT AND NOT APPLE_FRAMEWORK))
 274 OCV_OPTION(BUILD_EXAMPLES           "Build all examples"                          OFF )
 275 OCV_OPTION(BUILD_PACKAGE            "Enables 'make package_source' command"       ON  IF NOT WINRT)
 276 OCV_OPTION(BUILD_PERF_TESTS         "Build performance tests"                     ON  IF (NOT APPLE_FRAMEWORK) )
 277 OCV_OPTION(BUILD_TESTS              "Build accuracy & regression tests"           ON  IF (NOT APPLE_FRAMEWORK) )
 278 OCV_OPTION(BUILD_WITH_DEBUG_INFO    "Include debug info into debug libs (not MSCV only)" ON )
 279 OCV_OPTION(BUILD_WITH_STATIC_CRT    "Enables use of statically linked CRT for statically linked OpenCV" ON IF MSVC )
 280 OCV_OPTION(BUILD_WITH_DYNAMIC_IPP   "Enables dynamic linking of IPP (only for standalone IPP)" OFF )
 281 OCV_OPTION(BUILD_FAT_JAVA_LIB       "Create fat java wrapper containing the whole OpenCV library" ON IF NOT BUILD_SHARED_LIBS AND CMAKE_COMPILER_IS_GNUCXX )
 282 OCV_OPTION(BUILD_ANDROID_SERVICE    "Build OpenCV Manager for Google Play" OFF IF ANDROID )
 283 OCV_OPTION(BUILD_CUDA_STUBS         "Build CUDA modules stubs when no CUDA SDK" OFF  IF (NOT APPLE_FRAMEWORK) )
 284 OCV_OPTION(BUILD_JAVA               "Enable Java support"                         (ANDROID OR NOT CMAKE_CROSSCOMPILING)  IF (ANDROID OR (NOT APPLE_FRAMEWORK AND NOT WINRT)) )
 285
 286 # OpenCV installation options
 287 # ===================================================
 288 OCV_OPTION(INSTALL_CREATE_DISTRIB   "Change install rules to build the distribution package" OFF )
 289 OCV_OPTION(INSTALL_C_EXAMPLES       "Install C examples"        OFF )
 290 OCV_OPTION(INSTALL_PYTHON_EXAMPLES  "Install Python examples"   OFF )
 291 OCV_OPTION(INSTALL_ANDROID_EXAMPLES "Install Android examples"  OFF IF ANDROID )
 292 OCV_OPTION(INSTALL_TO_MANGLED_PATHS "Enables mangled install paths, that help with side by side installs." OFF IF (UNIX AND NOT ANDROID AND NOT APPLE_FRAMEWORK AND BUILD_SHARED_LIBS) )
 293 OCV_OPTION(INSTALL_TESTS            "Install accuracy and performance test binaries and test data" OFF)
 294
 295 # OpenCV build options
 296 # ===================================================
 297 OCV_OPTION(ENABLE_CCACHE              "Use ccache"                                               (UNIX AND NOT IOS AND (CMAKE_GENERATOR MATCHES "Makefile" OR CMAKE_GENERATOR MATCHES "Ninja")) )
 298 OCV_OPTION(ENABLE_PRECOMPILED_HEADERS "Use precompiled headers"                                  ON IF (NOT IOS AND NOT CMAKE_CROSSCOMPILING) )
 299 OCV_OPTION(ENABLE_SOLUTION_FOLDERS    "Solution folder in Visual Studio or in other IDEs"        (MSVC_IDE OR CMAKE_GENERATOR MATCHES Xcode) )
 300 OCV_OPTION(ENABLE_PROFILING           "Enable profiling in the GCC compiler (Add flags: -g -pg)" OFF  IF CMAKE_COMPILER_IS_GNUCXX )
 301 OCV_OPTION(ENABLE_COVERAGE            "Enable coverage collection with  GCov"                    OFF  IF CMAKE_COMPILER_IS_GNUCXX )
 302 OCV_OPTION(ENABLE_OMIT_FRAME_POINTER  "Enable -fomit-frame-pointer for GCC"                      ON   IF CMAKE_COMPILER_IS_GNUCXX AND NOT (APPLE AND CMAKE_COMPILER_IS_CLANGCXX) )
 303 OCV_OPTION(ENABLE_POWERPC             "Enable PowerPC for GCC"                                   ON   IF (CMAKE_COMPILER_IS_GNUCXX AND CMAKE_SYSTEM_PROCESSOR MATCHES powerpc.*) )
 304 OCV_OPTION(ENABLE_VSX                 "Enable POWER8 and above VSX (64-bit little-endian)"       ON   IF (CMAKE_COMPILER_IS_GNUCXX AND PPC64LE) )
 305 OCV_OPTION(ENABLE_FAST_MATH           "Enable -ffast-math (not recommended for GCC 4.6.x)"       OFF  IF (CMAKE_COMPILER_IS_GNUCXX AND (X86 OR X86_64)) )
 306 OCV_OPTION(ENABLE_NEON                "Enable NEON instructions"                                 (NEON OR ANDROID_ARM_NEON OR AARCH64) IF CMAKE_COMPILER_IS_GNUCXX AND (ARM OR AARCH64 OR IOS) )
 307 OCV_OPTION(ENABLE_VFPV3               "Enable VFPv3-D32 instructions"                            OFF  IF CMAKE_COMPILER_IS_GNUCXX AND (ARM OR AARCH64 OR IOS) )
 308 OCV_OPTION(ENABLE_NOISY_WARNINGS      "Show all warnings even if they are too noisy"             OFF )
 309 OCV_OPTION(OPENCV_WARNINGS_ARE_ERRORS "Treat warnings as errors"                                 OFF )
 310 OCV_OPTION(ANDROID_EXAMPLES_WITH_LIBS "Build binaries of Android examples with native libraries" OFF  IF ANDROID )
 311 OCV_OPTION(ENABLE_IMPL_COLLECTION     "Collect implementation data on function call"             OFF )
 312 OCV_OPTION(ENABLE_INSTRUMENTATION     "Instrument functions to collect calls trace and performance" OFF )
 313 OCV_OPTION(ENABLE_GNU_STL_DEBUG       "Enable GNU STL Debug mode (defines _GLIBCXX_DEBUG)"       OFF IF ((NOT CMAKE_VERSION VERSION_LESS "2.8.11") AND CMAKE_COMPILER_IS_GNUCXX) )
 314 OCV_OPTION(ENABLE_BUILD_HARDENING     "Enable hardening of the resulting binaries (against security attacks, detects memory corruption, etc)" OFF)
 315 OCV_OPTION(ENABLE_LTO                 "Enable Link Time Optimization" OFF IF CMAKE_COMPILER_IS_GNUCXX OR MSVC)
 316 OCV_OPTION(GENERATE_ABI_DESCRIPTOR    "Generate XML file for abi_compliance_checker tool" OFF IF UNIX)
 317 OCV_OPTION(CV_ENABLE_INTRINSICS       "Use intrinsic-based optimized code" ON )
 318 OCV_OPTION(CV_DISABLE_OPTIMIZATION    "Disable explicit optimized code (dispatched code/intrinsics/loop unrolling/etc)" OFF )
 319 OCV_OPTION(CV_TRACE                   "Enable OpenCV code trace" ON)
 320
 321 OCV_OPTION(ENABLE_PYLINT              "Add target with Pylint checks"                            (${BUILD_DOCS} OR ${BUILD_EXAMPLES}) IF (NOT CMAKE_CROSSCOMPILING AND NOT APPLE_FRAMEWORK) )
 322
 323 if(ENABLE_IMPL_COLLECTION)
 324   add_definitions(-DCV_COLLECT_IMPL_DATA)
 325 endif()
 326
 327
 328 # ----------------------------------------------------------------------------
 329 #  Get actual OpenCV version number from sources
 330 # ----------------------------------------------------------------------------
 331 include(cmake/OpenCVVersion.cmake)
 332
 333
 334 # ----------------------------------------------------------------------------
 335 #  Build & install layouts
 336 # ----------------------------------------------------------------------------
 337
 338 # Save libs and executables in the same place
 339 set(EXECUTABLE_OUTPUT_PATH "${CMAKE_BINARY_DIR}/bin" CACHE PATH "Output directory for applications")
 340
 341 if(ANDROID)
 342   if(ANDROID_ABI MATCHES "NEON")
 343     set(ENABLE_NEON ON)
 344   endif()
 345   if(ANDROID_ABI MATCHES "VFPV3")
 346     set(ENABLE_VFPV3 ON)
 347   endif()
 348 endif()
 349
 350 if(ANDROID OR WIN32)
 351   ocv_update(OPENCV_DOC_INSTALL_PATH doc)
 352 else()
 353   ocv_update(OPENCV_DOC_INSTALL_PATH share/OpenCV/doc)
 354 endif()
 355
 356 if(WIN32 AND CMAKE_HOST_SYSTEM_NAME MATCHES Windows)
 357   if(DEFINED OpenCV_RUNTIME AND DEFINED OpenCV_ARCH)
 358     ocv_update(OpenCV_INSTALL_BINARIES_PREFIX "${OpenCV_ARCH}/${OpenCV_RUNTIME}/")
 359   else()
 360     message(STATUS "Can't detect runtime and/or arch")
 361     ocv_update(OpenCV_INSTALL_BINARIES_PREFIX "")
 362   endif()
 363 elseif(ANDROID)
 364   ocv_update(OpenCV_INSTALL_BINARIES_PREFIX "sdk/native/")
 365 else()
 366   ocv_update(OpenCV_INSTALL_BINARIES_PREFIX "")
 367 endif()
 368
 369 if(ANDROID)
 370   ocv_update(OPENCV_SAMPLES_BIN_INSTALL_PATH "${OpenCV_INSTALL_BINARIES_PREFIX}samples/${ANDROID_NDK_ABI_NAME}")
 371 else()
 372   ocv_update(OPENCV_SAMPLES_BIN_INSTALL_PATH "${OpenCV_INSTALL_BINARIES_PREFIX}samples")
 373 endif()
 374
 375 if(ANDROID)
 376   ocv_update(OPENCV_BIN_INSTALL_PATH "${OpenCV_INSTALL_BINARIES_PREFIX}bin/${ANDROID_NDK_ABI_NAME}")
 377 else()
 378   ocv_update(OPENCV_BIN_INSTALL_PATH "${OpenCV_INSTALL_BINARIES_PREFIX}bin")
 379 endif()
 380
 381 if(NOT OPENCV_TEST_INSTALL_PATH)
 382   ocv_update(OPENCV_TEST_INSTALL_PATH "${OPENCV_BIN_INSTALL_PATH}")
 383 endif()
 384
 385 if (OPENCV_TEST_DATA_PATH)
 386   get_filename_component(OPENCV_TEST_DATA_PATH ${OPENCV_TEST_DATA_PATH} ABSOLUTE)
 387 endif()
 388
 389 if(ANDROID)
 390   ocv_update(OPENCV_TEST_DATA_INSTALL_PATH "sdk/etc/testdata")
 391 elseif(WIN32)
 392   ocv_update(OPENCV_TEST_DATA_INSTALL_PATH "testdata")
 393 else()
 394   ocv_update(OPENCV_TEST_DATA_INSTALL_PATH "share/OpenCV/testdata")
 395 endif()
 396
 397 if(ANDROID)
 398   set(LIBRARY_OUTPUT_PATH                "${OpenCV_BINARY_DIR}/lib/${ANDROID_NDK_ABI_NAME}")
 399   ocv_update(3P_LIBRARY_OUTPUT_PATH      "${OpenCV_BINARY_DIR}/3rdparty/lib/${ANDROID_NDK_ABI_NAME}")
 400   ocv_update(OPENCV_LIB_INSTALL_PATH     sdk/native/libs/${ANDROID_NDK_ABI_NAME})
 401   ocv_update(OPENCV_3P_LIB_INSTALL_PATH  sdk/native/3rdparty/libs/${ANDROID_NDK_ABI_NAME})
 402   ocv_update(OPENCV_CONFIG_INSTALL_PATH  sdk/native/jni)
 403   ocv_update(OPENCV_INCLUDE_INSTALL_PATH sdk/native/jni/include)
 404   ocv_update(OPENCV_SAMPLES_SRC_INSTALL_PATH samples/native)
 405   ocv_update(OPENCV_OTHER_INSTALL_PATH   sdk/etc)
 406 else()
 407   set(LIBRARY_OUTPUT_PATH                "${OpenCV_BINARY_DIR}/lib")
 408   ocv_update(3P_LIBRARY_OUTPUT_PATH      "${OpenCV_BINARY_DIR}/3rdparty/lib${LIB_SUFFIX}")
 409
 410   if(WIN32 AND CMAKE_HOST_SYSTEM_NAME MATCHES Windows)
 411     if(OpenCV_STATIC)
 412       ocv_update(OPENCV_LIB_INSTALL_PATH   "${OpenCV_INSTALL_BINARIES_PREFIX}staticlib${LIB_SUFFIX}")
 413     else()
 414       ocv_update(OPENCV_LIB_INSTALL_PATH   "${OpenCV_INSTALL_BINARIES_PREFIX}lib${LIB_SUFFIX}")
 415     endif()
 416     ocv_update(OPENCV_3P_LIB_INSTALL_PATH  "${OpenCV_INSTALL_BINARIES_PREFIX}staticlib${LIB_SUFFIX}")
 417     ocv_update(OPENCV_SAMPLES_SRC_INSTALL_PATH    samples/native)
 418     ocv_update(OPENCV_JAR_INSTALL_PATH java)
 419     ocv_update(OPENCV_OTHER_INSTALL_PATH   etc)
 420     ocv_update(OPENCV_CONFIG_INSTALL_PATH  ".")
 421   else()
 422     include(GNUInstallDirs)
 423     ocv_update(OPENCV_LIB_INSTALL_PATH     ${CMAKE_INSTALL_LIBDIR}${LIB_SUFFIX})
 424     ocv_update(OPENCV_3P_LIB_INSTALL_PATH  share/OpenCV/3rdparty/${OPENCV_LIB_INSTALL_PATH})
 425     ocv_update(OPENCV_SAMPLES_SRC_INSTALL_PATH    share/OpenCV/samples)
 426     ocv_update(OPENCV_JAR_INSTALL_PATH share/OpenCV/java)
 427     ocv_update(OPENCV_OTHER_INSTALL_PATH   share/OpenCV)
 428
 429     if(NOT DEFINED OPENCV_CONFIG_INSTALL_PATH)
 430       math(EXPR SIZEOF_VOID_P_BITS "8 * ${CMAKE_SIZEOF_VOID_P}")
 431       if(LIB_SUFFIX AND NOT SIZEOF_VOID_P_BITS EQUAL LIB_SUFFIX)
 432         ocv_update(OPENCV_CONFIG_INSTALL_PATH ${CMAKE_INSTALL_LIBDIR}${LIB_SUFFIX}/cmake/opencv)
 433       else()
 434         ocv_update(OPENCV_CONFIG_INSTALL_PATH share/OpenCV)
 435       endif()
 436     endif()
 437   endif()
 438   ocv_update(OPENCV_INCLUDE_INSTALL_PATH "include")
 439 endif()
 440
 441 ocv_update(CMAKE_INSTALL_RPATH "${CMAKE_INSTALL_PREFIX}/${OPENCV_LIB_INSTALL_PATH}")
 442 set(CMAKE_INSTALL_RPATH_USE_LINK_PATH TRUE)
 443
 444 if(INSTALL_TO_MANGLED_PATHS)
 445   set(OPENCV_INCLUDE_INSTALL_PATH ${OPENCV_INCLUDE_INSTALL_PATH}/opencv-${OPENCV_VERSION})
 446   foreach(v
 447       OPENCV_3P_LIB_INSTALL_PATH
 448       OPENCV_SAMPLES_SRC_INSTALL_PATH
 449       OPENCV_CONFIG_INSTALL_PATH
 450       OPENCV_DOC_INSTALL_PATH
 451       OPENCV_JAR_INSTALL_PATH
 452       OPENCV_TEST_DATA_INSTALL_PATH
 453       OPENCV_OTHER_INSTALL_PATH
 454     )
 455     string(REPLACE "OpenCV" "OpenCV-${OPENCV_VERSION}" ${v} "${${v}}")
 456     string(REPLACE "opencv" "opencv-${OPENCV_VERSION}" ${v} "${${v}}")
 457   endforeach()
 458 endif()
 459
 460
 461 if(WIN32)
 462   # Postfix of DLLs:
 463   set(OPENCV_DLLVERSION "${OPENCV_VERSION_MAJOR}${OPENCV_VERSION_MINOR}${OPENCV_VERSION_PATCH}")
 464   set(OPENCV_DEBUG_POSTFIX d)
 465 else()
 466   # Postfix of so's:
 467   set(OPENCV_DLLVERSION "")
 468   set(OPENCV_DEBUG_POSTFIX "")
 469 endif()
 470
 471 if(DEFINED CMAKE_DEBUG_POSTFIX)
 472   set(OPENCV_DEBUG_POSTFIX "${CMAKE_DEBUG_POSTFIX}")
 473 endif()
 474
 475 if((INSTALL_CREATE_DISTRIB AND BUILD_SHARED_LIBS AND NOT DEFINED BUILD_opencv_world) OR APPLE_FRAMEWORK)
 476   set(BUILD_opencv_world ON CACHE INTERNAL "")
 477 endif()
 478
 479 # ----------------------------------------------------------------------------
 480 #  Path for build/platform -specific headers
 481 # ----------------------------------------------------------------------------
 482 ocv_update(OPENCV_CONFIG_FILE_INCLUDE_DIR "${CMAKE_BINARY_DIR}/" CACHE PATH "Where to create the platform-dependant cvconfig.h")
 483 ocv_include_directories(${OPENCV_CONFIG_FILE_INCLUDE_DIR})
 484
 485 # ----------------------------------------------------------------------------
 486 #  Path for additional modules
 487 # ----------------------------------------------------------------------------
 488 set(OPENCV_EXTRA_MODULES_PATH "" CACHE PATH "Where to look for additional OpenCV modules")
 489
 490 # ----------------------------------------------------------------------------
 491 #  Autodetect if we are in a GIT repository
 492 # ----------------------------------------------------------------------------
 493 find_host_package(Git QUIET)
 494
 495 if(NOT DEFINED OPENCV_VCSVERSION AND GIT_FOUND)
 496   execute_process(COMMAND "${GIT_EXECUTABLE}" describe --tags --always --dirty --match "[0-9].[0-9].[0-9]*"
 497     WORKING_DIRECTORY "${OpenCV_SOURCE_DIR}"
 498     OUTPUT_VARIABLE OPENCV_VCSVERSION
 499     RESULT_VARIABLE GIT_RESULT
 500     ERROR_QUIET
 501     OUTPUT_STRIP_TRAILING_WHITESPACE
 502   )
 503   if(NOT GIT_RESULT EQUAL 0)
 504     set(OPENCV_VCSVERSION "unknown")
 505   endif()
 506 elseif(NOT DEFINED OPENCV_VCSVERSION)
 507   # We don't have git:
 508   set(OPENCV_VCSVERSION "unknown")
 509 endif()
 510
 511
 512 # ----------------------------------------------------------------------------
 513 # OpenCV compiler and linker options
 514 # ----------------------------------------------------------------------------
 515 # In case of Makefiles if the user does not setup CMAKE_BUILD_TYPE, assume it's Release:
 516 if(CMAKE_GENERATOR MATCHES "Makefiles|Ninja" AND "${CMAKE_BUILD_TYPE}" STREQUAL "")
 517   set(CMAKE_BUILD_TYPE Release)
 518 endif()
 519
 520 # --- Python Support ---
 521 if(NOT IOS)
 522   include(cmake/OpenCVDetectPython.cmake)
 523 endif()
 524
 525 include(cmake/OpenCVCompilerOptions.cmake)
 526
 527
 528 # ----------------------------------------------------------------------------
 529 # Use statically or dynamically linked CRT?
 530 # Default: dynamic
 531 # ----------------------------------------------------------------------------
 532 if(MSVC)
 533   include(cmake/OpenCVCRTLinkage.cmake)
 534 endif(MSVC)
 535
 536 if(WIN32 AND NOT MINGW)
 537   add_definitions(-D_VARIADIC_MAX=10)
 538 endif(WIN32 AND NOT MINGW)
 539
 540
 541 # ----------------------------------------------------------------------------
 542 #       CHECK FOR SYSTEM LIBRARIES, OPTIONS, ETC..
 543 # ----------------------------------------------------------------------------
 544 if(UNIX)
 545   if(NOT APPLE_FRAMEWORK)
 546     find_package(PkgConfig QUIET)
 547   endif()
 548   include(CheckFunctionExists)
 549   include(CheckIncludeFile)
 550   include(CheckSymbolExists)
 551
 552   if(NOT APPLE)
 553     CHECK_INCLUDE_FILE(pthread.h HAVE_PTHREAD)
 554     if(ANDROID)
 555       set(OPENCV_LINKER_LIBS ${OPENCV_LINKER_LIBS} dl m log)
 556     elseif(${CMAKE_SYSTEM_NAME} MATCHES "FreeBSD|NetBSD|DragonFly|OpenBSD|Haiku")
 557       set(OPENCV_LINKER_LIBS ${OPENCV_LINKER_LIBS} m pthread)
 558     elseif(EMSCRIPTEN)
 559       # no need to link to system libs with emscripten
 560     else()
 561       set(OPENCV_LINKER_LIBS ${OPENCV_LINKER_LIBS} dl m pthread rt)
 562     endif()
 563   else()
 564     set(HAVE_PTHREAD 1)
 565   endif()
 566
 567   CHECK_SYMBOL_EXISTS(posix_memalign stdlib.h HAVE_POSIX_MEMALIGN)
 568   CHECK_INCLUDE_FILE(malloc.h HAVE_MALLOC_H)
 569   if(HAVE_MALLOC_H)
 570     CHECK_SYMBOL_EXISTS(memalign malloc.h HAVE_MEMALIGN)
 571   endif()
 572 endif()
 573
 574 include(cmake/OpenCVPCHSupport.cmake)
 575 include(cmake/OpenCVModule.cmake)
 576
 577 # ----------------------------------------------------------------------------
 578 #  Detect endianness of build platform
 579 # ----------------------------------------------------------------------------
 580
 581 if(IOS)
 582   # test_big_endian needs try_compile, which doesn't work for iOS
 583   # http://public.kitware.com/Bug/view.php?id=12288
 584   set(WORDS_BIGENDIAN 0)
 585 else()
 586   include(TestBigEndian)
 587   test_big_endian(WORDS_BIGENDIAN)
 588 endif()
 589
 590 # ----------------------------------------------------------------------------
 591 #  Detect 3rd-party libraries
 592 # ----------------------------------------------------------------------------
 593
 594 if(ANDROID AND WITH_CPUFEATURES)
 595   add_subdirectory(3rdparty/cpufeatures)
 596   set(HAVE_CPUFEATURES 1)
 597 endif()
 598
 599 include(cmake/OpenCVFindLibsGrfmt.cmake)
 600 include(cmake/OpenCVFindLibsGUI.cmake)
 601 include(cmake/OpenCVFindLibsVideo.cmake)
 602 include(cmake/OpenCVFindLibsPerf.cmake)
 603 include(cmake/OpenCVFindLAPACK.cmake)
 604
 605 # ----------------------------------------------------------------------------
 606 #  Detect other 3rd-party libraries/tools
 607 # ----------------------------------------------------------------------------
 608
 609 # --- Doxygen for documentation ---
 610 if(BUILD_DOCS)
 611   find_package(Doxygen)
 612 else()
 613   unset(DOXYGEN_FOUND CACHE)
 614 endif()
 615
 616 # --- Java Support ---
 617 if(BUILD_JAVA)
 618   include(cmake/OpenCVDetectApacheAnt.cmake)
 619   if(ANDROID)
 620     include(cmake/OpenCVDetectAndroidSDK.cmake)
 621
 622     if(NOT ANDROID_TOOLS_Pkg_Revision GREATER 13)
 623       message(WARNING "OpenCV requires Android SDK tools revision 14 or newer. Otherwise tests and samples will no be compiled.")
 624     endif()
 625   else()
 626     find_package(JNI)
 627   endif()
 628 endif()
 629
 630 if(ENABLE_PYLINT)
 631   include(cmake/OpenCVPylint.cmake)
 632 endif()
 633
 634
 635 if(ANDROID AND ANDROID_EXECUTABLE AND ANT_EXECUTABLE AND (ANT_VERSION VERSION_GREATER 1.7) AND (ANDROID_TOOLS_Pkg_Revision GREATER 13))
 636   SET(CAN_BUILD_ANDROID_PROJECTS TRUE)
 637 else()
 638   SET(CAN_BUILD_ANDROID_PROJECTS FALSE)
 639 endif()
 640
 641 # --- OpenCL ---
 642 if(WITH_OPENCL)
 643   include(cmake/OpenCVDetectOpenCL.cmake)
 644 endif()
 645
 646 # --- Halide ---
 647 if(WITH_HALIDE)
 648   include(cmake/OpenCVDetectHalide.cmake)
 649 endif()
 650
 651 # --- DirectX ---
 652 if(WITH_DIRECTX)
 653   include(cmake/OpenCVDetectDirectX.cmake)
 654 endif()
 655
 656 # --- Matlab/Octave ---
 657 if(WITH_MATLAB)
 658   include(cmake/OpenCVFindMatlab.cmake)
 659 endif()
 660
 661 if(WITH_VTK)
 662   include(cmake/OpenCVDetectVTK.cmake)
 663 endif()
 664
 665 if(WITH_OPENVX)
 666   include(cmake/FindOpenVX.cmake)
 667 endif()
 668
 669 # ----------------------------------------------------------------------------
 670 # OpenCV HAL
 671 # ----------------------------------------------------------------------------
 672 set(_hal_includes "")
 673 macro(ocv_hal_register HAL_LIBRARIES_VAR HAL_HEADERS_VAR HAL_INCLUDE_DIRS_VAR)
 674   # 1. libraries
 675   foreach (l ${${HAL_LIBRARIES_VAR}})
 676     if(NOT TARGET ${l})
 677       get_filename_component(l "${l}" ABSOLUTE)
 678     endif()
 679     list(APPEND OPENCV_HAL_LINKER_LIBS ${l})
 680   endforeach()
 681   # 2. headers
 682   foreach (h ${${HAL_HEADERS_VAR}})
 683     set(_hal_includes "${_hal_includes}\n#include \"${h}\"")
 684   endforeach()
 685   # 3. include paths
 686   ocv_include_directories(${${HAL_INCLUDE_DIRS_VAR}})
 687 endmacro()
 688
 689 if(NOT DEFINED OpenCV_HAL)
 690   set(OpenCV_HAL "OpenCV_HAL")
 691 endif()
 692
 693 if(HAVE_OPENVX)
 694   if(NOT ";${OpenCV_HAL};" MATCHES ";openvx;")
 695     set(OpenCV_HAL "openvx;${OpenCV_HAL}")
 696   endif()
 697 endif()
 698
 699 if(WITH_CAROTENE)
 700   ocv_debug_message(STATUS "Enable carotene acceleration")
 701   if(NOT ";${OpenCV_HAL};" MATCHES ";carotene;")
 702     set(OpenCV_HAL "carotene;${OpenCV_HAL}")
 703   endif()
 704 endif()
 705
 706 foreach(hal ${OpenCV_HAL})
 707   if(hal STREQUAL "carotene")
 708     add_subdirectory(3rdparty/carotene/hal)
 709     ocv_hal_register(CAROTENE_HAL_LIBRARIES CAROTENE_HAL_HEADERS CAROTENE_HAL_INCLUDE_DIRS)
 710     list(APPEND OpenCV_USED_HAL "carotene (ver ${CAROTENE_HAL_VERSION})")
 711   elseif(hal STREQUAL "openvx")
 712     add_subdirectory(3rdparty/openvx)
 713     ocv_hal_register(OPENVX_HAL_LIBRARIES OPENVX_HAL_HEADERS OPENVX_HAL_INCLUDE_DIRS)
 714     list(APPEND OpenCV_USED_HAL "openvx (ver ${OPENVX_HAL_VERSION})")
 715   else()
 716     ocv_debug_message(STATUS "OpenCV HAL: ${hal} ...")
 717     ocv_clear_vars(OpenCV_HAL_LIBRARIES OpenCV_HAL_HEADERS OpenCV_HAL_INCLUDE_DIRS)
 718     find_package(${hal} NO_MODULE QUIET)
 719     if(${hal}_FOUND)
 720       ocv_hal_register(OpenCV_HAL_LIBRARIES OpenCV_HAL_HEADERS OpenCV_HAL_INCLUDE_DIRS)
 721       list(APPEND OpenCV_USED_HAL "${hal} (ver ${${hal}_VERSION})")
 722     endif()
 723   endif()
 724 endforeach()
 725 configure_file("${OpenCV_SOURCE_DIR}/cmake/templates/custom_hal.hpp.in" "${CMAKE_BINARY_DIR}/custom_hal.hpp" @ONLY)
 726 unset(_hal_includes)
 727
 728
 729 # ----------------------------------------------------------------------------
 730 # Add CUDA libraries (needed for apps/tools, samples)
 731 # ----------------------------------------------------------------------------
 732 if(HAVE_CUDA)
 733   set(OPENCV_LINKER_LIBS ${OPENCV_LINKER_LIBS} ${CUDA_LIBRARIES} ${CUDA_npp_LIBRARY})
 734   if(HAVE_CUBLAS)
 735     set(OPENCV_LINKER_LIBS ${OPENCV_LINKER_LIBS} ${CUDA_cublas_LIBRARY})
 736   endif()
 737   if(HAVE_CUFFT)
 738     set(OPENCV_LINKER_LIBS ${OPENCV_LINKER_LIBS} ${CUDA_cufft_LIBRARY})
 739   endif()
 740   foreach(p ${CUDA_LIBS_PATH})
 741     if(MSVC AND CMAKE_GENERATOR MATCHES "Ninja|JOM")
 742       set(OPENCV_LINKER_LIBS ${OPENCV_LINKER_LIBS} ${CMAKE_LIBRARY_PATH_FLAG}"${p}")
 743     else()
 744       set(OPENCV_LINKER_LIBS ${OPENCV_LINKER_LIBS} ${CMAKE_LIBRARY_PATH_FLAG}${p})
 745     endif()
 746   endforeach()
 747 endif()
 748
 749
 750 # ----------------------------------------------------------------------------
 751 # Code trace support
 752 # ----------------------------------------------------------------------------
 753 if(CV_TRACE)
 754   include(cmake/OpenCVDetectTrace.cmake)
 755 endif()
 756
 757
 758 # ----------------------------------------------------------------------------
 759 # Solution folders:
 760 # ----------------------------------------------------------------------------
 761 if(ENABLE_SOLUTION_FOLDERS)
 762   set_property(GLOBAL PROPERTY USE_FOLDERS ON)
 763   set_property(GLOBAL PROPERTY PREDEFINED_TARGETS_FOLDER "CMakeTargets")
 764 endif()
 765
 766 # Extra OpenCV targets: uninstall, package_source, perf, etc.
 767 include(cmake/OpenCVExtraTargets.cmake)
 768
 769 # ----------------------------------------------------------------------------
 770 # Process subdirectories
 771 # ----------------------------------------------------------------------------
 772
 773 # opencv.hpp and legacy headers
 774 add_subdirectory(include)
 775
 776 # OpenCV modules
 777 add_subdirectory(modules)
 778
 779 # Generate targets for documentation
 780 add_subdirectory(doc)
 781
 782 # various data that is used by cv libraries and/or demo applications.
 783 add_subdirectory(data)
 784
 785 # extra applications
 786 if(BUILD_opencv_apps)
 787   add_subdirectory(apps)
 788 endif()
 789
 790 # examples
 791 if(BUILD_EXAMPLES OR BUILD_ANDROID_EXAMPLES OR INSTALL_PYTHON_EXAMPLES)
 792   add_subdirectory(samples)
 793 endif()
 794
 795 if(ANDROID)
 796   add_subdirectory(platforms/android/service)
 797 endif()
 798
 799 # ----------------------------------------------------------------------------
 800 # Finalization: generate configuration-based files
 801 # ----------------------------------------------------------------------------
 802
 803 # Generate platform-dependent and configuration-dependent headers
 804 include(cmake/OpenCVGenHeaders.cmake)
 805
 806 # Generate opencv.pc for pkg-config command
 807 if(NOT OPENCV_SKIP_PKGCONFIG_GENERATION
 808     AND NOT CMAKE_GENERATOR MATCHES "Xcode")
 809   include(cmake/OpenCVGenPkgconfig.cmake)
 810 endif()
 811
 812 # Generate OpenCV.mk for ndk-build (Android build tool)
 813 include(cmake/OpenCVGenAndroidMK.cmake)
 814
 815 # Generate OpenCVConfig.cmake and OpenCVConfig-version.cmake for cmake projects
 816 include(cmake/OpenCVGenConfig.cmake)
 817
 818 # Generate Info.plist for the IOS framework
 819 if(APPLE_FRAMEWORK)
 820   include(cmake/OpenCVGenInfoPlist.cmake)
 821 endif()
 822
 823 # Generate ABI descriptor
 824 include(cmake/OpenCVGenABI.cmake)
 825
 826 # Generate environment setup file
 827 if(INSTALL_TESTS AND OPENCV_TEST_DATA_PATH)
 828   if(ANDROID)
 829     get_filename_component(TEST_PATH ${OPENCV_TEST_INSTALL_PATH} DIRECTORY)
 830     configure_file("${CMAKE_CURRENT_SOURCE_DIR}/cmake/templates/opencv_run_all_tests_android.sh.in"
 831                    "${CMAKE_BINARY_DIR}/unix-install/opencv_run_all_tests.sh" @ONLY)
 832     install(PROGRAMS "${CMAKE_BINARY_DIR}/unix-install/opencv_run_all_tests.sh"
 833             DESTINATION ./ COMPONENT tests)
 834   elseif(WIN32)
 835     configure_file("${CMAKE_CURRENT_SOURCE_DIR}/cmake/templates/opencv_run_all_tests_windows.cmd.in"
 836                    "${CMAKE_BINARY_DIR}/win-install/opencv_run_all_tests.cmd" @ONLY)
 837     install(PROGRAMS "${CMAKE_BINARY_DIR}/win-install/opencv_run_all_tests.cmd"
 838             DESTINATION ${OPENCV_TEST_INSTALL_PATH} COMPONENT tests)
 839   elseif(UNIX)
 840     configure_file("${CMAKE_CURRENT_SOURCE_DIR}/cmake/templates/opencv_run_all_tests_unix.sh.in"
 841                    "${CMAKE_BINARY_DIR}/unix-install/opencv_run_all_tests.sh" @ONLY)
 842     install(PROGRAMS "${CMAKE_BINARY_DIR}/unix-install/opencv_run_all_tests.sh"
 843             DESTINATION ${OPENCV_TEST_INSTALL_PATH} COMPONENT tests)
 844   endif()
 845 endif()
 846
 847 if(NOT OPENCV_README_FILE)
 848   if(ANDROID)
 849     set(OPENCV_README_FILE ${CMAKE_CURRENT_SOURCE_DIR}/platforms/android/README.android)
 850   endif()
 851 endif()
 852
 853 if(NOT OPENCV_LICENSE_FILE)
 854   set(OPENCV_LICENSE_FILE ${CMAKE_CURRENT_SOURCE_DIR}/LICENSE)
 855 endif()
 856
 857 # for UNIX it does not make sense as LICENSE and readme will be part of the package automatically
 858 if(ANDROID OR NOT UNIX)
 859   install(FILES ${OPENCV_LICENSE_FILE}
 860         PERMISSIONS OWNER_READ GROUP_READ WORLD_READ
 861         DESTINATION ./ COMPONENT libs)
 862   if(OPENCV_README_FILE)
 863     install(FILES ${OPENCV_README_FILE}
 864             PERMISSIONS OWNER_READ GROUP_READ WORLD_READ
 865             DESTINATION ./ COMPONENT libs)
 866   endif()
 867 endif()
 868
 869 if(COMMAND ocv_pylint_finalize)
 870   ocv_pylint_add_directory(${CMAKE_CURRENT_LIST_DIR}/modules/python/test)
 871   ocv_pylint_add_directory(${CMAKE_CURRENT_LIST_DIR}/samples/python)
 872   ocv_pylint_add_directory(${CMAKE_CURRENT_LIST_DIR}/samples/dnn)
 873   ocv_pylint_add_directory_recurse(${CMAKE_CURRENT_LIST_DIR}/samples/python/tutorial_code)
 874   ocv_pylint_finalize()
 875 endif()
 876
 877 # ----------------------------------------------------------------------------
 878 # Summary:
 879 # ----------------------------------------------------------------------------
 880 status("")
 881 status("General configuration for OpenCV ${OPENCV_VERSION} =====================================")
 882 if(OPENCV_VCSVERSION)
 883   status("  Version control:" ${OPENCV_VCSVERSION})
 884 endif()
 885 if(OPENCV_EXTRA_MODULES_PATH AND NOT BUILD_INFO_SKIP_EXTRA_MODULES)
 886   set(__dump_extra_header OFF)
 887   foreach(p ${OPENCV_EXTRA_MODULES_PATH})
 888     if(EXISTS ${p})
 889       if(NOT __dump_extra_header)
 890         set(__dump_extra_header ON)
 891         status("")
 892         status("  Extra modules:")
 893       else()
 894         status("")
 895       endif()
 896       set(EXTRA_MODULES_VCSVERSION "unknown")
 897       if(GIT_FOUND)
 898         execute_process(COMMAND "${GIT_EXECUTABLE}" describe --tags --always --dirty --match "[0-9].[0-9].[0-9]*"
 899           WORKING_DIRECTORY "${p}"
 900           OUTPUT_VARIABLE EXTRA_MODULES_VCSVERSION
 901           RESULT_VARIABLE GIT_RESULT
 902           ERROR_QUIET
 903           OUTPUT_STRIP_TRAILING_WHITESPACE
 904         )
 905         if(NOT GIT_RESULT EQUAL 0)
 906           set(EXTRA_MODULES_VCSVERSION "unknown")
 907         endif()
 908       endif()
 909       status("    Location (extra):" ${p})
 910       status("    Version control (extra):" ${EXTRA_MODULES_VCSVERSION})
 911     endif()
 912   endforeach()
 913   unset(__dump_extra_header)
 914 endif()
 915
 916 # ========================== build platform ==========================
 917 status("")
 918 status("  Platform:")
 919 if(NOT DEFINED OPENCV_TIMESTAMP
 920     AND NOT CMAKE_VERSION VERSION_LESS 2.8.11
 921     AND NOT BUILD_INFO_SKIP_TIMESTAMP
 922 )
 923   string(TIMESTAMP OPENCV_TIMESTAMP "" UTC)
 924   set(OPENCV_TIMESTAMP "${OPENCV_TIMESTAMP}" CACHE STRING "Timestamp of OpenCV build configuration" FORCE)
 925 endif()
 926 if(OPENCV_TIMESTAMP)
 927   status("    Timestamp:"      ${OPENCV_TIMESTAMP})
 928 endif()
 929 status("    Host:"             ${CMAKE_HOST_SYSTEM_NAME} ${CMAKE_HOST_SYSTEM_VERSION} ${CMAKE_HOST_SYSTEM_PROCESSOR})
 930 if(CMAKE_CROSSCOMPILING)
 931   status("    Target:"         ${CMAKE_SYSTEM_NAME} ${CMAKE_SYSTEM_VERSION} ${CMAKE_SYSTEM_PROCESSOR})
 932 endif()
 933 status("    CMake:"            ${CMAKE_VERSION})
 934 status("    CMake generator:"  ${CMAKE_GENERATOR})
 935 status("    CMake build tool:" ${CMAKE_BUILD_TOOL})
 936 if(MSVC)
 937   status("    MSVC:"           ${MSVC_VERSION})
 938 endif()
 939 if(CMAKE_GENERATOR MATCHES Xcode)
 940   status("    Xcode:"          ${XCODE_VERSION})
 941 endif()
 942 if(NOT CMAKE_GENERATOR MATCHES "Xcode|Visual Studio")
 943   status("    Configuration:"  ${CMAKE_BUILD_TYPE})
 944 endif()
 945
 946
 947 # ========================= CPU code generation mode =========================
 948 status("")
 949 status("  CPU/HW features:")
 950 status("    Baseline:"  "${CPU_BASELINE_FINAL}")
 951 if(NOT CPU_BASELINE STREQUAL CPU_BASELINE_FINAL)
 952   status("      requested:"  "${CPU_BASELINE}")
 953 endif()
 954 if(CPU_BASELINE_REQUIRE)
 955   status("      required:"  "${CPU_BASELINE_REQUIRE}")
 956 endif()
 957 if(CPU_BASELINE_DISABLE)
 958   status("      disabled:"  "${CPU_BASELINE_DISABLE}")
 959 endif()
 960 if(CPU_DISPATCH_FINAL OR CPU_DISPATCH)
 961   status("    Dispatched code generation:"  "${CPU_DISPATCH_FINAL}")
 962   if(NOT CPU_DISPATCH STREQUAL CPU_DISPATCH_FINAL)
 963     status("      requested:"  "${CPU_DISPATCH}")
 964   endif()
 965   if(CPU_DISPATCH_REQUIRE)
 966     status("      required:"  "${CPU_DISPATCH_REQUIRE}")
 967   endif()
 968   foreach(OPT ${CPU_DISPATCH_FINAL})
 969     status("      ${OPT} (${CPU_${OPT}_USAGE_COUNT} files):"  "+ ${CPU_DISPATCH_${OPT}_INCLUDED}")
 970   endforeach()
 971 endif()
 972
 973 # ========================== C/C++ options ==========================
 974 if(CMAKE_CXX_COMPILER_VERSION)
 975   set(OPENCV_COMPILER_STR "${CMAKE_CXX_COMPILER} ${CMAKE_CXX_COMPILER_ARG1} (ver ${CMAKE_CXX_COMPILER_VERSION})")
 976 else()
 977   set(OPENCV_COMPILER_STR "${CMAKE_CXX_COMPILER} ${CMAKE_CXX_COMPILER_ARG1}")
 978 endif()
 979 string(STRIP "${OPENCV_COMPILER_STR}" OPENCV_COMPILER_STR)
 980
 981 status("")
 982 status("  C/C++:")
 983 status("    Built as dynamic libs?:" BUILD_SHARED_LIBS THEN YES ELSE NO)
 984 if(ENABLE_CXX11 OR HAVE_CXX11)
 985 status("    C++11:" HAVE_CXX11 THEN YES ELSE NO)
 986 endif()
 987 status("    C++ Compiler:"           ${OPENCV_COMPILER_STR})
 988 status("    C++ flags (Release):"    ${CMAKE_CXX_FLAGS} ${CMAKE_CXX_FLAGS_RELEASE})
 989 status("    C++ flags (Debug):"      ${CMAKE_CXX_FLAGS} ${CMAKE_CXX_FLAGS_DEBUG})
 990 status("    C Compiler:"             ${CMAKE_C_COMPILER} ${CMAKE_C_COMPILER_ARG1})
 991 status("    C flags (Release):"      ${CMAKE_C_FLAGS} ${CMAKE_C_FLAGS_RELEASE})
 992 status("    C flags (Debug):"        ${CMAKE_C_FLAGS} ${CMAKE_C_FLAGS_DEBUG})
 993 if(WIN32)
 994   status("    Linker flags (Release):" ${CMAKE_EXE_LINKER_FLAGS} ${CMAKE_EXE_LINKER_FLAGS_RELEASE})
 995   status("    Linker flags (Debug):"   ${CMAKE_EXE_LINKER_FLAGS} ${CMAKE_EXE_LINKER_FLAGS_DEBUG})
 996 else()
 997   status("    Linker flags (Release):" ${CMAKE_SHARED_LINKER_FLAGS} ${CMAKE_SHARED_LINKER_FLAGS_RELEASE})
 998   status("    Linker flags (Debug):"   ${CMAKE_SHARED_LINKER_FLAGS} ${CMAKE_SHARED_LINKER_FLAGS_DEBUG})
 999 endif()
1000 status("    ccache:"                  CMAKE_COMPILER_IS_CCACHE THEN YES ELSE NO)
1001 status("    Precompiled headers:"     PCHSupport_FOUND AND ENABLE_PRECOMPILED_HEADERS THEN YES ELSE NO)
1002
1003 # ========================== Dependencies ============================
1004 ocv_get_all_libs(deps_modules deps_extra deps_3rdparty)
1005 status("    Extra dependencies:" ${deps_extra})
1006 status("    3rdparty dependencies:" ${deps_3rdparty})
1007
1008 # ========================== OpenCV modules ==========================
1009 status("")
1010 status("  OpenCV modules:")
1011 string(REPLACE "opencv_" "" OPENCV_MODULES_BUILD_ST          "${OPENCV_MODULES_BUILD}")
1012 string(REPLACE "opencv_" "" OPENCV_MODULES_DISABLED_USER_ST  "${OPENCV_MODULES_DISABLED_USER}")
1013 string(REPLACE "opencv_" "" OPENCV_MODULES_DISABLED_AUTO_ST  "${OPENCV_MODULES_DISABLED_AUTO}")
1014 string(REPLACE "opencv_" "" OPENCV_MODULES_DISABLED_FORCE_ST "${OPENCV_MODULES_DISABLED_FORCE}")
1015 list(SORT OPENCV_MODULES_BUILD_ST)
1016 list(SORT OPENCV_MODULES_DISABLED_USER_ST)
1017 list(SORT OPENCV_MODULES_DISABLED_AUTO_ST)
1018 list(SORT OPENCV_MODULES_DISABLED_FORCE_ST)
1019 status("    To be built:"            OPENCV_MODULES_BUILD          THEN ${OPENCV_MODULES_BUILD_ST}          ELSE "-")
1020 status("    Disabled:"               OPENCV_MODULES_DISABLED_USER  THEN ${OPENCV_MODULES_DISABLED_USER_ST}  ELSE "-")
1021 status("    Disabled by dependency:" OPENCV_MODULES_DISABLED_AUTO  THEN ${OPENCV_MODULES_DISABLED_AUTO_ST}  ELSE "-")
1022 status("    Unavailable:"            OPENCV_MODULES_DISABLED_FORCE THEN ${OPENCV_MODULES_DISABLED_FORCE_ST} ELSE "-")
1023
1024 ocv_build_features_string(apps_status
1025   IF BUILD_TESTS AND HAVE_opencv_ts THEN "tests"
1026   IF BUILD_PERF_TESTS AND HAVE_opencv_ts THEN "perf_tests"
1027   IF BUILD_EXAMPLES THEN "examples"
1028   IF BUILD_opencv_apps THEN "apps"
1029   IF BUILD_ANDROID_SERVICE THEN "android_service"
1030   IF BUILD_ANDROID_EXAMPLES AND CAN_BUILD_ANDROID_PROJECTS THEN "android_examples"
1031   ELSE "-")
1032 status("    Applications:" "${apps_status}")
1033 status("    Documentation:" BUILD_DOCS AND DOXYGEN_FOUND THEN "YES (${DOXYGEN_EXECUTABLE} ${DOXYGEN_VERSION})" ELSE "NO")
1034 status("    Non-free algorithms:" OPENCV_ENABLE_NONFREE THEN "YES" ELSE "NO")
1035
1036 # ========================== Android details ==========================
1037 if(ANDROID)
1038   status("")
1039   status("  Android: ")
1040   status("    Android ABI:" ${ANDROID_ABI})
1041   status("    STL type:" ${ANDROID_STL})
1042   status("    Native API level:" android-${ANDROID_NATIVE_API_LEVEL})
1043   android_get_compatible_target(android_sdk_target_status ${ANDROID_NATIVE_API_LEVEL} ${ANDROID_SDK_TARGET} 11)
1044   status("    SDK target:" "${android_sdk_target_status}")
1045   if(BUILD_WITH_ANDROID_NDK)
1046     status("    Android NDK:" "${ANDROID_NDK} (toolchain: ${ANDROID_TOOLCHAIN_NAME})")
1047   elseif(BUILD_WITH_STANDALONE_TOOLCHAIN)
1048     status("    Android toolchain:" "${ANDROID_STANDALONE_TOOLCHAIN}")
1049   endif()
1050   status("    android tool:"  ANDROID_EXECUTABLE  THEN "${ANDROID_EXECUTABLE} (${ANDROID_TOOLS_Pkg_Desc})" ELSE NO)
1051 endif()
1052
1053 # ================== Windows RT features ==================
1054 if(WIN32)
1055 status("")
1056 status("  Windows RT support:" WINRT THEN YES ELSE NO)
1057   if(WINRT)
1058     status("    Building for Microsoft platform: " ${CMAKE_SYSTEM_NAME})
1059     status("    Building for architectures: " ${CMAKE_VS_EFFECTIVE_PLATFORMS})
1060     status("    Building for version: " ${CMAKE_SYSTEM_VERSION})
1061     if (DEFINED ENABLE_WINRT_MODE_NATIVE)
1062       status("    Building for C++ without CX extensions")
1063     endif()
1064   endif()
1065 endif(WIN32)
1066
1067 # ========================== GUI ==========================
1068 status("")
1069 status("  GUI: ")
1070
1071 if(WITH_QT OR HAVE_QT)
1072   if(HAVE_QT5)
1073     status("    QT:" "YES (ver ${Qt5Core_VERSION_STRING})")
1074     status("      QT OpenGL support:" HAVE_QT_OPENGL THEN "YES (${Qt5OpenGL_LIBRARIES} ${Qt5OpenGL_VERSION_STRING})" ELSE NO)
1075   elseif(HAVE_QT)
1076     status("    QT:" "YES (ver ${QT_VERSION_MAJOR}.${QT_VERSION_MINOR}.${QT_VERSION_PATCH} ${QT_EDITION})")
1077     status("      QT OpenGL support:" HAVE_QT_OPENGL THEN "YES (${QT_QTOPENGL_LIBRARY})" ELSE NO)
1078   else()
1079     status("    QT:" "NO")
1080   endif()
1081 endif()
1082
1083 if(WITH_WIN32UI)
1084   status("    Win32 UI:" HAVE_WIN32UI THEN YES ELSE NO)
1085 endif()
1086
1087 if(APPLE)
1088   if(WITH_CARBON)
1089     status("    Carbon:" YES)
1090   else()
1091     status("    Cocoa:"  YES)
1092   endif()
1093 endif()
1094
1095 if(WITH_GTK OR HAVE_GTK)
1096   if(HAVE_GTK3)
1097     status("    GTK+:" "YES (ver ${ALIASOF_gtk+-3.0_VERSION})")
1098   elseif(HAVE_GTK)
1099     status("    GTK+:" "YES (ver ${ALIASOF_gtk+-2.0_VERSION})")
1100   else()
1101     status("    GTK+:" "NO")
1102   endif()
1103   if(HAVE_GTK)
1104     status(  "      GThread :" HAVE_GTHREAD THEN "YES (ver ${ALIASOF_gthread-2.0_VERSION})" ELSE NO)
1105     status(  "      GtkGlExt:" HAVE_GTKGLEXT THEN "YES (ver ${ALIASOF_gtkglext-1.0_VERSION})" ELSE NO)
1106   endif()
1107 endif()
1108
1109 if(WITH_OPENGL OR HAVE_OPENGL)
1110   status("    OpenGL support:" HAVE_OPENGL THEN "YES (${OPENGL_LIBRARIES})" ELSE NO)
1111 endif()
1112
1113 if(WITH_VTK OR HAVE_VTK)
1114   status("    VTK support:" HAVE_VTK THEN "YES (ver ${VTK_VERSION})" ELSE NO)
1115 endif()
1116
1117 # ========================== MEDIA IO ==========================
1118 status("")
1119 status("  Media I/O: ")
1120 status("    ZLib:"   ZLIB_FOUND THEN "${ZLIB_LIBRARIES} (ver ${ZLIB_VERSION_STRING})" ELSE "build (ver ${ZLIB_VERSION_STRING})")
1121
1122 if(WITH_JPEG OR HAVE_JPEG)
1123   status("    JPEG:" JPEG_FOUND THEN "${JPEG_LIBRARY} (ver ${JPEG_LIB_VERSION})" ELSE "build (ver ${JPEG_LIB_VERSION})")
1124 endif()
1125
1126 if(WITH_WEBP OR HAVE_WEBP)
1127   status("    WEBP:" WEBP_FOUND THEN "${WEBP_LIBRARY} (ver ${WEBP_VERSION})" ELSE "build (ver ${WEBP_VERSION})")
1128 endif()
1129
1130 if(WITH_PNG OR HAVE_PNG)
1131   status("    PNG:"  PNG_FOUND  THEN "${PNG_LIBRARY} (ver ${PNG_VERSION})" ELSE "build (ver ${PNG_VERSION})")
1132 endif()
1133
1134 if(WITH_TIFF OR HAVE_TIFF)
1135   status("    TIFF:" TIFF_FOUND THEN "${TIFF_LIBRARY} (ver ${TIFF_VERSION} / ${TIFF_VERSION_STRING})" ELSE "build (ver ${TIFF_VERSION} - ${TIFF_VERSION_STRING})")
1136 endif()
1137
1138 if(WITH_JASPER OR HAVE_JASPER)
1139   status("    JPEG 2000:" JASPER_FOUND THEN "${JASPER_LIBRARY} (ver ${JASPER_VERSION_STRING})" ELSE "build (ver ${JASPER_VERSION_STRING})")
1140 endif()
1141
1142 if(WITH_OPENEXR OR HAVE_OPENEXR)
1143   status("    OpenEXR:" OPENEXR_FOUND THEN "${OPENEXR_LIBRARIES} (ver ${OPENEXR_VERSION})" ELSE "build (ver ${OPENEXR_VERSION})")
1144 endif()
1145
1146 if(WITH_GDAL OR HAVE_GDAL)
1147   status("    GDAL:" HAVE_GDAL THEN "YES (${GDAL_LIBRARY})" ELSE "NO")
1148 endif()
1149
1150 if(WITH_GDCM OR HAVE_GDCM)
1151   status("    GDCM:" HAVE_GDCM THEN "YES (ver ${GDCM_VERSION})" ELSE "NO")
1152 endif()
1153
1154 # ========================== VIDEO IO ==========================
1155 status("")
1156 status("  Video I/O:")
1157
1158 if(WITH_VFW OR HAVE_VFW)
1159   status("    Video for Windows:" HAVE_VFW         THEN YES                                        ELSE NO)
1160 endif()
1161
1162 if(WITH_1394 OR HAVE_DC1394)
1163   if (HAVE_DC1394_2)
1164     status("    DC1394:" "YES (ver ${ALIASOF_libdc1394-2_VERSION})")
1165   elseif (HAVE_DC1394)
1166     status("    DC1394:" "YES (ver ${ALIASOF_libdc1394_VERSION})")
1167   else()
1168     status("    DC1394:" "NO")
1169   endif()
1170 endif()
1171
1172 if(WITH_FFMPEG OR HAVE_FFMPEG)
1173   if(WIN32)
1174     status("    FFMPEG:"       HAVE_FFMPEG         THEN "YES (prebuilt binaries)"                  ELSE NO)
1175   else()
1176     status("    FFMPEG:"       HAVE_FFMPEG         THEN YES ELSE NO)
1177   endif()
1178   status("      avcodec:"      FFMPEG_libavcodec_FOUND    THEN "YES (ver ${FFMPEG_libavcodec_VERSION})"    ELSE NO)
1179   status("      avformat:"     FFMPEG_libavformat_FOUND   THEN "YES (ver ${FFMPEG_libavformat_VERSION})"   ELSE NO)
1180   status("      avutil:"       FFMPEG_libavutil_FOUND     THEN "YES (ver ${FFMPEG_libavutil_VERSION})"     ELSE NO)
1181   status("      swscale:"      FFMPEG_libswscale_FOUND    THEN "YES (ver ${FFMPEG_libswscale_VERSION})"    ELSE NO)
1182   status("      avresample:"   FFMPEG_libavresample_FOUND THEN "YES (ver ${FFMPEG_libavresample_VERSION})" ELSE NO)
1183 endif()
1184
1185 if(WITH_GSTREAMER OR HAVE_GSTREAMER)
1186   status("    GStreamer:"      HAVE_GSTREAMER      THEN ""                                         ELSE NO)
1187   if(HAVE_GSTREAMER)
1188     status("      base:"       "YES (ver ${GSTREAMER_BASE_VERSION})")
1189     status("      video:"      "YES (ver ${GSTREAMER_VIDEO_VERSION})")
1190     status("      app:"        "YES (ver ${GSTREAMER_APP_VERSION})")
1191     status("      riff:"       "YES (ver ${GSTREAMER_RIFF_VERSION})")
1192     status("      pbutils:"    "YES (ver ${GSTREAMER_PBUTILS_VERSION})")
1193   endif(HAVE_GSTREAMER)
1194 endif()
1195
1196 if(WITH_OPENNI OR HAVE_OPENNI)
1197   status("    OpenNI:"         HAVE_OPENNI         THEN "YES (ver ${OPENNI_VERSION_STRING}, build ${OPENNI_VERSION_BUILD})" ELSE NO)
1198   status("    OpenNI PrimeSensor Modules:" HAVE_OPENNI_PRIME_SENSOR_MODULE THEN "YES (${OPENNI_PRIME_SENSOR_MODULE})"      ELSE NO)
1199 endif()
1200
1201 if(WITH_OPENNI2 OR HAVE_OPENNI2)
1202   status("    OpenNI2:"        HAVE_OPENNI2    THEN "YES (ver ${OPENNI2_VERSION_STRING}, build ${OPENNI2_VERSION_BUILD})" ELSE NO)
1203 endif()
1204
1205 if(WITH_PVAPI OR HAVE_PVAPI)
1206   status("    PvAPI:"          HAVE_PVAPI          THEN YES                                        ELSE NO)
1207 endif()
1208
1209 if(WITH_GIGEAPI OR HAVE_GIGE_API)
1210   status("    GigEVisionSDK:"  HAVE_GIGE_API       THEN YES                                        ELSE NO)
1211 endif()
1212
1213 if(WITH_ARAVIS OR HAVE_ARAVIS_API)
1214   status("    Aravis SDK:"     HAVE_ARAVIS_API     THEN "YES (${ARAVIS_LIBRARIES})"                ELSE NO)
1215 endif()
1216
1217 if(APPLE)
1218   status("    AVFoundation:"   HAVE_AVFOUNDATION   THEN YES                                        ELSE NO)
1219   if(WITH_QUICKTIME OR HAVE_QUICKTIME)
1220     status("    QuickTime:"      HAVE_QUICKTIME      THEN YES                                        ELSE NO)
1221   endif()
1222   if(WITH_QTKIT OR HAVE_QTKIT)
1223     status("    QTKit:"          HAVE_QTKIT          THEN "YES (deprecated)"                         ELSE NO)
1224   endif()
1225 endif()
1226
1227 if(WITH_UNICAP OR HAVE_UNICAP)
1228   status("    UniCap:"         HAVE_UNICAP         THEN "YES (ver ${ALIASOF_libunicap_VERSION})"   ELSE NO)
1229   status("    UniCap ucil:"    HAVE_UNICAP_UCIL    THEN "YES (ver ${ALIASOF_libucil_VERSION})"     ELSE NO)
1230 endif()
1231
1232 if(WITH_V4L OR WITH_LIBV4L OR HAVE_LIBV4L OR HAVE_CAMV4L OR HAVE_CAMV4L2 OR HAVE_VIDEOIO)
1233   status("    libv4l/libv4l2:" HAVE_LIBV4L THEN "${ALIASOF_libv4l1_VERSION} / ${ALIASOF_libv4l2_VERSION}" ELSE "NO")
1234   ocv_build_features_string(v4l_status
1235     IF HAVE_CAMV4L THEN "linux/videodev.h"
1236     IF HAVE_CAMV4L2 THEN "linux/videodev2.h"
1237     IF HAVE_VIDEOIO THEN "sys/videoio.h"
1238     ELSE "NO")
1239   status("    v4l/v4l2:" "${v4l_status}")
1240 endif()
1241
1242 if(WITH_DSHOW OR HAVE_DSHOW)
1243   status("    DirectShow:"     HAVE_DSHOW     THEN YES                                        ELSE NO)
1244 endif()
1245
1246 if(WITH_MSMF OR HAVE_MSMF)
1247   status("    Media Foundation:" HAVE_MSMF    THEN YES                                        ELSE NO)
1248 endif()
1249
1250 if(WITH_XIMEA OR HAVE_XIMEA)
1251   status("    XIMEA:"          HAVE_XIMEA          THEN YES                                        ELSE NO)
1252 endif()
1253
1254 if(WITH_XINE OR HAVE_XINE)
1255   status("    Xine:"           HAVE_XINE           THEN "YES (ver ${ALIASOF_libxine_VERSION})"     ELSE NO)
1256 endif()
1257
1258 if(WITH_INTELPERC OR HAVE_INTELPERC)
1259   status("    Intel PerC:"     HAVE_INTELPERC      THEN "YES"                                 ELSE NO)
1260 endif()
1261
1262 if(WITH_MFX OR HAVE_MFX)
1263   status("    Intel Media SDK:" HAVE_MFX      THEN "YES (${MFX_LIBRARY})" ELSE NO)
1264 endif()
1265
1266 if(WITH_GPHOTO2 OR HAVE_GPHOTO2)
1267   status("    gPhoto2:"        HAVE_GPHOTO2        THEN "YES"                                 ELSE NO)
1268 endif()
1269
1270 # Order is similar to CV_PARALLEL_FRAMEWORK in core/src/parallel.cpp
1271 ocv_build_features_string(parallel_status EXCLUSIVE
1272   IF HAVE_TBB THEN "TBB (ver ${TBB_VERSION_MAJOR}.${TBB_VERSION_MINOR} interface ${TBB_INTERFACE_VERSION})"
1273   IF HAVE_CSTRIPES THEN "C="
1274   IF HAVE_OPENMP THEN "OpenMP"
1275   IF HAVE_GCD THEN "GCD"
1276   IF WINRT OR HAVE_CONCURRENCY THEN "Concurrency"
1277   IF HAVE_PTHREADS_PF THEN "pthreads"
1278   ELSE "none")
1279 status("")
1280 status("  Parallel framework:" "${parallel_status}")
1281
1282 if(CV_TRACE OR OPENCV_TRACE)
1283   ocv_build_features_string(trace_status EXCLUSIVE
1284     IF HAVE_ITT THEN "with Intel ITT"
1285     ELSE "built-in")
1286   status("")
1287   status("  Trace: " OPENCV_TRACE THEN "YES (${trace_status})" ELSE NO)
1288 endif()
1289
1290 # ========================== Other third-party libraries ==========================
1291 status("")
1292 status("  Other third-party libraries:")
1293
1294 if(WITH_IPP AND HAVE_IPP)
1295   status("    Intel IPP:" "${IPP_VERSION_STR} [${IPP_VERSION_MAJOR}.${IPP_VERSION_MINOR}.${IPP_VERSION_BUILD}]")
1296   status("           at:" "${IPP_ROOT_DIR}")
1297   if(NOT HAVE_IPP_ICV)
1298     status("       linked:" BUILD_WITH_DYNAMIC_IPP THEN "dynamic" ELSE "static")
1299   endif()
1300   if(HAVE_IPP_IW)
1301     if(BUILD_IPP_IW)
1302       status("    Intel IPP IW:" "sources (${IW_VERSION_MAJOR}.${IW_VERSION_MINOR}.${IW_VERSION_UPDATE})")
1303     else()
1304       status("    Intel IPP IW:" "binaries (${IW_VERSION_MAJOR}.${IW_VERSION_MINOR}.${IW_VERSION_UPDATE})")
1305     endif()
1306     status("              at:" "${IPP_IW_PATH}")
1307   else()
1308     status("    Intel IPP IW:"   NO)
1309   endif()
1310 endif()
1311
1312 if(WITH_VA OR HAVE_VA)
1313   status("    VA:"            HAVE_VA          THEN "YES" ELSE NO)
1314 endif()
1315
1316 if(WITH_VA_INTEL OR HAVE_VA_INTEL)
1317   status("    Intel VA-API/OpenCL:"  HAVE_VA_INTEL       THEN "YES (MSDK: ${VA_INTEL_MSDK_ROOT}  OpenCL: ${VA_INTEL_IOCL_ROOT})" ELSE NO)
1318 endif()
1319
1320 if(WITH_LAPACK OR HAVE_LAPACK)
1321   status("    Lapack:"      HAVE_LAPACK     THEN "YES (${LAPACK_LIBRARIES})" ELSE NO)
1322 endif()
1323
1324 if(WITH_HALIDE OR HAVE_HALIDE)
1325   status("    Halide:"     HAVE_HALIDE      THEN "YES (${HALIDE_LIBRARIES} ${HALIDE_INCLUDE_DIRS})" ELSE NO)
1326 endif()
1327
1328 if(WITH_EIGEN OR HAVE_EIGEN)
1329   status("    Eigen:"      HAVE_EIGEN       THEN "YES (ver ${EIGEN_WORLD_VERSION}.${EIGEN_MAJOR_VERSION}.${EIGEN_MINOR_VERSION})" ELSE NO)
1330 endif()
1331
1332 if(WITH_OPENVX OR HAVE_OPENVX)
1333   status("    OpenVX:"     HAVE_OPENVX      THEN "YES (${OPENVX_LIBRARIES})" ELSE "NO")
1334 endif()
1335
1336 status("    Custom HAL:" OpenCV_USED_HAL  THEN "YES (${OpenCV_USED_HAL})" ELSE "NO")
1337
1338 if(WITH_CUDA OR HAVE_CUDA)
1339   ocv_build_features_string(cuda_features
1340     IF HAVE_CUFFT THEN "CUFFT"
1341     IF HAVE_CUBLAS THEN "CUBLAS"
1342     IF HAVE_NVCUVID THEN "NVCUVID"
1343     IF CUDA_FAST_MATH THEN "FAST_MATH"
1344     ELSE "no extra features")
1345   status("")
1346   status("  NVIDIA CUDA:" HAVE_CUDA THEN "YES (ver ${CUDA_VERSION_STRING}, ${cuda_features})" ELSE NO)
1347   if(HAVE_CUDA)
1348     status("    NVIDIA GPU arch:"      ${OPENCV_CUDA_ARCH_BIN})
1349     status("    NVIDIA PTX archs:"     ${OPENCV_CUDA_ARCH_PTX})
1350   endif()
1351 endif()
1352
1353 if(WITH_OPENCL OR HAVE_OPENCL)
1354   ocv_build_features_string(opencl_features
1355     IF HAVE_OPENCL_SVM THEN "SVM"
1356     IF HAVE_CLAMDFFT THEN "AMDFFT"
1357     IF HAVE_CLAMDBLAS THEN "AMDBLAS"
1358     ELSE "no extra features")
1359   status("")
1360   status("  OpenCL:"     HAVE_OPENCL   THEN   "YES (${opencl_features})" ELSE "NO")
1361   if(HAVE_OPENCL)
1362     status("    Include path:"  OPENCL_INCLUDE_DIRS THEN "${OPENCL_INCLUDE_DIRS}" ELSE "NO")
1363     status("    Link libraries:"       OPENCL_LIBRARIES THEN "${OPENCL_LIBRARIES}" ELSE "Dynamic load")
1364   endif()
1365 endif()
1366
1367 # ========================== python ==========================
1368 if(BUILD_opencv_python2)
1369   status("")
1370   status("  Python 2:")
1371   status("    Interpreter:"     PYTHON2INTERP_FOUND  THEN "${PYTHON2_EXECUTABLE} (ver ${PYTHON2_VERSION_STRING})"       ELSE NO)
1372   if(PYTHON2LIBS_VERSION_STRING)
1373     status("    Libraries:"   HAVE_opencv_python2  THEN  "${PYTHON2_LIBRARIES} (ver ${PYTHON2LIBS_VERSION_STRING})"   ELSE NO)
1374   else()
1375     status("    Libraries:"   HAVE_opencv_python2  THEN  "${PYTHON2_LIBRARIES}"                                      ELSE NO)
1376   endif()
1377   status("    numpy:"         PYTHON2_NUMPY_INCLUDE_DIRS THEN "${PYTHON2_NUMPY_INCLUDE_DIRS} (ver ${PYTHON2_NUMPY_VERSION})" ELSE "NO (Python wrappers can not be generated)")
1378   status("    packages path:" PYTHON2_EXECUTABLE         THEN "${PYTHON2_PACKAGES_PATH}"                                    ELSE "-")
1379 endif()
1380
1381 if(BUILD_opencv_python3)
1382   status("")
1383   status("  Python 3:")
1384   status("    Interpreter:"     PYTHON3INTERP_FOUND  THEN "${PYTHON3_EXECUTABLE} (ver ${PYTHON3_VERSION_STRING})"       ELSE NO)
1385   if(PYTHON3LIBS_VERSION_STRING)
1386     status("    Libraries:"   HAVE_opencv_python3  THEN  "${PYTHON3_LIBRARIES} (ver ${PYTHON3LIBS_VERSION_STRING})"   ELSE NO)
1387   else()
1388     status("    Libraries:"   HAVE_opencv_python3  THEN  "${PYTHON3_LIBRARIES}"                                      ELSE NO)
1389   endif()
1390   status("    numpy:"         PYTHON3_NUMPY_INCLUDE_DIRS THEN "${PYTHON3_NUMPY_INCLUDE_DIRS} (ver ${PYTHON3_NUMPY_VERSION})" ELSE "NO (Python3 wrappers can not be generated)")
1391   status("    packages path:" PYTHON3_EXECUTABLE         THEN "${PYTHON3_PACKAGES_PATH}"                                    ELSE "-")
1392 endif()
1393
1394 status("")
1395 status("  Python (for build):"  PYTHON_DEFAULT_AVAILABLE THEN "${PYTHON_DEFAULT_EXECUTABLE}" ELSE NO)
1396 if(PYLINT_FOUND AND PYLINT_EXECUTABLE)
1397   status("    Pylint:"  PYLINT_FOUND THEN "${PYLINT_EXECUTABLE} (ver: ${PYLINT_VERSION}, checks: ${PYLINT_TOTAL_TARGETS})" ELSE NO)
1398 endif()
1399
1400 # ========================== java ==========================
1401 if(BUILD_JAVA OR BUILD_opencv_java)
1402   status("")
1403   status("  Java:")
1404   status("    ant:"           ANT_EXECUTABLE      THEN "${ANT_EXECUTABLE} (ver ${ANT_VERSION})"                    ELSE NO)
1405   if(NOT ANDROID)
1406     status("    JNI:"         JNI_INCLUDE_DIRS    THEN "${JNI_INCLUDE_DIRS}"                                       ELSE NO)
1407   endif()
1408   status("    Java wrappers:" HAVE_opencv_java                                                            THEN YES ELSE NO)
1409   status("    Java tests:"    BUILD_TESTS AND opencv_test_java_BINARY_DIR                                 THEN YES ELSE NO)
1410 endif()
1411
1412 # ========================= matlab =========================
1413 if(WITH_MATLAB OR MATLAB_FOUND)
1414   status("")
1415   status("  Matlab:" MATLAB_FOUND THEN "YES" ELSE "NO")
1416   if(MATLAB_FOUND)
1417     status("    mex:"         MATLAB_MEX_SCRIPT  THEN  "${MATLAB_MEX_SCRIPT}"   ELSE NO)
1418     status("    Compiler/generator:" MEX_WORKS   THEN  "Working"                ELSE "Not working (bindings will not be generated)")
1419   endif()
1420 endif()
1421
1422 # ========================== auxiliary ==========================
1423 status("")
1424 status("  Install to:" "${CMAKE_INSTALL_PREFIX}")
1425 status("-----------------------------------------------------------------")
1426 status("")
1427
1428
1429 ocv_finalize_status()
1430
1431 # ----------------------------------------------------------------------------
1432 # CPack stuff
1433 # ----------------------------------------------------------------------------
1434
1435 include(cmake/OpenCVPackaging.cmake)
1436
1437 # This should be the last command
1438 ocv_cmake_dump_vars("" TOFILE "CMakeVars.txt")
1439 ocv_cmake_eval(DEBUG_POST ONCE)