CMakeLists.txt

   1 # ----------------------------------------------------------------------------
   2 #  Root CMake file for OpenCV
   3 #
   4 #    From the off-tree build directory, invoke:
   5 #      $ cmake <PATH_TO_OPENCV_ROOT>
   6 #
   7 # ----------------------------------------------------------------------------
   8
   9 # Disable in-source builds to prevent source tree corruption.
  10 if(" ${CMAKE_SOURCE_DIR}" STREQUAL " ${CMAKE_BINARY_DIR}")
  11   message(FATAL_ERROR "
  12 FATAL: In-source builds are not allowed.
  13        You should create a separate directory for build files.
  14 ")
  15 endif()
  16
  17
  18 include(cmake/OpenCVMinDepVersions.cmake)
  19
  20 if(CMAKE_GENERATOR MATCHES Xcode AND XCODE_VERSION VERSION_GREATER 4.3)
  21   cmake_minimum_required(VERSION 3.0 FATAL_ERROR)
  22 elseif(CMAKE_SYSTEM_NAME MATCHES WindowsPhone OR CMAKE_SYSTEM_NAME MATCHES WindowsStore)
  23   cmake_minimum_required(VERSION 3.1 FATAL_ERROR)
  24   #Required to resolve linker error issues due to incompatibility with CMake v3.0+ policies.
  25   #CMake fails to find _fseeko() which leads to subsequent linker error.
  26   #See details here: http://www.cmake.org/Wiki/CMake/Policies
  27   cmake_policy(VERSION 2.8)
  28 else()
  29   cmake_minimum_required(VERSION "${MIN_VER_CMAKE}" FATAL_ERROR)
  30 endif()
  31
  32 option(ENABLE_PIC "Generate position independent code (necessary for shared libraries)" TRUE)
  33 set(CMAKE_POSITION_INDEPENDENT_CODE ${ENABLE_PIC})
  34
  35 # Following block can break build in case of cross-compilng
  36 # but CMAKE_CROSSCOMPILING variable will be set only on project(OpenCV) command
  37 # so we will try to detect cross-compiling by presense of CMAKE_TOOLCHAIN_FILE
  38 if(NOT DEFINED CMAKE_INSTALL_PREFIX)
  39   if(NOT CMAKE_TOOLCHAIN_FILE)
  40     # it _must_ go before project(OpenCV) in order to work
  41     if(WIN32)
  42       set(CMAKE_INSTALL_PREFIX "${CMAKE_BINARY_DIR}/install" CACHE PATH "Installation Directory")
  43     else()
  44       set(CMAKE_INSTALL_PREFIX "/usr/local" CACHE PATH "Installation Directory")
  45     endif()
  46   else(NOT CMAKE_TOOLCHAIN_FILE)
  47     #Android: set output folder to ${CMAKE_BINARY_DIR}
  48     set( LIBRARY_OUTPUT_PATH_ROOT ${CMAKE_BINARY_DIR} CACHE PATH "root for library output, set this to change where android libs are compiled to" )
  49     # any cross-compiling
  50     set(CMAKE_INSTALL_PREFIX "${CMAKE_BINARY_DIR}/install" CACHE PATH "Installation Directory")
  51   endif(NOT CMAKE_TOOLCHAIN_FILE)
  52 endif()
  53
  54 if(CMAKE_SYSTEM_NAME MATCHES WindowsPhone OR CMAKE_SYSTEM_NAME MATCHES WindowsStore)
  55   set(WINRT TRUE)
  56 endif(CMAKE_SYSTEM_NAME MATCHES WindowsPhone OR CMAKE_SYSTEM_NAME MATCHES WindowsStore)
  57
  58 if(WINRT)
  59   add_definitions(-DWINRT -DNO_GETENV)
  60
  61   # Making definitions available to other configurations and
  62   # to filter dependency restrictions at compile time.
  63   if(CMAKE_SYSTEM_NAME MATCHES WindowsPhone)
  64     set(WINRT_PHONE TRUE)
  65     add_definitions(-DWINRT_PHONE)
  66   elseif(CMAKE_SYSTEM_NAME MATCHES WindowsStore)
  67     set(WINRT_STORE TRUE)
  68     add_definitions(-DWINRT_STORE)
  69   endif()
  70
  71   if(CMAKE_SYSTEM_VERSION MATCHES 10)
  72     set(WINRT_10 TRUE)
  73     add_definitions(-DWINRT_10)
  74   elseif(CMAKE_SYSTEM_VERSION MATCHES 8.1)
  75     set(WINRT_8_1 TRUE)
  76     add_definitions(-DWINRT_8_1)
  77   elseif(CMAKE_SYSTEM_VERSION MATCHES 8.0)
  78     set(WINRT_8_0 TRUE)
  79     add_definitions(-DWINRT_8_0)
  80   endif()
  81 endif()
  82
  83 if(POLICY CMP0026)
  84   cmake_policy(SET CMP0026 NEW)
  85 endif()
  86
  87 if(POLICY CMP0042)
  88   cmake_policy(SET CMP0042 NEW)
  89 endif()
  90
  91 if(POLICY CMP0046)
  92   cmake_policy(SET CMP0046 NEW)
  93 endif()
  94
  95 if(POLICY CMP0051)
  96   cmake_policy(SET CMP0051 NEW)
  97 endif()
  98
  99 if(POLICY CMP0056)
 100   cmake_policy(SET CMP0056 NEW)
 101 endif()
 102
 103 if(POLICY CMP0067)
 104   cmake_policy(SET CMP0067 NEW)
 105 endif()
 106
 107 include(cmake/OpenCVUtils.cmake)
 108
 109 # must go before the project command
 110 ocv_update(CMAKE_CONFIGURATION_TYPES "Debug;Release" CACHE STRING "Configs" FORCE)
 111 if(DEFINED CMAKE_BUILD_TYPE)
 112   set_property( CACHE CMAKE_BUILD_TYPE PROPERTY STRINGS ${CMAKE_CONFIGURATION_TYPES} )
 113 endif()
 114
 115 enable_testing()
 116
 117 project(OpenCV CXX C)
 118
 119 if(MSVC)
 120   set(CMAKE_USE_RELATIVE_PATHS ON CACHE INTERNAL "" FORCE)
 121 endif()
 122
 123 ocv_cmake_eval(DEBUG_PRE ONCE)
 124
 125 ocv_clear_vars(OpenCVModules_TARGETS)
 126
 127 include(cmake/OpenCVDownload.cmake)
 128
 129 set(BUILD_LIST "" CACHE STRING "Build only listed modules (comma-separated, e.g. 'videoio,dnn,ts')")
 130
 131 # ----------------------------------------------------------------------------
 132 # Break in case of popular CMake configuration mistakes
 133 # ----------------------------------------------------------------------------
 134 if(NOT CMAKE_SIZEOF_VOID_P GREATER 0)
 135   message(FATAL_ERROR "CMake fails to determine the bitness of the target platform.
 136   Please check your CMake and compiler installation. If you are cross-compiling then ensure that your CMake toolchain file correctly sets the compiler details.")
 137 endif()
 138
 139 # ----------------------------------------------------------------------------
 140 # Detect compiler and target platform architecture
 141 # ----------------------------------------------------------------------------
 142 OCV_OPTION(ENABLE_CXX11 "Enable C++11 compilation mode" "${OPENCV_CXX11}")
 143 include(cmake/OpenCVDetectCXXCompiler.cmake)
 144
 145 # Add these standard paths to the search paths for FIND_LIBRARY
 146 # to find libraries from these locations first
 147 if(UNIX AND NOT ANDROID)
 148   if(X86_64 OR CMAKE_SIZEOF_VOID_P EQUAL 8)
 149     if(EXISTS /lib64)
 150       list(APPEND CMAKE_LIBRARY_PATH /lib64)
 151     else()
 152       list(APPEND CMAKE_LIBRARY_PATH /lib)
 153     endif()
 154     if(EXISTS /usr/lib64)
 155       list(APPEND CMAKE_LIBRARY_PATH /usr/lib64)
 156     else()
 157       list(APPEND CMAKE_LIBRARY_PATH /usr/lib)
 158     endif()
 159   elseif(X86 OR CMAKE_SIZEOF_VOID_P EQUAL 4)
 160     if(EXISTS /lib32)
 161       list(APPEND CMAKE_LIBRARY_PATH /lib32)
 162     else()
 163       list(APPEND CMAKE_LIBRARY_PATH /lib)
 164     endif()
 165     if(EXISTS /usr/lib32)
 166       list(APPEND CMAKE_LIBRARY_PATH /usr/lib32)
 167     else()
 168       list(APPEND CMAKE_LIBRARY_PATH /usr/lib)
 169     endif()
 170   endif()
 171 endif()
 172
 173 # Add these standard paths to the search paths for FIND_PATH
 174 # to find include files from these locations first
 175 if(MINGW)
 176   if(EXISTS /mingw)
 177       list(APPEND CMAKE_INCLUDE_PATH /mingw)
 178   endif()
 179   if(EXISTS /mingw32)
 180       list(APPEND CMAKE_INCLUDE_PATH /mingw32)
 181   endif()
 182   if(EXISTS /mingw64)
 183       list(APPEND CMAKE_INCLUDE_PATH /mingw64)
 184   endif()
 185 endif()
 186
 187 # ----------------------------------------------------------------------------
 188 # OpenCV cmake options
 189 # ----------------------------------------------------------------------------
 190
 191 OCV_OPTION(OPENCV_ENABLE_NONFREE "Enable non-free algorithms" OFF)
 192
 193 # 3rd party libs
 194 OCV_OPTION(BUILD_ZLIB               "Build zlib from source"             WIN32 OR APPLE)
 195 OCV_OPTION(BUILD_TIFF               "Build libtiff from source"          WIN32 OR ANDROID OR APPLE)
 196 OCV_OPTION(BUILD_JASPER             "Build libjasper from source"        WIN32 OR ANDROID OR APPLE)
 197 OCV_OPTION(BUILD_JPEG               "Build libjpeg from source"          WIN32 OR ANDROID OR APPLE)
 198 OCV_OPTION(BUILD_PNG                "Build libpng from source"           WIN32 OR ANDROID OR APPLE)
 199 OCV_OPTION(BUILD_OPENEXR            "Build openexr from source"          (WIN32 OR ANDROID OR APPLE) AND NOT WINRT)
 200 OCV_OPTION(BUILD_WEBP               "Build WebP from source"             (WIN32 OR ANDROID OR APPLE) AND NOT WINRT)
 201 OCV_OPTION(BUILD_TBB                "Download and build TBB from source" ANDROID )
 202 OCV_OPTION(BUILD_IPP_IW             "Build IPP IW from source"           NOT MINGW IF (X86_64 OR X86) AND NOT WINRT )
 203 OCV_OPTION(BUILD_ITT                "Build Intel ITT from source"        NOT MINGW IF (X86_64 OR X86) AND NOT WINRT AND NOT APPLE_FRAMEWORK )
 204
 205 # Optional 3rd party components
 206 # ===================================================
 207 OCV_OPTION(WITH_1394           "Include IEEE1394 support"                    ON   IF (NOT ANDROID AND NOT IOS AND NOT WINRT) )
 208 OCV_OPTION(WITH_AVFOUNDATION   "Use AVFoundation for Video I/O (iOS/Mac)"    ON   IF APPLE)
 209 OCV_OPTION(WITH_CARBON         "Use Carbon for UI instead of Cocoa"          OFF  IF APPLE )
 210 OCV_OPTION(WITH_CAROTENE       "Use NVidia carotene acceleration library for ARM platform"                   ON  IF (ARM OR AARCH64) AND NOT IOS AND NOT (CMAKE_VERSION VERSION_LESS "2.8.11"))
 211 OCV_OPTION(WITH_CPUFEATURES    "Use cpufeatures Android library"             ON   IF ANDROID)
 212 OCV_OPTION(WITH_VTK            "Include VTK library support (and build opencv_viz module eiher)"             ON  IF (NOT ANDROID AND NOT IOS AND NOT WINRT AND NOT CMAKE_CROSSCOMPILING) )
 213 OCV_OPTION(WITH_CUDA           "Include NVidia Cuda Runtime support"                                         ON  IF (NOT IOS AND NOT WINRT) )
 214 OCV_OPTION(WITH_CUFFT          "Include NVidia Cuda Fast Fourier Transform (FFT) library support"            ON  IF (NOT IOS AND NOT WINRT) )
 215 OCV_OPTION(WITH_CUBLAS         "Include NVidia Cuda Basic Linear Algebra Subprograms (BLAS) library support" ON IF (NOT IOS AND NOT WINRT) )
 216 OCV_OPTION(WITH_NVCUVID        "Include NVidia Video Decoding library support"                               ON IF (NOT IOS AND NOT APPLE) )
 217 OCV_OPTION(WITH_EIGEN          "Include Eigen2/Eigen3 support"               (NOT CV_DISABLE_OPTIMIZATION)       IF (NOT WINRT AND NOT CMAKE_CROSSCOMPILING) )
 218 OCV_OPTION(WITH_VFW            "Include Video for Windows support"           ON   IF WIN32 )
 219 OCV_OPTION(WITH_FFMPEG         "Include FFMPEG support"                      ON   IF (NOT ANDROID AND NOT IOS AND NOT WINRT) )
 220 OCV_OPTION(WITH_GSTREAMER      "Include Gstreamer support"                   ON   IF (NOT ANDROID AND NOT IOS AND NOT WINRT) )
 221 OCV_OPTION(WITH_GSTREAMER_0_10 "Enable Gstreamer 0.10 support (instead of 1.x)"                              OFF )
 222 OCV_OPTION(WITH_GTK            "Include GTK support"                         ON   IF (UNIX AND NOT APPLE AND NOT ANDROID) )
 223 OCV_OPTION(WITH_GTK_2_X        "Use GTK version 2"                           OFF  IF (UNIX AND NOT APPLE AND NOT ANDROID) )
 224 OCV_OPTION(WITH_IPP            "Include Intel IPP support"                   (NOT MINGW AND NOT CV_DISABLE_OPTIMIZATION)  IF (X86_64 OR X86) AND NOT WINRT AND NOT IOS )
 225 OCV_OPTION(WITH_HALIDE         "Include Halide support"                      OFF)
 226 OCV_OPTION(WITH_JASPER         "Include JPEG2K support"                      ON   IF (NOT IOS) )
 227 OCV_OPTION(WITH_JPEG           "Include JPEG support"                        ON)
 228 OCV_OPTION(WITH_WEBP           "Include WebP support"                        ON   IF (NOT WINRT) )
 229 OCV_OPTION(WITH_OPENEXR        "Include ILM support via OpenEXR"             ON   IF (NOT IOS AND NOT WINRT) )
 230 OCV_OPTION(WITH_OPENGL         "Include OpenGL support"                      OFF  IF (NOT ANDROID AND NOT WINRT) )
 231 OCV_OPTION(WITH_OPENVX         "Include OpenVX support"                      OFF)
 232 OCV_OPTION(WITH_OPENNI         "Include OpenNI support"                      OFF  IF (NOT ANDROID AND NOT IOS AND NOT WINRT) )
 233 OCV_OPTION(WITH_OPENNI2        "Include OpenNI2 support"                     OFF  IF (NOT ANDROID AND NOT IOS AND NOT WINRT) )
 234 OCV_OPTION(WITH_PNG            "Include PNG support"                         ON)
 235 OCV_OPTION(WITH_GDCM           "Include DICOM support"                       OFF)
 236 OCV_OPTION(WITH_PVAPI          "Include Prosilica GigE support"              OFF   IF (NOT ANDROID AND NOT IOS AND NOT WINRT) )
 237 OCV_OPTION(WITH_GIGEAPI        "Include Smartek GigE support"                OFF   IF (NOT ANDROID AND NOT IOS AND NOT WINRT) )
 238 OCV_OPTION(WITH_ARAVIS         "Include Aravis GigE support"                 OFF   IF (NOT ANDROID AND NOT IOS AND NOT WINRT AND NOT WIN32) )
 239 OCV_OPTION(WITH_QT             "Build with Qt Backend support"               OFF  IF (NOT ANDROID AND NOT IOS AND NOT WINRT) )
 240 OCV_OPTION(WITH_WIN32UI        "Build with Win32 UI Backend support"         ON   IF WIN32 AND NOT WINRT)
 241 OCV_OPTION(WITH_QUICKTIME      "Use QuickTime for Video I/O"                 OFF  IF APPLE )
 242 OCV_OPTION(WITH_QTKIT          "Use QTKit Video I/O backend"                 OFF  IF APPLE )
 243 OCV_OPTION(WITH_TBB            "Include Intel TBB support"                   OFF  IF (NOT IOS AND NOT WINRT) )
 244 OCV_OPTION(WITH_OPENMP         "Include OpenMP support"                      OFF)
 245 OCV_OPTION(WITH_CSTRIPES       "Include C= support"                          OFF  IF (WIN32 AND NOT WINRT)  )
 246 OCV_OPTION(WITH_PTHREADS_PF    "Use pthreads-based parallel_for"             ON   IF (NOT WIN32 OR MINGW) )
 247 OCV_OPTION(WITH_TIFF           "Include TIFF support"                        ON   IF (NOT IOS) )
 248 OCV_OPTION(WITH_UNICAP         "Include Unicap support (GPL)"                OFF  IF (UNIX AND NOT APPLE AND NOT ANDROID) )
 249 OCV_OPTION(WITH_V4L            "Include Video 4 Linux support"               ON   IF (UNIX AND NOT ANDROID AND NOT APPLE) )
 250 OCV_OPTION(WITH_LIBV4L         "Use libv4l for Video 4 Linux support"        OFF  IF (UNIX AND NOT ANDROID AND NOT APPLE) )
 251 OCV_OPTION(WITH_DSHOW          "Build VideoIO with DirectShow support"       ON   IF (WIN32 AND NOT ARM AND NOT WINRT) )
 252 OCV_OPTION(WITH_MSMF           "Build VideoIO with Media Foundation support" OFF  IF WIN32 )
 253 OCV_OPTION(WITH_XIMEA          "Include XIMEA cameras support"               OFF  IF (NOT ANDROID AND NOT WINRT) )
 254 OCV_OPTION(WITH_XINE           "Include Xine support (GPL)"                  OFF  IF (UNIX AND NOT APPLE AND NOT ANDROID) )
 255 OCV_OPTION(WITH_CLP            "Include Clp support (EPL)"                   OFF)
 256 OCV_OPTION(WITH_OPENCL         "Include OpenCL Runtime support"              (NOT ANDROID AND NOT CV_DISABLE_OPTIMIZATION)  IF (NOT IOS AND NOT WINRT) )
 257 OCV_OPTION(WITH_OPENCL_SVM     "Include OpenCL Shared Virtual Memory support" OFF ) # experimental
 258 OCV_OPTION(WITH_OPENCLAMDFFT   "Include AMD OpenCL FFT library support"      ON   IF (NOT ANDROID AND NOT IOS AND NOT WINRT) )
 259 OCV_OPTION(WITH_OPENCLAMDBLAS  "Include AMD OpenCL BLAS library support"     ON   IF (NOT ANDROID AND NOT IOS AND NOT WINRT) )
 260 OCV_OPTION(WITH_DIRECTX        "Include DirectX support"                     ON   IF (WIN32 AND NOT WINRT) )
 261 OCV_OPTION(WITH_INTELPERC      "Include Intel Perceptual Computing support"  OFF  IF (WIN32 AND NOT WINRT) )
 262 OCV_OPTION(WITH_MATLAB         "Include Matlab support"                      ON   IF (NOT ANDROID AND NOT IOS AND NOT WINRT))
 263 OCV_OPTION(WITH_VA             "Include VA support"                          OFF  IF (UNIX AND NOT ANDROID) )
 264 OCV_OPTION(WITH_VA_INTEL       "Include Intel VA-API/OpenCL support"         OFF  IF (UNIX AND NOT ANDROID) )
 265 OCV_OPTION(WITH_MFX            "Include Intel Media SDK support"             OFF   IF ((UNIX AND NOT ANDROID) OR (WIN32 AND NOT WINRT AND NOT MINGW)) )
 266 OCV_OPTION(WITH_GDAL           "Include GDAL Support"                        OFF  IF (NOT ANDROID AND NOT IOS AND NOT WINRT) )
 267 OCV_OPTION(WITH_GPHOTO2        "Include gPhoto2 library support"             ON   IF (UNIX AND NOT ANDROID AND NOT IOS) )
 268 OCV_OPTION(WITH_LAPACK         "Include Lapack library support"              (NOT CV_DISABLE_OPTIMIZATION)  IF (NOT ANDROID AND NOT IOS) )
 269 OCV_OPTION(WITH_ITT            "Include Intel ITT support"                   ON   IF (NOT APPLE_FRAMEWORK) )
 270
 271 # OpenCV build components
 272 # ===================================================
 273 OCV_OPTION(BUILD_SHARED_LIBS        "Build shared libraries (.dll/.so) instead of static ones (.lib/.a)" NOT (ANDROID OR APPLE_FRAMEWORK) )
 274 OCV_OPTION(BUILD_opencv_apps        "Build utility applications (used for example to train classifiers)" (NOT ANDROID AND NOT WINRT) IF (NOT APPLE_FRAMEWORK) )
 275 OCV_OPTION(BUILD_opencv_js          "Build JavaScript bindings by Emscripten" OFF )
 276 OCV_OPTION(BUILD_ANDROID_EXAMPLES   "Build examples for Android platform"         ON  IF ANDROID )
 277 OCV_OPTION(BUILD_DOCS               "Create build rules for OpenCV Documentation" OFF  IF (NOT WINRT AND NOT APPLE_FRAMEWORK))
 278 OCV_OPTION(BUILD_EXAMPLES           "Build all examples"                          OFF )
 279 OCV_OPTION(BUILD_PACKAGE            "Enables 'make package_source' command"       ON  IF NOT WINRT)
 280 OCV_OPTION(BUILD_PERF_TESTS         "Build performance tests"                     ON  IF (NOT APPLE_FRAMEWORK) )
 281 OCV_OPTION(BUILD_TESTS              "Build accuracy & regression tests"           ON  IF (NOT APPLE_FRAMEWORK) )
 282 OCV_OPTION(BUILD_WITH_DEBUG_INFO    "Include debug info into debug libs (not MSCV only)" ON )
 283 OCV_OPTION(BUILD_WITH_STATIC_CRT    "Enables use of statically linked CRT for statically linked OpenCV" ON IF MSVC )
 284 OCV_OPTION(BUILD_WITH_DYNAMIC_IPP   "Enables dynamic linking of IPP (only for standalone IPP)" OFF )
 285 OCV_OPTION(BUILD_FAT_JAVA_LIB       "Create Java wrapper exporting all functions of OpenCV library (requires static build of OpenCV modules)" ANDROID IF NOT BUILD_SHARED_LIBS)
 286 OCV_OPTION(BUILD_ANDROID_SERVICE    "Build OpenCV Manager for Google Play" OFF IF ANDROID )
 287 OCV_OPTION(BUILD_CUDA_STUBS         "Build CUDA modules stubs when no CUDA SDK" OFF  IF (NOT APPLE_FRAMEWORK) )
 288 OCV_OPTION(BUILD_JAVA               "Enable Java support"                         (ANDROID OR NOT CMAKE_CROSSCOMPILING)  IF (ANDROID OR (NOT APPLE_FRAMEWORK AND NOT WINRT)) )
 289
 290 # OpenCV installation options
 291 # ===================================================
 292 OCV_OPTION(INSTALL_CREATE_DISTRIB   "Change install rules to build the distribution package" OFF )
 293 OCV_OPTION(INSTALL_C_EXAMPLES       "Install C examples"        OFF )
 294 OCV_OPTION(INSTALL_PYTHON_EXAMPLES  "Install Python examples"   OFF )
 295 OCV_OPTION(INSTALL_ANDROID_EXAMPLES "Install Android examples"  OFF IF ANDROID )
 296 OCV_OPTION(INSTALL_TO_MANGLED_PATHS "Enables mangled install paths, that help with side by side installs." OFF IF (UNIX AND NOT ANDROID AND NOT APPLE_FRAMEWORK AND BUILD_SHARED_LIBS) )
 297 OCV_OPTION(INSTALL_TESTS            "Install accuracy and performance test binaries and test data" OFF)
 298
 299 # OpenCV build options
 300 # ===================================================
 301 OCV_OPTION(ENABLE_CCACHE              "Use ccache"                                               (UNIX AND NOT IOS AND (CMAKE_GENERATOR MATCHES "Makefile" OR CMAKE_GENERATOR MATCHES "Ninja")) )
 302 OCV_OPTION(ENABLE_PRECOMPILED_HEADERS "Use precompiled headers"                                  ON IF (NOT IOS AND NOT CMAKE_CROSSCOMPILING) )
 303 OCV_OPTION(ENABLE_SOLUTION_FOLDERS    "Solution folder in Visual Studio or in other IDEs"        (MSVC_IDE OR CMAKE_GENERATOR MATCHES Xcode) )
 304 OCV_OPTION(ENABLE_PROFILING           "Enable profiling in the GCC compiler (Add flags: -g -pg)" OFF  IF CMAKE_COMPILER_IS_GNUCXX )
 305 OCV_OPTION(ENABLE_COVERAGE            "Enable coverage collection with  GCov"                    OFF  IF CMAKE_COMPILER_IS_GNUCXX )
 306 OCV_OPTION(ENABLE_OMIT_FRAME_POINTER  "Enable -fomit-frame-pointer for GCC"                      ON   IF CMAKE_COMPILER_IS_GNUCXX AND NOT (APPLE AND CMAKE_COMPILER_IS_CLANGCXX) )
 307 OCV_OPTION(ENABLE_POWERPC             "Enable PowerPC for GCC"                                   ON   IF (CMAKE_COMPILER_IS_GNUCXX AND CMAKE_SYSTEM_PROCESSOR MATCHES powerpc.*) )
 308 OCV_OPTION(ENABLE_VSX                 "Enable POWER8 and above VSX (64-bit little-endian)"       ON   IF (CMAKE_COMPILER_IS_GNUCXX AND PPC64LE) )
 309 OCV_OPTION(ENABLE_FAST_MATH           "Enable -ffast-math (not recommended for GCC 4.6.x)"       OFF  IF (CMAKE_COMPILER_IS_GNUCXX AND (X86 OR X86_64)) )
 310 OCV_OPTION(ENABLE_NEON                "Enable NEON instructions"                                 (NEON OR ANDROID_ARM_NEON OR AARCH64) IF CMAKE_COMPILER_IS_GNUCXX AND (ARM OR AARCH64 OR IOS) )
 311 OCV_OPTION(ENABLE_VFPV3               "Enable VFPv3-D32 instructions"                            OFF  IF CMAKE_COMPILER_IS_GNUCXX AND (ARM OR AARCH64 OR IOS) )
 312 OCV_OPTION(ENABLE_NOISY_WARNINGS      "Show all warnings even if they are too noisy"             OFF )
 313 OCV_OPTION(OPENCV_WARNINGS_ARE_ERRORS "Treat warnings as errors"                                 OFF )
 314 OCV_OPTION(ANDROID_EXAMPLES_WITH_LIBS "Build binaries of Android examples with native libraries" OFF  IF ANDROID )
 315 OCV_OPTION(ENABLE_IMPL_COLLECTION     "Collect implementation data on function call"             OFF )
 316 OCV_OPTION(ENABLE_INSTRUMENTATION     "Instrument functions to collect calls trace and performance" OFF )
 317 OCV_OPTION(ENABLE_GNU_STL_DEBUG       "Enable GNU STL Debug mode (defines _GLIBCXX_DEBUG)"       OFF IF ((NOT CMAKE_VERSION VERSION_LESS "2.8.11") AND CMAKE_COMPILER_IS_GNUCXX) )
 318 OCV_OPTION(ENABLE_BUILD_HARDENING     "Enable hardening of the resulting binaries (against security attacks, detects memory corruption, etc)" OFF)
 319 OCV_OPTION(ENABLE_LTO                 "Enable Link Time Optimization" OFF IF CMAKE_COMPILER_IS_GNUCXX OR MSVC)
 320 OCV_OPTION(ENABLE_THIN_LTO            "Enable Thin LTO" OFF IF CMAKE_COMPILER_IS_CLANGCXX)
 321 OCV_OPTION(GENERATE_ABI_DESCRIPTOR    "Generate XML file for abi_compliance_checker tool" OFF IF UNIX)
 322 OCV_OPTION(CV_ENABLE_INTRINSICS       "Use intrinsic-based optimized code" ON )
 323 OCV_OPTION(CV_DISABLE_OPTIMIZATION    "Disable explicit optimized code (dispatched code/intrinsics/loop unrolling/etc)" OFF )
 324 OCV_OPTION(CV_TRACE                   "Enable OpenCV code trace" ON)
 325
 326 OCV_OPTION(ENABLE_PYLINT              "Add target with Pylint checks"                            (${BUILD_DOCS} OR ${BUILD_EXAMPLES}) IF (NOT CMAKE_CROSSCOMPILING AND NOT APPLE_FRAMEWORK) )
 327
 328 if(ENABLE_IMPL_COLLECTION)
 329   add_definitions(-DCV_COLLECT_IMPL_DATA)
 330 endif()
 331
 332
 333 # ----------------------------------------------------------------------------
 334 #  Get actual OpenCV version number from sources
 335 # ----------------------------------------------------------------------------
 336 include(cmake/OpenCVVersion.cmake)
 337
 338
 339 # ----------------------------------------------------------------------------
 340 #  Build & install layouts
 341 # ----------------------------------------------------------------------------
 342
 343 # Save libs and executables in the same place
 344 set(EXECUTABLE_OUTPUT_PATH "${CMAKE_BINARY_DIR}/bin" CACHE PATH "Output directory for applications")
 345
 346 if(ANDROID)
 347   if(ANDROID_ABI MATCHES "NEON")
 348     set(ENABLE_NEON ON)
 349   endif()
 350   if(ANDROID_ABI MATCHES "VFPV3")
 351     set(ENABLE_VFPV3 ON)
 352   endif()
 353 endif()
 354
 355 if(ANDROID OR WIN32)
 356   ocv_update(OPENCV_DOC_INSTALL_PATH doc)
 357 else()
 358   ocv_update(OPENCV_DOC_INSTALL_PATH share/OpenCV/doc)
 359 endif()
 360
 361 if(WIN32 AND CMAKE_HOST_SYSTEM_NAME MATCHES Windows)
 362   if(DEFINED OpenCV_RUNTIME AND DEFINED OpenCV_ARCH)
 363     ocv_update(OpenCV_INSTALL_BINARIES_PREFIX "${OpenCV_ARCH}/${OpenCV_RUNTIME}/")
 364   else()
 365     message(STATUS "Can't detect runtime and/or arch")
 366     ocv_update(OpenCV_INSTALL_BINARIES_PREFIX "")
 367   endif()
 368 elseif(ANDROID)
 369   ocv_update(OpenCV_INSTALL_BINARIES_PREFIX "sdk/native/")
 370 else()
 371   ocv_update(OpenCV_INSTALL_BINARIES_PREFIX "")
 372 endif()
 373
 374 if(ANDROID)
 375   ocv_update(OPENCV_SAMPLES_BIN_INSTALL_PATH "${OpenCV_INSTALL_BINARIES_PREFIX}samples/${ANDROID_NDK_ABI_NAME}")
 376 else()
 377   ocv_update(OPENCV_SAMPLES_BIN_INSTALL_PATH "${OpenCV_INSTALL_BINARIES_PREFIX}samples")
 378 endif()
 379
 380 if(ANDROID)
 381   ocv_update(OPENCV_BIN_INSTALL_PATH "${OpenCV_INSTALL_BINARIES_PREFIX}bin/${ANDROID_NDK_ABI_NAME}")
 382 else()
 383   ocv_update(OPENCV_BIN_INSTALL_PATH "${OpenCV_INSTALL_BINARIES_PREFIX}bin")
 384 endif()
 385
 386 if(NOT OPENCV_TEST_INSTALL_PATH)
 387   ocv_update(OPENCV_TEST_INSTALL_PATH "${OPENCV_BIN_INSTALL_PATH}")
 388 endif()
 389
 390 if (OPENCV_TEST_DATA_PATH)
 391   get_filename_component(OPENCV_TEST_DATA_PATH ${OPENCV_TEST_DATA_PATH} ABSOLUTE)
 392 endif()
 393
 394 if(ANDROID)
 395   ocv_update(OPENCV_TEST_DATA_INSTALL_PATH "sdk/etc/testdata")
 396 elseif(WIN32)
 397   ocv_update(OPENCV_TEST_DATA_INSTALL_PATH "testdata")
 398 else()
 399   ocv_update(OPENCV_TEST_DATA_INSTALL_PATH "share/OpenCV/testdata")
 400 endif()
 401
 402 if(ANDROID)
 403   set(LIBRARY_OUTPUT_PATH                "${OpenCV_BINARY_DIR}/lib/${ANDROID_NDK_ABI_NAME}")
 404   ocv_update(3P_LIBRARY_OUTPUT_PATH      "${OpenCV_BINARY_DIR}/3rdparty/lib/${ANDROID_NDK_ABI_NAME}")
 405   ocv_update(OPENCV_LIB_INSTALL_PATH     sdk/native/libs/${ANDROID_NDK_ABI_NAME})
 406   ocv_update(OPENCV_3P_LIB_INSTALL_PATH  sdk/native/3rdparty/libs/${ANDROID_NDK_ABI_NAME})
 407   ocv_update(OPENCV_CONFIG_INSTALL_PATH  sdk/native/jni)
 408   ocv_update(OPENCV_INCLUDE_INSTALL_PATH sdk/native/jni/include)
 409   ocv_update(OPENCV_SAMPLES_SRC_INSTALL_PATH samples/native)
 410   ocv_update(OPENCV_OTHER_INSTALL_PATH   sdk/etc)
 411 else()
 412   set(LIBRARY_OUTPUT_PATH                "${OpenCV_BINARY_DIR}/lib")
 413   ocv_update(3P_LIBRARY_OUTPUT_PATH      "${OpenCV_BINARY_DIR}/3rdparty/lib${LIB_SUFFIX}")
 414
 415   if(WIN32 AND CMAKE_HOST_SYSTEM_NAME MATCHES Windows)
 416     if(OpenCV_STATIC)
 417       ocv_update(OPENCV_LIB_INSTALL_PATH   "${OpenCV_INSTALL_BINARIES_PREFIX}staticlib${LIB_SUFFIX}")
 418     else()
 419       ocv_update(OPENCV_LIB_INSTALL_PATH   "${OpenCV_INSTALL_BINARIES_PREFIX}lib${LIB_SUFFIX}")
 420     endif()
 421     ocv_update(OPENCV_3P_LIB_INSTALL_PATH  "${OpenCV_INSTALL_BINARIES_PREFIX}staticlib${LIB_SUFFIX}")
 422     ocv_update(OPENCV_SAMPLES_SRC_INSTALL_PATH    samples/native)
 423     ocv_update(OPENCV_JAR_INSTALL_PATH java)
 424     ocv_update(OPENCV_OTHER_INSTALL_PATH   etc)
 425     ocv_update(OPENCV_CONFIG_INSTALL_PATH  ".")
 426   else()
 427     include(GNUInstallDirs)
 428     ocv_update(OPENCV_LIB_INSTALL_PATH     ${CMAKE_INSTALL_LIBDIR}${LIB_SUFFIX})
 429     ocv_update(OPENCV_3P_LIB_INSTALL_PATH  share/OpenCV/3rdparty/${OPENCV_LIB_INSTALL_PATH})
 430     ocv_update(OPENCV_SAMPLES_SRC_INSTALL_PATH    share/OpenCV/samples)
 431     ocv_update(OPENCV_JAR_INSTALL_PATH share/OpenCV/java)
 432     ocv_update(OPENCV_OTHER_INSTALL_PATH   share/OpenCV)
 433
 434     if(NOT DEFINED OPENCV_CONFIG_INSTALL_PATH)
 435       math(EXPR SIZEOF_VOID_P_BITS "8 * ${CMAKE_SIZEOF_VOID_P}")
 436       if(LIB_SUFFIX AND NOT SIZEOF_VOID_P_BITS EQUAL LIB_SUFFIX)
 437         ocv_update(OPENCV_CONFIG_INSTALL_PATH ${CMAKE_INSTALL_LIBDIR}${LIB_SUFFIX}/cmake/opencv)
 438       else()
 439         ocv_update(OPENCV_CONFIG_INSTALL_PATH share/OpenCV)
 440       endif()
 441     endif()
 442   endif()
 443   ocv_update(OPENCV_INCLUDE_INSTALL_PATH "include")
 444 endif()
 445
 446 ocv_update(CMAKE_INSTALL_RPATH "${CMAKE_INSTALL_PREFIX}/${OPENCV_LIB_INSTALL_PATH}")
 447 set(CMAKE_INSTALL_RPATH_USE_LINK_PATH TRUE)
 448
 449 if(INSTALL_TO_MANGLED_PATHS)
 450   set(OPENCV_INCLUDE_INSTALL_PATH ${OPENCV_INCLUDE_INSTALL_PATH}/opencv-${OPENCV_VERSION})
 451   foreach(v
 452       OPENCV_3P_LIB_INSTALL_PATH
 453       OPENCV_SAMPLES_SRC_INSTALL_PATH
 454       OPENCV_CONFIG_INSTALL_PATH
 455       OPENCV_DOC_INSTALL_PATH
 456       OPENCV_JAR_INSTALL_PATH
 457       OPENCV_TEST_DATA_INSTALL_PATH
 458       OPENCV_OTHER_INSTALL_PATH
 459     )
 460     string(REPLACE "OpenCV" "OpenCV-${OPENCV_VERSION}" ${v} "${${v}}")
 461     string(REPLACE "opencv" "opencv-${OPENCV_VERSION}" ${v} "${${v}}")
 462   endforeach()
 463 endif()
 464
 465 if(ANDROID)
 466   ocv_update(OPENCV_JNI_INSTALL_PATH "${OPENCV_LIB_INSTALL_PATH}")
 467 elseif(INSTALL_CREATE_DISTRIB)
 468   ocv_update(OPENCV_JNI_INSTALL_PATH "${OPENCV_JAR_INSTALL_PATH}/${OpenCV_ARCH}")
 469 else()
 470   ocv_update(OPENCV_JNI_INSTALL_PATH "${OPENCV_JAR_INSTALL_PATH}")
 471 endif()
 472 ocv_update(OPENCV_JNI_BIN_INSTALL_PATH "${OPENCV_JNI_INSTALL_PATH}")
 473
 474 if(WIN32)
 475   # Postfix of DLLs:
 476   set(OPENCV_DLLVERSION "${OPENCV_VERSION_MAJOR}${OPENCV_VERSION_MINOR}${OPENCV_VERSION_PATCH}")
 477   set(OPENCV_DEBUG_POSTFIX d)
 478 else()
 479   # Postfix of so's:
 480   set(OPENCV_DLLVERSION "")
 481   set(OPENCV_DEBUG_POSTFIX "")
 482 endif()
 483
 484 if(DEFINED CMAKE_DEBUG_POSTFIX)
 485   set(OPENCV_DEBUG_POSTFIX "${CMAKE_DEBUG_POSTFIX}")
 486 endif()
 487
 488 if((INSTALL_CREATE_DISTRIB AND BUILD_SHARED_LIBS AND NOT DEFINED BUILD_opencv_world) OR APPLE_FRAMEWORK)
 489   set(BUILD_opencv_world ON CACHE INTERNAL "")
 490 endif()
 491
 492 # ----------------------------------------------------------------------------
 493 #  Path for build/platform -specific headers
 494 # ----------------------------------------------------------------------------
 495 ocv_update(OPENCV_CONFIG_FILE_INCLUDE_DIR "${CMAKE_BINARY_DIR}/" CACHE PATH "Where to create the platform-dependant cvconfig.h")
 496 ocv_include_directories(${OPENCV_CONFIG_FILE_INCLUDE_DIR})
 497
 498 # ----------------------------------------------------------------------------
 499 #  Path for additional modules
 500 # ----------------------------------------------------------------------------
 501 set(OPENCV_EXTRA_MODULES_PATH "" CACHE PATH "Where to look for additional OpenCV modules (can be ;-separated list of paths)")
 502
 503 # ----------------------------------------------------------------------------
 504 #  Autodetect if we are in a GIT repository
 505 # ----------------------------------------------------------------------------
 506 find_host_package(Git QUIET)
 507
 508 if(NOT DEFINED OPENCV_VCSVERSION AND GIT_FOUND)
 509   execute_process(COMMAND "${GIT_EXECUTABLE}" describe --tags --always --dirty --match "[0-9].[0-9].[0-9]*"
 510     WORKING_DIRECTORY "${OpenCV_SOURCE_DIR}"
 511     OUTPUT_VARIABLE OPENCV_VCSVERSION
 512     RESULT_VARIABLE GIT_RESULT
 513     ERROR_QUIET
 514     OUTPUT_STRIP_TRAILING_WHITESPACE
 515   )
 516   if(NOT GIT_RESULT EQUAL 0)
 517     set(OPENCV_VCSVERSION "unknown")
 518   endif()
 519 elseif(NOT DEFINED OPENCV_VCSVERSION)
 520   # We don't have git:
 521   set(OPENCV_VCSVERSION "unknown")
 522 endif()
 523
 524
 525 # ----------------------------------------------------------------------------
 526 # OpenCV compiler and linker options
 527 # ----------------------------------------------------------------------------
 528 # In case of Makefiles if the user does not setup CMAKE_BUILD_TYPE, assume it's Release:
 529 if(CMAKE_GENERATOR MATCHES "Makefiles|Ninja" AND "${CMAKE_BUILD_TYPE}" STREQUAL "")
 530   set(CMAKE_BUILD_TYPE Release)
 531 endif()
 532
 533 # --- Python Support ---
 534 if(NOT IOS)
 535   include(cmake/OpenCVDetectPython.cmake)
 536 endif()
 537
 538 include(cmake/OpenCVCompilerOptions.cmake)
 539
 540
 541 # ----------------------------------------------------------------------------
 542 # Use statically or dynamically linked CRT?
 543 # Default: dynamic
 544 # ----------------------------------------------------------------------------
 545 if(MSVC)
 546   include(cmake/OpenCVCRTLinkage.cmake)
 547 endif(MSVC)
 548
 549 if(WIN32 AND NOT MINGW)
 550   add_definitions(-D_VARIADIC_MAX=10)
 551 endif(WIN32 AND NOT MINGW)
 552
 553
 554 # ----------------------------------------------------------------------------
 555 #       CHECK FOR SYSTEM LIBRARIES, OPTIONS, ETC..
 556 # ----------------------------------------------------------------------------
 557 if(UNIX)
 558   if(NOT APPLE_FRAMEWORK OR OPENCV_ENABLE_PKG_CONFIG)
 559     if(CMAKE_CROSSCOMPILING AND NOT DEFINED ENV{PKG_CONFIG_LIBDIR}
 560         AND NOT OPENCV_ENABLE_PKG_CONFIG
 561     )
 562       if(NOT PkgConfig_FOUND)
 563         message(STATUS "OpenCV disables pkg-config to avoid using of host libraries. Consider using PKG_CONFIG_LIBDIR to specify target SYSROOT")
 564       elseif(OPENCV_SKIP_PKG_CONFIG_WARNING)
 565         message(WARNING "pkg-config is enabled in cross-compilation mode without defining of PKG_CONFIG_LIBDIR environment variable. This may lead to misconfigured host-based dependencies.")
 566       endif()
 567     elseif(OPENCV_DISABLE_PKG_CONFIG)
 568       if(PkgConfig_FOUND)
 569         message(WARNING "OPENCV_DISABLE_PKG_CONFIG flag has no effect")
 570       endif()
 571     else()
 572       find_package(PkgConfig QUIET)
 573     endif()
 574   endif()
 575   include(CheckFunctionExists)
 576   include(CheckIncludeFile)
 577   include(CheckSymbolExists)
 578
 579   if(NOT APPLE)
 580     CHECK_INCLUDE_FILE(pthread.h HAVE_PTHREAD)
 581     if(ANDROID)
 582       set(OPENCV_LINKER_LIBS ${OPENCV_LINKER_LIBS} dl m log)
 583     elseif(${CMAKE_SYSTEM_NAME} MATCHES "FreeBSD|NetBSD|DragonFly|OpenBSD|Haiku")
 584       set(OPENCV_LINKER_LIBS ${OPENCV_LINKER_LIBS} m pthread)
 585     elseif(EMSCRIPTEN)
 586       # no need to link to system libs with emscripten
 587     else()
 588       set(OPENCV_LINKER_LIBS ${OPENCV_LINKER_LIBS} dl m pthread rt)
 589     endif()
 590   else()
 591     set(HAVE_PTHREAD 1)
 592   endif()
 593
 594   CHECK_SYMBOL_EXISTS(posix_memalign stdlib.h HAVE_POSIX_MEMALIGN)
 595   CHECK_INCLUDE_FILE(malloc.h HAVE_MALLOC_H)
 596   if(HAVE_MALLOC_H)
 597     CHECK_SYMBOL_EXISTS(memalign malloc.h HAVE_MEMALIGN)
 598   endif()
 599 endif()
 600
 601 include(cmake/OpenCVPCHSupport.cmake)
 602 include(cmake/OpenCVModule.cmake)
 603
 604 # ----------------------------------------------------------------------------
 605 #  Detect endianness of build platform
 606 # ----------------------------------------------------------------------------
 607
 608 if(IOS)
 609   # test_big_endian needs try_compile, which doesn't work for iOS
 610   # http://public.kitware.com/Bug/view.php?id=12288
 611   set(WORDS_BIGENDIAN 0)
 612 else()
 613   include(TestBigEndian)
 614   test_big_endian(WORDS_BIGENDIAN)
 615 endif()
 616
 617 # ----------------------------------------------------------------------------
 618 #  Detect 3rd-party libraries
 619 # ----------------------------------------------------------------------------
 620
 621 if(ANDROID AND WITH_CPUFEATURES)
 622   add_subdirectory(3rdparty/cpufeatures)
 623   set(HAVE_CPUFEATURES 1)
 624 endif()
 625
 626 include(cmake/OpenCVFindLibsGrfmt.cmake)
 627 include(cmake/OpenCVFindLibsGUI.cmake)
 628 include(cmake/OpenCVFindLibsVideo.cmake)
 629 include(cmake/OpenCVFindLibsPerf.cmake)
 630 include(cmake/OpenCVFindLAPACK.cmake)
 631 include(cmake/OpenCVFindProtobuf.cmake)
 632
 633 # ----------------------------------------------------------------------------
 634 #  Detect other 3rd-party libraries/tools
 635 # ----------------------------------------------------------------------------
 636
 637 # --- Java Support ---
 638 if(BUILD_JAVA)
 639   include(cmake/OpenCVDetectApacheAnt.cmake)
 640   if(ANDROID)
 641     include(cmake/OpenCVDetectAndroidSDK.cmake)
 642
 643     if(NOT ANDROID_TOOLS_Pkg_Revision GREATER 13)
 644       message(WARNING "OpenCV requires Android SDK tools revision 14 or newer. Otherwise tests and samples will no be compiled.")
 645     endif()
 646   else()
 647     find_package(JNI)
 648   endif()
 649 endif()
 650
 651 if(ENABLE_PYLINT)
 652   include(cmake/OpenCVPylint.cmake)
 653 endif()
 654
 655
 656 if(ANDROID AND ANDROID_EXECUTABLE AND ANT_EXECUTABLE AND (ANT_VERSION VERSION_GREATER 1.7) AND (ANDROID_TOOLS_Pkg_Revision GREATER 13))
 657   SET(CAN_BUILD_ANDROID_PROJECTS TRUE)
 658 else()
 659   SET(CAN_BUILD_ANDROID_PROJECTS FALSE)
 660 endif()
 661
 662 # --- OpenCL ---
 663 if(WITH_OPENCL)
 664   include(cmake/OpenCVDetectOpenCL.cmake)
 665 endif()
 666
 667 # --- Halide ---
 668 if(WITH_HALIDE)
 669   include(cmake/OpenCVDetectHalide.cmake)
 670 endif()
 671
 672 # --- DirectX ---
 673 if(WITH_DIRECTX)
 674   include(cmake/OpenCVDetectDirectX.cmake)
 675 endif()
 676
 677 # --- Matlab/Octave ---
 678 if(WITH_MATLAB)
 679   include(cmake/OpenCVFindMatlab.cmake)
 680 endif()
 681
 682 if(WITH_VTK)
 683   include(cmake/OpenCVDetectVTK.cmake)
 684 endif()
 685
 686 if(WITH_OPENVX)
 687   include(cmake/FindOpenVX.cmake)
 688 endif()
 689
 690 # ----------------------------------------------------------------------------
 691 # OpenCV HAL
 692 # ----------------------------------------------------------------------------
 693 set(_hal_includes "")
 694 macro(ocv_hal_register HAL_LIBRARIES_VAR HAL_HEADERS_VAR HAL_INCLUDE_DIRS_VAR)
 695   # 1. libraries
 696   foreach (l ${${HAL_LIBRARIES_VAR}})
 697     if(NOT TARGET ${l})
 698       get_filename_component(l "${l}" ABSOLUTE)
 699     endif()
 700     list(APPEND OPENCV_HAL_LINKER_LIBS ${l})
 701   endforeach()
 702   # 2. headers
 703   foreach (h ${${HAL_HEADERS_VAR}})
 704     set(_hal_includes "${_hal_includes}\n#include \"${h}\"")
 705   endforeach()
 706   # 3. include paths
 707   ocv_include_directories(${${HAL_INCLUDE_DIRS_VAR}})
 708 endmacro()
 709
 710 if(NOT DEFINED OpenCV_HAL)
 711   set(OpenCV_HAL "OpenCV_HAL")
 712 endif()
 713
 714 if(HAVE_OPENVX)
 715   if(NOT ";${OpenCV_HAL};" MATCHES ";openvx;")
 716     set(OpenCV_HAL "openvx;${OpenCV_HAL}")
 717   endif()
 718 endif()
 719
 720 if(WITH_CAROTENE)
 721   ocv_debug_message(STATUS "Enable carotene acceleration")
 722   if(NOT ";${OpenCV_HAL};" MATCHES ";carotene;")
 723     set(OpenCV_HAL "carotene;${OpenCV_HAL}")
 724   endif()
 725 endif()
 726
 727 foreach(hal ${OpenCV_HAL})
 728   if(hal STREQUAL "carotene")
 729     add_subdirectory(3rdparty/carotene/hal)
 730     ocv_hal_register(CAROTENE_HAL_LIBRARIES CAROTENE_HAL_HEADERS CAROTENE_HAL_INCLUDE_DIRS)
 731     list(APPEND OpenCV_USED_HAL "carotene (ver ${CAROTENE_HAL_VERSION})")
 732   elseif(hal STREQUAL "openvx")
 733     add_subdirectory(3rdparty/openvx)
 734     ocv_hal_register(OPENVX_HAL_LIBRARIES OPENVX_HAL_HEADERS OPENVX_HAL_INCLUDE_DIRS)
 735     list(APPEND OpenCV_USED_HAL "openvx (ver ${OPENVX_HAL_VERSION})")
 736   else()
 737     ocv_debug_message(STATUS "OpenCV HAL: ${hal} ...")
 738     ocv_clear_vars(OpenCV_HAL_LIBRARIES OpenCV_HAL_HEADERS OpenCV_HAL_INCLUDE_DIRS)
 739     find_package(${hal} NO_MODULE QUIET)
 740     if(${hal}_FOUND)
 741       ocv_hal_register(OpenCV_HAL_LIBRARIES OpenCV_HAL_HEADERS OpenCV_HAL_INCLUDE_DIRS)
 742       list(APPEND OpenCV_USED_HAL "${hal} (ver ${${hal}_VERSION})")
 743     endif()
 744   endif()
 745 endforeach()
 746 configure_file("${OpenCV_SOURCE_DIR}/cmake/templates/custom_hal.hpp.in" "${CMAKE_BINARY_DIR}/custom_hal.hpp" @ONLY)
 747 unset(_hal_includes)
 748
 749
 750 # ----------------------------------------------------------------------------
 751 # Add CUDA libraries (needed for apps/tools, samples)
 752 # ----------------------------------------------------------------------------
 753 if(HAVE_CUDA)
 754   set(OPENCV_LINKER_LIBS ${OPENCV_LINKER_LIBS} ${CUDA_LIBRARIES} ${CUDA_npp_LIBRARY})
 755   if(HAVE_CUBLAS)
 756     set(OPENCV_LINKER_LIBS ${OPENCV_LINKER_LIBS} ${CUDA_cublas_LIBRARY})
 757   endif()
 758   if(HAVE_CUFFT)
 759     set(OPENCV_LINKER_LIBS ${OPENCV_LINKER_LIBS} ${CUDA_cufft_LIBRARY})
 760   endif()
 761   foreach(p ${CUDA_LIBS_PATH})
 762     if(MSVC AND CMAKE_GENERATOR MATCHES "Ninja|JOM")
 763       set(OPENCV_LINKER_LIBS ${OPENCV_LINKER_LIBS} ${CMAKE_LIBRARY_PATH_FLAG}"${p}")
 764     else()
 765       set(OPENCV_LINKER_LIBS ${OPENCV_LINKER_LIBS} ${CMAKE_LIBRARY_PATH_FLAG}${p})
 766     endif()
 767   endforeach()
 768 endif()
 769
 770
 771 # ----------------------------------------------------------------------------
 772 # Code trace support
 773 # ----------------------------------------------------------------------------
 774 if(CV_TRACE)
 775   include(cmake/OpenCVDetectTrace.cmake)
 776 endif()
 777
 778
 779 # ----------------------------------------------------------------------------
 780 # Solution folders:
 781 # ----------------------------------------------------------------------------
 782 if(ENABLE_SOLUTION_FOLDERS)
 783   set_property(GLOBAL PROPERTY USE_FOLDERS ON)
 784   set_property(GLOBAL PROPERTY PREDEFINED_TARGETS_FOLDER "CMakeTargets")
 785 endif()
 786
 787 # Extra OpenCV targets: uninstall, package_source, perf, etc.
 788 include(cmake/OpenCVExtraTargets.cmake)
 789
 790 # ----------------------------------------------------------------------------
 791 # Process subdirectories
 792 # ----------------------------------------------------------------------------
 793
 794 # opencv.hpp and legacy headers
 795 add_subdirectory(include)
 796
 797 # OpenCV modules
 798 add_subdirectory(modules)
 799
 800 # Generate targets for documentation
 801 add_subdirectory(doc)
 802
 803 # various data that is used by cv libraries and/or demo applications.
 804 add_subdirectory(data)
 805
 806 # extra applications
 807 if(BUILD_opencv_apps)
 808   add_subdirectory(apps)
 809 endif()
 810
 811 # examples
 812 if(BUILD_EXAMPLES OR BUILD_ANDROID_EXAMPLES OR INSTALL_PYTHON_EXAMPLES)
 813   add_subdirectory(samples)
 814 endif()
 815
 816 if(ANDROID)
 817   add_subdirectory(platforms/android/service)
 818 endif()
 819
 820 # ----------------------------------------------------------------------------
 821 # Finalization: generate configuration-based files
 822 # ----------------------------------------------------------------------------
 823
 824 # Generate platform-dependent and configuration-dependent headers
 825 include(cmake/OpenCVGenHeaders.cmake)
 826
 827 # Generate opencv.pc for pkg-config command
 828 if(NOT OPENCV_SKIP_PKGCONFIG_GENERATION
 829     AND NOT CMAKE_GENERATOR MATCHES "Xcode")
 830   include(cmake/OpenCVGenPkgconfig.cmake)
 831 endif()
 832
 833 # Generate OpenCV.mk for ndk-build (Android build tool)
 834 include(cmake/OpenCVGenAndroidMK.cmake)
 835
 836 # Generate OpenCVConfig.cmake and OpenCVConfig-version.cmake for cmake projects
 837 include(cmake/OpenCVGenConfig.cmake)
 838
 839 # Generate Info.plist for the IOS framework
 840 if(APPLE_FRAMEWORK)
 841   include(cmake/OpenCVGenInfoPlist.cmake)
 842 endif()
 843
 844 # Generate ABI descriptor
 845 include(cmake/OpenCVGenABI.cmake)
 846
 847 # Generate environment setup file
 848 if(INSTALL_TESTS AND OPENCV_TEST_DATA_PATH)
 849   if(ANDROID)
 850     get_filename_component(TEST_PATH ${OPENCV_TEST_INSTALL_PATH} DIRECTORY)
 851     configure_file("${CMAKE_CURRENT_SOURCE_DIR}/cmake/templates/opencv_run_all_tests_android.sh.in"
 852                    "${CMAKE_BINARY_DIR}/unix-install/opencv_run_all_tests.sh" @ONLY)
 853     install(PROGRAMS "${CMAKE_BINARY_DIR}/unix-install/opencv_run_all_tests.sh"
 854             DESTINATION ./ COMPONENT tests)
 855   elseif(WIN32)
 856     configure_file("${CMAKE_CURRENT_SOURCE_DIR}/cmake/templates/opencv_run_all_tests_windows.cmd.in"
 857                    "${CMAKE_BINARY_DIR}/win-install/opencv_run_all_tests.cmd" @ONLY)
 858     install(PROGRAMS "${CMAKE_BINARY_DIR}/win-install/opencv_run_all_tests.cmd"
 859             DESTINATION ${OPENCV_TEST_INSTALL_PATH} COMPONENT tests)
 860   elseif(UNIX)
 861     configure_file("${CMAKE_CURRENT_SOURCE_DIR}/cmake/templates/opencv_run_all_tests_unix.sh.in"
 862                    "${CMAKE_BINARY_DIR}/unix-install/opencv_run_all_tests.sh" @ONLY)
 863     install(PROGRAMS "${CMAKE_BINARY_DIR}/unix-install/opencv_run_all_tests.sh"
 864             DESTINATION ${OPENCV_TEST_INSTALL_PATH} COMPONENT tests)
 865   endif()
 866 endif()
 867
 868 if(NOT OPENCV_README_FILE)
 869   if(ANDROID)
 870     set(OPENCV_README_FILE ${CMAKE_CURRENT_SOURCE_DIR}/platforms/android/README.android)
 871   endif()
 872 endif()
 873
 874 if(NOT OPENCV_LICENSE_FILE)
 875   set(OPENCV_LICENSE_FILE ${CMAKE_CURRENT_SOURCE_DIR}/LICENSE)
 876 endif()
 877
 878 # for UNIX it does not make sense as LICENSE and readme will be part of the package automatically
 879 if(ANDROID OR NOT UNIX)
 880   install(FILES ${OPENCV_LICENSE_FILE}
 881         PERMISSIONS OWNER_READ GROUP_READ WORLD_READ
 882         DESTINATION ./ COMPONENT libs)
 883   if(OPENCV_README_FILE)
 884     install(FILES ${OPENCV_README_FILE}
 885             PERMISSIONS OWNER_READ GROUP_READ WORLD_READ
 886             DESTINATION ./ COMPONENT libs)
 887   endif()
 888 endif()
 889
 890 if(COMMAND ocv_pylint_finalize)
 891   ocv_pylint_add_directory(${CMAKE_CURRENT_LIST_DIR}/modules/python/test)
 892   ocv_pylint_add_directory(${CMAKE_CURRENT_LIST_DIR}/samples/python)
 893   ocv_pylint_add_directory(${CMAKE_CURRENT_LIST_DIR}/samples/dnn)
 894   ocv_pylint_add_directory_recurse(${CMAKE_CURRENT_LIST_DIR}/samples/python/tutorial_code)
 895   ocv_pylint_finalize()
 896 endif()
 897
 898 # ----------------------------------------------------------------------------
 899 # Summary:
 900 # ----------------------------------------------------------------------------
 901 status("")
 902 status("General configuration for OpenCV ${OPENCV_VERSION} =====================================")
 903 if(OPENCV_VCSVERSION)
 904   status("  Version control:" ${OPENCV_VCSVERSION})
 905 endif()
 906 if(OPENCV_EXTRA_MODULES_PATH AND NOT BUILD_INFO_SKIP_EXTRA_MODULES)
 907   set(__dump_extra_header OFF)
 908   foreach(p ${OPENCV_EXTRA_MODULES_PATH})
 909     if(EXISTS ${p})
 910       if(NOT __dump_extra_header)
 911         set(__dump_extra_header ON)
 912         status("")
 913         status("  Extra modules:")
 914       else()
 915         status("")
 916       endif()
 917       set(EXTRA_MODULES_VCSVERSION "unknown")
 918       if(GIT_FOUND)
 919         execute_process(COMMAND "${GIT_EXECUTABLE}" describe --tags --always --dirty --match "[0-9].[0-9].[0-9]*"
 920           WORKING_DIRECTORY "${p}"
 921           OUTPUT_VARIABLE EXTRA_MODULES_VCSVERSION
 922           RESULT_VARIABLE GIT_RESULT
 923           ERROR_QUIET
 924           OUTPUT_STRIP_TRAILING_WHITESPACE
 925         )
 926         if(NOT GIT_RESULT EQUAL 0)
 927           set(EXTRA_MODULES_VCSVERSION "unknown")
 928         endif()
 929       endif()
 930       status("    Location (extra):" ${p})
 931       status("    Version control (extra):" ${EXTRA_MODULES_VCSVERSION})
 932     endif()
 933   endforeach()
 934   unset(__dump_extra_header)
 935 endif()
 936
 937 # ========================== build platform ==========================
 938 status("")
 939 status("  Platform:")
 940 if(NOT DEFINED OPENCV_TIMESTAMP
 941     AND NOT CMAKE_VERSION VERSION_LESS 2.8.11
 942     AND NOT BUILD_INFO_SKIP_TIMESTAMP
 943 )
 944   string(TIMESTAMP OPENCV_TIMESTAMP "" UTC)
 945   set(OPENCV_TIMESTAMP "${OPENCV_TIMESTAMP}" CACHE STRING "Timestamp of OpenCV build configuration" FORCE)
 946 endif()
 947 if(OPENCV_TIMESTAMP)
 948   status("    Timestamp:"      ${OPENCV_TIMESTAMP})
 949 endif()
 950 status("    Host:"             ${CMAKE_HOST_SYSTEM_NAME} ${CMAKE_HOST_SYSTEM_VERSION} ${CMAKE_HOST_SYSTEM_PROCESSOR})
 951 if(CMAKE_CROSSCOMPILING)
 952   status("    Target:"         ${CMAKE_SYSTEM_NAME} ${CMAKE_SYSTEM_VERSION} ${CMAKE_SYSTEM_PROCESSOR})
 953 endif()
 954 status("    CMake:"            ${CMAKE_VERSION})
 955 status("    CMake generator:"  ${CMAKE_GENERATOR})
 956 status("    CMake build tool:" ${CMAKE_BUILD_TOOL})
 957 if(MSVC)
 958   status("    MSVC:"           ${MSVC_VERSION})
 959 endif()
 960 if(CMAKE_GENERATOR MATCHES Xcode)
 961   status("    Xcode:"          ${XCODE_VERSION})
 962 endif()
 963 if(NOT CMAKE_GENERATOR MATCHES "Xcode|Visual Studio")
 964   status("    Configuration:"  ${CMAKE_BUILD_TYPE})
 965 endif()
 966
 967
 968 # ========================= CPU code generation mode =========================
 969 status("")
 970 status("  CPU/HW features:")
 971 status("    Baseline:"  "${CPU_BASELINE_FINAL}")
 972 if(NOT CPU_BASELINE STREQUAL CPU_BASELINE_FINAL)
 973   status("      requested:"  "${CPU_BASELINE}")
 974 endif()
 975 if(CPU_BASELINE_REQUIRE)
 976   status("      required:"  "${CPU_BASELINE_REQUIRE}")
 977 endif()
 978 if(CPU_BASELINE_DISABLE)
 979   status("      disabled:"  "${CPU_BASELINE_DISABLE}")
 980 endif()
 981 if(CPU_DISPATCH_FINAL OR CPU_DISPATCH)
 982   status("    Dispatched code generation:"  "${CPU_DISPATCH_FINAL}")
 983   if(NOT CPU_DISPATCH STREQUAL CPU_DISPATCH_FINAL)
 984     status("      requested:"  "${CPU_DISPATCH}")
 985   endif()
 986   if(CPU_DISPATCH_REQUIRE)
 987     status("      required:"  "${CPU_DISPATCH_REQUIRE}")
 988   endif()
 989   foreach(OPT ${CPU_DISPATCH_FINAL})
 990     status("      ${OPT} (${CPU_${OPT}_USAGE_COUNT} files):"  "+ ${CPU_DISPATCH_${OPT}_INCLUDED}")
 991   endforeach()
 992 endif()
 993
 994 # ========================== C/C++ options ==========================
 995 if(CMAKE_CXX_COMPILER_VERSION)
 996   set(OPENCV_COMPILER_STR "${CMAKE_CXX_COMPILER} ${CMAKE_CXX_COMPILER_ARG1} (ver ${CMAKE_CXX_COMPILER_VERSION})")
 997 else()
 998   set(OPENCV_COMPILER_STR "${CMAKE_CXX_COMPILER} ${CMAKE_CXX_COMPILER_ARG1}")
 999 endif()
1000 string(STRIP "${OPENCV_COMPILER_STR}" OPENCV_COMPILER_STR)
1001
1002 status("")
1003 status("  C/C++:")
1004 status("    Built as dynamic libs?:" BUILD_SHARED_LIBS THEN YES ELSE NO)
1005 if(ENABLE_CXX11 OR HAVE_CXX11)
1006 status("    C++11:" HAVE_CXX11 THEN YES ELSE NO)
1007 endif()
1008 status("    C++ Compiler:"           ${OPENCV_COMPILER_STR})
1009 status("    C++ flags (Release):"    ${CMAKE_CXX_FLAGS} ${CMAKE_CXX_FLAGS_RELEASE})
1010 status("    C++ flags (Debug):"      ${CMAKE_CXX_FLAGS} ${CMAKE_CXX_FLAGS_DEBUG})
1011 status("    C Compiler:"             ${CMAKE_C_COMPILER} ${CMAKE_C_COMPILER_ARG1})
1012 status("    C flags (Release):"      ${CMAKE_C_FLAGS} ${CMAKE_C_FLAGS_RELEASE})
1013 status("    C flags (Debug):"        ${CMAKE_C_FLAGS} ${CMAKE_C_FLAGS_DEBUG})
1014 if(WIN32)
1015   status("    Linker flags (Release):" ${CMAKE_EXE_LINKER_FLAGS} ${CMAKE_EXE_LINKER_FLAGS_RELEASE})
1016   status("    Linker flags (Debug):"   ${CMAKE_EXE_LINKER_FLAGS} ${CMAKE_EXE_LINKER_FLAGS_DEBUG})
1017 else()
1018   status("    Linker flags (Release):" ${CMAKE_SHARED_LINKER_FLAGS} ${CMAKE_SHARED_LINKER_FLAGS_RELEASE})
1019   status("    Linker flags (Debug):"   ${CMAKE_SHARED_LINKER_FLAGS} ${CMAKE_SHARED_LINKER_FLAGS_DEBUG})
1020 endif()
1021 status("    ccache:"                  CMAKE_COMPILER_IS_CCACHE THEN YES ELSE NO)
1022 status("    Precompiled headers:"     PCHSupport_FOUND AND ENABLE_PRECOMPILED_HEADERS THEN YES ELSE NO)
1023
1024 # ========================== Dependencies ============================
1025 ocv_get_all_libs(deps_modules deps_extra deps_3rdparty)
1026 status("    Extra dependencies:" ${deps_extra})
1027 status("    3rdparty dependencies:" ${deps_3rdparty})
1028
1029 # ========================== OpenCV modules ==========================
1030 status("")
1031 status("  OpenCV modules:")
1032 string(REPLACE "opencv_" "" OPENCV_MODULES_BUILD_ST          "${OPENCV_MODULES_BUILD}")
1033 string(REPLACE "opencv_" "" OPENCV_MODULES_DISABLED_USER_ST  "${OPENCV_MODULES_DISABLED_USER}")
1034 string(REPLACE "opencv_" "" OPENCV_MODULES_DISABLED_AUTO_ST  "${OPENCV_MODULES_DISABLED_AUTO}")
1035 string(REPLACE "opencv_" "" OPENCV_MODULES_DISABLED_FORCE_ST "${OPENCV_MODULES_DISABLED_FORCE}")
1036 list(SORT OPENCV_MODULES_BUILD_ST)
1037 list(SORT OPENCV_MODULES_DISABLED_USER_ST)
1038 list(SORT OPENCV_MODULES_DISABLED_AUTO_ST)
1039 list(SORT OPENCV_MODULES_DISABLED_FORCE_ST)
1040 status("    To be built:"            OPENCV_MODULES_BUILD          THEN ${OPENCV_MODULES_BUILD_ST}          ELSE "-")
1041 status("    Disabled:"               OPENCV_MODULES_DISABLED_USER  THEN ${OPENCV_MODULES_DISABLED_USER_ST}  ELSE "-")
1042 status("    Disabled by dependency:" OPENCV_MODULES_DISABLED_AUTO  THEN ${OPENCV_MODULES_DISABLED_AUTO_ST}  ELSE "-")
1043 status("    Unavailable:"            OPENCV_MODULES_DISABLED_FORCE THEN ${OPENCV_MODULES_DISABLED_FORCE_ST} ELSE "-")
1044
1045 ocv_build_features_string(apps_status
1046   IF BUILD_TESTS AND HAVE_opencv_ts THEN "tests"
1047   IF BUILD_PERF_TESTS AND HAVE_opencv_ts THEN "perf_tests"
1048   IF BUILD_EXAMPLES THEN "examples"
1049   IF BUILD_opencv_apps THEN "apps"
1050   IF BUILD_ANDROID_SERVICE THEN "android_service"
1051   IF BUILD_ANDROID_EXAMPLES AND CAN_BUILD_ANDROID_PROJECTS THEN "android_examples"
1052   ELSE "-")
1053 status("    Applications:" "${apps_status}")
1054 ocv_build_features_string(docs_status
1055     IF TARGET doxygen_cpp THEN "doxygen"
1056     IF TARGET doxygen_python THEN "python"
1057     IF TARGET doxygen_javadoc THEN "javadoc"
1058     IF BUILD_opencv_js OR DEFINED OPENCV_JS_LOCATION THEN "js"
1059     ELSE "NO"
1060 )
1061 status("    Documentation:" "${docs_status}")
1062 status("    Non-free algorithms:" OPENCV_ENABLE_NONFREE THEN "YES" ELSE "NO")
1063
1064 # ========================== Android details ==========================
1065 if(ANDROID)
1066   status("")
1067   status("  Android: ")
1068   status("    Android ABI:" ${ANDROID_ABI})
1069   status("    STL type:" ${ANDROID_STL})
1070   status("    Native API level:" android-${ANDROID_NATIVE_API_LEVEL})
1071   android_get_compatible_target(android_sdk_target_status ${ANDROID_NATIVE_API_LEVEL} ${ANDROID_SDK_TARGET} 11)
1072   status("    SDK target:" "${android_sdk_target_status}")
1073   if(BUILD_WITH_ANDROID_NDK)
1074     status("    Android NDK:" "${ANDROID_NDK} (toolchain: ${ANDROID_TOOLCHAIN_NAME})")
1075   elseif(BUILD_WITH_STANDALONE_TOOLCHAIN)
1076     status("    Android toolchain:" "${ANDROID_STANDALONE_TOOLCHAIN}")
1077   endif()
1078   status("    android tool:"  ANDROID_EXECUTABLE  THEN "${ANDROID_EXECUTABLE} (${ANDROID_TOOLS_Pkg_Desc})" ELSE NO)
1079 endif()
1080
1081 # ================== Windows RT features ==================
1082 if(WIN32)
1083 status("")
1084 status("  Windows RT support:" WINRT THEN YES ELSE NO)
1085   if(WINRT)
1086     status("    Building for Microsoft platform: " ${CMAKE_SYSTEM_NAME})
1087     status("    Building for architectures: " ${CMAKE_VS_EFFECTIVE_PLATFORMS})
1088     status("    Building for version: " ${CMAKE_SYSTEM_VERSION})
1089     if (DEFINED ENABLE_WINRT_MODE_NATIVE)
1090       status("    Building for C++ without CX extensions")
1091     endif()
1092   endif()
1093 endif(WIN32)
1094
1095 # ========================== GUI ==========================
1096 status("")
1097 status("  GUI: ")
1098
1099 if(WITH_QT OR HAVE_QT)
1100   if(HAVE_QT5)
1101     status("    QT:" "YES (ver ${Qt5Core_VERSION_STRING})")
1102     status("      QT OpenGL support:" HAVE_QT_OPENGL THEN "YES (${Qt5OpenGL_LIBRARIES} ${Qt5OpenGL_VERSION_STRING})" ELSE NO)
1103   elseif(HAVE_QT)
1104     status("    QT:" "YES (ver ${QT_VERSION_MAJOR}.${QT_VERSION_MINOR}.${QT_VERSION_PATCH} ${QT_EDITION})")
1105     status("      QT OpenGL support:" HAVE_QT_OPENGL THEN "YES (${QT_QTOPENGL_LIBRARY})" ELSE NO)
1106   else()
1107     status("    QT:" "NO")
1108   endif()
1109 endif()
1110
1111 if(WITH_WIN32UI)
1112   status("    Win32 UI:" HAVE_WIN32UI THEN YES ELSE NO)
1113 endif()
1114
1115 if(APPLE)
1116   if(WITH_CARBON)
1117     status("    Carbon:" YES)
1118   else()
1119     status("    Cocoa:"  YES)
1120   endif()
1121 endif()
1122
1123 if(WITH_GTK OR HAVE_GTK)
1124   if(HAVE_GTK3)
1125     status("    GTK+:" "YES (ver ${ALIASOF_gtk+-3.0_VERSION})")
1126   elseif(HAVE_GTK)
1127     status("    GTK+:" "YES (ver ${ALIASOF_gtk+-2.0_VERSION})")
1128   else()
1129     status("    GTK+:" "NO")
1130   endif()
1131   if(HAVE_GTK)
1132     status(  "      GThread :" HAVE_GTHREAD THEN "YES (ver ${ALIASOF_gthread-2.0_VERSION})" ELSE NO)
1133     status(  "      GtkGlExt:" HAVE_GTKGLEXT THEN "YES (ver ${ALIASOF_gtkglext-1.0_VERSION})" ELSE NO)
1134   endif()
1135 endif()
1136
1137 if(WITH_OPENGL OR HAVE_OPENGL)
1138   status("    OpenGL support:" HAVE_OPENGL THEN "YES (${OPENGL_LIBRARIES})" ELSE NO)
1139 endif()
1140
1141 if(WITH_VTK OR HAVE_VTK)
1142   status("    VTK support:" HAVE_VTK THEN "YES (ver ${VTK_VERSION})" ELSE NO)
1143 endif()
1144
1145 # ========================== MEDIA IO ==========================
1146 status("")
1147 status("  Media I/O: ")
1148 status("    ZLib:"   ZLIB_FOUND THEN "${ZLIB_LIBRARIES} (ver ${ZLIB_VERSION_STRING})" ELSE "build (ver ${ZLIB_VERSION_STRING})")
1149
1150 if(WITH_JPEG OR HAVE_JPEG)
1151   status("    JPEG:" JPEG_FOUND THEN "${JPEG_LIBRARY} (ver ${JPEG_LIB_VERSION})" ELSE "build (ver ${JPEG_LIB_VERSION})")
1152 endif()
1153
1154 if(WITH_WEBP OR HAVE_WEBP)
1155   status("    WEBP:" WEBP_FOUND THEN "${WEBP_LIBRARY} (ver ${WEBP_VERSION})" ELSE "build (ver ${WEBP_VERSION})")
1156 endif()
1157
1158 if(WITH_PNG OR HAVE_PNG)
1159   status("    PNG:"  PNG_FOUND  THEN "${PNG_LIBRARY} (ver ${PNG_VERSION})" ELSE "build (ver ${PNG_VERSION})")
1160 endif()
1161
1162 if(WITH_TIFF OR HAVE_TIFF)
1163   status("    TIFF:" TIFF_FOUND THEN "${TIFF_LIBRARY} (ver ${TIFF_VERSION} / ${TIFF_VERSION_STRING})" ELSE "build (ver ${TIFF_VERSION} - ${TIFF_VERSION_STRING})")
1164 endif()
1165
1166 if(WITH_JASPER OR HAVE_JASPER)
1167   status("    JPEG 2000:" JASPER_FOUND THEN "${JASPER_LIBRARY} (ver ${JASPER_VERSION_STRING})" ELSE "build (ver ${JASPER_VERSION_STRING})")
1168 endif()
1169
1170 if(WITH_OPENEXR OR HAVE_OPENEXR)
1171   status("    OpenEXR:" OPENEXR_FOUND THEN "${OPENEXR_LIBRARIES} (ver ${OPENEXR_VERSION})" ELSE "build (ver ${OPENEXR_VERSION})")
1172 endif()
1173
1174 if(WITH_GDAL OR HAVE_GDAL)
1175   status("    GDAL:" HAVE_GDAL THEN "YES (${GDAL_LIBRARY})" ELSE "NO")
1176 endif()
1177
1178 if(WITH_GDCM OR HAVE_GDCM)
1179   status("    GDCM:" HAVE_GDCM THEN "YES (ver ${GDCM_VERSION})" ELSE "NO")
1180 endif()
1181
1182 # ========================== VIDEO IO ==========================
1183 status("")
1184 status("  Video I/O:")
1185
1186 if(WITH_VFW OR HAVE_VFW)
1187   status("    Video for Windows:" HAVE_VFW         THEN YES                                        ELSE NO)
1188 endif()
1189
1190 if(WITH_1394 OR HAVE_DC1394)
1191   if (HAVE_DC1394_2)
1192     status("    DC1394:" "YES (ver ${ALIASOF_libdc1394-2_VERSION})")
1193   elseif (HAVE_DC1394)
1194     status("    DC1394:" "YES (ver ${ALIASOF_libdc1394_VERSION})")
1195   else()
1196     status("    DC1394:" "NO")
1197   endif()
1198 endif()
1199
1200 if(WITH_FFMPEG OR HAVE_FFMPEG)
1201   if(WIN32)
1202     status("    FFMPEG:"       HAVE_FFMPEG         THEN "YES (prebuilt binaries)"                  ELSE NO)
1203   else()
1204     status("    FFMPEG:"       HAVE_FFMPEG         THEN YES ELSE NO)
1205   endif()
1206   status("      avcodec:"      FFMPEG_libavcodec_FOUND    THEN "YES (ver ${FFMPEG_libavcodec_VERSION})"    ELSE NO)
1207   status("      avformat:"     FFMPEG_libavformat_FOUND   THEN "YES (ver ${FFMPEG_libavformat_VERSION})"   ELSE NO)
1208   status("      avutil:"       FFMPEG_libavutil_FOUND     THEN "YES (ver ${FFMPEG_libavutil_VERSION})"     ELSE NO)
1209   status("      swscale:"      FFMPEG_libswscale_FOUND    THEN "YES (ver ${FFMPEG_libswscale_VERSION})"    ELSE NO)
1210   status("      avresample:"   FFMPEG_libavresample_FOUND THEN "YES (ver ${FFMPEG_libavresample_VERSION})" ELSE NO)
1211 endif()
1212
1213 if(WITH_GSTREAMER OR HAVE_GSTREAMER)
1214   status("    GStreamer:"      HAVE_GSTREAMER      THEN ""                                         ELSE NO)
1215   if(HAVE_GSTREAMER)
1216     status("      base:"       "YES (ver ${GSTREAMER_BASE_VERSION})")
1217     status("      video:"      "YES (ver ${GSTREAMER_VIDEO_VERSION})")
1218     status("      app:"        "YES (ver ${GSTREAMER_APP_VERSION})")
1219     status("      riff:"       "YES (ver ${GSTREAMER_RIFF_VERSION})")
1220     status("      pbutils:"    "YES (ver ${GSTREAMER_PBUTILS_VERSION})")
1221   endif(HAVE_GSTREAMER)
1222 endif()
1223
1224 if(WITH_OPENNI OR HAVE_OPENNI)
1225   status("    OpenNI:"         HAVE_OPENNI         THEN "YES (ver ${OPENNI_VERSION_STRING}, build ${OPENNI_VERSION_BUILD})" ELSE NO)
1226   status("    OpenNI PrimeSensor Modules:" HAVE_OPENNI_PRIME_SENSOR_MODULE THEN "YES (${OPENNI_PRIME_SENSOR_MODULE})"      ELSE NO)
1227 endif()
1228
1229 if(WITH_OPENNI2 OR HAVE_OPENNI2)
1230   status("    OpenNI2:"        HAVE_OPENNI2    THEN "YES (ver ${OPENNI2_VERSION_STRING}, build ${OPENNI2_VERSION_BUILD})" ELSE NO)
1231 endif()
1232
1233 if(WITH_PVAPI OR HAVE_PVAPI)
1234   status("    PvAPI:"          HAVE_PVAPI          THEN YES                                        ELSE NO)
1235 endif()
1236
1237 if(WITH_GIGEAPI OR HAVE_GIGE_API)
1238   status("    GigEVisionSDK:"  HAVE_GIGE_API       THEN YES                                        ELSE NO)
1239 endif()
1240
1241 if(WITH_ARAVIS OR HAVE_ARAVIS_API)
1242   status("    Aravis SDK:"     HAVE_ARAVIS_API     THEN "YES (${ARAVIS_LIBRARIES})"                ELSE NO)
1243 endif()
1244
1245 if(APPLE)
1246   status("    AVFoundation:"   HAVE_AVFOUNDATION   THEN YES                                        ELSE NO)
1247   if(WITH_QUICKTIME OR HAVE_QUICKTIME)
1248     status("    QuickTime:"      HAVE_QUICKTIME      THEN YES                                        ELSE NO)
1249   endif()
1250   if(WITH_QTKIT OR HAVE_QTKIT)
1251     status("    QTKit:"          HAVE_QTKIT          THEN "YES (deprecated)"                         ELSE NO)
1252   endif()
1253 endif()
1254
1255 if(WITH_UNICAP OR HAVE_UNICAP)
1256   status("    UniCap:"         HAVE_UNICAP         THEN "YES (ver ${ALIASOF_libunicap_VERSION})"   ELSE NO)
1257   status("    UniCap ucil:"    HAVE_UNICAP_UCIL    THEN "YES (ver ${ALIASOF_libucil_VERSION})"     ELSE NO)
1258 endif()
1259
1260 if(WITH_V4L OR WITH_LIBV4L OR HAVE_LIBV4L OR HAVE_CAMV4L OR HAVE_CAMV4L2 OR HAVE_VIDEOIO)
1261   status("    libv4l/libv4l2:" HAVE_LIBV4L THEN "${ALIASOF_libv4l1_VERSION} / ${ALIASOF_libv4l2_VERSION}" ELSE "NO")
1262   ocv_build_features_string(v4l_status
1263     IF HAVE_CAMV4L THEN "linux/videodev.h"
1264     IF HAVE_CAMV4L2 THEN "linux/videodev2.h"
1265     IF HAVE_VIDEOIO THEN "sys/videoio.h"
1266     ELSE "NO")
1267   status("    v4l/v4l2:" "${v4l_status}")
1268 endif()
1269
1270 if(WITH_DSHOW OR HAVE_DSHOW)
1271   status("    DirectShow:"     HAVE_DSHOW     THEN YES                                        ELSE NO)
1272 endif()
1273
1274 if(WITH_MSMF OR HAVE_MSMF)
1275   status("    Media Foundation:" HAVE_MSMF    THEN YES                                        ELSE NO)
1276 endif()
1277
1278 if(WITH_XIMEA OR HAVE_XIMEA)
1279   status("    XIMEA:"          HAVE_XIMEA          THEN YES                                        ELSE NO)
1280 endif()
1281
1282 if(WITH_XINE OR HAVE_XINE)
1283   status("    Xine:"           HAVE_XINE           THEN "YES (ver ${ALIASOF_libxine_VERSION})"     ELSE NO)
1284 endif()
1285
1286 if(WITH_INTELPERC OR HAVE_INTELPERC)
1287   status("    Intel PerC:"     HAVE_INTELPERC      THEN "YES"                                 ELSE NO)
1288 endif()
1289
1290 if(WITH_MFX OR HAVE_MFX)
1291   status("    Intel Media SDK:" HAVE_MFX      THEN "YES (${MFX_LIBRARY})" ELSE NO)
1292 endif()
1293
1294 if(WITH_GPHOTO2 OR HAVE_GPHOTO2)
1295   status("    gPhoto2:"        HAVE_GPHOTO2        THEN "YES"                                 ELSE NO)
1296 endif()
1297
1298 # Order is similar to CV_PARALLEL_FRAMEWORK in core/src/parallel.cpp
1299 ocv_build_features_string(parallel_status EXCLUSIVE
1300   IF HAVE_TBB THEN "TBB (ver ${TBB_VERSION_MAJOR}.${TBB_VERSION_MINOR} interface ${TBB_INTERFACE_VERSION})"
1301   IF HAVE_CSTRIPES THEN "C="
1302   IF HAVE_OPENMP THEN "OpenMP"
1303   IF HAVE_GCD THEN "GCD"
1304   IF WINRT OR HAVE_CONCURRENCY THEN "Concurrency"
1305   IF HAVE_PTHREADS_PF THEN "pthreads"
1306   ELSE "none")
1307 status("")
1308 status("  Parallel framework:" "${parallel_status}")
1309
1310 if(CV_TRACE OR OPENCV_TRACE)
1311   ocv_build_features_string(trace_status EXCLUSIVE
1312     IF HAVE_ITT THEN "with Intel ITT"
1313     ELSE "built-in")
1314   status("")
1315   status("  Trace: " OPENCV_TRACE THEN "YES (${trace_status})" ELSE NO)
1316 endif()
1317
1318 # ========================== Other third-party libraries ==========================
1319 status("")
1320 status("  Other third-party libraries:")
1321
1322 if(WITH_IPP AND HAVE_IPP)
1323   status("    Intel IPP:" "${IPP_VERSION_STR} [${IPP_VERSION_MAJOR}.${IPP_VERSION_MINOR}.${IPP_VERSION_BUILD}]")
1324   status("           at:" "${IPP_ROOT_DIR}")
1325   if(NOT HAVE_IPP_ICV)
1326     status("       linked:" BUILD_WITH_DYNAMIC_IPP THEN "dynamic" ELSE "static")
1327   endif()
1328   if(HAVE_IPP_IW)
1329     if(BUILD_IPP_IW)
1330       status("    Intel IPP IW:" "sources (${IW_VERSION_MAJOR}.${IW_VERSION_MINOR}.${IW_VERSION_UPDATE})")
1331     else()
1332       status("    Intel IPP IW:" "binaries (${IW_VERSION_MAJOR}.${IW_VERSION_MINOR}.${IW_VERSION_UPDATE})")
1333     endif()
1334     status("              at:" "${IPP_IW_PATH}")
1335   else()
1336     status("    Intel IPP IW:"   NO)
1337   endif()
1338 endif()
1339
1340 if(WITH_VA OR HAVE_VA)
1341   status("    VA:"            HAVE_VA          THEN "YES" ELSE NO)
1342 endif()
1343
1344 if(WITH_VA_INTEL OR HAVE_VA_INTEL)
1345   status("    Intel VA-API/OpenCL:"  HAVE_VA_INTEL       THEN "YES (MSDK: ${VA_INTEL_MSDK_ROOT}  OpenCL: ${VA_INTEL_IOCL_ROOT})" ELSE NO)
1346 endif()
1347
1348 if(WITH_LAPACK OR HAVE_LAPACK)
1349   status("    Lapack:"      HAVE_LAPACK     THEN "YES (${LAPACK_LIBRARIES})" ELSE NO)
1350 endif()
1351
1352 if(WITH_HALIDE OR HAVE_HALIDE)
1353   status("    Halide:"     HAVE_HALIDE      THEN "YES (${HALIDE_LIBRARIES} ${HALIDE_INCLUDE_DIRS})" ELSE NO)
1354 endif()
1355
1356 if(WITH_EIGEN OR HAVE_EIGEN)
1357   status("    Eigen:"      HAVE_EIGEN       THEN "YES (ver ${EIGEN_WORLD_VERSION}.${EIGEN_MAJOR_VERSION}.${EIGEN_MINOR_VERSION})" ELSE NO)
1358 endif()
1359
1360 if(WITH_OPENVX OR HAVE_OPENVX)
1361   status("    OpenVX:"     HAVE_OPENVX      THEN "YES (${OPENVX_LIBRARIES})" ELSE "NO")
1362 endif()
1363
1364 status("    Custom HAL:" OpenCV_USED_HAL  THEN "YES (${OpenCV_USED_HAL})" ELSE "NO")
1365
1366 foreach(s ${CUSTOM_STATUS})
1367   status(${CUSTOM_STATUS_${s}})
1368 endforeach()
1369
1370 if(WITH_CUDA OR HAVE_CUDA)
1371   ocv_build_features_string(cuda_features
1372     IF HAVE_CUFFT THEN "CUFFT"
1373     IF HAVE_CUBLAS THEN "CUBLAS"
1374     IF HAVE_NVCUVID THEN "NVCUVID"
1375     IF CUDA_FAST_MATH THEN "FAST_MATH"
1376     ELSE "no extra features")
1377   status("")
1378   status("  NVIDIA CUDA:" HAVE_CUDA THEN "YES (ver ${CUDA_VERSION_STRING}, ${cuda_features})" ELSE NO)
1379   if(HAVE_CUDA)
1380     status("    NVIDIA GPU arch:"      ${OPENCV_CUDA_ARCH_BIN})
1381     status("    NVIDIA PTX archs:"     ${OPENCV_CUDA_ARCH_PTX})
1382   endif()
1383 endif()
1384
1385 if(WITH_OPENCL OR HAVE_OPENCL)
1386   ocv_build_features_string(opencl_features
1387     IF HAVE_OPENCL_SVM THEN "SVM"
1388     IF HAVE_CLAMDFFT THEN "AMDFFT"
1389     IF HAVE_CLAMDBLAS THEN "AMDBLAS"
1390     ELSE "no extra features")
1391   status("")
1392   status("  OpenCL:"     HAVE_OPENCL   THEN   "YES (${opencl_features})" ELSE "NO")
1393   if(HAVE_OPENCL)
1394     status("    Include path:"  OPENCL_INCLUDE_DIRS THEN "${OPENCL_INCLUDE_DIRS}" ELSE "NO")
1395     status("    Link libraries:"       OPENCL_LIBRARIES THEN "${OPENCL_LIBRARIES}" ELSE "Dynamic load")
1396   endif()
1397 endif()
1398
1399 # ========================== python ==========================
1400 if(BUILD_opencv_python2)
1401   status("")
1402   status("  Python 2:")
1403   status("    Interpreter:"     PYTHON2INTERP_FOUND  THEN "${PYTHON2_EXECUTABLE} (ver ${PYTHON2_VERSION_STRING})"       ELSE NO)
1404   if(PYTHON2LIBS_VERSION_STRING)
1405     status("    Libraries:"   HAVE_opencv_python2  THEN  "${PYTHON2_LIBRARIES} (ver ${PYTHON2LIBS_VERSION_STRING})"   ELSE NO)
1406   else()
1407     status("    Libraries:"   HAVE_opencv_python2  THEN  "${PYTHON2_LIBRARIES}"                                      ELSE NO)
1408   endif()
1409   status("    numpy:"         PYTHON2_NUMPY_INCLUDE_DIRS THEN "${PYTHON2_NUMPY_INCLUDE_DIRS} (ver ${PYTHON2_NUMPY_VERSION})" ELSE "NO (Python wrappers can not be generated)")
1410   status("    packages path:" PYTHON2_EXECUTABLE         THEN "${PYTHON2_PACKAGES_PATH}"                                    ELSE "-")
1411 endif()
1412
1413 if(BUILD_opencv_python3)
1414   status("")
1415   status("  Python 3:")
1416   status("    Interpreter:"     PYTHON3INTERP_FOUND  THEN "${PYTHON3_EXECUTABLE} (ver ${PYTHON3_VERSION_STRING})"       ELSE NO)
1417   if(PYTHON3LIBS_VERSION_STRING)
1418     status("    Libraries:"   HAVE_opencv_python3  THEN  "${PYTHON3_LIBRARIES} (ver ${PYTHON3LIBS_VERSION_STRING})"   ELSE NO)
1419   else()
1420     status("    Libraries:"   HAVE_opencv_python3  THEN  "${PYTHON3_LIBRARIES}"                                      ELSE NO)
1421   endif()
1422   status("    numpy:"         PYTHON3_NUMPY_INCLUDE_DIRS THEN "${PYTHON3_NUMPY_INCLUDE_DIRS} (ver ${PYTHON3_NUMPY_VERSION})" ELSE "NO (Python3 wrappers can not be generated)")
1423   status("    packages path:" PYTHON3_EXECUTABLE         THEN "${PYTHON3_PACKAGES_PATH}"                                    ELSE "-")
1424 endif()
1425
1426 status("")
1427 status("  Python (for build):"  PYTHON_DEFAULT_AVAILABLE THEN "${PYTHON_DEFAULT_EXECUTABLE}" ELSE NO)
1428 if(PYLINT_FOUND AND PYLINT_EXECUTABLE)
1429   status("    Pylint:"  PYLINT_FOUND THEN "${PYLINT_EXECUTABLE} (ver: ${PYLINT_VERSION}, checks: ${PYLINT_TOTAL_TARGETS})" ELSE NO)
1430 endif()
1431
1432 # ========================== java ==========================
1433 if(BUILD_JAVA OR BUILD_opencv_java)
1434   status("")
1435   status("  Java:"            BUILD_FAT_JAVA_LIB  THEN "export all functions"                                      ELSE "")
1436   status("    ant:"           ANT_EXECUTABLE      THEN "${ANT_EXECUTABLE} (ver ${ANT_VERSION})"                    ELSE NO)
1437   if(NOT ANDROID)
1438     status("    JNI:"         JNI_INCLUDE_DIRS    THEN "${JNI_INCLUDE_DIRS}"                                       ELSE NO)
1439   endif()
1440   status("    Java wrappers:" HAVE_opencv_java                                                            THEN YES ELSE NO)
1441   status("    Java tests:"    BUILD_TESTS AND opencv_test_java_BINARY_DIR                                 THEN YES ELSE NO)
1442 endif()
1443
1444 # ========================= matlab =========================
1445 if(WITH_MATLAB OR MATLAB_FOUND)
1446   status("")
1447   status("  Matlab:" MATLAB_FOUND THEN "YES" ELSE "NO")
1448   if(MATLAB_FOUND)
1449     status("    mex:"         MATLAB_MEX_SCRIPT  THEN  "${MATLAB_MEX_SCRIPT}"   ELSE NO)
1450     status("    Compiler/generator:" MEX_WORKS   THEN  "Working"                ELSE "Not working (bindings will not be generated)")
1451   endif()
1452 endif()
1453
1454 # ========================== auxiliary ==========================
1455 status("")
1456 status("  Install to:" "${CMAKE_INSTALL_PREFIX}")
1457 status("-----------------------------------------------------------------")
1458 status("")
1459
1460
1461 ocv_finalize_status()
1462
1463 # ----------------------------------------------------------------------------
1464 # CPack stuff
1465 # ----------------------------------------------------------------------------
1466
1467 include(cmake/OpenCVPackaging.cmake)
1468
1469 # This should be the last command
1470 ocv_cmake_dump_vars("" TOFILE "CMakeVars.txt")
1471 ocv_cmake_eval(DEBUG_POST ONCE)