CMakeLists.txt

   1 # ----------------------------------------------------------------------------
   2 #  Root CMake file for OpenCV
   3 #
   4 #    From the off-tree build directory, invoke:
   5 #      $ cmake <PATH_TO_OPENCV_ROOT>
   6 #
   7 #
   8 #   - OCT-2008: Initial version <joseluisblancoc@gmail.com>
   9 #
  10 # ----------------------------------------------------------------------------
  11
  12 set(CMAKE_ALLOW_LOOSE_LOOP_CONSTRUCTS true)
  13
  14 # Following block can broke build in case of cross-compilng
  15 # but CMAKE_CROSSCOMPILING variable will be set only on project(OpenCV) command
  16 # so we will try to detect crosscompiling by presense of CMAKE_TOOLCHAIN_FILE
  17 if(NOT CMAKE_TOOLCHAIN_FILE)
  18   # it _must_ go before project(OpenCV) in order to work
  19   if(WIN32)
  20     set(CMAKE_INSTALL_PREFIX "${CMAKE_BINARY_DIR}/install" CACHE PATH "Installation Directory")
  21   else()
  22     set(CMAKE_INSTALL_PREFIX "/usr/local" CACHE PATH "Installation Directory")
  23   endif()
  24 else(NOT CMAKE_TOOLCHAIN_FILE)
  25   #Android: set output folder to ${CMAKE_BINARY_DIR}
  26   set( LIBRARY_OUTPUT_PATH_ROOT ${CMAKE_BINARY_DIR} CACHE PATH "root for library output, set this to change where android libs are compiled to" )
  27   # any crosscompiling
  28   set(CMAKE_INSTALL_PREFIX "${CMAKE_BINARY_DIR}/install" CACHE PATH "Installation Directory")
  29 endif(NOT CMAKE_TOOLCHAIN_FILE)
  30
  31 # --------------------------------------------------------------
  32 # Top level OpenCV project
  33 # --------------------------------------------------------------
  34 if(CMAKE_GENERATOR MATCHES Xcode AND XCODE_VERSION VERSION_GREATER 4.3)
  35   cmake_minimum_required(VERSION 2.8.8)
  36 elseif(IOS)
  37   cmake_minimum_required(VERSION 2.8.0)
  38 else()
  39   cmake_minimum_required(VERSION 2.6.3)
  40 endif()
  41
  42 if(POLICY CMP0017)
  43   cmake_policy(SET CMP0017 NEW)
  44 endif()
  45
  46 if(POLICY CMP0022)
  47   cmake_policy(SET CMP0022 OLD)
  48 endif()
  49
  50 # must go before the project command
  51 set(CMAKE_CONFIGURATION_TYPES "Debug;Release" CACHE STRING "Configs" FORCE)
  52 if(DEFINED CMAKE_BUILD_TYPE AND CMAKE_VERSION VERSION_GREATER "2.8")
  53   set_property( CACHE CMAKE_BUILD_TYPE PROPERTY STRINGS ${CMAKE_CONFIGURATION_TYPES} )
  54 endif()
  55
  56 project(OpenCV CXX C)
  57
  58 if(MSVC)
  59   set(CMAKE_USE_RELATIVE_PATHS ON CACHE INTERNAL "" FORCE)
  60 endif()
  61
  62 include(cmake/OpenCVUtils.cmake)
  63
  64 ocv_clear_vars(OpenCVModules_TARGETS)
  65
  66 # ----------------------------------------------------------------------------
  67 # Break in case of popular CMake configuration mistakes
  68 # ----------------------------------------------------------------------------
  69 if(NOT CMAKE_SIZEOF_VOID_P GREATER 0)
  70   message(FATAL_ERROR "CMake fails to deterimine the bitness of target platform.
  71   Please check your CMake and compiler installation. If you are crosscompiling then ensure that your CMake toolchain file correctly sets the compiler details.")
  72 endif()
  73
  74 # ----------------------------------------------------------------------------
  75 # Detect compiler and target platform architecture
  76 # ----------------------------------------------------------------------------
  77 include(cmake/OpenCVDetectCXXCompiler.cmake)
  78
  79 # Add these standard paths to the search paths for FIND_LIBRARY
  80 # to find libraries from these locations first
  81 if(UNIX AND NOT ANDROID)
  82   if(X86_64 OR CMAKE_SIZEOF_VOID_P EQUAL 8)
  83     if(EXISTS /lib64)
  84       list(APPEND CMAKE_LIBRARY_PATH /lib64)
  85     else()
  86       list(APPEND CMAKE_LIBRARY_PATH /lib)
  87     endif()
  88     if(EXISTS /usr/lib64)
  89       list(APPEND CMAKE_LIBRARY_PATH /usr/lib64)
  90     else()
  91       list(APPEND CMAKE_LIBRARY_PATH /usr/lib)
  92     endif()
  93   elseif(X86 OR CMAKE_SIZEOF_VOID_P EQUAL 4)
  94     if(EXISTS /lib32)
  95       list(APPEND CMAKE_LIBRARY_PATH /lib32)
  96     else()
  97       list(APPEND CMAKE_LIBRARY_PATH /lib)
  98     endif()
  99     if(EXISTS /usr/lib32)
 100       list(APPEND CMAKE_LIBRARY_PATH /usr/lib32)
 101     else()
 102       list(APPEND CMAKE_LIBRARY_PATH /usr/lib)
 103     endif()
 104   endif()
 105 endif()
 106
 107 # Add these standard paths to the search paths for FIND_PATH
 108 # to find include files from these locations first
 109 if(MINGW)
 110   if(EXISTS /mingw)
 111       list(APPEND CMAKE_INCLUDE_PATH /mingw)
 112   endif()
 113   if(EXISTS /mingw32)
 114       list(APPEND CMAKE_INCLUDE_PATH /mingw32)
 115   endif()
 116   if(EXISTS /mingw64)
 117       list(APPEND CMAKE_INCLUDE_PATH /mingw64)
 118   endif()
 119 endif()
 120
 121 # ----------------------------------------------------------------------------
 122 # OpenCV cmake options
 123 # ----------------------------------------------------------------------------
 124
 125 # Optional 3rd party components
 126 # ===================================================
 127 OCV_OPTION(WITH_1394           "Include IEEE1394 support"                    ON   IF (NOT ANDROID AND NOT IOS) )
 128 OCV_OPTION(WITH_AVFOUNDATION   "Use AVFoundation for Video I/O"              ON   IF IOS)
 129 OCV_OPTION(WITH_CARBON         "Use Carbon for UI instead of Cocoa"          OFF  IF APPLE )
 130 OCV_OPTION(WITH_CUDA           "Include NVidia Cuda Runtime support"         ON   IF (CMAKE_VERSION VERSION_GREATER "2.8" AND NOT ANDROID AND NOT IOS) )
 131 OCV_OPTION(WITH_CUFFT          "Include NVidia Cuda Fast Fourier Transform (FFT) library support"            ON  IF (CMAKE_VERSION VERSION_GREATER "2.8" AND NOT ANDROID AND NOT IOS) )
 132 OCV_OPTION(WITH_CUBLAS         "Include NVidia Cuda Basic Linear Algebra Subprograms (BLAS) library support" OFF IF (CMAKE_VERSION VERSION_GREATER "2.8" AND NOT ANDROID AND NOT IOS) )
 133 OCV_OPTION(WITH_NVCUVID        "Include NVidia Video Decoding library support"                               OFF IF (CMAKE_VERSION VERSION_GREATER "2.8" AND NOT ANDROID AND NOT IOS AND NOT APPLE) )
 134 OCV_OPTION(WITH_EIGEN          "Include Eigen2/Eigen3 support"               ON)
 135 OCV_OPTION(WITH_VFW            "Include Video for Windows support"           ON   IF WIN32 )
 136 OCV_OPTION(WITH_FFMPEG         "Include FFMPEG support"                      ON   IF (NOT ANDROID AND NOT IOS))
 137 OCV_OPTION(WITH_GSTREAMER      "Include Gstreamer support"                   ON   IF (UNIX AND NOT APPLE AND NOT ANDROID) )
 138 OCV_OPTION(WITH_GTK            "Include GTK support"                         ON   IF (UNIX AND NOT APPLE AND NOT ANDROID) )
 139 OCV_OPTION(WITH_IMAGEIO        "ImageIO support for OS X"                    OFF  IF APPLE )
 140 OCV_OPTION(WITH_IPP            "Include Intel IPP support"                   OFF  IF (MSVC OR X86 OR X86_64) )
 141 OCV_OPTION(WITH_JASPER         "Include JPEG2K support"                      ON   IF (NOT IOS) )
 142 OCV_OPTION(WITH_JPEG           "Include JPEG support"                        ON)
 143 OCV_OPTION(WITH_OPENEXR        "Include ILM support via OpenEXR"             ON   IF (NOT IOS) )
 144 OCV_OPTION(WITH_OPENGL         "Include OpenGL support"                      OFF  IF (NOT ANDROID AND NOT APPLE) )
 145 OCV_OPTION(WITH_OPENNI         "Include OpenNI support"                      OFF  IF (NOT ANDROID AND NOT IOS) )
 146 OCV_OPTION(WITH_PNG            "Include PNG support"                         ON)
 147 OCV_OPTION(WITH_PVAPI          "Include Prosilica GigE support"              ON   IF (NOT ANDROID AND NOT IOS) )
 148 OCV_OPTION(WITH_GIGEAPI        "Include Smartek GigE support"                ON   IF (NOT ANDROID AND NOT IOS) )
 149 OCV_OPTION(WITH_QT             "Build with Qt Backend support"               OFF  IF (NOT ANDROID AND NOT IOS) )
 150 OCV_OPTION(WITH_WIN32UI        "Build with Win32 UI Backend support"         ON   IF WIN32 )
 151 OCV_OPTION(WITH_QUICKTIME      "Use QuickTime for Video I/O insted of QTKit" OFF  IF APPLE )
 152 OCV_OPTION(WITH_TBB            "Include Intel TBB support"                   OFF  IF (NOT IOS) )
 153 OCV_OPTION(WITH_OPENMP         "Include OpenMP support"                      OFF)
 154 OCV_OPTION(WITH_CSTRIPES       "Include C= support"                          OFF  IF WIN32 )
 155 OCV_OPTION(WITH_TIFF           "Include TIFF support"                        ON   IF (NOT IOS) )
 156 OCV_OPTION(WITH_UNICAP         "Include Unicap support (GPL)"                OFF  IF (UNIX AND NOT APPLE AND NOT ANDROID) )
 157 OCV_OPTION(WITH_V4L            "Include Video 4 Linux support"               ON   IF (UNIX AND NOT ANDROID) )
 158 OCV_OPTION(WITH_LIBV4L         "Use libv4l for Video 4 Linux support"        ON   IF (UNIX AND NOT ANDROID) )
 159 OCV_OPTION(WITH_DSHOW          "Build HighGUI with DirectShow support"       ON   IF (WIN32 AND NOT ARM) )
 160 OCV_OPTION(WITH_MSMF           "Build HighGUI with Media Foundation support" OFF  IF WIN32 )
 161 OCV_OPTION(WITH_XIMEA          "Include XIMEA cameras support"               OFF  IF (NOT ANDROID AND NOT APPLE) )
 162 OCV_OPTION(WITH_XINE           "Include Xine support (GPL)"                  OFF  IF (UNIX AND NOT APPLE AND NOT ANDROID) )
 163 OCV_OPTION(WITH_OPENCL         "Include OpenCL Runtime support"              ON   IF (NOT IOS) )
 164 OCV_OPTION(WITH_OPENCLAMDFFT   "Include AMD OpenCL FFT library support"      ON   IF (NOT ANDROID AND NOT IOS) )
 165 OCV_OPTION(WITH_OPENCLAMDBLAS  "Include AMD OpenCL BLAS library support"     ON   IF (NOT ANDROID AND NOT IOS) )
 166
 167
 168 # OpenCV build components
 169 # ===================================================
 170 OCV_OPTION(BUILD_SHARED_LIBS        "Build shared libraries (.dll/.so) instead of static ones (.lib/.a)" NOT (ANDROID OR IOS) )
 171 OCV_OPTION(BUILD_opencv_apps        "Build utility applications (used for example to train classifiers)" (NOT ANDROID) IF (NOT IOS) )
 172 OCV_OPTION(BUILD_ANDROID_EXAMPLES   "Build examples for Android platform"         ON  IF ANDROID )
 173 OCV_OPTION(BUILD_DOCS               "Create build rules for OpenCV Documentation" ON )
 174 OCV_OPTION(BUILD_EXAMPLES           "Build all examples"                          OFF )
 175 OCV_OPTION(BUILD_PACKAGE            "Enables 'make package_source' command"       ON )
 176 OCV_OPTION(BUILD_PERF_TESTS         "Build performance tests"                     ON  IF (NOT IOS) )
 177 OCV_OPTION(BUILD_TESTS              "Build accuracy & regression tests"           ON  IF (NOT IOS) )
 178 OCV_OPTION(BUILD_WITH_DEBUG_INFO    "Include debug info into debug libs (not MSCV only)" ON )
 179 OCV_OPTION(BUILD_WITH_STATIC_CRT    "Enables use of staticaly linked CRT for staticaly linked OpenCV" ON IF MSVC )
 180 OCV_OPTION(BUILD_FAT_JAVA_LIB       "Create fat java wrapper containing the whole OpenCV library" ON IF NOT BUILD_SHARED_LIBS AND CMAKE_COMPILER_IS_GNUCXX )
 181 OCV_OPTION(BUILD_ANDROID_SERVICE    "Build OpenCV Manager for Google Play" OFF IF ANDROID AND ANDROID_SOURCE_TREE )
 182 OCV_OPTION(BUILD_ANDROID_PACKAGE    "Build platform-specific package for Google Play" OFF IF ANDROID )
 183
 184 # 3rd party libs
 185 OCV_OPTION(BUILD_ZLIB               "Build zlib from source"             WIN32 OR APPLE )
 186 OCV_OPTION(BUILD_TIFF               "Build libtiff from source"          WIN32 OR ANDROID OR APPLE )
 187 OCV_OPTION(BUILD_JASPER             "Build libjasper from source"        WIN32 OR ANDROID OR APPLE )
 188 OCV_OPTION(BUILD_JPEG               "Build libjpeg from source"          WIN32 OR ANDROID OR APPLE )
 189 OCV_OPTION(BUILD_PNG                "Build libpng from source"           WIN32 OR ANDROID OR APPLE )
 190 OCV_OPTION(BUILD_OPENEXR            "Build openexr from source"          WIN32 OR ANDROID OR APPLE )
 191 OCV_OPTION(BUILD_TBB                "Download and build TBB from source" ANDROID )
 192
 193 # OpenCV installation options
 194 # ===================================================
 195 OCV_OPTION(INSTALL_CREATE_DISTRIB   "Change install rules to build the distribution package" OFF )
 196 OCV_OPTION(INSTALL_C_EXAMPLES       "Install C examples"        OFF )
 197 OCV_OPTION(INSTALL_PYTHON_EXAMPLES  "Install Python examples"   OFF )
 198 OCV_OPTION(INSTALL_ANDROID_EXAMPLES "Install Android examples"  OFF IF ANDROID )
 199 OCV_OPTION(INSTALL_TO_MANGLED_PATHS "Enables mangled install paths, that help with side by side installs." OFF IF (UNIX AND NOT ANDROID AND NOT IOS AND BUILD_SHARED_LIBS) )
 200
 201
 202 # OpenCV build options
 203 # ===================================================
 204 OCV_OPTION(ENABLE_PRECOMPILED_HEADERS "Use precompiled headers"                                  ON   IF (NOT IOS) )
 205 OCV_OPTION(ENABLE_SOLUTION_FOLDERS    "Solution folder in Visual Studio or in other IDEs"        (MSVC_IDE OR CMAKE_GENERATOR MATCHES Xcode) IF (CMAKE_VERSION VERSION_GREATER "2.8.0") )
 206 OCV_OPTION(ENABLE_PROFILING           "Enable profiling in the GCC compiler (Add flags: -g -pg)" OFF  IF CMAKE_COMPILER_IS_GNUCXX )
 207 OCV_OPTION(ENABLE_OMIT_FRAME_POINTER  "Enable -fomit-frame-pointer for GCC"                      ON   IF CMAKE_COMPILER_IS_GNUCXX AND NOT (APPLE AND CMAKE_COMPILER_IS_CLANGCXX) )
 208 OCV_OPTION(ENABLE_POWERPC             "Enable PowerPC for GCC"                                   ON   IF (CMAKE_COMPILER_IS_GNUCXX AND CMAKE_SYSTEM_PROCESSOR MATCHES powerpc.*) )
 209 OCV_OPTION(ENABLE_FAST_MATH           "Enable -ffast-math (not recommended for GCC 4.6.x)"       OFF  IF (CMAKE_COMPILER_IS_GNUCXX AND (X86 OR X86_64)) )
 210 OCV_OPTION(ENABLE_SSE                 "Enable SSE instructions"                                  ON   IF ((MSVC OR CMAKE_COMPILER_IS_GNUCXX) AND (X86 OR X86_64)) )
 211 OCV_OPTION(ENABLE_SSE2                "Enable SSE2 instructions"                                 ON   IF ((MSVC OR CMAKE_COMPILER_IS_GNUCXX) AND (X86 OR X86_64)) )
 212 OCV_OPTION(ENABLE_SSE3                "Enable SSE3 instructions"                                 ON   IF ((CV_ICC OR CMAKE_COMPILER_IS_GNUCXX) AND (X86 OR X86_64)) )
 213 OCV_OPTION(ENABLE_SSSE3               "Enable SSSE3 instructions"                                OFF  IF (CMAKE_COMPILER_IS_GNUCXX AND (X86 OR X86_64)) )
 214 OCV_OPTION(ENABLE_SSE41               "Enable SSE4.1 instructions"                               OFF  IF ((CV_ICC OR CMAKE_COMPILER_IS_GNUCXX) AND (X86 OR X86_64)) )
 215 OCV_OPTION(ENABLE_SSE42               "Enable SSE4.2 instructions"                               OFF  IF (CMAKE_COMPILER_IS_GNUCXX AND (X86 OR X86_64)) )
 216 OCV_OPTION(ENABLE_AVX                 "Enable AVX instructions"                                  OFF  IF ((MSVC OR CMAKE_COMPILER_IS_GNUCXX) AND (X86 OR X86_64)) )
 217 OCV_OPTION(ENABLE_NOISY_WARNINGS      "Show all warnings even if they are too noisy"             OFF )
 218 OCV_OPTION(OPENCV_WARNINGS_ARE_ERRORS "Treat warnings as errors"                                 OFF )
 219 OCV_OPTION(ENABLE_WINRT_MODE          "Build with Windows Runtime support"                       OFF  IF WIN32 )
 220
 221 # uncategorized options
 222 # ===================================================
 223 OCV_OPTION(CMAKE_VERBOSE "Verbose mode" OFF )
 224
 225 # backward compatibility
 226 # ===================================================
 227 include(cmake/OpenCVLegacyOptions.cmake OPTIONAL)
 228
 229
 230 # ----------------------------------------------------------------------------
 231 #  Get actual OpenCV version number from sources
 232 # ----------------------------------------------------------------------------
 233 include(cmake/OpenCVVersion.cmake)
 234
 235
 236 # ----------------------------------------------------------------------------
 237 #  Build & install layouts
 238 # ----------------------------------------------------------------------------
 239
 240 # Save libs and executables in the same place
 241 set(EXECUTABLE_OUTPUT_PATH "${CMAKE_BINARY_DIR}/bin" CACHE PATH "Output directory for applications" )
 242
 243 if(ANDROID OR WIN32)
 244   set(OPENCV_DOC_INSTALL_PATH doc)
 245 elseif(INSTALL_TO_MANGLED_PATHS)
 246   set(OPENCV_DOC_INSTALL_PATH share/OpenCV-${OPENCV_VERSION}/doc)
 247 else()
 248   set(OPENCV_DOC_INSTALL_PATH share/OpenCV/doc)
 249 endif()
 250
 251 if(WIN32)
 252   if(DEFINED OpenCV_RUNTIME AND DEFINED OpenCV_ARCH)
 253     set(OpenCV_INSTALL_BINARIES_PREFIX "${OpenCV_ARCH}/${OpenCV_RUNTIME}/")
 254   else()
 255     message(STATUS "Can't detect runtime and/or arch")
 256     set(OpenCV_INSTALL_BINARIES_PREFIX "")
 257   endif()
 258 else()
 259   set(OpenCV_INSTALL_BINARIES_PREFIX "")
 260 endif()
 261
 262 set(OPENCV_SAMPLES_BIN_INSTALL_PATH "${OpenCV_INSTALL_BINARIES_PREFIX}samples")
 263
 264 set(OPENCV_BIN_INSTALL_PATH "${OpenCV_INSTALL_BINARIES_PREFIX}bin")
 265
 266 if(ANDROID)
 267   set(LIBRARY_OUTPUT_PATH         "${OpenCV_BINARY_DIR}/lib/${ANDROID_NDK_ABI_NAME}")
 268   set(3P_LIBRARY_OUTPUT_PATH      "${OpenCV_BINARY_DIR}/3rdparty/lib/${ANDROID_NDK_ABI_NAME}")
 269   set(OPENCV_LIB_INSTALL_PATH     sdk/native/libs/${ANDROID_NDK_ABI_NAME})
 270   set(OPENCV_3P_LIB_INSTALL_PATH  sdk/native/3rdparty/libs/${ANDROID_NDK_ABI_NAME})
 271   set(OPENCV_CONFIG_INSTALL_PATH  sdk/native/jni)
 272   set(OPENCV_INCLUDE_INSTALL_PATH sdk/native/jni/include)
 273 else()
 274   set(LIBRARY_OUTPUT_PATH         "${OpenCV_BINARY_DIR}/lib")
 275   set(3P_LIBRARY_OUTPUT_PATH      "${OpenCV_BINARY_DIR}/3rdparty/lib${LIB_SUFFIX}")
 276   if(WIN32)
 277     if(OpenCV_STATIC)
 278       set(OPENCV_LIB_INSTALL_PATH   "${OpenCV_INSTALL_BINARIES_PREFIX}staticlib${LIB_SUFFIX}")
 279     else()
 280       set(OPENCV_LIB_INSTALL_PATH   "${OpenCV_INSTALL_BINARIES_PREFIX}lib${LIB_SUFFIX}")
 281     endif()
 282     set(OPENCV_3P_LIB_INSTALL_PATH  "${OpenCV_INSTALL_BINARIES_PREFIX}staticlib${LIB_SUFFIX}")
 283   else()
 284     set(OPENCV_LIB_INSTALL_PATH     lib${LIB_SUFFIX})
 285     set(OPENCV_3P_LIB_INSTALL_PATH  share/OpenCV/3rdparty/${OPENCV_LIB_INSTALL_PATH})
 286   endif()
 287   set(OPENCV_INCLUDE_INSTALL_PATH "include")
 288
 289   math(EXPR SIZEOF_VOID_P_BITS "8 * ${CMAKE_SIZEOF_VOID_P}")
 290   if(LIB_SUFFIX AND NOT SIZEOF_VOID_P_BITS EQUAL LIB_SUFFIX)
 291     set(OPENCV_CONFIG_INSTALL_PATH lib${LIB_SUFFIX}/cmake/opencv)
 292   else()
 293     set(OPENCV_CONFIG_INSTALL_PATH share/OpenCV)
 294   endif()
 295 endif()
 296
 297 set(CMAKE_INSTALL_RPATH "${CMAKE_INSTALL_PREFIX}/${OPENCV_LIB_INSTALL_PATH}")
 298 set(CMAKE_INSTALL_RPATH_USE_LINK_PATH TRUE)
 299
 300 if(INSTALL_TO_MANGLED_PATHS)
 301   set(OPENCV_INCLUDE_INSTALL_PATH ${OPENCV_INCLUDE_INSTALL_PATH}/opencv-${OPENCV_VERSION})
 302 endif()
 303
 304 if(WIN32)
 305   # Postfix of DLLs:
 306   set(OPENCV_DLLVERSION "${OPENCV_VERSION_MAJOR}${OPENCV_VERSION_MINOR}${OPENCV_VERSION_PATCH}")
 307   set(OPENCV_DEBUG_POSTFIX d)
 308 else()
 309   # Postfix of so's:
 310   set(OPENCV_DLLVERSION "")
 311   set(OPENCV_DEBUG_POSTFIX "")
 312 endif()
 313
 314 if(DEFINED CMAKE_DEBUG_POSTFIX)
 315   set(OPENCV_DEBUG_POSTFIX "${CMAKE_DEBUG_POSTFIX}")
 316 endif()
 317
 318 if(CMAKE_VERBOSE)
 319   set(CMAKE_VERBOSE_MAKEFILE 1)
 320 endif()
 321
 322
 323 # ----------------------------------------------------------------------------
 324 #  Path for build/platform -specific headers
 325 # ----------------------------------------------------------------------------
 326 set(OPENCV_CONFIG_FILE_INCLUDE_DIR "${CMAKE_BINARY_DIR}/" CACHE PATH "Where to create the platform-dependant cvconfig.h")
 327 ocv_include_directories(${OPENCV_CONFIG_FILE_INCLUDE_DIR})
 328
 329 # ----------------------------------------------------------------------------
 330 #  Path for additional modules
 331 # ----------------------------------------------------------------------------
 332 set(OPENCV_EXTRA_MODULES_PATH "" CACHE PATH "Where to look for additional OpenCV modules")
 333
 334 # ----------------------------------------------------------------------------
 335 #  Autodetect if we are in a GIT repository
 336 # ----------------------------------------------------------------------------
 337
 338 # don't use FindGit because it requires CMake 2.8.2
 339 set(git_names git eg) # eg = easy git
 340 # Prefer .cmd variants on Windows unless running in a Makefile in the MSYS shell
 341 if(CMAKE_HOST_WIN32)
 342   if(NOT CMAKE_GENERATOR MATCHES "MSYS")
 343     set(git_names git.cmd git eg.cmd eg)
 344   endif()
 345 endif()
 346
 347 find_host_program(GIT_EXECUTABLE NAMES ${git_names} PATH_SUFFIXES Git/cmd Git/bin DOC "git command line client")
 348 mark_as_advanced(GIT_EXECUTABLE)
 349
 350 if(GIT_EXECUTABLE)
 351   execute_process(COMMAND ${GIT_EXECUTABLE} describe --tags --always --dirty --match "2.[0-9].[0-9]*"
 352     WORKING_DIRECTORY "${OpenCV_SOURCE_DIR}"
 353     OUTPUT_VARIABLE OPENCV_VCSVERSION
 354     RESULT_VARIABLE GIT_RESULT
 355     ERROR_QUIET
 356     OUTPUT_STRIP_TRAILING_WHITESPACE
 357   )
 358   if(NOT GIT_RESULT EQUAL 0)
 359     set(OPENCV_VCSVERSION "unknown")
 360   endif()
 361 else()
 362   # We don't have git:
 363   set(OPENCV_VCSVERSION "unknown")
 364 endif()
 365
 366
 367 # ----------------------------------------------------------------------------
 368 # OpenCV compiler and linker options
 369 # ----------------------------------------------------------------------------
 370 # In case of Makefiles if the user does not setup CMAKE_BUILD_TYPE, assume it's Release:
 371 if(CMAKE_GENERATOR MATCHES "Makefiles|Ninja" AND "${CMAKE_BUILD_TYPE}" STREQUAL "")
 372   set(CMAKE_BUILD_TYPE Release)
 373 endif()
 374
 375 include(cmake/OpenCVCompilerOptions.cmake)
 376
 377
 378 # ----------------------------------------------------------------------------
 379 # Use statically or dynamically linked CRT?
 380 # Default: dynamic
 381 # ----------------------------------------------------------------------------
 382 if(MSVC)
 383   include(cmake/OpenCVCRTLinkage.cmake)
 384 endif(MSVC)
 385
 386 if(WIN32 AND NOT MINGW)
 387   add_definitions(-D_VARIADIC_MAX=10)
 388 endif(WIN32 AND NOT MINGW)
 389
 390
 391 # ----------------------------------------------------------------------------
 392 #       CHECK FOR SYSTEM LIBRARIES, OPTIONS, ETC..
 393 # ----------------------------------------------------------------------------
 394 if(UNIX)
 395   include(cmake/OpenCVFindPkgConfig.cmake OPTIONAL)
 396   include(CheckFunctionExists)
 397   include(CheckIncludeFile)
 398
 399   if(NOT APPLE)
 400     CHECK_INCLUDE_FILE(pthread.h HAVE_LIBPTHREAD)
 401     if(ANDROID)
 402       set(OPENCV_LINKER_LIBS ${OPENCV_LINKER_LIBS} dl m log)
 403     elseif(${CMAKE_SYSTEM_NAME} MATCHES "FreeBSD|NetBSD|DragonFly")
 404       set(OPENCV_LINKER_LIBS ${OPENCV_LINKER_LIBS} m pthread)
 405     else()
 406       set(OPENCV_LINKER_LIBS ${OPENCV_LINKER_LIBS} dl m pthread rt)
 407     endif()
 408   else()
 409     set(HAVE_LIBPTHREAD YES)
 410   endif()
 411 endif()
 412
 413 include(cmake/OpenCVPCHSupport.cmake)
 414 include(cmake/OpenCVModule.cmake)
 415
 416 # ----------------------------------------------------------------------------
 417 #  Detect 3rd-party libraries
 418 # ----------------------------------------------------------------------------
 419
 420 include(cmake/OpenCVFindLibsGrfmt.cmake)
 421 include(cmake/OpenCVFindLibsGUI.cmake)
 422 include(cmake/OpenCVFindLibsVideo.cmake)
 423 include(cmake/OpenCVFindLibsPerf.cmake)
 424
 425
 426 # ----------------------------------------------------------------------------
 427 #  Detect other 3rd-party libraries/tools
 428 # ----------------------------------------------------------------------------
 429
 430 # --- LATEX for pdf documentation ---
 431 if(BUILD_DOCS)
 432   include(cmake/OpenCVFindLATEX.cmake)
 433 endif(BUILD_DOCS)
 434
 435 # --- Python Support ---
 436 include(cmake/OpenCVDetectPython.cmake)
 437
 438 # --- Java Support ---
 439 include(cmake/OpenCVDetectApacheAnt.cmake)
 440 if(ANDROID)
 441   include(cmake/OpenCVDetectAndroidSDK.cmake)
 442
 443   if(NOT ANDROID_TOOLS_Pkg_Revision GREATER 13)
 444     message(WARNING "OpenCV requires Android SDK tools revision 14 or newer. Otherwise tests and samples will no be compiled.")
 445   endif()
 446 else()
 447   find_package(JNI)
 448 endif()
 449
 450 if(ANDROID AND ANDROID_EXECUTABLE AND ANT_EXECUTABLE AND (ANT_VERSION VERSION_GREATER 1.7) AND (ANDROID_TOOLS_Pkg_Revision GREATER 13))
 451   SET(CAN_BUILD_ANDROID_PROJECTS TRUE)
 452 else()
 453   SET(CAN_BUILD_ANDROID_PROJECTS FALSE)
 454 endif()
 455
 456 # --- OpenCL ---
 457 if(WITH_OPENCL)
 458   include(cmake/OpenCVDetectOpenCL.cmake)
 459 endif()
 460
 461 # ----------------------------------------------------------------------------
 462 # Add CUDA libraries (needed for apps/tools, samples)
 463 # ----------------------------------------------------------------------------
 464 if(HAVE_CUDA)
 465   set(OPENCV_LINKER_LIBS ${OPENCV_LINKER_LIBS} ${CUDA_LIBRARIES} ${CUDA_npp_LIBRARY})
 466   if(HAVE_CUBLAS)
 467     set(OPENCV_LINKER_LIBS ${OPENCV_LINKER_LIBS} ${CUDA_cublas_LIBRARY})
 468   endif()
 469   if(HAVE_CUFFT)
 470     set(OPENCV_LINKER_LIBS ${OPENCV_LINKER_LIBS} ${CUDA_cufft_LIBRARY})
 471   endif()
 472 endif()
 473 # ----------------------------------------------------------------------------
 474 # Solution folders:
 475 # ----------------------------------------------------------------------------
 476 if(ENABLE_SOLUTION_FOLDERS)
 477   set_property(GLOBAL PROPERTY USE_FOLDERS ON)
 478   set_property(GLOBAL PROPERTY PREDEFINED_TARGETS_FOLDER "CMakeTargets")
 479 endif()
 480
 481 # Extra OpenCV targets: uninstall, package_source, perf, etc.
 482 include(cmake/OpenCVExtraTargets.cmake)
 483
 484
 485 # ----------------------------------------------------------------------------
 486 # Process subdirectories
 487 # ----------------------------------------------------------------------------
 488
 489 # opencv.hpp and legacy headers
 490 add_subdirectory(include)
 491
 492 # OpenCV modules
 493 add_subdirectory(modules)
 494
 495 # Generate targets for documentation
 496 add_subdirectory(doc)
 497
 498 # various data that is used by cv libraries and/or demo applications.
 499 add_subdirectory(data)
 500
 501 # extra applications
 502 if(BUILD_opencv_apps)
 503   add_subdirectory(apps)
 504 endif()
 505
 506 # examples
 507 if(BUILD_EXAMPLES OR BUILD_ANDROID_EXAMPLES OR INSTALL_PYTHON_EXAMPLES)
 508   add_subdirectory(samples)
 509 endif()
 510
 511 if(ANDROID)
 512   add_subdirectory(platforms/android/service)
 513 endif()
 514
 515 if(BUILD_ANDROID_PACKAGE)
 516   add_subdirectory(platforms/android/package)
 517 endif()
 518
 519 if (ANDROID)
 520   add_subdirectory(platforms/android/libinfo)
 521 endif()
 522
 523 # ----------------------------------------------------------------------------
 524 # Finalization: generate configuration-based files
 525 # ----------------------------------------------------------------------------
 526 ocv_track_build_dependencies()
 527
 528 # Generate platform-dependent and configuration-dependent headers
 529 include(cmake/OpenCVGenHeaders.cmake)
 530
 531 # Generate opencv.pc for pkg-config command
 532 include(cmake/OpenCVGenPkgconfig.cmake)
 533
 534 # Generate OpenCV.mk for ndk-build (Android build tool)
 535 include(cmake/OpenCVGenAndroidMK.cmake)
 536
 537 # Generate OpenCVСonfig.cmake and OpenCVConfig-version.cmake for cmake projects
 538 include(cmake/OpenCVGenConfig.cmake)
 539
 540 # Generate Info.plist for the IOS framework
 541 include(cmake/OpenCVGenInfoPlist.cmake)
 542
 543 # ----------------------------------------------------------------------------
 544 # Summary:
 545 # ----------------------------------------------------------------------------
 546 status("")
 547 status("General configuration for OpenCV ${OPENCV_VERSION} =====================================")
 548 if(OPENCV_VCSVERSION)
 549   status("  Version control:" ${OPENCV_VCSVERSION})
 550 endif()
 551
 552 # ========================== build platform ==========================
 553 status("")
 554 status("  Platform:")
 555 status("    Host:"             ${CMAKE_HOST_SYSTEM_NAME} ${CMAKE_HOST_SYSTEM_VERSION} ${CMAKE_HOST_SYSTEM_PROCESSOR})
 556 if(CMAKE_CROSSCOMPILING)
 557   status("    Target:"         ${CMAKE_SYSTEM_NAME} ${CMAKE_SYSTEM_VERSION} ${CMAKE_SYSTEM_PROCESSOR})
 558 endif()
 559 status("    CMake:"            ${CMAKE_VERSION})
 560 status("    CMake generator:"  ${CMAKE_GENERATOR})
 561 status("    CMake build tool:" ${CMAKE_BUILD_TOOL})
 562 if(MSVC)
 563   status("    MSVC:"           ${MSVC_VERSION})
 564 endif()
 565 if(CMAKE_GENERATOR MATCHES Xcode)
 566   status("    Xcode:"          ${XCODE_VERSION})
 567 endif()
 568 if(NOT CMAKE_GENERATOR MATCHES "Xcode|Visual Studio")
 569   status("    Configuration:"  ${CMAKE_BUILD_TYPE})
 570 endif()
 571
 572 # ========================== C/C++ options ==========================
 573 if(CMAKE_CXX_COMPILER_VERSION)
 574   set(OPENCV_COMPILER_STR "${CMAKE_CXX_COMPILER} ${CMAKE_CXX_COMPILER_ARG1} (ver ${CMAKE_CXX_COMPILER_VERSION})")
 575 elseif(CMAKE_COMPILER_IS_CLANGCXX)
 576   set(OPENCV_COMPILER_STR "${CMAKE_CXX_COMPILER} ${CMAKE_CXX_COMPILER_ARG1} (ver ${CMAKE_CLANG_REGEX_VERSION})")
 577 elseif(CMAKE_COMPILER_IS_GNUCXX)
 578   set(OPENCV_COMPILER_STR "${CMAKE_CXX_COMPILER} ${CMAKE_CXX_COMPILER_ARG1} (ver ${CMAKE_GCC_REGEX_VERSION})")
 579 else()
 580   set(OPENCV_COMPILER_STR "${CMAKE_CXX_COMPILER} ${CMAKE_CXX_COMPILER_ARG1}")
 581 endif()
 582 string(STRIP "${OPENCV_COMPILER_STR}" OPENCV_COMPILER_STR)
 583
 584 status("")
 585 status("  C/C++:")
 586 status("    Built as dynamic libs?:" BUILD_SHARED_LIBS THEN YES ELSE NO)
 587 status("    C++ Compiler:"           ${OPENCV_COMPILER_STR})
 588 status("    C++ flags (Release):"    ${CMAKE_CXX_FLAGS} ${CMAKE_CXX_FLAGS_RELEASE})
 589 status("    C++ flags (Debug):"      ${CMAKE_CXX_FLAGS} ${CMAKE_CXX_FLAGS_DEBUG})
 590 status("    C Compiler:"             ${CMAKE_C_COMPILER} ${CMAKE_C_COMPILER_ARG1})
 591 status("    C flags (Release):"      ${CMAKE_C_FLAGS} ${CMAKE_C_FLAGS_RELEASE})
 592 status("    C flags (Debug):"        ${CMAKE_C_FLAGS} ${CMAKE_C_FLAGS_DEBUG})
 593 if(WIN32)
 594   status("    Linker flags (Release):" ${CMAKE_EXE_LINKER_FLAGS} ${CMAKE_EXE_LINKER_FLAGS_RELEASE})
 595   status("    Linker flags (Debug):"   ${CMAKE_EXE_LINKER_FLAGS} ${CMAKE_EXE_LINKER_FLAGS_DEBUG})
 596 else()
 597   status("    Linker flags (Release):" ${CMAKE_SHARED_LINKER_FLAGS} ${CMAKE_SHARED_LINKER_FLAGS_RELEASE})
 598   status("    Linker flags (Debug):"   ${CMAKE_SHARED_LINKER_FLAGS} ${CMAKE_SHARED_LINKER_FLAGS_DEBUG})
 599 endif()
 600 status("    Precompiled headers:"     PCHSupport_FOUND AND ENABLE_PRECOMPILED_HEADERS THEN YES ELSE NO)
 601
 602 # ========================== OpenCV modules ==========================
 603 status("")
 604 status("  OpenCV modules:")
 605 string(REPLACE "opencv_" "" OPENCV_MODULES_BUILD_ST          "${OPENCV_MODULES_BUILD}")
 606 string(REPLACE "opencv_" "" OPENCV_MODULES_DISABLED_USER_ST  "${OPENCV_MODULES_DISABLED_USER}")
 607 string(REPLACE "opencv_" "" OPENCV_MODULES_DISABLED_FORCE_ST "${OPENCV_MODULES_DISABLED_FORCE}")
 608 set(OPENCV_MODULES_DISABLED_AUTO_ST "")
 609 foreach(m ${OPENCV_MODULES_DISABLED_AUTO})
 610   set(__mdeps "")
 611   foreach(d ${OPENCV_MODULE_${m}_DEPS})
 612     if(d MATCHES "^opencv_" AND NOT HAVE_${d})
 613       list(APPEND __mdeps ${d})
 614     endif()
 615   endforeach()
 616   if(__mdeps)
 617     list(APPEND OPENCV_MODULES_DISABLED_AUTO_ST "${m}(deps: ${__mdeps})")
 618   else()
 619     list(APPEND OPENCV_MODULES_DISABLED_AUTO_ST "${m}")
 620   endif()
 621 endforeach()
 622 string(REPLACE "opencv_" "" OPENCV_MODULES_DISABLED_AUTO_ST  "${OPENCV_MODULES_DISABLED_AUTO_ST}")
 623
 624 status("    To be built:"            OPENCV_MODULES_BUILD          THEN ${OPENCV_MODULES_BUILD_ST}          ELSE "-")
 625 status("    Disabled:"               OPENCV_MODULES_DISABLED_USER  THEN ${OPENCV_MODULES_DISABLED_USER_ST}  ELSE "-")
 626 status("    Disabled by dependency:" OPENCV_MODULES_DISABLED_AUTO  THEN ${OPENCV_MODULES_DISABLED_AUTO_ST}  ELSE "-")
 627 status("    Unavailable:"            OPENCV_MODULES_DISABLED_FORCE THEN ${OPENCV_MODULES_DISABLED_FORCE_ST} ELSE "-")
 628
 629 # ========================== Android details ==========================
 630 if(ANDROID)
 631   status("")
 632   status("  Android: ")
 633   status("    Android ABI:" ${ANDROID_ABI})
 634   status("    STL type:" ${ANDROID_STL})
 635   status("    Native API level:" android-${ANDROID_NATIVE_API_LEVEL})
 636   android_get_compatible_target(android_sdk_target_status ${ANDROID_NATIVE_API_LEVEL} ${ANDROID_SDK_TARGET} 11)
 637   status("    SDK target:" "${android_sdk_target_status}")
 638   if(BUILD_WITH_ANDROID_NDK)
 639     status("    Android NDK:" "${ANDROID_NDK} (toolchain: ${ANDROID_TOOLCHAIN_NAME})")
 640   elseif(BUILD_WITH_STANDALONE_TOOLCHAIN)
 641     status("    Android toolchain:" "${ANDROID_STANDALONE_TOOLCHAIN}")
 642   endif()
 643   status("    android tool:"  ANDROID_EXECUTABLE  THEN "${ANDROID_EXECUTABLE} (${ANDROID_TOOLS_Pkg_Desc})" ELSE NO)
 644   status("    Google Play package:" BUILD_ANDROID_PACKAGE                                         THEN YES ELSE NO)
 645   status("    Android examples:"    BUILD_ANDROID_EXAMPLES AND CAN_BUILD_ANDROID_PROJECTS         THEN YES ELSE NO)
 646 endif()
 647
 648 # ================== Windows RT features ==================
 649 if(WIN32)
 650 status("")
 651     status("  Windows RT support:" HAVE_WINRT THEN YES ELSE NO)
 652     if (ENABLE_WINRT_MODE)
 653       status("    Windows SDK v8.0:" ${WINDOWS_SDK_PATH})
 654       status("    Visual Studio 2012:" ${VISUAL_STUDIO_PATH})
 655     endif()
 656 endif(WIN32)
 657
 658 # ========================== GUI ==========================
 659 status("")
 660 status("  GUI: ")
 661
 662 if(HAVE_QT5)
 663   status("    QT 5.x:"            HAVE_QT        THEN "YES (ver ${Qt5Core_VERSION_STRING})" ELSE NO)
 664   status("    QT OpenGL support:" HAVE_QT_OPENGL THEN "YES (${Qt5OpenGL_LIBRARIES} ${Qt5OpenGL_VERSION_STRING})" ELSE NO)
 665 elseif(HAVE_QT)
 666   status("    QT 4.x:"            HAVE_QT        THEN "YES (ver ${QT_VERSION_MAJOR}.${QT_VERSION_MINOR}.${QT_VERSION_PATCH} ${QT_EDITION})" ELSE NO)
 667   status("    QT OpenGL support:" HAVE_QT_OPENGL THEN "YES (${QT_QTOPENGL_LIBRARY})" ELSE NO)
 668 else()
 669   if(DEFINED WITH_QT)
 670     status("    QT:" NO)
 671   endif()
 672   if(DEFINED WITH_WIN32UI)
 673     status("    Win32 UI:" HAVE_WIN32UI THEN YES ELSE NO)
 674   else()
 675     if(APPLE)
 676       if(WITH_CARBON)
 677         status("    Carbon:" YES)
 678       else()
 679         status("    Cocoa:"  YES)
 680       endif()
 681     else()
 682       status("    GTK+ 2.x:" HAVE_GTK      THEN "YES (ver ${ALIASOF_gtk+-2.0_VERSION})"     ELSE NO)
 683       status("    GThread :" HAVE_GTHREAD  THEN "YES (ver ${ALIASOF_gthread-2.0_VERSION})"  ELSE NO)
 684       status("    GtkGlExt:" HAVE_GTKGLEXT THEN "YES (ver ${ALIASOF_gtkglext-1.0_VERSION})" ELSE NO)
 685     endif()
 686   endif()
 687 endif()
 688
 689 status("    OpenGL support:" HAVE_OPENGL THEN "YES (${OPENGL_LIBRARIES})" ELSE NO)
 690
 691 # ========================== MEDIA IO ==========================
 692 status("")
 693 status("  Media I/O: ")
 694 status("    ZLib:"         BUILD_ZLIB    THEN "build (ver ${ZLIB_VERSION_STRING})"               ELSE "${ZLIB_LIBRARY} (ver ${ZLIB_VERSION_STRING})")
 695
 696 if(WITH_JPEG)
 697   status("    JPEG:"       JPEG_FOUND    THEN "${JPEG_LIBRARY} (ver ${JPEG_LIB_VERSION})"        ELSE "build (ver ${JPEG_LIB_VERSION})")
 698 else()
 699   status("    JPEG:"       "NO")
 700 endif()
 701 if(WITH_PNG)
 702   status("    PNG:"        PNG_FOUND     THEN "${PNG_LIBRARY} (ver ${PNG_VERSION})"              ELSE "build (ver ${PNG_VERSION})")
 703 else()
 704   status("    PNG:"        "NO")
 705 endif()
 706 if(WITH_TIFF)
 707   if(TIFF_VERSION_STRING AND TIFF_FOUND)
 708     status("    TIFF:"     "${TIFF_LIBRARY} (ver ${TIFF_VERSION} - ${TIFF_VERSION_STRING})")
 709   else()
 710     status("    TIFF:"     TIFF_FOUND    THEN "${TIFF_LIBRARY} (ver ${TIFF_VERSION})"            ELSE "build (ver ${TIFF_VERSION} - ${TIFF_VERSION_STRING})")
 711   endif()
 712 else()
 713   status("    TIFF:"       "NO")
 714 endif()
 715 if(WITH_JASPER)
 716   status("    JPEG 2000:"  JASPER_FOUND  THEN "${JASPER_LIBRARY} (ver ${JASPER_VERSION_STRING})" ELSE "build (ver ${JASPER_VERSION_STRING})")
 717 else()
 718   status("    JPEG 2000:"  "NO")
 719 endif()
 720 if(WITH_OPENEXR)
 721   status("    OpenEXR:"  OPENEXR_FOUND  THEN "${OPENEXR_LIBRARIES} (ver ${OPENEXR_VERSION})" ELSE "build (ver ${OPENEXR_VERSION})")
 722 else()
 723   status("    OpenEXR:"  "NO")
 724 endif()
 725
 726 # ========================== VIDEO IO ==========================
 727 status("")
 728 status("  Video I/O:")
 729
 730 if (DEFINED WITH_VFW)
 731   status("    Video for Windows:" HAVE_VFW         THEN YES                                        ELSE NO)
 732 endif(DEFINED WITH_VFW)
 733
 734 if(DEFINED WITH_1394)
 735   status("    DC1394 1.x:"     HAVE_DC1394         THEN "YES (ver ${ALIASOF_libdc1394_VERSION})"   ELSE NO)
 736   status("    DC1394 2.x:"     HAVE_DC1394_2       THEN "YES (ver ${ALIASOF_libdc1394-2_VERSION})" ELSE NO)
 737 endif(DEFINED WITH_1394)
 738
 739 if(ANDROID)
 740   if(HAVE_opencv_androidcamera)
 741     status("    AndroidNativeCamera:" BUILD_ANDROID_CAMERA_WRAPPER
 742                                                    THEN "YES, build for Android${ANDROID_VERSION}" ELSE "YES, use prebuilt libraries")
 743   else()
 744     status("    AndroidNativeCamera:" "NO (native camera requires Android API level 8 or higher)")
 745   endif()
 746 endif()
 747
 748 if(DEFINED WITH_AVFOUNDATION)
 749   status("    AVFoundation:"   WITH_AVFOUNDATION   THEN YES                                        ELSE NO)
 750 endif(DEFINED WITH_AVFOUNDATION)
 751
 752 if(DEFINED WITH_FFMPEG)
 753   if(WIN32)
 754     status("    FFMPEG:"       WITH_FFMPEG         THEN "YES (prebuilt binaries)"                  ELSE NO)
 755   else()
 756     status("    FFMPEG:"       HAVE_FFMPEG         THEN YES ELSE NO)
 757   endif()
 758   status("      codec:"        HAVE_FFMPEG_CODEC   THEN "YES (ver ${ALIASOF_libavcodec_VERSION})"  ELSE NO)
 759   status("      format:"       HAVE_FFMPEG_FORMAT  THEN "YES (ver ${ALIASOF_libavformat_VERSION})" ELSE NO)
 760   status("      util:"         HAVE_FFMPEG_UTIL    THEN "YES (ver ${ALIASOF_libavutil_VERSION})"   ELSE NO)
 761   status("      swscale:"      HAVE_FFMPEG_SWSCALE THEN "YES (ver ${ALIASOF_libswscale_VERSION})"  ELSE NO)
 762   status("      gentoo-style:" HAVE_GENTOO_FFMPEG  THEN YES                                        ELSE NO)
 763 endif(DEFINED WITH_FFMPEG)
 764
 765 if(DEFINED WITH_GSTREAMER)
 766   status("    GStreamer:"      HAVE_GSTREAMER      THEN ""                                         ELSE NO)
 767   if(HAVE_GSTREAMER)
 768     status("      base:"       "YES (ver ${ALIASOF_gstreamer-base-0.10_VERSION})")
 769     status("      app:"        "YES (ver ${ALIASOF_gstreamer-app-0.10_VERSION})")
 770     status("      video:"      "YES (ver ${ALIASOF_gstreamer-video-0.10_VERSION})")
 771   endif()
 772 endif(DEFINED WITH_GSTREAMER)
 773
 774 if(DEFINED WITH_OPENNI)
 775   status("    OpenNI:"         HAVE_OPENNI         THEN "YES (ver ${OPENNI_VERSION_STRING}, build ${OPENNI_VERSION_BUILD})"
 776                                                                                                    ELSE NO)
 777   status("    OpenNI PrimeSensor Modules:" HAVE_OPENNI_PRIME_SENSOR_MODULE
 778                                                    THEN "YES (${OPENNI_PRIME_SENSOR_MODULE})"      ELSE NO)
 779 endif(DEFINED WITH_OPENNI)
 780
 781 if(DEFINED WITH_PVAPI)
 782   status("    PvAPI:"          HAVE_PVAPI          THEN YES                                        ELSE NO)
 783 endif(DEFINED WITH_PVAPI)
 784
 785 if(DEFINED WITH_GIGEAPI)
 786   status("    GigEVisionSDK:"  HAVE_GIGE_API       THEN YES                                        ELSE NO)
 787 endif(DEFINED WITH_GIGEAPI)
 788
 789 if(DEFINED WITH_QUICKTIME)
 790   status("    QuickTime:"      HAVE_QUICKTIME      THEN YES                                        ELSE NO)
 791   status("    QTKit:"          HAVE_QTKIT          THEN YES                                        ELSE NO)
 792 endif(DEFINED WITH_QUICKTIME)
 793
 794 if(DEFINED WITH_UNICAP)
 795   status("    UniCap:"         HAVE_UNICAP         THEN "YES (ver ${ALIASOF_libunicap_VERSION})"   ELSE NO)
 796   status("    UniCap ucil:"    HAVE_UNICAP_UCIL    THEN "YES (ver ${ALIASOF_libucil_VERSION})"     ELSE NO)
 797 endif(DEFINED WITH_UNICAP)
 798
 799 if(DEFINED WITH_V4L)
 800   if(HAVE_CAMV4L)
 801     set(HAVE_CAMV4L_STR "YES")
 802   else()
 803     set(HAVE_CAMV4L_STR "NO")
 804   endif()
 805   if(HAVE_CAMV4L2)
 806     set(HAVE_CAMV4L2_STR "YES")
 807   elseif(HAVE_VIDEOIO)
 808     set(HAVE_CAMV4L2_STR "YES(videoio)")
 809   else()
 810     set(HAVE_CAMV4L2_STR "NO")
 811   endif()
 812   status("    V4L/V4L2:"       HAVE_LIBV4L         THEN "Using libv4l (ver ${ALIASOF_libv4l1_VERSION})"
 813                                                    ELSE "${HAVE_CAMV4L_STR}/${HAVE_CAMV4L2_STR}")
 814 endif(DEFINED WITH_V4L)
 815
 816 if(DEFINED WITH_DSHOW)
 817   status("    DirectShow:"     HAVE_DSHOW     THEN YES                                        ELSE NO)
 818 endif(DEFINED WITH_DSHOW)
 819
 820 if(DEFINED WITH_MSMF)
 821   status("    Media Foundation:" HAVE_MSMF    THEN YES                                        ELSE NO)
 822 endif(DEFINED WITH_MSMF)
 823
 824 if(DEFINED WITH_XIMEA)
 825   status("    XIMEA:"          HAVE_XIMEA          THEN YES                                        ELSE NO)
 826 endif(DEFINED WITH_XIMEA)
 827
 828 if(DEFINED WITH_XINE)
 829   status("    Xine:"           HAVE_XINE           THEN "YES (ver ${ALIASOF_libxine_VERSION})"     ELSE NO)
 830 endif(DEFINED WITH_XINE)
 831
 832 # ========================== Other third-party libraries ==========================
 833 status("")
 834 status("  Other third-party libraries:")
 835
 836 if(WITH_IPP AND IPP_FOUND)
 837   status("    Use IPP:" "${IPP_LATEST_VERSION_STR} [${IPP_LATEST_VERSION_MAJOR}.${IPP_LATEST_VERSION_MINOR}.${IPP_LATEST_VERSION_BUILD}]")
 838   status("         at:" "${IPP_ROOT_DIR}")
 839 else()
 840   status("    Use IPP:"   WITH_IPP AND NOT IPP_FOUND THEN "IPP not found" ELSE NO)
 841 endif()
 842
 843 status("    Use Eigen:"      HAVE_EIGEN       THEN "YES (ver ${EIGEN_WORLD_VERSION}.${EIGEN_MAJOR_VERSION}.${EIGEN_MINOR_VERSION})" ELSE NO)
 844 status("    Use TBB:"        HAVE_TBB         THEN "YES (ver ${TBB_VERSION_MAJOR}.${TBB_VERSION_MINOR} interface ${TBB_INTERFACE_VERSION})" ELSE NO)
 845 status("    Use OpenMP:"     HAVE_OPENMP      THEN YES ELSE NO)
 846 status("    Use GCD"         HAVE_GCD         THEN YES ELSE NO)
 847 status("    Use Concurrency" HAVE_CONCURRENCY THEN YES ELSE NO)
 848 status("    Use C=:"         HAVE_CSTRIPES    THEN YES ELSE NO)
 849 status("    Use Cuda:"       HAVE_CUDA        THEN "YES (ver ${CUDA_VERSION_STRING})" ELSE NO)
 850 status("    Use OpenCL:"     HAVE_OPENCL      THEN YES ELSE NO)
 851
 852 if(HAVE_CUDA)
 853   status("")
 854   status("  NVIDIA CUDA")
 855
 856   status("    Use CUFFT:"            HAVE_CUFFT   THEN YES ELSE NO)
 857   status("    Use CUBLAS:"           HAVE_CUBLAS  THEN YES ELSE NO)
 858   status("    USE NVCUVID:"          HAVE_NVCUVID THEN YES ELSE NO)
 859   status("    NVIDIA GPU arch:"      ${OPENCV_CUDA_ARCH_BIN})
 860   status("    NVIDIA PTX archs:"     ${OPENCV_CUDA_ARCH_PTX})
 861   status("    Use fast math:"        CUDA_FAST_MATH THEN YES ELSE NO)
 862 endif()
 863
 864 if(HAVE_OPENCL)
 865   status("")
 866   status("  OpenCL:")
 867   if(HAVE_OPENCL_STATIC)
 868     set(__opencl_ver "static")
 869   else()
 870     set(__opencl_ver "dynamic")
 871   endif()
 872   status("    Version:"       ${__opencl_ver})
 873   if(OPENCL_INCLUDE_DIR)
 874     status("    Include path:"       ${OPENCL_INCLUDE_DIRS})
 875   endif()
 876   if(OPENCL_LIBRARIES)
 877     set(__libs "")
 878     foreach(l ${OPENCL_LIBRARIES})
 879       if(TARGET ${l})
 880         get_target_property(p ${l} LOCATION)
 881         if(p MATCHES NOTFOUND)
 882           list(APPEND __libs "${l}")
 883         else()
 884           list(APPEND __libs "${p}")
 885         endif()
 886       else()
 887         list(APPEND __libs "${l}")
 888       endif()
 889     endforeach()
 890     status("    libraries:"          ${__libs})
 891   endif()
 892   status("    Use AMD FFT:"          HAVE_CLAMDFFT  THEN YES ELSE NO)
 893   status("    Use AMD BLAS:"         HAVE_CLAMDBLAS THEN YES ELSE NO)
 894 endif()
 895
 896 # ========================== python ==========================
 897 status("")
 898 status("  Python:")
 899 status("    Interpreter:"     PYTHON_EXECUTABLE   THEN "${PYTHON_EXECUTABLE} (ver ${PYTHON_VERSION_FULL})"         ELSE NO)
 900 if(BUILD_opencv_python)
 901   if(PYTHONLIBS_VERSION_STRING)
 902     status("    Libraries:"   HAVE_opencv_python  THEN  "${PYTHON_LIBRARIES} (ver ${PYTHONLIBS_VERSION_STRING})"   ELSE NO)
 903   else()
 904     status("    Libraries:"   HAVE_opencv_python  THEN  ${PYTHON_LIBRARIES}                                        ELSE NO)
 905   endif()
 906   status("    numpy:"         PYTHON_USE_NUMPY    THEN "${PYTHON_NUMPY_INCLUDE_DIR} (ver ${PYTHON_NUMPY_VERSION})" ELSE "NO (Python wrappers can not be generated)")
 907   status("    packages path:" PYTHON_EXECUTABLE   THEN "${PYTHON_PACKAGES_PATH}"                                   ELSE "-")
 908 endif()
 909
 910 # ========================== java ==========================
 911 status("")
 912 status("  Java:")
 913 status("    ant:"           ANT_EXECUTABLE      THEN "${ANT_EXECUTABLE} (ver ${ANT_VERSION})"                    ELSE NO)
 914 if(NOT ANDROID)
 915   status("    JNI:"         JNI_INCLUDE_DIRS    THEN "${JNI_INCLUDE_DIRS}"                                       ELSE NO)
 916 endif()
 917 status("    Java tests:"    BUILD_TESTS AND (CAN_BUILD_ANDROID_PROJECTS OR HAVE_opencv_java)            THEN YES ELSE NO)
 918
 919 # ========================== documentation ==========================
 920 if(BUILD_DOCS)
 921   status("")
 922   status("  Documentation:")
 923   if(HAVE_SPHINX)
 924     status("    Build Documentation:" PDFLATEX_COMPILER      THEN YES ELSE "YES (only HTML and without math expressions)")
 925   else()
 926     status("    Build Documentation:" NO)
 927   endif()
 928   status("    Sphinx:"              HAVE_SPHINX              THEN "${SPHINX_BUILD} (ver ${SPHINX_VERSION})" ELSE NO)
 929   status("    PdfLaTeX compiler:"   PDFLATEX_COMPILER        THEN "${PDFLATEX_COMPILER}" ELSE NO)
 930 endif()
 931
 932 # ========================== samples and tests ==========================
 933 status("")
 934 status("  Tests and samples:")
 935 status("    Tests:"             BUILD_TESTS AND HAVE_opencv_ts       THEN YES ELSE NO)
 936 status("    Performance tests:" BUILD_PERF_TESTS AND HAVE_opencv_ts  THEN YES ELSE NO)
 937 status("    C/C++ Examples:"    BUILD_EXAMPLES                       THEN YES ELSE NO)
 938
 939 # ========================== auxiliary ==========================
 940 status("")
 941 status("  Install path:" "${CMAKE_INSTALL_PREFIX}")
 942 status("")
 943 status("  cvconfig.h is in:" "${OPENCV_CONFIG_FILE_INCLUDE_DIR}")
 944 status("-----------------------------------------------------------------")
 945 status("")
 946
 947 ocv_finalize_status()
 948
 949 # ----------------------------------------------------------------------------
 950 # Warn in the case of in-source build
 951 # ----------------------------------------------------------------------------
 952 if("${CMAKE_CURRENT_SOURCE_DIR}" STREQUAL "${CMAKE_CURRENT_BINARY_DIR}")
 953   message(WARNING "The source directory is the same as binary directory. \"make clean\" may damage the source tree")
 954 endif()