CMakeLists.txt

   1 # Copyright (c) 2015-2016 The Khronos Group Inc.
   2 #
   3 # Permission is hereby granted, free of charge, to any person obtaining a
   4 # copy of this software and/or associated documentation files (the
   5 # "Materials"), to deal in the Materials without restriction, including
   6 # without limitation the rights to use, copy, modify, merge, publish,
   7 # distribute, sublicense, and/or sell copies of the Materials, and to
   8 # permit persons to whom the Materials are furnished to do so, subject to
   9 # the following conditions:
  10 #
  11 # The above copyright notice and this permission notice shall be included
  12 # in all copies or substantial portions of the Materials.
  13 #
  14 # MODIFICATIONS TO THIS FILE MAY MEAN IT NO LONGER ACCURATELY REFLECTS
  15 # KHRONOS STANDARDS. THE UNMODIFIED, NORMATIVE VERSIONS OF KHRONOS
  16 # SPECIFICATIONS AND HEADER INFORMATION ARE LOCATED AT
  17 #    https://www.khronos.org/registry/
  18 #
  19 # THE MATERIALS ARE PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,
  20 # EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF
  21 # MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.
  22 # IN NO EVENT SHALL THE AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY
  23 # CLAIM, DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION OF CONTRACT,
  24 # TORT OR OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION WITH THE
  25 # MATERIALS OR THE USE OR OTHER DEALINGS IN THE MATERIALS.
  26
  27 cmake_minimum_required(VERSION 2.8)
  28 project(spirv-tools)
  29 set(SPIRV_TOOLS "SPIRV-Tools")
  30
  31 if("${CMAKE_SYSTEM_NAME}" STREQUAL "Linux")
  32   add_definitions(-DSPIRV_LINUX)
  33 elseif("${CMAKE_SYSTEM_NAME}" STREQUAL "Windows")
  34   add_definitions(-DSPIRV_WINDOWS)
  35 elseif("${CMAKE_SYSTEM_NAME}" STREQUAL "Darwin")
  36   add_definitions(-DSPIRV_MAC)
  37 else()
  38   message(FATAL_ERROR "Your platform '${CMAKE_SYSTEM_NAME}' is not supported!")
  39 endif()
  40
  41 if ("${CMAKE_BUILD_TYPE}" STREQUAL "")
  42   message(STATUS "No build type selected, default to Debug")
  43   set(CMAKE_BUILD_TYPE "Debug")
  44 endif()
  45
  46 option(SPIRV_WERROR "Enable error on warning" ON)
  47 if(UNIX)
  48   set(SPIRV_WARNINGS -Wall -Wextra -Wno-missing-field-initializers)
  49
  50   option(SPIRV_WARN_EVERYTHING "Enable -Weverything" ${SPIRV_WARN_EVERYTHING})
  51   if(${SPIRV_WARN_EVERYTHING})
  52     if("${CMAKE_CXX_COMPILER_ID}" STREQUAL "Clang")
  53       set(SPIRV_WARNINGS ${SPIRV_WARNINGS}
  54         -Weverything -Wno-c++98-compat -Wno-c++98-compat-pedantic -Wno-padded)
  55     elseif("${CMAKE_CXX_COMPILER_ID}" STREQUAL "GNU")
  56       set(SPIRV_WARNINGS ${SPIRV_WARNINGS} -Wpedantic -pedantic-errors)
  57     else()
  58       message(STATUS "Unknown compiler ${CMAKE_CXX_COMPILER_ID}, "
  59                      "so SPIRV_WARN_EVERYTHING has no effect")
  60     endif()
  61   endif()
  62
  63   if(${SPIRV_WERROR})
  64     set(SPIRV_WARNINGS ${SPIRV_WARNINGS} -Werror)
  65   endif()
  66 elseif(WIN32)
  67   set(SPIRV_WARNINGS -D_CRT_SECURE_NO_WARNINGS /wd4800)
  68
  69   if(${SPIRV_WERROR})
  70     set(SPIRV_WARNINGS ${SPIRV_WARNINGS} /WX)
  71   endif()
  72 endif()
  73
  74 option(SPIRV_COLOR_TERMINAL "Enable color terminal output" ON)
  75 if(${SPIRV_COLOR_TERMINAL})
  76   add_definitions(-DSPIRV_COLOR_TERMINAL)
  77 endif()
  78
  79 function(spvtools_default_compile_options TARGET)
  80   target_compile_options(${TARGET} PRIVATE ${SPIRV_WARNINGS})
  81   if (UNIX)
  82     target_compile_options(${TARGET} PRIVATE
  83       -std=c++11 -fno-exceptions -fno-rtti)
  84     target_compile_options(${TARGET} PRIVATE
  85       -Wall -Wextra -Wno-long-long -Wshadow -Wundef -Wconversion
  86       -Wno-sign-conversion)
  87     # For good call stacks in profiles, keep the frame pointers.
  88     if(NOT "${SPIRV_PERF}" STREQUAL "")
  89       target_compile_options(${TARGET} PRIVATE -fno-omit-frame-pointer)
  90     endif()
  91     if("${CMAKE_CXX_COMPILER_ID}" STREQUAL "Clang")
  92       set(SPIRV_USE_SANITIZER "" CACHE STRING
  93         "Use the clang sanitizer [address|memory|thread|...]")
  94       if(NOT "${SPIRV_USE_SANITIZER}" STREQUAL "")
  95         target_compile_options(${TARGET} PRIVATE
  96           -fsanitize=${SPIRV_USE_SANITIZER})
  97       endif()
  98     else()
  99       target_compile_options(${TARGET} PRIVATE
 100          -Wno-missing-field-initializers)
 101     endif()
 102   endif()
 103 endfunction()
 104
 105 set(SPIRV_SOURCES
 106   ${CMAKE_CURRENT_SOURCE_DIR}/include/libspirv/libspirv.h
 107   ${CMAKE_CURRENT_SOURCE_DIR}/include/util/bitutils.h
 108   ${CMAKE_CURRENT_SOURCE_DIR}/include/util/hex_float.h
 109   ${CMAKE_CURRENT_SOURCE_DIR}/source/assembly_grammar.h
 110   ${CMAKE_CURRENT_SOURCE_DIR}/source/binary.h
 111   ${CMAKE_CURRENT_SOURCE_DIR}/source/diagnostic.h
 112   ${CMAKE_CURRENT_SOURCE_DIR}/source/ext_inst.h
 113   ${CMAKE_CURRENT_SOURCE_DIR}/source/instruction.h
 114   ${CMAKE_CURRENT_SOURCE_DIR}/source/opcode.h
 115   ${CMAKE_CURRENT_SOURCE_DIR}/source/operand.h
 116   ${CMAKE_CURRENT_SOURCE_DIR}/source/print.h
 117   ${CMAKE_CURRENT_SOURCE_DIR}/source/spirv_constant.h
 118   ${CMAKE_CURRENT_SOURCE_DIR}/source/spirv_definition.h
 119   ${CMAKE_CURRENT_SOURCE_DIR}/source/spirv_endian.h
 120   ${CMAKE_CURRENT_SOURCE_DIR}/source/table.h
 121   ${CMAKE_CURRENT_SOURCE_DIR}/source/text.h
 122   ${CMAKE_CURRENT_SOURCE_DIR}/source/text_handler.h
 123   ${CMAKE_CURRENT_SOURCE_DIR}/source/validate.h
 124   ${CMAKE_CURRENT_SOURCE_DIR}/source/assembly_grammar.cpp
 125   ${CMAKE_CURRENT_SOURCE_DIR}/source/binary.cpp
 126   ${CMAKE_CURRENT_SOURCE_DIR}/source/disassemble.cpp
 127   ${CMAKE_CURRENT_SOURCE_DIR}/source/diagnostic.cpp
 128   ${CMAKE_CURRENT_SOURCE_DIR}/source/ext_inst.cpp
 129   ${CMAKE_CURRENT_SOURCE_DIR}/source/opcode.cpp
 130   ${CMAKE_CURRENT_SOURCE_DIR}/source/operand.cpp
 131   ${CMAKE_CURRENT_SOURCE_DIR}/source/print.cpp
 132   ${CMAKE_CURRENT_SOURCE_DIR}/source/spirv_endian.cpp
 133   ${CMAKE_CURRENT_SOURCE_DIR}/source/table.cpp
 134   ${CMAKE_CURRENT_SOURCE_DIR}/source/text.cpp
 135   ${CMAKE_CURRENT_SOURCE_DIR}/source/text_handler.cpp
 136   ${CMAKE_CURRENT_SOURCE_DIR}/source/validate.cpp
 137   ${CMAKE_CURRENT_SOURCE_DIR}/source/validate_cfg.cpp
 138   ${CMAKE_CURRENT_SOURCE_DIR}/source/validate_id.cpp
 139   ${CMAKE_CURRENT_SOURCE_DIR}/source/validate_instruction.cpp
 140   ${CMAKE_CURRENT_SOURCE_DIR}/source/validate_layout.cpp
 141   ${CMAKE_CURRENT_SOURCE_DIR}/source/validate_ssa.cpp
 142   ${CMAKE_CURRENT_SOURCE_DIR}/source/validate_types.cpp)
 143
 144 add_library(${SPIRV_TOOLS} ${SPIRV_SOURCES})
 145 spvtools_default_compile_options(${SPIRV_TOOLS})
 146 target_include_directories(${SPIRV_TOOLS} PUBLIC
 147   ${CMAKE_CURRENT_SOURCE_DIR}/include
 148   ${CMAKE_CURRENT_SOURCE_DIR}/external/include)
 149
 150 # Defaults to OFF if the user didn't set it.
 151 option(SPIRV_SKIP_EXECUTABLES
 152        "Skip building the executable and tests along with the library"
 153        ${SPIRV_SKIP_EXECUTABLES})
 154 set(SPIRV_INSTALL_TARGETS ${SPIRV_TOOLS})
 155 if (NOT ${SPIRV_SKIP_EXECUTABLES})
 156   list(APPEND SPIRV_INSTALL_TARGETS spirv-as spirv-dis spirv-val)
 157
 158   add_executable(spirv-as ${CMAKE_CURRENT_SOURCE_DIR}/tools/as/as.cpp)
 159   spvtools_default_compile_options(spirv-as)
 160   target_link_libraries(spirv-as PRIVATE ${SPIRV_TOOLS})
 161
 162   add_executable(spirv-dis ${CMAKE_CURRENT_SOURCE_DIR}/tools/dis/dis.cpp)
 163   spvtools_default_compile_options(spirv-dis)
 164   target_link_libraries(spirv-dis PRIVATE ${SPIRV_TOOLS})
 165
 166   add_executable(spirv-val ${CMAKE_CURRENT_SOURCE_DIR}/tools/val/val.cpp)
 167   spvtools_default_compile_options(spirv-val)
 168   target_link_libraries(spirv-val PRIVATE ${SPIRV_TOOLS})
 169
 170   set(GMOCK_DIR ${CMAKE_CURRENT_SOURCE_DIR}/external/googletest/googlemock)
 171   if(EXISTS ${GMOCK_DIR})
 172     if(WIN32)
 173       option(gtest_force_shared_crt
 174         "Use shared (DLL) run-time lib even when Google Test is built as static lib."
 175         ON)
 176     endif()
 177
 178     add_subdirectory(${GMOCK_DIR})
 179   endif()
 180   if (TARGET gmock)
 181     message(STATUS "Found Google Mock, building tests.")
 182
 183     set(TEST_SOURCES
 184       ${CMAKE_CURRENT_SOURCE_DIR}/test/TestFixture.h
 185       ${CMAKE_CURRENT_SOURCE_DIR}/test/UnitSPIRV.h
 186
 187       ${CMAKE_CURRENT_SOURCE_DIR}/test/AssemblyContext.cpp
 188       ${CMAKE_CURRENT_SOURCE_DIR}/test/AssemblyFormat.cpp
 189       ${CMAKE_CURRENT_SOURCE_DIR}/test/BinaryDestroy.cpp
 190       ${CMAKE_CURRENT_SOURCE_DIR}/test/BinaryEndianness.cpp
 191       ${CMAKE_CURRENT_SOURCE_DIR}/test/BinaryHeaderGet.cpp
 192       ${CMAKE_CURRENT_SOURCE_DIR}/test/BinaryParse.cpp
 193       ${CMAKE_CURRENT_SOURCE_DIR}/test/BinaryToText.cpp
 194       ${CMAKE_CURRENT_SOURCE_DIR}/test/BinaryToText.Literal.cpp
 195       ${CMAKE_CURRENT_SOURCE_DIR}/test/Comment.cpp
 196       ${CMAKE_CURRENT_SOURCE_DIR}/test/DiagnosticDestroy.cpp
 197       ${CMAKE_CURRENT_SOURCE_DIR}/test/DiagnosticPrint.cpp
 198       ${CMAKE_CURRENT_SOURCE_DIR}/test/DiagnosticStream.cpp
 199       ${CMAKE_CURRENT_SOURCE_DIR}/test/ExtInstGLSLstd450.cpp
 200       ${CMAKE_CURRENT_SOURCE_DIR}/test/ExtInst.OpenCL.std.cpp
 201       ${CMAKE_CURRENT_SOURCE_DIR}/test/FixWord.cpp
 202       ${CMAKE_CURRENT_SOURCE_DIR}/test/GeneratorMagicNumber.cpp
 203       ${CMAKE_CURRENT_SOURCE_DIR}/test/HexFloat.cpp
 204       ${CMAKE_CURRENT_SOURCE_DIR}/test/ImmediateInt.cpp
 205       ${CMAKE_CURRENT_SOURCE_DIR}/test/LibspirvMacros.cpp
 206       ${CMAKE_CURRENT_SOURCE_DIR}/test/NamedId.cpp
 207       ${CMAKE_CURRENT_SOURCE_DIR}/test/OpcodeMake.cpp
 208       ${CMAKE_CURRENT_SOURCE_DIR}/test/OpcodeRequiresCapabilities.cpp
 209       ${CMAKE_CURRENT_SOURCE_DIR}/test/OpcodeSplit.cpp
 210       ${CMAKE_CURRENT_SOURCE_DIR}/test/OpcodeTableGet.cpp
 211       ${CMAKE_CURRENT_SOURCE_DIR}/test/OperandCapabilities.cpp
 212       ${CMAKE_CURRENT_SOURCE_DIR}/test/Operand.cpp
 213       ${CMAKE_CURRENT_SOURCE_DIR}/test/OperandPattern.cpp
 214       ${CMAKE_CURRENT_SOURCE_DIR}/test/TextAdvance.cpp
 215       ${CMAKE_CURRENT_SOURCE_DIR}/test/TextDestroy.cpp
 216       ${CMAKE_CURRENT_SOURCE_DIR}/test/TextLiteral.cpp
 217       ${CMAKE_CURRENT_SOURCE_DIR}/test/TextStartsNewInst.cpp
 218       ${CMAKE_CURRENT_SOURCE_DIR}/test/TextToBinary.Annotation.cpp
 219       ${CMAKE_CURRENT_SOURCE_DIR}/test/TextToBinary.Barrier.cpp
 220       ${CMAKE_CURRENT_SOURCE_DIR}/test/TextToBinary.Constant.cpp
 221       ${CMAKE_CURRENT_SOURCE_DIR}/test/TextToBinary.ControlFlow.cpp
 222       ${CMAKE_CURRENT_SOURCE_DIR}/test/TextToBinary.cpp
 223       ${CMAKE_CURRENT_SOURCE_DIR}/test/TextToBinary.Debug.cpp
 224       ${CMAKE_CURRENT_SOURCE_DIR}/test/TextToBinary.DeviceSideEnqueue.cpp
 225       ${CMAKE_CURRENT_SOURCE_DIR}/test/TextToBinary.Extension.cpp
 226       ${CMAKE_CURRENT_SOURCE_DIR}/test/TextToBinary.Function.cpp
 227       ${CMAKE_CURRENT_SOURCE_DIR}/test/TextToBinary.Group.cpp
 228       ${CMAKE_CURRENT_SOURCE_DIR}/test/TextToBinary.Image.cpp
 229       ${CMAKE_CURRENT_SOURCE_DIR}/test/TextToBinary.Literal.cpp
 230       ${CMAKE_CURRENT_SOURCE_DIR}/test/TextToBinary.Memory.cpp
 231       ${CMAKE_CURRENT_SOURCE_DIR}/test/TextToBinary.Miscellaneous.cpp
 232       ${CMAKE_CURRENT_SOURCE_DIR}/test/TextToBinary.ModeSetting.cpp
 233       ${CMAKE_CURRENT_SOURCE_DIR}/test/TextToBinary.TypeDeclaration.cpp
 234       ${CMAKE_CURRENT_SOURCE_DIR}/test/TextWordGet.cpp
 235       ${CMAKE_CURRENT_SOURCE_DIR}/test/UnitSPIRV.cpp
 236       ${CMAKE_CURRENT_SOURCE_DIR}/test/ValidateFixtures.cpp
 237       ${CMAKE_CURRENT_SOURCE_DIR}/test/Validate.Capability.cpp
 238       ${CMAKE_CURRENT_SOURCE_DIR}/test/Validate.Layout.cpp
 239       ${CMAKE_CURRENT_SOURCE_DIR}/test/Validate.SSA.cpp
 240       ${CMAKE_CURRENT_SOURCE_DIR}/test/ValidateID.cpp
 241       ${CMAKE_CURRENT_SOURCE_DIR}/test/main.cpp)
 242
 243     add_executable(UnitSPIRV ${TEST_SOURCES})
 244     spvtools_default_compile_options(UnitSPIRV)
 245     if(UNIX)
 246       target_compile_options(UnitSPIRV PRIVATE -Wno-undef)
 247     endif()
 248     if(${CMAKE_CXX_COMPILER_ID} STREQUAL "MSVC")
 249       # Disable C4503 "decorated name length exceeded" warning, triggered
 250       # by some heavily templated types.
 251       # We don't care much about that in test code.
 252       # Important to do since we have warnings-as-errors.
 253       target_compile_options(UnitSPIRV PRIVATE /wd4503)
 254     endif()
 255     target_include_directories(UnitSPIRV PRIVATE
 256       ${CMAKE_CURRENT_SOURCE_DIR}
 257       ${gmock_SOURCE_DIR}/include ${gtest_SOURCE_DIR}/include)
 258     target_link_libraries(UnitSPIRV PRIVATE ${SPIRV_TOOLS} gmock)
 259   else()
 260     message(STATUS "Did not find googletest, tests will not be built."
 261       "To enable tests place googletest in '<spirv-dir>/external/googletest'.")
 262   endif()
 263 endif()
 264
 265 install(TARGETS ${SPIRV_INSTALL_TARGETS}
 266   RUNTIME DESTINATION bin
 267   LIBRARY DESTINATION lib
 268   ARCHIVE DESTINATION lib)
 269
 270 install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/include/libspirv/libspirv.h
 271   DESTINATION include/libspirv/)