CMakeLists.txt

   1 # The name of our project is "VULKAN". CMakeLists files in this project can
   2 # refer to the root source directory of the project as ${VULKAN_SOURCE_DIR} and
   3 # to the root binary directory of the project as ${VULKAN_BINARY_DIR}.
   4 cmake_minimum_required(VERSION 2.8.11)
   5 project (VULKAN)
   6 # set (CMAKE_VERBOSE_MAKEFILE 1)
   7
   8 # The API_NAME allows renaming builds to avoid conflicts with installed SDKs
   9 # The MAJOR number of the version we're building, used in naming
  10 # <api-name>-<major>.dll (and other files).
  11 set(API_NAME "Vulkan" CACHE STRING "API name to use when building")
  12 set(MAJOR "1")
  13 string(TOLOWER ${API_NAME} API_LOWERCASE)
  14
  15 set(CMAKE_MODULE_PATH ${CMAKE_MODULE_PATH} "${CMAKE_CURRENT_SOURCE_DIR}/cmake")
  16 find_package(PythonInterp 3 REQUIRED)
  17
  18 if(CMAKE_SYSTEM_NAME STREQUAL "Linux")
  19     include(FindPkgConfig)
  20     option(BUILD_WSI_XCB_SUPPORT "Build XCB WSI support" ON)
  21     option(BUILD_WSI_XLIB_SUPPORT "Build Xlib WSI support" ON)
  22     option(BUILD_WSI_WAYLAND_SUPPORT "Build Wayland WSI support" ON)
  23     option(BUILD_WSI_MIR_SUPPORT "Build Mir WSI support" ON)
  24     set(DEMOS_WSI_SELECTION "XCB" CACHE STRING "Select WSI target for demos (XCB, XLIB, WAYLAND, MIR, DISPLAY)")
  25
  26     if (BUILD_WSI_XCB_SUPPORT)
  27         find_package(XCB REQUIRED)
  28     endif()
  29
  30     if (BUILD_WSI_XLIB_SUPPORT)
  31         find_package(X11 REQUIRED)
  32     endif()
  33
  34     if (BUILD_WSI_WAYLAND_SUPPORT)
  35         find_package(Wayland REQUIRED)
  36     endif()
  37
  38     if (BUILD_WSI_MIR_SUPPORT)
  39         find_package(Mir REQUIRED)
  40     endif()
  41 endif()
  42
  43 set(SCRIPTS_DIR "${CMAKE_CURRENT_SOURCE_DIR}/scripts")
  44
  45 # Header file for CMake settings
  46 include_directories("${PROJECT_SOURCE_DIR}/include")
  47
  48 if (CMAKE_COMPILER_IS_GNUCC OR CMAKE_C_COMPILER_ID MATCHES "Clang")
  49     set(COMMON_COMPILE_FLAGS "-Wall -Wextra -Wno-unused-parameter -Wno-missing-field-initializers")
  50     set(COMMON_COMPILE_FLAGS "${COMMON_COMPILE_FLAGS} -fno-strict-aliasing -fno-builtin-memcmp")
  51     set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -std=c99 ${COMMON_COMPILE_FLAGS}")
  52     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} ${COMMON_COMPILE_FLAGS} -std=c++11 -fno-rtti")
  53     if (UNIX)
  54         set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -fvisibility=hidden")
  55         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -fvisibility=hidden")
  56     endif()
  57 endif()
  58
  59 if(WIN32)
  60     # Treat warnings as errors
  61     add_compile_options("$<$<CXX_COMPILER_ID:MSVC>:/WX>")
  62     # Disable RTTI
  63     add_compile_options("$<$<CXX_COMPILER_ID:MSVC>:/GR->")
  64     # Warn about nested declarations
  65     add_compile_options("$<$<CXX_COMPILER_ID:MSVC>:/w34456>")
  66 endif()
  67
  68 if(NOT WIN32)
  69     set (BUILDTGT_DIR build)
  70     set (BINDATA_DIR Bin)
  71     set (LIBSOURCE_DIR Lib)
  72 else()
  73     option(DISABLE_BUILD_PATH_DECORATION "Disable the decoration of the gslang and SPIRV-Tools build path with MSVC build type info" OFF)
  74     option(DISABLE_BUILDTGT_DIR_DECORATION "Disable the decoration of the gslang and SPIRV-Tools build path with target info" OFF)
  75
  76     # For Windows, since 32-bit and 64-bit items can co-exist, we build each in its own build directory.
  77     # 32-bit target data goes in build32, and 64-bit target data goes into build.  So, include/link the
  78     # appropriate data at build time.
  79     if (DISABLE_BUILDTGT_DIR_DECORATION)
  80         set (BUILDTGT_DIR "")
  81         set (BINDATA_DIR "")
  82         set (LIBSOURCE_DIR "")
  83     elseif (CMAKE_CL_64)
  84         set (BUILDTGT_DIR build)
  85         set (BINDATA_DIR Bin)
  86         set (LIBSOURCE_DIR Lib)
  87     else()
  88         set (BUILDTGT_DIR build32)
  89         set (BINDATA_DIR Bin32)
  90         set (LIBSOURCE_DIR Lib32)
  91     endif()
  92 endif()
  93
  94 option(BUILD_LOADER "Build loader" ON)
  95 option(BUILD_TESTS "Build tests" ON)
  96 option(BUILD_LAYERS "Build layers" ON)
  97 option(BUILD_DEMOS "Build demos" ON)
  98 option(BUILD_VKJSON "Build vkjson" ON)
  99 option(CUSTOM_GLSLANG_BIN_ROOT "Use the user defined GLSLANG_BINARY_ROOT" OFF)
 100 option(CUSTOM_SPIRV_TOOLS_BIN_ROOT "Use the user defined SPIRV_TOOLS_BINARY_ROOT" OFF)
 101
 102 #Choose natural default paths for glslang and SPIRV-Tools binaries to support custom definition by the user on the CMake command line or in the GUI
 103 set(GLSLANG_BINARY_ROOT "${CMAKE_BINARY_DIR}/../glslang" CACHE STRING "User defined path to the glslang binaries for this project")
 104 set(SPIRV_TOOLS_BINARY_ROOT "${CMAKE_BINARY_DIR}/../SPIRV-Tools" CACHE STRING "User defined path to the SPIRV-Tools binaries for this project")
 105
 106 # Define a variable for a default root location to the gslang, SPIRV-Tools and other external sources and cache it to allow the user to customize it as needed
 107 set(EXTERNAL_SOURCE_ROOT "${CMAKE_SOURCE_DIR}/external" CACHE STRING "Root path to external sources such as glslang and SPIRV-Tools")
 108
 109
 110 if (WIN32)
 111     if(CUSTOM_GLSLANG_BIN_ROOT)
 112         set(GSLANG_FINAL_BINARY_PATH ${GLSLANG_BINARY_ROOT}/${BUILDTGT_DIR})
 113     else()
 114         set(GSLANG_FINAL_BINARY_PATH "${EXTERNAL_SOURCE_ROOT}/glslang/${BUILDTGT_DIR}")
 115     endif()
 116
 117     if(DISABLE_BUILD_PATH_DECORATION)
 118         set (DEBUG_DECORATION "")
 119         set (RELEASE_DECORATION "")
 120     else()
 121         set (DEBUG_DECORATION "Debug")
 122         set (RELEASE_DECORATION "Release")
 123     endif()
 124
 125     # Take some steps to set up a variable pointing to the final glslang binaries given the variety of input options
 126     set (GLSLANG_SEARCH_PATH "${GSLANG_FINAL_BINARY_PATH}/glslang/${RELEASE_DECORATION}"
 127                              "${GSLANG_FINAL_BINARY_PATH}/glslang/OSDependent/Windows/${RELEASE_DECORATION}"
 128                              "${GSLANG_FINAL_BINARY_PATH}/hlsl/${RELEASE_DECORATION}"
 129                              "${GSLANG_FINAL_BINARY_PATH}/OGLCompilersDLL/${RELEASE_DECORATION}"
 130                              "${GSLANG_FINAL_BINARY_PATH}/SPIRV/${RELEASE_DECORATION}" )
 131
 132     set (GLSLANG_DEBUG_SEARCH_PATH "${GSLANG_FINAL_BINARY_PATH}/glslang/${DEBUG_DECORATION}"
 133                                    "${GSLANG_FINAL_BINARY_PATH}/glslang/OSDependent/Windows/${DEBUG_DECORATION}"
 134                                    "${GSLANG_FINAL_BINARY_PATH}/hlsl/${DEBUG_DECORATION}"
 135                                    "${GSLANG_FINAL_BINARY_PATH}/OGLCompilersDLL/${DEBUG_DECORATION}"
 136                                    "${GSLANG_FINAL_BINARY_PATH}/SPIRV/${DEBUG_DECORATION}")
 137
 138     if(CUSTOM_SPIRV_TOOLS_BIN_ROOT)
 139         set (SPIRV_TOOLS_SEARCH_PATH "${SPIRV_TOOLS_BINARY_ROOT}/${BUILDTGT_DIR}/source/${RELEASE_DECORATION}")
 140         set (SPIRV_TOOLS_DEBUG_SEARCH_PATH "${SPIRV_TOOLS_BINARY_ROOT}/${BUILDTGT_DIR}/source/${DEBUG_DECORATION}")
 141     else()
 142         set (SPIRV_TOOLS_SEARCH_PATH "${EXTERNAL_SOURCE_ROOT}/spirv-tools/${BUILDTGT_DIR}/source/${RELEASE_DECORATION}")
 143         set (SPIRV_TOOLS_DEBUG_SEARCH_PATH "${EXTERNAL_SOURCE_ROOT}/spirv-tools/${BUILDTGT_DIR}/source/${DEBUG_DECORATION}")
 144     endif()
 145 else()
 146     #non windows
 147     if(CUSTOM_GLSLANG_BIN_ROOT)
 148         set (GLSLANG_SEARCH_PATH "${GLSLANG_BINARY_ROOT}/install/lib"
 149                                  "${GLSLANG_BINARY_ROOT}/glslang"
 150                                  "${GLSLANG_BINARY_ROOT}/glslang/OSDependent/Unix"
 151                                  "${GLSLANG_BINARY_ROOT}/OGLCompilersDLL"
 152                                  "${GLSLANG_BINARY_ROOT}/SPIRV"
 153                                  "${GLSLANG_BINARY_ROOT}/hlsl"
 154                                  "${GLSLANG_BINARY_ROOT}/StandAlone")
 155     else()
 156         set (GLSLANG_SEARCH_PATH "${EXTERNAL_SOURCE_ROOT}/glslang/${BUILDTGT_DIR}/install/lib" "${CMAKE_SOURCE_DIR}/../x86_64/lib/glslang" )
 157     endif()
 158
 159     if(CUSTOM_SPIRV_TOOLS_BIN_ROOT)
 160         set (SPIRV_TOOLS_SEARCH_PATH "${SPIRV_TOOLS_BINARY_ROOT}/source" )
 161     else()
 162         set (SPIRV_TOOLS_SEARCH_PATH "${EXTERNAL_SOURCE_ROOT}/spirv-tools/${BUILDTGT_DIR}/source" "${CMAKE_SOURCE_DIR}/../x86_64/lib/spirv-tools" )
 163     endif()
 164 endif()
 165
 166 find_program(GLSLANG_VALIDATOR NAMES glslangValidator
 167              HINTS "${CMAKE_SOURCE_DIR}/external/glslang/${BUILDTGT_DIR}/install/bin"
 168                    "${GLSLANG_BINARY_ROOT}/StandAlone"
 169                    "${PROJECT_SOURCE_DIR}/external/${BINDATA_DIR}")
 170
 171 find_path(GLSLANG_SPIRV_INCLUDE_DIR SPIRV/spirv.hpp HINTS "${EXTERNAL_SOURCE_ROOT}/glslang"
 172                                                     "${CMAKE_SOURCE_DIR}/../glslang"
 173                                               DOC "Path to SPIRV/spirv.hpp")
 174
 175 find_path(SPIRV_TOOLS_INCLUDE_DIR spirv-tools/libspirv.h HINTS "${EXTERNAL_SOURCE_ROOT}/spirv-tools/include"
 176                                                    "${EXTERNAL_SOURCE_ROOT}/SPIRV-Tools/include"
 177                                                    "${CMAKE_SOURCE_DIR}/../spirv-tools/include"
 178                                                    "${CMAKE_SOURCE_DIR}/../SPIRV-Tools/include"
 179                                                    "${EXTERNAL_SOURCE_ROOT}/source/spirv-tools/external/include"
 180                                              DOC "Path to spirv-tools/libspirv.h")
 181
 182 find_library(GLSLANG_LIB NAMES glslang
 183              HINTS ${GLSLANG_SEARCH_PATH} )
 184
 185 find_library(OGLCompiler_LIB NAMES OGLCompiler
 186              HINTS ${GLSLANG_SEARCH_PATH} )
 187
 188 find_library(OSDependent_LIB NAMES OSDependent
 189              HINTS ${GLSLANG_SEARCH_PATH} )
 190
 191 find_library(HLSL_LIB NAMES HLSL
 192              HINTS ${GLSLANG_SEARCH_PATH} )
 193
 194 find_library(SPIRV_LIB NAMES SPIRV
 195              HINTS ${GLSLANG_SEARCH_PATH} )
 196
 197 find_library(SPIRV_REMAPPER_LIB NAMES SPVRemapper
 198              HINTS ${GLSLANG_SEARCH_PATH} )
 199
 200 find_library(SPIRV_TOOLS_LIB NAMES SPIRV-Tools
 201              HINTS ${SPIRV_TOOLS_SEARCH_PATH} )
 202
 203 if (WIN32)
 204     add_library(glslang     STATIC IMPORTED)
 205     add_library(OGLCompiler STATIC IMPORTED)
 206     add_library(OSDependent STATIC IMPORTED)
 207     add_library(HLSL        STATIC IMPORTED)
 208     add_library(SPIRV       STATIC IMPORTED)
 209     add_library(SPVRemapper       STATIC IMPORTED)
 210     add_library(Loader      STATIC IMPORTED)
 211     add_library(SPIRV-Tools STATIC IMPORTED)
 212
 213     find_library(GLSLANG_DLIB NAMES glslangd
 214                  HINTS ${GLSLANG_DEBUG_SEARCH_PATH} )
 215     find_library(OGLCompiler_DLIB NAMES OGLCompilerd
 216                  HINTS ${GLSLANG_DEBUG_SEARCH_PATH} )
 217     find_library(OSDependent_DLIB NAMES OSDependentd
 218                  HINTS ${GLSLANG_DEBUG_SEARCH_PATH} )
 219     find_library(HLSL_DLIB NAMES HLSLd
 220                  HINTS ${GLSLANG_DEBUG_SEARCH_PATH} )
 221     find_library(SPIRV_DLIB NAMES SPIRVd
 222                  HINTS ${GLSLANG_DEBUG_SEARCH_PATH} )
 223     find_library(SPIRV_REMAPPER_DLIB NAMES SPVRemapperd
 224                  HINTS ${GLSLANG_DEBUG_SEARCH_PATH} )
 225     find_library(SPIRV_TOOLS_DLIB NAMES SPIRV-Tools
 226                  HINTS ${SPIRV_TOOLS_DEBUG_SEARCH_PATH} )
 227
 228     set_target_properties(glslang PROPERTIES
 229                          IMPORTED_LOCATION       "${GLSLANG_LIB}"
 230                          IMPORTED_LOCATION_DEBUG "${GLSLANG_DLIB}")
 231     set_target_properties(OGLCompiler PROPERTIES
 232                          IMPORTED_LOCATION       "${OGLCompiler_LIB}"
 233                          IMPORTED_LOCATION_DEBUG "${OGLCompiler_DLIB}")
 234     set_target_properties(OSDependent PROPERTIES
 235                          IMPORTED_LOCATION       "${OSDependent_LIB}"
 236                          IMPORTED_LOCATION_DEBUG "${OSDependent_DLIB}")
 237     set_target_properties(HLSL PROPERTIES
 238                          IMPORTED_LOCATION       "${HLSL_LIB}"
 239                          IMPORTED_LOCATION_DEBUG "${HLSL_DLIB}")
 240     set_target_properties(SPIRV PROPERTIES
 241                          IMPORTED_LOCATION       "${SPIRV_LIB}"
 242                          IMPORTED_LOCATION_DEBUG "${SPIRV_DLIB}")
 243     set_target_properties(SPVRemapper PROPERTIES
 244                          IMPORTED_LOCATION       "${SPIRV_REMAPPER_LIB}"
 245                          IMPORTED_LOCATION_DEBUG "${SPIRV_REMAPPER_DLIB}")
 246     set_target_properties(SPIRV-Tools PROPERTIES
 247                          IMPORTED_LOCATION       "${SPIRV_TOOLS_LIB}"
 248                          IMPORTED_LOCATION_DEBUG "${SPIRV_TOOLS_DLIB}")
 249
 250     set (GLSLANG_LIBRARIES glslang OGLCompiler OSDependent HLSL SPIRV SPVRemapper)
 251     set (SPIRV_TOOLS_LIBRARIES SPIRV-Tools)
 252 else ()
 253     set (GLSLANG_LIBRARIES ${GLSLANG_LIB} ${OGLCompiler_LIB} ${OSDependent_LIB} ${HLSL_LIB} ${SPIRV_LIB} ${SPIRV_REMAPPER_LIB})
 254     set (SPIRV_TOOLS_LIBRARIES ${SPIRV_TOOLS_LIB})
 255 endif()
 256
 257 set (PYTHON_CMD ${PYTHON_EXECUTABLE})
 258
 259 # Define macro used for building vkxml generated files
 260 macro(run_vk_xml_generate dependency output)
 261     add_custom_command(OUTPUT ${output}
 262     COMMAND ${PYTHON_CMD} ${SCRIPTS_DIR}/lvl_genvk.py -registry ${SCRIPTS_DIR}/vk.xml ${output}
 263     DEPENDS ${SCRIPTS_DIR}/vk.xml ${SCRIPTS_DIR}/generator.py ${SCRIPTS_DIR}/${dependency} ${SCRIPTS_DIR}/lvl_genvk.py ${SCRIPTS_DIR}/reg.py
 264     )
 265 endmacro()
 266
 267 # Custom target for generated vulkan helper file dependencies
 268 add_custom_target(generate_helper_files DEPENDS
 269     vk_dispatch_table_helper.h
 270     vk_enum_string_helper.h
 271     vk_struct_size_helper.h
 272     vk_struct_size_helper.c
 273     vk_safe_struct.h
 274     vk_safe_struct.cpp
 275     )
 276
 277 # Rules to build generated helper files
 278 run_vk_xml_generate(helper_file_generator.py vk_safe_struct.h)
 279 run_vk_xml_generate(helper_file_generator.py vk_safe_struct.cpp)
 280 run_vk_xml_generate(helper_file_generator.py vk_struct_size_helper.h)
 281 run_vk_xml_generate(helper_file_generator.py vk_struct_size_helper.c)
 282 run_vk_xml_generate(helper_file_generator.py vk_enum_string_helper.h)
 283 run_vk_xml_generate(dispatch_table_generator.py vk_dispatch_table_helper.h)
 284
 285 if(NOT WIN32)
 286     include(GNUInstallDirs)
 287
 288     add_definitions(-DSYSCONFDIR="${CMAKE_INSTALL_FULL_SYSCONFDIR}")
 289     add_definitions(-DDATADIR="${CMAKE_INSTALL_FULL_DATADIR}")
 290
 291     # Make sure /etc is searched by the loader
 292     if (NOT (CMAKE_INSTALL_FULL_SYSCONFDIR STREQUAL "/etc"))
 293         add_definitions(-DEXTRASYSCONFDIR="/etc")
 294     endif()
 295
 296     # Make sure /usr/share is searched by the loader
 297     if (NOT (CMAKE_INSTALL_FULL_DATADIR STREQUAL "/usr/share"))
 298         add_definitions(-DEXTRADATADIR="/usr/share")
 299     endif()
 300 endif()
 301
 302 if(UNIX)
 303     install(DIRECTORY "${PROJECT_SOURCE_DIR}/include/vulkan" DESTINATION ${CMAKE_INSTALL_INCLUDEDIR})
 304 endif()
 305
 306 # loader: Generic VULKAN ICD loader
 307 # tests: VULKAN tests
 308 if(BUILD_LOADER)
 309     add_subdirectory(loader)
 310 endif()
 311
 312 if(BUILD_TESTS)
 313     add_subdirectory(tests)
 314 endif()
 315
 316 if(BUILD_LAYERS)
 317     add_subdirectory(layers)
 318 endif()
 319
 320 if(BUILD_DEMOS)
 321     add_subdirectory(demos)
 322 endif()
 323
 324 if(BUILD_VKJSON)
 325     add_subdirectory(libs/vkjson)
 326 endif()