CMakeLists.txt

   1 # vim:ts=4:sw=4:expandtab:autoindent:
   2 #
   3 # Copyright (C) 1997-2015 by Dimitri van Heesch.
   4 #
   5 # Permission to use, copy, modify, and distribute this software and its
   6 # documentation under the terms of the GNU General Public License is hereby
   7 # granted. No representations are made about the suitability of this software
   8 # for any purpose. It is provided "as is" without express or implied warranty.
   9 # See the GNU General Public License for more details.
  10 #
  11 # Documents produced by Doxygen are derivative works derived from the
  12 # input used in their production; they are not affected by this license.
  13
  14 cmake_minimum_required(VERSION 3.3)
  15 project(doxygen)
  16
  17 option(build_wizard    "Build the GUI frontend for doxygen." OFF)
  18 option(build_app       "Example showing how to embed doxygen in an application." OFF)
  19 option(build_parse     "Parses source code and dumps the dependencies between the code elements." OFF)
  20 option(build_xmlparser "Example showing how to parse doxygen's XML output." OFF)
  21 option(build_search    "Build external search tools (doxysearch and doxyindexer)" OFF)
  22 option(build_doc       "Build user manual (HTML and PDF)" OFF)
  23 option(build_doc_chm   "Build user manual (CHM)" OFF)
  24 option(use_sqlite3     "Add support for sqlite3 output [experimental]." OFF)
  25 option(use_libclang    "Add support for libclang parsing." OFF)
  26 option(win_static      "Link with /MT in stead of /MD on windows" OFF)
  27 option(english_only    "Only compile in support for the English language" OFF)
  28 option(force_qt4       "Forces doxywizard to build using Qt4 even if Qt5 is installed" OFF)
  29
  30 SET(enlarge_lex_buffers "262144" CACHE INTERNAL "Sets the lex input and read buffers to the specified size")
  31
  32 list(APPEND CMAKE_MODULE_PATH "${CMAKE_SOURCE_DIR}/cmake")
  33 set(TOP "${CMAKE_SOURCE_DIR}")
  34 include(version)
  35
  36 set(sqlite3  "0" CACHE INTERNAL "used in settings.h")
  37 set(clang    "0" CACHE INTERNAL "used in settings.h")
  38 if (use_sqlite3)
  39         set(sqlite3  "1" CACHE INTERNAL "used in settings.h")
  40 endif()
  41
  42 set(MACOS_VERSION_MIN 10.9)
  43 if (use_libclang)
  44         set(clang    "1" CACHE INTERNAL "used in settings.h")
  45         find_package(LLVM CONFIG REQUIRED)
  46         find_package(Clang CONFIG REQUIRED)
  47     if (CMAKE_SYSTEM MATCHES "Darwin")
  48         set(MACOS_VERSION_MIN 10.11)
  49     endif()
  50 endif()
  51
  52 # use C++14 standard for compiling (libclang option requires it)
  53 set(CMAKE_CXX_STANDARD 14)
  54 set(CMAKE_CXX_STANDARD_REQUIRED ON)
  55 set(CMAKE_CXX_EXTENSIONS ON)
  56
  57 if (CMAKE_SYSTEM MATCHES "Darwin")
  58     set(CMAKE_CXX_FLAGS "-Wno-deprecated-register -mmacosx-version-min=${MACOS_VERSION_MIN} ${CMAKE_CXX_FLAGS}")
  59     set(CMAKE_C_FLAGS "-Wno-deprecated-register -mmacosx-version-min=${MACOS_VERSION_MIN} ${CMAKE_C_FLAGS}")
  60     find_library(CORESERVICES_LIB CoreServices)
  61     set(EXTRA_LIBS ${CORESERVICES_LIB})
  62 endif()
  63
  64 if (WIN32)
  65     if ((NOT CMAKE_GENERATOR MATCHES "MinGW Makefiles") AND
  66         (NOT CMAKE_GENERATOR MATCHES "MSYS Makefiles"))
  67         if (NOT ICONV_DIR)
  68           set(ICONV_DIR "${CMAKE_SOURCE_DIR}/winbuild")
  69         endif()
  70         set(CMAKE_REQUIRED_DEFINITIONS "-DLIBICONV_STATIC")
  71         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /bigobj") # needed for language.cpp on 64bit
  72         add_definitions(-DLIBICONV_STATIC -D_CRT_SECURE_NO_WARNINGS)
  73     endif()
  74     if (CMAKE_GENERATOR MATCHES "NMake Makefiles")
  75         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /EHsc")
  76     endif()
  77 endif()
  78
  79 if(POLICY CMP0063)
  80   cmake_policy(SET CMP0063 NEW)
  81 endif()
  82 set(CMAKE_CXX_VISIBILITY_PRESET hidden)
  83 set(CMAKE_C_VISIBILITY_PRESET hidden)
  84 set(CMAKE_VISIBILITY_INLINES_HIDDEN 1)
  85
  86 if (CMAKE_GENERATOR MATCHES "Ninja")
  87   set(LEX_FLAGS )
  88   set(YACC_FLAGS )
  89   set(JAVACC_FLAGS )
  90 else ()
  91   set(LEX_FLAGS $(LEX_FLAGS))
  92   set(YACC_FLAGS $(YACC_FLAGS))
  93   set(JAVACC_FLAGS $(JAVACC_FLAGS))
  94 endif ()
  95
  96 find_program(DOT NAMES dot)
  97 find_package(PythonInterp REQUIRED)
  98 find_package(FLEX REQUIRED)
  99 find_package(BISON REQUIRED)
 100 if (BISON_VERSION VERSION_LESS 2.7)
 101   message(SEND_ERROR "Doxygen requires at least bison version 2.7 (installed: ${BISON_VERSION})")
 102 endif()
 103 find_package(Threads)
 104
 105 if (sqlite3)
 106   find_package(SQLite3 REQUIRED)
 107   if (SQLITE3_VERSION VERSION_LESS 3.9.0)
 108     message(SEND_ERROR "Doxygen requires at least sqlite3 version 3.9.0 (installed: ${SQLITE3_VERSION})")
 109   endif()
 110 endif()
 111
 112 find_package(Iconv REQUIRED)
 113 include_directories(${ICONV_INCLUDE_DIR})
 114
 115
 116 #set(DOXYDOCS ${CMAKE_SOURCE_DIR}/doc CACHE INTERNAL "Path to doxygen docs")
 117 set(DOXYDOCS ${PROJECT_BINARY_DIR}/doc)
 118 set(ENV{DOXYGEN_DOCDIR} ${DOXYDOCS})
 119 set(GENERATED_SRC "${CMAKE_BINARY_DIR}/generated_src" CACHE INTERNAL "Stores generated files")
 120 set(LIBRARY_OUTPUT_PATH ${PROJECT_BINARY_DIR}/lib)
 121 set(EXECUTABLE_OUTPUT_PATH ${PROJECT_BINARY_DIR}/bin)
 122
 123 # place binaries for all build types in the same directory, so we know where to find it
 124 # when running tests or generating docs
 125 set(CMAKE_RUNTIME_OUTPUT_DIRECTORY_DEBUG ${EXECUTABLE_OUTPUT_PATH})
 126 set(CMAKE_RUNTIME_OUTPUT_DIRECTORY_RELEASE ${EXECUTABLE_OUTPUT_PATH})
 127 set(CMAKE_RUNTIME_OUTPUT_DIRECTORY_MINSIZEREL ${EXECUTABLE_OUTPUT_PATH})
 128 set(CMAKE_RUNTIME_OUTPUT_DIRECTORY_RELWITHDEBINFO ${EXECUTABLE_OUTPUT_PATH})
 129
 130 # gather lang codes for translation
 131 file(GLOB lang_files RELATIVE "${CMAKE_SOURCE_DIR}/src" "${CMAKE_SOURCE_DIR}/src/translator_??.h")
 132 if (english_only) # user only wants English
 133   set(lcodes "ENONLY")
 134 else ()
 135   set(lcodes "")
 136   foreach (_lang ${lang_files})
 137     string(REGEX REPLACE "translator_(.*).h" "\\1" _lang_code ${_lang})
 138     string(TOUPPER ${_lang_code} lang_code)
 139     list(APPEND lcodes "${lang_code}")
 140   endforeach()
 141 endif()
 142 set(LANG_CODES ${lcodes} CACHE STRING "List of language codes for which translations should be compiled in")
 143
 144 if (win_static)
 145     set(CompilerFlags
 146         CMAKE_CXX_FLAGS
 147         CMAKE_CXX_FLAGS_DEBUG
 148         CMAKE_CXX_FLAGS_RELEASE
 149         CMAKE_CXX_FLAGS_MINSIZEREL
 150         CMAKE_CXX_FLAGS_RELWITHDEBINFO
 151         CMAKE_C_FLAGS
 152         CMAKE_C_FLAGS_DEBUG
 153         CMAKE_C_FLAGS_RELEASE
 154         CMAKE_C_FLAGS_MINSIZEREL
 155         CMAKE_C_FLAGS_RELWITHDEBINFO)
 156     foreach(CompilerFlag ${CompilerFlags})
 157       string(REPLACE "/MD" "/MT" ${CompilerFlag} "${${CompilerFlag}}")
 158     endforeach()
 159 endif()
 160
 161 include(cmake/CompilerWarnings.cmake)
 162
 163 add_subdirectory(libmd5)
 164 add_subdirectory(liblodepng)
 165 add_subdirectory(libmscgen)
 166 add_subdirectory(libversion)
 167 add_subdirectory(qtools)
 168 add_subdirectory(vhdlparser)
 169 add_subdirectory(src)
 170
 171 if (build_doc_chm)
 172     if (WIN32)
 173           find_package(HTMLHelp REQUIRED)
 174           set(build_doc ON)
 175     else ()
 176           message(WARNING "CHM documentation generation not supported for this platform, ignoring setting.")
 177           set(build_doc_chm OFF)
 178     endif ()
 179 endif ()
 180
 181 if (build_doc)
 182     add_subdirectory(examples)
 183     add_subdirectory(doc)
 184 endif ()
 185
 186 add_subdirectory(addon)
 187
 188 enable_testing()
 189 add_subdirectory(testing)
 190
 191 include(cmake/packaging.cmake) # set CPACK_xxxx properties
 192 include(CPack)