CMakeLists.txt

   1 # Copyright (c) 2015-2016 The Khronos Group Inc.
   2 #
   3 # Permission is hereby granted, free of charge, to any person obtaining a
   4 # copy of this software and/or associated documentation files (the
   5 # "Materials"), to deal in the Materials without restriction, including
   6 # without limitation the rights to use, copy, modify, merge, publish,
   7 # distribute, sublicense, and/or sell copies of the Materials, and to
   8 # permit persons to whom the Materials are furnished to do so, subject to
   9 # the following conditions:
  10 #
  11 # The above copyright notice and this permission notice shall be included
  12 # in all copies or substantial portions of the Materials.
  13 #
  14 # MODIFICATIONS TO THIS FILE MAY MEAN IT NO LONGER ACCURATELY REFLECTS
  15 # KHRONOS STANDARDS. THE UNMODIFIED, NORMATIVE VERSIONS OF KHRONOS
  16 # SPECIFICATIONS AND HEADER INFORMATION ARE LOCATED AT
  17 #    https://www.khronos.org/registry/
  18 #
  19 # THE MATERIALS ARE PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,
  20 # EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF
  21 # MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.
  22 # IN NO EVENT SHALL THE AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY
  23 # CLAIM, DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION OF CONTRACT,
  24 # TORT OR OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION WITH THE
  25 # MATERIALS OR THE USE OR OTHER DEALINGS IN THE MATERIALS.
  26
  27 cmake_minimum_required(VERSION 2.8)
  28 project(spirv-tools)
  29 enable_testing()
  30 set(SPIRV_TOOLS "SPIRV-Tools")
  31
  32 if("${CMAKE_SYSTEM_NAME}" STREQUAL "Linux")
  33   add_definitions(-DSPIRV_LINUX)
  34 elseif("${CMAKE_SYSTEM_NAME}" STREQUAL "Windows")
  35   add_definitions(-DSPIRV_WINDOWS)
  36 elseif("${CMAKE_SYSTEM_NAME}" STREQUAL "Darwin")
  37   add_definitions(-DSPIRV_MAC)
  38 else()
  39   message(FATAL_ERROR "Your platform '${CMAKE_SYSTEM_NAME}' is not supported!")
  40 endif()
  41
  42 if ("${CMAKE_BUILD_TYPE}" STREQUAL "")
  43   message(STATUS "No build type selected, default to Debug")
  44   set(CMAKE_BUILD_TYPE "Debug")
  45 endif()
  46
  47 option(SPIRV_WERROR "Enable error on warning" ON)
  48 if(UNIX)
  49   set(SPIRV_WARNINGS -Wall -Wextra -Wno-missing-field-initializers)
  50
  51   option(SPIRV_WARN_EVERYTHING "Enable -Weverything" ${SPIRV_WARN_EVERYTHING})
  52   if(${SPIRV_WARN_EVERYTHING})
  53     if("${CMAKE_CXX_COMPILER_ID}" STREQUAL "Clang")
  54       set(SPIRV_WARNINGS ${SPIRV_WARNINGS}
  55         -Weverything -Wno-c++98-compat -Wno-c++98-compat-pedantic -Wno-padded)
  56     elseif("${CMAKE_CXX_COMPILER_ID}" STREQUAL "GNU")
  57       set(SPIRV_WARNINGS ${SPIRV_WARNINGS} -Wpedantic -pedantic-errors)
  58     else()
  59       message(STATUS "Unknown compiler ${CMAKE_CXX_COMPILER_ID}, "
  60                      "so SPIRV_WARN_EVERYTHING has no effect")
  61     endif()
  62   endif()
  63
  64   if(${SPIRV_WERROR})
  65     set(SPIRV_WARNINGS ${SPIRV_WARNINGS} -Werror)
  66   endif()
  67 elseif(WIN32)
  68   set(SPIRV_WARNINGS -D_CRT_SECURE_NO_WARNINGS /wd4800)
  69
  70   if(${SPIRV_WERROR})
  71     set(SPIRV_WARNINGS ${SPIRV_WARNINGS} /WX)
  72   endif()
  73 endif()
  74
  75 option(SPIRV_COLOR_TERMINAL "Enable color terminal output" ON)
  76 if(${SPIRV_COLOR_TERMINAL})
  77   add_definitions(-DSPIRV_COLOR_TERMINAL)
  78 endif()
  79
  80 function(spvtools_default_compile_options TARGET)
  81   target_compile_options(${TARGET} PRIVATE ${SPIRV_WARNINGS})
  82   if (UNIX)
  83     target_compile_options(${TARGET} PRIVATE
  84       -std=c++11 -fno-exceptions -fno-rtti)
  85     target_compile_options(${TARGET} PRIVATE
  86       -Wall -Wextra -Wno-long-long -Wshadow -Wundef -Wconversion
  87       -Wno-sign-conversion)
  88     # For good call stacks in profiles, keep the frame pointers.
  89     if(NOT "${SPIRV_PERF}" STREQUAL "")
  90       target_compile_options(${TARGET} PRIVATE -fno-omit-frame-pointer)
  91     endif()
  92     if("${CMAKE_CXX_COMPILER_ID}" STREQUAL "Clang")
  93       set(SPIRV_USE_SANITIZER "" CACHE STRING
  94         "Use the clang sanitizer [address|memory|thread|...]")
  95       if(NOT "${SPIRV_USE_SANITIZER}" STREQUAL "")
  96         target_compile_options(${TARGET} PRIVATE
  97           -fsanitize=${SPIRV_USE_SANITIZER})
  98       endif()
  99     else()
 100       target_compile_options(${TARGET} PRIVATE
 101          -Wno-missing-field-initializers)
 102     endif()
 103   endif()
 104 endfunction()
 105
 106 set(SPIRV_SOURCES
 107   ${CMAKE_CURRENT_SOURCE_DIR}/include/spirv-tools/libspirv.h
 108   ${CMAKE_CURRENT_SOURCE_DIR}/include/spirv/spirv.h
 109   ${CMAKE_CURRENT_SOURCE_DIR}/include/spirv/GLSL.std.450.h
 110   ${CMAKE_CURRENT_SOURCE_DIR}/include/spirv/OpenCL.std.h
 111   ${CMAKE_CURRENT_SOURCE_DIR}/source/util/bitutils.h
 112   ${CMAKE_CURRENT_SOURCE_DIR}/source/util/hex_float.h
 113   ${CMAKE_CURRENT_SOURCE_DIR}/source/assembly_grammar.h
 114   ${CMAKE_CURRENT_SOURCE_DIR}/source/binary.h
 115   ${CMAKE_CURRENT_SOURCE_DIR}/source/diagnostic.h
 116   ${CMAKE_CURRENT_SOURCE_DIR}/source/ext_inst.h
 117   ${CMAKE_CURRENT_SOURCE_DIR}/source/instruction.h
 118   ${CMAKE_CURRENT_SOURCE_DIR}/source/opcode.h
 119   ${CMAKE_CURRENT_SOURCE_DIR}/source/operand.h
 120   ${CMAKE_CURRENT_SOURCE_DIR}/source/print.h
 121   ${CMAKE_CURRENT_SOURCE_DIR}/source/spirv_constant.h
 122   ${CMAKE_CURRENT_SOURCE_DIR}/source/spirv_definition.h
 123   ${CMAKE_CURRENT_SOURCE_DIR}/source/spirv_endian.h
 124   ${CMAKE_CURRENT_SOURCE_DIR}/source/table.h
 125   ${CMAKE_CURRENT_SOURCE_DIR}/source/text.h
 126   ${CMAKE_CURRENT_SOURCE_DIR}/source/text_handler.h
 127   ${CMAKE_CURRENT_SOURCE_DIR}/source/validate.h
 128   ${CMAKE_CURRENT_SOURCE_DIR}/source/assembly_grammar.cpp
 129   ${CMAKE_CURRENT_SOURCE_DIR}/source/binary.cpp
 130   ${CMAKE_CURRENT_SOURCE_DIR}/source/disassemble.cpp
 131   ${CMAKE_CURRENT_SOURCE_DIR}/source/diagnostic.cpp
 132   ${CMAKE_CURRENT_SOURCE_DIR}/source/ext_inst.cpp
 133   ${CMAKE_CURRENT_SOURCE_DIR}/source/instruction.cpp
 134   ${CMAKE_CURRENT_SOURCE_DIR}/source/opcode.cpp
 135   ${CMAKE_CURRENT_SOURCE_DIR}/source/operand.cpp
 136   ${CMAKE_CURRENT_SOURCE_DIR}/source/print.cpp
 137   ${CMAKE_CURRENT_SOURCE_DIR}/source/spirv_endian.cpp
 138   ${CMAKE_CURRENT_SOURCE_DIR}/source/table.cpp
 139   ${CMAKE_CURRENT_SOURCE_DIR}/source/text.cpp
 140   ${CMAKE_CURRENT_SOURCE_DIR}/source/text_handler.cpp
 141   ${CMAKE_CURRENT_SOURCE_DIR}/source/validate.cpp
 142   ${CMAKE_CURRENT_SOURCE_DIR}/source/validate_cfg.cpp
 143   ${CMAKE_CURRENT_SOURCE_DIR}/source/validate_id.cpp
 144   ${CMAKE_CURRENT_SOURCE_DIR}/source/validate_instruction.cpp
 145   ${CMAKE_CURRENT_SOURCE_DIR}/source/validate_layout.cpp
 146   ${CMAKE_CURRENT_SOURCE_DIR}/source/validate_ssa.cpp
 147   ${CMAKE_CURRENT_SOURCE_DIR}/source/validate_types.cpp)
 148
 149 add_library(${SPIRV_TOOLS} ${SPIRV_SOURCES})
 150 spvtools_default_compile_options(${SPIRV_TOOLS})
 151 target_include_directories(${SPIRV_TOOLS} PUBLIC ${CMAKE_CURRENT_SOURCE_DIR}/include)
 152
 153 # Defaults to OFF if the user didn't set it.
 154 option(SPIRV_SKIP_EXECUTABLES
 155        "Skip building the executable and tests along with the library"
 156        ${SPIRV_SKIP_EXECUTABLES})
 157 set(SPIRV_INSTALL_TARGETS ${SPIRV_TOOLS})
 158 if (NOT ${SPIRV_SKIP_EXECUTABLES})
 159   list(APPEND SPIRV_INSTALL_TARGETS spirv-as spirv-dis spirv-val)
 160
 161   add_executable(spirv-as ${CMAKE_CURRENT_SOURCE_DIR}/tools/as/as.cpp)
 162   spvtools_default_compile_options(spirv-as)
 163   target_link_libraries(spirv-as PRIVATE ${SPIRV_TOOLS})
 164
 165   add_executable(spirv-dis ${CMAKE_CURRENT_SOURCE_DIR}/tools/dis/dis.cpp)
 166   spvtools_default_compile_options(spirv-dis)
 167   target_link_libraries(spirv-dis PRIVATE ${SPIRV_TOOLS})
 168
 169   add_executable(spirv-val ${CMAKE_CURRENT_SOURCE_DIR}/tools/val/val.cpp)
 170   spvtools_default_compile_options(spirv-val)
 171   target_link_libraries(spirv-val PRIVATE ${SPIRV_TOOLS})
 172
 173   # Find gmock if we can. If it's not already configured, then try finding
 174   # it in external/googletest
 175   if (TARGET gmock)
 176     message(STATUS "Google Mock already configured")
 177   else()
 178     set(GMOCK_DIR ${CMAKE_CURRENT_SOURCE_DIR}/external/googletest/googlemock)
 179     if(EXISTS ${GMOCK_DIR})
 180       if(WIN32)
 181         option(gtest_force_shared_crt
 182           "Use shared (DLL) run-time lib even when Google Test is built as static lib."
 183           ON)
 184       endif()
 185       add_subdirectory(${GMOCK_DIR})
 186     endif()
 187   endif()
 188   if (TARGET gmock)
 189     message(STATUS "Found Google Mock, building tests.")
 190
 191     set(TEST_SOURCES
 192       ${CMAKE_CURRENT_SOURCE_DIR}/test/TestFixture.h
 193       ${CMAKE_CURRENT_SOURCE_DIR}/test/UnitSPIRV.h
 194
 195       ${CMAKE_CURRENT_SOURCE_DIR}/test/AssemblyContext.cpp
 196       ${CMAKE_CURRENT_SOURCE_DIR}/test/AssemblyFormat.cpp
 197       ${CMAKE_CURRENT_SOURCE_DIR}/test/BinaryDestroy.cpp
 198       ${CMAKE_CURRENT_SOURCE_DIR}/test/BinaryEndianness.cpp
 199       ${CMAKE_CURRENT_SOURCE_DIR}/test/BinaryHeaderGet.cpp
 200       ${CMAKE_CURRENT_SOURCE_DIR}/test/BinaryParse.cpp
 201       ${CMAKE_CURRENT_SOURCE_DIR}/test/BinaryToText.cpp
 202       ${CMAKE_CURRENT_SOURCE_DIR}/test/BinaryToText.Literal.cpp
 203       ${CMAKE_CURRENT_SOURCE_DIR}/test/Comment.cpp
 204       ${CMAKE_CURRENT_SOURCE_DIR}/test/DiagnosticDestroy.cpp
 205       ${CMAKE_CURRENT_SOURCE_DIR}/test/DiagnosticPrint.cpp
 206       ${CMAKE_CURRENT_SOURCE_DIR}/test/DiagnosticStream.cpp
 207       ${CMAKE_CURRENT_SOURCE_DIR}/test/ExtInstGLSLstd450.cpp
 208       ${CMAKE_CURRENT_SOURCE_DIR}/test/ExtInst.OpenCL.std.cpp
 209       ${CMAKE_CURRENT_SOURCE_DIR}/test/FixWord.cpp
 210       ${CMAKE_CURRENT_SOURCE_DIR}/test/GeneratorMagicNumber.cpp
 211       ${CMAKE_CURRENT_SOURCE_DIR}/test/HexFloat.cpp
 212       ${CMAKE_CURRENT_SOURCE_DIR}/test/ImmediateInt.cpp
 213       ${CMAKE_CURRENT_SOURCE_DIR}/test/LibspirvMacros.cpp
 214       ${CMAKE_CURRENT_SOURCE_DIR}/test/NamedId.cpp
 215       ${CMAKE_CURRENT_SOURCE_DIR}/test/OpcodeMake.cpp
 216       ${CMAKE_CURRENT_SOURCE_DIR}/test/OpcodeRequiresCapabilities.cpp
 217       ${CMAKE_CURRENT_SOURCE_DIR}/test/OpcodeSplit.cpp
 218       ${CMAKE_CURRENT_SOURCE_DIR}/test/OpcodeTableGet.cpp
 219       ${CMAKE_CURRENT_SOURCE_DIR}/test/OperandCapabilities.cpp
 220       ${CMAKE_CURRENT_SOURCE_DIR}/test/Operand.cpp
 221       ${CMAKE_CURRENT_SOURCE_DIR}/test/OperandPattern.cpp
 222       ${CMAKE_CURRENT_SOURCE_DIR}/test/TextAdvance.cpp
 223       ${CMAKE_CURRENT_SOURCE_DIR}/test/TextDestroy.cpp
 224       ${CMAKE_CURRENT_SOURCE_DIR}/test/TextLiteral.cpp
 225       ${CMAKE_CURRENT_SOURCE_DIR}/test/TextStartsNewInst.cpp
 226       ${CMAKE_CURRENT_SOURCE_DIR}/test/TextToBinary.Annotation.cpp
 227       ${CMAKE_CURRENT_SOURCE_DIR}/test/TextToBinary.Barrier.cpp
 228       ${CMAKE_CURRENT_SOURCE_DIR}/test/TextToBinary.Constant.cpp
 229       ${CMAKE_CURRENT_SOURCE_DIR}/test/TextToBinary.ControlFlow.cpp
 230       ${CMAKE_CURRENT_SOURCE_DIR}/test/TextToBinary.cpp
 231       ${CMAKE_CURRENT_SOURCE_DIR}/test/TextToBinary.Debug.cpp
 232       ${CMAKE_CURRENT_SOURCE_DIR}/test/TextToBinary.DeviceSideEnqueue.cpp
 233       ${CMAKE_CURRENT_SOURCE_DIR}/test/TextToBinary.Extension.cpp
 234       ${CMAKE_CURRENT_SOURCE_DIR}/test/TextToBinary.Function.cpp
 235       ${CMAKE_CURRENT_SOURCE_DIR}/test/TextToBinary.Group.cpp
 236       ${CMAKE_CURRENT_SOURCE_DIR}/test/TextToBinary.Image.cpp
 237       ${CMAKE_CURRENT_SOURCE_DIR}/test/TextToBinary.Literal.cpp
 238       ${CMAKE_CURRENT_SOURCE_DIR}/test/TextToBinary.Memory.cpp
 239       ${CMAKE_CURRENT_SOURCE_DIR}/test/TextToBinary.Miscellaneous.cpp
 240       ${CMAKE_CURRENT_SOURCE_DIR}/test/TextToBinary.ModeSetting.cpp
 241       ${CMAKE_CURRENT_SOURCE_DIR}/test/TextToBinary.TypeDeclaration.cpp
 242       ${CMAKE_CURRENT_SOURCE_DIR}/test/TextWordGet.cpp
 243       ${CMAKE_CURRENT_SOURCE_DIR}/test/UnitSPIRV.cpp
 244       ${CMAKE_CURRENT_SOURCE_DIR}/test/ValidateFixtures.cpp
 245       ${CMAKE_CURRENT_SOURCE_DIR}/test/Validate.Capability.cpp
 246       ${CMAKE_CURRENT_SOURCE_DIR}/test/Validate.Layout.cpp
 247       ${CMAKE_CURRENT_SOURCE_DIR}/test/Validate.Storage.cpp
 248       ${CMAKE_CURRENT_SOURCE_DIR}/test/Validate.SSA.cpp
 249       ${CMAKE_CURRENT_SOURCE_DIR}/test/ValidateID.cpp
 250       ${CMAKE_CURRENT_SOURCE_DIR}/test/ValidationState.cpp
 251       ${CMAKE_CURRENT_SOURCE_DIR}/test/Version.cpp
 252       ${CMAKE_CURRENT_SOURCE_DIR}/test/main.cpp)
 253
 254     add_executable(UnitSPIRV ${TEST_SOURCES})
 255     spvtools_default_compile_options(UnitSPIRV)
 256     if(UNIX)
 257       target_compile_options(UnitSPIRV PRIVATE -Wno-undef)
 258     endif()
 259     if(${CMAKE_CXX_COMPILER_ID} STREQUAL "MSVC")
 260       # Disable C4503 "decorated name length exceeded" warning, triggered
 261       # by some heavily templated types.
 262       # We don't care much about that in test code.
 263       # Important to do since we have warnings-as-errors.
 264       target_compile_options(UnitSPIRV PRIVATE /wd4503)
 265     endif()
 266     target_include_directories(UnitSPIRV PRIVATE
 267       ${CMAKE_CURRENT_SOURCE_DIR}
 268       ${gmock_SOURCE_DIR}/include ${gtest_SOURCE_DIR}/include)
 269     target_link_libraries(UnitSPIRV PRIVATE ${SPIRV_TOOLS} gmock)
 270     add_test(NAME spirv-tools-testsuite COMMAND UnitSPIRV)
 271   else()
 272     message(STATUS "Did not find googletest, tests will not be built."
 273       "To enable tests place googletest in '<spirv-dir>/external/googletest'.")
 274   endif()
 275 endif()
 276
 277 install(TARGETS ${SPIRV_INSTALL_TARGETS}
 278   RUNTIME DESTINATION bin
 279   LIBRARY DESTINATION lib
 280   ARCHIVE DESTINATION lib)
 281
 282 install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/include/spirv-tools/libspirv.h
 283   DESTINATION include/spirv-tools/)
 284 # The installation is broken without these header files from the SPIR-V Registry.
 285 # The libspirv.h header includes them.
 286 install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/include/spirv/spirv.h
 287               ${CMAKE_CURRENT_SOURCE_DIR}/include/spirv/GLSL.std.450.h
 288               ${CMAKE_CURRENT_SOURCE_DIR}/include/spirv/OpenCL.std.h
 289   DESTINATION include/spirv/)