CMakeLists.txt

   1 cmake_minimum_required(VERSION 2.8.10)
   2
   3 # Set a default build type if none was specified
   4 if(NOT CMAKE_BUILD_TYPE AND NOT CMAKE_CONFIGURATION_TYPES)
   5   message(STATUS "Setting build type to 'Release' as none was specified.")
   6   set(CMAKE_BUILD_TYPE Release CACHE STRING "Choose the type of build." FORCE)
   7   # Set the possible values of build type for cmake-gui
   8   set_property(CACHE CMAKE_BUILD_TYPE PROPERTY STRINGS "Debug" "Release" "MinSizeRel" "RelWithDebInfo")
   9 endif()
  10
  11 project(LAPACK Fortran)
  12
  13 set(LAPACK_MAJOR_VERSION 3)
  14 set(LAPACK_MINOR_VERSION 6)
  15 set(LAPACK_PATCH_VERSION 1)
  16 set(
  17   LAPACK_VERSION
  18   ${LAPACK_MAJOR_VERSION}.${LAPACK_MINOR_VERSION}.${LAPACK_PATCH_VERSION}
  19   )
  20
  21 # Updated OSX RPATH settings
  22 # In response to CMake 3.0 generating warnings regarding policy CMP0042,
  23 # the OSX RPATH settings have been updated per recommendations found
  24 # in the CMake Wiki:
  25 #  http://www.cmake.org/Wiki/CMake_RPATH_handling#Mac_OS_X_and_the_RPATH
  26     set(CMAKE_MACOSX_RPATH ON)
  27     set(CMAKE_SKIP_BUILD_RPATH FALSE)
  28     set(CMAKE_BUILD_WITH_INSTALL_RPATH FALSE)
  29     list(FIND CMAKE_PLATFORM_IMPLICIT_LINK_DIRECTORIES "${CMAKE_INSTALL_PREFIX}/lib${LIB_SUFFIX}" isSystemDir)
  30     if("${isSystemDir}" STREQUAL "-1")
  31         set(CMAKE_INSTALL_RPATH "${CMAKE_INSTALL_PREFIX}/lib${LIB_SUFFIX}")
  32         set(CMAKE_INSTALL_RPATH_USE_LINK_PATH TRUE)
  33     endif()
  34
  35
  36 # Configure the warning and code coverage suppression file
  37 configure_file(
  38   "${LAPACK_SOURCE_DIR}/CTestCustom.cmake.in"
  39   "${LAPACK_BINARY_DIR}/CTestCustom.cmake"
  40   @ONLY
  41 )
  42
  43 # Add the CMake directory for custon CMake modules
  44 set(CMAKE_MODULE_PATH "${LAPACK_SOURCE_DIR}/CMAKE" ${CMAKE_MODULE_PATH})
  45 include(PreventInSourceBuilds)
  46 include(PreventInBuildInstalls)
  47
  48 if (UNIX)
  49    if ( "${CMAKE_Fortran_COMPILER}" MATCHES "ifort" )
  50   set( CMAKE_Fortran_FLAGS "${CMAKE_Fortran_FLAGS} -fp-model strict" )
  51    endif ()
  52    if ( "${CMAKE_Fortran_COMPILER}" MATCHES "xlf" )
  53   set( CMAKE_Fortran_FLAGS "${CMAKE_Fortran_FLAGS} -qnosave -qstrict=none" )
  54    endif ()
  55 # Delete libmtsk in linking sequence for Sun/Oracle Fortran Compiler.
  56 # This library is not present in the Sun package SolarisStudio12.3-linux-x86-bin
  57    string(REPLACE \;mtsk\; \; CMAKE_Fortran_IMPLICIT_LINK_LIBRARIES "${CMAKE_Fortran_IMPLICIT_LINK_LIBRARIES}")
  58 endif ()
  59
  60 if ( CMAKE_Fortran_COMPILER_ID STREQUAL "Compaq" )
  61    if ( WIN32 )
  62       if (CMAKE_GENERATOR STREQUAL "NMake Makefiles")
  63          get_filename_component(CMAKE_Fortran_COMPILER_CMDNAM ${CMAKE_Fortran_COMPILER} NAME_WE)
  64          message(STATUS "Using Compaq Fortran compiler with command name ${CMAKE_Fortran_COMPILER_CMDNAM}")
  65          set( cmd ${CMAKE_Fortran_COMPILER_CMDNAM} )
  66          string( TOLOWER "${cmd}" cmdlc )
  67          if ( cmdlc STREQUAL "df" )
  68             message(STATUS "Assume the Compaq Visual Fortran Compiler is being used")
  69             set(CMAKE_Fortran_USE_RESPONSE_FILE_FOR_OBJECTS 1)
  70             set(CMAKE_Fortran_USE_RESPONSE_FILE_FOR_INCLUDES 1)
  71             #This is a workaround that is needed to avoid forward-slashes in the
  72             #filenames listed in response files from incorrectly being interpreted as
  73             #introducing compiler command options
  74           if (${BUILD_SHARED_LIBS})
  75                message(FATAL_ERROR "Making of shared libraries with CVF has not been tested.")
  76             endif()
  77             set(str "NMake version 9 or later should be used. NMake version 6.0 which is\n")
  78             set(str "${str}   included with the CVF distribution fails to build Lapack because\n")
  79             set(str "${str}   the number of source files exceeds the limit for NMake v6.0\n")
  80             message(STATUS ${str})
  81             set(CMAKE_Fortran_LINK_EXECUTABLE "LINK /out:<TARGET> <LINK_FLAGS> <LINK_LIBRARIES> <OBJECTS>")
  82          endif()
  83       endif()
  84    endif()
  85 endif()
  86
  87 # Get Python
  88 message(STATUS "Looking for Python greater than 2.6 - ${PYTHONINTERP_FOUND}")
  89 find_package(PythonInterp 2.7) # lapack_testing.py uses features from python 2.7 and greater
  90 if (PYTHONINTERP_FOUND)
  91    message(STATUS "Using Python version ${PYTHON_VERSION_STRING}")
  92 else()
  93    message(STATUS "No suitable Python version found, so skipping summary tests.")
  94 endif()
  95 # --------------------------------------------------
  96
  97 set(LAPACK_INSTALL_EXPORT_NAME lapack-targets)
  98
  99 if (UNIX)
 100   include(GNUInstallDirs)
 101   set(ARCHIVE_DIR ${CMAKE_INSTALL_LIBDIR})
 102   set(LIBRARY_DIR ${CMAKE_INSTALL_LIBDIR})
 103   set(RUNTIME_DIR ${CMAKE_INSTALL_BINDIR})
 104 else()
 105   set(ARCHIVE_DIR lib${LIB_SUFFIX})
 106   set(LIBRARY_DIR lib${LIB_SUFFIX})
 107   set(RUNTIME_DIR bin)
 108 endif()
 109
 110 macro(lapack_install_library lib)
 111   install(TARGETS ${lib}
 112     EXPORT ${LAPACK_INSTALL_EXPORT_NAME}
 113     ARCHIVE DESTINATION ${ARCHIVE_DIR}
 114     LIBRARY DESTINATION ${LIBRARY_DIR}
 115     RUNTIME DESTINATION ${RUNTIME_DIR}
 116   )
 117 endmacro()
 118
 119 # --------------------------------------------------
 120 # Testing
 121
 122 enable_testing()
 123 include(CTest)
 124 enable_testing()
 125 # --------------------------------------------------
 126
 127 # Organize output files.  On Windows this also keeps .dll files next
 128 # to the .exe files that need them, making tests easy to run.
 129 set(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${LAPACK_BINARY_DIR}/bin)
 130 set(CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${LAPACK_BINARY_DIR}/lib)
 131 set(CMAKE_LIBRARY_OUTPUT_DIRECTORY ${LAPACK_BINARY_DIR}/lib)
 132
 133 # --------------------------------------------------
 134 # Check for any necessary platform specific compiler flags
 135 include( CheckLAPACKCompilerFlags )
 136 CheckLAPACKCompilerFlags()
 137
 138 # --------------------------------------------------
 139 # Check second function
 140
 141 include(CheckTimeFunction)
 142 set(TIME_FUNC NONE ${TIME_FUNC})
 143 CHECK_TIME_FUNCTION(NONE TIME_FUNC)
 144 CHECK_TIME_FUNCTION(INT_CPU_TIME TIME_FUNC)
 145 CHECK_TIME_FUNCTION(EXT_ETIME TIME_FUNC)
 146 CHECK_TIME_FUNCTION(EXT_ETIME_ TIME_FUNC)
 147 CHECK_TIME_FUNCTION(INT_ETIME TIME_FUNC)
 148 message(STATUS "--> Will use second_${TIME_FUNC}.f and dsecnd_${TIME_FUNC}.f as timing function.")
 149
 150 set(SECOND_SRC  ${LAPACK_SOURCE_DIR}/INSTALL/second_${TIME_FUNC}.f)
 151 set(DSECOND_SRC  ${LAPACK_SOURCE_DIR}/INSTALL/dsecnd_${TIME_FUNC}.f)
 152 set(PKG_CONFIG_DIR ${LIBRARY_DIR}/pkgconfig)
 153
 154 # --------------------------------------------------
 155 # Precision to build
 156 # By default all precisions are generated
 157
 158
 159 # --------------------------------------------------
 160 # Subdirectories that need to be processed
 161
 162 option(USE_OPTIMIZED_BLAS "Whether or not to use an optimized BLAS library instead of included netlib BLAS" OFF)
 163
 164
 165 # Check the usage of the user provided BLAS libraries
 166 if(BLAS_LIBRARIES)
 167   include(CheckFortranFunctionExists)
 168   set(CMAKE_REQUIRED_LIBRARIES ${BLAS_LIBRARIES})
 169   CHECK_FORTRAN_FUNCTION_EXISTS("dgemm" BLAS_FOUND)
 170   unset( CMAKE_REQUIRED_LIBRARIES )
 171   if(BLAS_FOUND)
 172     message(STATUS "--> BLAS supplied by user is WORKING, will use ${BLAS_LIBRARIES}.")
 173   else()
 174     message(ERROR "--> BLAS supplied by user is not WORKING, CANNOT USE ${BLAS_LIBRARIES}.")
 175     message(ERROR "-->     Will use REFERENCE BLAS (by default)")
 176     message(ERROR "-->     Or Correct your BLAS_LIBRARIES entry ")
 177     message(ERROR "-->     Or Consider checking USE_OPTIMIZED_BLAS")
 178   endif()
 179
 180 # User did not provide a BLAS Library but specified to search for one
 181 elseif( USE_OPTIMIZED_BLAS )
 182   find_package( BLAS )
 183 endif ()
 184
 185 # Neither user specified or optimized BLAS libraries can be used
 186 if(NOT BLAS_FOUND)
 187   message(STATUS "Using supplied NETLIB BLAS implementation")
 188   add_subdirectory(BLAS)
 189   set( BLAS_LIBRARIES blas )
 190 else()
 191   set( CMAKE_EXE_LINKER_FLAGS
 192     "${CMAKE_EXE_LINKER_FLAGS} ${BLAS_LINKER_FLAGS}"
 193     CACHE STRING "Linker flags for executables" FORCE)
 194   set( CMAKE_MODULE_LINKER_FLAGS
 195     "${CMAKE_MODULE_LINKER_FLAGS} ${BLAS_LINKER_FLAGS}"
 196     CACHE STRING "Linker flags for modules" FORCE)
 197   set( CMAKE_SHARED_LINKER_FLAGS
 198     "${CMAKE_SHARED_LINKER_FLAGS} ${BLAS_LINKER_FLAGS}"
 199     CACHE STRING "Linker flags for shared libs" FORCE)
 200 endif()
 201
 202
 203 # --------------------------------------------------
 204 # CBLAS
 205 option(CBLAS "Build CBLAS" OFF)
 206
 207 if(CBLAS)
 208   add_subdirectory(CBLAS)
 209 endif()
 210
 211 # --------------------------------------------------
 212 # XBLAS
 213
 214 option(USE_XBLAS "Build extended precision (needs XBLAS)" OFF)
 215 if (USE_XBLAS)
 216   find_library(XBLAS_LIBRARY NAMES xblas)
 217 endif()
 218
 219 option(USE_OPTIMIZED_LAPACK "Whether or not to use an optimized LAPACK library instead of included netlib LAPACK" OFF)
 220
 221 # --------------------------------------------------
 222 # LAPACK
 223 # User did not provide a LAPACK Library but specified to search for one
 224 if( USE_OPTIMIZED_LAPACK )
 225   find_package( LAPACK )
 226 endif ()
 227
 228 # Check the usage of the user provided or automatically found LAPACK libraries
 229 if(LAPACK_LIBRARIES)
 230   include(CheckFortranFunctionExists)
 231   set(CMAKE_REQUIRED_LIBRARIES ${LAPACK_LIBRARIES})
 232   # Check if new routine of 3.4.0 is in LAPACK_LIBRARIES
 233   CHECK_FORTRAN_FUNCTION_EXISTS("dgeqrt" LATESTLAPACK_FOUND)
 234   unset( CMAKE_REQUIRED_LIBRARIES )
 235   if(LATESTLAPACK_FOUND)
 236     message(STATUS "--> LAPACK supplied by user is WORKING, will use ${LAPACK_LIBRARIES}.")
 237   else()
 238     message(ERROR "--> LAPACK supplied by user is not WORKING or is older than LAPACK 3.4.0,    CANNOT USE ${LAPACK_LIBRARIES}.")
 239     message(ERROR "-->     Will use REFERENCE LAPACK (by default)")
 240     message(ERROR "-->     Or Correct your LAPACK_LIBRARIES entry ")
 241     message(ERROR "-->     Or Consider checking USE_OPTIMIZED_LAPACK")
 242   endif()
 243 endif ()
 244
 245 # Neither user specified or optimized LAPACK libraries can be used
 246 if(NOT LATESTLAPACK_FOUND)
 247   message(STATUS "Using supplied NETLIB LAPACK implementation")
 248   set( LAPACK_LIBRARIES lapack )
 249   option(BUILD_SINGLE "Build LAPACK Single Precision" ON)
 250   option(BUILD_DOUBLE "Build LAPACK Double Precision" ON)
 251   option(BUILD_COMPLEX "Build LAPACK Complex Precision" ON)
 252   option(BUILD_COMPLEX16 "Build LAPACK Double Complex Precision" ON)
 253   add_subdirectory(SRC)
 254 else()
 255   set( CMAKE_EXE_LINKER_FLAGS
 256     "${CMAKE_EXE_LINKER_FLAGS} ${LAPACK_LINKER_FLAGS}"
 257     CACHE STRING "Linker flags for executables" FORCE)
 258   set( CMAKE_MODULE_LINKER_FLAGS
 259     "${CMAKE_MODULE_LINKER_FLAGS} ${LAPACK_LINKER_FLAGS}"
 260     CACHE STRING "Linker flags for modules" FORCE)
 261   set( CMAKE_SHARED_LINKER_FLAGS
 262     "${CMAKE_SHARED_LINKER_FLAGS} ${LAPACK_LINKER_FLAGS}"
 263     CACHE STRING "Linker flags for shared libs" FORCE)
 264 endif()
 265
 266 message(STATUS "BUILD TESTING : ${BUILD_TESTING}" )
 267 if(BUILD_TESTING)
 268   add_subdirectory(TESTING)
 269 endif()
 270
 271 # deprecated LAPACK routines
 272 option(BUILD_DEPRECATED "Build deprecated routines" OFF)
 273
 274 # --------------------------------------------------
 275 # LAPACKE
 276 option(LAPACKE "Build LAPACKE" OFF)
 277
 278 # LAPACKE has also the interface to some routines from tmglib,
 279 # if LAPACKE_WITH_TMG is selected, we need to add those routines to LAPACKE
 280 option(LAPACKE_WITH_TMG "Build LAPACKE with tmglib routines" OFF)
 281 if (LAPACKE_WITH_TMG)
 282   set(LAPACKE ON)
 283 endif()
 284 if(BUILD_TESTING OR LAPACKE_WITH_TMG) #already included, avoid double inclusion
 285      add_subdirectory(TESTING/MATGEN)
 286 endif()
 287
 288 if(LAPACKE)
 289   add_subdirectory(LAPACKE)
 290 endif()
 291
 292 # --------------------------------------------------
 293 # CPACK Packaging
 294
 295 set(CPACK_PACKAGE_NAME "LAPACK")
 296 set(CPACK_PACKAGE_VENDOR "University of Tennessee, Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd")
 297 set(CPACK_PACKAGE_DESCRIPTION_SUMMARY "LAPACK- Linear Algebra Package")
 298 set(CPACK_PACKAGE_VERSION_MAJOR 3)
 299 set(CPACK_PACKAGE_VERSION_MINOR 5)
 300 set(CPACK_PACKAGE_VERSION_PATCH 0)
 301 set(CPACK_RESOURCE_FILE_LICENSE "${CMAKE_CURRENT_SOURCE_DIR}/LICENSE")
 302 set(CPACK_PACKAGE_INSTALL_DIRECTORY "LAPACK")
 303 if(WIN32 AND NOT UNIX)
 304   # There is a bug in NSI that does not handle full unix paths properly. Make
 305   # sure there is at least one set of four (4) backlasshes.
 306   set(CPACK_NSIS_HELP_LINK "http:\\\\\\\\http://icl.cs.utk.edu/lapack-forum")
 307   set(CPACK_NSIS_URL_INFO_ABOUT "http:\\\\\\\\www.netlib.org/lapack")
 308   set(CPACK_NSIS_CONTACT "lapack@eecs.utk.edu")
 309   set(CPACK_NSIS_MODIFY_PATH ON)
 310   set(CPACK_NSIS_DISPLAY_NAME "LAPACK-${LAPACK_VERSION}")
 311   set(CPACK_PACKAGE_RELOCATABLE "true")
 312 else()
 313   set(CPACK_GENERATOR "TGZ")
 314   set(CPACK_SOURCE_GENERATOR TGZ)
 315   set(CPACK_SOURCE_PACKAGE_FILE_NAME "lapack-${LAPACK_VERSION}" )
 316   set(CPACK_SOURCE_IGNORE_FILES ~$ .svn ${CPACK_SOURCE_IGNORE_FILES} )
 317 endif()
 318 include(CPack)
 319
 320
 321 # --------------------------------------------------
 322 # By default static library
 323 option(BUILD_SHARED_LIBS "Build shared libraries" OFF )
 324 option(BUILD_STATIC_LIBS "Build static libraries" ON )
 325 #option(BUILD_SHARED_LIBS "Build shared libraries" ON )
 326
 327 if(NOT BLAS_FOUND)
 328   set(ALL_TARGETS ${ALL_TARGETS} blas)
 329 endif()
 330
 331 if(NOT LATESTLAPACK_FOUND)
 332   set(ALL_TARGETS ${ALL_TARGETS} lapack)
 333 endif()
 334
 335 if(BUILD_TESTING OR LAPACKE_WITH_TMG)
 336   set(ALL_TARGETS ${ALL_TARGETS} tmglib)
 337 endif()
 338
 339 # Export lapack targets, not including lapacke, from the
 340 # install tree, if any.
 341 set(_lapack_config_install_guard_target "")
 342 if(ALL_TARGETS)
 343   install(EXPORT lapack-targets
 344     DESTINATION ${LIBRARY_DIR}/cmake/lapack-${LAPACK_VERSION})
 345
 346   # Choose one of the lapack targets to use as a guard for
 347   # lapack-config.cmake to load targets from the install tree.
 348   list(GET ALL_TARGETS 0 _lapack_config_install_guard_target)
 349 endif()
 350
 351 # Include cblas in targets exported from the build tree.
 352 if(CBLAS)
 353   set(ALL_TARGETS ${ALL_TARGETS} cblas)
 354 endif()
 355
 356 # Include lapacke in targets exported from the build tree.
 357 if(LAPACKE)
 358   set(ALL_TARGETS ${ALL_TARGETS} lapacke)
 359 endif()
 360
 361 # Export lapack and lapacke targets from the build tree, if any.
 362 set(_lapack_config_build_guard_target "")
 363 if(ALL_TARGETS)
 364   export(TARGETS ${ALL_TARGETS} FILE lapack-targets.cmake)
 365
 366   # Choose one of the lapack or lapacke targets to use as a guard
 367   # for lapack-config.cmake to load targets from the build tree.
 368   list(GET ALL_TARGETS 0 _lapack_config_build_guard_target)
 369 endif()
 370
 371 configure_file(${LAPACK_SOURCE_DIR}/CMAKE/lapack-config-build.cmake.in
 372   ${LAPACK_BINARY_DIR}/lapack-config.cmake @ONLY)
 373
 374
 375 configure_file(${CMAKE_CURRENT_SOURCE_DIR}/lapack.pc.in ${CMAKE_CURRENT_BINARY_DIR}/lapack.pc)
 376   install(FILES
 377   ${CMAKE_CURRENT_BINARY_DIR}/lapack.pc
 378   DESTINATION ${PKG_CONFIG_DIR}
 379    )
 380
 381 configure_file(${LAPACK_SOURCE_DIR}/CMAKE/lapack-config-install.cmake.in
 382   ${LAPACK_BINARY_DIR}/CMakeFiles/lapack-config.cmake @ONLY)
 383
 384 include(CMakePackageConfigHelpers)
 385 write_basic_package_version_file(
 386   ${LAPACK_BINARY_DIR}/lapack-config-version.cmake
 387   VERSION ${LAPACK_VERSION}
 388   COMPATIBILITY SameMajorVersion
 389   )
 390
 391 install(FILES
 392   ${LAPACK_BINARY_DIR}/CMakeFiles/lapack-config.cmake
 393   ${LAPACK_BINARY_DIR}/lapack-config-version.cmake
 394   DESTINATION ${LIBRARY_DIR}/cmake/lapack-${LAPACK_VERSION}
 395   )