CMakeLists.txt

   1 # ----------------------------------------------------------------------------
   2 #  Root CMake file for OpenCV
   3 #
   4 #    From the off-tree build directory, invoke:
   5 #      $ cmake <PATH_TO_OPENCV_ROOT>
   6 #
   7 # ----------------------------------------------------------------------------
   8
   9 # Disable in-source builds to prevent source tree corruption.
  10 if(" ${CMAKE_SOURCE_DIR}" STREQUAL " ${CMAKE_BINARY_DIR}")
  11   message(FATAL_ERROR "
  12 FATAL: In-source builds are not allowed.
  13        You should create a separate directory for build files.
  14 ")
  15 endif()
  16
  17
  18 include(cmake/OpenCVMinDepVersions.cmake)
  19
  20 if(CMAKE_GENERATOR MATCHES Xcode AND XCODE_VERSION VERSION_GREATER 4.3)
  21   cmake_minimum_required(VERSION 3.0 FATAL_ERROR)
  22 elseif(CMAKE_SYSTEM_NAME MATCHES WindowsPhone OR CMAKE_SYSTEM_NAME MATCHES WindowsStore)
  23   cmake_minimum_required(VERSION 3.1 FATAL_ERROR)
  24   #Required to resolve linker error issues due to incompatibility with CMake v3.0+ policies.
  25   #CMake fails to find _fseeko() which leads to subsequent linker error.
  26   #See details here: http://www.cmake.org/Wiki/CMake/Policies
  27   cmake_policy(VERSION 2.8)
  28 else()
  29   cmake_minimum_required(VERSION "${MIN_VER_CMAKE}" FATAL_ERROR)
  30 endif()
  31
  32 option(ENABLE_PIC "Generate position independent code (necessary for shared libraries)" TRUE)
  33 set(CMAKE_POSITION_INDEPENDENT_CODE ${ENABLE_PIC})
  34
  35 # Following block can break build in case of cross-compiling
  36 # but CMAKE_CROSSCOMPILING variable will be set only on project(OpenCV) command
  37 # so we will try to detect cross-compiling by the presence of CMAKE_TOOLCHAIN_FILE
  38 if(NOT DEFINED CMAKE_INSTALL_PREFIX)
  39   if(NOT CMAKE_TOOLCHAIN_FILE)
  40     # it _must_ go before project(OpenCV) in order to work
  41     if(WIN32)
  42       set(CMAKE_INSTALL_PREFIX "${CMAKE_BINARY_DIR}/install" CACHE PATH "Installation Directory")
  43     else()
  44       set(CMAKE_INSTALL_PREFIX "/usr/local" CACHE PATH "Installation Directory")
  45     endif()
  46   else()
  47     #Android: set output folder to ${CMAKE_BINARY_DIR}
  48     set(LIBRARY_OUTPUT_PATH_ROOT ${CMAKE_BINARY_DIR} CACHE PATH "root for library output, set this to change where android libs are compiled to" )
  49     # any cross-compiling
  50     set(CMAKE_INSTALL_PREFIX "${CMAKE_BINARY_DIR}/install" CACHE PATH "Installation Directory")
  51   endif()
  52 endif()
  53
  54 if(CMAKE_SYSTEM_NAME MATCHES WindowsPhone OR CMAKE_SYSTEM_NAME MATCHES WindowsStore)
  55   set(WINRT TRUE)
  56 endif()
  57
  58 if(WINRT)
  59   add_definitions(-DWINRT -DNO_GETENV)
  60
  61   # Making definitions available to other configurations and
  62   # to filter dependency restrictions at compile time.
  63   if(CMAKE_SYSTEM_NAME MATCHES WindowsPhone)
  64     set(WINRT_PHONE TRUE)
  65     add_definitions(-DWINRT_PHONE)
  66   elseif(CMAKE_SYSTEM_NAME MATCHES WindowsStore)
  67     set(WINRT_STORE TRUE)
  68     add_definitions(-DWINRT_STORE)
  69   endif()
  70
  71   if(CMAKE_SYSTEM_VERSION MATCHES 10)
  72     set(WINRT_10 TRUE)
  73     add_definitions(-DWINRT_10)
  74   elseif(CMAKE_SYSTEM_VERSION MATCHES 8.1)
  75     set(WINRT_8_1 TRUE)
  76     add_definitions(-DWINRT_8_1)
  77   elseif(CMAKE_SYSTEM_VERSION MATCHES 8.0)
  78     set(WINRT_8_0 TRUE)
  79     add_definitions(-DWINRT_8_0)
  80   endif()
  81 endif()
  82
  83 if(POLICY CMP0026)
  84   cmake_policy(SET CMP0026 NEW)
  85 endif()
  86
  87 if(POLICY CMP0042)
  88   cmake_policy(SET CMP0042 NEW)
  89 endif()
  90
  91 if(POLICY CMP0046)
  92   cmake_policy(SET CMP0046 NEW)
  93 endif()
  94
  95 if(POLICY CMP0051)
  96   cmake_policy(SET CMP0051 NEW)
  97 endif()
  98
  99 if(POLICY CMP0056)
 100   cmake_policy(SET CMP0056 NEW)
 101 endif()
 102
 103 if(POLICY CMP0067)
 104   cmake_policy(SET CMP0067 NEW)
 105 endif()
 106
 107 include(cmake/OpenCVUtils.cmake)
 108 ocv_cmake_reset_hooks()
 109 ocv_check_environment_variables(OPENCV_CMAKE_HOOKS_DIR)
 110 if(DEFINED OPENCV_CMAKE_HOOKS_DIR)
 111   foreach(__dir ${OPENCV_CMAKE_HOOKS_DIR})
 112     get_filename_component(__dir "${__dir}" ABSOLUTE)
 113     ocv_cmake_hook_register_dir(${__dir})
 114   endforeach()
 115 endif()
 116
 117 ocv_cmake_hook(CMAKE_INIT)
 118
 119 # must go before the project command
 120 ocv_update(CMAKE_CONFIGURATION_TYPES "Debug;Release" CACHE STRING "Configs" FORCE)
 121 if(DEFINED CMAKE_BUILD_TYPE)
 122   set_property( CACHE CMAKE_BUILD_TYPE PROPERTY STRINGS ${CMAKE_CONFIGURATION_TYPES} )
 123 endif()
 124
 125 enable_testing()
 126
 127 project(OpenCV CXX C)
 128
 129 if(MSVC)
 130   set(CMAKE_USE_RELATIVE_PATHS ON CACHE INTERNAL "" FORCE)
 131 endif()
 132
 133 ocv_cmake_eval(DEBUG_PRE ONCE)
 134
 135 ocv_clear_vars(OpenCVModules_TARGETS)
 136
 137 include(cmake/OpenCVDownload.cmake)
 138
 139 set(BUILD_LIST "" CACHE STRING "Build only listed modules (comma-separated, e.g. 'videoio,dnn,ts')")
 140
 141 # ----------------------------------------------------------------------------
 142 # Break in case of popular CMake configuration mistakes
 143 # ----------------------------------------------------------------------------
 144 if(NOT CMAKE_SIZEOF_VOID_P GREATER 0)
 145   message(FATAL_ERROR "CMake fails to determine the bitness of the target platform.
 146   Please check your CMake and compiler installation. If you are cross-compiling then ensure that your CMake toolchain file correctly sets the compiler details.")
 147 endif()
 148
 149 # ----------------------------------------------------------------------------
 150 # Detect compiler and target platform architecture
 151 # ----------------------------------------------------------------------------
 152 OCV_OPTION(ENABLE_CXX11 "Enable C++11 compilation mode" "${OPENCV_CXX11}")
 153 include(cmake/OpenCVDetectCXXCompiler.cmake)
 154 ocv_cmake_hook(POST_DETECT_COMPILER)
 155
 156 # Add these standard paths to the search paths for FIND_LIBRARY
 157 # to find libraries from these locations first
 158 if(UNIX AND NOT ANDROID)
 159   if(X86_64 OR CMAKE_SIZEOF_VOID_P EQUAL 8)
 160     if(EXISTS /lib64)
 161       list(APPEND CMAKE_LIBRARY_PATH /lib64)
 162     else()
 163       list(APPEND CMAKE_LIBRARY_PATH /lib)
 164     endif()
 165     if(EXISTS /usr/lib64)
 166       list(APPEND CMAKE_LIBRARY_PATH /usr/lib64)
 167     else()
 168       list(APPEND CMAKE_LIBRARY_PATH /usr/lib)
 169     endif()
 170   elseif(X86 OR CMAKE_SIZEOF_VOID_P EQUAL 4)
 171     if(EXISTS /lib32)
 172       list(APPEND CMAKE_LIBRARY_PATH /lib32)
 173     else()
 174       list(APPEND CMAKE_LIBRARY_PATH /lib)
 175     endif()
 176     if(EXISTS /usr/lib32)
 177       list(APPEND CMAKE_LIBRARY_PATH /usr/lib32)
 178     else()
 179       list(APPEND CMAKE_LIBRARY_PATH /usr/lib)
 180     endif()
 181   endif()
 182 endif()
 183
 184 # Add these standard paths to the search paths for FIND_PATH
 185 # to find include files from these locations first
 186 if(MINGW)
 187   if(EXISTS /mingw)
 188       list(APPEND CMAKE_INCLUDE_PATH /mingw)
 189   endif()
 190   if(EXISTS /mingw32)
 191       list(APPEND CMAKE_INCLUDE_PATH /mingw32)
 192   endif()
 193   if(EXISTS /mingw64)
 194       list(APPEND CMAKE_INCLUDE_PATH /mingw64)
 195   endif()
 196 endif()
 197
 198 # ----------------------------------------------------------------------------
 199 # OpenCV cmake options
 200 # ----------------------------------------------------------------------------
 201
 202 OCV_OPTION(OPENCV_ENABLE_NONFREE "Enable non-free algorithms" OFF)
 203
 204 # 3rd party libs
 205 OCV_OPTION(BUILD_ZLIB               "Build zlib from source"             WIN32 OR APPLE)
 206 OCV_OPTION(BUILD_TIFF               "Build libtiff from source"          WIN32 OR ANDROID OR APPLE)
 207 OCV_OPTION(BUILD_JASPER             "Build libjasper from source"        WIN32 OR ANDROID OR APPLE)
 208 OCV_OPTION(BUILD_JPEG               "Build libjpeg from source"          WIN32 OR ANDROID OR APPLE)
 209 OCV_OPTION(BUILD_PNG                "Build libpng from source"           WIN32 OR ANDROID OR APPLE)
 210 OCV_OPTION(BUILD_OPENEXR            "Build openexr from source"          (WIN32 OR ANDROID OR APPLE) AND NOT WINRT)
 211 OCV_OPTION(BUILD_WEBP               "Build WebP from source"             (WIN32 OR ANDROID OR APPLE) AND NOT WINRT)
 212 OCV_OPTION(BUILD_TBB                "Download and build TBB from source" ANDROID )
 213 OCV_OPTION(BUILD_IPP_IW             "Build IPP IW from source"           NOT MINGW IF (X86_64 OR X86) AND NOT WINRT )
 214 OCV_OPTION(BUILD_ITT                "Build Intel ITT from source"        NOT MINGW IF (X86_64 OR X86) AND NOT WINRT AND NOT APPLE_FRAMEWORK )
 215
 216 # Optional 3rd party components
 217 # ===================================================
 218 OCV_OPTION(WITH_1394           "Include IEEE1394 support"                    ON   IF (NOT ANDROID AND NOT IOS AND NOT WINRT) )
 219 OCV_OPTION(WITH_AVFOUNDATION   "Use AVFoundation for Video I/O (iOS/Mac)"    ON   IF APPLE)
 220 OCV_OPTION(WITH_CARBON         "Use Carbon for UI instead of Cocoa"          OFF  IF APPLE )
 221 OCV_OPTION(WITH_CAROTENE       "Use NVidia carotene acceleration library for ARM platform"                   ON  IF (ARM OR AARCH64) AND NOT IOS AND NOT (CMAKE_VERSION VERSION_LESS "2.8.11"))
 222 OCV_OPTION(WITH_CPUFEATURES    "Use cpufeatures Android library"             ON   IF ANDROID)
 223 OCV_OPTION(WITH_VTK            "Include VTK library support (and build opencv_viz module eiher)"             ON  IF (NOT ANDROID AND NOT IOS AND NOT WINRT AND NOT CMAKE_CROSSCOMPILING) )
 224 OCV_OPTION(WITH_CUDA           "Include NVidia Cuda Runtime support"                                         OFF IF (NOT IOS AND NOT WINRT) )
 225 OCV_OPTION(WITH_CUFFT          "Include NVidia Cuda Fast Fourier Transform (FFT) library support"            ON  IF (NOT IOS AND NOT WINRT) )
 226 OCV_OPTION(WITH_CUBLAS         "Include NVidia Cuda Basic Linear Algebra Subprograms (BLAS) library support" ON IF (NOT IOS AND NOT WINRT) )
 227 OCV_OPTION(WITH_NVCUVID        "Include NVidia Video Decoding library support"                               ON IF (NOT IOS AND NOT APPLE) )
 228 OCV_OPTION(WITH_EIGEN          "Include Eigen2/Eigen3 support"               (NOT CV_DISABLE_OPTIMIZATION)       IF (NOT WINRT AND NOT CMAKE_CROSSCOMPILING) )
 229 OCV_OPTION(WITH_VFW            "Include Video for Windows support"           ON   IF WIN32 )
 230 OCV_OPTION(WITH_FFMPEG         "Include FFMPEG support"                      ON   IF (NOT ANDROID AND NOT IOS AND NOT WINRT) )
 231 OCV_OPTION(WITH_GSTREAMER      "Include Gstreamer support"                   ON   IF (NOT ANDROID AND NOT IOS AND NOT WINRT) )
 232 OCV_OPTION(WITH_GSTREAMER_0_10 "Enable Gstreamer 0.10 support (instead of 1.x)"                              OFF )
 233 OCV_OPTION(WITH_GTK            "Include GTK support"                         ON   IF (UNIX AND NOT APPLE AND NOT ANDROID) )
 234 OCV_OPTION(WITH_GTK_2_X        "Use GTK version 2"                           OFF  IF (UNIX AND NOT APPLE AND NOT ANDROID) )
 235 OCV_OPTION(WITH_IPP            "Include Intel IPP support"                   (NOT MINGW AND NOT CV_DISABLE_OPTIMIZATION)  IF (X86_64 OR X86) AND NOT WINRT AND NOT IOS )
 236 OCV_OPTION(WITH_HALIDE         "Include Halide support"                      OFF)
 237 OCV_OPTION(WITH_INF_ENGINE     "Include Intel Inference Engine support"      OFF)
 238 OCV_OPTION(WITH_JASPER         "Include JPEG2K support"                      ON   IF (NOT IOS) )
 239 OCV_OPTION(WITH_JPEG           "Include JPEG support"                        ON)
 240 OCV_OPTION(WITH_WEBP           "Include WebP support"                        ON   IF (NOT WINRT) )
 241 OCV_OPTION(WITH_OPENEXR        "Include ILM support via OpenEXR"             ON   IF (NOT IOS AND NOT WINRT) )
 242 OCV_OPTION(WITH_OPENGL         "Include OpenGL support"                      OFF  IF (NOT ANDROID AND NOT WINRT) )
 243 OCV_OPTION(WITH_OPENVX         "Include OpenVX support"                      OFF)
 244 OCV_OPTION(WITH_OPENNI         "Include OpenNI support"                      OFF  IF (NOT ANDROID AND NOT IOS AND NOT WINRT) )
 245 OCV_OPTION(WITH_OPENNI2        "Include OpenNI2 support"                     OFF  IF (NOT ANDROID AND NOT IOS AND NOT WINRT) )
 246 OCV_OPTION(WITH_PNG            "Include PNG support"                         ON)
 247 OCV_OPTION(WITH_GDCM           "Include DICOM support"                       OFF)
 248 OCV_OPTION(WITH_PVAPI          "Include Prosilica GigE support"              OFF   IF (NOT ANDROID AND NOT IOS AND NOT WINRT) )
 249 OCV_OPTION(WITH_GIGEAPI        "Include Smartek GigE support"                OFF   IF (NOT ANDROID AND NOT IOS AND NOT WINRT) )
 250 OCV_OPTION(WITH_ARAVIS         "Include Aravis GigE support"                 OFF   IF (NOT ANDROID AND NOT IOS AND NOT WINRT AND NOT WIN32) )
 251 OCV_OPTION(WITH_QT             "Build with Qt Backend support"               OFF  IF (NOT ANDROID AND NOT IOS AND NOT WINRT) )
 252 OCV_OPTION(WITH_WIN32UI        "Build with Win32 UI Backend support"         ON   IF WIN32 AND NOT WINRT)
 253 OCV_OPTION(WITH_QUICKTIME      "Use QuickTime for Video I/O"                 OFF  IF APPLE )
 254 OCV_OPTION(WITH_QTKIT          "Use QTKit Video I/O backend"                 OFF  IF APPLE )
 255 OCV_OPTION(WITH_TBB            "Include Intel TBB support"                   OFF  IF (NOT IOS AND NOT WINRT) )
 256 OCV_OPTION(WITH_OPENMP         "Include OpenMP support"                      OFF)
 257 OCV_OPTION(WITH_CSTRIPES       "Include C= support"                          OFF  IF (WIN32 AND NOT WINRT)  )
 258 OCV_OPTION(WITH_PTHREADS_PF    "Use pthreads-based parallel_for"             ON   IF (NOT WIN32 OR MINGW) )
 259 OCV_OPTION(WITH_TIFF           "Include TIFF support"                        ON   IF (NOT IOS) )
 260 OCV_OPTION(WITH_UNICAP         "Include Unicap support (GPL)"                OFF  IF (UNIX AND NOT APPLE AND NOT ANDROID) )
 261 OCV_OPTION(WITH_V4L            "Include Video 4 Linux support"               ON   IF (UNIX AND NOT ANDROID AND NOT APPLE) )
 262 OCV_OPTION(WITH_LIBV4L         "Use libv4l for Video 4 Linux support"        OFF  IF (UNIX AND NOT ANDROID AND NOT APPLE) )
 263 OCV_OPTION(WITH_DSHOW          "Build VideoIO with DirectShow support"       ON   IF (WIN32 AND NOT ARM AND NOT WINRT) )
 264 OCV_OPTION(WITH_MSMF           "Build VideoIO with Media Foundation support" ON  IF WIN32 )
 265 OCV_OPTION(WITH_XIMEA          "Include XIMEA cameras support"               OFF  IF (NOT ANDROID AND NOT WINRT) )
 266 OCV_OPTION(WITH_XINE           "Include Xine support (GPL)"                  OFF  IF (UNIX AND NOT APPLE AND NOT ANDROID) )
 267 OCV_OPTION(WITH_CLP            "Include Clp support (EPL)"                   OFF)
 268 OCV_OPTION(WITH_OPENCL         "Include OpenCL Runtime support"              (NOT ANDROID AND NOT CV_DISABLE_OPTIMIZATION)  IF (NOT IOS AND NOT WINRT) )
 269 OCV_OPTION(WITH_OPENCL_SVM     "Include OpenCL Shared Virtual Memory support" OFF ) # experimental
 270 OCV_OPTION(WITH_OPENCLAMDFFT   "Include AMD OpenCL FFT library support"      ON   IF (NOT ANDROID AND NOT IOS AND NOT WINRT) )
 271 OCV_OPTION(WITH_OPENCLAMDBLAS  "Include AMD OpenCL BLAS library support"     ON   IF (NOT ANDROID AND NOT IOS AND NOT WINRT) )
 272 OCV_OPTION(WITH_DIRECTX        "Include DirectX support"                     ON   IF (WIN32 AND NOT WINRT) )
 273 OCV_OPTION(WITH_INTELPERC      "Include Intel Perceptual Computing support"  OFF  IF (WIN32 AND NOT WINRT) )
 274 OCV_OPTION(WITH_VA             "Include VA support"                          OFF  IF (UNIX AND NOT ANDROID) )
 275 OCV_OPTION(WITH_VA_INTEL       "Include Intel VA-API/OpenCL support"         OFF  IF (UNIX AND NOT ANDROID) )
 276 OCV_OPTION(WITH_MFX            "Include Intel Media SDK support"             OFF   IF ((UNIX AND NOT ANDROID) OR (WIN32 AND NOT WINRT AND NOT MINGW)) )
 277 OCV_OPTION(WITH_GDAL           "Include GDAL Support"                        OFF  IF (NOT ANDROID AND NOT IOS AND NOT WINRT) )
 278 OCV_OPTION(WITH_GPHOTO2        "Include gPhoto2 library support"             OFF  IF (UNIX AND NOT ANDROID AND NOT IOS) )
 279 OCV_OPTION(WITH_LAPACK         "Include Lapack library support"              (NOT CV_DISABLE_OPTIMIZATION)  IF (NOT ANDROID AND NOT IOS) )
 280 OCV_OPTION(WITH_ITT            "Include Intel ITT support"                   ON   IF (NOT APPLE_FRAMEWORK) )
 281 OCV_OPTION(WITH_PROTOBUF       "Enable libprotobuf"                          ON )
 282 OCV_OPTION(WITH_IMGCODEC_HDR   "Include HDR support"                         ON)
 283 OCV_OPTION(WITH_IMGCODEC_SUNRASTER "Include SUNRASTER support"               ON)
 284 OCV_OPTION(WITH_IMGCODEC_PXM   "Include PNM (PBM,PGM,PPM) and PAM formats support" ON)
 285
 286 # OpenCV build components
 287 # ===================================================
 288 OCV_OPTION(BUILD_SHARED_LIBS        "Build shared libraries (.dll/.so) instead of static ones (.lib/.a)" NOT (ANDROID OR APPLE_FRAMEWORK) )
 289 OCV_OPTION(BUILD_opencv_apps        "Build utility applications (used for example to train classifiers)" (NOT ANDROID AND NOT WINRT) IF (NOT APPLE_FRAMEWORK) )
 290 OCV_OPTION(BUILD_opencv_js          "Build JavaScript bindings by Emscripten" OFF )
 291 OCV_OPTION(BUILD_ANDROID_PROJECTS   "Build Android projects providing .apk files" ON  IF ANDROID )
 292 OCV_OPTION(BUILD_ANDROID_EXAMPLES   "Build examples for Android platform"         ON  IF ANDROID )
 293 OCV_OPTION(BUILD_DOCS               "Create build rules for OpenCV Documentation" OFF  IF (NOT WINRT AND NOT APPLE_FRAMEWORK))
 294 OCV_OPTION(BUILD_EXAMPLES           "Build all examples"                          OFF )
 295 OCV_OPTION(BUILD_PACKAGE            "Enables 'make package_source' command"       ON  IF NOT WINRT)
 296 OCV_OPTION(BUILD_PERF_TESTS         "Build performance tests"                     ON  IF (NOT APPLE_FRAMEWORK) )
 297 OCV_OPTION(BUILD_TESTS              "Build accuracy & regression tests"           ON  IF (NOT APPLE_FRAMEWORK) )
 298 OCV_OPTION(BUILD_WITH_DEBUG_INFO    "Include debug info into release binaries ('OFF' means default settings)" OFF )
 299 OCV_OPTION(BUILD_WITH_STATIC_CRT    "Enables use of statically linked CRT for statically linked OpenCV" ON IF MSVC )
 300 OCV_OPTION(BUILD_WITH_DYNAMIC_IPP   "Enables dynamic linking of IPP (only for standalone IPP)" OFF )
 301 OCV_OPTION(BUILD_FAT_JAVA_LIB       "Create Java wrapper exporting all functions of OpenCV library (requires static build of OpenCV modules)" ANDROID IF NOT BUILD_SHARED_LIBS)
 302 OCV_OPTION(BUILD_ANDROID_SERVICE    "Build OpenCV Manager for Google Play" OFF IF ANDROID )
 303 OCV_OPTION(BUILD_CUDA_STUBS         "Build CUDA modules stubs when no CUDA SDK" OFF  IF (NOT APPLE_FRAMEWORK) )
 304 OCV_OPTION(BUILD_JAVA               "Enable Java support"                         (ANDROID OR NOT CMAKE_CROSSCOMPILING)  IF (ANDROID OR (NOT APPLE_FRAMEWORK AND NOT WINRT)) )
 305
 306 # OpenCV installation options
 307 # ===================================================
 308 OCV_OPTION(INSTALL_CREATE_DISTRIB   "Change install rules to build the distribution package" OFF )
 309 OCV_OPTION(INSTALL_C_EXAMPLES       "Install C examples"        OFF )
 310 OCV_OPTION(INSTALL_PYTHON_EXAMPLES  "Install Python examples"   OFF )
 311 OCV_OPTION(INSTALL_ANDROID_EXAMPLES "Install Android examples"  OFF IF ANDROID )
 312 OCV_OPTION(INSTALL_TO_MANGLED_PATHS "Enables mangled install paths, that help with side by side installs." OFF IF (UNIX AND NOT ANDROID AND NOT APPLE_FRAMEWORK AND BUILD_SHARED_LIBS) )
 313 OCV_OPTION(INSTALL_TESTS            "Install accuracy and performance test binaries and test data" OFF)
 314
 315 # OpenCV build options
 316 # ===================================================
 317 OCV_OPTION(ENABLE_CCACHE              "Use ccache"                                               (UNIX AND NOT IOS AND (CMAKE_GENERATOR MATCHES "Makefile" OR CMAKE_GENERATOR MATCHES "Ninja")) )
 318 OCV_OPTION(ENABLE_PRECOMPILED_HEADERS "Use precompiled headers"                                  ON IF (MSVC OR (NOT IOS AND NOT CMAKE_CROSSCOMPILING) ) )
 319 OCV_OPTION(ENABLE_SOLUTION_FOLDERS    "Solution folder in Visual Studio or in other IDEs"        (MSVC_IDE OR CMAKE_GENERATOR MATCHES Xcode) )
 320 OCV_OPTION(ENABLE_PROFILING           "Enable profiling in the GCC compiler (Add flags: -g -pg)" OFF  IF CV_GCC )
 321 OCV_OPTION(ENABLE_COVERAGE            "Enable coverage collection with  GCov"                    OFF  IF CV_GCC )
 322 OCV_OPTION(ENABLE_OMIT_FRAME_POINTER  "Enable -fomit-frame-pointer for GCC"                      ON   IF CV_GCC )
 323 OCV_OPTION(ENABLE_POWERPC             "Enable PowerPC for GCC"                                   ON   IF (CV_GCC AND CMAKE_SYSTEM_PROCESSOR MATCHES powerpc.*) )
 324 OCV_OPTION(ENABLE_VSX                 "Enable POWER8 and above VSX (64-bit little-endian)"       ON   IF ((CV_GCC OR CV_CLANG) AND PPC64LE) )
 325 OCV_OPTION(ENABLE_FAST_MATH           "Enable -ffast-math (not recommended for GCC 4.6.x)"       OFF  IF (CV_GCC AND (X86 OR X86_64)) )
 326 OCV_OPTION(ENABLE_NEON                "Enable NEON instructions"                                 (NEON OR ANDROID_ARM_NEON OR AARCH64) IF (CV_GCC OR CV_CLANG) AND (ARM OR AARCH64 OR IOS) )
 327 OCV_OPTION(ENABLE_VFPV3               "Enable VFPv3-D32 instructions"                            OFF  IF (CV_GCC OR CV_CLANG) AND (ARM OR AARCH64 OR IOS) )
 328 OCV_OPTION(ENABLE_NOISY_WARNINGS      "Show all warnings even if they are too noisy"             OFF )
 329 OCV_OPTION(OPENCV_WARNINGS_ARE_ERRORS "Treat warnings as errors"                                 OFF )
 330 OCV_OPTION(ANDROID_EXAMPLES_WITH_LIBS "Build binaries of Android examples with native libraries" OFF  IF ANDROID )
 331 OCV_OPTION(ENABLE_IMPL_COLLECTION     "Collect implementation data on function call"             OFF )
 332 OCV_OPTION(ENABLE_INSTRUMENTATION     "Instrument functions to collect calls trace and performance" OFF )
 333 OCV_OPTION(ENABLE_GNU_STL_DEBUG       "Enable GNU STL Debug mode (defines _GLIBCXX_DEBUG)"       OFF IF ((NOT CMAKE_VERSION VERSION_LESS "2.8.11") AND CV_GCC) )
 334 OCV_OPTION(ENABLE_BUILD_HARDENING     "Enable hardening of the resulting binaries (against security attacks, detects memory corruption, etc)" OFF)
 335 OCV_OPTION(ENABLE_LTO                 "Enable Link Time Optimization" OFF IF CV_GCC OR MSVC)
 336 OCV_OPTION(ENABLE_THIN_LTO            "Enable Thin LTO" OFF IF CV_CLANG)
 337 OCV_OPTION(GENERATE_ABI_DESCRIPTOR    "Generate XML file for abi_compliance_checker tool" OFF IF UNIX)
 338 OCV_OPTION(CV_ENABLE_INTRINSICS       "Use intrinsic-based optimized code" ON )
 339 OCV_OPTION(CV_DISABLE_OPTIMIZATION    "Disable explicit optimized code (dispatched code/intrinsics/loop unrolling/etc)" OFF )
 340 OCV_OPTION(CV_TRACE                   "Enable OpenCV code trace" ON)
 341
 342 OCV_OPTION(ENABLE_PYLINT              "Add target with Pylint checks"                            (BUILD_DOCS OR BUILD_EXAMPLES) IF (NOT CMAKE_CROSSCOMPILING AND NOT APPLE_FRAMEWORK) )
 343 OCV_OPTION(ENABLE_FLAKE8              "Add target with Python flake8 checker"                    (BUILD_DOCS OR BUILD_EXAMPLES) IF (NOT CMAKE_CROSSCOMPILING AND NOT APPLE_FRAMEWORK) )
 344
 345 if(ENABLE_IMPL_COLLECTION)
 346   add_definitions(-DCV_COLLECT_IMPL_DATA)
 347 endif()
 348
 349
 350 # ----------------------------------------------------------------------------
 351 #  Get actual OpenCV version number from sources
 352 # ----------------------------------------------------------------------------
 353 include(cmake/OpenCVVersion.cmake)
 354
 355 ocv_cmake_hook(POST_OPTIONS)
 356
 357 # ----------------------------------------------------------------------------
 358 #  Build & install layouts
 359 # ----------------------------------------------------------------------------
 360
 361 # Save libs and executables in the same place
 362 set(EXECUTABLE_OUTPUT_PATH "${CMAKE_BINARY_DIR}/bin" CACHE PATH "Output directory for applications")
 363
 364 if(ANDROID)
 365   if(ANDROID_ABI MATCHES "NEON")
 366     set(ENABLE_NEON ON)
 367   endif()
 368   if(ANDROID_ABI MATCHES "VFPV3")
 369     set(ENABLE_VFPV3 ON)
 370   endif()
 371 endif()
 372
 373 if(ANDROID OR WIN32)
 374   ocv_update(OPENCV_DOC_INSTALL_PATH doc)
 375 else()
 376   ocv_update(OPENCV_DOC_INSTALL_PATH share/OpenCV/doc)
 377 endif()
 378
 379 if(WIN32 AND CMAKE_HOST_SYSTEM_NAME MATCHES Windows)
 380   if(DEFINED OpenCV_RUNTIME AND DEFINED OpenCV_ARCH)
 381     ocv_update(OpenCV_INSTALL_BINARIES_PREFIX "${OpenCV_ARCH}/${OpenCV_RUNTIME}/")
 382   else()
 383     message(STATUS "Can't detect runtime and/or arch")
 384     ocv_update(OpenCV_INSTALL_BINARIES_PREFIX "")
 385   endif()
 386 elseif(ANDROID)
 387   ocv_update(OpenCV_INSTALL_BINARIES_PREFIX "sdk/native/")
 388 else()
 389   ocv_update(OpenCV_INSTALL_BINARIES_PREFIX "")
 390 endif()
 391
 392 if(ANDROID)
 393   ocv_update(OPENCV_SAMPLES_BIN_INSTALL_PATH "${OpenCV_INSTALL_BINARIES_PREFIX}samples/${ANDROID_NDK_ABI_NAME}")
 394 else()
 395   ocv_update(OPENCV_SAMPLES_BIN_INSTALL_PATH "${OpenCV_INSTALL_BINARIES_PREFIX}samples")
 396 endif()
 397
 398 if(ANDROID)
 399   ocv_update(OPENCV_BIN_INSTALL_PATH "${OpenCV_INSTALL_BINARIES_PREFIX}bin/${ANDROID_NDK_ABI_NAME}")
 400 else()
 401   ocv_update(OPENCV_BIN_INSTALL_PATH "${OpenCV_INSTALL_BINARIES_PREFIX}bin")
 402 endif()
 403
 404 if(NOT OPENCV_TEST_INSTALL_PATH)
 405   ocv_update(OPENCV_TEST_INSTALL_PATH "${OPENCV_BIN_INSTALL_PATH}")
 406 endif()
 407
 408 if (OPENCV_TEST_DATA_PATH)
 409   get_filename_component(OPENCV_TEST_DATA_PATH ${OPENCV_TEST_DATA_PATH} ABSOLUTE)
 410 endif()
 411
 412 if(ANDROID)
 413   ocv_update(OPENCV_TEST_DATA_INSTALL_PATH "sdk/etc/testdata")
 414 elseif(WIN32)
 415   ocv_update(OPENCV_TEST_DATA_INSTALL_PATH "testdata")
 416 else()
 417   ocv_update(OPENCV_TEST_DATA_INSTALL_PATH "share/OpenCV/testdata")
 418 endif()
 419
 420 if(ANDROID)
 421   set(LIBRARY_OUTPUT_PATH                "${OpenCV_BINARY_DIR}/lib/${ANDROID_NDK_ABI_NAME}")
 422   ocv_update(3P_LIBRARY_OUTPUT_PATH      "${OpenCV_BINARY_DIR}/3rdparty/lib/${ANDROID_NDK_ABI_NAME}")
 423   ocv_update(OPENCV_LIB_INSTALL_PATH     sdk/native/libs/${ANDROID_NDK_ABI_NAME})
 424   ocv_update(OPENCV_LIB_ARCHIVE_INSTALL_PATH sdk/native/staticlibs/${ANDROID_NDK_ABI_NAME})
 425   ocv_update(OPENCV_3P_LIB_INSTALL_PATH  sdk/native/3rdparty/libs/${ANDROID_NDK_ABI_NAME})
 426   ocv_update(OPENCV_CONFIG_INSTALL_PATH  sdk/native/jni)
 427   ocv_update(OPENCV_INCLUDE_INSTALL_PATH sdk/native/jni/include)
 428   ocv_update(OPENCV_SAMPLES_SRC_INSTALL_PATH samples/native)
 429   ocv_update(OPENCV_OTHER_INSTALL_PATH   sdk/etc)
 430 else()
 431   set(LIBRARY_OUTPUT_PATH                "${OpenCV_BINARY_DIR}/lib")
 432   ocv_update(3P_LIBRARY_OUTPUT_PATH      "${OpenCV_BINARY_DIR}/3rdparty/lib${LIB_SUFFIX}")
 433
 434   if(WIN32 AND CMAKE_HOST_SYSTEM_NAME MATCHES Windows)
 435     if(OpenCV_STATIC)
 436       ocv_update(OPENCV_LIB_INSTALL_PATH   "${OpenCV_INSTALL_BINARIES_PREFIX}staticlib${LIB_SUFFIX}")
 437     else()
 438       ocv_update(OPENCV_LIB_INSTALL_PATH   "${OpenCV_INSTALL_BINARIES_PREFIX}lib${LIB_SUFFIX}")
 439     endif()
 440     ocv_update(OPENCV_3P_LIB_INSTALL_PATH  "${OpenCV_INSTALL_BINARIES_PREFIX}staticlib${LIB_SUFFIX}")
 441     ocv_update(OPENCV_SAMPLES_SRC_INSTALL_PATH    samples)
 442     ocv_update(OPENCV_JAR_INSTALL_PATH java)
 443     ocv_update(OPENCV_OTHER_INSTALL_PATH   etc)
 444     ocv_update(OPENCV_CONFIG_INSTALL_PATH  ".")
 445   else()
 446     include(GNUInstallDirs)
 447     ocv_update(OPENCV_LIB_INSTALL_PATH     ${CMAKE_INSTALL_LIBDIR}${LIB_SUFFIX})
 448     ocv_update(OPENCV_3P_LIB_INSTALL_PATH  share/OpenCV/3rdparty/${OPENCV_LIB_INSTALL_PATH})
 449     ocv_update(OPENCV_SAMPLES_SRC_INSTALL_PATH    share/OpenCV/samples)
 450     ocv_update(OPENCV_JAR_INSTALL_PATH share/OpenCV/java)
 451     ocv_update(OPENCV_OTHER_INSTALL_PATH   share/OpenCV)
 452
 453     if(NOT DEFINED OPENCV_CONFIG_INSTALL_PATH)
 454       math(EXPR SIZEOF_VOID_P_BITS "8 * ${CMAKE_SIZEOF_VOID_P}")
 455       if(LIB_SUFFIX AND NOT SIZEOF_VOID_P_BITS EQUAL LIB_SUFFIX)
 456         ocv_update(OPENCV_CONFIG_INSTALL_PATH ${CMAKE_INSTALL_LIBDIR}${LIB_SUFFIX}/cmake/opencv)
 457       else()
 458         ocv_update(OPENCV_CONFIG_INSTALL_PATH share/OpenCV)
 459       endif()
 460     endif()
 461   endif()
 462   ocv_update(OPENCV_INCLUDE_INSTALL_PATH "include")
 463 endif()
 464
 465 ocv_update(CMAKE_INSTALL_RPATH "${CMAKE_INSTALL_PREFIX}/${OPENCV_LIB_INSTALL_PATH}")
 466 set(CMAKE_INSTALL_RPATH_USE_LINK_PATH TRUE)
 467
 468 if(INSTALL_TO_MANGLED_PATHS)
 469   set(OPENCV_INCLUDE_INSTALL_PATH ${OPENCV_INCLUDE_INSTALL_PATH}/opencv-${OPENCV_VERSION})
 470   foreach(v
 471       OPENCV_3P_LIB_INSTALL_PATH
 472       OPENCV_SAMPLES_SRC_INSTALL_PATH
 473       OPENCV_CONFIG_INSTALL_PATH
 474       OPENCV_DOC_INSTALL_PATH
 475       OPENCV_JAR_INSTALL_PATH
 476       OPENCV_TEST_DATA_INSTALL_PATH
 477       OPENCV_OTHER_INSTALL_PATH
 478     )
 479     string(REPLACE "OpenCV" "OpenCV-${OPENCV_VERSION}" ${v} "${${v}}")
 480     string(REPLACE "opencv" "opencv-${OPENCV_VERSION}" ${v} "${${v}}")
 481   endforeach()
 482 endif()
 483
 484 if(ANDROID)
 485   ocv_update(OPENCV_JNI_INSTALL_PATH "${OPENCV_LIB_INSTALL_PATH}")
 486 elseif(INSTALL_CREATE_DISTRIB)
 487   ocv_update(OPENCV_JNI_INSTALL_PATH "${OPENCV_JAR_INSTALL_PATH}/${OpenCV_ARCH}")
 488 else()
 489   ocv_update(OPENCV_JNI_INSTALL_PATH "${OPENCV_JAR_INSTALL_PATH}")
 490 endif()
 491 ocv_update(OPENCV_JNI_BIN_INSTALL_PATH "${OPENCV_JNI_INSTALL_PATH}")
 492
 493 if(NOT OPENCV_LIB_ARCHIVE_INSTALL_PATH)
 494   set(OPENCV_LIB_ARCHIVE_INSTALL_PATH ${OPENCV_LIB_INSTALL_PATH})
 495 endif()
 496
 497 if(WIN32)
 498   # Postfix of DLLs:
 499   set(OPENCV_DLLVERSION "${OPENCV_VERSION_MAJOR}${OPENCV_VERSION_MINOR}${OPENCV_VERSION_PATCH}")
 500   set(OPENCV_DEBUG_POSTFIX d)
 501 else()
 502   # Postfix of so's:
 503   set(OPENCV_DLLVERSION "")
 504   set(OPENCV_DEBUG_POSTFIX "")
 505 endif()
 506
 507 if(DEFINED CMAKE_DEBUG_POSTFIX)
 508   set(OPENCV_DEBUG_POSTFIX "${CMAKE_DEBUG_POSTFIX}")
 509 endif()
 510
 511 if((INSTALL_CREATE_DISTRIB AND BUILD_SHARED_LIBS AND NOT DEFINED BUILD_opencv_world) OR APPLE_FRAMEWORK)
 512   set(BUILD_opencv_world ON CACHE INTERNAL "")
 513 endif()
 514
 515 # ----------------------------------------------------------------------------
 516 #  Path for build/platform -specific headers
 517 # ----------------------------------------------------------------------------
 518 ocv_update(OPENCV_CONFIG_FILE_INCLUDE_DIR "${CMAKE_BINARY_DIR}/" CACHE PATH "Where to create the platform-dependant cvconfig.h")
 519 ocv_include_directories(${OPENCV_CONFIG_FILE_INCLUDE_DIR})
 520
 521 # ----------------------------------------------------------------------------
 522 #  Path for additional modules
 523 # ----------------------------------------------------------------------------
 524 set(OPENCV_EXTRA_MODULES_PATH "" CACHE PATH "Where to look for additional OpenCV modules (can be ;-separated list of paths)")
 525
 526 # ----------------------------------------------------------------------------
 527 #  Autodetect if we are in a GIT repository
 528 # ----------------------------------------------------------------------------
 529 find_host_package(Git QUIET)
 530
 531 if(NOT DEFINED OPENCV_VCSVERSION AND GIT_FOUND)
 532   ocv_git_describe(OPENCV_VCSVERSION "${OpenCV_SOURCE_DIR}")
 533 elseif(NOT DEFINED OPENCV_VCSVERSION)
 534   # We don't have git:
 535   set(OPENCV_VCSVERSION "unknown")
 536 endif()
 537
 538
 539 # ----------------------------------------------------------------------------
 540 # OpenCV compiler and linker options
 541 # ----------------------------------------------------------------------------
 542 # In case of Makefiles if the user does not setup CMAKE_BUILD_TYPE, assume it's Release:
 543 if(CMAKE_GENERATOR MATCHES "Makefiles|Ninja" AND "${CMAKE_BUILD_TYPE}" STREQUAL "")
 544   set(CMAKE_BUILD_TYPE Release)
 545 endif()
 546
 547 ocv_cmake_hook(POST_CMAKE_BUILD_OPTIONS)
 548
 549 # --- Python Support ---
 550 if(NOT IOS)
 551   include(cmake/OpenCVDetectPython.cmake)
 552 endif()
 553
 554 include(cmake/OpenCVCompilerOptions.cmake)
 555
 556 ocv_cmake_hook(POST_COMPILER_OPTIONS)
 557
 558 # ----------------------------------------------------------------------------
 559 #       CHECK FOR SYSTEM LIBRARIES, OPTIONS, ETC..
 560 # ----------------------------------------------------------------------------
 561 if(UNIX)
 562   if(NOT APPLE_FRAMEWORK OR OPENCV_ENABLE_PKG_CONFIG)
 563     if(CMAKE_CROSSCOMPILING AND NOT DEFINED ENV{PKG_CONFIG_LIBDIR}
 564         AND NOT OPENCV_ENABLE_PKG_CONFIG
 565     )
 566       if(NOT PkgConfig_FOUND)
 567         message(STATUS "OpenCV disables pkg-config to avoid using of host libraries. Consider using PKG_CONFIG_LIBDIR to specify target SYSROOT")
 568       elseif(OPENCV_SKIP_PKG_CONFIG_WARNING)
 569         message(WARNING "pkg-config is enabled in cross-compilation mode without defining of PKG_CONFIG_LIBDIR environment variable. This may lead to misconfigured host-based dependencies.")
 570       endif()
 571     elseif(OPENCV_DISABLE_PKG_CONFIG)
 572       if(PkgConfig_FOUND)
 573         message(WARNING "OPENCV_DISABLE_PKG_CONFIG flag has no effect")
 574       endif()
 575     else()
 576       find_package(PkgConfig QUIET)
 577     endif()
 578   endif()
 579   include(CheckFunctionExists)
 580   include(CheckIncludeFile)
 581   include(CheckSymbolExists)
 582
 583   if(NOT APPLE)
 584     CHECK_INCLUDE_FILE(pthread.h HAVE_PTHREAD)
 585     if(ANDROID)
 586       set(OPENCV_LINKER_LIBS ${OPENCV_LINKER_LIBS} dl m log)
 587     elseif(${CMAKE_SYSTEM_NAME} MATCHES "FreeBSD|NetBSD|DragonFly|OpenBSD|Haiku")
 588       set(OPENCV_LINKER_LIBS ${OPENCV_LINKER_LIBS} m pthread)
 589     elseif(EMSCRIPTEN)
 590       # no need to link to system libs with emscripten
 591     else()
 592       set(OPENCV_LINKER_LIBS ${OPENCV_LINKER_LIBS} dl m pthread rt)
 593     endif()
 594   else()
 595     set(HAVE_PTHREAD 1)
 596   endif()
 597
 598   CHECK_SYMBOL_EXISTS(posix_memalign stdlib.h HAVE_POSIX_MEMALIGN)
 599   CHECK_INCLUDE_FILE(malloc.h HAVE_MALLOC_H)
 600   if(HAVE_MALLOC_H)
 601     CHECK_SYMBOL_EXISTS(memalign malloc.h HAVE_MEMALIGN)
 602   endif()
 603 endif()
 604
 605 include(cmake/OpenCVPCHSupport.cmake)
 606 include(cmake/OpenCVModule.cmake)
 607
 608 # ----------------------------------------------------------------------------
 609 #  Detect endianness of build platform
 610 # ----------------------------------------------------------------------------
 611
 612 if(IOS)
 613   # test_big_endian needs try_compile, which doesn't work for iOS
 614   # http://public.kitware.com/Bug/view.php?id=12288
 615   set(WORDS_BIGENDIAN 0)
 616 else()
 617   include(TestBigEndian)
 618   test_big_endian(WORDS_BIGENDIAN)
 619 endif()
 620
 621 # ----------------------------------------------------------------------------
 622 #  Detect 3rd-party libraries
 623 # ----------------------------------------------------------------------------
 624
 625 if(ANDROID AND WITH_CPUFEATURES)
 626   add_subdirectory(3rdparty/cpufeatures)
 627   set(HAVE_CPUFEATURES 1)
 628 endif()
 629
 630 include(cmake/OpenCVFindLibsGrfmt.cmake)
 631 include(cmake/OpenCVFindLibsGUI.cmake)
 632 include(cmake/OpenCVFindLibsVideo.cmake)
 633 include(cmake/OpenCVFindLibsPerf.cmake)
 634 include(cmake/OpenCVFindLAPACK.cmake)
 635 include(cmake/OpenCVFindProtobuf.cmake)
 636
 637 # ----------------------------------------------------------------------------
 638 #  Detect other 3rd-party libraries/tools
 639 # ----------------------------------------------------------------------------
 640
 641 # --- Java Support ---
 642 if(BUILD_JAVA)
 643   if(ANDROID)
 644     include(cmake/android/OpenCVDetectAndroidSDK.cmake)
 645   else()
 646     include(cmake/OpenCVDetectApacheAnt.cmake)
 647     find_package(JNI)
 648   endif()
 649 endif()
 650
 651 if(ENABLE_PYLINT AND PYTHON_DEFAULT_AVAILABLE)
 652   include(cmake/OpenCVPylint.cmake)
 653 endif()
 654 if(ENABLE_FLAKE8 AND PYTHON_DEFAULT_AVAILABLE)
 655   find_package(Flake8 QUIET)
 656   if(NOT FLAKE8_FOUND OR NOT FLAKE8_EXECUTABLE)
 657     include("${CMAKE_CURRENT_LIST_DIR}/cmake/FindFlake8.cmake")
 658   endif()
 659   if(FLAKE8_FOUND)
 660     add_custom_target(check_flake8
 661         COMMAND "${FLAKE8_EXECUTABLE}" . --count --select=E9,E901,E999,F821,F822,F823 --show-source --statistics --exclude='.git,__pycache__,*.config.py,svgfig.py'
 662         WORKING_DIRECTORY "${OpenCV_SOURCE_DIR}"
 663         COMMENT "Running flake8"
 664     )
 665   endif()
 666 endif()
 667
 668
 669 if(ANDROID AND ANDROID_EXECUTABLE AND ANT_EXECUTABLE AND (ANT_VERSION VERSION_GREATER 1.7) AND (ANDROID_TOOLS_Pkg_Revision GREATER 13))
 670   SET(CAN_BUILD_ANDROID_PROJECTS TRUE)
 671 else()
 672   SET(CAN_BUILD_ANDROID_PROJECTS FALSE)
 673 endif()
 674
 675 # --- OpenCL ---
 676 if(WITH_OPENCL)
 677   include(cmake/OpenCVDetectOpenCL.cmake)
 678 endif()
 679
 680 # --- Halide ---
 681 if(WITH_HALIDE)
 682   include(cmake/OpenCVDetectHalide.cmake)
 683 endif()
 684
 685 # --- Inference Engine ---
 686 if(WITH_INF_ENGINE)
 687   include(cmake/OpenCVDetectInferenceEngine.cmake)
 688 endif()
 689
 690 # --- DirectX ---
 691 if(WITH_DIRECTX)
 692   include(cmake/OpenCVDetectDirectX.cmake)
 693 endif()
 694
 695 if(WITH_VTK)
 696   include(cmake/OpenCVDetectVTK.cmake)
 697 endif()
 698
 699 if(WITH_OPENVX)
 700   include(cmake/FindOpenVX.cmake)
 701 endif()
 702
 703 # ----------------------------------------------------------------------------
 704 # OpenCV HAL
 705 # ----------------------------------------------------------------------------
 706 set(_hal_includes "")
 707 macro(ocv_hal_register HAL_LIBRARIES_VAR HAL_HEADERS_VAR HAL_INCLUDE_DIRS_VAR)
 708   # 1. libraries
 709   foreach (l ${${HAL_LIBRARIES_VAR}})
 710     if(NOT TARGET ${l})
 711       get_filename_component(l "${l}" ABSOLUTE)
 712     endif()
 713     list(APPEND OPENCV_HAL_LINKER_LIBS ${l})
 714   endforeach()
 715   # 2. headers
 716   foreach (h ${${HAL_HEADERS_VAR}})
 717     set(_hal_includes "${_hal_includes}\n#include \"${h}\"")
 718   endforeach()
 719   # 3. include paths
 720   ocv_include_directories(${${HAL_INCLUDE_DIRS_VAR}})
 721 endmacro()
 722
 723 if(NOT DEFINED OpenCV_HAL)
 724   set(OpenCV_HAL "OpenCV_HAL")
 725 endif()
 726
 727 if(HAVE_OPENVX)
 728   if(NOT ";${OpenCV_HAL};" MATCHES ";openvx;")
 729     set(OpenCV_HAL "openvx;${OpenCV_HAL}")
 730   endif()
 731 endif()
 732
 733 if(WITH_CAROTENE)
 734   ocv_debug_message(STATUS "Enable carotene acceleration")
 735   if(NOT ";${OpenCV_HAL};" MATCHES ";carotene;")
 736     set(OpenCV_HAL "carotene;${OpenCV_HAL}")
 737   endif()
 738 endif()
 739
 740 foreach(hal ${OpenCV_HAL})
 741   if(hal STREQUAL "carotene")
 742     add_subdirectory(3rdparty/carotene/hal)
 743     ocv_hal_register(CAROTENE_HAL_LIBRARIES CAROTENE_HAL_HEADERS CAROTENE_HAL_INCLUDE_DIRS)
 744     list(APPEND OpenCV_USED_HAL "carotene (ver ${CAROTENE_HAL_VERSION})")
 745   elseif(hal STREQUAL "openvx")
 746     add_subdirectory(3rdparty/openvx)
 747     ocv_hal_register(OPENVX_HAL_LIBRARIES OPENVX_HAL_HEADERS OPENVX_HAL_INCLUDE_DIRS)
 748     list(APPEND OpenCV_USED_HAL "openvx (ver ${OPENVX_HAL_VERSION})")
 749   else()
 750     ocv_debug_message(STATUS "OpenCV HAL: ${hal} ...")
 751     ocv_clear_vars(OpenCV_HAL_LIBRARIES OpenCV_HAL_HEADERS OpenCV_HAL_INCLUDE_DIRS)
 752     find_package(${hal} NO_MODULE QUIET)
 753     if(${hal}_FOUND)
 754       ocv_hal_register(OpenCV_HAL_LIBRARIES OpenCV_HAL_HEADERS OpenCV_HAL_INCLUDE_DIRS)
 755       list(APPEND OpenCV_USED_HAL "${hal} (ver ${${hal}_VERSION})")
 756     endif()
 757   endif()
 758 endforeach()
 759 configure_file("${OpenCV_SOURCE_DIR}/cmake/templates/custom_hal.hpp.in" "${CMAKE_BINARY_DIR}/custom_hal.hpp" @ONLY)
 760 unset(_hal_includes)
 761
 762
 763 # ----------------------------------------------------------------------------
 764 # Add CUDA libraries (needed for apps/tools, samples)
 765 # ----------------------------------------------------------------------------
 766 if(HAVE_CUDA)
 767   set(OPENCV_LINKER_LIBS ${OPENCV_LINKER_LIBS} ${CUDA_LIBRARIES} ${CUDA_npp_LIBRARY})
 768   if(HAVE_CUBLAS)
 769     set(OPENCV_LINKER_LIBS ${OPENCV_LINKER_LIBS} ${CUDA_cublas_LIBRARY})
 770   endif()
 771   if(HAVE_CUFFT)
 772     set(OPENCV_LINKER_LIBS ${OPENCV_LINKER_LIBS} ${CUDA_cufft_LIBRARY})
 773   endif()
 774   foreach(p ${CUDA_LIBS_PATH})
 775     if(MSVC AND CMAKE_GENERATOR MATCHES "Ninja|JOM")
 776       set(OPENCV_LINKER_LIBS ${OPENCV_LINKER_LIBS} ${CMAKE_LIBRARY_PATH_FLAG}"${p}")
 777     else()
 778       set(OPENCV_LINKER_LIBS ${OPENCV_LINKER_LIBS} ${CMAKE_LIBRARY_PATH_FLAG}${p})
 779     endif()
 780   endforeach()
 781 endif()
 782
 783
 784 # ----------------------------------------------------------------------------
 785 # Code trace support
 786 # ----------------------------------------------------------------------------
 787 if(CV_TRACE)
 788   include(cmake/OpenCVDetectTrace.cmake)
 789 endif()
 790
 791 ocv_cmake_hook(POST_DETECT_DEPENDECIES)
 792
 793 # ----------------------------------------------------------------------------
 794 # Solution folders:
 795 # ----------------------------------------------------------------------------
 796 if(ENABLE_SOLUTION_FOLDERS)
 797   set_property(GLOBAL PROPERTY USE_FOLDERS ON)
 798   set_property(GLOBAL PROPERTY PREDEFINED_TARGETS_FOLDER "CMakeTargets")
 799 endif()
 800
 801 # Extra OpenCV targets: uninstall, package_source, perf, etc.
 802 include(cmake/OpenCVExtraTargets.cmake)
 803
 804 # ----------------------------------------------------------------------------
 805 # Process subdirectories
 806 # ----------------------------------------------------------------------------
 807
 808 # opencv.hpp and legacy headers
 809 add_subdirectory(include)
 810
 811 # Enable compiler options for OpenCV modules/apps/samples only (ignore 3rdparty)
 812 ocv_add_modules_compiler_options()
 813
 814 # OpenCV modules
 815 add_subdirectory(modules)
 816
 817 # Generate targets for documentation
 818 add_subdirectory(doc)
 819
 820 # various data that is used by cv libraries and/or demo applications.
 821 add_subdirectory(data)
 822
 823 # extra applications
 824 if(BUILD_opencv_apps)
 825   add_subdirectory(apps)
 826 endif()
 827
 828 # examples
 829 if(BUILD_EXAMPLES OR BUILD_ANDROID_EXAMPLES OR INSTALL_PYTHON_EXAMPLES OR INSTALL_C_EXAMPLES)
 830   add_subdirectory(samples)
 831 endif()
 832
 833 if(ANDROID)
 834   add_subdirectory(platforms/android/service)
 835 endif()
 836
 837 # ----------------------------------------------------------------------------
 838 # Finalization: generate configuration-based files
 839 # ----------------------------------------------------------------------------
 840
 841 ocv_cmake_hook(PRE_FINALIZE)
 842
 843 # Generate platform-dependent and configuration-dependent headers
 844 include(cmake/OpenCVGenHeaders.cmake)
 845
 846 # Generate opencv.pc for pkg-config command
 847 if(NOT OPENCV_SKIP_PKGCONFIG_GENERATION
 848     AND NOT CMAKE_GENERATOR MATCHES "Xcode")
 849   include(cmake/OpenCVGenPkgconfig.cmake)
 850 endif()
 851
 852 # Generate OpenCV.mk for ndk-build (Android build tool)
 853 include(cmake/OpenCVGenAndroidMK.cmake)
 854
 855 # Generate OpenCVConfig.cmake and OpenCVConfig-version.cmake for cmake projects
 856 include(cmake/OpenCVGenConfig.cmake)
 857
 858 # Generate Info.plist for the IOS framework
 859 if(APPLE_FRAMEWORK)
 860   include(cmake/OpenCVGenInfoPlist.cmake)
 861 endif()
 862
 863 # Generate ABI descriptor
 864 include(cmake/OpenCVGenABI.cmake)
 865
 866 # Generate environment setup file
 867 if(INSTALL_TESTS AND OPENCV_TEST_DATA_PATH)
 868   if(ANDROID)
 869     get_filename_component(TEST_PATH ${OPENCV_TEST_INSTALL_PATH} DIRECTORY)
 870     configure_file("${CMAKE_CURRENT_SOURCE_DIR}/cmake/templates/opencv_run_all_tests_android.sh.in"
 871                    "${CMAKE_BINARY_DIR}/unix-install/opencv_run_all_tests.sh" @ONLY)
 872     install(PROGRAMS "${CMAKE_BINARY_DIR}/unix-install/opencv_run_all_tests.sh"
 873             DESTINATION ./ COMPONENT tests)
 874   elseif(WIN32)
 875     configure_file("${CMAKE_CURRENT_SOURCE_DIR}/cmake/templates/opencv_run_all_tests_windows.cmd.in"
 876                    "${CMAKE_BINARY_DIR}/win-install/opencv_run_all_tests.cmd" @ONLY)
 877     install(PROGRAMS "${CMAKE_BINARY_DIR}/win-install/opencv_run_all_tests.cmd"
 878             DESTINATION ${OPENCV_TEST_INSTALL_PATH} COMPONENT tests)
 879   elseif(UNIX)
 880     configure_file("${CMAKE_CURRENT_SOURCE_DIR}/cmake/templates/opencv_run_all_tests_unix.sh.in"
 881                    "${CMAKE_BINARY_DIR}/unix-install/opencv_run_all_tests.sh" @ONLY)
 882     install(PROGRAMS "${CMAKE_BINARY_DIR}/unix-install/opencv_run_all_tests.sh"
 883             DESTINATION ${OPENCV_TEST_INSTALL_PATH} COMPONENT tests)
 884   endif()
 885 endif()
 886
 887 if(NOT OPENCV_README_FILE)
 888   if(ANDROID)
 889     set(OPENCV_README_FILE ${CMAKE_CURRENT_SOURCE_DIR}/platforms/android/README.android)
 890   endif()
 891 endif()
 892
 893 if(NOT OPENCV_LICENSE_FILE)
 894   set(OPENCV_LICENSE_FILE ${CMAKE_CURRENT_SOURCE_DIR}/LICENSE)
 895 endif()
 896
 897 # for UNIX it does not make sense as LICENSE and readme will be part of the package automatically
 898 if(ANDROID OR NOT UNIX)
 899   install(FILES ${OPENCV_LICENSE_FILE}
 900         PERMISSIONS OWNER_READ GROUP_READ WORLD_READ
 901         DESTINATION ./ COMPONENT libs)
 902   if(OPENCV_README_FILE)
 903     install(FILES ${OPENCV_README_FILE}
 904             PERMISSIONS OWNER_READ GROUP_READ WORLD_READ
 905             DESTINATION ./ COMPONENT libs)
 906   endif()
 907 endif()
 908
 909 if(COMMAND ocv_pylint_finalize)
 910   ocv_pylint_add_directory(${CMAKE_CURRENT_LIST_DIR}/modules/python/test)
 911   ocv_pylint_add_directory(${CMAKE_CURRENT_LIST_DIR}/samples/python)
 912   ocv_pylint_add_directory(${CMAKE_CURRENT_LIST_DIR}/samples/dnn)
 913   ocv_pylint_add_directory_recurse(${CMAKE_CURRENT_LIST_DIR}/samples/python/tutorial_code)
 914   ocv_pylint_finalize()
 915 endif()
 916
 917 # ----------------------------------------------------------------------------
 918 # Summary:
 919 # ----------------------------------------------------------------------------
 920 status("")
 921 status("General configuration for OpenCV ${OPENCV_VERSION} =====================================")
 922 if(OPENCV_VCSVERSION)
 923   status("  Version control:" ${OPENCV_VCSVERSION})
 924 endif()
 925 if(OPENCV_EXTRA_MODULES_PATH AND NOT BUILD_INFO_SKIP_EXTRA_MODULES)
 926   set(__dump_extra_header OFF)
 927   foreach(p ${OPENCV_EXTRA_MODULES_PATH})
 928     if(EXISTS ${p})
 929       if(NOT __dump_extra_header)
 930         set(__dump_extra_header ON)
 931         status("")
 932         status("  Extra modules:")
 933       else()
 934         status("")
 935       endif()
 936       ocv_git_describe(EXTRA_MODULES_VCSVERSION "${p}")
 937       status("    Location (extra):" ${p})
 938       status("    Version control (extra):" ${EXTRA_MODULES_VCSVERSION})
 939     endif()
 940   endforeach()
 941   unset(__dump_extra_header)
 942 endif()
 943
 944 # ========================== build platform ==========================
 945 status("")
 946 status("  Platform:")
 947 if(NOT DEFINED OPENCV_TIMESTAMP
 948     AND NOT CMAKE_VERSION VERSION_LESS 2.8.11
 949     AND NOT BUILD_INFO_SKIP_TIMESTAMP
 950 )
 951   string(TIMESTAMP OPENCV_TIMESTAMP "" UTC)
 952   set(OPENCV_TIMESTAMP "${OPENCV_TIMESTAMP}" CACHE STRING "Timestamp of OpenCV build configuration" FORCE)
 953 endif()
 954 if(OPENCV_TIMESTAMP)
 955   status("    Timestamp:"      ${OPENCV_TIMESTAMP})
 956 endif()
 957 status("    Host:"             ${CMAKE_HOST_SYSTEM_NAME} ${CMAKE_HOST_SYSTEM_VERSION} ${CMAKE_HOST_SYSTEM_PROCESSOR})
 958 if(CMAKE_CROSSCOMPILING)
 959   status("    Target:"         ${CMAKE_SYSTEM_NAME} ${CMAKE_SYSTEM_VERSION} ${CMAKE_SYSTEM_PROCESSOR})
 960 endif()
 961 status("    CMake:"            ${CMAKE_VERSION})
 962 status("    CMake generator:"  ${CMAKE_GENERATOR})
 963 status("    CMake build tool:" ${CMAKE_BUILD_TOOL})
 964 if(MSVC)
 965   status("    MSVC:"           ${MSVC_VERSION})
 966 endif()
 967 if(CMAKE_GENERATOR MATCHES Xcode)
 968   status("    Xcode:"          ${XCODE_VERSION})
 969 endif()
 970 if(NOT CMAKE_GENERATOR MATCHES "Xcode|Visual Studio")
 971   status("    Configuration:"  ${CMAKE_BUILD_TYPE})
 972 endif()
 973
 974
 975 # ========================= CPU code generation mode =========================
 976 status("")
 977 status("  CPU/HW features:")
 978 status("    Baseline:"  "${CPU_BASELINE_FINAL}")
 979 if(NOT CPU_BASELINE STREQUAL CPU_BASELINE_FINAL)
 980   status("      requested:"  "${CPU_BASELINE}")
 981 endif()
 982 if(CPU_BASELINE_REQUIRE)
 983   status("      required:"  "${CPU_BASELINE_REQUIRE}")
 984 endif()
 985 if(CPU_BASELINE_DISABLE)
 986   status("      disabled:"  "${CPU_BASELINE_DISABLE}")
 987 endif()
 988 if(CPU_DISPATCH_FINAL OR CPU_DISPATCH)
 989   status("    Dispatched code generation:"  "${CPU_DISPATCH_FINAL}")
 990   if(NOT CPU_DISPATCH STREQUAL CPU_DISPATCH_FINAL)
 991     status("      requested:"  "${CPU_DISPATCH}")
 992   endif()
 993   if(CPU_DISPATCH_REQUIRE)
 994     status("      required:"  "${CPU_DISPATCH_REQUIRE}")
 995   endif()
 996   foreach(OPT ${CPU_DISPATCH_FINAL})
 997     status("      ${OPT} (${CPU_${OPT}_USAGE_COUNT} files):"  "+ ${CPU_DISPATCH_${OPT}_INCLUDED}")
 998   endforeach()
 999 endif()
1000
1001 # ========================== C/C++ options ==========================
1002 if(CMAKE_CXX_COMPILER_VERSION)
1003   set(OPENCV_COMPILER_STR "${CMAKE_CXX_COMPILER} ${CMAKE_CXX_COMPILER_ARG1} (ver ${CMAKE_CXX_COMPILER_VERSION})")
1004 else()
1005   set(OPENCV_COMPILER_STR "${CMAKE_CXX_COMPILER} ${CMAKE_CXX_COMPILER_ARG1}")
1006 endif()
1007 string(STRIP "${OPENCV_COMPILER_STR}" OPENCV_COMPILER_STR)
1008
1009 status("")
1010 status("  C/C++:")
1011 status("    Built as dynamic libs?:" BUILD_SHARED_LIBS THEN YES ELSE NO)
1012 if(ENABLE_CXX11 OR HAVE_CXX11)
1013 status("    C++11:" HAVE_CXX11 THEN YES ELSE NO)
1014 endif()
1015 status("    C++ Compiler:"           ${OPENCV_COMPILER_STR})
1016 status("    C++ flags (Release):"    ${CMAKE_CXX_FLAGS} ${CMAKE_CXX_FLAGS_RELEASE})
1017 status("    C++ flags (Debug):"      ${CMAKE_CXX_FLAGS} ${CMAKE_CXX_FLAGS_DEBUG})
1018 status("    C Compiler:"             ${CMAKE_C_COMPILER} ${CMAKE_C_COMPILER_ARG1})
1019 status("    C flags (Release):"      ${CMAKE_C_FLAGS} ${CMAKE_C_FLAGS_RELEASE})
1020 status("    C flags (Debug):"        ${CMAKE_C_FLAGS} ${CMAKE_C_FLAGS_DEBUG})
1021 if(WIN32)
1022   status("    Linker flags (Release):" ${CMAKE_EXE_LINKER_FLAGS} ${CMAKE_EXE_LINKER_FLAGS_RELEASE})
1023   status("    Linker flags (Debug):"   ${CMAKE_EXE_LINKER_FLAGS} ${CMAKE_EXE_LINKER_FLAGS_DEBUG})
1024 else()
1025   status("    Linker flags (Release):" ${CMAKE_SHARED_LINKER_FLAGS} ${CMAKE_SHARED_LINKER_FLAGS_RELEASE})
1026   status("    Linker flags (Debug):"   ${CMAKE_SHARED_LINKER_FLAGS} ${CMAKE_SHARED_LINKER_FLAGS_DEBUG})
1027 endif()
1028 status("    ccache:"                  OPENCV_COMPILER_IS_CCACHE THEN YES ELSE NO)
1029 status("    Precompiled headers:"     PCHSupport_FOUND AND ENABLE_PRECOMPILED_HEADERS THEN YES ELSE NO)
1030
1031 # ========================== Dependencies ============================
1032 ocv_get_all_libs(deps_modules deps_extra deps_3rdparty)
1033 status("    Extra dependencies:" ${deps_extra})
1034 status("    3rdparty dependencies:" ${deps_3rdparty})
1035
1036 # ========================== OpenCV modules ==========================
1037 status("")
1038 status("  OpenCV modules:")
1039 string(REPLACE "opencv_" "" OPENCV_MODULES_BUILD_ST          "${OPENCV_MODULES_BUILD}")
1040 string(REPLACE "opencv_" "" OPENCV_MODULES_DISABLED_USER_ST  "${OPENCV_MODULES_DISABLED_USER}")
1041 string(REPLACE "opencv_" "" OPENCV_MODULES_DISABLED_AUTO_ST  "${OPENCV_MODULES_DISABLED_AUTO}")
1042 string(REPLACE "opencv_" "" OPENCV_MODULES_DISABLED_FORCE_ST "${OPENCV_MODULES_DISABLED_FORCE}")
1043 list(SORT OPENCV_MODULES_BUILD_ST)
1044 list(SORT OPENCV_MODULES_DISABLED_USER_ST)
1045 list(SORT OPENCV_MODULES_DISABLED_AUTO_ST)
1046 list(SORT OPENCV_MODULES_DISABLED_FORCE_ST)
1047 status("    To be built:"            OPENCV_MODULES_BUILD          THEN ${OPENCV_MODULES_BUILD_ST}          ELSE "-")
1048 status("    Disabled:"               OPENCV_MODULES_DISABLED_USER  THEN ${OPENCV_MODULES_DISABLED_USER_ST}  ELSE "-")
1049 status("    Disabled by dependency:" OPENCV_MODULES_DISABLED_AUTO  THEN ${OPENCV_MODULES_DISABLED_AUTO_ST}  ELSE "-")
1050 status("    Unavailable:"            OPENCV_MODULES_DISABLED_FORCE THEN ${OPENCV_MODULES_DISABLED_FORCE_ST} ELSE "-")
1051
1052 ocv_build_features_string(apps_status
1053   IF BUILD_TESTS AND HAVE_opencv_ts THEN "tests"
1054   IF BUILD_PERF_TESTS AND HAVE_opencv_ts THEN "perf_tests"
1055   IF BUILD_EXAMPLES THEN "examples"
1056   IF BUILD_opencv_apps THEN "apps"
1057   IF BUILD_ANDROID_SERVICE THEN "android_service"
1058   IF BUILD_ANDROID_EXAMPLES AND CAN_BUILD_ANDROID_PROJECTS THEN "android_examples"
1059   ELSE "-")
1060 status("    Applications:" "${apps_status}")
1061 ocv_build_features_string(docs_status
1062     IF TARGET doxygen_cpp THEN "doxygen"
1063     IF TARGET doxygen_python THEN "python"
1064     IF TARGET doxygen_javadoc THEN "javadoc"
1065     IF BUILD_opencv_js OR DEFINED OPENCV_JS_LOCATION THEN "js"
1066     ELSE "NO"
1067 )
1068 status("    Documentation:" "${docs_status}")
1069 status("    Non-free algorithms:" OPENCV_ENABLE_NONFREE THEN "YES" ELSE "NO")
1070
1071 # ========================== Android details ==========================
1072 if(ANDROID)
1073   status("")
1074   if(DEFINED ANDROID_NDK_REVISION)
1075     set(__msg "${ANDROID_NDK} (ver ${ANDROID_NDK_REVISION})")
1076   else()
1077     set(__msg "location: ${ANDROID_NDK}")
1078   endif()
1079   status("  Android NDK: " ${__msg})
1080   status("    Android ABI:" ${ANDROID_ABI})
1081   if(BUILD_WITH_STANDALONE_TOOLCHAIN)
1082     status("    NDK toolchain:" "standalone: ${ANDROID_STANDALONE_TOOLCHAIN}")
1083   elseif(BUILD_WITH_ANDROID_NDK OR DEFINED ANDROID_TOOLCHAIN_NAME)
1084     status("    NDK toolchain:" "${ANDROID_TOOLCHAIN_NAME}")
1085   endif()
1086   status("    STL type:" ${ANDROID_STL})
1087   status("    Native API level:" ${ANDROID_NATIVE_API_LEVEL})
1088
1089   if(BUILD_ANDROID_PROJECTS)
1090     status("  Android SDK: " "${ANDROID_SDK} (tools: ${ANDROID_SDK_TOOLS_VERSION} build tools: ${ANDROID_SDK_BUILD_TOOLS_VERSION})")
1091     if(ANDROID_EXECUTABLE)
1092       status("    android tool:"  "${ANDROID_EXECUTABLE}")
1093     endif()
1094   else()
1095     status("  Android SDK: " "not used, projects are not built")
1096   endif()
1097   if(DEFINED ANDROID_SDK_COMPATIBLE_TARGET)
1098     status("    SDK target:" "${ANDROID_SDK_COMPATIBLE_TARGET}")
1099   endif()
1100   if(DEFINED ANDROID_PROJECTS_BUILD_TYPE)
1101     if(ANDROID_PROJECTS_BUILD_TYPE STREQUAL "ANT")
1102       status("    Projects build scripts:" "Ant/Eclipse compatible")
1103     elseif(ANDROID_PROJECTS_BUILD_TYPE STREQUAL "ANT")
1104       status("    Projects build scripts:" "Gradle")
1105     endif()
1106   endif()
1107 endif()
1108
1109 # ================== Windows RT features ==================
1110 if(WIN32)
1111 status("")
1112 status("  Windows RT support:" WINRT THEN YES ELSE NO)
1113   if(WINRT)
1114     status("    Building for Microsoft platform: " ${CMAKE_SYSTEM_NAME})
1115     status("    Building for architectures: " ${CMAKE_VS_EFFECTIVE_PLATFORMS})
1116     status("    Building for version: " ${CMAKE_SYSTEM_VERSION})
1117     if (DEFINED ENABLE_WINRT_MODE_NATIVE)
1118       status("    Building for C++ without CX extensions")
1119     endif()
1120   endif()
1121 endif(WIN32)
1122
1123 # ========================== GUI ==========================
1124 status("")
1125 status("  GUI: ")
1126
1127 if(WITH_QT OR HAVE_QT)
1128   if(HAVE_QT5)
1129     status("    QT:" "YES (ver ${Qt5Core_VERSION_STRING})")
1130     status("      QT OpenGL support:" HAVE_QT_OPENGL THEN "YES (${Qt5OpenGL_LIBRARIES} ${Qt5OpenGL_VERSION_STRING})" ELSE NO)
1131   elseif(HAVE_QT)
1132     status("    QT:" "YES (ver ${QT_VERSION_MAJOR}.${QT_VERSION_MINOR}.${QT_VERSION_PATCH} ${QT_EDITION})")
1133     status("      QT OpenGL support:" HAVE_QT_OPENGL THEN "YES (${QT_QTOPENGL_LIBRARY})" ELSE NO)
1134   else()
1135     status("    QT:" "NO")
1136   endif()
1137 endif()
1138
1139 if(WITH_WIN32UI)
1140   status("    Win32 UI:" HAVE_WIN32UI THEN YES ELSE NO)
1141 endif()
1142
1143 if(APPLE)
1144   if(WITH_CARBON)
1145     status("    Carbon:" YES)
1146   else()
1147     status("    Cocoa:"  YES)
1148   endif()
1149 endif()
1150
1151 if(WITH_GTK OR HAVE_GTK)
1152   if(HAVE_GTK3)
1153     status("    GTK+:" "YES (ver ${ALIASOF_gtk+-3.0_VERSION})")
1154   elseif(HAVE_GTK)
1155     status("    GTK+:" "YES (ver ${ALIASOF_gtk+-2.0_VERSION})")
1156   else()
1157     status("    GTK+:" "NO")
1158   endif()
1159   if(HAVE_GTK)
1160     status(  "      GThread :" HAVE_GTHREAD THEN "YES (ver ${ALIASOF_gthread-2.0_VERSION})" ELSE NO)
1161     status(  "      GtkGlExt:" HAVE_GTKGLEXT THEN "YES (ver ${ALIASOF_gtkglext-1.0_VERSION})" ELSE NO)
1162   endif()
1163 endif()
1164
1165 if(WITH_OPENGL OR HAVE_OPENGL)
1166   status("    OpenGL support:" HAVE_OPENGL THEN "YES (${OPENGL_LIBRARIES})" ELSE NO)
1167 endif()
1168
1169 if(WITH_VTK OR HAVE_VTK)
1170   status("    VTK support:" HAVE_VTK THEN "YES (ver ${VTK_VERSION})" ELSE NO)
1171 endif()
1172
1173 # ========================== MEDIA IO ==========================
1174 status("")
1175 status("  Media I/O: ")
1176 status("    ZLib:"   ZLIB_FOUND THEN "${ZLIB_LIBRARIES} (ver ${ZLIB_VERSION_STRING})" ELSE "build (ver ${ZLIB_VERSION_STRING})")
1177
1178 if(WITH_JPEG OR HAVE_JPEG)
1179   if(NOT HAVE_JPEG)
1180     status("    JPEG:" NO)
1181   elseif(BUILD_JPEG)
1182     status("    JPEG:" "build-${JPEG_LIBRARY} (ver ${JPEG_LIB_VERSION})")
1183   else()
1184     status("    JPEG:" "${JPEG_LIBRARY} (ver ${JPEG_LIB_VERSION})")
1185   endif()
1186 endif()
1187
1188 if(WITH_WEBP OR HAVE_WEBP)
1189   status("    WEBP:" WEBP_FOUND THEN "${WEBP_LIBRARY} (ver ${WEBP_VERSION})" ELSE "build (ver ${WEBP_VERSION})")
1190 endif()
1191
1192 if(WITH_PNG OR HAVE_PNG)
1193   status("    PNG:"  PNG_FOUND  THEN "${PNG_LIBRARY} (ver ${PNG_VERSION})" ELSE "build (ver ${PNG_VERSION})")
1194 endif()
1195
1196 if(WITH_TIFF OR HAVE_TIFF)
1197   status("    TIFF:" TIFF_FOUND THEN "${TIFF_LIBRARY} (ver ${TIFF_VERSION} / ${TIFF_VERSION_STRING})" ELSE "build (ver ${TIFF_VERSION} - ${TIFF_VERSION_STRING})")
1198 endif()
1199
1200 if(WITH_JASPER OR HAVE_JASPER)
1201   status("    JPEG 2000:" JASPER_FOUND THEN "${JASPER_LIBRARY} (ver ${JASPER_VERSION_STRING})" ELSE "build (ver ${JASPER_VERSION_STRING})")
1202 endif()
1203
1204 if(WITH_OPENEXR OR HAVE_OPENEXR)
1205   status("    OpenEXR:" OPENEXR_FOUND THEN "${OPENEXR_LIBRARIES} (ver ${OPENEXR_VERSION})" ELSE "build (ver ${OPENEXR_VERSION})")
1206 endif()
1207
1208 if(WITH_GDAL OR HAVE_GDAL)
1209   status("    GDAL:" HAVE_GDAL THEN "YES (${GDAL_LIBRARY})" ELSE "NO")
1210 endif()
1211
1212 if(WITH_GDCM OR HAVE_GDCM)
1213   status("    GDCM:" HAVE_GDCM THEN "YES (ver ${GDCM_VERSION})" ELSE "NO")
1214 endif()
1215
1216 if(WITH_IMGCODEC_HDR OR DEFINED HAVE_IMGCODEC_HDR)
1217   status("    HDR:" HAVE_IMGCODEC_HDR THEN "YES" ELSE "NO")
1218 endif()
1219
1220 if(WITH_IMGCODEC_SUNRASTER OR DEFINED HAVE_IMGCODEC_SUNRASTER)
1221   status("    SUNRASTER:" HAVE_IMGCODEC_SUNRASTER THEN "YES" ELSE "NO")
1222 endif()
1223
1224 if(WITH_IMGCODEC_PXM OR DEFINED HAVE_IMGCODEC_PXM)
1225   status("    PXM:" HAVE_IMGCODEC_PXM THEN "YES" ELSE "NO")
1226 endif()
1227
1228 # ========================== VIDEO IO ==========================
1229 status("")
1230 status("  Video I/O:")
1231
1232 if(WITH_VFW OR HAVE_VFW)
1233   status("    Video for Windows:" HAVE_VFW         THEN YES                                        ELSE NO)
1234 endif()
1235
1236 if(WITH_1394 OR HAVE_DC1394)
1237   if (HAVE_DC1394_2)
1238     status("    DC1394:" "YES (ver ${ALIASOF_libdc1394-2_VERSION})")
1239   elseif (HAVE_DC1394)
1240     status("    DC1394:" "YES (ver ${ALIASOF_libdc1394_VERSION})")
1241   else()
1242     status("    DC1394:" "NO")
1243   endif()
1244 endif()
1245
1246 if(WITH_FFMPEG OR HAVE_FFMPEG)
1247   if(OPENCV_FFMPEG_USE_FIND_PACKAGE)
1248     status("    FFMPEG:"       HAVE_FFMPEG         THEN "YES (find_package)"                       ELSE "NO (find_package)")
1249   elseif(WIN32)
1250     status("    FFMPEG:"       HAVE_FFMPEG         THEN "YES (prebuilt binaries)"                  ELSE NO)
1251   else()
1252     status("    FFMPEG:"       HAVE_FFMPEG         THEN YES ELSE NO)
1253   endif()
1254   status("      avcodec:"      FFMPEG_libavcodec_FOUND    THEN "YES (ver ${FFMPEG_libavcodec_VERSION})"    ELSE NO)
1255   status("      avformat:"     FFMPEG_libavformat_FOUND   THEN "YES (ver ${FFMPEG_libavformat_VERSION})"   ELSE NO)
1256   status("      avutil:"       FFMPEG_libavutil_FOUND     THEN "YES (ver ${FFMPEG_libavutil_VERSION})"     ELSE NO)
1257   status("      swscale:"      FFMPEG_libswscale_FOUND    THEN "YES (ver ${FFMPEG_libswscale_VERSION})"    ELSE NO)
1258   status("      avresample:"   FFMPEG_libavresample_FOUND THEN "YES (ver ${FFMPEG_libavresample_VERSION})" ELSE NO)
1259 endif()
1260
1261 if(WITH_GSTREAMER OR HAVE_GSTREAMER)
1262   status("    GStreamer:"      HAVE_GSTREAMER      THEN ""                                         ELSE NO)
1263   if(HAVE_GSTREAMER)
1264     status("      base:"       "YES (ver ${GSTREAMER_BASE_VERSION})")
1265     status("      video:"      "YES (ver ${GSTREAMER_VIDEO_VERSION})")
1266     status("      app:"        "YES (ver ${GSTREAMER_APP_VERSION})")
1267     status("      riff:"       "YES (ver ${GSTREAMER_RIFF_VERSION})")
1268     status("      pbutils:"    "YES (ver ${GSTREAMER_PBUTILS_VERSION})")
1269   endif(HAVE_GSTREAMER)
1270 endif()
1271
1272 if(WITH_OPENNI OR HAVE_OPENNI)
1273   status("    OpenNI:"         HAVE_OPENNI         THEN "YES (ver ${OPENNI_VERSION_STRING}, build ${OPENNI_VERSION_BUILD})" ELSE NO)
1274   status("    OpenNI PrimeSensor Modules:" HAVE_OPENNI_PRIME_SENSOR_MODULE THEN "YES (${OPENNI_PRIME_SENSOR_MODULE})"      ELSE NO)
1275 endif()
1276
1277 if(WITH_OPENNI2 OR HAVE_OPENNI2)
1278   status("    OpenNI2:"        HAVE_OPENNI2    THEN "YES (ver ${OPENNI2_VERSION_STRING}, build ${OPENNI2_VERSION_BUILD})" ELSE NO)
1279 endif()
1280
1281 if(WITH_PVAPI OR HAVE_PVAPI)
1282   status("    PvAPI:"          HAVE_PVAPI          THEN YES                                        ELSE NO)
1283 endif()
1284
1285 if(WITH_GIGEAPI OR HAVE_GIGE_API)
1286   status("    GigEVisionSDK:"  HAVE_GIGE_API       THEN YES                                        ELSE NO)
1287 endif()
1288
1289 if(WITH_ARAVIS OR HAVE_ARAVIS_API)
1290   status("    Aravis SDK:"     HAVE_ARAVIS_API     THEN "YES (${ARAVIS_LIBRARIES})"                ELSE NO)
1291 endif()
1292
1293 if(APPLE)
1294   status("    AVFoundation:"   HAVE_AVFOUNDATION   THEN YES                                        ELSE NO)
1295   if(WITH_QUICKTIME OR HAVE_QUICKTIME)
1296     status("    QuickTime:"      HAVE_QUICKTIME      THEN YES                                        ELSE NO)
1297   endif()
1298   if(WITH_QTKIT OR HAVE_QTKIT)
1299     status("    QTKit:"          HAVE_QTKIT          THEN "YES (deprecated)"                         ELSE NO)
1300   endif()
1301 endif()
1302
1303 if(WITH_UNICAP OR HAVE_UNICAP)
1304   status("    UniCap:"         HAVE_UNICAP         THEN "YES (ver ${ALIASOF_libunicap_VERSION})"   ELSE NO)
1305   status("    UniCap ucil:"    HAVE_UNICAP_UCIL    THEN "YES (ver ${ALIASOF_libucil_VERSION})"     ELSE NO)
1306 endif()
1307
1308 if(WITH_V4L OR WITH_LIBV4L OR HAVE_LIBV4L OR HAVE_CAMV4L OR HAVE_CAMV4L2 OR HAVE_VIDEOIO)
1309   status("    libv4l/libv4l2:" HAVE_LIBV4L THEN "${ALIASOF_libv4l1_VERSION} / ${ALIASOF_libv4l2_VERSION}" ELSE "NO")
1310   ocv_build_features_string(v4l_status
1311     IF HAVE_CAMV4L THEN "linux/videodev.h"
1312     IF HAVE_CAMV4L2 THEN "linux/videodev2.h"
1313     IF HAVE_VIDEOIO THEN "sys/videoio.h"
1314     ELSE "NO")
1315   status("    v4l/v4l2:" "${v4l_status}")
1316 endif()
1317
1318 if(WITH_DSHOW OR HAVE_DSHOW)
1319   status("    DirectShow:"     HAVE_DSHOW     THEN YES                                        ELSE NO)
1320 endif()
1321
1322 if(WITH_MSMF OR HAVE_MSMF)
1323   status("    Media Foundation:" HAVE_MSMF    THEN YES                                        ELSE NO)
1324 endif()
1325
1326 if(WITH_XIMEA OR HAVE_XIMEA)
1327   status("    XIMEA:"          HAVE_XIMEA          THEN YES                                        ELSE NO)
1328 endif()
1329
1330 if(WITH_XINE OR HAVE_XINE)
1331   status("    Xine:"           HAVE_XINE           THEN "YES (ver ${ALIASOF_libxine_VERSION})"     ELSE NO)
1332 endif()
1333
1334 if(WITH_INTELPERC OR HAVE_INTELPERC)
1335   status("    Intel PerC:"     HAVE_INTELPERC      THEN "YES"                                 ELSE NO)
1336 endif()
1337
1338 if(WITH_MFX OR HAVE_MFX)
1339   status("    Intel Media SDK:" HAVE_MFX      THEN "YES (${MFX_LIBRARY})" ELSE NO)
1340 endif()
1341
1342 if(WITH_GPHOTO2 OR HAVE_GPHOTO2)
1343   status("    gPhoto2:"        HAVE_GPHOTO2        THEN "YES"                                 ELSE NO)
1344 endif()
1345
1346 # Order is similar to CV_PARALLEL_FRAMEWORK in core/src/parallel.cpp
1347 ocv_build_features_string(parallel_status EXCLUSIVE
1348   IF HAVE_TBB THEN "TBB (ver ${TBB_VERSION_MAJOR}.${TBB_VERSION_MINOR} interface ${TBB_INTERFACE_VERSION})"
1349   IF HAVE_CSTRIPES THEN "C="
1350   IF HAVE_OPENMP THEN "OpenMP"
1351   IF HAVE_GCD THEN "GCD"
1352   IF WINRT OR HAVE_CONCURRENCY THEN "Concurrency"
1353   IF HAVE_PTHREADS_PF THEN "pthreads"
1354   ELSE "none")
1355 status("")
1356 status("  Parallel framework:" "${parallel_status}")
1357
1358 if(CV_TRACE OR OPENCV_TRACE)
1359   ocv_build_features_string(trace_status EXCLUSIVE
1360     IF HAVE_ITT THEN "with Intel ITT"
1361     ELSE "built-in")
1362   status("")
1363   status("  Trace: " OPENCV_TRACE THEN "YES (${trace_status})" ELSE NO)
1364 endif()
1365
1366 # ========================== Other third-party libraries ==========================
1367 status("")
1368 status("  Other third-party libraries:")
1369
1370 if(WITH_IPP AND HAVE_IPP)
1371   status("    Intel IPP:" "${IPP_VERSION_STR} [${IPP_VERSION_MAJOR}.${IPP_VERSION_MINOR}.${IPP_VERSION_BUILD}]")
1372   status("           at:" "${IPP_ROOT_DIR}")
1373   if(NOT HAVE_IPP_ICV)
1374     status("       linked:" BUILD_WITH_DYNAMIC_IPP THEN "dynamic" ELSE "static")
1375   endif()
1376   if(HAVE_IPP_IW)
1377     if(BUILD_IPP_IW)
1378       status("    Intel IPP IW:" "sources (${IW_VERSION_MAJOR}.${IW_VERSION_MINOR}.${IW_VERSION_UPDATE})")
1379     else()
1380       status("    Intel IPP IW:" "binaries (${IW_VERSION_MAJOR}.${IW_VERSION_MINOR}.${IW_VERSION_UPDATE})")
1381     endif()
1382     status("              at:" "${IPP_IW_PATH}")
1383   else()
1384     status("    Intel IPP IW:"   NO)
1385   endif()
1386 endif()
1387
1388 if(WITH_VA OR HAVE_VA)
1389   status("    VA:"            HAVE_VA          THEN "YES" ELSE NO)
1390 endif()
1391
1392 if(WITH_VA_INTEL OR HAVE_VA_INTEL)
1393   status("    Intel VA-API/OpenCL:"  HAVE_VA_INTEL       THEN "YES (OpenCL: ${VA_INTEL_IOCL_ROOT})" ELSE NO)
1394 endif()
1395
1396 if(WITH_LAPACK OR HAVE_LAPACK)
1397   status("    Lapack:"      HAVE_LAPACK     THEN "YES (${LAPACK_LIBRARIES})" ELSE NO)
1398 endif()
1399
1400 if(WITH_HALIDE OR HAVE_HALIDE)
1401   status("    Halide:"     HAVE_HALIDE      THEN "YES (${HALIDE_LIBRARIES} ${HALIDE_INCLUDE_DIRS})" ELSE NO)
1402 endif()
1403
1404 if(WITH_INF_ENGINE OR INF_ENGINE_TARGET)
1405   if(INF_ENGINE_TARGET)
1406     set(__msg "YES (${INF_ENGINE_RELEASE} / ${INF_ENGINE_VERSION})")
1407     get_target_property(_lib ${INF_ENGINE_TARGET} IMPORTED_LOCATION)
1408     if(NOT _lib)
1409       get_target_property(_lib_rel ${INF_ENGINE_TARGET} IMPORTED_IMPLIB_RELEASE)
1410       get_target_property(_lib_dbg ${INF_ENGINE_TARGET} IMPORTED_IMPLIB_DEBUG)
1411       set(_lib "${_lib_rel} / ${_lib_dbg}")
1412     endif()
1413     get_target_property(_inc ${INF_ENGINE_TARGET} INTERFACE_INCLUDE_DIRECTORIES)
1414     status("    Inference Engine:" "${__msg}")
1415     status("                libs:" "${_lib}")
1416     status("            includes:" "${_inc}")
1417   else()
1418     status("    Inference Engine:"     "NO")
1419   endif()
1420 endif()
1421
1422 if(WITH_EIGEN OR HAVE_EIGEN)
1423   status("    Eigen:"      HAVE_EIGEN       THEN "YES (ver ${EIGEN_WORLD_VERSION}.${EIGEN_MAJOR_VERSION}.${EIGEN_MINOR_VERSION})" ELSE NO)
1424 endif()
1425
1426 if(WITH_OPENVX OR HAVE_OPENVX)
1427   status("    OpenVX:"     HAVE_OPENVX      THEN "YES (${OPENVX_LIBRARIES})" ELSE "NO")
1428 endif()
1429
1430 status("    Custom HAL:" OpenCV_USED_HAL  THEN "YES (${OpenCV_USED_HAL})" ELSE "NO")
1431
1432 foreach(s ${CUSTOM_STATUS})
1433   status(${CUSTOM_STATUS_${s}})
1434 endforeach()
1435
1436 if(WITH_CUDA OR HAVE_CUDA)
1437   ocv_build_features_string(cuda_features
1438     IF HAVE_CUFFT THEN "CUFFT"
1439     IF HAVE_CUBLAS THEN "CUBLAS"
1440     IF HAVE_NVCUVID THEN "NVCUVID"
1441     IF CUDA_FAST_MATH THEN "FAST_MATH"
1442     ELSE "no extra features")
1443   status("")
1444   status("  NVIDIA CUDA:" HAVE_CUDA THEN "YES (ver ${CUDA_VERSION_STRING}, ${cuda_features})" ELSE NO)
1445   if(HAVE_CUDA)
1446     status("    NVIDIA GPU arch:"      ${OPENCV_CUDA_ARCH_BIN})
1447     status("    NVIDIA PTX archs:"     ${OPENCV_CUDA_ARCH_PTX})
1448   endif()
1449 endif()
1450
1451 if(WITH_OPENCL OR HAVE_OPENCL)
1452   ocv_build_features_string(opencl_features
1453     IF HAVE_OPENCL_SVM THEN "SVM"
1454     IF HAVE_CLAMDFFT THEN "AMDFFT"
1455     IF HAVE_CLAMDBLAS THEN "AMDBLAS"
1456     ELSE "no extra features")
1457   status("")
1458   status("  OpenCL:"     HAVE_OPENCL   THEN   "YES (${opencl_features})" ELSE "NO")
1459   if(HAVE_OPENCL)
1460     status("    Include path:"  OPENCL_INCLUDE_DIRS THEN "${OPENCL_INCLUDE_DIRS}" ELSE "NO")
1461     status("    Link libraries:"       OPENCL_LIBRARIES THEN "${OPENCL_LIBRARIES}" ELSE "Dynamic load")
1462   endif()
1463 endif()
1464
1465 # ========================== python ==========================
1466 if(BUILD_opencv_python2)
1467   status("")
1468   status("  Python 2:")
1469   status("    Interpreter:"     PYTHON2INTERP_FOUND  THEN "${PYTHON2_EXECUTABLE} (ver ${PYTHON2_VERSION_STRING})"       ELSE NO)
1470   if(PYTHON2LIBS_VERSION_STRING)
1471     status("    Libraries:"   HAVE_opencv_python2  THEN  "${PYTHON2_LIBRARIES} (ver ${PYTHON2LIBS_VERSION_STRING})"   ELSE NO)
1472   else()
1473     status("    Libraries:"   HAVE_opencv_python2  THEN  "${PYTHON2_LIBRARIES}"                                      ELSE NO)
1474   endif()
1475   status("    numpy:"         PYTHON2_NUMPY_INCLUDE_DIRS THEN "${PYTHON2_NUMPY_INCLUDE_DIRS} (ver ${PYTHON2_NUMPY_VERSION})" ELSE "NO (Python wrappers can not be generated)")
1476   status("    packages path:" PYTHON2_EXECUTABLE         THEN "${PYTHON2_PACKAGES_PATH}"                                    ELSE "-")
1477 endif()
1478
1479 if(BUILD_opencv_python3)
1480   status("")
1481   status("  Python 3:")
1482   status("    Interpreter:"     PYTHON3INTERP_FOUND  THEN "${PYTHON3_EXECUTABLE} (ver ${PYTHON3_VERSION_STRING})"       ELSE NO)
1483   if(PYTHON3LIBS_VERSION_STRING)
1484     status("    Libraries:"   HAVE_opencv_python3  THEN  "${PYTHON3_LIBRARIES} (ver ${PYTHON3LIBS_VERSION_STRING})"   ELSE NO)
1485   else()
1486     status("    Libraries:"   HAVE_opencv_python3  THEN  "${PYTHON3_LIBRARIES}"                                      ELSE NO)
1487   endif()
1488   status("    numpy:"         PYTHON3_NUMPY_INCLUDE_DIRS THEN "${PYTHON3_NUMPY_INCLUDE_DIRS} (ver ${PYTHON3_NUMPY_VERSION})" ELSE "NO (Python3 wrappers can not be generated)")
1489   status("    packages path:" PYTHON3_EXECUTABLE         THEN "${PYTHON3_PACKAGES_PATH}"                                    ELSE "-")
1490 endif()
1491
1492 status("")
1493 status("  Python (for build):"  PYTHON_DEFAULT_AVAILABLE THEN "${PYTHON_DEFAULT_EXECUTABLE}" ELSE NO)
1494 if(PYLINT_FOUND AND PYLINT_EXECUTABLE)
1495   status("    Pylint:"  PYLINT_FOUND THEN "${PYLINT_EXECUTABLE} (ver: ${PYLINT_VERSION}, checks: ${PYLINT_TOTAL_TARGETS})" ELSE NO)
1496 endif()
1497 if(FLAKE8_FOUND AND FLAKE8_EXECUTABLE)
1498   status("    Flake8:"  FLAKE8_FOUND THEN "${FLAKE8_EXECUTABLE} (ver: ${FLAKE8_VERSION})" ELSE NO)
1499 endif()
1500
1501 # ========================== java ==========================
1502 if(BUILD_JAVA OR BUILD_opencv_java)
1503   status("")
1504   status("  Java:"            BUILD_FAT_JAVA_LIB  THEN "export all functions"                                      ELSE "")
1505   status("    ant:"           ANT_EXECUTABLE      THEN "${ANT_EXECUTABLE} (ver ${ANT_VERSION})"                    ELSE NO)
1506   if(NOT ANDROID)
1507     status("    JNI:"         JNI_INCLUDE_DIRS    THEN "${JNI_INCLUDE_DIRS}"                                       ELSE NO)
1508   endif()
1509   status("    Java wrappers:" HAVE_opencv_java                                                            THEN YES ELSE NO)
1510   status("    Java tests:"    BUILD_TESTS AND opencv_test_java_BINARY_DIR                                 THEN YES ELSE NO)
1511 endif()
1512
1513 ocv_cmake_hook(STATUS_DUMP_EXTRA)
1514
1515 # ========================== auxiliary ==========================
1516 status("")
1517 status("  Install to:" "${CMAKE_INSTALL_PREFIX}")
1518 status("-----------------------------------------------------------------")
1519 status("")
1520
1521
1522 ocv_finalize_status()
1523
1524 ocv_cmake_hook(POST_FINALIZE)
1525
1526 # ----------------------------------------------------------------------------
1527 # CPack stuff
1528 # ----------------------------------------------------------------------------
1529
1530 include(cmake/OpenCVPackaging.cmake)
1531
1532 # This should be the last command
1533 ocv_cmake_dump_vars("" TOFILE "CMakeVars.txt")
1534 ocv_cmake_eval(DEBUG_POST ONCE)