CMakeLists.txt

   1 # ----------------------------------------------------------------------------
   2 #  Root CMake file for OpenCV
   3 #
   4 #    From the off-tree build directory, invoke:
   5 #      $ cmake <PATH_TO_OPENCV_ROOT>
   6 #
   7 #
   8 #   - OCT-2008: Initial version <joseluisblancoc@gmail.com>
   9 #
  10 # ----------------------------------------------------------------------------
  11
  12 set(CMAKE_ALLOW_LOOSE_LOOP_CONSTRUCTS true)
  13
  14 # Following block can broke build in case of cross-compilng
  15 # but CMAKE_CROSSCOMPILING variable will be set only on project(OpenCV) command
  16 # so we will try to detect crosscompiling by presense of CMAKE_TOOLCHAIN_FILE
  17 if(NOT CMAKE_TOOLCHAIN_FILE)
  18   # it _must_ go before project(OpenCV) in order to work
  19   if(WIN32)
  20     set(CMAKE_INSTALL_PREFIX "${CMAKE_BINARY_DIR}/install" CACHE PATH "Installation Directory")
  21   else()
  22     set(CMAKE_INSTALL_PREFIX "/usr/local" CACHE PATH "Installation Directory")
  23   endif()
  24 else(NOT CMAKE_TOOLCHAIN_FILE)
  25   #Android: set output folder to ${CMAKE_BINARY_DIR}
  26   set( LIBRARY_OUTPUT_PATH_ROOT ${CMAKE_BINARY_DIR} CACHE PATH "root for library output, set this to change where android libs are compiled to" )
  27   # any crosscompiling
  28   set(CMAKE_INSTALL_PREFIX "${CMAKE_BINARY_DIR}/install" CACHE PATH "Installation Directory")
  29 endif(NOT CMAKE_TOOLCHAIN_FILE)
  30
  31 # --------------------------------------------------------------
  32 # Top level OpenCV project
  33 # --------------------------------------------------------------
  34 if(CMAKE_GENERATOR MATCHES Xcode AND XCODE_VERSION VERSION_GREATER 4.3)
  35   cmake_minimum_required(VERSION 2.8.8)
  36 elseif(IOS)
  37   cmake_minimum_required(VERSION 2.8.0)
  38 else()
  39   cmake_minimum_required(VERSION 2.6.3)
  40 endif()
  41
  42 if(POLICY CMP0017)
  43   cmake_policy(SET CMP0017 NEW)
  44 endif()
  45
  46 if(POLICY CMP0022)
  47   cmake_policy(SET CMP0022 OLD)
  48 endif()
  49
  50 # must go before the project command
  51 set(CMAKE_CONFIGURATION_TYPES "Debug;Release" CACHE STRING "Configs" FORCE)
  52 if(DEFINED CMAKE_BUILD_TYPE AND CMAKE_VERSION VERSION_GREATER "2.8")
  53   set_property( CACHE CMAKE_BUILD_TYPE PROPERTY STRINGS ${CMAKE_CONFIGURATION_TYPES} )
  54 endif()
  55
  56 project(OpenCV CXX C)
  57
  58 if(MSVC)
  59   set(CMAKE_USE_RELATIVE_PATHS ON CACHE INTERNAL "" FORCE)
  60 endif()
  61
  62 include(cmake/OpenCVUtils.cmake)
  63
  64 ocv_clear_vars(OpenCVModules_TARGETS)
  65
  66 # ----------------------------------------------------------------------------
  67 # Break in case of popular CMake configuration mistakes
  68 # ----------------------------------------------------------------------------
  69 if(NOT CMAKE_SIZEOF_VOID_P GREATER 0)
  70   message(FATAL_ERROR "CMake fails to deterimine the bitness of target platform.
  71   Please check your CMake and compiler installation. If you are crosscompiling then ensure that your CMake toolchain file correctly sets the compiler details.")
  72 endif()
  73
  74 # ----------------------------------------------------------------------------
  75 # Detect compiler and target platform architecture
  76 # ----------------------------------------------------------------------------
  77 include(cmake/OpenCVDetectCXXCompiler.cmake)
  78
  79 # Add these standard paths to the search paths for FIND_LIBRARY
  80 # to find libraries from these locations first
  81 if(UNIX AND NOT ANDROID)
  82   if(X86_64 OR CMAKE_SIZEOF_VOID_P EQUAL 8)
  83     if(EXISTS /lib64)
  84       list(APPEND CMAKE_LIBRARY_PATH /lib64)
  85     else()
  86       list(APPEND CMAKE_LIBRARY_PATH /lib)
  87     endif()
  88     if(EXISTS /usr/lib64)
  89       list(APPEND CMAKE_LIBRARY_PATH /usr/lib64)
  90     else()
  91       list(APPEND CMAKE_LIBRARY_PATH /usr/lib)
  92     endif()
  93   elseif(X86 OR CMAKE_SIZEOF_VOID_P EQUAL 4)
  94     if(EXISTS /lib32)
  95       list(APPEND CMAKE_LIBRARY_PATH /lib32)
  96     else()
  97       list(APPEND CMAKE_LIBRARY_PATH /lib)
  98     endif()
  99     if(EXISTS /usr/lib32)
 100       list(APPEND CMAKE_LIBRARY_PATH /usr/lib32)
 101     else()
 102       list(APPEND CMAKE_LIBRARY_PATH /usr/lib)
 103     endif()
 104   endif()
 105 endif()
 106
 107 # Add these standard paths to the search paths for FIND_PATH
 108 # to find include files from these locations first
 109 if(MINGW)
 110   if(EXISTS /mingw)
 111       list(APPEND CMAKE_INCLUDE_PATH /mingw)
 112   endif()
 113   if(EXISTS /mingw32)
 114       list(APPEND CMAKE_INCLUDE_PATH /mingw32)
 115   endif()
 116   if(EXISTS /mingw64)
 117       list(APPEND CMAKE_INCLUDE_PATH /mingw64)
 118   endif()
 119 endif()
 120
 121 # ----------------------------------------------------------------------------
 122 # OpenCV cmake options
 123 # ----------------------------------------------------------------------------
 124
 125 # Optional 3rd party components
 126 # ===================================================
 127 OCV_OPTION(WITH_1394           "Include IEEE1394 support"                    ON   IF (NOT ANDROID AND NOT IOS) )
 128 OCV_OPTION(WITH_AVFOUNDATION   "Use AVFoundation for Video I/O"              ON   IF IOS)
 129 OCV_OPTION(WITH_CARBON         "Use Carbon for UI instead of Cocoa"          OFF  IF APPLE )
 130 OCV_OPTION(WITH_CUDA           "Include NVidia Cuda Runtime support"         ON   IF (CMAKE_VERSION VERSION_GREATER "2.8" AND NOT IOS) )
 131 OCV_OPTION(WITH_CUFFT          "Include NVidia Cuda Fast Fourier Transform (FFT) library support"            ON  IF (CMAKE_VERSION VERSION_GREATER "2.8" AND NOT IOS) )
 132 OCV_OPTION(WITH_CUBLAS         "Include NVidia Cuda Basic Linear Algebra Subprograms (BLAS) library support" OFF IF (CMAKE_VERSION VERSION_GREATER "2.8" AND NOT IOS) )
 133 OCV_OPTION(WITH_NVCUVID        "Include NVidia Video Decoding library support"                               OFF IF (CMAKE_VERSION VERSION_GREATER "2.8" AND NOT ANDROID AND NOT IOS AND NOT APPLE) )
 134 OCV_OPTION(WITH_EIGEN          "Include Eigen2/Eigen3 support"               ON)
 135 OCV_OPTION(WITH_VFW            "Include Video for Windows support"           ON   IF WIN32 )
 136 OCV_OPTION(WITH_FFMPEG         "Include FFMPEG support"                      ON   IF (NOT ANDROID AND NOT IOS))
 137 OCV_OPTION(WITH_GSTREAMER      "Include Gstreamer support"                   ON   IF (UNIX AND NOT APPLE AND NOT ANDROID) )
 138 OCV_OPTION(WITH_GTK            "Include GTK support"                         ON   IF (UNIX AND NOT APPLE AND NOT ANDROID) )
 139 OCV_OPTION(WITH_IMAGEIO        "ImageIO support for OS X"                    OFF  IF APPLE )
 140 OCV_OPTION(WITH_IPP            "Include Intel IPP support"                   OFF  IF (MSVC OR X86 OR X86_64) )
 141 OCV_OPTION(WITH_JASPER         "Include JPEG2K support"                      ON   IF (NOT IOS) )
 142 OCV_OPTION(WITH_JPEG           "Include JPEG support"                        ON)
 143 OCV_OPTION(WITH_OPENEXR        "Include ILM support via OpenEXR"             ON   IF (NOT IOS) )
 144 OCV_OPTION(WITH_OPENGL         "Include OpenGL support"                      OFF  IF (NOT ANDROID AND NOT APPLE) )
 145 OCV_OPTION(WITH_OPENNI         "Include OpenNI support"                      OFF  IF (NOT ANDROID AND NOT IOS) )
 146 OCV_OPTION(WITH_PNG            "Include PNG support"                         ON)
 147 OCV_OPTION(WITH_PVAPI          "Include Prosilica GigE support"              ON   IF (NOT ANDROID AND NOT IOS) )
 148 OCV_OPTION(WITH_GIGEAPI        "Include Smartek GigE support"                ON   IF (NOT ANDROID AND NOT IOS) )
 149 OCV_OPTION(WITH_QT             "Build with Qt Backend support"               OFF  IF (NOT ANDROID AND NOT IOS) )
 150 OCV_OPTION(WITH_WIN32UI        "Build with Win32 UI Backend support"         ON   IF WIN32 )
 151 OCV_OPTION(WITH_QUICKTIME      "Use QuickTime for Video I/O insted of QTKit" OFF  IF APPLE )
 152 OCV_OPTION(WITH_TBB            "Include Intel TBB support"                   OFF  IF (NOT IOS) )
 153 OCV_OPTION(WITH_OPENMP         "Include OpenMP support"                      OFF)
 154 OCV_OPTION(WITH_CSTRIPES       "Include C= support"                          OFF  IF WIN32 )
 155 OCV_OPTION(WITH_TIFF           "Include TIFF support"                        ON   IF (NOT IOS) )
 156 OCV_OPTION(WITH_UNICAP         "Include Unicap support (GPL)"                OFF  IF (UNIX AND NOT APPLE AND NOT ANDROID) )
 157 OCV_OPTION(WITH_V4L            "Include Video 4 Linux support"               ON   IF (UNIX AND NOT ANDROID) )
 158 OCV_OPTION(WITH_LIBV4L         "Use libv4l for Video 4 Linux support"        ON   IF (UNIX AND NOT ANDROID) )
 159 OCV_OPTION(WITH_DSHOW          "Build HighGUI with DirectShow support"       ON   IF (WIN32 AND NOT ARM) )
 160 OCV_OPTION(WITH_MSMF           "Build HighGUI with Media Foundation support" OFF  IF WIN32 )
 161 OCV_OPTION(WITH_XIMEA          "Include XIMEA cameras support"               OFF  IF (NOT ANDROID AND NOT APPLE) )
 162 OCV_OPTION(WITH_XINE           "Include Xine support (GPL)"                  OFF  IF (UNIX AND NOT APPLE AND NOT ANDROID) )
 163 OCV_OPTION(WITH_OPENCL         "Include OpenCL Runtime support"              ON   IF (NOT IOS) )
 164 OCV_OPTION(WITH_OPENCLAMDFFT   "Include AMD OpenCL FFT library support"      ON   IF (NOT ANDROID AND NOT IOS) )
 165 OCV_OPTION(WITH_OPENCLAMDBLAS  "Include AMD OpenCL BLAS library support"     ON   IF (NOT ANDROID AND NOT IOS) )
 166 OCV_OPTION(WITH_INTELPERC      "Include Intel Perceptual Computing support"  OFF  IF WIN32 )
 167
 168 # OpenCV build components
 169 # ===================================================
 170 OCV_OPTION(BUILD_SHARED_LIBS        "Build shared libraries (.dll/.so) instead of static ones (.lib/.a)" NOT (ANDROID OR IOS) )
 171 OCV_OPTION(BUILD_opencv_apps        "Build utility applications (used for example to train classifiers)" (NOT ANDROID) IF (NOT IOS) )
 172 OCV_OPTION(BUILD_ANDROID_EXAMPLES   "Build examples for Android platform"         ON  IF ANDROID )
 173 OCV_OPTION(BUILD_DOCS               "Create build rules for OpenCV Documentation" ON )
 174 OCV_OPTION(BUILD_EXAMPLES           "Build all examples"                          OFF )
 175 OCV_OPTION(BUILD_PACKAGE            "Enables 'make package_source' command"       ON )
 176 OCV_OPTION(BUILD_PERF_TESTS         "Build performance tests"                     ON  IF (NOT IOS) )
 177 OCV_OPTION(BUILD_TESTS              "Build accuracy & regression tests"           ON  IF (NOT IOS) )
 178 OCV_OPTION(BUILD_WITH_DEBUG_INFO    "Include debug info into debug libs (not MSCV only)" ON )
 179 OCV_OPTION(BUILD_WITH_STATIC_CRT    "Enables use of staticaly linked CRT for staticaly linked OpenCV" ON IF MSVC )
 180 OCV_OPTION(BUILD_FAT_JAVA_LIB       "Create fat java wrapper containing the whole OpenCV library" ON IF NOT BUILD_SHARED_LIBS AND CMAKE_COMPILER_IS_GNUCXX )
 181 OCV_OPTION(BUILD_ANDROID_SERVICE    "Build OpenCV Manager for Google Play" OFF IF ANDROID AND ANDROID_SOURCE_TREE )
 182 OCV_OPTION(BUILD_ANDROID_PACKAGE    "Build platform-specific package for Google Play" OFF IF ANDROID )
 183
 184 # 3rd party libs
 185 OCV_OPTION(BUILD_ZLIB               "Build zlib from source"             WIN32 OR APPLE )
 186 OCV_OPTION(BUILD_TIFF               "Build libtiff from source"          WIN32 OR ANDROID OR APPLE )
 187 OCV_OPTION(BUILD_JASPER             "Build libjasper from source"        WIN32 OR ANDROID OR APPLE )
 188 OCV_OPTION(BUILD_JPEG               "Build libjpeg from source"          WIN32 OR ANDROID OR APPLE )
 189 OCV_OPTION(BUILD_PNG                "Build libpng from source"           WIN32 OR ANDROID OR APPLE )
 190 OCV_OPTION(BUILD_OPENEXR            "Build openexr from source"          WIN32 OR ANDROID OR APPLE )
 191 OCV_OPTION(BUILD_TBB                "Download and build TBB from source" ANDROID )
 192
 193 # OpenCV installation options
 194 # ===================================================
 195 OCV_OPTION(INSTALL_CREATE_DISTRIB   "Change install rules to build the distribution package" OFF )
 196 OCV_OPTION(INSTALL_C_EXAMPLES       "Install C examples"        OFF )
 197 OCV_OPTION(INSTALL_PYTHON_EXAMPLES  "Install Python examples"   OFF )
 198 OCV_OPTION(INSTALL_ANDROID_EXAMPLES "Install Android examples"  OFF IF ANDROID )
 199 OCV_OPTION(INSTALL_TO_MANGLED_PATHS "Enables mangled install paths, that help with side by side installs." OFF IF (UNIX AND NOT ANDROID AND NOT IOS AND BUILD_SHARED_LIBS) )
 200 OCV_OPTION(INSTALL_TESTS            "Install accuracy and performance test binaries and test data" OFF)
 201
 202 # OpenCV build options
 203 # ===================================================
 204 OCV_OPTION(ENABLE_DYNAMIC_CUDA        "Enabled dynamic CUDA linkage"                             ON   IF ANDROID )
 205 OCV_OPTION(ENABLE_PRECOMPILED_HEADERS "Use precompiled headers"                                  ON   IF (NOT IOS) )
 206 OCV_OPTION(ENABLE_SOLUTION_FOLDERS    "Solution folder in Visual Studio or in other IDEs"        (MSVC_IDE OR CMAKE_GENERATOR MATCHES Xcode) IF (CMAKE_VERSION VERSION_GREATER "2.8.0") )
 207 OCV_OPTION(ENABLE_PROFILING           "Enable profiling in the GCC compiler (Add flags: -g -pg)" OFF  IF CMAKE_COMPILER_IS_GNUCXX )
 208 OCV_OPTION(ENABLE_OMIT_FRAME_POINTER  "Enable -fomit-frame-pointer for GCC"                      ON   IF CMAKE_COMPILER_IS_GNUCXX AND NOT (APPLE AND CMAKE_COMPILER_IS_CLANGCXX) )
 209 OCV_OPTION(ENABLE_POWERPC             "Enable PowerPC for GCC"                                   ON   IF (CMAKE_COMPILER_IS_GNUCXX AND CMAKE_SYSTEM_PROCESSOR MATCHES powerpc.*) )
 210 OCV_OPTION(ENABLE_FAST_MATH           "Enable -ffast-math (not recommended for GCC 4.6.x)"       OFF  IF (CMAKE_COMPILER_IS_GNUCXX AND (X86 OR X86_64)) )
 211 OCV_OPTION(ENABLE_SSE                 "Enable SSE instructions"                                  ON   IF ((MSVC OR CMAKE_COMPILER_IS_GNUCXX) AND (X86 OR X86_64)) )
 212 OCV_OPTION(ENABLE_SSE2                "Enable SSE2 instructions"                                 ON   IF ((MSVC OR CMAKE_COMPILER_IS_GNUCXX) AND (X86 OR X86_64)) )
 213 OCV_OPTION(ENABLE_SSE3                "Enable SSE3 instructions"                                 ON   IF ((CV_ICC OR CMAKE_COMPILER_IS_GNUCXX) AND (X86 OR X86_64)) )
 214 OCV_OPTION(ENABLE_SSSE3               "Enable SSSE3 instructions"                                OFF  IF (CMAKE_COMPILER_IS_GNUCXX AND (X86 OR X86_64)) )
 215 OCV_OPTION(ENABLE_SSE41               "Enable SSE4.1 instructions"                               OFF  IF ((CV_ICC OR CMAKE_COMPILER_IS_GNUCXX) AND (X86 OR X86_64)) )
 216 OCV_OPTION(ENABLE_SSE42               "Enable SSE4.2 instructions"                               OFF  IF (CMAKE_COMPILER_IS_GNUCXX AND (X86 OR X86_64)) )
 217 OCV_OPTION(ENABLE_AVX                 "Enable AVX instructions"                                  OFF  IF ((MSVC OR CMAKE_COMPILER_IS_GNUCXX) AND (X86 OR X86_64)) )
 218 OCV_OPTION(ENABLE_NEON                "Enable NEON instructions"                                 OFF  IF CMAKE_COMPILER_IS_GNUCXX AND ARM )
 219 OCV_OPTION(ENABLE_VFPV3               "Enable VFPv3-D32 instructions"                            OFF  IF CMAKE_COMPILER_IS_GNUCXX AND ARM )
 220 OCV_OPTION(ENABLE_NOISY_WARNINGS      "Show all warnings even if they are too noisy"             OFF )
 221 OCV_OPTION(OPENCV_WARNINGS_ARE_ERRORS "Treat warnings as errors"                                 OFF )
 222 OCV_OPTION(ENABLE_WINRT_MODE          "Build with Windows Runtime support"                       OFF  IF WIN32 )
 223 OCV_OPTION(ENABLE_WINRT_MODE_NATIVE   "Build with Windows Runtime native C++ support"            OFF  IF WIN32 )
 224
 225 # uncategorized options
 226 # ===================================================
 227 OCV_OPTION(CMAKE_VERBOSE "Verbose mode" OFF )
 228
 229 # backward compatibility
 230 # ===================================================
 231 include(cmake/OpenCVLegacyOptions.cmake OPTIONAL)
 232
 233
 234 # ----------------------------------------------------------------------------
 235 #  Get actual OpenCV version number from sources
 236 # ----------------------------------------------------------------------------
 237 include(cmake/OpenCVVersion.cmake)
 238
 239
 240 # ----------------------------------------------------------------------------
 241 #  Build & install layouts
 242 # ----------------------------------------------------------------------------
 243
 244 # Save libs and executables in the same place
 245 set(EXECUTABLE_OUTPUT_PATH "${CMAKE_BINARY_DIR}/bin" CACHE PATH "Output directory for applications" )
 246
 247 if (ANDROID)
 248   if (ANDROID_ABI MATCHES "NEON")
 249     set(ENABLE_NEON ON)
 250   endif()
 251   if (ANDROID_ABI MATCHES "VFPV3")
 252     set(ENABLE_VFPV3 ON)
 253   endif()
 254 endif()
 255
 256 if(ANDROID OR WIN32)
 257   set(OPENCV_DOC_INSTALL_PATH doc)
 258 elseif(INSTALL_TO_MANGLED_PATHS)
 259   set(OPENCV_DOC_INSTALL_PATH share/OpenCV-${OPENCV_VERSION}/doc)
 260 else()
 261   set(OPENCV_DOC_INSTALL_PATH share/OpenCV/doc)
 262 endif()
 263
 264 if(WIN32)
 265   if(DEFINED OpenCV_RUNTIME AND DEFINED OpenCV_ARCH)
 266     set(OpenCV_INSTALL_BINARIES_PREFIX "${OpenCV_ARCH}/${OpenCV_RUNTIME}/")
 267   else()
 268     message(STATUS "Can't detect runtime and/or arch")
 269     set(OpenCV_INSTALL_BINARIES_PREFIX "")
 270   endif()
 271 else()
 272   set(OpenCV_INSTALL_BINARIES_PREFIX "")
 273 endif()
 274
 275 set(OPENCV_SAMPLES_BIN_INSTALL_PATH "${OpenCV_INSTALL_BINARIES_PREFIX}samples")
 276
 277 set(OPENCV_BIN_INSTALL_PATH "${OpenCV_INSTALL_BINARIES_PREFIX}bin")
 278
 279 if(ANDROID)
 280   set(LIBRARY_OUTPUT_PATH         "${OpenCV_BINARY_DIR}/lib/${ANDROID_NDK_ABI_NAME}")
 281   set(3P_LIBRARY_OUTPUT_PATH      "${OpenCV_BINARY_DIR}/3rdparty/lib/${ANDROID_NDK_ABI_NAME}")
 282   set(OPENCV_LIB_INSTALL_PATH     sdk/native/libs/${ANDROID_NDK_ABI_NAME})
 283   set(OPENCV_3P_LIB_INSTALL_PATH  sdk/native/3rdparty/libs/${ANDROID_NDK_ABI_NAME})
 284   set(OPENCV_CONFIG_INSTALL_PATH  sdk/native/jni)
 285   set(OPENCV_INCLUDE_INSTALL_PATH sdk/native/jni/include)
 286   set(OPENCV_SAMPLES_SRC_INSTALL_PATH samples/native)
 287 else()
 288   set(LIBRARY_OUTPUT_PATH         "${OpenCV_BINARY_DIR}/lib")
 289   set(3P_LIBRARY_OUTPUT_PATH      "${OpenCV_BINARY_DIR}/3rdparty/lib${LIB_SUFFIX}")
 290   if(WIN32)
 291     if(OpenCV_STATIC)
 292       set(OPENCV_LIB_INSTALL_PATH   "${OpenCV_INSTALL_BINARIES_PREFIX}staticlib${LIB_SUFFIX}")
 293     else()
 294       set(OPENCV_LIB_INSTALL_PATH   "${OpenCV_INSTALL_BINARIES_PREFIX}lib${LIB_SUFFIX}")
 295     endif()
 296     set(OPENCV_3P_LIB_INSTALL_PATH  "${OpenCV_INSTALL_BINARIES_PREFIX}staticlib${LIB_SUFFIX}")
 297     set(OPENCV_SAMPLES_SRC_INSTALL_PATH    samples/native)
 298   else()
 299     set(OPENCV_LIB_INSTALL_PATH     lib${LIB_SUFFIX})
 300     set(OPENCV_3P_LIB_INSTALL_PATH  share/OpenCV/3rdparty/${OPENCV_LIB_INSTALL_PATH})
 301     set(OPENCV_SAMPLES_SRC_INSTALL_PATH    share/OpenCV/samples)
 302   endif()
 303   set(OPENCV_INCLUDE_INSTALL_PATH "include")
 304
 305   math(EXPR SIZEOF_VOID_P_BITS "8 * ${CMAKE_SIZEOF_VOID_P}")
 306   if(LIB_SUFFIX AND NOT SIZEOF_VOID_P_BITS EQUAL LIB_SUFFIX)
 307     set(OPENCV_CONFIG_INSTALL_PATH lib${LIB_SUFFIX}/cmake/opencv)
 308   else()
 309     set(OPENCV_CONFIG_INSTALL_PATH share/OpenCV)
 310   endif()
 311 endif()
 312
 313 set(CMAKE_INSTALL_RPATH "${CMAKE_INSTALL_PREFIX}/${OPENCV_LIB_INSTALL_PATH}")
 314 set(CMAKE_INSTALL_RPATH_USE_LINK_PATH TRUE)
 315
 316 if(INSTALL_TO_MANGLED_PATHS)
 317   set(OPENCV_INCLUDE_INSTALL_PATH ${OPENCV_INCLUDE_INSTALL_PATH}/opencv-${OPENCV_VERSION})
 318 endif()
 319
 320 if(WIN32)
 321   # Postfix of DLLs:
 322   set(OPENCV_DLLVERSION "${OPENCV_VERSION_MAJOR}${OPENCV_VERSION_MINOR}${OPENCV_VERSION_PATCH}")
 323   set(OPENCV_DEBUG_POSTFIX d)
 324 else()
 325   # Postfix of so's:
 326   set(OPENCV_DLLVERSION "")
 327   set(OPENCV_DEBUG_POSTFIX "")
 328 endif()
 329
 330 if(DEFINED CMAKE_DEBUG_POSTFIX)
 331   set(OPENCV_DEBUG_POSTFIX "${CMAKE_DEBUG_POSTFIX}")
 332 endif()
 333
 334 if(CMAKE_VERBOSE)
 335   set(CMAKE_VERBOSE_MAKEFILE 1)
 336 endif()
 337
 338
 339 # ----------------------------------------------------------------------------
 340 #  Path for build/platform -specific headers
 341 # ----------------------------------------------------------------------------
 342 set(OPENCV_CONFIG_FILE_INCLUDE_DIR "${CMAKE_BINARY_DIR}/" CACHE PATH "Where to create the platform-dependant cvconfig.h")
 343 ocv_include_directories(${OPENCV_CONFIG_FILE_INCLUDE_DIR})
 344
 345 # ----------------------------------------------------------------------------
 346 #  Path for additional modules
 347 # ----------------------------------------------------------------------------
 348 set(OPENCV_EXTRA_MODULES_PATH "" CACHE PATH "Where to look for additional OpenCV modules")
 349
 350 # ----------------------------------------------------------------------------
 351 #  Autodetect if we are in a GIT repository
 352 # ----------------------------------------------------------------------------
 353
 354 # don't use FindGit because it requires CMake 2.8.2
 355 set(git_names git eg) # eg = easy git
 356 # Prefer .cmd variants on Windows unless running in a Makefile in the MSYS shell
 357 if(CMAKE_HOST_WIN32)
 358   if(NOT CMAKE_GENERATOR MATCHES "MSYS")
 359     set(git_names git.cmd git eg.cmd eg)
 360   endif()
 361 endif()
 362
 363 find_host_program(GIT_EXECUTABLE NAMES ${git_names} PATH_SUFFIXES Git/cmd Git/bin DOC "git command line client")
 364 mark_as_advanced(GIT_EXECUTABLE)
 365
 366 if(GIT_EXECUTABLE)
 367   execute_process(COMMAND ${GIT_EXECUTABLE} describe --tags --always --dirty --match "2.[0-9].[0-9]*"
 368     WORKING_DIRECTORY "${OpenCV_SOURCE_DIR}"
 369     OUTPUT_VARIABLE OPENCV_VCSVERSION
 370     RESULT_VARIABLE GIT_RESULT
 371     ERROR_QUIET
 372     OUTPUT_STRIP_TRAILING_WHITESPACE
 373   )
 374   if(NOT GIT_RESULT EQUAL 0)
 375     set(OPENCV_VCSVERSION "unknown")
 376   endif()
 377 else()
 378   # We don't have git:
 379   set(OPENCV_VCSVERSION "unknown")
 380 endif()
 381
 382
 383 # ----------------------------------------------------------------------------
 384 # OpenCV compiler and linker options
 385 # ----------------------------------------------------------------------------
 386 # In case of Makefiles if the user does not setup CMAKE_BUILD_TYPE, assume it's Release:
 387 if(CMAKE_GENERATOR MATCHES "Makefiles|Ninja" AND "${CMAKE_BUILD_TYPE}" STREQUAL "")
 388   set(CMAKE_BUILD_TYPE Release)
 389 endif()
 390
 391 include(cmake/OpenCVCompilerOptions.cmake)
 392
 393
 394 # ----------------------------------------------------------------------------
 395 # Use statically or dynamically linked CRT?
 396 # Default: dynamic
 397 # ----------------------------------------------------------------------------
 398 if(MSVC)
 399   include(cmake/OpenCVCRTLinkage.cmake)
 400 endif(MSVC)
 401
 402 if(WIN32 AND NOT MINGW)
 403   add_definitions(-D_VARIADIC_MAX=10)
 404 endif(WIN32 AND NOT MINGW)
 405
 406
 407 # ----------------------------------------------------------------------------
 408 #       CHECK FOR SYSTEM LIBRARIES, OPTIONS, ETC..
 409 # ----------------------------------------------------------------------------
 410 if(UNIX)
 411   include(cmake/OpenCVFindPkgConfig.cmake OPTIONAL)
 412   include(CheckFunctionExists)
 413   include(CheckIncludeFile)
 414
 415   if(NOT APPLE)
 416     CHECK_INCLUDE_FILE(pthread.h HAVE_LIBPTHREAD)
 417     if(ANDROID)
 418       set(OPENCV_LINKER_LIBS ${OPENCV_LINKER_LIBS} dl m log)
 419     elseif(${CMAKE_SYSTEM_NAME} MATCHES "FreeBSD|NetBSD|DragonFly")
 420       set(OPENCV_LINKER_LIBS ${OPENCV_LINKER_LIBS} m pthread)
 421     else()
 422       set(OPENCV_LINKER_LIBS ${OPENCV_LINKER_LIBS} dl m pthread rt)
 423     endif()
 424   else()
 425     set(HAVE_LIBPTHREAD YES)
 426   endif()
 427 endif()
 428
 429 include(cmake/OpenCVPCHSupport.cmake)
 430 include(cmake/OpenCVModule.cmake)
 431
 432 # ----------------------------------------------------------------------------
 433 #  Detect 3rd-party libraries
 434 # ----------------------------------------------------------------------------
 435
 436 include(cmake/OpenCVFindLibsGrfmt.cmake)
 437 include(cmake/OpenCVFindLibsGUI.cmake)
 438 include(cmake/OpenCVFindLibsVideo.cmake)
 439 include(cmake/OpenCVFindLibsPerf.cmake)
 440
 441
 442 # ----------------------------------------------------------------------------
 443 #  Detect other 3rd-party libraries/tools
 444 # ----------------------------------------------------------------------------
 445
 446 # --- LATEX for pdf documentation ---
 447 if(BUILD_DOCS)
 448   include(cmake/OpenCVFindLATEX.cmake)
 449 endif(BUILD_DOCS)
 450
 451 # --- Python Support ---
 452 include(cmake/OpenCVDetectPython.cmake)
 453
 454 # --- Java Support ---
 455 include(cmake/OpenCVDetectApacheAnt.cmake)
 456 if(ANDROID)
 457   include(cmake/OpenCVDetectAndroidSDK.cmake)
 458
 459   if(NOT ANDROID_TOOLS_Pkg_Revision GREATER 13)
 460     message(WARNING "OpenCV requires Android SDK tools revision 14 or newer. Otherwise tests and samples will no be compiled.")
 461   endif()
 462 else()
 463   find_package(JNI)
 464 endif()
 465
 466 if(ANDROID AND ANDROID_EXECUTABLE AND ANT_EXECUTABLE AND (ANT_VERSION VERSION_GREATER 1.7) AND (ANDROID_TOOLS_Pkg_Revision GREATER 13))
 467   SET(CAN_BUILD_ANDROID_PROJECTS TRUE)
 468 else()
 469   SET(CAN_BUILD_ANDROID_PROJECTS FALSE)
 470 endif()
 471
 472 # --- OpenCL ---
 473 if(WITH_OPENCL)
 474   include(cmake/OpenCVDetectOpenCL.cmake)
 475 endif()
 476
 477 # ----------------------------------------------------------------------------
 478 # Add CUDA libraries (needed for apps/tools, samples)
 479 # ----------------------------------------------------------------------------
 480 if(NOT HAVE_CUDA)
 481   set(ENABLE_DYNAMIC_CUDA OFF)
 482 endif()
 483
 484 if(HAVE_CUDA AND NOT ENABLE_DYNAMIC_CUDA)
 485   set(OPENCV_LINKER_LIBS ${OPENCV_LINKER_LIBS} ${CUDA_LIBRARIES} ${CUDA_npp_LIBRARY})
 486   if(HAVE_CUBLAS)
 487     set(OPENCV_LINKER_LIBS ${OPENCV_LINKER_LIBS} ${CUDA_cublas_LIBRARY})
 488   endif()
 489   if(HAVE_CUFFT)
 490     set(OPENCV_LINKER_LIBS ${OPENCV_LINKER_LIBS} ${CUDA_cufft_LIBRARY})
 491   endif()
 492 endif()
 493
 494 # ----------------------------------------------------------------------------
 495 # Solution folders:
 496 # ----------------------------------------------------------------------------
 497 if(ENABLE_SOLUTION_FOLDERS)
 498   set_property(GLOBAL PROPERTY USE_FOLDERS ON)
 499   set_property(GLOBAL PROPERTY PREDEFINED_TARGETS_FOLDER "CMakeTargets")
 500 endif()
 501
 502 # Extra OpenCV targets: uninstall, package_source, perf, etc.
 503 include(cmake/OpenCVExtraTargets.cmake)
 504
 505
 506 # ----------------------------------------------------------------------------
 507 # Process subdirectories
 508 # ----------------------------------------------------------------------------
 509
 510 # opencv.hpp and legacy headers
 511 add_subdirectory(include)
 512
 513 # OpenCV modules
 514 add_subdirectory(modules)
 515
 516 # Generate targets for documentation
 517 add_subdirectory(doc)
 518
 519 # various data that is used by cv libraries and/or demo applications.
 520 add_subdirectory(data)
 521
 522 # extra applications
 523 if(BUILD_opencv_apps)
 524   add_subdirectory(apps)
 525 endif()
 526
 527 # examples
 528 if(BUILD_EXAMPLES OR BUILD_ANDROID_EXAMPLES OR INSTALL_PYTHON_EXAMPLES)
 529   add_subdirectory(samples)
 530 endif()
 531
 532 if(ANDROID)
 533   add_subdirectory(platforms/android/service)
 534 endif()
 535
 536 if(BUILD_ANDROID_PACKAGE)
 537   add_subdirectory(platforms/android/package)
 538 endif()
 539
 540 if (ANDROID)
 541   add_subdirectory(platforms/android/libinfo)
 542 endif()
 543
 544 # ----------------------------------------------------------------------------
 545 # Finalization: generate configuration-based files
 546 # ----------------------------------------------------------------------------
 547 ocv_track_build_dependencies()
 548
 549 # Generate platform-dependent and configuration-dependent headers
 550 include(cmake/OpenCVGenHeaders.cmake)
 551
 552 # Generate opencv.pc for pkg-config command
 553 include(cmake/OpenCVGenPkgconfig.cmake)
 554
 555 # Generate OpenCV.mk for ndk-build (Android build tool)
 556 include(cmake/OpenCVGenAndroidMK.cmake)
 557
 558 # Generate OpenCVСonfig.cmake and OpenCVConfig-version.cmake for cmake projects
 559 include(cmake/OpenCVGenConfig.cmake)
 560
 561 # Generate Info.plist for the IOS framework
 562 include(cmake/OpenCVGenInfoPlist.cmake)
 563
 564 # ----------------------------------------------------------------------------
 565 # Summary:
 566 # ----------------------------------------------------------------------------
 567 status("")
 568 status("General configuration for OpenCV ${OPENCV_VERSION} =====================================")
 569 if(OPENCV_VCSVERSION)
 570   status("  Version control:" ${OPENCV_VCSVERSION})
 571 endif()
 572
 573 # ========================== build platform ==========================
 574 status("")
 575 status("  Platform:")
 576 status("    Host:"             ${CMAKE_HOST_SYSTEM_NAME} ${CMAKE_HOST_SYSTEM_VERSION} ${CMAKE_HOST_SYSTEM_PROCESSOR})
 577 if(CMAKE_CROSSCOMPILING)
 578   status("    Target:"         ${CMAKE_SYSTEM_NAME} ${CMAKE_SYSTEM_VERSION} ${CMAKE_SYSTEM_PROCESSOR})
 579 endif()
 580 status("    CMake:"            ${CMAKE_VERSION})
 581 status("    CMake generator:"  ${CMAKE_GENERATOR})
 582 status("    CMake build tool:" ${CMAKE_BUILD_TOOL})
 583 if(MSVC)
 584   status("    MSVC:"           ${MSVC_VERSION})
 585 endif()
 586 if(CMAKE_GENERATOR MATCHES Xcode)
 587   status("    Xcode:"          ${XCODE_VERSION})
 588 endif()
 589 if(NOT CMAKE_GENERATOR MATCHES "Xcode|Visual Studio")
 590   status("    Configuration:"  ${CMAKE_BUILD_TYPE})
 591 endif()
 592
 593 # ========================== C/C++ options ==========================
 594 if(CMAKE_CXX_COMPILER_VERSION)
 595   set(OPENCV_COMPILER_STR "${CMAKE_CXX_COMPILER} ${CMAKE_CXX_COMPILER_ARG1} (ver ${CMAKE_CXX_COMPILER_VERSION})")
 596 elseif(CMAKE_COMPILER_IS_CLANGCXX)
 597   set(OPENCV_COMPILER_STR "${CMAKE_CXX_COMPILER} ${CMAKE_CXX_COMPILER_ARG1} (ver ${CMAKE_CLANG_REGEX_VERSION})")
 598 elseif(CMAKE_COMPILER_IS_GNUCXX)
 599   set(OPENCV_COMPILER_STR "${CMAKE_CXX_COMPILER} ${CMAKE_CXX_COMPILER_ARG1} (ver ${CMAKE_GCC_REGEX_VERSION})")
 600 else()
 601   set(OPENCV_COMPILER_STR "${CMAKE_CXX_COMPILER} ${CMAKE_CXX_COMPILER_ARG1}")
 602 endif()
 603 string(STRIP "${OPENCV_COMPILER_STR}" OPENCV_COMPILER_STR)
 604
 605 status("")
 606 status("  C/C++:")
 607 status("    Built as dynamic libs?:" BUILD_SHARED_LIBS THEN YES ELSE NO)
 608 status("    C++ Compiler:"           ${OPENCV_COMPILER_STR})
 609 status("    C++ flags (Release):"    ${CMAKE_CXX_FLAGS} ${CMAKE_CXX_FLAGS_RELEASE})
 610 status("    C++ flags (Debug):"      ${CMAKE_CXX_FLAGS} ${CMAKE_CXX_FLAGS_DEBUG})
 611 status("    C Compiler:"             ${CMAKE_C_COMPILER} ${CMAKE_C_COMPILER_ARG1})
 612 status("    C flags (Release):"      ${CMAKE_C_FLAGS} ${CMAKE_C_FLAGS_RELEASE})
 613 status("    C flags (Debug):"        ${CMAKE_C_FLAGS} ${CMAKE_C_FLAGS_DEBUG})
 614 if(WIN32)
 615   status("    Linker flags (Release):" ${CMAKE_EXE_LINKER_FLAGS} ${CMAKE_EXE_LINKER_FLAGS_RELEASE})
 616   status("    Linker flags (Debug):"   ${CMAKE_EXE_LINKER_FLAGS} ${CMAKE_EXE_LINKER_FLAGS_DEBUG})
 617 else()
 618   status("    Linker flags (Release):" ${CMAKE_SHARED_LINKER_FLAGS} ${CMAKE_SHARED_LINKER_FLAGS_RELEASE})
 619   status("    Linker flags (Debug):"   ${CMAKE_SHARED_LINKER_FLAGS} ${CMAKE_SHARED_LINKER_FLAGS_DEBUG})
 620 endif()
 621 status("    Precompiled headers:"     PCHSupport_FOUND AND ENABLE_PRECOMPILED_HEADERS THEN YES ELSE NO)
 622
 623 # ========================== OpenCV modules ==========================
 624 status("")
 625 status("  OpenCV modules:")
 626 string(REPLACE "opencv_" "" OPENCV_MODULES_BUILD_ST          "${OPENCV_MODULES_BUILD}")
 627 string(REPLACE "opencv_" "" OPENCV_MODULES_DISABLED_USER_ST  "${OPENCV_MODULES_DISABLED_USER}")
 628 string(REPLACE "opencv_" "" OPENCV_MODULES_DISABLED_FORCE_ST "${OPENCV_MODULES_DISABLED_FORCE}")
 629 set(OPENCV_MODULES_DISABLED_AUTO_ST "")
 630 foreach(m ${OPENCV_MODULES_DISABLED_AUTO})
 631   set(__mdeps "")
 632   foreach(d ${OPENCV_MODULE_${m}_DEPS})
 633     if(d MATCHES "^opencv_" AND NOT HAVE_${d})
 634       list(APPEND __mdeps ${d})
 635     endif()
 636   endforeach()
 637   if(__mdeps)
 638     list(APPEND OPENCV_MODULES_DISABLED_AUTO_ST "${m}(deps: ${__mdeps})")
 639   else()
 640     list(APPEND OPENCV_MODULES_DISABLED_AUTO_ST "${m}")
 641   endif()
 642 endforeach()
 643 string(REPLACE "opencv_" "" OPENCV_MODULES_DISABLED_AUTO_ST  "${OPENCV_MODULES_DISABLED_AUTO_ST}")
 644
 645 status("    To be built:"            OPENCV_MODULES_BUILD          THEN ${OPENCV_MODULES_BUILD_ST}          ELSE "-")
 646 status("    Disabled:"               OPENCV_MODULES_DISABLED_USER  THEN ${OPENCV_MODULES_DISABLED_USER_ST}  ELSE "-")
 647 status("    Disabled by dependency:" OPENCV_MODULES_DISABLED_AUTO  THEN ${OPENCV_MODULES_DISABLED_AUTO_ST}  ELSE "-")
 648 status("    Unavailable:"            OPENCV_MODULES_DISABLED_FORCE THEN ${OPENCV_MODULES_DISABLED_FORCE_ST} ELSE "-")
 649
 650 # ========================== Android details ==========================
 651 if(ANDROID)
 652   status("")
 653   status("  Android: ")
 654   status("    Android ABI:" ${ANDROID_ABI})
 655   status("    STL type:" ${ANDROID_STL})
 656   status("    Native API level:" android-${ANDROID_NATIVE_API_LEVEL})
 657   android_get_compatible_target(android_sdk_target_status ${ANDROID_NATIVE_API_LEVEL} ${ANDROID_SDK_TARGET} 11)
 658   status("    SDK target:" "${android_sdk_target_status}")
 659   if(BUILD_WITH_ANDROID_NDK)
 660     status("    Android NDK:" "${ANDROID_NDK} (toolchain: ${ANDROID_TOOLCHAIN_NAME})")
 661   elseif(BUILD_WITH_STANDALONE_TOOLCHAIN)
 662     status("    Android toolchain:" "${ANDROID_STANDALONE_TOOLCHAIN}")
 663   endif()
 664   status("    android tool:"  ANDROID_EXECUTABLE  THEN "${ANDROID_EXECUTABLE} (${ANDROID_TOOLS_Pkg_Desc})" ELSE NO)
 665   status("    Google Play package:" BUILD_ANDROID_PACKAGE                                         THEN YES ELSE NO)
 666   status("    Android examples:"    BUILD_ANDROID_EXAMPLES AND CAN_BUILD_ANDROID_PROJECTS         THEN YES ELSE NO)
 667 endif()
 668
 669 # ================== Windows RT features ==================
 670 if(WIN32)
 671 status("")
 672     status("  Windows RT support:" HAVE_WINRT THEN YES ELSE NO)
 673     if (ENABLE_WINRT_MODE OR ENABLE_WINRT_MODE_NATIVE)
 674       status("    Windows SDK v8.0:" ${WINDOWS_SDK_PATH})
 675       status("    Visual Studio 2012:" ${VISUAL_STUDIO_PATH})
 676     endif()
 677 endif(WIN32)
 678
 679 # ========================== GUI ==========================
 680 status("")
 681 status("  GUI: ")
 682
 683 if(HAVE_QT5)
 684   status("    QT 5.x:"            HAVE_QT        THEN "YES (ver ${Qt5Core_VERSION_STRING})" ELSE NO)
 685   status("    QT OpenGL support:" HAVE_QT_OPENGL THEN "YES (${Qt5OpenGL_LIBRARIES} ${Qt5OpenGL_VERSION_STRING})" ELSE NO)
 686 elseif(HAVE_QT)
 687   status("    QT 4.x:"            HAVE_QT        THEN "YES (ver ${QT_VERSION_MAJOR}.${QT_VERSION_MINOR}.${QT_VERSION_PATCH} ${QT_EDITION})" ELSE NO)
 688   status("    QT OpenGL support:" HAVE_QT_OPENGL THEN "YES (${QT_QTOPENGL_LIBRARY})" ELSE NO)
 689 else()
 690   if(DEFINED WITH_QT)
 691     status("    QT:" NO)
 692   endif()
 693   if(DEFINED WITH_WIN32UI)
 694     status("    Win32 UI:" HAVE_WIN32UI THEN YES ELSE NO)
 695   else()
 696     if(APPLE)
 697       if(WITH_CARBON)
 698         status("    Carbon:" YES)
 699       else()
 700         status("    Cocoa:"  YES)
 701       endif()
 702     else()
 703       status("    GTK+ 2.x:" HAVE_GTK      THEN "YES (ver ${ALIASOF_gtk+-2.0_VERSION})"     ELSE NO)
 704       status("    GThread :" HAVE_GTHREAD  THEN "YES (ver ${ALIASOF_gthread-2.0_VERSION})"  ELSE NO)
 705       status("    GtkGlExt:" HAVE_GTKGLEXT THEN "YES (ver ${ALIASOF_gtkglext-1.0_VERSION})" ELSE NO)
 706     endif()
 707   endif()
 708 endif()
 709
 710 status("    OpenGL support:" HAVE_OPENGL THEN "YES (${OPENGL_LIBRARIES})" ELSE NO)
 711
 712 # ========================== MEDIA IO ==========================
 713 status("")
 714 status("  Media I/O: ")
 715 status("    ZLib:"         BUILD_ZLIB    THEN "build (ver ${ZLIB_VERSION_STRING})"               ELSE "${ZLIB_LIBRARY} (ver ${ZLIB_VERSION_STRING})")
 716
 717 if(WITH_JPEG)
 718   status("    JPEG:"       JPEG_FOUND    THEN "${JPEG_LIBRARY} (ver ${JPEG_LIB_VERSION})"        ELSE "build (ver ${JPEG_LIB_VERSION})")
 719 else()
 720   status("    JPEG:"       "NO")
 721 endif()
 722 if(WITH_PNG)
 723   status("    PNG:"        PNG_FOUND     THEN "${PNG_LIBRARY} (ver ${PNG_VERSION})"              ELSE "build (ver ${PNG_VERSION})")
 724 else()
 725   status("    PNG:"        "NO")
 726 endif()
 727 if(WITH_TIFF)
 728   if(TIFF_VERSION_STRING AND TIFF_FOUND)
 729     status("    TIFF:"     "${TIFF_LIBRARY} (ver ${TIFF_VERSION} - ${TIFF_VERSION_STRING})")
 730   else()
 731     status("    TIFF:"     TIFF_FOUND    THEN "${TIFF_LIBRARY} (ver ${TIFF_VERSION})"            ELSE "build (ver ${TIFF_VERSION} - ${TIFF_VERSION_STRING})")
 732   endif()
 733 else()
 734   status("    TIFF:"       "NO")
 735 endif()
 736 if(WITH_JASPER)
 737   status("    JPEG 2000:"  JASPER_FOUND  THEN "${JASPER_LIBRARY} (ver ${JASPER_VERSION_STRING})" ELSE "build (ver ${JASPER_VERSION_STRING})")
 738 else()
 739   status("    JPEG 2000:"  "NO")
 740 endif()
 741 if(WITH_OPENEXR)
 742   status("    OpenEXR:"  OPENEXR_FOUND  THEN "${OPENEXR_LIBRARIES} (ver ${OPENEXR_VERSION})" ELSE "build (ver ${OPENEXR_VERSION})")
 743 else()
 744   status("    OpenEXR:"  "NO")
 745 endif()
 746
 747 # ========================== VIDEO IO ==========================
 748 status("")
 749 status("  Video I/O:")
 750
 751 if (DEFINED WITH_VFW)
 752   status("    Video for Windows:" HAVE_VFW         THEN YES                                        ELSE NO)
 753 endif(DEFINED WITH_VFW)
 754
 755 if(DEFINED WITH_1394)
 756   status("    DC1394 1.x:"     HAVE_DC1394         THEN "YES (ver ${ALIASOF_libdc1394_VERSION})"   ELSE NO)
 757   status("    DC1394 2.x:"     HAVE_DC1394_2       THEN "YES (ver ${ALIASOF_libdc1394-2_VERSION})" ELSE NO)
 758 endif(DEFINED WITH_1394)
 759
 760 if(ANDROID)
 761   if(HAVE_opencv_androidcamera)
 762     status("    AndroidNativeCamera:" BUILD_ANDROID_CAMERA_WRAPPER
 763                                                    THEN "YES, build for Android${ANDROID_VERSION}" ELSE "YES, use prebuilt libraries")
 764   else()
 765     status("    AndroidNativeCamera:" "NO (native camera requires Android API level 8 or higher)")
 766   endif()
 767 endif()
 768
 769 if(DEFINED WITH_AVFOUNDATION)
 770   status("    AVFoundation:"   WITH_AVFOUNDATION   THEN YES                                        ELSE NO)
 771 endif(DEFINED WITH_AVFOUNDATION)
 772
 773 if(DEFINED WITH_FFMPEG)
 774   if(WIN32)
 775     status("    FFMPEG:"       WITH_FFMPEG         THEN "YES (prebuilt binaries)"                  ELSE NO)
 776   else()
 777     status("    FFMPEG:"       HAVE_FFMPEG         THEN YES ELSE NO)
 778   endif()
 779   status("      codec:"        HAVE_FFMPEG_CODEC   THEN "YES (ver ${ALIASOF_libavcodec_VERSION})"  ELSE NO)
 780   status("      format:"       HAVE_FFMPEG_FORMAT  THEN "YES (ver ${ALIASOF_libavformat_VERSION})" ELSE NO)
 781   status("      util:"         HAVE_FFMPEG_UTIL    THEN "YES (ver ${ALIASOF_libavutil_VERSION})"   ELSE NO)
 782   status("      swscale:"      HAVE_FFMPEG_SWSCALE THEN "YES (ver ${ALIASOF_libswscale_VERSION})"  ELSE NO)
 783   status("      gentoo-style:" HAVE_GENTOO_FFMPEG  THEN YES                                        ELSE NO)
 784 endif(DEFINED WITH_FFMPEG)
 785
 786 if(DEFINED WITH_GSTREAMER)
 787   status("    GStreamer:"      HAVE_GSTREAMER      THEN ""                                         ELSE NO)
 788   if(HAVE_GSTREAMER)
 789     status("      base:"       "YES (ver ${ALIASOF_gstreamer-base-0.10_VERSION})")
 790     status("      app:"        "YES (ver ${ALIASOF_gstreamer-app-0.10_VERSION})")
 791     status("      video:"      "YES (ver ${ALIASOF_gstreamer-video-0.10_VERSION})")
 792   endif()
 793 endif(DEFINED WITH_GSTREAMER)
 794
 795 if(DEFINED WITH_OPENNI)
 796   status("    OpenNI:"         HAVE_OPENNI         THEN "YES (ver ${OPENNI_VERSION_STRING}, build ${OPENNI_VERSION_BUILD})"
 797                                                                                                    ELSE NO)
 798   status("    OpenNI PrimeSensor Modules:" HAVE_OPENNI_PRIME_SENSOR_MODULE
 799                                                    THEN "YES (${OPENNI_PRIME_SENSOR_MODULE})"      ELSE NO)
 800 endif(DEFINED WITH_OPENNI)
 801
 802 if(DEFINED WITH_PVAPI)
 803   status("    PvAPI:"          HAVE_PVAPI          THEN YES                                        ELSE NO)
 804 endif(DEFINED WITH_PVAPI)
 805
 806 if(DEFINED WITH_GIGEAPI)
 807   status("    GigEVisionSDK:"  HAVE_GIGE_API       THEN YES                                        ELSE NO)
 808 endif(DEFINED WITH_GIGEAPI)
 809
 810 if(DEFINED WITH_QUICKTIME)
 811   status("    QuickTime:"      HAVE_QUICKTIME      THEN YES                                        ELSE NO)
 812   status("    QTKit:"          HAVE_QTKIT          THEN YES                                        ELSE NO)
 813 endif(DEFINED WITH_QUICKTIME)
 814
 815 if(DEFINED WITH_UNICAP)
 816   status("    UniCap:"         HAVE_UNICAP         THEN "YES (ver ${ALIASOF_libunicap_VERSION})"   ELSE NO)
 817   status("    UniCap ucil:"    HAVE_UNICAP_UCIL    THEN "YES (ver ${ALIASOF_libucil_VERSION})"     ELSE NO)
 818 endif(DEFINED WITH_UNICAP)
 819
 820 if(DEFINED WITH_V4L)
 821   if(HAVE_CAMV4L)
 822     set(HAVE_CAMV4L_STR "YES")
 823   else()
 824     set(HAVE_CAMV4L_STR "NO")
 825   endif()
 826   if(HAVE_CAMV4L2)
 827     set(HAVE_CAMV4L2_STR "YES")
 828   elseif(HAVE_VIDEOIO)
 829     set(HAVE_CAMV4L2_STR "YES(videoio)")
 830   else()
 831     set(HAVE_CAMV4L2_STR "NO")
 832   endif()
 833   status("    V4L/V4L2:"       HAVE_LIBV4L         THEN "Using libv4l (ver ${ALIASOF_libv4l1_VERSION})"
 834                                                    ELSE "${HAVE_CAMV4L_STR}/${HAVE_CAMV4L2_STR}")
 835 endif(DEFINED WITH_V4L)
 836
 837 if(DEFINED WITH_DSHOW)
 838   status("    DirectShow:"     HAVE_DSHOW     THEN YES                                        ELSE NO)
 839 endif(DEFINED WITH_DSHOW)
 840
 841 if(DEFINED WITH_MSMF)
 842   status("    Media Foundation:" HAVE_MSMF    THEN YES                                        ELSE NO)
 843 endif(DEFINED WITH_MSMF)
 844
 845 if(DEFINED WITH_XIMEA)
 846   status("    XIMEA:"          HAVE_XIMEA          THEN YES                                        ELSE NO)
 847 endif(DEFINED WITH_XIMEA)
 848
 849 if(DEFINED WITH_XINE)
 850   status("    Xine:"           HAVE_XINE           THEN "YES (ver ${ALIASOF_libxine_VERSION})"     ELSE NO)
 851 endif(DEFINED WITH_XINE)
 852
 853 if(DEFINED WITH_INTELPERC)
 854   status("    Intel PerC:"     HAVE_INTELPERC      THEN "YES"                                 ELSE NO)
 855 endif(DEFINED WITH_INTELPERC)
 856
 857
 858 # ========================== Other third-party libraries ==========================
 859 status("")
 860 status("  Other third-party libraries:")
 861
 862 if(WITH_IPP AND IPP_FOUND)
 863   status("    Use IPP:" "${IPP_LATEST_VERSION_STR} [${IPP_LATEST_VERSION_MAJOR}.${IPP_LATEST_VERSION_MINOR}.${IPP_LATEST_VERSION_BUILD}]")
 864   status("         at:" "${IPP_ROOT_DIR}")
 865 else()
 866   status("    Use IPP:"   WITH_IPP AND NOT IPP_FOUND THEN "IPP not found" ELSE NO)
 867 endif()
 868
 869 status("    Use Eigen:"      HAVE_EIGEN       THEN "YES (ver ${EIGEN_WORLD_VERSION}.${EIGEN_MAJOR_VERSION}.${EIGEN_MINOR_VERSION})" ELSE NO)
 870 status("    Use TBB:"        HAVE_TBB         THEN "YES (ver ${TBB_VERSION_MAJOR}.${TBB_VERSION_MINOR} interface ${TBB_INTERFACE_VERSION})" ELSE NO)
 871 status("    Use OpenMP:"     HAVE_OPENMP      THEN YES ELSE NO)
 872 status("    Use GCD"         HAVE_GCD         THEN YES ELSE NO)
 873 status("    Use Concurrency" HAVE_CONCURRENCY THEN YES ELSE NO)
 874 status("    Use C=:"         HAVE_CSTRIPES    THEN YES ELSE NO)
 875 status("    Use Cuda:"       HAVE_CUDA        THEN "YES (ver ${CUDA_VERSION_STRING})" ELSE NO)
 876 status("    Use OpenCL:"     HAVE_OPENCL      THEN YES ELSE NO)
 877
 878 if(HAVE_CUDA)
 879   status("")
 880   status("  NVIDIA CUDA")
 881
 882   status("    Use CUFFT:"            HAVE_CUFFT   THEN YES ELSE NO)
 883   status("    Use CUBLAS:"           HAVE_CUBLAS  THEN YES ELSE NO)
 884   status("    USE NVCUVID:"          HAVE_NVCUVID THEN YES ELSE NO)
 885   status("    NVIDIA GPU arch:"      ${OPENCV_CUDA_ARCH_BIN})
 886   status("    NVIDIA PTX archs:"     ${OPENCV_CUDA_ARCH_PTX})
 887   status("    Use fast math:"        CUDA_FAST_MATH THEN YES ELSE NO)
 888 endif()
 889
 890 if(HAVE_OPENCL)
 891   status("")
 892   status("  OpenCL:")
 893   if(HAVE_OPENCL_STATIC)
 894     set(__opencl_ver "static")
 895   else()
 896     set(__opencl_ver "dynamic")
 897   endif()
 898   status("    Version:"       ${__opencl_ver})
 899   if(OPENCL_INCLUDE_DIR)
 900     status("    Include path:"       ${OPENCL_INCLUDE_DIRS})
 901   endif()
 902   if(OPENCL_LIBRARIES)
 903     set(__libs "")
 904     foreach(l ${OPENCL_LIBRARIES})
 905       if(TARGET ${l})
 906         get_target_property(p ${l} LOCATION)
 907         if(p MATCHES NOTFOUND)
 908           list(APPEND __libs "${l}")
 909         else()
 910           list(APPEND __libs "${p}")
 911         endif()
 912       else()
 913         list(APPEND __libs "${l}")
 914       endif()
 915     endforeach()
 916     status("    libraries:"          ${__libs})
 917   endif()
 918   status("    Use AMD FFT:"          HAVE_CLAMDFFT  THEN YES ELSE NO)
 919   status("    Use AMD BLAS:"         HAVE_CLAMDBLAS THEN YES ELSE NO)
 920 endif()
 921
 922 # ========================== python ==========================
 923 status("")
 924 status("  Python:")
 925 status("    Interpreter:"     PYTHON_EXECUTABLE   THEN "${PYTHON_EXECUTABLE} (ver ${PYTHON_VERSION_FULL})"         ELSE NO)
 926 if(BUILD_opencv_python)
 927   if(PYTHONLIBS_VERSION_STRING)
 928     status("    Libraries:"   HAVE_opencv_python  THEN  "${PYTHON_LIBRARIES} (ver ${PYTHONLIBS_VERSION_STRING})"   ELSE NO)
 929   else()
 930     status("    Libraries:"   HAVE_opencv_python  THEN  ${PYTHON_LIBRARIES}                                        ELSE NO)
 931   endif()
 932   status("    numpy:"         PYTHON_USE_NUMPY    THEN "${PYTHON_NUMPY_INCLUDE_DIR} (ver ${PYTHON_NUMPY_VERSION})" ELSE "NO (Python wrappers can not be generated)")
 933   status("    packages path:" PYTHON_EXECUTABLE   THEN "${PYTHON_PACKAGES_PATH}"                                   ELSE "-")
 934 endif()
 935
 936 # ========================== java ==========================
 937 status("")
 938 status("  Java:")
 939 status("    ant:"           ANT_EXECUTABLE      THEN "${ANT_EXECUTABLE} (ver ${ANT_VERSION})"                    ELSE NO)
 940 if(NOT ANDROID)
 941   status("    JNI:"         JNI_INCLUDE_DIRS    THEN "${JNI_INCLUDE_DIRS}"                                       ELSE NO)
 942 endif()
 943 status("    Java tests:"    BUILD_TESTS AND (CAN_BUILD_ANDROID_PROJECTS OR HAVE_opencv_java)            THEN YES ELSE NO)
 944
 945 # ========================== documentation ==========================
 946 if(BUILD_DOCS)
 947   status("")
 948   status("  Documentation:")
 949   if(HAVE_SPHINX)
 950     status("    Build Documentation:" PDFLATEX_COMPILER      THEN YES ELSE "YES (only HTML and without math expressions)")
 951   else()
 952     status("    Build Documentation:" NO)
 953   endif()
 954   status("    Sphinx:"              HAVE_SPHINX              THEN "${SPHINX_BUILD} (ver ${SPHINX_VERSION})" ELSE NO)
 955   status("    PdfLaTeX compiler:"   PDFLATEX_COMPILER        THEN "${PDFLATEX_COMPILER}" ELSE NO)
 956 endif()
 957
 958 # ========================== samples and tests ==========================
 959 status("")
 960 status("  Tests and samples:")
 961 status("    Tests:"             BUILD_TESTS AND HAVE_opencv_ts       THEN YES ELSE NO)
 962 status("    Performance tests:" BUILD_PERF_TESTS AND HAVE_opencv_ts  THEN YES ELSE NO)
 963 status("    C/C++ Examples:"    BUILD_EXAMPLES                       THEN YES ELSE NO)
 964
 965 # ========================== auxiliary ==========================
 966 status("")
 967 status("  Install path:" "${CMAKE_INSTALL_PREFIX}")
 968 status("")
 969 status("  cvconfig.h is in:" "${OPENCV_CONFIG_FILE_INCLUDE_DIR}")
 970 status("-----------------------------------------------------------------")
 971 status("")
 972
 973 ocv_finalize_status()
 974
 975 # ----------------------------------------------------------------------------
 976 # Warn in the case of in-source build
 977 # ----------------------------------------------------------------------------
 978 if("${CMAKE_CURRENT_SOURCE_DIR}" STREQUAL "${CMAKE_CURRENT_BINARY_DIR}")
 979   message(WARNING "The source directory is the same as binary directory. \"make clean\" may damage the source tree")
 980 endif()
 981
 982 # ----------------------------------------------------------------------------
 983 # CPack stuff
 984 # ----------------------------------------------------------------------------
 985
 986 include(cmake/OpenCVPackaging.cmake)