CMakeLists.txt

   1 # Copyright (C) 2018-2020 Intel Corporation
   2 # SPDX-License-Identifier: Apache-2.0
   3 #
   4
   5 cmake_policy(SET CMP0054 NEW)
   6
   7 # TODO: for make instal / package we need to use 3.13.3 version because
   8 # it allows to install targets created outside of current projects
   9 # See https://blog.kitware.com/cmake-3-13-0-available-for-download/
  10
  11 if (APPLE)
  12     # due to https://cmake.org/cmake/help/v3.12/policy/CMP0068.html
  13     cmake_minimum_required(VERSION 3.9 FATAL_ERROR)
  14 else()
  15     cmake_minimum_required(VERSION 3.7.2 FATAL_ERROR)
  16 endif()
  17
  18 project(OpenVINO)
  19
  20 set(OpenVINO_MAIN_SOURCE_DIR ${CMAKE_CURRENT_SOURCE_DIR})
  21 set(IE_MAIN_SOURCE_DIR ${OpenVINO_MAIN_SOURCE_DIR}/inference-engine)
  22 set(CMAKE_MODULE_PATH "${OpenVINO_MAIN_SOURCE_DIR}/cmake" ${CMAKE_MODULE_PATH})
  23
  24 include(CTest)
  25 include(features)
  26
  27 # include developer package
  28 include(developer_package)
  29
  30 # These options are shared with 3rdparty plugins
  31 # by means of developer package
  32 include(check_features)
  33 include(dependencies)
  34
  35 # resolving dependencies for the project
  36 message (STATUS "PROJECT ............................... " ${PROJECT_NAME})
  37 message (STATUS "CMAKE_BINARY_DIR ...................... " ${CMAKE_BINARY_DIR})
  38 message (STATUS "OpenVINO_MAIN_SOURCE_DIR .............. " ${OpenVINO_MAIN_SOURCE_DIR})
  39 message (STATUS "IE_MAIN_SOURCE_DIR .................... " ${IE_MAIN_SOURCE_DIR})
  40 message (STATUS "CMAKE_GENERATOR ....................... " ${CMAKE_GENERATOR})
  41 message (STATUS "CMAKE_C_COMPILER_ID ................... " ${CMAKE_C_COMPILER_ID})
  42 message (STATUS "CMAKE_BUILD_TYPE ...................... " ${CMAKE_BUILD_TYPE})
  43
  44 # remove file with exported developer targets to force its regeneration
  45 file(REMOVE "${CMAKE_BINARY_DIR}/targets_developer.cmake")
  46 file(REMOVE "${CMAKE_BINARY_DIR}/targets.cmake")
  47
  48 function(build_ngraph)
  49     function(ngraph_set option value)
  50         if(NOT DEFINED ${option})
  51             set(${option} ${value} CACHE BOOL "" FORCE)
  52         endif()
  53     endfunction()
  54
  55     set(NGRAPH_BUILD_DIR ${CMAKE_LIBRARY_OUTPUT_DIRECTORY} CACHE STRING "" FORCE)
  56     set(CMAKE_MODULE_PATH ${CMAKE_MODULE_PATH} "${OpenVINO_MAIN_SOURCE_DIR}/ngraph/cmake/Modules/")
  57
  58     if (ENABLE_SANITIZER)
  59         ngraph_set(NGRAPH_ADDRESS_SANITIZER TRUE)
  60     else ()
  61         ngraph_set(NGRAPH_ADDRESS_SANITIZER FALSE)
  62     endif ()
  63     ngraph_set(NGRAPH_TOOLS_ENABLE FALSE)
  64     ngraph_set(NGRAPH_CPU_ENABLE FALSE)
  65     ngraph_set(NGRAPH_INTERPRETER_ENABLE TRUE)
  66     ngraph_set(NGRAPH_NOP_ENABLE FALSE)
  67     ngraph_set(NGRAPH_GPUH_ENABLE FALSE)
  68     ngraph_set(NGRAPH_GENERIC_CPU_ENABLE FALSE)
  69     ngraph_set(NGRAPH_ENABLE_CPU_CONV_AUTO FALSE)
  70     ngraph_set(NGRAPH_PYTHON_BUILD_ENABLE FALSE)
  71     ngraph_set(NGRAPH_PLAIDML_ENABLE FALSE)
  72     ngraph_set(NGRAPH_FAST_MATH_ENABLE FALSE)
  73     ngraph_set(NGRAPH_JSON_ENABLE FALSE)
  74     ngraph_set(NGRAPH_NATIVE_ARCH_ENABLE FALSE)
  75
  76     if (NOT ANDROID)
  77         ngraph_set(NGRAPH_UNIT_TEST_ENABLE TRUE)
  78         ngraph_set(NGRAPH_IE_ENABLE TRUE)
  79         ngraph_set(NGRAPH_ONNX_IMPORT_ENABLE TRUE)
  80     else()
  81         ngraph_set(NGRAPH_UNIT_TEST_ENABLE FALSE)
  82         ngraph_set(NGRAPH_TEST_UTIL_ENABLE FALSE)
  83         ngraph_set(NGRAPH_IE_ENABLE FALSE)
  84         ngraph_set(NGRAPH_ONNX_IMPORT_ENABLE FALSE)
  85     endif()
  86
  87     if(CMAKE_CXX_COMPILER_ID MATCHES "^(Apple)?Clang$")
  88         ie_add_compiler_flags(-Wno-error=uninitialized -Wno-error=literal-conversion)
  89     elseif(UNIX)
  90         ie_add_compiler_flags(-Wno-error=maybe-uninitialized -Wno-error=return-type -fPIC)
  91     endif()
  92     if(ANDROID)
  93         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -Wno-error=defaulted-function-deleted -Wno-error=unused-command-line-argument")
  94     endif()
  95
  96     # WA for GCC 7.0
  97     if (UNIX)
  98         ie_add_compiler_flags(-Wno-error=return-type -Wno-undef)
  99     elseif(WIN32)
 100         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /wd4308 /wd4146 /wd4703 /wd4244")
 101     endif()
 102
 103     if(ENABLE_LTO)
 104         ie_enable_lto()
 105     endif()
 106
 107     ie_cpack_add_component(ngraph)
 108
 109     set(SDL_cmake_included ON)
 110     # set(NGRAPH_COMPONENT_PREFIX "deployment_tools/ngraph/")
 111     add_subdirectory(ngraph)
 112 endfunction()
 113
 114 build_ngraph()
 115
 116 add_subdirectory(inference-engine)
 117
 118 # cpack
 119
 120 # install setupvars
 121
 122 ie_cpack_add_component(setupvars REQUIRED)
 123
 124 if(UNIX)
 125     install(PROGRAMS scripts/setupvars/setupvars.sh
 126             DESTINATION bin
 127             COMPONENT setupvars)
 128 elseif(WIN32)
 129     install(PROGRAMS scripts/setupvars/setupvars.bat
 130             DESTINATION bin
 131             COMPONENT setupvars)
 132 endif()
 133
 134 # install install_dependencies
 135
 136 if(UNIX)
 137     ie_cpack_add_component(install_dependencies REQUIRED)
 138     install(DIRECTORY scripts/install_dependencies/
 139             DESTINATION install_dependencies
 140             COMPONENT install_dependencies)
 141 endif()
 142
 143 # install files for demo
 144
 145 ie_cpack_add_component(demo_scripts REQUIRED DEPENDS core)
 146
 147 if(UNIX)
 148     install(DIRECTORY scripts/demo/
 149             DESTINATION deployment_tools/demo
 150             COMPONENT demo_scripts
 151             USE_SOURCE_PERMISSIONS
 152             PATTERN *.bat EXCLUDE)
 153 elseif(WIN32)
 154     install(DIRECTORY scripts/demo/
 155             DESTINATION deployment_tools/demo
 156             COMPONENT demo_scripts
 157             USE_SOURCE_PERMISSIONS
 158             PATTERN *.sh EXCLUDE)
 159 endif()
 160
 161 ie_cpack(${IE_CPACK_COMPONENTS_ALL})