CMakeLists.txt

   1 # ----------------------------------------------------------------------------
   2 #  Root CMake file for OpenCV
   3 #
   4 #    From the off-tree build directory, invoke:
   5 #      $ cmake <PATH_TO_OPENCV_ROOT>
   6 #
   7 #
   8 #   - OCT-2008: Initial version <joseluisblancoc@gmail.com>
   9 #
  10 # ----------------------------------------------------------------------------
  11
  12 set(CMAKE_ALLOW_LOOSE_LOOP_CONSTRUCTS true)
  13
  14 # Following block can broke build in case of cross-compilng
  15 # but CMAKE_CROSSCOMPILING variable will be set only on project(OpenCV) command
  16 # so we will try to detect crosscompiling by presense of CMAKE_TOOLCHAIN_FILE
  17 if(NOT CMAKE_TOOLCHAIN_FILE)
  18   # it _must_ go before project(OpenCV) in order to work
  19   if(WIN32)
  20     set(CMAKE_INSTALL_PREFIX "${CMAKE_BINARY_DIR}/install" CACHE PATH "Installation Directory")
  21   else()
  22     set(CMAKE_INSTALL_PREFIX "/usr/local" CACHE PATH "Installation Directory")
  23   endif()
  24 else(NOT CMAKE_TOOLCHAIN_FILE)
  25   #Android: set output folder to ${CMAKE_BINARY_DIR}
  26   set( LIBRARY_OUTPUT_PATH_ROOT ${CMAKE_BINARY_DIR} CACHE PATH "root for library output, set this to change where android libs are compiled to" )
  27   # any crosscompiling
  28   set(CMAKE_INSTALL_PREFIX "${CMAKE_BINARY_DIR}/install" CACHE PATH "Installation Directory")
  29 endif(NOT CMAKE_TOOLCHAIN_FILE)
  30
  31 # --------------------------------------------------------------
  32 # Top level OpenCV project
  33 # --------------------------------------------------------------
  34 if(CMAKE_GENERATOR MATCHES Xcode AND XCODE_VERSION VERSION_GREATER 4.3)
  35   cmake_minimum_required(VERSION 2.8.8)
  36 elseif(IOS)
  37   cmake_minimum_required(VERSION 2.8.0)
  38 else()
  39   cmake_minimum_required(VERSION 2.6.3)
  40 endif()
  41
  42 if(POLICY CMP0017)
  43   cmake_policy(SET CMP0017 NEW)
  44 endif()
  45
  46 if(POLICY CMP0022)
  47   cmake_policy(SET CMP0022 OLD)
  48 endif()
  49
  50 # must go before the project command
  51 set(CMAKE_CONFIGURATION_TYPES "Debug;Release" CACHE STRING "Configs" FORCE)
  52 if(DEFINED CMAKE_BUILD_TYPE AND CMAKE_VERSION VERSION_GREATER "2.8")
  53   set_property( CACHE CMAKE_BUILD_TYPE PROPERTY STRINGS ${CMAKE_CONFIGURATION_TYPES} )
  54 endif()
  55
  56 project(OpenCV CXX C)
  57
  58 if(MSVC)
  59   set(CMAKE_USE_RELATIVE_PATHS ON CACHE INTERNAL "" FORCE)
  60 endif()
  61
  62 include(cmake/OpenCVUtils.cmake)
  63
  64 ocv_clear_vars(OpenCVModules_TARGETS)
  65
  66 # ----------------------------------------------------------------------------
  67 # Break in case of popular CMake configuration mistakes
  68 # ----------------------------------------------------------------------------
  69 if(NOT CMAKE_SIZEOF_VOID_P GREATER 0)
  70   message(FATAL_ERROR "CMake fails to deterimine the bitness of target platform.
  71   Please check your CMake and compiler installation. If you are crosscompiling then ensure that your CMake toolchain file correctly sets the compiler details.")
  72 endif()
  73
  74 # ----------------------------------------------------------------------------
  75 # Detect compiler and target platform architecture
  76 # ----------------------------------------------------------------------------
  77 include(cmake/OpenCVDetectCXXCompiler.cmake)
  78
  79 # Add these standard paths to the search paths for FIND_LIBRARY
  80 # to find libraries from these locations first
  81 if(UNIX AND NOT ANDROID)
  82   if(X86_64 OR CMAKE_SIZEOF_VOID_P EQUAL 8)
  83     if(EXISTS /lib64)
  84       list(APPEND CMAKE_LIBRARY_PATH /lib64)
  85     else()
  86       list(APPEND CMAKE_LIBRARY_PATH /lib)
  87     endif()
  88     if(EXISTS /usr/lib64)
  89       list(APPEND CMAKE_LIBRARY_PATH /usr/lib64)
  90     else()
  91       list(APPEND CMAKE_LIBRARY_PATH /usr/lib)
  92     endif()
  93   elseif(X86 OR CMAKE_SIZEOF_VOID_P EQUAL 4)
  94     if(EXISTS /lib32)
  95       list(APPEND CMAKE_LIBRARY_PATH /lib32)
  96     else()
  97       list(APPEND CMAKE_LIBRARY_PATH /lib)
  98     endif()
  99     if(EXISTS /usr/lib32)
 100       list(APPEND CMAKE_LIBRARY_PATH /usr/lib32)
 101     else()
 102       list(APPEND CMAKE_LIBRARY_PATH /usr/lib)
 103     endif()
 104   endif()
 105 endif()
 106
 107 # Add these standard paths to the search paths for FIND_PATH
 108 # to find include files from these locations first
 109 if(MINGW)
 110   if(EXISTS /mingw)
 111       list(APPEND CMAKE_INCLUDE_PATH /mingw)
 112   endif()
 113   if(EXISTS /mingw32)
 114       list(APPEND CMAKE_INCLUDE_PATH /mingw32)
 115   endif()
 116   if(EXISTS /mingw64)
 117       list(APPEND CMAKE_INCLUDE_PATH /mingw64)
 118   endif()
 119 endif()
 120
 121 # ----------------------------------------------------------------------------
 122 # OpenCV cmake options
 123 # ----------------------------------------------------------------------------
 124
 125 # Optional 3rd party components
 126 # ===================================================
 127 OCV_OPTION(WITH_1394           "Include IEEE1394 support"                    ON   IF (NOT ANDROID AND NOT IOS) )
 128 OCV_OPTION(WITH_AVFOUNDATION   "Use AVFoundation for Video I/O"              ON   IF IOS)
 129 OCV_OPTION(WITH_CARBON         "Use Carbon for UI instead of Cocoa"          OFF  IF APPLE )
 130 OCV_OPTION(WITH_CUDA           "Include NVidia Cuda Runtime support"         ON   IF (CMAKE_VERSION VERSION_GREATER "2.8" AND NOT IOS) )
 131 OCV_OPTION(WITH_VTK            "Include VTK library support (and build opencv_viz module eiher)"             OFF IF (NOT ANDROID AND NOT IOS) )
 132 OCV_OPTION(WITH_CUFFT          "Include NVidia Cuda Fast Fourier Transform (FFT) library support"            ON  IF (CMAKE_VERSION VERSION_GREATER "2.8" AND NOT IOS) )
 133 OCV_OPTION(WITH_CUBLAS         "Include NVidia Cuda Basic Linear Algebra Subprograms (BLAS) library support" OFF IF (CMAKE_VERSION VERSION_GREATER "2.8" AND NOT IOS) )
 134 OCV_OPTION(WITH_NVCUVID        "Include NVidia Video Decoding library support"                               OFF IF (CMAKE_VERSION VERSION_GREATER "2.8" AND NOT ANDROID AND NOT IOS AND NOT APPLE) )
 135 OCV_OPTION(WITH_EIGEN          "Include Eigen2/Eigen3 support"               ON)
 136 OCV_OPTION(WITH_VFW            "Include Video for Windows support"           ON   IF WIN32 )
 137 OCV_OPTION(WITH_FFMPEG         "Include FFMPEG support"                      ON   IF (NOT ANDROID AND NOT IOS))
 138 OCV_OPTION(WITH_GSTREAMER      "Include Gstreamer support"                   ON   IF (UNIX AND NOT APPLE AND NOT ANDROID) )
 139 OCV_OPTION(WITH_GTK            "Include GTK support"                         ON   IF (UNIX AND NOT APPLE AND NOT ANDROID) )
 140 OCV_OPTION(WITH_IMAGEIO        "ImageIO support for OS X"                    OFF  IF APPLE )
 141 OCV_OPTION(WITH_IPP            "Include Intel IPP support"                   OFF  IF (MSVC OR X86 OR X86_64) )
 142 OCV_OPTION(WITH_JASPER         "Include JPEG2K support"                      ON   IF (NOT IOS) )
 143 OCV_OPTION(WITH_JPEG           "Include JPEG support"                        ON)
 144 OCV_OPTION(WITH_OPENEXR        "Include ILM support via OpenEXR"             ON   IF (NOT IOS) )
 145 OCV_OPTION(WITH_OPENGL         "Include OpenGL support"                      OFF  IF (NOT ANDROID AND NOT APPLE) )
 146 OCV_OPTION(WITH_OPENNI         "Include OpenNI support"                      OFF  IF (NOT ANDROID AND NOT IOS) )
 147 OCV_OPTION(WITH_PNG            "Include PNG support"                         ON)
 148 OCV_OPTION(WITH_PVAPI          "Include Prosilica GigE support"              ON   IF (NOT ANDROID AND NOT IOS) )
 149 OCV_OPTION(WITH_GIGEAPI        "Include Smartek GigE support"                ON   IF (NOT ANDROID AND NOT IOS) )
 150 OCV_OPTION(WITH_QT             "Build with Qt Backend support"               OFF  IF (NOT ANDROID AND NOT IOS) )
 151 OCV_OPTION(WITH_WIN32UI        "Build with Win32 UI Backend support"         ON   IF WIN32 )
 152 OCV_OPTION(WITH_QUICKTIME      "Use QuickTime for Video I/O insted of QTKit" OFF  IF APPLE )
 153 OCV_OPTION(WITH_TBB            "Include Intel TBB support"                   OFF  IF (NOT IOS) )
 154 OCV_OPTION(WITH_OPENMP         "Include OpenMP support"                      OFF)
 155 OCV_OPTION(WITH_CSTRIPES       "Include C= support"                          OFF  IF WIN32 )
 156 OCV_OPTION(WITH_TIFF           "Include TIFF support"                        ON   IF (NOT IOS) )
 157 OCV_OPTION(WITH_UNICAP         "Include Unicap support (GPL)"                OFF  IF (UNIX AND NOT APPLE AND NOT ANDROID) )
 158 OCV_OPTION(WITH_V4L            "Include Video 4 Linux support"               ON   IF (UNIX AND NOT ANDROID) )
 159 OCV_OPTION(WITH_LIBV4L         "Use libv4l for Video 4 Linux support"        ON   IF (UNIX AND NOT ANDROID) )
 160 OCV_OPTION(WITH_DSHOW          "Build HighGUI with DirectShow support"       ON   IF (WIN32 AND NOT ARM) )
 161 OCV_OPTION(WITH_MSMF           "Build HighGUI with Media Foundation support" OFF  IF WIN32 )
 162 OCV_OPTION(WITH_XIMEA          "Include XIMEA cameras support"               OFF  IF (NOT ANDROID AND NOT APPLE) )
 163 OCV_OPTION(WITH_XINE           "Include Xine support (GPL)"                  OFF  IF (UNIX AND NOT APPLE AND NOT ANDROID) )
 164 OCV_OPTION(WITH_OPENCL         "Include OpenCL Runtime support"              ON   IF (NOT IOS) )
 165 OCV_OPTION(WITH_OPENCLAMDFFT   "Include AMD OpenCL FFT library support"      ON   IF (NOT ANDROID AND NOT IOS) )
 166 OCV_OPTION(WITH_OPENCLAMDBLAS  "Include AMD OpenCL BLAS library support"     ON   IF (NOT ANDROID AND NOT IOS) )
 167 OCV_OPTION(WITH_INTELPERC      "Include Intel Perceptual Computing support"  OFF  IF WIN32 )
 168
 169 # OpenCV build components
 170 # ===================================================
 171 OCV_OPTION(BUILD_SHARED_LIBS        "Build shared libraries (.dll/.so) instead of static ones (.lib/.a)" NOT (ANDROID OR IOS) )
 172 OCV_OPTION(BUILD_opencv_apps        "Build utility applications (used for example to train classifiers)" (NOT ANDROID) IF (NOT IOS) )
 173 OCV_OPTION(BUILD_ANDROID_EXAMPLES   "Build examples for Android platform"         ON  IF ANDROID )
 174 OCV_OPTION(BUILD_DOCS               "Create build rules for OpenCV Documentation" ON )
 175 OCV_OPTION(BUILD_EXAMPLES           "Build all examples"                          OFF )
 176 OCV_OPTION(BUILD_PACKAGE            "Enables 'make package_source' command"       ON )
 177 OCV_OPTION(BUILD_PERF_TESTS         "Build performance tests"                     ON  IF (NOT IOS) )
 178 OCV_OPTION(BUILD_TESTS              "Build accuracy & regression tests"           ON  IF (NOT IOS) )
 179 OCV_OPTION(BUILD_WITH_DEBUG_INFO    "Include debug info into debug libs (not MSCV only)" ON )
 180 OCV_OPTION(BUILD_WITH_STATIC_CRT    "Enables use of staticaly linked CRT for staticaly linked OpenCV" ON IF MSVC )
 181 OCV_OPTION(BUILD_FAT_JAVA_LIB       "Create fat java wrapper containing the whole OpenCV library" ON IF NOT BUILD_SHARED_LIBS AND CMAKE_COMPILER_IS_GNUCXX )
 182 OCV_OPTION(BUILD_ANDROID_SERVICE    "Build OpenCV Manager for Google Play" OFF IF ANDROID AND ANDROID_SOURCE_TREE )
 183 OCV_OPTION(BUILD_ANDROID_PACKAGE    "Build platform-specific package for Google Play" OFF IF ANDROID )
 184
 185 # 3rd party libs
 186 OCV_OPTION(BUILD_ZLIB               "Build zlib from source"             WIN32 OR APPLE )
 187 OCV_OPTION(BUILD_TIFF               "Build libtiff from source"          WIN32 OR ANDROID OR APPLE )
 188 OCV_OPTION(BUILD_JASPER             "Build libjasper from source"        WIN32 OR ANDROID OR APPLE )
 189 OCV_OPTION(BUILD_JPEG               "Build libjpeg from source"          WIN32 OR ANDROID OR APPLE )
 190 OCV_OPTION(BUILD_PNG                "Build libpng from source"           WIN32 OR ANDROID OR APPLE )
 191 OCV_OPTION(BUILD_OPENEXR            "Build openexr from source"          WIN32 OR ANDROID OR APPLE )
 192 OCV_OPTION(BUILD_TBB                "Download and build TBB from source" ANDROID )
 193
 194 # OpenCV installation options
 195 # ===================================================
 196 OCV_OPTION(INSTALL_CREATE_DISTRIB   "Change install rules to build the distribution package" OFF )
 197 OCV_OPTION(INSTALL_C_EXAMPLES       "Install C examples"        OFF )
 198 OCV_OPTION(INSTALL_PYTHON_EXAMPLES  "Install Python examples"   OFF )
 199 OCV_OPTION(INSTALL_ANDROID_EXAMPLES "Install Android examples"  OFF IF ANDROID )
 200 OCV_OPTION(INSTALL_TO_MANGLED_PATHS "Enables mangled install paths, that help with side by side installs." OFF IF (UNIX AND NOT ANDROID AND NOT IOS AND BUILD_SHARED_LIBS) )
 201 OCV_OPTION(INSTALL_TESTS            "Install accuracy and performance test binaries and test data" OFF)
 202
 203 # OpenCV build options
 204 # ===================================================
 205 OCV_OPTION(ENABLE_DYNAMIC_CUDA        "Enabled dynamic CUDA linkage"                             ON   IF ANDROID )
 206 OCV_OPTION(ENABLE_PRECOMPILED_HEADERS "Use precompiled headers"                                  ON   IF (NOT IOS) )
 207 OCV_OPTION(ENABLE_SOLUTION_FOLDERS    "Solution folder in Visual Studio or in other IDEs"        (MSVC_IDE OR CMAKE_GENERATOR MATCHES Xcode) IF (CMAKE_VERSION VERSION_GREATER "2.8.0") )
 208 OCV_OPTION(ENABLE_PROFILING           "Enable profiling in the GCC compiler (Add flags: -g -pg)" OFF  IF CMAKE_COMPILER_IS_GNUCXX )
 209 OCV_OPTION(ENABLE_OMIT_FRAME_POINTER  "Enable -fomit-frame-pointer for GCC"                      ON   IF CMAKE_COMPILER_IS_GNUCXX AND NOT (APPLE AND CMAKE_COMPILER_IS_CLANGCXX) )
 210 OCV_OPTION(ENABLE_POWERPC             "Enable PowerPC for GCC"                                   ON   IF (CMAKE_COMPILER_IS_GNUCXX AND CMAKE_SYSTEM_PROCESSOR MATCHES powerpc.*) )
 211 OCV_OPTION(ENABLE_FAST_MATH           "Enable -ffast-math (not recommended for GCC 4.6.x)"       OFF  IF (CMAKE_COMPILER_IS_GNUCXX AND (X86 OR X86_64)) )
 212 OCV_OPTION(ENABLE_SSE                 "Enable SSE instructions"                                  ON   IF ((MSVC OR CMAKE_COMPILER_IS_GNUCXX) AND (X86 OR X86_64)) )
 213 OCV_OPTION(ENABLE_SSE2                "Enable SSE2 instructions"                                 ON   IF ((MSVC OR CMAKE_COMPILER_IS_GNUCXX) AND (X86 OR X86_64)) )
 214 OCV_OPTION(ENABLE_SSE3                "Enable SSE3 instructions"                                 ON   IF ((CV_ICC OR CMAKE_COMPILER_IS_GNUCXX) AND (X86 OR X86_64)) )
 215 OCV_OPTION(ENABLE_SSSE3               "Enable SSSE3 instructions"                                OFF  IF (CMAKE_COMPILER_IS_GNUCXX AND (X86 OR X86_64)) )
 216 OCV_OPTION(ENABLE_SSE41               "Enable SSE4.1 instructions"                               OFF  IF ((CV_ICC OR CMAKE_COMPILER_IS_GNUCXX) AND (X86 OR X86_64)) )
 217 OCV_OPTION(ENABLE_SSE42               "Enable SSE4.2 instructions"                               OFF  IF (CMAKE_COMPILER_IS_GNUCXX AND (X86 OR X86_64)) )
 218 OCV_OPTION(ENABLE_AVX                 "Enable AVX instructions"                                  OFF  IF ((MSVC OR CMAKE_COMPILER_IS_GNUCXX) AND (X86 OR X86_64)) )
 219 OCV_OPTION(ENABLE_NEON                "Enable NEON instructions"                                 OFF  IF CMAKE_COMPILER_IS_GNUCXX AND ARM )
 220 OCV_OPTION(ENABLE_VFPV3               "Enable VFPv3-D32 instructions"                            OFF  IF CMAKE_COMPILER_IS_GNUCXX AND ARM )
 221 OCV_OPTION(ENABLE_NOISY_WARNINGS      "Show all warnings even if they are too noisy"             OFF )
 222 OCV_OPTION(OPENCV_WARNINGS_ARE_ERRORS "Treat warnings as errors"                                 OFF )
 223 OCV_OPTION(ENABLE_WINRT_MODE          "Build with Windows Runtime support"                       OFF  IF WIN32 )
 224 OCV_OPTION(ENABLE_WINRT_MODE_NATIVE   "Build with Windows Runtime native C++ support"            OFF  IF WIN32 )
 225
 226 # uncategorized options
 227 # ===================================================
 228 OCV_OPTION(CMAKE_VERBOSE "Verbose mode" OFF )
 229
 230 # backward compatibility
 231 # ===================================================
 232 include(cmake/OpenCVLegacyOptions.cmake OPTIONAL)
 233
 234
 235 # ----------------------------------------------------------------------------
 236 #  Get actual OpenCV version number from sources
 237 # ----------------------------------------------------------------------------
 238 include(cmake/OpenCVVersion.cmake)
 239
 240
 241 # ----------------------------------------------------------------------------
 242 #  Build & install layouts
 243 # ----------------------------------------------------------------------------
 244
 245 # Save libs and executables in the same place
 246 set(EXECUTABLE_OUTPUT_PATH "${CMAKE_BINARY_DIR}/bin" CACHE PATH "Output directory for applications" )
 247
 248 if (ANDROID)
 249   if (ANDROID_ABI MATCHES "NEON")
 250     set(ENABLE_NEON ON)
 251   endif()
 252   if (ANDROID_ABI MATCHES "VFPV3")
 253     set(ENABLE_VFPV3 ON)
 254   endif()
 255 endif()
 256
 257 if(ANDROID OR WIN32)
 258   set(OPENCV_DOC_INSTALL_PATH doc)
 259 elseif(INSTALL_TO_MANGLED_PATHS)
 260   set(OPENCV_DOC_INSTALL_PATH share/OpenCV-${OPENCV_VERSION}/doc)
 261 else()
 262   set(OPENCV_DOC_INSTALL_PATH share/OpenCV/doc)
 263 endif()
 264
 265 if(WIN32)
 266   if(DEFINED OpenCV_RUNTIME AND DEFINED OpenCV_ARCH)
 267     set(OpenCV_INSTALL_BINARIES_PREFIX "${OpenCV_ARCH}/${OpenCV_RUNTIME}/")
 268   else()
 269     message(STATUS "Can't detect runtime and/or arch")
 270     set(OpenCV_INSTALL_BINARIES_PREFIX "")
 271   endif()
 272 elseif(ANDROID)
 273   set(OpenCV_INSTALL_BINARIES_PREFIX "sdk/native/")
 274 else()
 275   set(OpenCV_INSTALL_BINARIES_PREFIX "")
 276 endif()
 277
 278 if(ANDROID)
 279   set(OPENCV_SAMPLES_BIN_INSTALL_PATH "${OpenCV_INSTALL_BINARIES_PREFIX}samples/${ANDROID_NDK_ABI_NAME}")
 280 else()
 281   set(OPENCV_SAMPLES_BIN_INSTALL_PATH "${OpenCV_INSTALL_BINARIES_PREFIX}samples")
 282 endif()
 283
 284 if(ANDROID)
 285   set(OPENCV_BIN_INSTALL_PATH "${OpenCV_INSTALL_BINARIES_PREFIX}bin/${ANDROID_NDK_ABI_NAME}")
 286 else()
 287   set(OPENCV_BIN_INSTALL_PATH "${OpenCV_INSTALL_BINARIES_PREFIX}bin")
 288 endif()
 289
 290 if(NOT OPENCV_TEST_INSTALL_PATH)
 291   set(OPENCV_TEST_INSTALL_PATH "${OPENCV_BIN_INSTALL_PATH}")
 292 endif()
 293
 294 if(ANDROID)
 295   set(LIBRARY_OUTPUT_PATH         "${OpenCV_BINARY_DIR}/lib/${ANDROID_NDK_ABI_NAME}")
 296   set(3P_LIBRARY_OUTPUT_PATH      "${OpenCV_BINARY_DIR}/3rdparty/lib/${ANDROID_NDK_ABI_NAME}")
 297   set(OPENCV_LIB_INSTALL_PATH     sdk/native/libs/${ANDROID_NDK_ABI_NAME})
 298   set(OPENCV_3P_LIB_INSTALL_PATH  sdk/native/3rdparty/libs/${ANDROID_NDK_ABI_NAME})
 299   set(OPENCV_CONFIG_INSTALL_PATH  sdk/native/jni)
 300   set(OPENCV_INCLUDE_INSTALL_PATH sdk/native/jni/include)
 301   set(OPENCV_SAMPLES_SRC_INSTALL_PATH samples/native)
 302 else()
 303   set(LIBRARY_OUTPUT_PATH         "${OpenCV_BINARY_DIR}/lib")
 304   set(3P_LIBRARY_OUTPUT_PATH      "${OpenCV_BINARY_DIR}/3rdparty/lib${LIB_SUFFIX}")
 305   if(WIN32)
 306     if(OpenCV_STATIC)
 307       set(OPENCV_LIB_INSTALL_PATH   "${OpenCV_INSTALL_BINARIES_PREFIX}staticlib${LIB_SUFFIX}")
 308     else()
 309       set(OPENCV_LIB_INSTALL_PATH   "${OpenCV_INSTALL_BINARIES_PREFIX}lib${LIB_SUFFIX}")
 310     endif()
 311     set(OPENCV_3P_LIB_INSTALL_PATH  "${OpenCV_INSTALL_BINARIES_PREFIX}staticlib${LIB_SUFFIX}")
 312     set(OPENCV_SAMPLES_SRC_INSTALL_PATH    samples/native)
 313   else()
 314     set(OPENCV_LIB_INSTALL_PATH     lib${LIB_SUFFIX})
 315     set(OPENCV_3P_LIB_INSTALL_PATH  share/OpenCV/3rdparty/${OPENCV_LIB_INSTALL_PATH})
 316     set(OPENCV_SAMPLES_SRC_INSTALL_PATH    share/OpenCV/samples)
 317   endif()
 318   set(OPENCV_INCLUDE_INSTALL_PATH "include")
 319
 320   math(EXPR SIZEOF_VOID_P_BITS "8 * ${CMAKE_SIZEOF_VOID_P}")
 321   if(LIB_SUFFIX AND NOT SIZEOF_VOID_P_BITS EQUAL LIB_SUFFIX)
 322     set(OPENCV_CONFIG_INSTALL_PATH lib${LIB_SUFFIX}/cmake/opencv)
 323   else()
 324     set(OPENCV_CONFIG_INSTALL_PATH share/OpenCV)
 325   endif()
 326 endif()
 327
 328 set(CMAKE_INSTALL_RPATH "${CMAKE_INSTALL_PREFIX}/${OPENCV_LIB_INSTALL_PATH}")
 329 set(CMAKE_INSTALL_RPATH_USE_LINK_PATH TRUE)
 330
 331 if(INSTALL_TO_MANGLED_PATHS)
 332   set(OPENCV_INCLUDE_INSTALL_PATH ${OPENCV_INCLUDE_INSTALL_PATH}/opencv-${OPENCV_VERSION})
 333 endif()
 334
 335 if(WIN32)
 336   # Postfix of DLLs:
 337   set(OPENCV_DLLVERSION "${OPENCV_VERSION_MAJOR}${OPENCV_VERSION_MINOR}${OPENCV_VERSION_PATCH}")
 338   set(OPENCV_DEBUG_POSTFIX d)
 339 else()
 340   # Postfix of so's:
 341   set(OPENCV_DLLVERSION "")
 342   set(OPENCV_DEBUG_POSTFIX "")
 343 endif()
 344
 345 if(DEFINED CMAKE_DEBUG_POSTFIX)
 346   set(OPENCV_DEBUG_POSTFIX "${CMAKE_DEBUG_POSTFIX}")
 347 endif()
 348
 349 if(CMAKE_VERBOSE)
 350   set(CMAKE_VERBOSE_MAKEFILE 1)
 351 endif()
 352
 353
 354 # ----------------------------------------------------------------------------
 355 #  Path for build/platform -specific headers
 356 # ----------------------------------------------------------------------------
 357 set(OPENCV_CONFIG_FILE_INCLUDE_DIR "${CMAKE_BINARY_DIR}/" CACHE PATH "Where to create the platform-dependant cvconfig.h")
 358 ocv_include_directories(${OPENCV_CONFIG_FILE_INCLUDE_DIR})
 359
 360 # ----------------------------------------------------------------------------
 361 #  Path for additional modules
 362 # ----------------------------------------------------------------------------
 363 set(OPENCV_EXTRA_MODULES_PATH "" CACHE PATH "Where to look for additional OpenCV modules")
 364
 365 # ----------------------------------------------------------------------------
 366 #  Autodetect if we are in a GIT repository
 367 # ----------------------------------------------------------------------------
 368
 369 # don't use FindGit because it requires CMake 2.8.2
 370 set(git_names git eg) # eg = easy git
 371 # Prefer .cmd variants on Windows unless running in a Makefile in the MSYS shell
 372 if(CMAKE_HOST_WIN32)
 373   if(NOT CMAKE_GENERATOR MATCHES "MSYS")
 374     set(git_names git.cmd git eg.cmd eg)
 375   endif()
 376 endif()
 377
 378 find_host_program(GIT_EXECUTABLE NAMES ${git_names} PATH_SUFFIXES Git/cmd Git/bin DOC "git command line client")
 379 mark_as_advanced(GIT_EXECUTABLE)
 380
 381 if(GIT_EXECUTABLE)
 382   execute_process(COMMAND ${GIT_EXECUTABLE} describe --tags --always --dirty --match "2.[0-9].[0-9]*"
 383     WORKING_DIRECTORY "${OpenCV_SOURCE_DIR}"
 384     OUTPUT_VARIABLE OPENCV_VCSVERSION
 385     RESULT_VARIABLE GIT_RESULT
 386     ERROR_QUIET
 387     OUTPUT_STRIP_TRAILING_WHITESPACE
 388   )
 389   if(NOT GIT_RESULT EQUAL 0)
 390     set(OPENCV_VCSVERSION "unknown")
 391   endif()
 392 else()
 393   # We don't have git:
 394   set(OPENCV_VCSVERSION "unknown")
 395 endif()
 396
 397
 398 # ----------------------------------------------------------------------------
 399 # OpenCV compiler and linker options
 400 # ----------------------------------------------------------------------------
 401 # In case of Makefiles if the user does not setup CMAKE_BUILD_TYPE, assume it's Release:
 402 if(CMAKE_GENERATOR MATCHES "Makefiles|Ninja" AND "${CMAKE_BUILD_TYPE}" STREQUAL "")
 403   set(CMAKE_BUILD_TYPE Release)
 404 endif()
 405
 406 include(cmake/OpenCVCompilerOptions.cmake)
 407
 408
 409 # ----------------------------------------------------------------------------
 410 # Use statically or dynamically linked CRT?
 411 # Default: dynamic
 412 # ----------------------------------------------------------------------------
 413 if(MSVC)
 414   include(cmake/OpenCVCRTLinkage.cmake)
 415 endif(MSVC)
 416
 417 if(WIN32 AND NOT MINGW)
 418   add_definitions(-D_VARIADIC_MAX=10)
 419 endif(WIN32 AND NOT MINGW)
 420
 421
 422 # ----------------------------------------------------------------------------
 423 #       CHECK FOR SYSTEM LIBRARIES, OPTIONS, ETC..
 424 # ----------------------------------------------------------------------------
 425 if(UNIX)
 426   include(cmake/OpenCVFindPkgConfig.cmake OPTIONAL)
 427   include(CheckFunctionExists)
 428   include(CheckIncludeFile)
 429
 430   if(NOT APPLE)
 431     CHECK_INCLUDE_FILE(pthread.h HAVE_LIBPTHREAD)
 432     if(ANDROID)
 433       set(OPENCV_LINKER_LIBS ${OPENCV_LINKER_LIBS} dl m log)
 434     elseif(${CMAKE_SYSTEM_NAME} MATCHES "FreeBSD|NetBSD|DragonFly")
 435       set(OPENCV_LINKER_LIBS ${OPENCV_LINKER_LIBS} m pthread)
 436     else()
 437       set(OPENCV_LINKER_LIBS ${OPENCV_LINKER_LIBS} dl m pthread rt)
 438     endif()
 439   else()
 440     set(HAVE_LIBPTHREAD YES)
 441   endif()
 442 endif()
 443
 444 include(cmake/OpenCVPCHSupport.cmake)
 445 include(cmake/OpenCVModule.cmake)
 446
 447 # ----------------------------------------------------------------------------
 448 #  Detect 3rd-party libraries
 449 # ----------------------------------------------------------------------------
 450
 451 include(cmake/OpenCVFindLibsGrfmt.cmake)
 452 include(cmake/OpenCVFindLibsGUI.cmake)
 453 include(cmake/OpenCVFindLibsVideo.cmake)
 454 include(cmake/OpenCVFindLibsPerf.cmake)
 455
 456
 457 # ----------------------------------------------------------------------------
 458 #  Detect other 3rd-party libraries/tools
 459 # ----------------------------------------------------------------------------
 460
 461 # --- LATEX for pdf documentation ---
 462 if(BUILD_DOCS)
 463   include(cmake/OpenCVFindLATEX.cmake)
 464 endif(BUILD_DOCS)
 465
 466 # --- Python Support ---
 467 include(cmake/OpenCVDetectPython.cmake)
 468
 469 # --- Java Support ---
 470 include(cmake/OpenCVDetectApacheAnt.cmake)
 471 if(ANDROID)
 472   include(cmake/OpenCVDetectAndroidSDK.cmake)
 473
 474   if(NOT ANDROID_TOOLS_Pkg_Revision GREATER 13)
 475     message(WARNING "OpenCV requires Android SDK tools revision 14 or newer. Otherwise tests and samples will no be compiled.")
 476   endif()
 477 else()
 478   find_package(JNI)
 479 endif()
 480
 481 if(ANDROID AND ANDROID_EXECUTABLE AND ANT_EXECUTABLE AND (ANT_VERSION VERSION_GREATER 1.7) AND (ANDROID_TOOLS_Pkg_Revision GREATER 13))
 482   SET(CAN_BUILD_ANDROID_PROJECTS TRUE)
 483 else()
 484   SET(CAN_BUILD_ANDROID_PROJECTS FALSE)
 485 endif()
 486
 487 # --- OpenCL ---
 488 if(WITH_OPENCL)
 489   include(cmake/OpenCVDetectOpenCL.cmake)
 490 endif()
 491
 492 # --- VTK support ---
 493 include(cmake/OpenCVDetectVTK.cmake)
 494
 495 # ----------------------------------------------------------------------------
 496 # Add CUDA libraries (needed for apps/tools, samples)
 497 # ----------------------------------------------------------------------------
 498 if(NOT HAVE_CUDA)
 499   set(ENABLE_DYNAMIC_CUDA OFF)
 500 endif()
 501
 502 if(HAVE_CUDA AND NOT ENABLE_DYNAMIC_CUDA)
 503   set(OPENCV_LINKER_LIBS ${OPENCV_LINKER_LIBS} ${CUDA_LIBRARIES} ${CUDA_npp_LIBRARY})
 504   if(HAVE_CUBLAS)
 505     set(OPENCV_LINKER_LIBS ${OPENCV_LINKER_LIBS} ${CUDA_cublas_LIBRARY})
 506   endif()
 507   if(HAVE_CUFFT)
 508     set(OPENCV_LINKER_LIBS ${OPENCV_LINKER_LIBS} ${CUDA_cufft_LIBRARY})
 509   endif()
 510 endif()
 511
 512 # ----------------------------------------------------------------------------
 513 # Solution folders:
 514 # ----------------------------------------------------------------------------
 515 if(ENABLE_SOLUTION_FOLDERS)
 516   set_property(GLOBAL PROPERTY USE_FOLDERS ON)
 517   set_property(GLOBAL PROPERTY PREDEFINED_TARGETS_FOLDER "CMakeTargets")
 518 endif()
 519
 520 # Extra OpenCV targets: uninstall, package_source, perf, etc.
 521 include(cmake/OpenCVExtraTargets.cmake)
 522
 523
 524 # ----------------------------------------------------------------------------
 525 # Process subdirectories
 526 # ----------------------------------------------------------------------------
 527
 528 # opencv.hpp and legacy headers
 529 add_subdirectory(include)
 530
 531 # OpenCV modules
 532 add_subdirectory(modules)
 533
 534 # Generate targets for documentation
 535 add_subdirectory(doc)
 536
 537 # various data that is used by cv libraries and/or demo applications.
 538 add_subdirectory(data)
 539
 540 # extra applications
 541 if(BUILD_opencv_apps)
 542   add_subdirectory(apps)
 543 endif()
 544
 545 # examples
 546 if(BUILD_EXAMPLES OR BUILD_ANDROID_EXAMPLES OR INSTALL_PYTHON_EXAMPLES)
 547   add_subdirectory(samples)
 548 endif()
 549
 550 if(ANDROID)
 551   add_subdirectory(platforms/android/service)
 552 endif()
 553
 554 if(BUILD_ANDROID_PACKAGE)
 555   add_subdirectory(platforms/android/package)
 556 endif()
 557
 558 if (ANDROID)
 559   add_subdirectory(platforms/android/libinfo)
 560 endif()
 561
 562 # ----------------------------------------------------------------------------
 563 # Finalization: generate configuration-based files
 564 # ----------------------------------------------------------------------------
 565 ocv_track_build_dependencies()
 566
 567 # Generate platform-dependent and configuration-dependent headers
 568 include(cmake/OpenCVGenHeaders.cmake)
 569
 570 # Generate opencv.pc for pkg-config command
 571 include(cmake/OpenCVGenPkgconfig.cmake)
 572
 573 # Generate OpenCV.mk for ndk-build (Android build tool)
 574 include(cmake/OpenCVGenAndroidMK.cmake)
 575
 576 # Generate OpenCVСonfig.cmake and OpenCVConfig-version.cmake for cmake projects
 577 include(cmake/OpenCVGenConfig.cmake)
 578
 579 # Generate Info.plist for the IOS framework
 580 include(cmake/OpenCVGenInfoPlist.cmake)
 581
 582 # Generate environment setup file
 583 if(INSTALL_TESTS AND OPENCV_TEST_DATA_PATH AND UNIX AND NOT ANDROID)
 584   configure_file("${CMAKE_CURRENT_SOURCE_DIR}/cmake/templates/opencv_testing.sh.in"
 585                  "${CMAKE_BINARY_DIR}/unix-install/opencv_testing.sh" @ONLY)
 586   install(FILES "${CMAKE_BINARY_DIR}/unix-install/opencv_testing.sh"
 587           DESTINATION /etc/profile.d/ COMPONENT tests)
 588   configure_file("${CMAKE_CURRENT_SOURCE_DIR}/cmake/templates/opencv_run_all_tests.sh.in"
 589                  "${CMAKE_BINARY_DIR}/unix-install/opencv_run_all_tests.sh" @ONLY)
 590   install(FILES "${CMAKE_BINARY_DIR}/unix-install/opencv_run_all_tests.sh"
 591           PERMISSIONS OWNER_READ OWNER_WRITE GROUP_READ WORLD_READ OWNER_EXECUTE GROUP_EXECUTE WORLD_EXECUTE
 592           DESTINATION ${OPENCV_TEST_INSTALL_PATH} COMPONENT tests)
 593 endif()
 594
 595 # ----------------------------------------------------------------------------
 596 # Summary:
 597 # ----------------------------------------------------------------------------
 598 status("")
 599 status("General configuration for OpenCV ${OPENCV_VERSION} =====================================")
 600 if(OPENCV_VCSVERSION)
 601   status("  Version control:" ${OPENCV_VCSVERSION})
 602 endif()
 603
 604 # ========================== build platform ==========================
 605 status("")
 606 status("  Platform:")
 607 status("    Host:"             ${CMAKE_HOST_SYSTEM_NAME} ${CMAKE_HOST_SYSTEM_VERSION} ${CMAKE_HOST_SYSTEM_PROCESSOR})
 608 if(CMAKE_CROSSCOMPILING)
 609   status("    Target:"         ${CMAKE_SYSTEM_NAME} ${CMAKE_SYSTEM_VERSION} ${CMAKE_SYSTEM_PROCESSOR})
 610 endif()
 611 status("    CMake:"            ${CMAKE_VERSION})
 612 status("    CMake generator:"  ${CMAKE_GENERATOR})
 613 status("    CMake build tool:" ${CMAKE_BUILD_TOOL})
 614 if(MSVC)
 615   status("    MSVC:"           ${MSVC_VERSION})
 616 endif()
 617 if(CMAKE_GENERATOR MATCHES Xcode)
 618   status("    Xcode:"          ${XCODE_VERSION})
 619 endif()
 620 if(NOT CMAKE_GENERATOR MATCHES "Xcode|Visual Studio")
 621   status("    Configuration:"  ${CMAKE_BUILD_TYPE})
 622 endif()
 623
 624 # ========================== C/C++ options ==========================
 625 if(CMAKE_CXX_COMPILER_VERSION)
 626   set(OPENCV_COMPILER_STR "${CMAKE_CXX_COMPILER} ${CMAKE_CXX_COMPILER_ARG1} (ver ${CMAKE_CXX_COMPILER_VERSION})")
 627 elseif(CMAKE_COMPILER_IS_CLANGCXX)
 628   set(OPENCV_COMPILER_STR "${CMAKE_CXX_COMPILER} ${CMAKE_CXX_COMPILER_ARG1} (ver ${CMAKE_CLANG_REGEX_VERSION})")
 629 elseif(CMAKE_COMPILER_IS_GNUCXX)
 630   set(OPENCV_COMPILER_STR "${CMAKE_CXX_COMPILER} ${CMAKE_CXX_COMPILER_ARG1} (ver ${CMAKE_GCC_REGEX_VERSION})")
 631 else()
 632   set(OPENCV_COMPILER_STR "${CMAKE_CXX_COMPILER} ${CMAKE_CXX_COMPILER_ARG1}")
 633 endif()
 634 string(STRIP "${OPENCV_COMPILER_STR}" OPENCV_COMPILER_STR)
 635
 636 status("")
 637 status("  C/C++:")
 638 status("    Built as dynamic libs?:" BUILD_SHARED_LIBS THEN YES ELSE NO)
 639 status("    C++ Compiler:"           ${OPENCV_COMPILER_STR})
 640 status("    C++ flags (Release):"    ${CMAKE_CXX_FLAGS} ${CMAKE_CXX_FLAGS_RELEASE})
 641 status("    C++ flags (Debug):"      ${CMAKE_CXX_FLAGS} ${CMAKE_CXX_FLAGS_DEBUG})
 642 status("    C Compiler:"             ${CMAKE_C_COMPILER} ${CMAKE_C_COMPILER_ARG1})
 643 status("    C flags (Release):"      ${CMAKE_C_FLAGS} ${CMAKE_C_FLAGS_RELEASE})
 644 status("    C flags (Debug):"        ${CMAKE_C_FLAGS} ${CMAKE_C_FLAGS_DEBUG})
 645 if(WIN32)
 646   status("    Linker flags (Release):" ${CMAKE_EXE_LINKER_FLAGS} ${CMAKE_EXE_LINKER_FLAGS_RELEASE})
 647   status("    Linker flags (Debug):"   ${CMAKE_EXE_LINKER_FLAGS} ${CMAKE_EXE_LINKER_FLAGS_DEBUG})
 648 else()
 649   status("    Linker flags (Release):" ${CMAKE_SHARED_LINKER_FLAGS} ${CMAKE_SHARED_LINKER_FLAGS_RELEASE})
 650   status("    Linker flags (Debug):"   ${CMAKE_SHARED_LINKER_FLAGS} ${CMAKE_SHARED_LINKER_FLAGS_DEBUG})
 651 endif()
 652 status("    Precompiled headers:"     PCHSupport_FOUND AND ENABLE_PRECOMPILED_HEADERS THEN YES ELSE NO)
 653
 654 # ========================== OpenCV modules ==========================
 655 status("")
 656 status("  OpenCV modules:")
 657 string(REPLACE "opencv_" "" OPENCV_MODULES_BUILD_ST          "${OPENCV_MODULES_BUILD}")
 658 string(REPLACE "opencv_" "" OPENCV_MODULES_DISABLED_USER_ST  "${OPENCV_MODULES_DISABLED_USER}")
 659 string(REPLACE "opencv_" "" OPENCV_MODULES_DISABLED_FORCE_ST "${OPENCV_MODULES_DISABLED_FORCE}")
 660 set(OPENCV_MODULES_DISABLED_AUTO_ST "")
 661 foreach(m ${OPENCV_MODULES_DISABLED_AUTO})
 662   set(__mdeps "")
 663   foreach(d ${OPENCV_MODULE_${m}_DEPS})
 664     if(d MATCHES "^opencv_" AND NOT HAVE_${d})
 665       list(APPEND __mdeps ${d})
 666     endif()
 667   endforeach()
 668   if(__mdeps)
 669     list(APPEND OPENCV_MODULES_DISABLED_AUTO_ST "${m}(deps: ${__mdeps})")
 670   else()
 671     list(APPEND OPENCV_MODULES_DISABLED_AUTO_ST "${m}")
 672   endif()
 673 endforeach()
 674 string(REPLACE "opencv_" "" OPENCV_MODULES_DISABLED_AUTO_ST  "${OPENCV_MODULES_DISABLED_AUTO_ST}")
 675
 676 status("    To be built:"            OPENCV_MODULES_BUILD          THEN ${OPENCV_MODULES_BUILD_ST}          ELSE "-")
 677 status("    Disabled:"               OPENCV_MODULES_DISABLED_USER  THEN ${OPENCV_MODULES_DISABLED_USER_ST}  ELSE "-")
 678 status("    Disabled by dependency:" OPENCV_MODULES_DISABLED_AUTO  THEN ${OPENCV_MODULES_DISABLED_AUTO_ST}  ELSE "-")
 679 status("    Unavailable:"            OPENCV_MODULES_DISABLED_FORCE THEN ${OPENCV_MODULES_DISABLED_FORCE_ST} ELSE "-")
 680
 681 # ========================== Android details ==========================
 682 if(ANDROID)
 683   status("")
 684   status("  Android: ")
 685   status("    Android ABI:" ${ANDROID_ABI})
 686   status("    STL type:" ${ANDROID_STL})
 687   status("    Native API level:" android-${ANDROID_NATIVE_API_LEVEL})
 688   android_get_compatible_target(android_sdk_target_status ${ANDROID_NATIVE_API_LEVEL} ${ANDROID_SDK_TARGET} 11)
 689   status("    SDK target:" "${android_sdk_target_status}")
 690   if(BUILD_WITH_ANDROID_NDK)
 691     status("    Android NDK:" "${ANDROID_NDK} (toolchain: ${ANDROID_TOOLCHAIN_NAME})")
 692   elseif(BUILD_WITH_STANDALONE_TOOLCHAIN)
 693     status("    Android toolchain:" "${ANDROID_STANDALONE_TOOLCHAIN}")
 694   endif()
 695   status("    android tool:"  ANDROID_EXECUTABLE  THEN "${ANDROID_EXECUTABLE} (${ANDROID_TOOLS_Pkg_Desc})" ELSE NO)
 696   status("    Google Play package:" BUILD_ANDROID_PACKAGE                                         THEN YES ELSE NO)
 697   status("    Android examples:"    BUILD_ANDROID_EXAMPLES AND CAN_BUILD_ANDROID_PROJECTS         THEN YES ELSE NO)
 698 endif()
 699
 700 # ================== Windows RT features ==================
 701 if(WIN32)
 702 status("")
 703     status("  Windows RT support:" HAVE_WINRT THEN YES ELSE NO)
 704     if (ENABLE_WINRT_MODE OR ENABLE_WINRT_MODE_NATIVE)
 705       status("    Windows SDK v8.0:" ${WINDOWS_SDK_PATH})
 706       status("    Visual Studio 2012:" ${VISUAL_STUDIO_PATH})
 707     endif()
 708 endif(WIN32)
 709
 710 # ========================== GUI ==========================
 711 status("")
 712 status("  GUI: ")
 713
 714 if(HAVE_QT5)
 715   status("    QT 5.x:"            HAVE_QT        THEN "YES (ver ${Qt5Core_VERSION_STRING})" ELSE NO)
 716   status("    QT OpenGL support:" HAVE_QT_OPENGL THEN "YES (${Qt5OpenGL_LIBRARIES} ${Qt5OpenGL_VERSION_STRING})" ELSE NO)
 717 elseif(HAVE_QT)
 718   status("    QT 4.x:"            HAVE_QT        THEN "YES (ver ${QT_VERSION_MAJOR}.${QT_VERSION_MINOR}.${QT_VERSION_PATCH} ${QT_EDITION})" ELSE NO)
 719   status("    QT OpenGL support:" HAVE_QT_OPENGL THEN "YES (${QT_QTOPENGL_LIBRARY})" ELSE NO)
 720 else()
 721   if(DEFINED WITH_QT)
 722     status("    QT:" NO)
 723   endif()
 724   if(DEFINED WITH_WIN32UI)
 725     status("    Win32 UI:" HAVE_WIN32UI THEN YES ELSE NO)
 726   else()
 727     if(APPLE)
 728       if(WITH_CARBON)
 729         status("    Carbon:" YES)
 730       else()
 731         status("    Cocoa:"  YES)
 732       endif()
 733     else()
 734       status("    GTK+ 2.x:" HAVE_GTK      THEN "YES (ver ${ALIASOF_gtk+-2.0_VERSION})"     ELSE NO)
 735       status("    GThread :" HAVE_GTHREAD  THEN "YES (ver ${ALIASOF_gthread-2.0_VERSION})"  ELSE NO)
 736       status("    GtkGlExt:" HAVE_GTKGLEXT THEN "YES (ver ${ALIASOF_gtkglext-1.0_VERSION})" ELSE NO)
 737     endif()
 738   endif()
 739 endif()
 740
 741 status("    OpenGL support:" HAVE_OPENGL THEN "YES (${OPENGL_LIBRARIES})" ELSE NO)
 742 status("    VTK support:" HAVE_VTK THEN "YES (ver ${VTK_VERSION})" ELSE NO)
 743
 744 # ========================== MEDIA IO ==========================
 745 status("")
 746 status("  Media I/O: ")
 747 status("    ZLib:"         BUILD_ZLIB    THEN "build (ver ${ZLIB_VERSION_STRING})"               ELSE "${ZLIB_LIBRARY} (ver ${ZLIB_VERSION_STRING})")
 748
 749 if(WITH_JPEG)
 750   status("    JPEG:"       JPEG_FOUND    THEN "${JPEG_LIBRARY} (ver ${JPEG_LIB_VERSION})"        ELSE "build (ver ${JPEG_LIB_VERSION})")
 751 else()
 752   status("    JPEG:"       "NO")
 753 endif()
 754 if(WITH_PNG)
 755   status("    PNG:"        PNG_FOUND     THEN "${PNG_LIBRARY} (ver ${PNG_VERSION})"              ELSE "build (ver ${PNG_VERSION})")
 756 else()
 757   status("    PNG:"        "NO")
 758 endif()
 759 if(WITH_TIFF)
 760   if(TIFF_VERSION_STRING AND TIFF_FOUND)
 761     status("    TIFF:"     "${TIFF_LIBRARY} (ver ${TIFF_VERSION} - ${TIFF_VERSION_STRING})")
 762   else()
 763     status("    TIFF:"     TIFF_FOUND    THEN "${TIFF_LIBRARY} (ver ${TIFF_VERSION})"            ELSE "build (ver ${TIFF_VERSION} - ${TIFF_VERSION_STRING})")
 764   endif()
 765 else()
 766   status("    TIFF:"       "NO")
 767 endif()
 768 if(WITH_JASPER)
 769   status("    JPEG 2000:"  JASPER_FOUND  THEN "${JASPER_LIBRARY} (ver ${JASPER_VERSION_STRING})" ELSE "build (ver ${JASPER_VERSION_STRING})")
 770 else()
 771   status("    JPEG 2000:"  "NO")
 772 endif()
 773 if(WITH_OPENEXR)
 774   status("    OpenEXR:"  OPENEXR_FOUND  THEN "${OPENEXR_LIBRARIES} (ver ${OPENEXR_VERSION})" ELSE "build (ver ${OPENEXR_VERSION})")
 775 else()
 776   status("    OpenEXR:"  "NO")
 777 endif()
 778
 779 # ========================== VIDEO IO ==========================
 780 status("")
 781 status("  Video I/O:")
 782
 783 if (DEFINED WITH_VFW)
 784   status("    Video for Windows:" HAVE_VFW         THEN YES                                        ELSE NO)
 785 endif(DEFINED WITH_VFW)
 786
 787 if(DEFINED WITH_1394)
 788   status("    DC1394 1.x:"     HAVE_DC1394         THEN "YES (ver ${ALIASOF_libdc1394_VERSION})"   ELSE NO)
 789   status("    DC1394 2.x:"     HAVE_DC1394_2       THEN "YES (ver ${ALIASOF_libdc1394-2_VERSION})" ELSE NO)
 790 endif(DEFINED WITH_1394)
 791
 792 if(ANDROID)
 793   if(HAVE_opencv_androidcamera)
 794     status("    AndroidNativeCamera:" BUILD_ANDROID_CAMERA_WRAPPER
 795                                                    THEN "YES, build for Android${ANDROID_VERSION}" ELSE "YES, use prebuilt libraries")
 796   else()
 797     status("    AndroidNativeCamera:" "NO (native camera requires Android API level 8 or higher)")
 798   endif()
 799 endif()
 800
 801 if(DEFINED WITH_AVFOUNDATION)
 802   status("    AVFoundation:"   WITH_AVFOUNDATION   THEN YES                                        ELSE NO)
 803 endif(DEFINED WITH_AVFOUNDATION)
 804
 805 if(DEFINED WITH_FFMPEG)
 806   if(WIN32)
 807     status("    FFMPEG:"       WITH_FFMPEG         THEN "YES (prebuilt binaries)"                  ELSE NO)
 808   else()
 809     status("    FFMPEG:"       HAVE_FFMPEG         THEN YES ELSE NO)
 810   endif()
 811   status("      codec:"        HAVE_FFMPEG_CODEC   THEN "YES (ver ${ALIASOF_libavcodec_VERSION})"  ELSE NO)
 812   status("      format:"       HAVE_FFMPEG_FORMAT  THEN "YES (ver ${ALIASOF_libavformat_VERSION})" ELSE NO)
 813   status("      util:"         HAVE_FFMPEG_UTIL    THEN "YES (ver ${ALIASOF_libavutil_VERSION})"   ELSE NO)
 814   status("      swscale:"      HAVE_FFMPEG_SWSCALE THEN "YES (ver ${ALIASOF_libswscale_VERSION})"  ELSE NO)
 815   status("      gentoo-style:" HAVE_GENTOO_FFMPEG  THEN YES                                        ELSE NO)
 816 endif(DEFINED WITH_FFMPEG)
 817
 818 if(DEFINED WITH_GSTREAMER)
 819   status("    GStreamer:"      HAVE_GSTREAMER      THEN ""                                         ELSE NO)
 820   if(HAVE_GSTREAMER)
 821     status("      base:"       "YES (ver ${ALIASOF_gstreamer-base-0.10_VERSION})")
 822     status("      app:"        "YES (ver ${ALIASOF_gstreamer-app-0.10_VERSION})")
 823     status("      video:"      "YES (ver ${ALIASOF_gstreamer-video-0.10_VERSION})")
 824   endif()
 825 endif(DEFINED WITH_GSTREAMER)
 826
 827 if(DEFINED WITH_OPENNI)
 828   status("    OpenNI:"         HAVE_OPENNI         THEN "YES (ver ${OPENNI_VERSION_STRING}, build ${OPENNI_VERSION_BUILD})"
 829                                                                                                    ELSE NO)
 830   status("    OpenNI PrimeSensor Modules:" HAVE_OPENNI_PRIME_SENSOR_MODULE
 831                                                    THEN "YES (${OPENNI_PRIME_SENSOR_MODULE})"      ELSE NO)
 832 endif(DEFINED WITH_OPENNI)
 833
 834 if(DEFINED WITH_PVAPI)
 835   status("    PvAPI:"          HAVE_PVAPI          THEN YES                                        ELSE NO)
 836 endif(DEFINED WITH_PVAPI)
 837
 838 if(DEFINED WITH_GIGEAPI)
 839   status("    GigEVisionSDK:"  HAVE_GIGE_API       THEN YES                                        ELSE NO)
 840 endif(DEFINED WITH_GIGEAPI)
 841
 842 if(DEFINED WITH_QUICKTIME)
 843   status("    QuickTime:"      HAVE_QUICKTIME      THEN YES                                        ELSE NO)
 844   status("    QTKit:"          HAVE_QTKIT          THEN YES                                        ELSE NO)
 845 endif(DEFINED WITH_QUICKTIME)
 846
 847 if(DEFINED WITH_UNICAP)
 848   status("    UniCap:"         HAVE_UNICAP         THEN "YES (ver ${ALIASOF_libunicap_VERSION})"   ELSE NO)
 849   status("    UniCap ucil:"    HAVE_UNICAP_UCIL    THEN "YES (ver ${ALIASOF_libucil_VERSION})"     ELSE NO)
 850 endif(DEFINED WITH_UNICAP)
 851
 852 if(DEFINED WITH_V4L)
 853   if(HAVE_CAMV4L)
 854     set(HAVE_CAMV4L_STR "YES")
 855   else()
 856     set(HAVE_CAMV4L_STR "NO")
 857   endif()
 858   if(HAVE_CAMV4L2)
 859     set(HAVE_CAMV4L2_STR "YES")
 860   elseif(HAVE_VIDEOIO)
 861     set(HAVE_CAMV4L2_STR "YES(videoio)")
 862   else()
 863     set(HAVE_CAMV4L2_STR "NO")
 864   endif()
 865   status("    V4L/V4L2:"       HAVE_LIBV4L         THEN "Using libv4l (ver ${ALIASOF_libv4l1_VERSION})"
 866                                                    ELSE "${HAVE_CAMV4L_STR}/${HAVE_CAMV4L2_STR}")
 867 endif(DEFINED WITH_V4L)
 868
 869 if(DEFINED WITH_DSHOW)
 870   status("    DirectShow:"     HAVE_DSHOW     THEN YES                                        ELSE NO)
 871 endif(DEFINED WITH_DSHOW)
 872
 873 if(DEFINED WITH_MSMF)
 874   status("    Media Foundation:" HAVE_MSMF    THEN YES                                        ELSE NO)
 875 endif(DEFINED WITH_MSMF)
 876
 877 if(DEFINED WITH_XIMEA)
 878   status("    XIMEA:"          HAVE_XIMEA          THEN YES                                        ELSE NO)
 879 endif(DEFINED WITH_XIMEA)
 880
 881 if(DEFINED WITH_XINE)
 882   status("    Xine:"           HAVE_XINE           THEN "YES (ver ${ALIASOF_libxine_VERSION})"     ELSE NO)
 883 endif(DEFINED WITH_XINE)
 884
 885 if(DEFINED WITH_INTELPERC)
 886   status("    Intel PerC:"     HAVE_INTELPERC      THEN "YES"                                 ELSE NO)
 887 endif(DEFINED WITH_INTELPERC)
 888
 889
 890 # ========================== Other third-party libraries ==========================
 891 status("")
 892 status("  Other third-party libraries:")
 893
 894 if(WITH_IPP AND IPP_FOUND)
 895   status("    Use IPP:" "${IPP_LATEST_VERSION_STR} [${IPP_LATEST_VERSION_MAJOR}.${IPP_LATEST_VERSION_MINOR}.${IPP_LATEST_VERSION_BUILD}]")
 896   status("         at:" "${IPP_ROOT_DIR}")
 897 else()
 898   status("    Use IPP:"   WITH_IPP AND NOT IPP_FOUND THEN "IPP not found" ELSE NO)
 899 endif()
 900
 901 status("    Use Eigen:"      HAVE_EIGEN       THEN "YES (ver ${EIGEN_WORLD_VERSION}.${EIGEN_MAJOR_VERSION}.${EIGEN_MINOR_VERSION})" ELSE NO)
 902 status("    Use TBB:"        HAVE_TBB         THEN "YES (ver ${TBB_VERSION_MAJOR}.${TBB_VERSION_MINOR} interface ${TBB_INTERFACE_VERSION})" ELSE NO)
 903 status("    Use OpenMP:"     HAVE_OPENMP      THEN YES ELSE NO)
 904 status("    Use GCD"         HAVE_GCD         THEN YES ELSE NO)
 905 status("    Use Concurrency" HAVE_CONCURRENCY THEN YES ELSE NO)
 906 status("    Use C=:"         HAVE_CSTRIPES    THEN YES ELSE NO)
 907 status("    Use Cuda:"       HAVE_CUDA        THEN "YES (ver ${CUDA_VERSION_STRING})" ELSE NO)
 908 status("    Use OpenCL:"     HAVE_OPENCL      THEN YES ELSE NO)
 909
 910 if(HAVE_CUDA)
 911   status("")
 912   status("  NVIDIA CUDA")
 913
 914   status("    Use CUFFT:"            HAVE_CUFFT   THEN YES ELSE NO)
 915   status("    Use CUBLAS:"           HAVE_CUBLAS  THEN YES ELSE NO)
 916   status("    USE NVCUVID:"          HAVE_NVCUVID THEN YES ELSE NO)
 917   status("    NVIDIA GPU arch:"      ${OPENCV_CUDA_ARCH_BIN})
 918   status("    NVIDIA PTX archs:"     ${OPENCV_CUDA_ARCH_PTX})
 919   status("    Use fast math:"        CUDA_FAST_MATH THEN YES ELSE NO)
 920 endif()
 921
 922 if(HAVE_OPENCL)
 923   status("")
 924   status("  OpenCL:")
 925   if(HAVE_OPENCL_STATIC)
 926     set(__opencl_ver "static")
 927   else()
 928     set(__opencl_ver "dynamic")
 929   endif()
 930   status("    Version:"       ${__opencl_ver})
 931   if(OPENCL_INCLUDE_DIR)
 932     status("    Include path:"       ${OPENCL_INCLUDE_DIRS})
 933   endif()
 934   if(OPENCL_LIBRARIES)
 935     set(__libs "")
 936     foreach(l ${OPENCL_LIBRARIES})
 937       if(TARGET ${l})
 938         get_target_property(p ${l} LOCATION)
 939         if(p MATCHES NOTFOUND)
 940           list(APPEND __libs "${l}")
 941         else()
 942           list(APPEND __libs "${p}")
 943         endif()
 944       else()
 945         list(APPEND __libs "${l}")
 946       endif()
 947     endforeach()
 948     status("    libraries:"          ${__libs})
 949   endif()
 950   status("    Use AMD FFT:"          HAVE_CLAMDFFT  THEN YES ELSE NO)
 951   status("    Use AMD BLAS:"         HAVE_CLAMDBLAS THEN YES ELSE NO)
 952 endif()
 953
 954 # ========================== python ==========================
 955 status("")
 956 status("  Python:")
 957 status("    Interpreter:"     PYTHON_EXECUTABLE   THEN "${PYTHON_EXECUTABLE} (ver ${PYTHON_VERSION_FULL})"         ELSE NO)
 958 if(BUILD_opencv_python)
 959   if(PYTHONLIBS_VERSION_STRING)
 960     status("    Libraries:"   HAVE_opencv_python  THEN  "${PYTHON_LIBRARIES} (ver ${PYTHONLIBS_VERSION_STRING})"   ELSE NO)
 961   else()
 962     status("    Libraries:"   HAVE_opencv_python  THEN  ${PYTHON_LIBRARIES}                                        ELSE NO)
 963   endif()
 964   status("    numpy:"         PYTHON_USE_NUMPY    THEN "${PYTHON_NUMPY_INCLUDE_DIR} (ver ${PYTHON_NUMPY_VERSION})" ELSE "NO (Python wrappers can not be generated)")
 965   status("    packages path:" PYTHON_EXECUTABLE   THEN "${PYTHON_PACKAGES_PATH}"                                   ELSE "-")
 966 endif()
 967
 968 # ========================== java ==========================
 969 status("")
 970 status("  Java:")
 971 status("    ant:"           ANT_EXECUTABLE      THEN "${ANT_EXECUTABLE} (ver ${ANT_VERSION})"                    ELSE NO)
 972 if(NOT ANDROID)
 973   status("    JNI:"         JNI_INCLUDE_DIRS    THEN "${JNI_INCLUDE_DIRS}"                                       ELSE NO)
 974 endif()
 975 status("    Java tests:"    BUILD_TESTS AND (CAN_BUILD_ANDROID_PROJECTS OR HAVE_opencv_java)            THEN YES ELSE NO)
 976
 977 # ========================== documentation ==========================
 978 if(BUILD_DOCS)
 979   status("")
 980   status("  Documentation:")
 981   if(HAVE_SPHINX)
 982     status("    Build Documentation:" PDFLATEX_COMPILER      THEN YES ELSE "YES (only HTML and without math expressions)")
 983   else()
 984     status("    Build Documentation:" NO)
 985   endif()
 986   status("    Sphinx:"              HAVE_SPHINX              THEN "${SPHINX_BUILD} (ver ${SPHINX_VERSION})" ELSE NO)
 987   status("    PdfLaTeX compiler:"   PDFLATEX_COMPILER        THEN "${PDFLATEX_COMPILER}" ELSE NO)
 988 endif()
 989
 990 # ========================== samples and tests ==========================
 991 status("")
 992 status("  Tests and samples:")
 993 status("    Tests:"             BUILD_TESTS AND HAVE_opencv_ts       THEN YES ELSE NO)
 994 status("    Performance tests:" BUILD_PERF_TESTS AND HAVE_opencv_ts  THEN YES ELSE NO)
 995 status("    C/C++ Examples:"    BUILD_EXAMPLES                       THEN YES ELSE NO)
 996
 997 # ========================== auxiliary ==========================
 998 status("")
 999 status("  Install path:" "${CMAKE_INSTALL_PREFIX}")
1000 status("")
1001 status("  cvconfig.h is in:" "${OPENCV_CONFIG_FILE_INCLUDE_DIR}")
1002 status("-----------------------------------------------------------------")
1003 status("")
1004
1005 ocv_finalize_status()
1006
1007 # ----------------------------------------------------------------------------
1008 # Warn in the case of in-source build
1009 # ----------------------------------------------------------------------------
1010 if("${CMAKE_CURRENT_SOURCE_DIR}" STREQUAL "${CMAKE_CURRENT_BINARY_DIR}")
1011   message(WARNING "The source directory is the same as binary directory. \"make clean\" may damage the source tree")
1012 endif()
1013
1014 # ----------------------------------------------------------------------------
1015 # CPack stuff
1016 # ----------------------------------------------------------------------------
1017
1018 include(cmake/OpenCVPackaging.cmake)