CMakeLists.txt

   1 # Require at least version 2.8.12 of CMake
   2 cmake_minimum_required(VERSION 2.8.12)
   3
   4 if(CMAKE_VERSION VERSION_EQUAL 3.0 OR CMAKE_VERSION VERSION_GREATER 3.0)
   5     cmake_policy(SET CMP0042 NEW)
   6 endif()
   7
   8 # Set the project name
   9 project(CoreCLR)
  10
  11 # Include cmake functions
  12 include(functions.cmake)
  13
  14 # Include global configure settings
  15 include(configure.cmake)
  16
  17 if (WIN32)
  18   message(STATUS "VS_PLATFORM_TOOLSET is ${CMAKE_VS_PLATFORM_TOOLSET}")
  19   message(STATUS "VS_PLATFORM_NAME is ${CMAKE_VS_PLATFORM_NAME}")
  20 endif (WIN32)
  21
  22 # Set commonly used directory names
  23 set(CLR_DIR ${CMAKE_CURRENT_SOURCE_DIR})
  24 set(VM_DIR ${CMAKE_CURRENT_SOURCE_DIR}/src/vm)
  25 set(GENERATED_INCLUDE_DIR ${CMAKE_CURRENT_BINARY_DIR}/src/inc)
  26 set(VERSION_FILE_PATH "${CMAKE_BINARY_DIR}/version.cpp")
  27
  28 set(CORECLR_SET_RPATH ON)
  29 if(CORECLR_SET_RPATH)
  30     # Enable @rpath support for shared libraries.
  31     set(MACOSX_RPATH ON)
  32 endif(CORECLR_SET_RPATH)
  33
  34 OPTION(CLR_CMAKE_ENABLE_CODE_COVERAGE "Enable code coverage" OFF)
  35 OPTION(CLR_CMAKE_WARNINGS_ARE_ERRORS "Warnings are errors" ON)
  36
  37 # Ensure that python is present
  38 find_program(PYTHON python)
  39 if (PYTHON STREQUAL "PYTHON-NOTFOUND")
  40     message(FATAL_ERROR "PYTHON not found: Please install Python 2.7.9 or later from https://www.python.org/downloads/")
  41 endif()
  42
  43 # Ensure other tools are present
  44 if (WIN32)
  45     if(CLR_CMAKE_HOST_ARCH STREQUAL arm)
  46
  47       # Confirm that Windows SDK is present
  48       if(NOT DEFINED CMAKE_VS_WINDOWS_TARGET_PLATFORM_VERSION OR CMAKE_VS_WINDOWS_TARGET_PLATFORM_VERSION STREQUAL "" )
  49               message(FATAL_ERROR "Windows SDK is required for the Arm32 build.")
  50       else()
  51               message("Using Windows SDK version ${CMAKE_VS_WINDOWS_TARGET_PLATFORM_VERSION}")
  52       endif()
  53
  54       # Explicitly specify the assembler to be used for Arm32 compile
  55       if($ENV{__VSVersion} STREQUAL "vs2015")
  56         file(TO_CMAKE_PATH "$ENV{VCINSTALLDIR}\\bin\\x86_arm\\armasm.exe" CMAKE_ASM_COMPILER)
  57       else()
  58         file(TO_CMAKE_PATH "$ENV{VCToolsInstallDir}\\bin\\HostX86\\arm\\armasm.exe" CMAKE_ASM_COMPILER)
  59       endif()
  60
  61       set(CMAKE_ASM_MASM_COMPILER ${CMAKE_ASM_COMPILER})
  62       message("CMAKE_ASM_MASM_COMPILER explicitly set to: ${CMAKE_ASM_MASM_COMPILER}")
  63
  64       # Enable generic assembly compilation to avoid CMake generate VS proj files that explicitly
  65       # use ml[64].exe as the assembler.
  66       enable_language(ASM)
  67     else()
  68       enable_language(ASM_MASM)
  69     endif()
  70
  71     # Ensure that MC is present
  72     find_program(MC mc)
  73     if (MC STREQUAL "MC-NOTFOUND")
  74         message(FATAL_ERROR "MC not found")
  75     endif()
  76
  77     if (CLR_CMAKE_HOST_ARCH STREQUAL arm64)
  78       # CMAKE_CXX_COMPILER will default to the compiler installed with
  79       # Visual studio. Overwrite it to the compiler on the path.
  80       # TODO, remove when cmake generator supports Arm64 as a target.
  81       find_program(PATH_CXX_COMPILER cl)
  82       set(CMAKE_CXX_COMPILER ${PATH_CXX_COMPILER})
  83       message("Overwriting the CMAKE_CXX_COMPILER.")
  84       message(CMAKE_CXX_COMPILER found:${CMAKE_CXX_COMPILER})
  85     endif()
  86
  87 else (WIN32)
  88     enable_language(ASM)
  89
  90     # Ensure that awk is present
  91     find_program(AWK awk)
  92     if (AWK STREQUAL "AWK-NOTFOUND")
  93         message(FATAL_ERROR "AWK not found")
  94     endif()
  95
  96     if (CMAKE_SYSTEM_NAME STREQUAL Darwin)
  97
  98       # Ensure that dsymutil and strip are present
  99       find_program(DSYMUTIL dsymutil)
 100       if (DSYMUTIL STREQUAL "DSYMUTIL-NOTFOUND")
 101           message(FATAL_ERROR "dsymutil not found")
 102       endif()
 103
 104       find_program(STRIP strip)
 105       if (STRIP STREQUAL "STRIP-NOTFOUND")
 106           message(FATAL_ERROR "strip not found")
 107       endif()
 108
 109     else (CMAKE_SYSTEM_NAME STREQUAL Darwin)
 110
 111       # Ensure that objcopy is present
 112       if (CLR_UNIX_CROSS_BUILD AND NOT DEFINED CLR_CROSS_COMPONENTS_BUILD)
 113         if (CMAKE_SYSTEM_PROCESSOR STREQUAL armv7l OR CMAKE_SYSTEM_PROCESSOR STREQUAL aarch64 OR CMAKE_SYSTEM_PROCESSOR STREQUAL arm)
 114           find_program(OBJCOPY ${TOOLCHAIN}-objcopy)
 115         elseif(CMAKE_SYSTEM_PROCESSOR STREQUAL i686)
 116           find_program(OBJCOPY objcopy)
 117         else()
 118           clr_unknown_arch()
 119         endif()
 120       else()
 121         find_program(OBJCOPY objcopy)
 122       endif()
 123
 124       if (OBJCOPY STREQUAL "OBJCOPY-NOTFOUND")
 125           message(FATAL_ERROR "objcopy not found")
 126       endif()
 127
 128     endif (CMAKE_SYSTEM_NAME STREQUAL Darwin)
 129 endif(WIN32)
 130
 131 #----------------------------------------
 132 # Detect and set platform variable names
 133 #     - for non-windows build platform & architecture is detected using inbuilt CMAKE variables and cross target component configure
 134 #     - for windows we use the passed in parameter to CMAKE to determine build arch
 135 #----------------------------------------
 136 if(CMAKE_SYSTEM_NAME STREQUAL Linux)
 137     set(CLR_CMAKE_PLATFORM_UNIX 1)
 138     if(CLR_CROSS_COMPONENTS_BUILD)
 139         # CMAKE_HOST_SYSTEM_PROCESSOR returns the value of `uname -p` on host.
 140         if(CMAKE_HOST_SYSTEM_PROCESSOR STREQUAL x86_64 OR CMAKE_HOST_SYSTEM_PROCESSOR STREQUAL amd64)
 141             if(CLR_CMAKE_TARGET_ARCH STREQUAL "arm")
 142                 set(CLR_CMAKE_PLATFORM_UNIX_X86 1)
 143             else()
 144                 set(CLR_CMAKE_PLATFORM_UNIX_AMD64 1)
 145             endif()
 146         elseif(CMAKE_HOST_SYSTEM_PROCESSOR STREQUAL i686)
 147             set(CLR_CMAKE_PLATFORM_UNIX_X86 1)
 148         else()
 149             clr_unknown_arch()
 150         endif()
 151     else()
 152         # CMAKE_SYSTEM_PROCESSOR returns the value of `uname -p` on target.
 153         # For the AMD/Intel 64bit architecure two different strings are common.
 154         # Linux and Darwin identify it as "x86_64" while FreeBSD and netbsd uses the
 155         # "amd64" string. Accept either of the two here.
 156         if(CMAKE_SYSTEM_PROCESSOR STREQUAL x86_64 OR CMAKE_SYSTEM_PROCESSOR STREQUAL amd64)
 157             set(CLR_CMAKE_PLATFORM_UNIX_AMD64 1)
 158         elseif(CMAKE_SYSTEM_PROCESSOR STREQUAL armv7l)
 159             set(CLR_CMAKE_PLATFORM_UNIX_ARM 1)
 160         elseif(CMAKE_SYSTEM_PROCESSOR STREQUAL arm)
 161             set(CLR_CMAKE_PLATFORM_UNIX_ARM 1)
 162         elseif(CMAKE_SYSTEM_PROCESSOR STREQUAL aarch64)
 163             set(CLR_CMAKE_PLATFORM_UNIX_ARM64 1)
 164         elseif(CMAKE_SYSTEM_PROCESSOR STREQUAL i686)
 165             set(CLR_CMAKE_PLATFORM_UNIX_X86 1)
 166         else()
 167             clr_unknown_arch()
 168         endif()
 169     endif()
 170     set(CLR_CMAKE_PLATFORM_LINUX 1)
 171
 172     # Detect Linux ID
 173     if(DEFINED CLR_CMAKE_LINUX_ID)
 174         if(CLR_CMAKE_LINUX_ID STREQUAL ubuntu)
 175             set(CLR_CMAKE_TARGET_UBUNTU_LINUX 1)
 176         elseif(CLR_CMAKE_LINUX_ID STREQUAL tizen)
 177             set(CLR_CMAKE_TARGET_TIZEN_LINUX 1)
 178         elseif(CLR_CMAKE_LINUX_ID STREQUAL alpine)
 179             set(CLR_CMAKE_PLATFORM_ALPINE_LINUX 1)
 180         endif()
 181         if(CLR_CMAKE_LINUX_ID STREQUAL ubuntu)
 182             set(CLR_CMAKE_PLATFORM_UBUNTU_LINUX 1)
 183         endif()
 184     endif(DEFINED CLR_CMAKE_LINUX_ID)
 185 endif(CMAKE_SYSTEM_NAME STREQUAL Linux)
 186
 187 if(CMAKE_SYSTEM_NAME STREQUAL Darwin)
 188   set(CLR_CMAKE_PLATFORM_UNIX 1)
 189   set(CLR_CMAKE_PLATFORM_UNIX_AMD64 1)
 190   set(CLR_CMAKE_PLATFORM_DARWIN 1)
 191   if(CMAKE_VERSION VERSION_LESS "3.4.0")
 192     set(CMAKE_ASM_COMPILE_OBJECT "${CMAKE_C_COMPILER} <FLAGS> <DEFINES> -o <OBJECT> -c <SOURCE>")
 193   else()
 194     set(CMAKE_ASM_COMPILE_OBJECT "${CMAKE_C_COMPILER} <FLAGS> <DEFINES> <INCLUDES> -o <OBJECT> -c <SOURCE>")
 195   endif(CMAKE_VERSION VERSION_LESS "3.4.0")
 196 endif(CMAKE_SYSTEM_NAME STREQUAL Darwin)
 197
 198 if(CMAKE_SYSTEM_NAME STREQUAL FreeBSD)
 199   set(CLR_CMAKE_PLATFORM_UNIX 1)
 200   set(CLR_CMAKE_PLATFORM_UNIX_AMD64 1)
 201   set(CLR_CMAKE_PLATFORM_FREEBSD 1)
 202 endif(CMAKE_SYSTEM_NAME STREQUAL FreeBSD)
 203
 204 if(CMAKE_SYSTEM_NAME STREQUAL OpenBSD)
 205   set(CLR_CMAKE_PLATFORM_UNIX 1)
 206   set(CLR_CMAKE_PLATFORM_UNIX_AMD64 1)
 207   set(CLR_CMAKE_PLATFORM_OPENBSD 1)
 208 endif(CMAKE_SYSTEM_NAME STREQUAL OpenBSD)
 209
 210 if(CMAKE_SYSTEM_NAME STREQUAL NetBSD)
 211   set(CLR_CMAKE_PLATFORM_UNIX 1)
 212   set(CLR_CMAKE_PLATFORM_UNIX_AMD64 1)
 213   set(CLR_CMAKE_PLATFORM_NETBSD 1)
 214 endif(CMAKE_SYSTEM_NAME STREQUAL NetBSD)
 215
 216 if(CMAKE_SYSTEM_NAME STREQUAL SunOS)
 217   set(CLR_CMAKE_PLATFORM_UNIX 1)
 218   EXECUTE_PROCESS(
 219     COMMAND isainfo -n
 220     OUTPUT_VARIABLE SUNOS_NATIVE_INSTRUCTION_SET
 221     )
 222   if(SUNOS_NATIVE_INSTRUCTION_SET MATCHES "amd64")
 223     set(CLR_CMAKE_PLATFORM_UNIX_AMD64 1)
 224     set(CMAKE_SYSTEM_PROCESSOR "amd64")
 225   else()
 226     clr_unknown_arch()
 227   endif()
 228   set(CLR_CMAKE_PLATFORM_SUNOS 1)
 229 endif(CMAKE_SYSTEM_NAME STREQUAL SunOS)
 230
 231 #--------------------------------------------
 232 # This repo builds two set of binaries
 233 # 1. binaries which execute on target arch machine
 234 #        - for such binaries host architecture & target architecture are same
 235 #        - eg. coreclr.dll
 236 # 2. binaries which execute on host machine but target another architecture
 237 #        - host architecture is different from target architecture
 238 #        - eg. crossgen.exe - runs on x64 machine and generates nis targeting arm64
 239 #        - for complete list of such binaries refer to file crosscomponents.cmake
 240 #-------------------------------------------------------------
 241 # Set HOST architecture variables
 242 if(CLR_CMAKE_PLATFORM_UNIX_ARM)
 243     set(CLR_CMAKE_PLATFORM_ARCH_ARM 1)
 244     set(CLR_CMAKE_HOST_ARCH "arm")
 245 elseif(CLR_CMAKE_PLATFORM_UNIX_ARM64)
 246     set(CLR_CMAKE_PLATFORM_ARCH_ARM64 1)
 247     set(CLR_CMAKE_HOST_ARCH "arm64")
 248 elseif(CLR_CMAKE_PLATFORM_UNIX_AMD64)
 249     set(CLR_CMAKE_PLATFORM_ARCH_AMD64 1)
 250     set(CLR_CMAKE_HOST_ARCH "x64")
 251 elseif(CLR_CMAKE_PLATFORM_UNIX_X86)
 252     set(CLR_CMAKE_PLATFORM_ARCH_I386 1)
 253     set(CLR_CMAKE_HOST_ARCH "x86")
 254 elseif(WIN32)
 255     # CLR_CMAKE_HOST_ARCH is passed in as param to cmake
 256     if (CLR_CMAKE_HOST_ARCH STREQUAL x64)
 257         set(CLR_CMAKE_PLATFORM_ARCH_AMD64 1)
 258     elseif(CLR_CMAKE_HOST_ARCH STREQUAL x86)
 259         set(CLR_CMAKE_PLATFORM_ARCH_I386 1)
 260     elseif(CLR_CMAKE_HOST_ARCH STREQUAL arm)
 261         set(CLR_CMAKE_PLATFORM_ARCH_ARM 1)
 262     elseif(CLR_CMAKE_HOST_ARCH STREQUAL arm64)
 263         set(CLR_CMAKE_PLATFORM_ARCH_ARM64 1)
 264     else()
 265         clr_unknown_arch()
 266     endif()
 267 endif()
 268
 269 # Set TARGET architecture variables
 270 # Target arch will be a cmake param (optional) for both windows as well as non-windows build
 271 # if target arch is not specified then host & target are same
 272 if(NOT DEFINED CLR_CMAKE_TARGET_ARCH OR CLR_CMAKE_TARGET_ARCH STREQUAL "" )
 273   set(CLR_CMAKE_TARGET_ARCH ${CLR_CMAKE_HOST_ARCH})
 274 endif()
 275
 276 # Set target architecture variables
 277 if (CLR_CMAKE_TARGET_ARCH STREQUAL x64)
 278     set(CLR_CMAKE_TARGET_ARCH_AMD64 1)
 279   elseif(CLR_CMAKE_TARGET_ARCH STREQUAL x86)
 280     set(CLR_CMAKE_TARGET_ARCH_I386 1)
 281   elseif(CLR_CMAKE_TARGET_ARCH STREQUAL arm64)
 282     set(CLR_CMAKE_TARGET_ARCH_ARM64 1)
 283   elseif(CLR_CMAKE_TARGET_ARCH STREQUAL arm)
 284     set(CLR_CMAKE_TARGET_ARCH_ARM 1)
 285   else()
 286     clr_unknown_arch()
 287 endif()
 288
 289 # check if host & target arch combination are valid
 290 if(NOT(CLR_CMAKE_TARGET_ARCH STREQUAL CLR_CMAKE_HOST_ARCH))
 291     if(NOT((CLR_CMAKE_PLATFORM_ARCH_AMD64 AND CLR_CMAKE_TARGET_ARCH_ARM64) OR (CLR_CMAKE_PLATFORM_ARCH_I386 AND CLR_CMAKE_TARGET_ARCH_ARM)))
 292         message(FATAL_ERROR "Invalid host and target arch combination")
 293     endif()
 294 endif()
 295
 296 #-----------------------------------------------------
 297 # Initialize Cmake compiler flags and other variables
 298 #-----------------------------------------------------
 299
 300 if (CMAKE_CONFIGURATION_TYPES) # multi-configuration generator?
 301     set(CMAKE_CONFIGURATION_TYPES "Debug;Checked;Release;RelWithDebInfo" CACHE STRING "" FORCE)
 302 endif (CMAKE_CONFIGURATION_TYPES)
 303
 304 set(CMAKE_C_FLAGS_CHECKED ${CLR_C_FLAGS_CHECKED_INIT} CACHE STRING "Flags used by the compiler during checked builds.")
 305 set(CMAKE_CXX_FLAGS_CHECKED ${CLR_CXX_FLAGS_CHECKED_INIT} CACHE STRING "Flags used by the compiler during checked builds.")
 306 set(CMAKE_EXE_LINKER_FLAGS_CHECKED "")
 307 set(CMAKE_SHARED_LINKER_FLAGS_CHECKED "")
 308
 309 set(CMAKE_CXX_STANDARD_LIBRARIES "") # do not link against standard win32 libs i.e. kernel32, uuid, user32, etc.
 310
 311 if (WIN32)
 312   # For multi-configuration toolset (as Visual Studio)
 313   # set the different configuration defines.
 314   foreach (Config DEBUG CHECKED RELEASE RELWITHDEBINFO)
 315     foreach (Definition IN LISTS CLR_DEFINES_${Config}_INIT)
 316       set_property(DIRECTORY APPEND PROPERTY COMPILE_DEFINITIONS $<$<CONFIG:${Config}>:${Definition}>)
 317     endforeach (Definition)
 318   endforeach (Config)
 319
 320   set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} /GUARD:CF")
 321   set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} /GUARD:CF")
 322
 323   # Linker flags
 324   #
 325   set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} /MANIFEST:NO") #Do not create Side-by-Side Assembly Manifest
 326
 327   if (CLR_CMAKE_PLATFORM_ARCH_ARM)
 328     set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} /SUBSYSTEM:WINDOWS,6.02") #windows subsystem - arm minimum is 6.02
 329   elseif(CLR_CMAKE_PLATFORM_ARCH_ARM64)
 330     set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} /SUBSYSTEM:WINDOWS,6.03") #windows subsystem - arm64 minimum is 6.03
 331   else ()
 332     set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} /SUBSYSTEM:WINDOWS,6.01") #windows subsystem
 333   endif ()
 334
 335   set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} /LARGEADDRESSAWARE") # can handle addresses larger than 2 gigabytes
 336   set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} /NXCOMPAT") #Compatible with Data Execution Prevention
 337   set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} /DYNAMICBASE") #Use address space layout randomization
 338   set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} /PDBCOMPRESS") #shrink pdb size
 339   set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} /DEBUG")
 340   set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} /IGNORE:4197,4013,4254,4070,4221")
 341
 342   set(CMAKE_STATIC_LINKER_FLAGS "${CMAKE_STATIC_LINKER_FLAGS} /IGNORE:4221")
 343
 344   set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} /DEBUG /PDBCOMPRESS")
 345   set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} /STACK:1572864")
 346
 347   # Debug build specific flags
 348   set(CMAKE_SHARED_LINKER_FLAGS_DEBUG "/NOVCFEATURE ${NO_INCREMENTAL_LINKER_FLAGS}")
 349   set(CMAKE_EXE_LINKER_FLAGS_DEBUG "${NO_INCREMENTAL_LINKER_FLAGS}")
 350
 351   # Checked build specific flags
 352   set(CMAKE_SHARED_LINKER_FLAGS_CHECKED "${CMAKE_SHARED_LINKER_FLAGS_CHECKED} /OPT:REF /OPT:NOICF /NOVCFEATURE ${NO_INCREMENTAL_LINKER_FLAGS}")
 353   set(CMAKE_STATIC_LINKER_FLAGS_CHECKED "${CMAKE_STATIC_LINKER_FLAGS_CHECKED}")
 354   set(CMAKE_EXE_LINKER_FLAGS_CHECKED "${CMAKE_EXE_LINKER_FLAGS_CHECKED} /OPT:REF /OPT:NOICF ${NO_INCREMENTAL_LINKER_FLAGS}")
 355
 356   # Release build specific flags
 357   set(CMAKE_SHARED_LINKER_FLAGS_RELEASE "${CMAKE_SHARED_LINKER_FLAGS_RELEASE} /LTCG /OPT:REF /OPT:ICF ${NO_INCREMENTAL_LINKER_FLAGS}")
 358   set(CMAKE_STATIC_LINKER_FLAGS_RELEASE "${CMAKE_STATIC_LINKER_FLAGS_RELEASE} /LTCG")
 359   set(CMAKE_EXE_LINKER_FLAGS_RELEASE "${CMAKE_EXE_LINKER_FLAGS_RELEASE} /LTCG /OPT:REF /OPT:ICF ${NO_INCREMENTAL_LINKER_FLAGS}")
 360
 361   # ReleaseWithDebugInfo build specific flags
 362   set(CMAKE_SHARED_LINKER_FLAGS_RELWITHDEBINFO "${CMAKE_SHARED_LINKER_FLAGS_RELWITHDEBINFO} /LTCG /OPT:REF /OPT:ICF ${NO_INCREMENTAL_LINKER_FLAGS}")
 363   set(CMAKE_STATIC_LINKER_FLAGS_RELWITHDEBINFO "${CMAKE_STATIC_LINKER_FLAGS_RELWITHDEBINFO} /LTCG")
 364   set(CMAKE_EXE_LINKER_FLAGS_RELWITHDEBINFO "${CMAKE_EXE_LINKER_FLAGS_RELWITHDEBINFO} /LTCG /OPT:REF /OPT:ICF ${NO_INCREMENTAL_LINKER_FLAGS}")
 365
 366   # Temporary until cmake has VS generators for arm64
 367   if(CLR_CMAKE_PLATFORM_ARCH_ARM64)
 368     set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} /machine:arm64")
 369     set(CMAKE_STATIC_LINKER_FLAGS "${CMAKE_STATIC_LINKER_FLAGS} /machine:arm64")
 370     set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} /machine:arm64")
 371   endif(CLR_CMAKE_PLATFORM_ARCH_ARM64)
 372
 373   # Force uCRT to be dynamically linked for Release build
 374   set(CMAKE_SHARED_LINKER_FLAGS_RELEASE "${CMAKE_SHARED_LINKER_FLAGS_RELEASE} /NODEFAULTLIB:libucrt.lib /DEFAULTLIB:ucrt.lib")
 375   set(CMAKE_EXE_LINKER_FLAGS_RELEASE "${CMAKE_EXE_LINKER_FLAGS_RELEASE} /NODEFAULTLIB:libucrt.lib /DEFAULTLIB:ucrt.lib")
 376   set(CMAKE_SHARED_LINKER_FLAGS_RELWITHDEBINFO "${CMAKE_SHARED_LINKER_FLAGS_RELWITHDEBINFO} /NODEFAULTLIB:libucrt.lib /DEFAULTLIB:ucrt.lib")
 377   set(CMAKE_EXE_LINKER_FLAGS_RELWITHDEBINFO "${CMAKE_EXE_LINKER_FLAGS_RELWITHDEBINFO} /NODEFAULTLIB:libucrt.lib /DEFAULTLIB:ucrt.lib")
 378
 379 elseif (CLR_CMAKE_PLATFORM_UNIX)
 380   # Set the values to display when interactively configuring CMAKE_BUILD_TYPE
 381   set_property(CACHE CMAKE_BUILD_TYPE PROPERTY STRINGS "DEBUG;CHECKED;RELEASE;RELWITHDEBINFO")
 382
 383   # Use uppercase CMAKE_BUILD_TYPE for the string comparisons below
 384   string(TOUPPER ${CMAKE_BUILD_TYPE} UPPERCASE_CMAKE_BUILD_TYPE)
 385
 386   # For single-configuration toolset
 387   # set the different configuration defines.
 388   if (UPPERCASE_CMAKE_BUILD_TYPE STREQUAL DEBUG)
 389     # First DEBUG
 390     set_property(DIRECTORY  PROPERTY COMPILE_DEFINITIONS ${CLR_DEFINES_DEBUG_INIT})
 391   elseif (UPPERCASE_CMAKE_BUILD_TYPE STREQUAL CHECKED)
 392     # Then CHECKED
 393     set_property(DIRECTORY PROPERTY COMPILE_DEFINITIONS ${CLR_DEFINES_CHECKED_INIT})
 394   elseif (UPPERCASE_CMAKE_BUILD_TYPE STREQUAL RELEASE)
 395     # Then RELEASE
 396     set_property(DIRECTORY PROPERTY COMPILE_DEFINITIONS ${CLR_DEFINES_RELEASE_INIT})
 397   elseif (UPPERCASE_CMAKE_BUILD_TYPE STREQUAL RELWITHDEBINFO)
 398     # And then RELWITHDEBINFO
 399     set_property(DIRECTORY APPEND PROPERTY COMPILE_DEFINITIONS ${CLR_DEFINES_RELWITHDEBINFO_INIT})
 400   else ()
 401     message(FATAL_ERROR "Unknown build type! Set CMAKE_BUILD_TYPE to DEBUG, CHECKED, RELEASE, or RELWITHDEBINFO!")
 402   endif ()
 403
 404   # set the CLANG sanitizer flags for debug build
 405   if(UPPERCASE_CMAKE_BUILD_TYPE STREQUAL DEBUG OR UPPERCASE_CMAKE_BUILD_TYPE STREQUAL CHECKED)
 406     # obtain settings from running enablesanitizers.sh
 407     string(FIND "$ENV{DEBUG_SANITIZERS}" "asan" __ASAN_POS)
 408     string(FIND "$ENV{DEBUG_SANITIZERS}" "ubsan" __UBSAN_POS)
 409     if ((${__ASAN_POS} GREATER -1) OR (${__UBSAN_POS} GREATER -1))
 410       set(CLR_SANITIZE_CXX_FLAGS "${CLR_SANITIZE_CXX_FLAGS} -fsanitize-blacklist=${CMAKE_CURRENT_SOURCE_DIR}/sanitizerblacklist.txt -fsanitize=")
 411       set(CLR_SANITIZE_LINK_FLAGS "${CLR_SANITIZE_LINK_FLAGS} -fsanitize=")
 412       if (${__ASAN_POS} GREATER -1)
 413         set(CLR_SANITIZE_CXX_FLAGS "${CLR_SANITIZE_CXX_FLAGS}address,")
 414         set(CLR_SANITIZE_LINK_FLAGS "${CLR_SANITIZE_LINK_FLAGS}address,")
 415         message("Address Sanitizer (asan) enabled")
 416       endif ()
 417       if (${__UBSAN_POS} GREATER -1)
 418         # all sanitizier flags are enabled except alignment (due to heavy use of __unaligned modifier)
 419         set(CLR_SANITIZE_CXX_FLAGS "${CLR_SANITIZE_CXX_FLAGS}bool,bounds,enum,float-cast-overflow,float-divide-by-zero,function,integer,nonnull-attribute,null,object-size,return,returns-nonnull-attribute,shift,unreachable,vla-bound,vptr")
 420         set(CLR_SANITIZE_LINK_FLAGS "${CLR_SANITIZE_LINK_FLAGS}undefined")
 421         message("Undefined Behavior Sanitizer (ubsan) enabled")
 422       endif ()
 423
 424       # -fdata-sections -ffunction-sections: each function has own section instead of one per .o file (needed for --gc-sections)
 425       # -fPIC: enable Position Independent Code normally just for shared libraries but required when linking with address sanitizer
 426       # -O1: optimization level used instead of -O0 to avoid compile error "invalid operand for inline asm constraint"
 427       set(CMAKE_CXX_FLAGS_DEBUG "${CMAKE_CXX_FLAGS_DEBUG} ${CLR_SANITIZE_CXX_FLAGS} -fdata-sections -ffunction-sections -fPIC -O1")
 428       set(CMAKE_CXX_FLAGS_CHECKED "${CMAKE_CXX_FLAGS_CHECKED} ${CLR_SANITIZE_CXX_FLAGS} -fdata-sections -ffunction-sections -fPIC -O1")
 429
 430       set(CMAKE_EXE_LINKER_FLAGS_DEBUG "${CMAKE_EXE_LINKER_FLAGS_DEBUG} ${CLR_SANITIZE_LINK_FLAGS}")
 431       set(CMAKE_EXE_LINKER_FLAGS_CHECKED "${CMAKE_EXE_LINKER_FLAGS_CHECKED} ${CLR_SANITIZE_LINK_FLAGS}")
 432
 433       # -Wl and --gc-sections: drop unused sections\functions (similar to Windows /Gy function-level-linking)
 434       set(CMAKE_SHARED_LINKER_FLAGS_DEBUG "${CMAKE_SHARED_LINKER_FLAGS_DEBUG} ${CLR_SANITIZE_LINK_FLAGS} -Wl,--gc-sections")
 435       set(CMAKE_SHARED_LINKER_FLAGS_CHECKED "${CMAKE_SHARED_LINKER_FLAGS_CHECKED} ${CLR_SANITIZE_LINK_FLAGS} -Wl,--gc-sections")
 436     endif ()
 437   endif(UPPERCASE_CMAKE_BUILD_TYPE STREQUAL DEBUG OR UPPERCASE_CMAKE_BUILD_TYPE STREQUAL CHECKED)
 438 endif(WIN32)
 439
 440 if(CLR_CMAKE_PLATFORM_LINUX)
 441   set(CMAKE_ASM_FLAGS "${CMAKE_ASM_FLAGS} -Wa,--noexecstack")
 442   set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} -Wl,--build-id=sha1")
 443   set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -Wl,--build-id=sha1")
 444 endif(CLR_CMAKE_PLATFORM_LINUX)
 445
 446 #------------------------------------
 447 # Definitions (for platform)
 448 #-----------------------------------
 449 if (CLR_CMAKE_PLATFORM_ARCH_AMD64)
 450   add_definitions(-D_AMD64_)
 451   add_definitions(-D_WIN64)
 452   add_definitions(-DAMD64)
 453   add_definitions(-DBIT64=1)
 454 elseif (CLR_CMAKE_PLATFORM_ARCH_I386)
 455   add_definitions(-D_X86_)
 456 elseif (CLR_CMAKE_PLATFORM_ARCH_ARM)
 457   add_definitions(-D_ARM_)
 458   add_definitions(-DARM)
 459 elseif (CLR_CMAKE_PLATFORM_ARCH_ARM64)
 460   add_definitions(-D_ARM64_)
 461   add_definitions(-DARM64)
 462   add_definitions(-D_WIN64)
 463   add_definitions(-DBIT64=1)
 464 else ()
 465   clr_unknown_arch()
 466 endif ()
 467
 468 if (CLR_CMAKE_PLATFORM_UNIX)
 469   if(CLR_CMAKE_PLATFORM_LINUX)
 470     if(CLR_CMAKE_PLATFORM_UNIX_AMD64)
 471       message("Detected Linux x86_64")
 472       add_definitions(-DLINUX64)
 473     elseif(CLR_CMAKE_PLATFORM_UNIX_ARM)
 474       message("Detected Linux ARM")
 475       add_definitions(-DLINUX32)
 476     elseif(CLR_CMAKE_PLATFORM_UNIX_ARM64)
 477       message("Detected Linux ARM64")
 478       add_definitions(-DLINUX64)
 479     elseif(CLR_CMAKE_PLATFORM_UNIX_X86)
 480       message("Detected Linux i686")
 481       add_definitions(-DLINUX32)
 482     else()
 483       clr_unknown_arch()
 484     endif()
 485   endif(CLR_CMAKE_PLATFORM_LINUX)
 486 endif(CLR_CMAKE_PLATFORM_UNIX)
 487
 488 if (CLR_CMAKE_PLATFORM_UNIX)
 489   add_definitions(-DPLATFORM_UNIX=1)
 490
 491   if(CLR_CMAKE_PLATFORM_DARWIN)
 492     message("Detected OSX x86_64")
 493   endif(CLR_CMAKE_PLATFORM_DARWIN)
 494
 495   if(CLR_CMAKE_PLATFORM_FREEBSD)
 496     message("Detected FreeBSD amd64")
 497   endif(CLR_CMAKE_PLATFORM_FREEBSD)
 498
 499   if(CLR_CMAKE_PLATFORM_NETBSD)
 500     message("Detected NetBSD amd64")
 501   endif(CLR_CMAKE_PLATFORM_NETBSD)
 502 endif(CLR_CMAKE_PLATFORM_UNIX)
 503
 504 if (WIN32)
 505   # Define the CRT lib references that link into Desktop imports
 506   set(STATIC_MT_CRT_LIB  "libcmt$<$<OR:$<CONFIG:Debug>,$<CONFIG:Checked>>:d>.lib")
 507   set(STATIC_MT_VCRT_LIB  "libvcruntime$<$<OR:$<CONFIG:Debug>,$<CONFIG:Checked>>:d>.lib")
 508   set(STATIC_MT_CPP_LIB  "libcpmt$<$<OR:$<CONFIG:Debug>,$<CONFIG:Checked>>:d>.lib")
 509
 510   # Define the uCRT lib reference
 511   set(STATIC_UCRT_LIB  "libucrt$<$<OR:$<CONFIG:Debug>,$<CONFIG:Checked>>:d>.lib")
 512   set(DYNAMIC_UCRT_LIB  "ucrt$<$<OR:$<CONFIG:Debug>,$<CONFIG:Checked>>:d>.lib")
 513 endif(WIN32)
 514
 515 # Architecture specific files folder name
 516 if (CLR_CMAKE_TARGET_ARCH_AMD64)
 517     set(ARCH_SOURCES_DIR amd64)
 518 elseif (CLR_CMAKE_TARGET_ARCH_ARM64)
 519     set(ARCH_SOURCES_DIR arm64)
 520 elseif (CLR_CMAKE_TARGET_ARCH_ARM)
 521     set(ARCH_SOURCES_DIR arm)
 522 elseif (CLR_CMAKE_TARGET_ARCH_I386)
 523     set(ARCH_SOURCES_DIR i386)
 524 else ()
 525     clr_unknown_arch()
 526 endif ()
 527
 528 #--------------------------------------
 529 # Compile Options
 530 #--------------------------------------
 531 include(compileoptions.cmake)
 532
 533 #----------------------------------------------------
 534 # Cross target Component build specific configuration
 535 #----------------------------------------------------
 536 if(CLR_CROSS_COMPONENTS_BUILD)
 537   include(crosscomponents.cmake)
 538 endif(CLR_CROSS_COMPONENTS_BUILD)
 539
 540 #-------------------
 541 # Enable PGO support
 542 #-------------------
 543 include(pgosupport.cmake)
 544
 545 #-----------------------------------------
 546 # Add Projects
 547 #     - project which require platform header not clr's
 548 #     - do not depend on clr's compile definitions
 549 #-----------------------------------------
 550 if(CLR_CMAKE_PLATFORM_UNIX AND NOT DEFINED CLR_CROSS_COMPONENTS_BUILD)
 551     add_subdirectory(src/corefx)
 552 endif()
 553
 554 if(CLR_CMAKE_PLATFORM_UNIX)
 555     add_subdirectory(src/ToolBox/SOS/lldbplugin)
 556     add_subdirectory(src/pal)
 557     add_subdirectory(src/coreclr/hosts)
 558     add_subdirectory(src/ildasm/unixcoreclrloader)
 559 endif(CLR_CMAKE_PLATFORM_UNIX)
 560
 561 # Add this subdir. We install the headers for the jit.
 562 add_subdirectory(src/pal/prebuilt/inc)
 563
 564 add_subdirectory(src/debug/debug-pal)
 565
 566 if(WIN32)
 567   add_subdirectory(src/gc/sample)
 568 endif()
 569
 570 # Above projects do not build with these compile options
 571 # All of the compiler options are specified in file compileoptions.cmake
 572 # Do not add any new options here. They shoul be added in compileoptions.cmake
 573 if(WIN32)
 574   add_compile_options(/FIWarningControl.h) # force include of WarningControl.h
 575   add_compile_options(/Zl) # omit default library name in .OBJ
 576 endif(WIN32)
 577
 578 #--------------------------------
 579 # Definition directives
 580 #  - all clr specific compile definitions should be included in this file
 581 #  - all clr specific feature variable should also be added in this file
 582 #----------------------------------
 583 include(clrdefinitions.cmake)
 584
 585 #-------------------------------------
 586 # Include directory directives
 587 #-------------------------------------
 588 # Include the basic prebuilt headers - required for getting fileversion resource details.
 589 include_directories("src/pal/prebuilt/inc")
 590 include_directories("bin/obj")
 591
 592 if(FEATURE_STANDALONE_GC)
 593   add_definitions(-DFEATURE_STANDALONE_GC)
 594   add_subdirectory(src/gc)
 595 endif(FEATURE_STANDALONE_GC)
 596
 597 if(FEATURE_STANDALONE_GC_ONLY)
 598   add_definitions(-DFEATURE_STANDALONE_GC_ONLY)
 599 endif(FEATURE_STANDALONE_GC_ONLY)
 600
 601 if (CLR_CMAKE_PLATFORM_UNIX)
 602   include_directories("src/pal/inc")
 603   include_directories("src/pal/inc/rt")
 604   include_directories("src/pal/src/safecrt")
 605 endif (CLR_CMAKE_PLATFORM_UNIX)
 606
 607 # Microsoft.Dotnet.BuildTools.Coreclr version
 608 set(BuildToolsVersion "1.0.4-prerelease")
 609 set(BuildToolsDir "${CLR_DIR}/packages/Microsoft.DotNet.BuildTools.CoreCLR/${BuildToolsVersion}")
 610
 611 #------------------------------
 612 # Add Product Directory
 613 #------------------------------
 614 add_subdirectory(src)
 615
 616 #------------------------------
 617 # Add Test Directory
 618 #------------------------------
 619 if(CLR_CMAKE_BUILD_TESTS)
 620   # remove some definitions for test build
 621   remove_definitions(-D_SECURE_SCL=0)
 622   remove_definitions(-DUNICODE)
 623   remove_definitions(-D_UNICODE)
 624
 625   add_subdirectory(tests)
 626 endif(CLR_CMAKE_BUILD_TESTS)
 627
 628 include(definitionsconsistencycheck.cmake)