CMakeLists.txt

   1 # ----------------------------------------------------------------------------
   2 #  Root CMake file for OpenCV
   3 #
   4 #    From the off-tree build directory, invoke:
   5 #      $ cmake <PATH_TO_OPENCV_ROOT>
   6 #
   7 # ----------------------------------------------------------------------------
   8
   9 include(cmake/OpenCVMinDepVersions.cmake)
  10
  11 if(CMAKE_GENERATOR MATCHES Xcode AND XCODE_VERSION VERSION_GREATER 4.3)
  12   cmake_minimum_required(VERSION 2.8.8 FATAL_ERROR)
  13 else()
  14   cmake_minimum_required(VERSION "${MIN_VER_CMAKE}" FATAL_ERROR)
  15 endif()
  16
  17 # Following block can broke build in case of cross-compilng
  18 # but CMAKE_CROSSCOMPILING variable will be set only on project(OpenCV) command
  19 # so we will try to detect crosscompiling by presense of CMAKE_TOOLCHAIN_FILE
  20 if(NOT CMAKE_TOOLCHAIN_FILE)
  21   # it _must_ go before project(OpenCV) in order to work
  22   if(WIN32)
  23     set(CMAKE_INSTALL_PREFIX "${CMAKE_BINARY_DIR}/install" CACHE PATH "Installation Directory")
  24   else()
  25     set(CMAKE_INSTALL_PREFIX "/usr/local" CACHE PATH "Installation Directory")
  26   endif()
  27 else(NOT CMAKE_TOOLCHAIN_FILE)
  28   #Android: set output folder to ${CMAKE_BINARY_DIR}
  29   set( LIBRARY_OUTPUT_PATH_ROOT ${CMAKE_BINARY_DIR} CACHE PATH "root for library output, set this to change where android libs are compiled to" )
  30   # any crosscompiling
  31   set(CMAKE_INSTALL_PREFIX "${CMAKE_BINARY_DIR}/install" CACHE PATH "Installation Directory")
  32 endif(NOT CMAKE_TOOLCHAIN_FILE)
  33
  34
  35 if(POLICY CMP0022)
  36   cmake_policy(SET CMP0022 OLD)
  37 endif()
  38
  39 # must go before the project command
  40 set(CMAKE_CONFIGURATION_TYPES "Debug;Release" CACHE STRING "Configs" FORCE)
  41 if(DEFINED CMAKE_BUILD_TYPE)
  42   set_property( CACHE CMAKE_BUILD_TYPE PROPERTY STRINGS ${CMAKE_CONFIGURATION_TYPES} )
  43 endif()
  44
  45 project(OpenCV CXX C)
  46
  47 if(MSVC)
  48   set(CMAKE_USE_RELATIVE_PATHS ON CACHE INTERNAL "" FORCE)
  49 endif()
  50
  51 include(cmake/OpenCVUtils.cmake)
  52
  53 ocv_clear_vars(OpenCVModules_TARGETS)
  54
  55 # ----------------------------------------------------------------------------
  56 # Break in case of popular CMake configuration mistakes
  57 # ----------------------------------------------------------------------------
  58 if(NOT CMAKE_SIZEOF_VOID_P GREATER 0)
  59   message(FATAL_ERROR "CMake fails to deterimine the bitness of target platform.
  60   Please check your CMake and compiler installation. If you are crosscompiling then ensure that your CMake toolchain file correctly sets the compiler details.")
  61 endif()
  62
  63 # ----------------------------------------------------------------------------
  64 # Detect compiler and target platform architecture
  65 # ----------------------------------------------------------------------------
  66 include(cmake/OpenCVDetectCXXCompiler.cmake)
  67
  68 # Add these standard paths to the search paths for FIND_LIBRARY
  69 # to find libraries from these locations first
  70 if(UNIX AND NOT ANDROID)
  71   if(X86_64 OR CMAKE_SIZEOF_VOID_P EQUAL 8)
  72     if(EXISTS /lib64)
  73       list(APPEND CMAKE_LIBRARY_PATH /lib64)
  74     else()
  75       list(APPEND CMAKE_LIBRARY_PATH /lib)
  76     endif()
  77     if(EXISTS /usr/lib64)
  78       list(APPEND CMAKE_LIBRARY_PATH /usr/lib64)
  79     else()
  80       list(APPEND CMAKE_LIBRARY_PATH /usr/lib)
  81     endif()
  82   elseif(X86 OR CMAKE_SIZEOF_VOID_P EQUAL 4)
  83     if(EXISTS /lib32)
  84       list(APPEND CMAKE_LIBRARY_PATH /lib32)
  85     else()
  86       list(APPEND CMAKE_LIBRARY_PATH /lib)
  87     endif()
  88     if(EXISTS /usr/lib32)
  89       list(APPEND CMAKE_LIBRARY_PATH /usr/lib32)
  90     else()
  91       list(APPEND CMAKE_LIBRARY_PATH /usr/lib)
  92     endif()
  93   endif()
  94 endif()
  95
  96 # Add these standard paths to the search paths for FIND_PATH
  97 # to find include files from these locations first
  98 if(MINGW)
  99   if(EXISTS /mingw)
 100       list(APPEND CMAKE_INCLUDE_PATH /mingw)
 101   endif()
 102   if(EXISTS /mingw32)
 103       list(APPEND CMAKE_INCLUDE_PATH /mingw32)
 104   endif()
 105   if(EXISTS /mingw64)
 106       list(APPEND CMAKE_INCLUDE_PATH /mingw64)
 107   endif()
 108 endif()
 109
 110 # ----------------------------------------------------------------------------
 111 # OpenCV cmake options
 112 # ----------------------------------------------------------------------------
 113
 114 # Optional 3rd party components
 115 # ===================================================
 116 OCV_OPTION(WITH_1394           "Include IEEE1394 support"                    ON   IF (NOT ANDROID AND NOT IOS) )
 117 OCV_OPTION(WITH_AVFOUNDATION   "Use AVFoundation for Video I/O"              ON   IF IOS)
 118 OCV_OPTION(WITH_CARBON         "Use Carbon for UI instead of Cocoa"          OFF  IF APPLE )
 119 OCV_OPTION(WITH_VTK            "Include VTK library support (and build opencv_viz module eiher)"             OFF IF (NOT ANDROID AND NOT IOS) )
 120 OCV_OPTION(WITH_CUDA           "Include NVidia Cuda Runtime support"                                         ON  IF (NOT IOS) )
 121 OCV_OPTION(WITH_CUFFT          "Include NVidia Cuda Fast Fourier Transform (FFT) library support"            ON  IF (NOT IOS) )
 122 OCV_OPTION(WITH_CUBLAS         "Include NVidia Cuda Basic Linear Algebra Subprograms (BLAS) library support" OFF IF (NOT IOS) )
 123 OCV_OPTION(WITH_NVCUVID        "Include NVidia Video Decoding library support"                               OFF IF (NOT IOS AND NOT APPLE) )
 124 OCV_OPTION(WITH_EIGEN          "Include Eigen2/Eigen3 support"               ON)
 125 OCV_OPTION(WITH_VFW            "Include Video for Windows support"           ON   IF WIN32 )
 126 OCV_OPTION(WITH_FFMPEG         "Include FFMPEG support"                      ON   IF (NOT ANDROID AND NOT IOS))
 127 OCV_OPTION(WITH_GSTREAMER      "Include Gstreamer support"                   ON   IF (UNIX AND NOT APPLE AND NOT ANDROID) )
 128 OCV_OPTION(WITH_GSTREAMER_0_10 "Enable Gstreamer 0.10 support (instead of 1.x)"                              OFF )
 129 OCV_OPTION(WITH_GTK            "Include GTK support"                         ON   IF (UNIX AND NOT APPLE AND NOT ANDROID) )
 130 OCV_OPTION(WITH_IPP            "Include Intel IPP support"                   OFF  IF (MSVC OR X86 OR X86_64) )
 131 OCV_OPTION(WITH_JASPER         "Include JPEG2K support"                      ON   IF (NOT IOS) )
 132 OCV_OPTION(WITH_JPEG           "Include JPEG support"                        ON)
 133 OCV_OPTION(WITH_WEBP           "Include WebP support"                        ON   IF (NOT IOS) )
 134 OCV_OPTION(WITH_OPENEXR        "Include ILM support via OpenEXR"             ON   IF (NOT IOS) )
 135 OCV_OPTION(WITH_OPENGL         "Include OpenGL support"                      OFF  IF (NOT ANDROID AND NOT APPLE) )
 136 OCV_OPTION(WITH_OPENNI         "Include OpenNI support"                      OFF  IF (NOT ANDROID AND NOT IOS) )
 137 OCV_OPTION(WITH_PNG            "Include PNG support"                         ON)
 138 OCV_OPTION(WITH_PVAPI          "Include Prosilica GigE support"              ON   IF (NOT ANDROID AND NOT IOS) )
 139 OCV_OPTION(WITH_GIGEAPI        "Include Smartek GigE support"                ON   IF (NOT ANDROID AND NOT IOS) )
 140 OCV_OPTION(WITH_QT             "Build with Qt Backend support"               OFF  IF (NOT ANDROID AND NOT IOS) )
 141 OCV_OPTION(WITH_WIN32UI        "Build with Win32 UI Backend support"         ON   IF WIN32 )
 142 OCV_OPTION(WITH_QUICKTIME      "Use QuickTime for Video I/O insted of QTKit" OFF  IF APPLE )
 143 OCV_OPTION(WITH_TBB            "Include Intel TBB support"                   OFF  IF (NOT IOS) )
 144 OCV_OPTION(WITH_OPENMP         "Include OpenMP support"                      OFF)
 145 OCV_OPTION(WITH_CSTRIPES       "Include C= support"                          OFF  IF WIN32 )
 146 OCV_OPTION(WITH_TIFF           "Include TIFF support"                        ON   IF (NOT IOS) )
 147 OCV_OPTION(WITH_UNICAP         "Include Unicap support (GPL)"                OFF  IF (UNIX AND NOT APPLE AND NOT ANDROID) )
 148 OCV_OPTION(WITH_V4L            "Include Video 4 Linux support"               ON   IF (UNIX AND NOT ANDROID) )
 149 OCV_OPTION(WITH_LIBV4L         "Use libv4l for Video 4 Linux support"        ON   IF (UNIX AND NOT ANDROID) )
 150 OCV_OPTION(WITH_DSHOW          "Build HighGUI with DirectShow support"       ON   IF (WIN32 AND NOT ARM) )
 151 OCV_OPTION(WITH_MSMF           "Build HighGUI with Media Foundation support" OFF  IF WIN32 )
 152 OCV_OPTION(WITH_XIMEA          "Include XIMEA cameras support"               OFF  IF (NOT ANDROID AND NOT APPLE) )
 153 OCV_OPTION(WITH_XINE           "Include Xine support (GPL)"                  OFF  IF (UNIX AND NOT APPLE AND NOT ANDROID) )
 154 OCV_OPTION(WITH_CLP            "Include Clp support (EPL)"                   OFF)
 155 OCV_OPTION(WITH_OPENCL         "Include OpenCL Runtime support"              ON   IF (NOT IOS) )
 156 OCV_OPTION(WITH_OPENCLAMDFFT   "Include AMD OpenCL FFT library support"      ON   IF (NOT ANDROID AND NOT IOS) )
 157 OCV_OPTION(WITH_OPENCLAMDBLAS  "Include AMD OpenCL BLAS library support"     ON   IF (NOT ANDROID AND NOT IOS) )
 158 OCV_OPTION(WITH_DIRECTX        "Include DirectX support"                     ON   IF WIN32 )
 159 OCV_OPTION(WITH_INTELPERC      "Include Intel Perceptual Computing support"  OFF  IF WIN32 )
 160
 161
 162 # OpenCV build components
 163 # ===================================================
 164 OCV_OPTION(BUILD_SHARED_LIBS        "Build shared libraries (.dll/.so) instead of static ones (.lib/.a)" NOT (ANDROID OR IOS) )
 165 OCV_OPTION(BUILD_opencv_apps        "Build utility applications (used for example to train classifiers)" (NOT ANDROID) IF (NOT IOS) )
 166 OCV_OPTION(BUILD_ANDROID_EXAMPLES   "Build examples for Android platform"         ON  IF ANDROID )
 167 OCV_OPTION(BUILD_DOCS               "Create build rules for OpenCV Documentation" ON )
 168 OCV_OPTION(BUILD_EXAMPLES           "Build all examples"                          OFF )
 169 OCV_OPTION(BUILD_PACKAGE            "Enables 'make package_source' command"       ON )
 170 OCV_OPTION(BUILD_PERF_TESTS         "Build performance tests"                     ON  IF (NOT IOS) )
 171 OCV_OPTION(BUILD_TESTS              "Build accuracy & regression tests"           ON  IF (NOT IOS) )
 172 OCV_OPTION(BUILD_WITH_DEBUG_INFO    "Include debug info into debug libs (not MSCV only)" ON )
 173 OCV_OPTION(BUILD_WITH_STATIC_CRT    "Enables use of staticaly linked CRT for staticaly linked OpenCV" ON IF MSVC )
 174 OCV_OPTION(BUILD_FAT_JAVA_LIB       "Create fat java wrapper containing the whole OpenCV library" ON IF NOT BUILD_SHARED_LIBS AND CMAKE_COMPILER_IS_GNUCXX )
 175 OCV_OPTION(BUILD_ANDROID_SERVICE    "Build OpenCV Manager for Google Play" OFF IF ANDROID AND ANDROID_SOURCE_TREE )
 176 OCV_OPTION(BUILD_ANDROID_PACKAGE    "Build platform-specific package for Google Play" OFF IF ANDROID )
 177
 178 # 3rd party libs
 179 OCV_OPTION(BUILD_ZLIB               "Build zlib from source"             WIN32 OR APPLE )
 180 OCV_OPTION(BUILD_TIFF               "Build libtiff from source"          WIN32 OR ANDROID OR APPLE )
 181 OCV_OPTION(BUILD_JASPER             "Build libjasper from source"        WIN32 OR ANDROID OR APPLE )
 182 OCV_OPTION(BUILD_JPEG               "Build libjpeg from source"          WIN32 OR ANDROID OR APPLE )
 183 OCV_OPTION(BUILD_PNG                "Build libpng from source"           WIN32 OR ANDROID OR APPLE )
 184 OCV_OPTION(BUILD_OPENEXR            "Build openexr from source"          WIN32 OR ANDROID OR APPLE )
 185 OCV_OPTION(BUILD_TBB                "Download and build TBB from source" ANDROID )
 186
 187 # OpenCV installation options
 188 # ===================================================
 189 OCV_OPTION(INSTALL_CREATE_DISTRIB   "Change install rules to build the distribution package" OFF )
 190 OCV_OPTION(INSTALL_C_EXAMPLES       "Install C examples"        OFF )
 191 OCV_OPTION(INSTALL_PYTHON_EXAMPLES  "Install Python examples"   OFF )
 192 OCV_OPTION(INSTALL_ANDROID_EXAMPLES "Install Android examples"  OFF IF ANDROID )
 193 OCV_OPTION(INSTALL_TO_MANGLED_PATHS "Enables mangled install paths, that help with side by side installs." OFF IF (UNIX AND NOT ANDROID AND NOT IOS AND BUILD_SHARED_LIBS) )
 194
 195
 196 # OpenCV build options
 197 # ===================================================
 198 OCV_OPTION(ENABLE_PRECOMPILED_HEADERS "Use precompiled headers"                                  ON   IF (NOT IOS) )
 199 OCV_OPTION(ENABLE_SOLUTION_FOLDERS    "Solution folder in Visual Studio or in other IDEs"        (MSVC_IDE OR CMAKE_GENERATOR MATCHES Xcode) )
 200 OCV_OPTION(ENABLE_PROFILING           "Enable profiling in the GCC compiler (Add flags: -g -pg)" OFF  IF CMAKE_COMPILER_IS_GNUCXX )
 201 OCV_OPTION(ENABLE_OMIT_FRAME_POINTER  "Enable -fomit-frame-pointer for GCC"                      ON   IF CMAKE_COMPILER_IS_GNUCXX AND NOT (APPLE AND CMAKE_COMPILER_IS_CLANGCXX) )
 202 OCV_OPTION(ENABLE_POWERPC             "Enable PowerPC for GCC"                                   ON   IF (CMAKE_COMPILER_IS_GNUCXX AND CMAKE_SYSTEM_PROCESSOR MATCHES powerpc.*) )
 203 OCV_OPTION(ENABLE_FAST_MATH           "Enable -ffast-math (not recommended for GCC 4.6.x)"       OFF  IF (CMAKE_COMPILER_IS_GNUCXX AND (X86 OR X86_64)) )
 204 OCV_OPTION(ENABLE_SSE                 "Enable SSE instructions"                                  ON   IF ((MSVC OR CMAKE_COMPILER_IS_GNUCXX) AND (X86 OR X86_64)) )
 205 OCV_OPTION(ENABLE_SSE2                "Enable SSE2 instructions"                                 ON   IF ((MSVC OR CMAKE_COMPILER_IS_GNUCXX) AND (X86 OR X86_64)) )
 206 OCV_OPTION(ENABLE_SSE3                "Enable SSE3 instructions"                                 ON   IF ((CV_ICC OR CMAKE_COMPILER_IS_GNUCXX) AND (X86 OR X86_64)) )
 207 OCV_OPTION(ENABLE_SSSE3               "Enable SSSE3 instructions"                                OFF  IF (CMAKE_COMPILER_IS_GNUCXX AND (X86 OR X86_64)) )
 208 OCV_OPTION(ENABLE_SSE41               "Enable SSE4.1 instructions"                               OFF  IF ((CV_ICC OR CMAKE_COMPILER_IS_GNUCXX) AND (X86 OR X86_64)) )
 209 OCV_OPTION(ENABLE_SSE42               "Enable SSE4.2 instructions"                               OFF  IF (CMAKE_COMPILER_IS_GNUCXX AND (X86 OR X86_64)) )
 210 OCV_OPTION(ENABLE_AVX                 "Enable AVX instructions"                                  OFF  IF ((MSVC OR CMAKE_COMPILER_IS_GNUCXX) AND (X86 OR X86_64)) )
 211 OCV_OPTION(ENABLE_NEON                "Enable NEON instructions"                                 OFF  IF CMAKE_COMPILER_IS_GNUCXX AND ARM )
 212 OCV_OPTION(ENABLE_VFPV3               "Enable VFPv3-D32 instructions"                            OFF  IF CMAKE_COMPILER_IS_GNUCXX AND ARM )
 213 OCV_OPTION(ENABLE_NOISY_WARNINGS      "Show all warnings even if they are too noisy"             OFF )
 214 OCV_OPTION(OPENCV_WARNINGS_ARE_ERRORS "Treat warnings as errors"                                 OFF )
 215 OCV_OPTION(ENABLE_WINRT_MODE          "Build with Windows Runtime support"                       OFF  IF WIN32 )
 216
 217
 218 # ----------------------------------------------------------------------------
 219 #  Get actual OpenCV version number from sources
 220 # ----------------------------------------------------------------------------
 221 include(cmake/OpenCVVersion.cmake)
 222
 223
 224 # ----------------------------------------------------------------------------
 225 #  Build & install layouts
 226 # ----------------------------------------------------------------------------
 227
 228 # Save libs and executables in the same place
 229 set(EXECUTABLE_OUTPUT_PATH "${CMAKE_BINARY_DIR}/bin" CACHE PATH "Output directory for applications" )
 230
 231 if (ANDROID)
 232   if (ANDROID_ABI MATCHES "NEON")
 233     set(ENABLE_NEON ON)
 234   endif()
 235   if (ANDROID_ABI MATCHES "VFPV3")
 236     set(ENABLE_VFPV3 ON)
 237   endif()
 238 endif()
 239
 240 if(ANDROID OR WIN32)
 241   set(OPENCV_DOC_INSTALL_PATH doc)
 242 elseif(INSTALL_TO_MANGLED_PATHS)
 243   set(OPENCV_DOC_INSTALL_PATH share/OpenCV-${OPENCV_VERSION}/doc)
 244 else()
 245   set(OPENCV_DOC_INSTALL_PATH share/OpenCV/doc)
 246 endif()
 247
 248 if(WIN32)
 249   if(DEFINED OpenCV_RUNTIME AND DEFINED OpenCV_ARCH)
 250     set(OpenCV_INSTALL_BINARIES_PREFIX "${OpenCV_ARCH}/${OpenCV_RUNTIME}/")
 251   else()
 252     message(STATUS "Can't detect runtime and/or arch")
 253     set(OpenCV_INSTALL_BINARIES_PREFIX "")
 254   endif()
 255 else()
 256   set(OpenCV_INSTALL_BINARIES_PREFIX "")
 257 endif()
 258
 259 set(OPENCV_SAMPLES_BIN_INSTALL_PATH "${OpenCV_INSTALL_BINARIES_PREFIX}samples")
 260
 261 set(OPENCV_BIN_INSTALL_PATH "${OpenCV_INSTALL_BINARIES_PREFIX}bin")
 262
 263 if(ANDROID)
 264   set(LIBRARY_OUTPUT_PATH         "${OpenCV_BINARY_DIR}/lib/${ANDROID_NDK_ABI_NAME}")
 265   set(3P_LIBRARY_OUTPUT_PATH      "${OpenCV_BINARY_DIR}/3rdparty/lib/${ANDROID_NDK_ABI_NAME}")
 266   set(OPENCV_LIB_INSTALL_PATH     sdk/native/libs/${ANDROID_NDK_ABI_NAME})
 267   set(OPENCV_3P_LIB_INSTALL_PATH  sdk/native/3rdparty/libs/${ANDROID_NDK_ABI_NAME})
 268   set(OPENCV_CONFIG_INSTALL_PATH  sdk/native/jni)
 269   set(OPENCV_INCLUDE_INSTALL_PATH sdk/native/jni/include)
 270 else()
 271   set(LIBRARY_OUTPUT_PATH         "${OpenCV_BINARY_DIR}/lib")
 272   set(3P_LIBRARY_OUTPUT_PATH      "${OpenCV_BINARY_DIR}/3rdparty/lib${LIB_SUFFIX}")
 273   if(WIN32)
 274     if(OpenCV_STATIC)
 275       set(OPENCV_LIB_INSTALL_PATH   "${OpenCV_INSTALL_BINARIES_PREFIX}staticlib${LIB_SUFFIX}")
 276     else()
 277       set(OPENCV_LIB_INSTALL_PATH   "${OpenCV_INSTALL_BINARIES_PREFIX}lib${LIB_SUFFIX}")
 278     endif()
 279     set(OPENCV_3P_LIB_INSTALL_PATH  "${OpenCV_INSTALL_BINARIES_PREFIX}staticlib${LIB_SUFFIX}")
 280   else()
 281     set(OPENCV_LIB_INSTALL_PATH     lib${LIB_SUFFIX})
 282     set(OPENCV_3P_LIB_INSTALL_PATH  share/OpenCV/3rdparty/${OPENCV_LIB_INSTALL_PATH})
 283   endif()
 284   set(OPENCV_INCLUDE_INSTALL_PATH "include")
 285
 286   math(EXPR SIZEOF_VOID_P_BITS "8 * ${CMAKE_SIZEOF_VOID_P}")
 287   if(LIB_SUFFIX AND NOT SIZEOF_VOID_P_BITS EQUAL LIB_SUFFIX)
 288     set(OPENCV_CONFIG_INSTALL_PATH lib${LIB_SUFFIX}/cmake/opencv)
 289   else()
 290     set(OPENCV_CONFIG_INSTALL_PATH share/OpenCV)
 291   endif()
 292 endif()
 293
 294 set(CMAKE_INSTALL_RPATH "${CMAKE_INSTALL_PREFIX}/${OPENCV_LIB_INSTALL_PATH}")
 295 set(CMAKE_INSTALL_RPATH_USE_LINK_PATH TRUE)
 296
 297 if(INSTALL_TO_MANGLED_PATHS)
 298   set(OPENCV_INCLUDE_INSTALL_PATH ${OPENCV_INCLUDE_INSTALL_PATH}/opencv-${OPENCV_VERSION})
 299 endif()
 300
 301 if(WIN32)
 302   # Postfix of DLLs:
 303   set(OPENCV_DLLVERSION "${OPENCV_VERSION_MAJOR}${OPENCV_VERSION_MINOR}${OPENCV_VERSION_PATCH}")
 304   set(OPENCV_DEBUG_POSTFIX d)
 305 else()
 306   # Postfix of so's:
 307   set(OPENCV_DLLVERSION "")
 308   set(OPENCV_DEBUG_POSTFIX "")
 309 endif()
 310
 311 if(DEFINED CMAKE_DEBUG_POSTFIX)
 312   set(OPENCV_DEBUG_POSTFIX "${CMAKE_DEBUG_POSTFIX}")
 313 endif()
 314
 315
 316 # ----------------------------------------------------------------------------
 317 #  Path for build/platform -specific headers
 318 # ----------------------------------------------------------------------------
 319 set(OPENCV_CONFIG_FILE_INCLUDE_DIR "${CMAKE_BINARY_DIR}/" CACHE PATH "Where to create the platform-dependant cvconfig.h")
 320 ocv_include_directories(${OPENCV_CONFIG_FILE_INCLUDE_DIR})
 321
 322 # ----------------------------------------------------------------------------
 323 #  Path for additional modules
 324 # ----------------------------------------------------------------------------
 325 set(OPENCV_EXTRA_MODULES_PATH "" CACHE PATH "Where to look for additional OpenCV modules")
 326
 327 # ----------------------------------------------------------------------------
 328 #  Autodetect if we are in a GIT repository
 329 # ----------------------------------------------------------------------------
 330 find_host_package(Git QUIET)
 331
 332 if(GIT_FOUND)
 333   execute_process(COMMAND "${GIT_EXECUTABLE}" describe --tags --always --dirty --match "2.[0-9].[0-9]*"
 334     WORKING_DIRECTORY "${OpenCV_SOURCE_DIR}"
 335     OUTPUT_VARIABLE OPENCV_VCSVERSION
 336     RESULT_VARIABLE GIT_RESULT
 337     ERROR_QUIET
 338     OUTPUT_STRIP_TRAILING_WHITESPACE
 339   )
 340   if(NOT GIT_RESULT EQUAL 0)
 341     set(OPENCV_VCSVERSION "unknown")
 342   endif()
 343 else()
 344   # We don't have git:
 345   set(OPENCV_VCSVERSION "unknown")
 346 endif()
 347
 348
 349 # ----------------------------------------------------------------------------
 350 # OpenCV compiler and linker options
 351 # ----------------------------------------------------------------------------
 352 # In case of Makefiles if the user does not setup CMAKE_BUILD_TYPE, assume it's Release:
 353 if(CMAKE_GENERATOR MATCHES "Makefiles|Ninja" AND "${CMAKE_BUILD_TYPE}" STREQUAL "")
 354   set(CMAKE_BUILD_TYPE Release)
 355 endif()
 356
 357 include(cmake/OpenCVCompilerOptions.cmake)
 358
 359
 360 # ----------------------------------------------------------------------------
 361 # Use statically or dynamically linked CRT?
 362 # Default: dynamic
 363 # ----------------------------------------------------------------------------
 364 if(MSVC)
 365   include(cmake/OpenCVCRTLinkage.cmake)
 366 endif(MSVC)
 367
 368 if(WIN32 AND NOT MINGW)
 369   add_definitions(-D_VARIADIC_MAX=10)
 370 endif(WIN32 AND NOT MINGW)
 371
 372
 373 # ----------------------------------------------------------------------------
 374 #       CHECK FOR SYSTEM LIBRARIES, OPTIONS, ETC..
 375 # ----------------------------------------------------------------------------
 376 if(UNIX)
 377   find_package(PkgConfig QUIET)
 378   include(CheckFunctionExists)
 379   include(CheckIncludeFile)
 380
 381   if(NOT APPLE)
 382     CHECK_INCLUDE_FILE(pthread.h HAVE_LIBPTHREAD)
 383     if(ANDROID)
 384       set(OPENCV_LINKER_LIBS ${OPENCV_LINKER_LIBS} dl m log)
 385     elseif(${CMAKE_SYSTEM_NAME} MATCHES "FreeBSD|NetBSD|DragonFly")
 386       set(OPENCV_LINKER_LIBS ${OPENCV_LINKER_LIBS} m pthread)
 387     else()
 388       set(OPENCV_LINKER_LIBS ${OPENCV_LINKER_LIBS} dl m pthread rt)
 389     endif()
 390   else()
 391     set(HAVE_LIBPTHREAD YES)
 392   endif()
 393 endif()
 394
 395 include(cmake/OpenCVPCHSupport.cmake)
 396 include(cmake/OpenCVModule.cmake)
 397
 398 # ----------------------------------------------------------------------------
 399 #  Detect 3rd-party libraries
 400 # ----------------------------------------------------------------------------
 401
 402 include(cmake/OpenCVFindLibsGrfmt.cmake)
 403 include(cmake/OpenCVFindLibsGUI.cmake)
 404 include(cmake/OpenCVFindLibsVideo.cmake)
 405 include(cmake/OpenCVFindLibsPerf.cmake)
 406
 407
 408 # ----------------------------------------------------------------------------
 409 #  Detect other 3rd-party libraries/tools
 410 # ----------------------------------------------------------------------------
 411
 412 # --- LATEX for pdf documentation ---
 413 if(BUILD_DOCS)
 414   include(cmake/OpenCVFindLATEX.cmake)
 415 endif(BUILD_DOCS)
 416
 417 # --- Python Support ---
 418 include(cmake/OpenCVDetectPython.cmake)
 419
 420 # --- Java Support ---
 421 include(cmake/OpenCVDetectApacheAnt.cmake)
 422 if(ANDROID)
 423   include(cmake/OpenCVDetectAndroidSDK.cmake)
 424
 425   if(NOT ANDROID_TOOLS_Pkg_Revision GREATER 13)
 426     message(WARNING "OpenCV requires Android SDK tools revision 14 or newer. Otherwise tests and samples will no be compiled.")
 427   endif()
 428 else()
 429   find_package(JNI)
 430 endif()
 431
 432 if(ANDROID AND ANDROID_EXECUTABLE AND ANT_EXECUTABLE AND (ANT_VERSION VERSION_GREATER 1.7) AND (ANDROID_TOOLS_Pkg_Revision GREATER 13))
 433   SET(CAN_BUILD_ANDROID_PROJECTS TRUE)
 434 else()
 435   SET(CAN_BUILD_ANDROID_PROJECTS FALSE)
 436 endif()
 437
 438 # --- OpenCL ---
 439 if(WITH_OPENCL)
 440   include(cmake/OpenCVDetectOpenCL.cmake)
 441 endif()
 442
 443 # --- DirectX ---
 444 if(WITH_DIRECTX)
 445   include(cmake/OpenCVDetectDirectX.cmake)
 446 endif()
 447
 448 # --- Matlab/Octave ---
 449 include(cmake/OpenCVFindMatlab.cmake)
 450
 451 include(cmake/OpenCVDetectVTK.cmake)
 452
 453 # ----------------------------------------------------------------------------
 454 # Add CUDA libraries (needed for apps/tools, samples)
 455 # ----------------------------------------------------------------------------
 456 if(HAVE_CUDA)
 457   set(OPENCV_LINKER_LIBS ${OPENCV_LINKER_LIBS} ${CUDA_LIBRARIES} ${CUDA_npp_LIBRARY})
 458   if(HAVE_CUBLAS)
 459     set(OPENCV_LINKER_LIBS ${OPENCV_LINKER_LIBS} ${CUDA_cublas_LIBRARY})
 460   endif()
 461   if(HAVE_CUFFT)
 462     set(OPENCV_LINKER_LIBS ${OPENCV_LINKER_LIBS} ${CUDA_cufft_LIBRARY})
 463   endif()
 464 endif()
 465 # ----------------------------------------------------------------------------
 466 # Solution folders:
 467 # ----------------------------------------------------------------------------
 468 if(ENABLE_SOLUTION_FOLDERS)
 469   set_property(GLOBAL PROPERTY USE_FOLDERS ON)
 470   set_property(GLOBAL PROPERTY PREDEFINED_TARGETS_FOLDER "CMakeTargets")
 471 endif()
 472
 473 # Extra OpenCV targets: uninstall, package_source, perf, etc.
 474 include(cmake/OpenCVExtraTargets.cmake)
 475
 476
 477 # ----------------------------------------------------------------------------
 478 # Process subdirectories
 479 # ----------------------------------------------------------------------------
 480
 481 # opencv.hpp and legacy headers
 482 add_subdirectory(include)
 483
 484 # OpenCV modules
 485 add_subdirectory(modules)
 486
 487 # Generate targets for documentation
 488 add_subdirectory(doc)
 489
 490 # various data that is used by cv libraries and/or demo applications.
 491 add_subdirectory(data)
 492
 493 # extra applications
 494 if(BUILD_opencv_apps)
 495   add_subdirectory(apps)
 496 endif()
 497
 498 # examples
 499 if(BUILD_EXAMPLES OR BUILD_ANDROID_EXAMPLES OR INSTALL_PYTHON_EXAMPLES)
 500   add_subdirectory(samples)
 501 endif()
 502
 503 if(ANDROID)
 504   add_subdirectory(platforms/android/service)
 505 endif()
 506
 507 if(BUILD_ANDROID_PACKAGE)
 508   add_subdirectory(platforms/android/package)
 509 endif()
 510
 511 if (ANDROID)
 512   add_subdirectory(platforms/android/libinfo)
 513 endif()
 514
 515 # ----------------------------------------------------------------------------
 516 # Finalization: generate configuration-based files
 517 # ----------------------------------------------------------------------------
 518 ocv_track_build_dependencies()
 519
 520 # Generate platform-dependent and configuration-dependent headers
 521 include(cmake/OpenCVGenHeaders.cmake)
 522
 523 # Generate opencv.pc for pkg-config command
 524 include(cmake/OpenCVGenPkgconfig.cmake)
 525
 526 # Generate OpenCV.mk for ndk-build (Android build tool)
 527 include(cmake/OpenCVGenAndroidMK.cmake)
 528
 529 # Generate OpenCVСonfig.cmake and OpenCVConfig-version.cmake for cmake projects
 530 include(cmake/OpenCVGenConfig.cmake)
 531
 532 # Generate Info.plist for the IOS framework
 533 include(cmake/OpenCVGenInfoPlist.cmake)
 534
 535 # ----------------------------------------------------------------------------
 536 # Summary:
 537 # ----------------------------------------------------------------------------
 538 status("")
 539 status("General configuration for OpenCV ${OPENCV_VERSION} =====================================")
 540 if(OPENCV_VCSVERSION)
 541   status("  Version control:" ${OPENCV_VCSVERSION})
 542 endif()
 543
 544 # ========================== build platform ==========================
 545 status("")
 546 status("  Platform:")
 547 status("    Host:"             ${CMAKE_HOST_SYSTEM_NAME} ${CMAKE_HOST_SYSTEM_VERSION} ${CMAKE_HOST_SYSTEM_PROCESSOR})
 548 if(CMAKE_CROSSCOMPILING)
 549   status("    Target:"         ${CMAKE_SYSTEM_NAME} ${CMAKE_SYSTEM_VERSION} ${CMAKE_SYSTEM_PROCESSOR})
 550 endif()
 551 status("    CMake:"            ${CMAKE_VERSION})
 552 status("    CMake generator:"  ${CMAKE_GENERATOR})
 553 status("    CMake build tool:" ${CMAKE_BUILD_TOOL})
 554 if(MSVC)
 555   status("    MSVC:"           ${MSVC_VERSION})
 556 endif()
 557 if(CMAKE_GENERATOR MATCHES Xcode)
 558   status("    Xcode:"          ${XCODE_VERSION})
 559 endif()
 560 if(NOT CMAKE_GENERATOR MATCHES "Xcode|Visual Studio")
 561   status("    Configuration:"  ${CMAKE_BUILD_TYPE})
 562 endif()
 563
 564 # ========================== C/C++ options ==========================
 565 if(CMAKE_CXX_COMPILER_VERSION)
 566   set(OPENCV_COMPILER_STR "${CMAKE_CXX_COMPILER} ${CMAKE_CXX_COMPILER_ARG1} (ver ${CMAKE_CXX_COMPILER_VERSION})")
 567 elseif(CMAKE_COMPILER_IS_CLANGCXX)
 568   set(OPENCV_COMPILER_STR "${CMAKE_CXX_COMPILER} ${CMAKE_CXX_COMPILER_ARG1} (ver ${CMAKE_CLANG_REGEX_VERSION})")
 569 elseif(CMAKE_COMPILER_IS_GNUCXX)
 570   set(OPENCV_COMPILER_STR "${CMAKE_CXX_COMPILER} ${CMAKE_CXX_COMPILER_ARG1} (ver ${CMAKE_GCC_REGEX_VERSION})")
 571 else()
 572   set(OPENCV_COMPILER_STR "${CMAKE_CXX_COMPILER} ${CMAKE_CXX_COMPILER_ARG1}")
 573 endif()
 574 string(STRIP "${OPENCV_COMPILER_STR}" OPENCV_COMPILER_STR)
 575
 576 status("")
 577 status("  C/C++:")
 578 status("    Built as dynamic libs?:" BUILD_SHARED_LIBS THEN YES ELSE NO)
 579 status("    C++ Compiler:"           ${OPENCV_COMPILER_STR})
 580 status("    C++ flags (Release):"    ${CMAKE_CXX_FLAGS} ${CMAKE_CXX_FLAGS_RELEASE})
 581 status("    C++ flags (Debug):"      ${CMAKE_CXX_FLAGS} ${CMAKE_CXX_FLAGS_DEBUG})
 582 status("    C Compiler:"             ${CMAKE_C_COMPILER} ${CMAKE_C_COMPILER_ARG1})
 583 status("    C flags (Release):"      ${CMAKE_C_FLAGS} ${CMAKE_C_FLAGS_RELEASE})
 584 status("    C flags (Debug):"        ${CMAKE_C_FLAGS} ${CMAKE_C_FLAGS_DEBUG})
 585 if(WIN32)
 586   status("    Linker flags (Release):" ${CMAKE_EXE_LINKER_FLAGS} ${CMAKE_EXE_LINKER_FLAGS_RELEASE})
 587   status("    Linker flags (Debug):"   ${CMAKE_EXE_LINKER_FLAGS} ${CMAKE_EXE_LINKER_FLAGS_DEBUG})
 588 else()
 589   status("    Linker flags (Release):" ${CMAKE_SHARED_LINKER_FLAGS} ${CMAKE_SHARED_LINKER_FLAGS_RELEASE})
 590   status("    Linker flags (Debug):"   ${CMAKE_SHARED_LINKER_FLAGS} ${CMAKE_SHARED_LINKER_FLAGS_DEBUG})
 591 endif()
 592 status("    Precompiled headers:"     PCHSupport_FOUND AND ENABLE_PRECOMPILED_HEADERS THEN YES ELSE NO)
 593
 594 # ========================== OpenCV modules ==========================
 595 status("")
 596 status("  OpenCV modules:")
 597 string(REPLACE "opencv_" "" OPENCV_MODULES_BUILD_ST          "${OPENCV_MODULES_BUILD}")
 598 string(REPLACE "opencv_" "" OPENCV_MODULES_DISABLED_USER_ST  "${OPENCV_MODULES_DISABLED_USER}")
 599 string(REPLACE "opencv_" "" OPENCV_MODULES_DISABLED_FORCE_ST "${OPENCV_MODULES_DISABLED_FORCE}")
 600 set(OPENCV_MODULES_DISABLED_AUTO_ST "")
 601 foreach(m ${OPENCV_MODULES_DISABLED_AUTO})
 602   set(__mdeps "")
 603   foreach(d ${OPENCV_MODULE_${m}_DEPS})
 604     if(d MATCHES "^opencv_" AND NOT HAVE_${d})
 605       list(APPEND __mdeps ${d})
 606     endif()
 607   endforeach()
 608   if(__mdeps)
 609     list(APPEND OPENCV_MODULES_DISABLED_AUTO_ST "${m}(deps: ${__mdeps})")
 610   else()
 611     list(APPEND OPENCV_MODULES_DISABLED_AUTO_ST "${m}")
 612   endif()
 613 endforeach()
 614 string(REPLACE "opencv_" "" OPENCV_MODULES_DISABLED_AUTO_ST  "${OPENCV_MODULES_DISABLED_AUTO_ST}")
 615
 616 status("    To be built:"            OPENCV_MODULES_BUILD          THEN ${OPENCV_MODULES_BUILD_ST}          ELSE "-")
 617 status("    Disabled:"               OPENCV_MODULES_DISABLED_USER  THEN ${OPENCV_MODULES_DISABLED_USER_ST}  ELSE "-")
 618 status("    Disabled by dependency:" OPENCV_MODULES_DISABLED_AUTO  THEN ${OPENCV_MODULES_DISABLED_AUTO_ST}  ELSE "-")
 619 status("    Unavailable:"            OPENCV_MODULES_DISABLED_FORCE THEN ${OPENCV_MODULES_DISABLED_FORCE_ST} ELSE "-")
 620
 621 # ========================== Android details ==========================
 622 if(ANDROID)
 623   status("")
 624   status("  Android: ")
 625   status("    Android ABI:" ${ANDROID_ABI})
 626   status("    STL type:" ${ANDROID_STL})
 627   status("    Native API level:" android-${ANDROID_NATIVE_API_LEVEL})
 628   android_get_compatible_target(android_sdk_target_status ${ANDROID_NATIVE_API_LEVEL} ${ANDROID_SDK_TARGET} 11)
 629   status("    SDK target:" "${android_sdk_target_status}")
 630   if(BUILD_WITH_ANDROID_NDK)
 631     status("    Android NDK:" "${ANDROID_NDK} (toolchain: ${ANDROID_TOOLCHAIN_NAME})")
 632   elseif(BUILD_WITH_STANDALONE_TOOLCHAIN)
 633     status("    Android toolchain:" "${ANDROID_STANDALONE_TOOLCHAIN}")
 634   endif()
 635   status("    android tool:"  ANDROID_EXECUTABLE  THEN "${ANDROID_EXECUTABLE} (${ANDROID_TOOLS_Pkg_Desc})" ELSE NO)
 636   status("    Google Play package:" BUILD_ANDROID_PACKAGE                                         THEN YES ELSE NO)
 637   status("    Android examples:"    BUILD_ANDROID_EXAMPLES AND CAN_BUILD_ANDROID_PROJECTS         THEN YES ELSE NO)
 638 endif()
 639
 640 # ================== Windows RT features ==================
 641 if(WIN32)
 642 status("")
 643     status("  Windows RT support:" HAVE_WINRT THEN YES ELSE NO)
 644     if (ENABLE_WINRT_MODE)
 645       status("    Windows SDK v8.0:" ${WINDOWS_SDK_PATH})
 646       status("    Visual Studio 2012:" ${VISUAL_STUDIO_PATH})
 647     endif()
 648 endif(WIN32)
 649
 650 # ========================== GUI ==========================
 651 status("")
 652 status("  GUI: ")
 653
 654 if(HAVE_QT5)
 655   status("    QT 5.x:"            HAVE_QT        THEN "YES (ver ${Qt5Core_VERSION_STRING})" ELSE NO)
 656   status("    QT OpenGL support:" HAVE_QT_OPENGL THEN "YES (${Qt5OpenGL_LIBRARIES} ${Qt5OpenGL_VERSION_STRING})" ELSE NO)
 657 elseif(HAVE_QT)
 658   status("    QT 4.x:"            HAVE_QT        THEN "YES (ver ${QT_VERSION_MAJOR}.${QT_VERSION_MINOR}.${QT_VERSION_PATCH} ${QT_EDITION})" ELSE NO)
 659   status("    QT OpenGL support:" HAVE_QT_OPENGL THEN "YES (${QT_QTOPENGL_LIBRARY})" ELSE NO)
 660 else()
 661   if(DEFINED WITH_QT)
 662     status("    QT:" NO)
 663   endif()
 664   if(DEFINED WITH_WIN32UI)
 665     status("    Win32 UI:" HAVE_WIN32UI THEN YES ELSE NO)
 666   else()
 667     if(APPLE)
 668       if(WITH_CARBON)
 669         status("    Carbon:" YES)
 670       else()
 671         status("    Cocoa:"  YES)
 672       endif()
 673     else()
 674       status("    GTK+ 2.x:" HAVE_GTK      THEN "YES (ver ${ALIASOF_gtk+-2.0_VERSION})"     ELSE NO)
 675       status("    GThread :" HAVE_GTHREAD  THEN "YES (ver ${ALIASOF_gthread-2.0_VERSION})"  ELSE NO)
 676       status("    GtkGlExt:" HAVE_GTKGLEXT THEN "YES (ver ${ALIASOF_gtkglext-1.0_VERSION})" ELSE NO)
 677     endif()
 678   endif()
 679 endif()
 680
 681 status("    OpenGL support:" HAVE_OPENGL THEN "YES (${OPENGL_LIBRARIES})" ELSE NO)
 682 status("    VTK support:" HAVE_VTK THEN "YES (ver ${VTK_VERSION})" ELSE NO)
 683
 684 # ========================== MEDIA IO ==========================
 685 status("")
 686 status("  Media I/O: ")
 687 status("    ZLib:"         BUILD_ZLIB    THEN "build (ver ${ZLIB_VERSION_STRING})"               ELSE "${ZLIB_LIBRARIES} (ver ${ZLIB_VERSION_STRING})")
 688
 689 if(WITH_JPEG)
 690   status("    JPEG:"       JPEG_FOUND    THEN "${JPEG_LIBRARY} (ver ${JPEG_LIB_VERSION})"        ELSE "build (ver ${JPEG_LIB_VERSION})")
 691 else()
 692   status("    JPEG:"       "NO")
 693 endif()
 694
 695 if(WITH_WEBP)
 696   status("    WEBP:"       WEBP_FOUND    THEN "${WEBP_LIBRARY} (ver ${WEBP_VERSION})"        ELSE "build (ver ${WEBP_VERSION})")
 697 else()
 698   status("    WEBP:"       "NO")
 699 endif()
 700
 701 if(WITH_PNG)
 702   status("    PNG:"        PNG_FOUND     THEN "${PNG_LIBRARY} (ver ${PNG_VERSION})"              ELSE "build (ver ${PNG_VERSION})")
 703 else()
 704   status("    PNG:"        "NO")
 705 endif()
 706 if(WITH_TIFF)
 707   if(TIFF_VERSION_STRING AND TIFF_FOUND)
 708     status("    TIFF:"     "${TIFF_LIBRARY} (ver ${TIFF_VERSION} - ${TIFF_VERSION_STRING})")
 709   else()
 710     status("    TIFF:"     TIFF_FOUND    THEN "${TIFF_LIBRARY} (ver ${TIFF_VERSION})"            ELSE "build (ver ${TIFF_VERSION} - ${TIFF_VERSION_STRING})")
 711   endif()
 712 else()
 713   status("    TIFF:"       "NO")
 714 endif()
 715 if(WITH_JASPER)
 716   status("    JPEG 2000:"  JASPER_FOUND  THEN "${JASPER_LIBRARY} (ver ${JASPER_VERSION_STRING})" ELSE "build (ver ${JASPER_VERSION_STRING})")
 717 else()
 718   status("    JPEG 2000:"  "NO")
 719 endif()
 720 if(WITH_OPENEXR)
 721   status("    OpenEXR:"  OPENEXR_FOUND  THEN "${OPENEXR_LIBRARIES} (ver ${OPENEXR_VERSION})" ELSE "build (ver ${OPENEXR_VERSION})")
 722 else()
 723   status("    OpenEXR:"  "NO")
 724 endif()
 725
 726 # ========================== VIDEO IO ==========================
 727 status("")
 728 status("  Video I/O:")
 729
 730 if (DEFINED WITH_VFW)
 731   status("    Video for Windows:" HAVE_VFW         THEN YES                                        ELSE NO)
 732 endif(DEFINED WITH_VFW)
 733
 734 if(DEFINED WITH_1394)
 735   status("    DC1394 1.x:"     HAVE_DC1394         THEN "YES (ver ${ALIASOF_libdc1394_VERSION})"   ELSE NO)
 736   status("    DC1394 2.x:"     HAVE_DC1394_2       THEN "YES (ver ${ALIASOF_libdc1394-2_VERSION})" ELSE NO)
 737 endif(DEFINED WITH_1394)
 738
 739 if(ANDROID)
 740   if(HAVE_opencv_androidcamera)
 741     status("    AndroidNativeCamera:" BUILD_ANDROID_CAMERA_WRAPPER
 742                                                    THEN "YES, build for Android${ANDROID_VERSION}" ELSE "YES, use prebuilt libraries")
 743   else()
 744     status("    AndroidNativeCamera:" "NO (native camera requires Android API level 8 or higher)")
 745   endif()
 746 endif()
 747
 748 if(DEFINED WITH_AVFOUNDATION)
 749   status("    AVFoundation:"   WITH_AVFOUNDATION   THEN YES                                        ELSE NO)
 750 endif(DEFINED WITH_AVFOUNDATION)
 751
 752 if(DEFINED WITH_FFMPEG)
 753   if(WIN32)
 754     status("    FFMPEG:"       WITH_FFMPEG         THEN "YES (prebuilt binaries)"                  ELSE NO)
 755   else()
 756     status("    FFMPEG:"       HAVE_FFMPEG         THEN YES ELSE NO)
 757   endif()
 758   status("      codec:"        HAVE_FFMPEG_CODEC   THEN "YES (ver ${ALIASOF_libavcodec_VERSION})"  ELSE NO)
 759   status("      format:"       HAVE_FFMPEG_FORMAT  THEN "YES (ver ${ALIASOF_libavformat_VERSION})" ELSE NO)
 760   status("      util:"         HAVE_FFMPEG_UTIL    THEN "YES (ver ${ALIASOF_libavutil_VERSION})"   ELSE NO)
 761   status("      swscale:"      HAVE_FFMPEG_SWSCALE THEN "YES (ver ${ALIASOF_libswscale_VERSION})"  ELSE NO)
 762   status("      gentoo-style:" HAVE_GENTOO_FFMPEG  THEN YES                                        ELSE NO)
 763 endif(DEFINED WITH_FFMPEG)
 764
 765 if(DEFINED WITH_GSTREAMER)
 766   status("    GStreamer:"      HAVE_GSTREAMER      THEN ""                                         ELSE NO)
 767   if(HAVE_GSTREAMER)
 768     status("      base:"       "YES (ver ${GSTREAMER_BASE_VERSION})")
 769     status("      video:"      "YES (ver ${GSTREAMER_VIDEO_VERSION})")
 770     status("      app:"        "YES (ver ${GSTREAMER_APP_VERSION})")
 771     status("      riff:"       "YES (ver ${GSTREAMER_RIFF_VERSION})")
 772     status("      pbutils:"    "YES (ver ${GSTREAMER_PBUTILS_VERSION})")
 773   endif(HAVE_GSTREAMER)
 774 endif(DEFINED WITH_GSTREAMER)
 775
 776 if(DEFINED WITH_OPENNI)
 777   status("    OpenNI:"         HAVE_OPENNI         THEN "YES (ver ${OPENNI_VERSION_STRING}, build ${OPENNI_VERSION_BUILD})"
 778                                                                                                    ELSE NO)
 779   status("    OpenNI PrimeSensor Modules:" HAVE_OPENNI_PRIME_SENSOR_MODULE
 780                                                    THEN "YES (${OPENNI_PRIME_SENSOR_MODULE})"      ELSE NO)
 781 endif(DEFINED WITH_OPENNI)
 782
 783 if(DEFINED WITH_PVAPI)
 784   status("    PvAPI:"          HAVE_PVAPI          THEN YES                                        ELSE NO)
 785 endif(DEFINED WITH_PVAPI)
 786
 787 if(DEFINED WITH_GIGEAPI)
 788   status("    GigEVisionSDK:"  HAVE_GIGE_API       THEN YES                                        ELSE NO)
 789 endif(DEFINED WITH_GIGEAPI)
 790
 791 if(DEFINED WITH_QUICKTIME)
 792   status("    QuickTime:"      HAVE_QUICKTIME      THEN YES                                        ELSE NO)
 793   status("    QTKit:"          HAVE_QTKIT          THEN YES                                        ELSE NO)
 794 endif(DEFINED WITH_QUICKTIME)
 795
 796 if(DEFINED WITH_UNICAP)
 797   status("    UniCap:"         HAVE_UNICAP         THEN "YES (ver ${ALIASOF_libunicap_VERSION})"   ELSE NO)
 798   status("    UniCap ucil:"    HAVE_UNICAP_UCIL    THEN "YES (ver ${ALIASOF_libucil_VERSION})"     ELSE NO)
 799 endif(DEFINED WITH_UNICAP)
 800
 801 if(DEFINED WITH_V4L)
 802   if(HAVE_CAMV4L)
 803     set(HAVE_CAMV4L_STR "YES")
 804   else()
 805     set(HAVE_CAMV4L_STR "NO")
 806   endif()
 807   if(HAVE_CAMV4L2)
 808     set(HAVE_CAMV4L2_STR "YES")
 809   elseif(HAVE_VIDEOIO)
 810     set(HAVE_CAMV4L2_STR "YES(videoio)")
 811   else()
 812     set(HAVE_CAMV4L2_STR "NO")
 813   endif()
 814   status("    V4L/V4L2:"       HAVE_LIBV4L         THEN "Using libv4l (ver ${ALIASOF_libv4l1_VERSION})"
 815                                                    ELSE "${HAVE_CAMV4L_STR}/${HAVE_CAMV4L2_STR}")
 816 endif(DEFINED WITH_V4L)
 817
 818 if(DEFINED WITH_DSHOW)
 819   status("    DirectShow:"     HAVE_DSHOW     THEN YES                                        ELSE NO)
 820 endif(DEFINED WITH_DSHOW)
 821
 822 if(DEFINED WITH_MSMF)
 823   status("    Media Foundation:" HAVE_MSMF    THEN YES                                        ELSE NO)
 824 endif(DEFINED WITH_MSMF)
 825
 826 if(DEFINED WITH_XIMEA)
 827   status("    XIMEA:"          HAVE_XIMEA          THEN YES                                        ELSE NO)
 828 endif(DEFINED WITH_XIMEA)
 829
 830 if(DEFINED WITH_XINE)
 831   status("    Xine:"           HAVE_XINE           THEN "YES (ver ${ALIASOF_libxine_VERSION})"     ELSE NO)
 832 endif(DEFINED WITH_XINE)
 833
 834 if(DEFINED WITH_INTELPERC)
 835   status("    Intel PerC:"     HAVE_INTELPERC      THEN "YES"                                 ELSE NO)
 836 endif(DEFINED WITH_INTELPERC)
 837
 838
 839 # ========================== Other third-party libraries ==========================
 840 status("")
 841 status("  Other third-party libraries:")
 842
 843 if(WITH_IPP AND IPP_FOUND)
 844   status("    Use IPP:" "${IPP_LATEST_VERSION_STR} [${IPP_LATEST_VERSION_MAJOR}.${IPP_LATEST_VERSION_MINOR}.${IPP_LATEST_VERSION_BUILD}]")
 845   status("         at:" "${IPP_ROOT_DIR}")
 846 else()
 847   status("    Use IPP:"   WITH_IPP AND NOT IPP_FOUND THEN "IPP not found" ELSE NO)
 848 endif()
 849
 850 status("    Use Eigen:"      HAVE_EIGEN       THEN "YES (ver ${EIGEN_WORLD_VERSION}.${EIGEN_MAJOR_VERSION}.${EIGEN_MINOR_VERSION})" ELSE NO)
 851 status("    Use TBB:"        HAVE_TBB         THEN "YES (ver ${TBB_VERSION_MAJOR}.${TBB_VERSION_MINOR} interface ${TBB_INTERFACE_VERSION})" ELSE NO)
 852 status("    Use OpenMP:"     HAVE_OPENMP      THEN YES ELSE NO)
 853 status("    Use GCD"         HAVE_GCD         THEN YES ELSE NO)
 854 status("    Use Concurrency" HAVE_CONCURRENCY THEN YES ELSE NO)
 855 status("    Use C=:"         HAVE_CSTRIPES    THEN YES ELSE NO)
 856 status("    Use Cuda:"       HAVE_CUDA        THEN "YES (ver ${CUDA_VERSION_STRING})" ELSE NO)
 857 status("    Use OpenCL:"     HAVE_OPENCL      THEN YES ELSE NO)
 858
 859 if(HAVE_CUDA)
 860   status("")
 861   status("  NVIDIA CUDA")
 862
 863   status("    Use CUFFT:"            HAVE_CUFFT   THEN YES ELSE NO)
 864   status("    Use CUBLAS:"           HAVE_CUBLAS  THEN YES ELSE NO)
 865   status("    USE NVCUVID:"          HAVE_NVCUVID THEN YES ELSE NO)
 866   status("    NVIDIA GPU arch:"      ${OPENCV_CUDA_ARCH_BIN})
 867   status("    NVIDIA PTX archs:"     ${OPENCV_CUDA_ARCH_PTX})
 868   status("    Use fast math:"        CUDA_FAST_MATH THEN YES ELSE NO)
 869 endif()
 870
 871 if(HAVE_OPENCL)
 872   status("")
 873   status("  OpenCL:")
 874   if(HAVE_OPENCL_STATIC)
 875     set(__opencl_ver "static")
 876   else()
 877     set(__opencl_ver "dynamic")
 878   endif()
 879   status("    Version:"       ${__opencl_ver})
 880   if(OPENCL_INCLUDE_DIR)
 881     status("    Include path:"       ${OPENCL_INCLUDE_DIRS})
 882   endif()
 883   if(OPENCL_LIBRARIES)
 884     set(__libs "")
 885     foreach(l ${OPENCL_LIBRARIES})
 886       if(TARGET ${l})
 887         get_target_property(p ${l} LOCATION)
 888         if(p MATCHES NOTFOUND)
 889           list(APPEND __libs "${l}")
 890         else()
 891           list(APPEND __libs "${p}")
 892         endif()
 893       else()
 894         list(APPEND __libs "${l}")
 895       endif()
 896     endforeach()
 897     status("    libraries:"          ${__libs})
 898   endif()
 899   status("    Use AMDFFT:"           HAVE_CLAMDFFT  THEN YES ELSE NO)
 900   status("    Use AMDBLAS:"          HAVE_CLAMDBLAS THEN YES ELSE NO)
 901 endif()
 902
 903 # ========================== python ==========================
 904 status("")
 905 status("  Python:")
 906 status("    Interpreter:"     PYTHONINTERP_FOUND  THEN "${PYTHON_EXECUTABLE} (ver ${PYTHON_VERSION_STRING})"       ELSE NO)
 907 if(BUILD_opencv_python)
 908   if(PYTHONLIBS_VERSION_STRING)
 909     status("    Libraries:"   HAVE_opencv_python  THEN  "${PYTHON_LIBRARIES} (ver ${PYTHONLIBS_VERSION_STRING})"   ELSE NO)
 910   else()
 911     status("    Libraries:"   HAVE_opencv_python  THEN  "${PYTHON_LIBRARIES}"                                      ELSE NO)
 912   endif()
 913   status("    numpy:"         PYTHON_NUMPY_INCLUDE_DIRS THEN "${PYTHON_NUMPY_INCLUDE_DIRS} (ver ${PYTHON_NUMPY_VERSION})" ELSE "NO (Python wrappers can not be generated)")
 914   status("    packages path:" PYTHON_EXECUTABLE         THEN "${PYTHON_PACKAGES_PATH}"                                    ELSE "-")
 915 endif()
 916
 917 # ========================== java ==========================
 918 status("")
 919 status("  Java:")
 920 status("    ant:"           ANT_EXECUTABLE      THEN "${ANT_EXECUTABLE} (ver ${ANT_VERSION})"                    ELSE NO)
 921 if(NOT ANDROID)
 922   status("    JNI:"         JNI_INCLUDE_DIRS    THEN "${JNI_INCLUDE_DIRS}"                                       ELSE NO)
 923 endif()
 924 status("    Java tests:"    BUILD_TESTS AND (CAN_BUILD_ANDROID_PROJECTS OR HAVE_opencv_java)            THEN YES ELSE NO)
 925
 926 # ========================= matlab =========================
 927 status("")
 928 status("  Matlab:")
 929 status("    mex:"         MATLAB_MEX_SCRIPT  THEN  "${MATLAB_MEX_SCRIPT}"   ELSE NO)
 930 if (MATLAB_FOUND)
 931   status("    Compiler/generator:" MEX_WORKS    THEN  "Working"                ELSE "Not working (bindings will not be generated)")
 932 endif()
 933
 934 # ========================== documentation ==========================
 935 if(BUILD_DOCS)
 936   status("")
 937   status("  Documentation:")
 938   if(HAVE_SPHINX)
 939     status("    Build Documentation:" PDFLATEX_COMPILER      THEN YES ELSE "YES (only HTML and without math expressions)")
 940   else()
 941     status("    Build Documentation:" NO)
 942   endif()
 943   status("    Sphinx:"              HAVE_SPHINX              THEN "${SPHINX_BUILD} (ver ${SPHINX_VERSION})" ELSE NO)
 944   status("    PdfLaTeX compiler:"   PDFLATEX_COMPILER        THEN "${PDFLATEX_COMPILER}" ELSE NO)
 945   status("    PlantUML:"            PLANTUML                 THEN "${PLANTUML}" ELSE NO)
 946 endif()
 947
 948 # ========================== samples and tests ==========================
 949 status("")
 950 status("  Tests and samples:")
 951 status("    Tests:"             BUILD_TESTS AND HAVE_opencv_ts       THEN YES ELSE NO)
 952 status("    Performance tests:" BUILD_PERF_TESTS AND HAVE_opencv_ts  THEN YES ELSE NO)
 953 status("    C/C++ Examples:"    BUILD_EXAMPLES                       THEN YES ELSE NO)
 954
 955 # ========================== auxiliary ==========================
 956 status("")
 957 status("  Install path:" "${CMAKE_INSTALL_PREFIX}")
 958 status("")
 959 status("  cvconfig.h is in:" "${OPENCV_CONFIG_FILE_INCLUDE_DIR}")
 960 status("-----------------------------------------------------------------")
 961 status("")
 962
 963 ocv_finalize_status()
 964
 965 # ----------------------------------------------------------------------------
 966 # Warn in the case of in-source build
 967 # ----------------------------------------------------------------------------
 968 if("${CMAKE_CURRENT_SOURCE_DIR}" STREQUAL "${CMAKE_CURRENT_BINARY_DIR}")
 969   message(WARNING "The source directory is the same as binary directory. \"make clean\" may damage the source tree")
 970 endif()