CMakeLists.txt

   1 # The name of our project is "VULKAN". CMakeLists files in this project can
   2 # refer to the root source directory of the project as ${VULKAN_SOURCE_DIR} and
   3 # to the root binary directory of the project as ${VULKAN_BINARY_DIR}.
   4 cmake_minimum_required(VERSION 2.8.11)
   5
   6 # This must come before the project command.
   7 set(CMAKE_OSX_DEPLOYMENT_TARGET "10.12" CACHE STRING "Minimum OS X deployment version")
   8
   9 project (VULKAN)
  10 # set (CMAKE_VERBOSE_MAKEFILE 1)
  11
  12 # The API_NAME allows renaming builds to avoid conflicts with installed SDKs
  13 # The MAJOR number of the version we're building, used in naming
  14 # <api-name>-<major>.dll (and other files).
  15 set(API_NAME "Vulkan" CACHE STRING "API name to use when building")
  16 set(MAJOR "1")
  17 string(TOLOWER ${API_NAME} API_LOWERCASE)
  18
  19 set(CMAKE_MODULE_PATH ${CMAKE_MODULE_PATH} "${CMAKE_CURRENT_SOURCE_DIR}/cmake")
  20 find_package(PythonInterp 3 REQUIRED)
  21
  22 # If CMAKE 3.7+, use FindVulkan
  23 if (NOT CMAKE_VERSION VERSION_LESS 3.7.0)
  24     message(STATUS "Using find_package to locate Vulkan")
  25     find_package(Vulkan)
  26 endif()
  27
  28 option(USE_CCACHE "Use ccache" OFF)
  29 if (USE_CCACHE)
  30     find_program(CCACHE_FOUND ccache)
  31     if(CCACHE_FOUND)
  32         set_property(GLOBAL PROPERTY RULE_LAUNCH_COMPILE ccache)
  33         set_property(GLOBAL PROPERTY RULE_LAUNCH_LINK ccache)
  34     endif(CCACHE_FOUND)
  35 endif()
  36
  37 if(APPLE)
  38     # CMake versions 3 or later need CMAKE_MACOSX_RPATH defined.
  39     # This avoids the CMP0042 policy message.
  40     set(CMAKE_MACOSX_RPATH 1)
  41     # The "install" target for MacOS fixes up bundles in place.
  42     set(CMAKE_INSTALL_PREFIX ${CMAKE_BINARY_DIR})
  43 endif()
  44
  45 # Enable cmake folders
  46 set_property(GLOBAL PROPERTY USE_FOLDERS ON)
  47 set(LVL_TARGET_FOLDER lvl_cmake_targets)
  48
  49 # Move to ICD
  50 set(SCRIPTS_DIR "${CMAKE_CURRENT_SOURCE_DIR}/scripts")
  51
  52 # Header file for CMake settings
  53 include_directories("${PROJECT_SOURCE_DIR}/include")
  54
  55 if (CMAKE_COMPILER_IS_GNUCC OR CMAKE_C_COMPILER_ID MATCHES "Clang")
  56     set(COMMON_COMPILE_FLAGS "-Wall -Wextra -Wno-unused-parameter -Wno-missing-field-initializers")
  57     set(COMMON_COMPILE_FLAGS "${COMMON_COMPILE_FLAGS} -fno-strict-aliasing -fno-builtin-memcmp")
  58
  59     # For GCC version 7.1 or greater, we need to disable the implicit fallthrough warning since
  60     # there's no consistent way to satisfy all compilers until they all accept the C++17 standard
  61     if (CMAKE_COMPILER_IS_GNUCC AND NOT (CMAKE_CXX_COMPILER_VERSION LESS 7.1))
  62         set(COMMON_COMPILE_FLAGS "${COMMON_COMPILE_FLAGS} -Wimplicit-fallthrough=0")
  63     endif()
  64
  65     if (APPLE)
  66         set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} ${COMMON_COMPILE_FLAGS}")
  67     else()
  68         set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -std=c99 ${COMMON_COMPILE_FLAGS}")
  69     endif()
  70     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} ${COMMON_COMPILE_FLAGS} -std=c++11 -fno-rtti")
  71     if (UNIX)
  72         set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -fvisibility=hidden")
  73         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -fvisibility=hidden")
  74     endif()
  75 endif()
  76
  77 if(WIN32)
  78     # Treat warnings as errors
  79     add_compile_options("$<$<CXX_COMPILER_ID:MSVC>:/WX>")
  80     # Disable RTTI
  81     add_compile_options("$<$<CXX_COMPILER_ID:MSVC>:/GR->")
  82     # Warn about nested declarations
  83     add_compile_options("$<$<CXX_COMPILER_ID:MSVC>:/w34456>")
  84     # Warn about potentially uninitialized variables
  85     add_compile_options("$<$<CXX_COMPILER_ID:MSVC>:/w34701>")
  86     add_compile_options("$<$<CXX_COMPILER_ID:MSVC>:/w34703>")
  87     # Warn about different indirection types.
  88     add_compile_options("$<$<CXX_COMPILER_ID:MSVC>:/w34057>")
  89     # Warn about signed/unsigned mismatch.
  90     add_compile_options("$<$<CXX_COMPILER_ID:MSVC>:/w34245>")
  91 endif()
  92
  93 if(NOT WIN32)
  94     set (BUILDTGT_DIR build)
  95     set (BINDATA_DIR Bin)
  96     set (LIBSOURCE_DIR Lib)
  97 else()
  98     # is WIN32
  99     option(DISABLE_BUILD_PATH_DECORATION "Disable the decoration of the gslang and SPIRV-Tools build path with MSVC build type info" OFF)
 100     option(DISABLE_BUILDTGT_DIR_DECORATION "Disable the decoration of the gslang and SPIRV-Tools build path with target info" OFF)
 101     option(ENABLE_WIN10_ONECORE "Link the loader with OneCore umbrella libraries" OFF)
 102
 103     # For Windows, since 32-bit and 64-bit items can co-exist, we build each in its own build directory.
 104     # 32-bit target data goes in build32, and 64-bit target data goes into build.  So, include/link the
 105     # appropriate data at build time.
 106     if (DISABLE_BUILDTGT_DIR_DECORATION)
 107         set (BUILDTGT_DIR "")
 108         set (BINDATA_DIR "")
 109         set (LIBSOURCE_DIR "")
 110     elseif (CMAKE_CL_64)
 111         set (BUILDTGT_DIR build)
 112         set (BINDATA_DIR Bin)
 113         set (LIBSOURCE_DIR Lib)
 114     else()
 115         set (BUILDTGT_DIR build32)
 116         set (BINDATA_DIR Bin32)
 117         set (LIBSOURCE_DIR Lib32)
 118     endif()
 119 endif()
 120
 121 option(BUILD_CUBE "Build cube" ON)
 122 option(BUILD_VULKANINFO "Build vulkaninfo" ON)
 123 option(BUILD_ICD "Build icd" ON)
 124
 125 find_program(GLSLANG_VALIDATOR NAMES glslangValidator
 126              HINTS "${EXTERNAL_SOURCE_ROOT}/glslang/${BUILDTGT_DIR}/install/bin"
 127                    "${GLSLANG_BINARY_ROOT}/StandAlone"
 128                    "${PROJECT_SOURCE_DIR}/external/${BINDATA_DIR}")
 129
 130 find_library(Vulkan_LIBRARY NAMES vulkan-1 vulkan
 131              HINTS ${VK_SDK_PATH} )
 132
 133
 134 set (PYTHON_CMD ${PYTHON_EXECUTABLE})
 135
 136 # Move to icd dir
 137 # Define macro used for building vkxml generated files
 138 macro(run_vk_xml_generate dependency output)
 139     add_custom_command(OUTPUT ${output}
 140     COMMAND ${PYTHON_CMD} ${SCRIPTS_DIR}/lvl_genvk.py -registry ${SCRIPTS_DIR}/vk.xml ${output}
 141     DEPENDS ${SCRIPTS_DIR}/vk.xml ${SCRIPTS_DIR}/generator.py ${SCRIPTS_DIR}/${dependency} ${SCRIPTS_DIR}/lvl_genvk.py ${SCRIPTS_DIR}/reg.py
 142     )
 143 endmacro()
 144
 145 if(UNIX)
 146     if(INSTALL_LVL_FILES)
 147         install(DIRECTORY "${PROJECT_SOURCE_DIR}/include/vulkan" DESTINATION ${CMAKE_INSTALL_INCLUDEDIR})
 148     endif()
 149
 150     # uninstall target
 151     configure_file(
 152         "${CMAKE_CURRENT_SOURCE_DIR}/cmake/cmake_uninstall.cmake.in"
 153         "${CMAKE_CURRENT_BINARY_DIR}/cmake_uninstall.cmake"
 154         IMMEDIATE @ONLY)
 155
 156     add_custom_target(uninstall
 157         COMMAND ${CMAKE_COMMAND} -P ${CMAKE_CURRENT_BINARY_DIR}/cmake_uninstall.cmake)
 158 endif()
 159
 160 add_definitions(-DAPI_NAME="${API_NAME}")
 161
 162 if(BUILD_CUBE)
 163     add_subdirectory(cube)
 164 endif()
 165 if(BUILD_VULKANINFO)
 166     add_subdirectory(vulkaninfo)
 167 endif()
 168 if(BUILD_ICD)
 169     add_subdirectory(icd)
 170 endif()