CMakeLists.txt

   1 # dEQP cmake file
   2
   3 # Module FindGit requires cmake >= 2.8.2
   4 cmake_minimum_required(VERSION 3.0)
   5
   6 find_package(Git)
   7 find_package(PythonInterp 3)
   8
   9 # dEQP Target.
  10 set(DEQP_TARGET "default" CACHE STRING "dEQP Target (default, android...)")
  11
  12 if (DEFINED DEQP_TARGET_TOOLCHAIN)
  13         # \note Toolchain must be included before project() command
  14         include(targets/${DEQP_TARGET}/${DEQP_TARGET_TOOLCHAIN}.cmake NO_POLICY_SCOPE)
  15 endif ()
  16
  17 project(dEQP-Core-${DEQP_TARGET})
  18
  19 include(framework/delibs/cmake/Defs.cmake NO_POLICY_SCOPE)
  20 include(framework/delibs/cmake/CFlags.cmake)
  21
  22 add_definitions(-DDE_ASSERT_FAILURE_CALLBACK)
  23
  24 # dEQP-specific configuration. Target file should override these.
  25 set(DEQP_TARGET_NAME            "UNKNOWN")              # Target name
  26
  27 set(DEQP_GLES2_LIBRARIES        )                               # GLESv2 libraries. If empty, run-time linking is used
  28 set(DEQP_GLES3_LIBRARIES        )                               # GLESv3 libraries. If empty, run-time linking is used
  29 set(DEQP_EGL_LIBRARIES          )                               # EGL libraries
  30
  31 # Legacy APIs that don't use run-time loading
  32 set(DEQP_SUPPORT_GLES1          OFF)                    # Is GLESv1 supported
  33 set(DEQP_GLES1_LIBRARIES        )                               # GLESv1 libraries
  34 set(DEQP_SUPPORT_VG                     OFF)                    # Is OpenVG supported
  35 set(DEQP_VG_LIBRARIES           )                               # VG libraries
  36
  37 set(DEQP_SUPPORT_WGL            OFF)
  38 set(DEQP_SUPPORT_GLX            OFF)                    # Is GLX supported \todo [2016-10-12 pyry] X11 specific - move to framework/platform/
  39
  40 set(DEQP_PLATFORM_LIBRARIES     )                               # Other platform libraries
  41
  42 set(DEQP_PLATFORM_COPY_LIBRARIES        )               # Libraries / binaries that need to be copied to binary directory
  43
  44 # Delibs include directories
  45 include_directories(
  46         framework/delibs/debase
  47         framework/delibs/decpp
  48         framework/delibs/depool
  49         framework/delibs/dethread
  50         framework/delibs/deutil
  51         framework/delibs/destream
  52         )
  53
  54 # Include target-specific definitions
  55 include(targets/${DEQP_TARGET}/${DEQP_TARGET}.cmake)
  56
  57 # zlib
  58 find_path(ZLIB_INCLUDE_PATH     zlib.h)
  59 find_library(ZLIB_LIBRARY       z)
  60
  61 if (NOT ZLIB_INCLUDE_PATH OR NOT ZLIB_LIBRARY)
  62         message(STATUS "System version of zlib not found, using external/zlib")
  63         add_subdirectory(external/zlib)
  64         # \note ZLIB_LIBRARY and ZLIB_INCLUDE_PATH are promoted from external/zlib/CMakeLists.txt
  65 endif ()
  66
  67 include_directories(${ZLIB_INCLUDE_PATH})
  68
  69 # libpng
  70 #
  71 # The FindPNG module defines PNG_INCLUDE_DIRS and PNG_LIBRARIES. But dEQP's
  72 # CMake files expect the non-standard PNG_INCLUDE_PATH and PNG_LIBRARY. Set the
  73 # non-standard variables here to retain compatibility with dEQP's existing
  74 # CMake files.
  75 include(FindPNG)
  76 set(PNG_INCLUDE_PATH ${PNG_INCLUDE_DIRS})
  77 set(PNG_LIBRARY ${PNG_LIBRARIES})
  78
  79 if (NOT PNG_INCLUDE_PATH OR NOT PNG_LIBRARY)
  80         message(STATUS "System version of libpng not found, using external/libpng")
  81         add_subdirectory(external/libpng)
  82         # \note PNG_LIBRARY and PNG_INCLUDE_PATH are promoted from external/libpng/CMakeLists.txt
  83 endif ()
  84
  85 # glslang
  86 add_subdirectory(external/glslang)
  87
  88 # spirv-tools
  89 add_subdirectory(external/spirv-tools)
  90
  91 # spirv-headers
  92 set(SPIRV_INCLUDE_PATH "${PROJECT_SOURCE_DIR}/external/spirv-headers/src/include")
  93 if (NOT EXISTS ${SPIRV_INCLUDE_PATH})
  94         message(FATAL_ERROR "SPIR-V headers not found, please run external/fetch_sources.py")
  95 endif()
  96 include_directories(${SPIRV_INCLUDE_PATH})
  97
  98 # Amber
  99 add_subdirectory(external/amber)
 100 include_directories(external/amber)
 101
 102 # RenderDoc API
 103 include_directories(external/renderdoc/src)
 104
 105 include_directories(${PNG_INCLUDE_PATH})
 106
 107 message(STATUS "DEQP_TARGET_NAME        = ${DEQP_TARGET_NAME}")
 108 message(STATUS "DEQP_SUPPORT_GLES1      = ${DEQP_SUPPORT_GLES1}")
 109 message(STATUS "DEQP_GLES1_LIBRARIES    = ${DEQP_GLES1_LIBRARIES}")
 110 message(STATUS "DEQP_GLES2_LIBRARIES    = ${DEQP_GLES2_LIBRARIES}")
 111 message(STATUS "DEQP_GLES3_LIBRARIES    = ${DEQP_GLES3_LIBRARIES}")
 112 message(STATUS "DEQP_GLES31_LIBRARIES   = ${DEQP_GLES31_LIBRARIES}")
 113 message(STATUS "DEQP_GLES32_LIBRARIES   = ${DEQP_GLES32_LIBRARIES}")
 114 message(STATUS "DEQP_SUPPORT_VG         = ${DEQP_SUPPORT_VG}")
 115 message(STATUS "DEQP_VG_LIBRARIES       = ${DEQP_VG_LIBRARIES}")
 116 message(STATUS "DEQP_EGL_LIBRARIES      = ${DEQP_EGL_LIBRARIES}")
 117 message(STATUS "DEQP_PLATFORM_LIBRARIES = ${DEQP_PLATFORM_LIBRARIES}")
 118
 119 # Defines
 120 add_definitions(-DDEQP_TARGET_NAME="${DEQP_TARGET_NAME}")
 121
 122 # Entry points loaded directly by linking to libGL*?
 123 if (DEFINED DEQP_GLES2_LIBRARIES)
 124         add_definitions(-DDEQP_GLES2_DIRECT_LINK=1)
 125 endif ()
 126
 127 if (DEFINED DEQP_GLES3_LIBRARIES)
 128         add_definitions(-DDEQP_GLES3_DIRECT_LINK=1)
 129 endif ()
 130
 131 if (DEFINED DEQP_GLES31_LIBRARIES)
 132         add_definitions(-DDEQP_GLES31_DIRECT_LINK=1)
 133 endif ()
 134
 135 if (DEFINED DEQP_GLES32_LIBRARIES)
 136         add_definitions(-DDEQP_GLES32_DIRECT_LINK=1)
 137 endif ()
 138
 139 if (DEFINED DEQP_EGL_LIBRARIES)
 140         add_definitions(-DDEQP_EGL_DIRECT_LINK=1)
 141 endif ()
 142
 143 # Legacy APIs that don't support run-time loading
 144 if (DEQP_SUPPORT_GLES1)
 145         add_definitions(-DDEQP_SUPPORT_GLES1=1)
 146
 147         if (NOT DEFINED DEQP_GLES1_LIBRARIES)
 148                 message(FATAL_ERROR "Run-time loading of GLES1 is not supported (DEQP_GLES1_LIBRARIES is not set)")
 149         endif ()
 150 endif ()
 151
 152 if (DEQP_SUPPORT_VG)
 153         add_definitions(-DDEQP_SUPPORT_VG=1)
 154
 155         if (NOT DEFINED DEQP_VG_LIBRARIES)
 156                 message(FATAL_ERROR "Run-time loading of VG is not supported (DEQP_VG_LIBRARIES is not set)")
 157         endif ()
 158 endif ()
 159
 160 if (DE_COMPILER_IS_MSC)
 161         # Don't nag about std::copy for example
 162         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -D_SCL_SECURE_NO_WARNINGS")
 163 endif ()
 164
 165 # Precompiled header macro. Parameters are source file list and filename for pch cpp file.
 166 macro(PCH SRCS PCHCPP)
 167   if(MSVC AND CMAKE_GENERATOR MATCHES "^Visual Studio")
 168     set(PCH_NAME "$(IntDir)\\pch.pch")
 169     # make source files use/depend on PCH_NAME
 170     set_source_files_properties(${${SRCS}} PROPERTIES COMPILE_FLAGS "/Yupch.h /FIpch.h /Fp${PCH_NAME}" OBJECT_DEPENDS "${PCH_NAME}")
 171     # make PCHCPP file compile and generate PCH_NAME
 172     set_source_files_properties(${PCHCPP} PROPERTIES COMPILE_FLAGS "/Ycpch.h /Fp${PCH_NAME}" OBJECT_OUTPUTS "${PCH_NAME}")
 173     list(APPEND ${SRCS} "${PCHCPP}")
 174   endif()
 175 endmacro(PCH)
 176
 177 # delibs projects
 178 add_subdirectory(framework/delibs/debase)
 179 add_subdirectory(framework/delibs/depool)
 180 add_subdirectory(framework/delibs/dethread)
 181 add_subdirectory(framework/delibs/destream)
 182 add_subdirectory(framework/delibs/deutil)
 183 add_subdirectory(framework/delibs/decpp)
 184
 185 # ExecServer
 186 add_subdirectory(execserver)
 187
 188 # Executor framework and tools
 189 if (IS_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}/executor)
 190         add_subdirectory(executor)
 191 endif ()
 192
 193 # Test framework include directories
 194 include_directories(
 195         framework/common
 196         framework/qphelper
 197         framework/opengl
 198         framework/opengl/wrapper
 199         framework/referencerenderer
 200         framework/opengl/simplereference
 201         framework/randomshaders
 202         framework/egl
 203         framework/egl/wrapper
 204         external/vulkancts/framework/vulkan
 205         )
 206
 207 if (DE_OS_IS_ANDROID OR DE_OS_IS_IOS)
 208         # On Android deqp modules are compiled as libraries and linked into final .so
 209         set(DEQP_MODULE_LIBRARIES )
 210         set(DEQP_MODULE_ENTRY_POINTS )
 211 endif ()
 212
 213 # Macro for adding targets for copying binaries (usually target libraries) to the target destination dir
 214 macro (target_copy_files target dep_name files)
 215         if (NOT "${files}" STREQUAL "")
 216                 set(COPY_TARGETS )
 217                 foreach (SRCNAME ${files})
 218                         get_filename_component(BASENAME ${SRCNAME} NAME)
 219                         set(DSTNAME "${CMAKE_CURRENT_BINARY_DIR}/${BASENAME}")
 220                         add_custom_command(OUTPUT ${DSTNAME}
 221                                                            COMMAND ${CMAKE_COMMAND} -E copy_if_different ${SRCNAME} ${DSTNAME})
 222                         set(COPY_TARGETS ${COPY_TARGETS} ${DSTNAME})
 223                 endforeach ()
 224
 225                 add_custom_target(${dep_name} ALL DEPENDS ${COPY_TARGETS})
 226                 add_dependencies(${target} ${dep_name})
 227         endif ()
 228 endmacro (target_copy_files)
 229
 230 set(MODULE_LIB_TARGET_POSTFIX   "-package")
 231 set(MODULE_DATA_TARGET_POSTFIX  "-data")
 232
 233 # Macro for adding dEQP module
 234 # This adds 3 targets:
 235 #       ${MODULE_NAME}-package:         Static library that contains all SRCS and links to LIBS
 236 #       ${MODULE_NAME}-data:            Custom target that is used for data file copies
 237 #       ${MODULE_NAME}:                         Executable binary (if supported by the platform)
 238 macro (add_deqp_module MODULE_NAME SRCS LIBS ENTRY)
 239
 240         # Library target
 241         add_library("${MODULE_NAME}${MODULE_LIB_TARGET_POSTFIX}" STATIC ${SRCS})
 242         target_link_libraries("${MODULE_NAME}${MODULE_LIB_TARGET_POSTFIX}" ${LIBS})
 243
 244         set(DEQP_MODULE_LIBRARIES               ${DEQP_MODULE_LIBRARIES} "${MODULE_NAME}${MODULE_LIB_TARGET_POSTFIX}")
 245         set(DEQP_MODULE_ENTRY_POINTS    ${DEQP_MODULE_ENTRY_POINTS} "${CMAKE_CURRENT_SOURCE_DIR}/${ENTRY}")
 246
 247         # Forward to parent scope
 248         set(DEQP_MODULE_LIBRARIES               ${DEQP_MODULE_LIBRARIES} PARENT_SCOPE)
 249         set(DEQP_MODULE_ENTRY_POINTS    ${DEQP_MODULE_ENTRY_POINTS} PARENT_SCOPE)
 250
 251         if (NOT DE_OS_IS_ANDROID AND NOT DE_OS_IS_IOS)
 252                 # Executable target
 253                 add_executable(${MODULE_NAME} ${PROJECT_SOURCE_DIR}/framework/platform/tcuMain.cpp ${ENTRY})
 254                 target_link_libraries(${MODULE_NAME} tcutil-platform "${MODULE_NAME}${MODULE_LIB_TARGET_POSTFIX}")
 255                 target_copy_files(${MODULE_NAME} platform-libs-${MODULE_NAME} "${DEQP_PLATFORM_COPY_LIBRARIES}")
 256         endif ()
 257
 258         # Data file target
 259         add_custom_target("${MODULE_NAME}${MODULE_DATA_TARGET_POSTFIX}")
 260         add_dependencies("${MODULE_NAME}${MODULE_LIB_TARGET_POSTFIX}" "${MODULE_NAME}${MODULE_DATA_TARGET_POSTFIX}")
 261 endmacro (add_deqp_module)
 262
 263 # Macro for adding data dirs to module
 264 macro (add_data_dir MODULE_NAME SRC_DIR DST_DIR)
 265         if (DE_OS_IS_WIN32 OR DE_OS_IS_UNIX OR DE_OS_IS_OSX OR DE_OS_IS_QNX)
 266                 add_custom_command(TARGET "${MODULE_NAME}${MODULE_DATA_TARGET_POSTFIX}" POST_BUILD COMMAND ${CMAKE_COMMAND} -E copy_directory ${CMAKE_CURRENT_SOURCE_DIR}/${SRC_DIR} ${CMAKE_CURRENT_BINARY_DIR}/${DST_DIR})
 267
 268         elseif (DE_OS_IS_ANDROID)
 269                 add_custom_command(TARGET "${MODULE_NAME}${MODULE_DATA_TARGET_POSTFIX}" POST_BUILD COMMAND ${CMAKE_COMMAND} -E copy_directory ${CMAKE_CURRENT_SOURCE_DIR}/${SRC_DIR} ${CMAKE_BINARY_DIR}/assets/${DST_DIR})
 270
 271         elseif (DE_OS_IS_IOS)
 272                 add_custom_command(TARGET "${MODULE_NAME}${MODULE_DATA_TARGET_POSTFIX}" POST_BUILD COMMAND ${CMAKE_COMMAND} -E copy_directory ${CMAKE_CURRENT_SOURCE_DIR}/${SRC_DIR} ${CMAKE_BINARY_DIR}/\${CONFIGURATION}\${EFFECTIVE_PLATFORM_NAME}/deqp.app/${DST_DIR})
 273         endif ()
 274 endmacro (add_data_dir)
 275
 276 # Macro for adding individual data files to module
 277 macro (add_data_file MODULE_NAME SRC_FILE DST_FILE)
 278         if (DE_OS_IS_WIN32 OR DE_OS_IS_UNIX OR DE_OS_IS_OSX OR DE_OS_IS_QNX)
 279                 add_custom_command(TARGET "${MODULE_NAME}${MODULE_DATA_TARGET_POSTFIX}" POST_BUILD COMMAND ${CMAKE_COMMAND} -E copy_if_different ${CMAKE_CURRENT_SOURCE_DIR}/${SRC_FILE} ${CMAKE_CURRENT_BINARY_DIR}/${DST_FILE})
 280
 281         elseif (DE_OS_IS_ANDROID)
 282                 add_custom_command(TARGET "${MODULE_NAME}${MODULE_DATA_TARGET_POSTFIX}" POST_BUILD COMMAND ${CMAKE_COMMAND} -E copy_if_different ${CMAKE_CURRENT_SOURCE_DIR}/${SRC_FILE} ${CMAKE_BINARY_DIR}/assets/${DST_FILE})
 283
 284         elseif (DE_OS_IS_IOS)
 285                 add_custom_command(TARGET "${MODULE_NAME}${MODULE_DATA_TARGET_POSTFIX}" POST_BUILD COMMAND ${CMAKE_COMMAND} -E copy_if_different ${CMAKE_CURRENT_SOURCE_DIR}/${SRC_FILE} ${CMAKE_BINARY_DIR}/\${CONFIGURATION}\${EFFECTIVE_PLATFORM_NAME}/deqp.app/${DST_FILE})
 286         endif ()
 287 endmacro (add_data_file)
 288
 289 add_subdirectory(framework)
 290 add_subdirectory(external/vulkancts/framework/vulkan)
 291
 292 if (DE_COMPILER_IS_MSC)
 293         add_compile_options(/bigobj) # Required by glsBuiltinPrecisionTests.cpp
 294 endif ()
 295
 296 add_subdirectory(modules)
 297 add_subdirectory(external/vulkancts/modules/vulkan)
 298 add_subdirectory(external/openglcts)
 299
 300 # Single-binary targets
 301 if (DE_OS_IS_ANDROID)
 302         include_directories(executor)
 303
 304         set(DEQP_SRCS
 305                 framework/platform/android/tcuAndroidMain.cpp
 306                 framework/platform/android/tcuAndroidJNI.cpp
 307                 framework/platform/android/tcuAndroidPlatformCapabilityQueryJNI.cpp
 308                 framework/platform/android/tcuTestLogParserJNI.cpp
 309                 ${DEQP_MODULE_ENTRY_POINTS}
 310                 )
 311
 312         set(DEQP_LIBS
 313                 tcutil-platform
 314                 xecore
 315                 ${DEQP_MODULE_LIBRARIES}
 316                 )
 317
 318         add_library(deqp SHARED ${DEQP_SRCS})
 319         target_link_libraries(deqp ${DEQP_LIBS})
 320
 321         # Separate out the debug information because it's enormous
 322         add_custom_command(TARGET deqp POST_BUILD
 323                 COMMAND ${CMAKE_STRIP} --only-keep-debug -o $<TARGET_FILE:deqp>.debug $<TARGET_FILE:deqp>
 324                 COMMAND ${CMAKE_STRIP} -g $<TARGET_FILE:deqp>)
 325
 326         # Needed by OpenGL CTS that defines its own activity but depends on
 327         # common Android support code.
 328         target_include_directories(deqp PRIVATE framework/platform/android)
 329
 330 elseif (DE_OS_IS_IOS)
 331         # Code sign identity
 332         set(DEQP_IOS_CODE_SIGN_IDENTITY "drawElements" CACHE STRING "Code sign identity for iOS build")
 333
 334         set(MACOSX_BUNDLE_PRODUCT_NAME "\${PRODUCT_NAME}")
 335         set(MACOSX_BUNDLE_GUI_IDENTIFIER "com.drawelements.\${PRODUCT_NAME:identifier}")
 336
 337         include_directories(framework/platform/ios)
 338         set(TESTERCORE_SRC_FILES
 339                 framework/platform/ios/tcuEAGLView.h
 340                 framework/platform/ios/tcuEAGLView.m
 341                 framework/platform/ios/tcuIOSAppDelegate.h
 342                 framework/platform/ios/tcuIOSAppDelegate.m
 343                 framework/platform/ios/tcuIOSViewController.h
 344                 framework/platform/ios/tcuIOSViewController.m
 345                 framework/platform/ios/tcuIOSMain.m
 346                 )
 347         set_source_files_properties(${TESTERCORE_SRC_FILES} COMPILE_FLAGS "-std=c99")
 348
 349         add_executable(deqp MACOSX_BUNDLE ${TESTERCORE_SRC_FILES} ${DEQP_MODULE_ENTRY_POINTS})
 350         target_link_libraries(deqp tcutil-platform xscore ${DEQP_MODULE_LIBRARIES})
 351         set_target_properties(deqp PROPERTIES XCODE_ATTRIBUTE_TARGETED_DEVICE_FAMILY "1,2")
 352         set_target_properties(deqp PROPERTIES XCODE_ATTRIBUTE_CODE_SIGN_IDENTITY "iPhone Developer: ${DEQP_IOS_CODE_SIGN_IDENTITY}")
 353 endif ()