CMakeLists.txt

   1 # Copyright (C) 2018-2020 Intel Corporation
   2 # SPDX-License-Identifier: Apache-2.0
   3 #
   4
   5 cmake_policy(SET CMP0054 NEW)
   6
   7 # TODO: for make instal / package we need to use 3.13.3 version because
   8 # it allows to install targets created outside of current projects
   9 # See https://blog.kitware.com/cmake-3-13-0-available-for-download/
  10
  11 if (APPLE)
  12     if(CMAKE_GENERATOR STREQUAL "Xcode")
  13         # due to https://gitlab.kitware.com/cmake/cmake/issues/14254
  14         cmake_minimum_required(VERSION 3.12.0 FATAL_ERROR)
  15     else()
  16         # due to https://cmake.org/cmake/help/v3.12/policy/CMP0068.html
  17         cmake_minimum_required(VERSION 3.9 FATAL_ERROR)
  18     endif()
  19 else()
  20     cmake_minimum_required(VERSION 3.7.2 FATAL_ERROR)
  21 endif()
  22
  23 project(OpenVINO)
  24
  25 set(OpenVINO_MAIN_SOURCE_DIR ${CMAKE_CURRENT_SOURCE_DIR})
  26 set(IE_MAIN_SOURCE_DIR ${OpenVINO_MAIN_SOURCE_DIR}/inference-engine)
  27 list(APPEND CMAKE_MODULE_PATH "${OpenVINO_MAIN_SOURCE_DIR}/cmake")
  28
  29 include(CTest)
  30 include(features)
  31
  32 # include developer package
  33 include(developer_package)
  34
  35 # These options are shared with 3rdparty plugins
  36 # by means of developer package
  37 include(check_features)
  38 include(dependencies)
  39
  40 # resolving dependencies for the project
  41 message (STATUS "PROJECT ............................... " ${PROJECT_NAME})
  42 message (STATUS "CMAKE_BINARY_DIR ...................... " ${CMAKE_BINARY_DIR})
  43 message (STATUS "OpenVINO_MAIN_SOURCE_DIR .............. " ${OpenVINO_MAIN_SOURCE_DIR})
  44 message (STATUS "IE_MAIN_SOURCE_DIR .................... " ${IE_MAIN_SOURCE_DIR})
  45 message (STATUS "CMAKE_GENERATOR ....................... " ${CMAKE_GENERATOR})
  46 message (STATUS "CMAKE_C_COMPILER_ID ................... " ${CMAKE_C_COMPILER_ID})
  47 message (STATUS "CMAKE_BUILD_TYPE ...................... " ${CMAKE_BUILD_TYPE})
  48
  49 # remove file with exported developer targets to force its regeneration
  50 file(REMOVE "${CMAKE_BINARY_DIR}/targets_developer.cmake")
  51 file(REMOVE "${CMAKE_BINARY_DIR}/targets.cmake")
  52
  53 function(build_ngraph)
  54     function(ngraph_set option value)
  55         if(NOT DEFINED ${option})
  56             set(${option} ${value} CACHE BOOL "" FORCE)
  57         endif()
  58     endfunction()
  59
  60     set(NGRAPH_BUILD_DIR ${CMAKE_LIBRARY_OUTPUT_DIRECTORY} CACHE STRING "" FORCE)
  61     set(CMAKE_MODULE_PATH ${CMAKE_MODULE_PATH} "${OpenVINO_MAIN_SOURCE_DIR}/ngraph/cmake/Modules/")
  62
  63     if (ENABLE_SANITIZER)
  64         ngraph_set(NGRAPH_ADDRESS_SANITIZER TRUE)
  65     else ()
  66         ngraph_set(NGRAPH_ADDRESS_SANITIZER FALSE)
  67     endif ()
  68     ngraph_set(NGRAPH_PYTHON_BUILD_ENABLE FALSE)
  69
  70     if(ENABLE_TESTS AND NOT ANDROID)
  71         ngraph_set(NGRAPH_UNIT_TEST_ENABLE TRUE)
  72         ngraph_set(NGRAPH_IE_ENABLE TRUE)
  73     else()
  74         ngraph_set(NGRAPH_UNIT_TEST_ENABLE FALSE)
  75         ngraph_set(NGRAPH_IE_ENABLE FALSE)
  76     endif()
  77
  78     if(NOT ANDROID)
  79         ngraph_set(NGRAPH_ONNX_IMPORT_ENABLE TRUE)
  80     else()
  81         ngraph_set(NGRAPH_ONNX_IMPORT_ENABLE FALSE)
  82     endif()
  83     ngraph_set(NGRAPH_INTERPRETER_ENABLE TRUE)
  84
  85     if(CMAKE_CXX_COMPILER_ID MATCHES "^(Apple)?Clang$")
  86         ie_add_compiler_flags(-Wno-error=uninitialized -Wno-error=literal-conversion)
  87     elseif(UNIX)
  88         ie_add_compiler_flags(-Wno-error=maybe-uninitialized -Wno-error=return-type -fPIC)
  89     endif()
  90     if(ANDROID)
  91         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -Wno-error=defaulted-function-deleted -Wno-error=unused-command-line-argument")
  92     endif()
  93
  94     # WA for GCC 7.0
  95     if (UNIX)
  96         ie_add_compiler_flags(-Wno-error=return-type -Wno-undef)
  97     elseif(WIN32)
  98         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /wd4308 /wd4146 /wd4703 /wd4244 /wd4819")
  99     endif()
 100
 101     # Preserve the original flags for further use
 102     set(CMAKE_ORIGINAL_CXX_FLAGS_RELEASE "${CMAKE_CXX_FLAGS_RELEASE}")
 103     set(CMAKE_ORIGINAL_C_FLAGS_RELEASE "${CMAKE_C_FLAGS_RELEASE}")
 104     set(CMAKE_ORIGINAL_EXE_LINKER_FLAGS_RELEASE "${CMAKE_EXE_LINKER_FLAGS_RELEASE}")
 105     set(CMAKE_ORIGINAL_SHARED_LINKER_FLAGS_RELEASE "${CMAKE_SHARED_LINKER_FLAGS_RELEASE}")
 106     set(CMAKE_ORIGINAL_MODULE_LINKER_FLAGS_RELEASE "${CMAKE_MODULE_LINKER_FLAGS_RELEASE}")
 107
 108     if(ENABLE_LTO)
 109         ie_enable_lto()
 110     endif()
 111
 112     ie_cpack_add_component(ngraph)
 113
 114     set(SDL_cmake_included ON)
 115     # set(NGRAPH_COMPONENT_PREFIX "deployment_tools/ngraph/")
 116     add_subdirectory(ngraph)
 117     set(NGRAPH_LIBRARIES ngraph PARENT_SCOPE)
 118 endfunction()
 119
 120 add_subdirectory(openvino)
 121
 122 build_ngraph()
 123
 124 add_subdirectory(inference-engine)
 125
 126 add_subdirectory(docs)
 127
 128 # cpack
 129
 130 # install setupvars
 131
 132 ie_cpack_add_component(setupvars REQUIRED)
 133
 134 if(UNIX)
 135     install(PROGRAMS scripts/setupvars/setupvars.sh
 136             DESTINATION bin
 137             COMPONENT setupvars)
 138 elseif(WIN32)
 139     install(PROGRAMS scripts/setupvars/setupvars.bat
 140             DESTINATION bin
 141             COMPONENT setupvars)
 142 endif()
 143
 144 # install install_dependencies
 145
 146 if(UNIX)
 147     ie_cpack_add_component(install_dependencies REQUIRED)
 148     install(DIRECTORY scripts/install_dependencies/
 149             DESTINATION install_dependencies
 150             COMPONENT install_dependencies)
 151 endif()
 152
 153 # install files for demo
 154
 155 ie_cpack_add_component(demo_scripts REQUIRED DEPENDS core)
 156
 157 if(UNIX)
 158     install(DIRECTORY scripts/demo/
 159             DESTINATION deployment_tools/demo
 160             COMPONENT demo_scripts
 161             USE_SOURCE_PERMISSIONS
 162             PATTERN *.bat EXCLUDE)
 163 elseif(WIN32)
 164     install(DIRECTORY scripts/demo/
 165             DESTINATION deployment_tools/demo
 166             COMPONENT demo_scripts
 167             USE_SOURCE_PERMISSIONS
 168             PATTERN *.sh EXCLUDE)
 169 endif()
 170
 171 ie_cpack(${IE_CPACK_COMPONENTS_ALL})