CMakeLists.txt

   1 cmake_minimum_required(VERSION 2.8)
   2
   3 if(NOT DEFINED CMAKE_BUILD_TYPE)
   4         set(CMAKE_BUILD_TYPE Release CACHE STRING "Build type")
   5 endif()
   6
   7 project(libwebsockets C)
   8
   9 set(PACKAGE "libwebsockets")
  10 set(CPACK_PACKAGE_NAME "${PACKAGE}")
  11 set(CPACK_PACKAGE_VERSION_MAJOR "1")
  12 set(CPACK_PACKAGE_VERSION_MINOR "7")
  13 set(CPACK_PACKAGE_VERSION_PATCH "0")
  14 set(CPACK_PACKAGE_VERSION "${CPACK_PACKAGE_VERSION_MAJOR}.${CPACK_PACKAGE_VERSION_MINOR}.${CPACK_PACKAGE_VERSION_PATCH}")
  15 set(CPACK_PACKAGE_VENDOR "andy@warmcat.com")
  16 set(CPACK_PACKAGE_DESCRIPTION_SUMMARY "${PACKAGE} ${PACKAGE_VERSION}")
  17 set(SOVERSION "7")
  18 set(CPACK_SOURCE_GENERATOR "TGZ")
  19 set(CPACK_SOURCE_PACKAGE_FILE_NAME "${CPACK_PACKAGE_NAME}-${CPACK_PACKAGE_VERSION}")
  20 set(VERSION "${CPACK_PACKAGE_VERSION}")
  21
  22 set(LWS_LIBRARY_VERSION ${CPACK_PACKAGE_VERSION})
  23 set(LWS_LIBRARY_VERSION_MAJOR ${CPACK_PACKAGE_VERSION_MAJOR})
  24 set(LWS_LIBRARY_VERSION_MINOR ${CPACK_PACKAGE_VERSION_MINOR})
  25 set(LWS_LIBRARY_VERSION_PATCH ${CPACK_PACKAGE_VERSION_PATCH})
  26
  27 set(CMAKE_MODULE_PATH ${CMAKE_MODULE_PATH} "${PROJECT_SOURCE_DIR}/cmake/")
  28
  29 message(STATUS "CMAKE_TOOLCHAIN_FILE='${CMAKE_TOOLCHAIN_FILE}'")
  30
  31 # Try to find the current Git hash.
  32 find_package(Git)
  33 if(GIT_EXECUTABLE)
  34         execute_process(
  35     WORKING_DIRECTORY "${CMAKE_CURRENT_SOURCE_DIR}"
  36     COMMAND "${GIT_EXECUTABLE}" describe
  37     OUTPUT_VARIABLE GIT_HASH
  38     OUTPUT_STRIP_TRAILING_WHITESPACE
  39     )
  40         execute_process(
  41     WORKING_DIRECTORY "${CMAKE_CURRENT_SOURCE_DIR}"
  42     COMMAND "whoami"
  43     OUTPUT_VARIABLE GIT_USER
  44     OUTPUT_STRIP_TRAILING_WHITESPACE
  45     )
  46         execute_process(
  47     WORKING_DIRECTORY "${CMAKE_CURRENT_SOURCE_DIR}"
  48     COMMAND "hostname"
  49     OUTPUT_VARIABLE GIT_HOST
  50     OUTPUT_STRIP_TRAILING_WHITESPACE
  51     )
  52     set(LWS_BUILD_HASH ${GIT_USER}@${GIT_HOST}-${GIT_HASH})
  53     message("Git commit hash: ${LWS_BUILD_HASH}")
  54 endif()
  55
  56 set(LWS_USE_BUNDLED_ZLIB_DEFAULT OFF)
  57 if(WIN32)
  58         set(LWS_USE_BUNDLED_ZLIB_DEFAULT ON)
  59 endif()
  60
  61 option(LWS_WITH_STATIC "Build the static version of the library" ON)
  62 option(LWS_WITH_SHARED "Build the shared version of the library" ON)
  63 option(LWS_WITH_SSL "Include SSL support (default OpenSSL, wolfSSL if LWS_USE_WOLFSSL is set)" ON)
  64 option(LWS_USE_CYASSL "Use CyaSSL replacement for OpenSSL. When setting this, you also need to specify LWS_CYASSL_LIBRARIES and LWS_CYASSL_INCLUDE_DIRS" OFF)
  65 option(LWS_USE_WOLFSSL "Use wolfSSL replacement for OpenSSL. When setting this, you also need to specify LWS_WOLFSSL_LIBRARIES and LWS_WOLFSSL_INCLUDE_DIRS" OFF)
  66 option(LWS_WITH_ZLIB "Include zlib support (required for extensions)" ON)
  67 option(LWS_WITH_LIBEV "Compile with support for libev" OFF)
  68 option(LWS_WITH_LIBUV "Compile with support for libuv" OFF)
  69 option(LWS_USE_BUNDLED_ZLIB "Use bundled zlib version (Windows only)" ${LWS_USE_BUNDLED_ZLIB_DEFAULT})
  70 option(LWS_SSL_CLIENT_USE_OS_CA_CERTS "SSL support should make use of the OS-installed CA root certs" ON)
  71 option(LWS_WITHOUT_BUILTIN_GETIFADDRS "Don't use the BSD getifaddrs implementation from libwebsockets if it is missing (this will result in a compilation error) ... The default is to assume that your libc provides it. On some systems such as uclibc it doesn't exist." OFF)
  72 option(LWS_WITHOUT_BUILTIN_SHA1 "Don't build the lws sha-1 (eg, because openssl will provide it" OFF)
  73 option(LWS_WITHOUT_CLIENT "Don't build the client part of the library" OFF)
  74 option(LWS_WITHOUT_SERVER "Don't build the server part of the library" OFF)
  75 option(LWS_LINK_TESTAPPS_DYNAMIC "Link the test apps to the shared version of the library. Default is to link statically" OFF)
  76 option(LWS_WITHOUT_TESTAPPS "Don't build the libwebsocket-test-apps" OFF)
  77 option(LWS_WITHOUT_TEST_SERVER "Don't build the test server" OFF)
  78 option(LWS_WITHOUT_TEST_SERVER_EXTPOLL "Don't build the test server version that uses external poll" OFF)
  79 option(LWS_WITHOUT_TEST_PING "Don't build the ping test application" OFF)
  80 option(LWS_WITHOUT_TEST_ECHO "Don't build the echo test application" OFF)
  81 option(LWS_WITHOUT_TEST_CLIENT "Don't build the client test application" OFF)
  82 option(LWS_WITHOUT_TEST_FRAGGLE "Don't build the ping test application" OFF)
  83 option(LWS_WITHOUT_EXTENSIONS "Don't compile with extensions" OFF)
  84 option(LWS_WITH_LATENCY "Build latency measuring code into the library" OFF)
  85 option(LWS_WITHOUT_DAEMONIZE "Don't build the daemonization api" ON)
  86 option(LWS_IPV6 "Compile with support for ipv6" OFF)
  87 option(LWS_WITH_HTTP2 "Compile with support for http2" OFF)
  88 option(LWS_MBED3 "Platform is MBED3" OFF)
  89 option(LWS_SSL_SERVER_WITH_ECDH_CERT "Include SSL server use ECDH certificate" OFF)
  90 option(LWS_WITH_CGI "Include CGI (spawn process with network-connected stdin/out/err) APIs" OFF)
  91 option(LWS_WITH_HTTP_PROXY "Support for rewriting HTTP proxying" OFF)
  92
  93
  94 if (DEFINED YOTTA_WEBSOCKETS_VERSION_STRING)
  95
  96 set(LWS_WITH_SHARED OFF)
  97 set(LWS_WITH_SSL OFF)
  98 set(LWS_WITH_ZLIB OFF)
  99 set(LWS_WITHOUT_CLIENT ON)
 100 set(LWS_WITHOUT_TESTAPPS ON)
 101 set(LWS_WITHOUT_EXTENSIONS ON)
 102 set(LWS_MBED3 ON)
 103 # this implies no pthreads in the lib
 104 set(LWS_MAX_SMP 1)
 105
 106 endif()
 107
 108 if (WIN32)
 109 # this implies no pthreads in the lib
 110 set(LWS_MAX_SMP 1)
 111 endif()
 112
 113 if (LWS_WITH_HTTP_PROXY AND (LWS_WITHOUT_CLIENT OR LWS_WITHOUT_SERVER))
 114         message(FATAL_ERROR "You have to enable both client and server for http proxy")
 115 endif()
 116
 117 # Allow the user to override installation directories.
 118 set(LWS_INSTALL_LIB_DIR       lib CACHE PATH "Installation directory for libraries")
 119 set(LWS_INSTALL_BIN_DIR       bin CACHE PATH "Installation directory for executables")
 120 set(LWS_INSTALL_INCLUDE_DIR   include CACHE PATH "Installation directory for header files")
 121 set(LWS_INSTALL_EXAMPLES_DIR  bin CACHE PATH "Installation directory for example files")
 122
 123 # Allow the user to use the old CyaSSL options/library in stead of wolfSSL
 124 if (LWS_USE_CYASSL AND LWS_USE_WOLFSSL)
 125         message(FATAL_ERROR "LWS_USE_CYASSL and LWS_USE_WOLFSSL are mutually exclusive!")
 126 endif()
 127 if (LWS_USE_CYASSL)
 128         # Copy CyaSSL options to the wolfSSL options
 129         set(LWS_USE_WOLFSSL ${LWS_USE_CYASSL} CACHE BOOL "Use wolfSSL/CyaSSL instead of OpenSSL" FORCE)
 130         set(LWS_WOLFSSL_LIBRARIES ${LWS_CYASSL_LIBRARIES} CACHE PATH "Path to wolfSSL/CyaSSL libraries" FORCE)
 131         set(LWS_WOLFSSL_INCLUDE_DIRS ${LWS_CYASSL_INCLUDE_DIRS} CACHE PATH "Path to wolfSSL/CyaSSL header files" FORCE)
 132 endif()
 133
 134 if (LWS_WITHOUT_CLIENT AND LWS_WITHOUT_SERVER)
 135         message(FATAL_ERROR "Makes no sense to compile with neither client nor server.")
 136 endif()
 137
 138 if (NOT (LWS_WITH_STATIC OR LWS_WITH_SHARED))
 139         message(FATAL_ERROR "Makes no sense to compile with neither static nor shared libraries.")
 140 endif()
 141
 142 if (NOT LWS_WITHOUT_EXTENSIONS)
 143         if (NOT LWS_WITH_ZLIB)
 144                 message(FATAL_ERROR "zlib is required for extensions.")
 145         endif()
 146 endif()
 147
 148 set(LWS_ZLIB_LIBRARIES CACHE PATH "Path to the zlib library")
 149 set(LWS_ZLIB_INCLUDE_DIRS CACHE PATH "Path to the zlib include directory")
 150 set(LWS_OPENSSL_LIBRARIES CACHE PATH "Path to the OpenSSL library")
 151 set(LWS_OPENSSL_INCLUDE_DIRS CACHE PATH "Path to the OpenSSL include directory")
 152 set(LWS_WOLFSSL_LIBRARIES CACHE PATH "Path to the wolfSSL library")
 153 set(LWS_WOLFSSL_INCLUDE_DIRS CACHE PATH "Path to the wolfSSL include directory")
 154 set(LWS_LIBEV_LIBRARIES CACHE PATH "Path to the libev library")
 155 set(LWS_LIBEV_INCLUDE_DIRS CACHE PATH "Path to the libev include directory")
 156 set(LWS_LIBUV_LIBRARIES CACHE PATH "Path to the libuv library")
 157 set(LWS_LIBUV_INCLUDE_DIRS CACHE PATH "Path to the libuv include directory")
 158
 159 if (NOT LWS_WITH_SSL)
 160         set(LWS_WITHOUT_BUILTIN_SHA1 OFF)
 161 endif()
 162
 163 if (LWS_WITH_SSL AND NOT LWS_USE_WOLFSSL)
 164         if ("${LWS_OPENSSL_LIBRARIES}" STREQUAL "" OR "${LWS_OPENSSL_INCLUDE_DIRS}" STREQUAL "")
 165         else()
 166                 set(OPENSSL_LIBRARIES ${LWS_OPENSSL_LIBRARIES})
 167                 set(OPENSSL_INCLUDE_DIRS ${LWS_OPENSSL_INCLUDE_DIRS})
 168                 set(OPENSSL_FOUND 1)
 169         endif()
 170 endif()
 171
 172 if (LWS_WITH_SSL AND LWS_USE_WOLFSSL)
 173         if ("${LWS_WOLFSSL_LIBRARIES}" STREQUAL "" OR "${LWS_WOLFSSL_INCLUDE_DIRS}" STREQUAL "")
 174                 if (NOT WOLFSSL_FOUND)
 175                         if (LWS_USE_CYASSL)
 176                                 message(FATAL_ERROR "You must set LWS_CYASSL_LIBRARIES and LWS_CYASSL_INCLUDE_DIRS when LWS_USE_CYASSL is turned on.")
 177                         else()
 178                                 message(FATAL_ERROR "You must set LWS_WOLFSSL_LIBRARIES and LWS_WOLFSSL_INCLUDE_DIRS when LWS_USE_WOLFSSL is turned on.")
 179                         endif()
 180                 endif()
 181         else()
 182                 set(WOLFSSL_LIBRARIES ${LWS_WOLFSSL_LIBRARIES})
 183                 set(WOLFSSL_INCLUDE_DIRS ${LWS_WOLFSSL_INCLUDE_DIRS})
 184                 set(WOLFSSL_FOUND 1)
 185         endif()
 186         set(USE_WOLFSSL 1)
 187         if (LWS_USE_CYASSL)
 188                 set(USE_OLD_CYASSL 1)
 189         endif()
 190 endif()
 191
 192 if (LWS_WITH_ZLIB AND NOT LWS_USE_BUNDLED_ZLIB)
 193         if ("${LWS_ZLIB_LIBRARIES}" STREQUAL "" OR "${LWS_ZLIB_INCLUDE_DIRS}" STREQUAL "")
 194         else()
 195                 set(ZLIB_LIBRARIES ${LWS_ZLIB_LIBRARIES})
 196                 set(ZLIB_INCLUDE_DIRS ${LWS_ZLIB_INCLUDE_DIRS})
 197                 set(ZLIB_FOUND 1)
 198         endif()
 199 endif()
 200
 201 if (LWS_WITH_LIBEV)
 202         if ("${LWS_LIBEV_LIBRARIES}" STREQUAL "" OR "${LWS_LIBEV_INCLUDE_DIRS}" STREQUAL "")
 203         else()
 204                 set(LIBEV_LIBRARIES ${LWS_LIBEV_LIBRARIES})
 205                 set(LIBEV_INCLUDE_DIRS ${LWS_LIBEV_INCLUDE_DIRS})
 206                 set(LIBEV_FOUND 1)
 207         endif()
 208 endif()
 209
 210 if (LWS_WITH_LIBUV)
 211         if ("${LWS_LIBUV_LIBRARIES}" STREQUAL "" OR "${LWS_LIBUV_INCLUDE_DIRS}" STREQUAL "")
 212         else()
 213                 set(LIBUV_LIBRARIES ${LWS_LIBUV_LIBRARIES})
 214                 set(LIBUV_INCLUDE_DIRS ${LWS_LIBUV_INCLUDE_DIRS})
 215                 set(LIBUV_FOUND 1)
 216         endif()
 217 endif()
 218
 219
 220 # FIXME: This must be runtime-only option.
 221 # The base dir where the test-apps look for the SSL certs.
 222 set(LWS_OPENSSL_CLIENT_CERTS ../share CACHE PATH "Server SSL certificate directory")
 223 if (WIN32)
 224         set(LWS_OPENSSL_CLIENT_CERTS . CACHE PATH "Client SSL certificate directory")
 225
 226         if (LWS_IPV6)
 227                 set(LWS_IPV6 OFF)
 228                 message(WARNING "IPv6 does not currently work on Windows!")
 229         endif()
 230 else()
 231         set(LWS_OPENSSL_CLIENT_CERTS /etc/pki/tls/certs/ CACHE PATH "Client SSL certificate directory")
 232 endif()
 233
 234 if (LWS_WITHOUT_EXTENSIONS)
 235         set(LWS_NO_EXTENSIONS 1)
 236 endif()
 237
 238 if (LWS_WITH_SSL)
 239         set(LWS_OPENSSL_SUPPORT 1)
 240 endif()
 241
 242 if (LWS_SSL_CLIENT_USE_OS_CA_CERTS)
 243         set(LWS_SSL_CLIENT_USE_OS_CA_CERTS 1)
 244 endif()
 245
 246 if (LWS_WITH_LATENCY)
 247         set(LWS_LATENCY 1)
 248 endif()
 249
 250 if (LWS_WITHOUT_DAEMONIZE OR WIN32)
 251         set(LWS_NO_DAEMONIZE 1)
 252 endif()
 253
 254 if (LWS_WITHOUT_SERVER)
 255         set(LWS_NO_SERVER 1)
 256 endif()
 257
 258 if (LWS_WITHOUT_CLIENT)
 259         set(LWS_NO_CLIENT 1)
 260 endif()
 261
 262 if (LWS_WITH_LIBEV)
 263         set(LWS_USE_LIBEV 1)
 264 endif()
 265
 266 if (LWS_WITH_LIBUV)
 267         set(LWS_USE_LIBUV 1)
 268 endif()
 269
 270 if (LWS_IPV6)
 271         set(LWS_USE_IPV6 1)
 272 endif()
 273
 274 if (LWS_WITH_HTTP2)
 275         set(LWS_USE_HTTP2 1)
 276 endif()
 277
 278 if ("${LWS_MAX_SMP}" STREQUAL "")
 279         set(LWS_MAX_SMP 32)
 280 endif()
 281
 282 #if (LWS_MBED3)
 283 #       set(CMAKE_C_FLAGS "-D_DEBUG ${CMAKE_C_FLAGS}")
 284 #endif()
 285
 286 if (MINGW)
 287         set(LWS_MINGW_SUPPORT 1)
 288         set(CMAKE_C_FLAGS "-D__USE_MINGW_ANSI_STDIO ${CMAKE_C_FLAGS}")
 289 endif()
 290
 291 if (LWS_SSL_SERVER_WITH_ECDH_CERT)
 292         set(LWS_SSL_SERVER_WITH_ECDH_CERT 1)
 293 endif()
 294
 295 include_directories("${PROJECT_BINARY_DIR}")
 296
 297 include(CheckCSourceCompiles)
 298
 299 # Check for different inline keyword versions.
 300 foreach(KEYWORD "inline" "__inline__" "__inline")
 301         set(CMAKE_REQUIRED_DEFINITIONS "-DKEYWORD=${KEYWORD}")
 302         CHECK_C_SOURCE_COMPILES(
 303                 "
 304                 #include <stdio.h>
 305                 static KEYWORD void a() {}
 306                 int main(int argc, char **argv) { a(); return 0; }
 307                 " LWS_HAVE_${KEYWORD})
 308 endforeach()
 309
 310 if (NOT LWS_HAVE_inline)
 311         if (LWS_HAVE___inline__)
 312                 set(inline __inline__)
 313         elseif(LWS_HAVE___inline)
 314                 set(inline __inline)
 315         endif()
 316 endif()
 317
 318 # Put the libaries and binaries that get built into directories at the
 319 # top of the build tree rather than in hard-to-find leaf directories.
 320 SET(CMAKE_RUNTIME_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin")
 321 SET(CMAKE_LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/lib")
 322 SET(CMAKE_ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/lib")
 323
 324 # Put absolute path of dynamic libraries into the object code. Some
 325 # architectures, notably Mac OS X, need this.
 326 SET(CMAKE_INSTALL_NAME_DIR "${CMAKE_INSTALL_PREFIX}/${LWS_INSTALL_LIB_DIR}${LIB_SUFFIX}")
 327
 328 include(CheckFunctionExists)
 329 include(CheckIncludeFile)
 330 include(CheckIncludeFiles)
 331 include(CheckLibraryExists)
 332 include(CheckTypeSize)
 333
 334 if (LWS_WITHOUT_BUILTIN_SHA1)
 335         set(LWS_SHA1_USE_OPENSSL_NAME 1)
 336 endif()
 337
 338 CHECK_FUNCTION_EXISTS(bzero LWS_HAVE_BZERO)
 339 CHECK_FUNCTION_EXISTS(fork LWS_HAVE_FORK)
 340 CHECK_FUNCTION_EXISTS(getenv LWS_HAVE_GETENV)
 341 CHECK_FUNCTION_EXISTS(malloc LWS_HAVE_MALLOC)
 342 CHECK_FUNCTION_EXISTS(memset LWS_HAVE_MEMSET)
 343 CHECK_FUNCTION_EXISTS(realloc LWS_HAVE_REALLOC)
 344 CHECK_FUNCTION_EXISTS(socket LWS_HAVE_SOCKET)
 345 CHECK_FUNCTION_EXISTS(strerror LWS_HAVE_STRERROR)
 346 CHECK_FUNCTION_EXISTS(vfork LWS_HAVE_VFORK)
 347 CHECK_FUNCTION_EXISTS(getifaddrs LWS_HAVE_GETIFADDRS)
 348 CHECK_FUNCTION_EXISTS(snprintf LWS_HAVE_SNPRINTF)
 349 CHECK_FUNCTION_EXISTS(_snprintf LWS_HAVE__SNPRINTF)
 350 CHECK_FUNCTION_EXISTS(_vsnprintf LWS_HAVE__VSNPRINTF)
 351
 352 if (NOT LWS_HAVE_GETIFADDRS)
 353         if (LWS_WITHOUT_BUILTIN_GETIFADDRS)
 354                 message(FATAL_ERROR "No getifaddrs was found on the system. Turn off the LWS_WITHOUT_BUILTIN_GETIFADDRS compile option to use the supplied BSD version.")
 355         endif()
 356         set(LWS_BUILTIN_GETIFADDRS 1)
 357 endif()
 358
 359 CHECK_INCLUDE_FILE(dlfcn.h LWS_HAVE_DLFCN_H)
 360 CHECK_INCLUDE_FILE(fcntl.h LWS_HAVE_FCNTL_H)
 361 CHECK_INCLUDE_FILE(in6addr.h LWS_HAVE_IN6ADDR_H)
 362 CHECK_INCLUDE_FILE(inttypes.h LWS_HAVE_INTTYPES_H)
 363 CHECK_INCLUDE_FILE(memory.h LWS_HAVE_MEMORY_H)
 364 CHECK_INCLUDE_FILE(netinet/in.h LWS_HAVE_NETINET_IN_H)
 365 CHECK_INCLUDE_FILE(stdint.h LWS_HAVE_STDINT_H)
 366 CHECK_INCLUDE_FILE(stdlib.h LWS_HAVE_STDLIB_H)
 367 CHECK_INCLUDE_FILE(strings.h LWS_HAVE_STRINGS_H)
 368 CHECK_INCLUDE_FILE(string.h LWS_HAVE_STRING_H)
 369 CHECK_INCLUDE_FILE(sys/prctl.h LWS_HAVE_SYS_PRCTL_H)
 370 CHECK_INCLUDE_FILE(sys/socket.h LWS_HAVE_SYS_SOCKET_H)
 371 CHECK_INCLUDE_FILE(sys/stat.h LWS_HAVE_SYS_STAT_H)
 372 CHECK_INCLUDE_FILE(sys/types.h LWS_HAVE_SYS_TYPES_H)
 373 CHECK_INCLUDE_FILE(unistd.h LWS_HAVE_UNISTD_H)
 374 CHECK_INCLUDE_FILE(vfork.h LWS_HAVE_VFORK_H)
 375
 376 if (LWS_WITH_ZLIB AND NOT LWS_USE_BUNDLED_ZLIB)
 377         CHECK_INCLUDE_FILE(zlib.h LWS_HAVE_ZLIB_H)
 378 endif()
 379
 380 # TODO: These can also be tested to see whether they actually work...
 381 set(LWS_HAVE_WORKING_FORK LWS_HAVE_FORK)
 382 set(LWS_HAVE_WORKING_VFORK LWS_HAVE_VFORK)
 383
 384 CHECK_INCLUDE_FILES("stdlib.h;stdarg.h;string.h;float.h" STDC_HEADERS)
 385
 386 # These don't work Cross...
 387 #CHECK_TYPE_SIZE(pid_t PID_T_SIZE)
 388 #CHECK_TYPE_SIZE(size_t SIZE_T_SIZE)
 389 #CHECK_TYPE_SIZE("void *" LWS_SIZEOFPTR LANGUAGE C)
 390
 391 if (NOT PID_T_SIZE)
 392         set(pid_t int)
 393 endif()
 394
 395 if (NOT SIZE_T_SIZE)
 396         set(size_t "unsigned int")
 397 endif()
 398
 399 if (NOT LWS_HAVE_MALLOC)
 400         set(malloc rpl_malloc)
 401 endif()
 402
 403 if (NOT LWS_HAVE_REALLOC)
 404         set(realloc rpl_realloc)
 405 endif()
 406
 407 # Generate the lws_config.h that includes all the public compilation settings.
 408 configure_file(
 409        "${PROJECT_SOURCE_DIR}/lws_config.h.in"
 410        "${PROJECT_BINARY_DIR}/lws_config.h")
 411
 412 # Generate the lws_config.h that includes all the private compilation settings.
 413 configure_file(
 414        "${PROJECT_SOURCE_DIR}/lws_config_private.h.in"
 415        "${PROJECT_BINARY_DIR}/lws_config_private.h")
 416
 417 if (MSVC)
 418         # Turn off stupid microsoft security warnings.
 419         add_definitions(-D_CRT_SECURE_NO_DEPRECATE -D_CRT_NONSTDC_NO_DEPRECATE)
 420 endif(MSVC)
 421
 422 include_directories("${PROJECT_SOURCE_DIR}/lib")
 423
 424 # Group headers and sources.
 425 # Some IDEs use this for nicer file structure.
 426 set(HDR_PRIVATE
 427         lib/private-libwebsockets.h)
 428
 429 set(HDR_PUBLIC
 430         "${PROJECT_SOURCE_DIR}/lib/libwebsockets.h"
 431         "${PROJECT_BINARY_DIR}/lws_config.h")
 432
 433 set(SOURCES
 434         lib/base64-decode.c
 435         lib/handshake.c
 436         lib/libwebsockets.c
 437         lib/service.c
 438         lib/pollfd.c
 439         lib/output.c
 440         lib/parsers.c
 441         lib/context.c
 442         lib/alloc.c
 443         lib/header.c)
 444
 445 if (NOT LWS_WITHOUT_CLIENT)
 446         list(APPEND SOURCES
 447                 lib/client.c
 448                 lib/client-handshake.c
 449                 lib/client-parser.c)
 450 endif()
 451
 452 if (LWS_WITH_SSL)
 453         list(APPEND SOURCES
 454                 lib/ssl.c)
 455 endif()
 456
 457 if (NOT LWS_WITHOUT_BUILTIN_SHA1)
 458         list(APPEND SOURCES
 459                 lib/sha-1.c)
 460 endif()
 461
 462 if (LWS_WITH_HTTP2)
 463         list(APPEND SOURCES
 464                 lib/http2.c
 465                 lib/hpack.c
 466                 lib/ssl-http2.c)
 467 endif()
 468 # select the active platform files
 469
 470 if (WIN32)
 471         list(APPEND SOURCES
 472                 lib/lws-plat-win.c)
 473 else()
 474         if (LWS_MBED3)
 475                 list(APPEND SOURCES
 476                         lib/lws-plat-mbed3.cpp
 477                         lib/lws-plat-mbed3.c)
 478         else()
 479                 list(APPEND SOURCES
 480                         lib/lws-plat-unix.c)
 481         endif()
 482 endif()
 483
 484 if (NOT LWS_WITHOUT_SERVER)
 485         list(APPEND SOURCES
 486                 lib/server.c
 487                 lib/server-handshake.c)
 488 endif()
 489
 490 if (NOT LWS_WITHOUT_EXTENSIONS)
 491         list(APPEND HDR_PRIVATE
 492                 lib/extension-permessage-deflate.h)
 493         list(APPEND SOURCES
 494                 lib/extension.c
 495                 lib/extension-permessage-deflate.c)
 496 endif()
 497
 498 if (LWS_WITH_HTTP_PROXY)
 499         list(APPEND SOURCES
 500                 lib/rewrite.c)
 501 endif()
 502
 503 if (LWS_WITH_LIBEV)
 504         list(APPEND SOURCES
 505                 lib/libev.c)
 506 endif()
 507
 508 if (LWS_WITH_LIBUV)
 509         list(APPEND SOURCES
 510                 lib/libuv.c)
 511 endif()
 512
 513 # Add helper files for Windows.
 514 if (WIN32)
 515         set(WIN32_HELPERS_PATH win32port/win32helpers)
 516         include_directories(${WIN32_HELPERS_PATH})
 517 else()
 518         # Unix.
 519         if (NOT LWS_WITHOUT_DAEMONIZE)
 520                 list(APPEND SOURCES
 521                         lib/daemonize.c)
 522         endif()
 523 endif()
 524
 525 if (UNIX)
 526         if (NOT LWS_HAVE_GETIFADDRS)
 527                 list(APPEND HDR_PRIVATE lib/getifaddrs.h)
 528                 list(APPEND SOURCES lib/getifaddrs.c)
 529         endif()
 530 endif()
 531
 532 if (CMAKE_COMPILER_IS_GNUCC OR CMAKE_COMPILER_IS_GNUCXX OR (CMAKE_C_COMPILER_ID MATCHES "Clang") OR (CMAKE_CXX_COMPILER_ID MATCHES "Clang"))
 533     include (CheckCCompilerFlag)
 534     CHECK_C_COMPILER_FLAG(-fvisibility=hidden LWS_HAVE_VISIBILITY)
 535     if (LWS_HAVE_VISIBILITY)
 536                 set(VISIBILITY_FLAG -fvisibility=hidden)
 537     endif()
 538     if (UNIX)
 539                set(CMAKE_C_FLAGS "-Wall -Werror ${VISIBILITY_FLAG} ${CMAKE_C_FLAGS}" )
 540     else(UNIX)
 541                set(CMAKE_C_FLAGS "-Wall ${VISIBILITY_FLAG} ${CMAKE_C_FLAGS}" )
 542     endif(UNIX)
 543 endif ()
 544
 545 if ((CMAKE_COMPILER_IS_GNUCC OR CMAKE_COMPILER_IS_GNUCXX) AND NOT LWS_WITHOUT_TESTAPPS)
 546     if (UNIX)
 547         # jeez clang understands -pthread but dies if he sees it at link time!
 548         # http://stackoverflow.com/questions/2391194/what-is-gs-pthread-equiv-in-clang
 549         set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -pthread" )
 550     endif()
 551 endif()
 552
 553 if ((CMAKE_C_COMPILER_ID MATCHES "Clang") OR (CMAKE_CXX_COMPILER_ID MATCHES "Clang"))
 554         # otherwise osx blows a bunch of openssl deprecated api errors
 555         set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -Wno-deprecated-declarations" )
 556 endif()
 557
 558 source_group("Headers Private"  FILES ${HDR_PRIVATE})
 559 source_group("Headers Public"   FILES ${HDR_PUBLIC})
 560 source_group("Sources"          FILES ${SOURCES})
 561
 562 #
 563 # Create the lib.
 564 #
 565 set(LWS_LIBRARIES)
 566
 567 if (LWS_WITH_STATIC)
 568         add_library(websockets STATIC
 569                                 ${HDR_PRIVATE}
 570                                 ${HDR_PUBLIC}
 571                                 ${SOURCES})
 572         list(APPEND LWS_LIBRARIES websockets)
 573
 574         if (WIN32)
 575                 # Windows uses the same .lib ending for static libraries and shared
 576                 # library linker files, so rename the static library.
 577                 set_target_properties(websockets
 578                         PROPERTIES
 579                         OUTPUT_NAME websockets_static)
 580         endif()
 581 endif()
 582
 583 if (LWS_WITH_SHARED)
 584         add_library(websockets_shared SHARED
 585                                 ${HDR_PRIVATE}
 586                                 ${HDR_PUBLIC}
 587                                 ${SOURCES})
 588         list(APPEND LWS_LIBRARIES websockets_shared)
 589
 590         # We want the shared lib to be named "libwebsockets"
 591         # not "libwebsocket_shared".
 592         set_target_properties(websockets_shared
 593                 PROPERTIES
 594                 OUTPUT_NAME websockets)
 595
 596         if (WIN32)
 597                 # Compile as DLL (export function declarations)
 598                 set_property(
 599                         TARGET websockets_shared
 600                         PROPERTY COMPILE_DEFINITIONS
 601                         LWS_DLL
 602                         LWS_INTERNAL)
 603         endif()
 604
 605         if (APPLE)
 606                 set_property(TARGET websockets_shared PROPERTY MACOSX_RPATH YES)
 607         endif()
 608 endif()
 609
 610 # Set the so version of the lib.
 611 # Equivalent to LDFLAGS=-version-info x:x:x
 612 if(CMAKE_COMPILER_IS_GNUCC OR CMAKE_COMPILER_IS_GNUCXX OR (CMAKE_C_COMPILER_ID MATCHES "Clang") OR (CMAKE_CXX_COMPILER_ID MATCHES "Clang"))
 613         foreach(lib ${LWS_LIBRARIES})
 614                 set_target_properties(${lib}
 615                         PROPERTIES
 616                         SOVERSION ${SOVERSION})
 617         endforeach()
 618 endif()
 619
 620 set(LIB_LIST)
 621
 622 #
 623 # Find libraries.
 624 #
 625
 626 #
 627 # ZLIB (Only needed for deflate extensions).
 628 #
 629 if (LWS_WITH_ZLIB)
 630         if (LWS_USE_BUNDLED_ZLIB)
 631                 if (WIN32)
 632                         set(WIN32_ZLIB_PATH "win32port/zlib")
 633                         set(ZLIB_SRCS
 634                                 ${WIN32_ZLIB_PATH}/adler32.c
 635                                 ${WIN32_ZLIB_PATH}/compress.c
 636                                 ${WIN32_ZLIB_PATH}/crc32.c
 637                                 ${WIN32_ZLIB_PATH}/deflate.c
 638                                 ${WIN32_ZLIB_PATH}/gzclose.c
 639                                 ${WIN32_ZLIB_PATH}/gzio.c
 640                                 ${WIN32_ZLIB_PATH}/gzlib.c
 641                                 ${WIN32_ZLIB_PATH}/gzread.c
 642                                 ${WIN32_ZLIB_PATH}/gzwrite.c
 643                                 ${WIN32_ZLIB_PATH}/infback.c
 644                                 ${WIN32_ZLIB_PATH}/inffast.c
 645                                 ${WIN32_ZLIB_PATH}/inflate.c
 646                                 ${WIN32_ZLIB_PATH}/inftrees.c
 647                                 ${WIN32_ZLIB_PATH}/trees.c
 648                                 ${WIN32_ZLIB_PATH}/uncompr.c
 649                                 ${WIN32_ZLIB_PATH}/zutil.c)
 650                         add_library(zlib_internal STATIC ${ZLIB_SRCS})
 651                         set(ZLIB_INCLUDE_DIRS ${WIN32_ZLIB_PATH})
 652                         get_property(ZLIB_LIBRARIES TARGET zlib_internal PROPERTY LOCATION)
 653                         set(ZLIB_FOUND 1)
 654                         # Make sure zlib_internal is compiled before the libs.
 655                         foreach (lib ${LWS_LIBRARIES})
 656                                 add_dependencies(${lib} zlib_internal)
 657                         endforeach()
 658                 else()
 659                         message(FATAL_ERROR "Don't have bundled zlib for that platform")
 660                 endif()
 661         elseif (NOT ZLIB_FOUND)
 662                 find_package(ZLIB REQUIRED)
 663         endif()
 664         message("zlib include dirs: ${ZLIB_INCLUDE_DIRS}")
 665         message("zlib libraries: ${ZLIB_LIBRARIES}")
 666         include_directories(${ZLIB_INCLUDE_DIRS})
 667         list(APPEND LIB_LIST ${ZLIB_LIBRARIES})
 668 endif()
 669
 670 #
 671 # OpenSSL
 672 #
 673 if (LWS_WITH_SSL)
 674         message("Compiling with SSL support")
 675
 676         if (LWS_USE_WOLFSSL)
 677                 # Use wolfSSL as OpenSSL replacement.
 678                 # TODO: Add a find_package command for this also.
 679                 message("wolfSSL include dir: ${WOLFSSL_INCLUDE_DIRS}")
 680                 message("wolfSSL libraries: ${WOLFSSL_LIBRARIES}")
 681
 682                 # Additional to the root directory we need to include
 683                 # the wolfssl/ subdirectory which contains the OpenSSL
 684                 # compatibility layer headers.
 685
 686                 if (LWS_USE_CYASSL)
 687                         foreach(inc ${WOLFSSL_INCLUDE_DIRS})
 688                                 include_directories("${inc}" "${inc}/cyassl")
 689                         endforeach()
 690                 else()
 691                         foreach(inc ${WOLFSSL_INCLUDE_DIRS})
 692                                 include_directories("${inc}" "${inc}/wolfssl")
 693                         endforeach()
 694                 endif()
 695
 696                 list(APPEND LIB_LIST "${WOLFSSL_LIBRARIES}")
 697         else()
 698                 if (NOT OPENSSL_FOUND)
 699                         # TODO: Add support for STATIC also.
 700                         find_package(OpenSSL REQUIRED)
 701                         set(OPENSSL_INCLUDE_DIRS "${OPENSSL_INCLUDE_DIR}")
 702                 endif()
 703
 704                 message("OpenSSL include dir: ${OPENSSL_INCLUDE_DIRS}")
 705                 message("OpenSSL libraries: ${OPENSSL_LIBRARIES}")
 706
 707                 include_directories("${OPENSSL_INCLUDE_DIRS}")
 708                 list(APPEND LIB_LIST ${OPENSSL_LIBRARIES})
 709         endif()
 710
 711         # older (0.98) Openssl lacks this
 712         set(CMAKE_REQUIRED_INCLUDES ${OPENSSL_INCLUDE_DIRS})
 713         check_include_file(openssl/ecdh.h LWS_HAVE_OPENSSL_ECDH_H)
 714
 715         if (LWS_SSL_SERVER_WITH_ECDH_CERT AND NOT LWS_HAVE_OPENSSL_ECDH_H)
 716                 message(FATAL_ERROR "Missing openssl/ecdh.h, so cannot use LWS_SSL_SERVER_WITH_ECDH_CERT")
 717         endif()
 718
 719 endif(LWS_WITH_SSL)
 720
 721 if (LWS_WITH_LIBEV)
 722         if (NOT LIBEV_FOUND)
 723                 find_path(LIBEV_INCLUDE_DIRS NAMES ev.h)
 724                 find_library(LIBEV_LIBRARIES NAMES ev)
 725                 if(LIBEV_INCLUDE_DIRS AND LIBEV_LIBRARIES)
 726                         set(LIBEV_FOUND 1)
 727                 endif()
 728         endif()
 729         message("libev include dir: ${LIBEV_INCLUDE_DIRS}")
 730         message("libev libraries: ${LIBEV_LIBRARIES}")
 731         include_directories("${LIBEV_INCLUDE_DIRS}")
 732         list(APPEND LIB_LIST ${LIBEV_LIBRARIES})
 733 endif(LWS_WITH_LIBEV)
 734
 735 if (LWS_WITH_LIBUV)
 736         if (NOT LIBUV_FOUND)
 737                 find_path(LIBUV_INCLUDE_DIRS NAMES uv.h)
 738                 find_library(LIBUV_LIBRARIES NAMES uv)
 739                 if(LIBUV_INCLUDE_DIRS AND LIBUV_LIBRARIES)
 740                         set(LIBUV_FOUND 1)
 741                 endif()
 742         endif()
 743         message("libuv include dir: ${LIBUV_INCLUDE_DIRS}")
 744         message("libuv libraries: ${LIBUV_LIBRARIES}")
 745         include_directories("${LIBUV_INCLUDE_DIRS}")
 746         list(APPEND LIB_LIST ${LIBUV_LIBRARIES})
 747 endif()
 748 if (LWS_WITH_HTTP_PROXY)
 749         find_library(LIBHUBBUB_LIBRARIES NAMES libhubbub)
 750         list(APPEND LIB_LIST ${LIBHUBBUB_LIBRARIES} )
 751 endif()
 752
 753
 754 #
 755 # Platform specific libs.
 756 #
 757 if (WINCE)
 758         list(APPEND LIB_LIST ws2.lib)
 759 elseif (WIN32)
 760         list(APPEND LIB_LIST ws2_32.lib)
 761 endif()
 762
 763 if (UNIX)
 764         list(APPEND LIB_LIST m)
 765 endif()
 766
 767 # Setup the linking for all libs.
 768 foreach (lib ${LWS_LIBRARIES})
 769         target_link_libraries(${lib} ${LIB_LIST})
 770 endforeach()
 771
 772 #
 773 # Test applications
 774 #
 775 set(TEST_APP_LIST)
 776 if (NOT LWS_WITHOUT_TESTAPPS)
 777         #
 778         # Helper function for adding a test app.
 779         #
 780         macro(create_test_app TEST_NAME MAIN_SRC S2 S3 S4 S5 S6)
 781
 782                 set(TEST_SRCS ${MAIN_SRC})
 783                 set(TEST_HDR)
 784                 if ("${S2}" STREQUAL "")
 785                 else()
 786                         list(APPEND TEST_SRCS ${S2})
 787                 endif()
 788                 if ("${S3}" STREQUAL "")
 789                 else()
 790                         list(APPEND TEST_SRCS ${S3})
 791                 endif()
 792                 if ("${S4}" STREQUAL "")
 793                 else()
 794                         list(APPEND TEST_SRCS ${S4})
 795                 endif()
 796                 if ("${S5}" STREQUAL "")
 797                 else()
 798                         list(APPEND TEST_SRCS ${S5})
 799                 endif()
 800                 if ("${S6}" STREQUAL "")
 801                 else()
 802                         list(APPEND TEST_SRCS ${S6})
 803                 endif()
 804                 if (WIN32)
 805                         list(APPEND TEST_SRCS
 806                                 ${WIN32_HELPERS_PATH}/getopt.c
 807                                 ${WIN32_HELPERS_PATH}/getopt_long.c
 808                                 ${WIN32_HELPERS_PATH}/gettimeofday.c
 809                         )
 810
 811                         list(APPEND TEST_HDR
 812                                 ${WIN32_HELPERS_PATH}/getopt.h
 813                                 ${WIN32_HELPERS_PATH}/gettimeofday.h
 814                         )
 815                 endif(WIN32)
 816
 817                 source_group("Headers Private"   FILES ${TEST_HDR})
 818                 source_group("Sources"   FILES ${TEST_SRCS})
 819                 add_executable(${TEST_NAME} ${TEST_SRCS} ${TEST_HDR})
 820
 821                 if (LWS_LINK_TESTAPPS_DYNAMIC)
 822                         if (NOT LWS_WITH_SHARED)
 823                                 message(FATAL_ERROR "Build of the shared library is disabled. LWS_LINK_TESTAPPS_DYNAMIC must be combined with LWS_WITH_SHARED.")
 824                         endif()
 825                         target_link_libraries(${TEST_NAME} websockets_shared)
 826                         add_dependencies(${TEST_NAME} websockets_shared)
 827                 else()
 828                         if (NOT LWS_WITH_STATIC)
 829                                 message(FATAL_ERROR "Build of the static library is disabled. Disabled LWS_LINK_TESTAPPS_DYNAMIC must be combined with LWS_WITH_STATIC.")
 830                         endif()
 831                         target_link_libraries(${TEST_NAME} websockets)
 832                         add_dependencies(${TEST_NAME} websockets)
 833                 endif()
 834
 835                 # Set test app specific defines.
 836                 set_property(TARGET ${TEST_NAME}
 837                                         PROPERTY COMPILE_DEFINITIONS
 838                                                 INSTALL_DATADIR="${CMAKE_INSTALL_PREFIX}/share"
 839                                         )
 840
 841                 # Prefix the binary names with libwebsockets.
 842                 set_target_properties(${TEST_NAME}
 843                         PROPERTIES
 844                         OUTPUT_NAME libwebsockets-${TEST_NAME})
 845
 846                 # Add to the list of tests.
 847                 list(APPEND TEST_APP_LIST ${TEST_NAME})
 848         endmacro()
 849
 850         if (LWS_WITH_SSL AND NOT LWS_USE_WOLFSSL)
 851                 message("Searching for OpenSSL executable and dlls")
 852                 find_package(OpenSSLbins)
 853                 message("OpenSSL executable: ${OPENSSL_EXECUTABLE}")
 854         endif()
 855
 856         if (NOT LWS_WITHOUT_SERVER)
 857                 #
 858                 # test-server
 859                 #
 860                 if (NOT LWS_WITHOUT_TEST_SERVER)
 861                         create_test_app(test-server "test-server/test-server.c"
 862                                 "test-server/test-server-http.c"
 863                                 "test-server/test-server-dumb-increment.c"
 864                                 "test-server/test-server-mirror.c"
 865                                 "test-server/test-server-status.c"
 866                                 "test-server/test-server-echogen.c")
 867                         if (UNIX)
 868                                 create_test_app(test-fuzxy "test-server/fuzxy.c"
 869                                         ""
 870                                         ""
 871                                         ""
 872                                         ""
 873                                         "")
 874                         endif()
 875                         if (UNIX AND NOT ((CMAKE_C_COMPILER_ID MATCHES "Clang") OR (CMAKE_CXX_COMPILER_ID MATCHES "Clang")))
 876                                 create_test_app(test-server-pthreads
 877                                         "test-server/test-server-pthreads.c"
 878                                         "test-server/test-server-http.c"
 879                                         "test-server/test-server-dumb-increment.c"
 880                                         "test-server/test-server-mirror.c"
 881                                         "test-server/test-server-status.c"
 882                                         "test-server/test-server-echogen.c")
 883                         endif()
 884                         if (UNIX AND NOT ((CMAKE_C_COMPILER_ID MATCHES "Clang") OR (CMAKE_CXX_COMPILER_ID MATCHES "Clang"))
 885                                 AND LWS_WITH_LIBEV)
 886                                 create_test_app(test-server-libev
 887                                         "test-server/test-server-libev.c"
 888                                         "test-server/test-server-http.c"
 889                                         "test-server/test-server-dumb-increment.c"
 890                                         "test-server/test-server-mirror.c"
 891                                         "test-server/test-server-status.c"
 892                                         "test-server/test-server-echogen.c")
 893                         endif()
 894                         if (UNIX AND NOT ((CMAKE_C_COMPILER_ID MATCHES "Clang") OR (CMAKE_CXX_COMPILER_ID MATCHES "Clang"))
 895                                 AND LWS_WITH_LIBUV)
 896                                 create_test_app(test-server-libuv
 897                                         "test-server/test-server-libuv.c"
 898                                         "test-server/test-server-http.c"
 899                                         "test-server/test-server-dumb-increment.c"
 900                                         "test-server/test-server-mirror.c"
 901                                         "test-server/test-server-status.c"
 902                                         "test-server/test-server-echogen.c")
 903                         endif()
 904                 endif()
 905
 906                 #
 907                 # test-server-extpoll
 908                 #
 909                 if (NOT LWS_WITHOUT_TEST_SERVER_EXTPOLL)
 910                         create_test_app(test-server-extpoll "test-server/test-server.c"
 911                                 "test-server/test-server-http.c"
 912                                 "test-server/test-server-dumb-increment.c"
 913                                 "test-server/test-server-mirror.c"
 914                                 "test-server/test-server-status.c"
 915                                 "test-server/test-server-echogen.c")
 916                         # Set defines for this executable only.
 917                         set_property(
 918                                 TARGET test-server-extpoll
 919                                 PROPERTY COMPILE_DEFINITIONS
 920                                         EXTERNAL_POLL
 921                                         INSTALL_DATADIR="${CMAKE_INSTALL_PREFIX}/share"
 922                                 )
 923
 924                         # We need to link against winsock code.
 925                         if (WIN32)
 926                                 target_link_libraries(test-server-extpoll ws2_32.lib)
 927                         endif(WIN32)
 928                 endif()
 929
 930                 # Data files for running the test server.
 931                 set(TEST_SERVER_DATA
 932                         "${PROJECT_SOURCE_DIR}/test-server/favicon.ico"
 933                         "${PROJECT_SOURCE_DIR}/test-server/leaf.jpg"
 934                         "${PROJECT_SOURCE_DIR}/test-server/libwebsockets.org-logo.png"
 935                         "${PROJECT_SOURCE_DIR}/test-server/test.html")
 936
 937                 # Generate self-signed SSL certs for the test-server.
 938                 if (LWS_WITH_SSL AND OPENSSL_EXECUTABLE AND NOT LWS_WITHOUT_TEST_SERVER)
 939                         message("Generating SSL Certificates for the test-server...")
 940
 941                         set(TEST_SERVER_SSL_KEY "${PROJECT_BINARY_DIR}/libwebsockets-test-server.key.pem")
 942                         set(TEST_SERVER_SSL_CERT "${PROJECT_BINARY_DIR}/libwebsockets-test-server.pem")
 943
 944                         if (WIN32)
 945                                 if (MINGW)
 946                                         message("cmd = \"${OPENSSL_EXECUTABLE}\" req -new -newkey rsa:1024 -days 10000 -nodes -x509 -subj \"/C=GB/ST=Erewhon/L=All around/O=libwebsockets-test/CN=localhost\" -keyout \"${TEST_SERVER_SSL_KEY}\" -out \"${TEST_SERVER_SSL_CERT}\"")
 947                                         execute_process(
 948                                                 COMMAND "${OPENSSL_EXECUTABLE}" req -new -newkey rsa:1024 -days 10000 -nodes -x509 -subj "/C=GB/ST=Erewhon/L=All around/O=libwebsockets-test/CN=localhost" -keyout "${TEST_SERVER_SSL_KEY}" -out "${TEST_SERVER_SSL_CERT}"
 949                                                 RESULT_VARIABLE OPENSSL_RETURN_CODE)
 950                                 else()
 951                                         file(WRITE "${PROJECT_BINARY_DIR}/openssl_input.txt"
 952                                                 "GB\n"
 953                                                 "Erewhon\n"
 954                                                 "All around\n"
 955                                                 "libwebsockets-test\n"
 956                                                 "localhost\n"
 957                                                 "none@invalid.org\n\n"
 958                                                 )
 959
 960                                         # The "type" command is a bit picky with paths.
 961                                         file(TO_NATIVE_PATH "${PROJECT_BINARY_DIR}/openssl_input.txt" OPENSSL_INPUT_WIN_PATH)
 962                                         message("OPENSSL_INPUT_WIN_PATH = ${OPENSSL_INPUT_WIN_PATH}")
 963                                         message("cmd = \"${OPENSSL_EXECUTABLE}\" req -new -newkey rsa:1024 -days 10000 -nodes -x509 -keyout \"${TEST_SERVER_SSL_KEY}\" -out \"${TEST_SERVER_SSL_CERT}\"")
 964
 965                                         execute_process(
 966                                                 COMMAND cmd /c type "${OPENSSL_INPUT_WIN_PATH}"
 967                                                 COMMAND "${OPENSSL_EXECUTABLE}" req -new -newkey rsa:1024 -days 10000 -nodes -x509 -keyout "${TEST_SERVER_SSL_KEY}" -out "${TEST_SERVER_SSL_CERT}"
 968                                                 RESULT_VARIABLE OPENSSL_RETURN_CODE
 969                                                 OUTPUT_QUIET ERROR_QUIET)
 970
 971                                         message("\n")
 972                                 endif()
 973
 974                                 if (OPENSSL_RETURN_CODE)
 975                                         message(WARNING "!!! Failed to generate SSL certificate for Test Server using cmd.exe !!!:\nOpenSSL return code = ${OPENSSL_RETURN_CODE}")
 976                                 else()
 977                                         message("SUCCSESFULLY generated SSL certificate")
 978                                 endif()
 979                         else()
 980                                 # Unix.
 981                                 execute_process(
 982                                         COMMAND printf "GB\\nErewhon\\nAll around\\nlibwebsockets-test\\n\\nlocalhost\\nnone@invalid.org\\n"
 983                                         COMMAND "${OPENSSL_EXECUTABLE}"
 984                                                 req -new -newkey rsa:1024 -days 10000 -nodes -x509 -keyout "${TEST_SERVER_SSL_KEY}" -out "${TEST_SERVER_SSL_CERT}"
 985                                         RESULT_VARIABLE OPENSSL_RETURN_CODE
 986                                         OUTPUT_QUIET ERROR_QUIET)
 987
 988                                 if (OPENSSL_RETURN_CODE)
 989                                         message(WARNING "!!! Failed to generate SSL certificate for Test Server!!!:\nOpenSSL return code = ${OPENSSL_RETURN_CODE}")
 990                                 else()
 991                                         message("SUCCESSFULLY generated SSL certificate")
 992                                 endif()
 993                         endif()
 994
 995                         list(APPEND TEST_SERVER_DATA
 996                                 "${TEST_SERVER_SSL_KEY}"
 997                                 "${TEST_SERVER_SSL_CERT}")
 998                 endif()
 999
1000                 add_custom_command(TARGET test-server
1001                                                 POST_BUILD
1002                                                 COMMAND "${CMAKE_COMMAND}" -E make_directory "$<TARGET_FILE_DIR:test-server>/../share/libwebsockets-test-server")
1003
1004                 # Copy the file needed to run the server so that the test apps can
1005                 # reach them from their default output location
1006                 foreach (TEST_FILE ${TEST_SERVER_DATA})
1007                         if (EXISTS ${TEST_FILE})
1008                                 add_custom_command(TARGET test-server
1009                                                         POST_BUILD
1010                                                         COMMAND "${CMAKE_COMMAND}" -E copy "${TEST_FILE}" "$<TARGET_FILE_DIR:test-server>/../share/libwebsockets-test-server" VERBATIM)
1011                         endif()
1012                 endforeach()
1013         endif(NOT LWS_WITHOUT_SERVER)
1014
1015         if (NOT LWS_WITHOUT_CLIENT)
1016                 #
1017                 # test-client
1018                 #
1019                 if (NOT LWS_WITHOUT_TEST_CLIENT)
1020                         create_test_app(test-client "test-server/test-client.c" "" "" "" "" "")
1021                 endif()
1022
1023                 #
1024                 # test-fraggle
1025                 #
1026                 if (NOT LWS_WITHOUT_TEST_FRAGGLE)
1027                         create_test_app(test-fraggle "test-server/test-fraggle.c" "" "" "" "" "")
1028                 endif()
1029
1030                 #
1031                 # test-ping
1032                 #
1033                 if (NOT LWS_WITHOUT_TEST_PING)
1034                         create_test_app(test-ping "test-server/test-ping.c" "" "" "" "" "")
1035                 endif()
1036                 #
1037                 # test-echo
1038                 #
1039                 if (NOT LWS_WITHOUT_TEST_ECHO)
1040                         create_test_app(test-echo "test-server/test-echo.c" "" "" "" "" "")
1041                 endif()
1042
1043         endif(NOT LWS_WITHOUT_CLIENT)
1044
1045         #
1046         # Copy OpenSSL dlls to the output directory on Windows.
1047         # (Otherwise we'll get an error when trying to run)
1048         #
1049         if (WIN32 AND LWS_WITH_SSL AND NOT LWS_USE_WOLFSSL)
1050                 if(OPENSSL_BIN_FOUND)
1051                         message("OpenSSL dlls found:")
1052                         message("  Libeay: ${LIBEAY_BIN}")
1053                         message("  SSLeay: ${SSLEAY_BIN}")
1054
1055                         foreach(TARGET_BIN ${TEST_APP_LIST})
1056                                 add_custom_command(TARGET ${TARGET_BIN}
1057                                         POST_BUILD
1058                                         COMMAND "${CMAKE_COMMAND}" -E copy "${LIBEAY_BIN}" "$<TARGET_FILE_DIR:${TARGET_BIN}>" VERBATIM)
1059                                 add_custom_command(TARGET ${TARGET_BIN}
1060                                         POST_BUILD
1061                                         COMMAND "${CMAKE_COMMAND}" -E copy "${SSLEAY_BIN}" "$<TARGET_FILE_DIR:${TARGET_BIN}>" VERBATIM)
1062                         endforeach()
1063                 endif()
1064         endif()
1065 endif(NOT LWS_WITHOUT_TESTAPPS)
1066
1067 if (UNIX)
1068         # Generate documentation.
1069         # TODO: Fix this on Windows.
1070         message("Generating API documentation")
1071         file(GLOB C_FILES "${PROJECT_SOURCE_DIR}/lib/*.c")
1072         list(SORT C_FILES)
1073         execute_process(COMMAND "${CMAKE_COMMAND}" -E make_directory "${PROJECT_BINARY_DIR}/doc/")
1074
1075         execute_process(
1076                 COMMAND "${PROJECT_SOURCE_DIR}/scripts/kernel-doc" -html ${C_FILES} ${HDR_PUBLIC}
1077                 OUTPUT_FILE "${PROJECT_BINARY_DIR}/doc/libwebsockets-api-doc.html"
1078                 ERROR_QUIET)
1079
1080         execute_process(
1081                 COMMAND "${PROJECT_SOURCE_DIR}/scripts/kernel-doc" -text ${C_FILES} ${HDR_PUBLIC}
1082                 OUTPUT_FILE "${PROJECT_BINARY_DIR}/doc/libwebsockets-api-doc.txt"
1083                 ERROR_QUIET)
1084
1085 # Generate and install pkgconfig.
1086 # (This is not indented, because the tabs will be part of the output)
1087 file(WRITE "${PROJECT_BINARY_DIR}/libwebsockets.pc"
1088 "prefix=\"${CMAKE_INSTALL_PREFIX}\"
1089 exec_prefix=\${prefix}
1090 libdir=\${exec_prefix}/lib${LIB_SUFFIX}
1091 includedir=\${prefix}/include
1092
1093 Name: libwebsockets
1094 Description: Websockets server and client library
1095 Version: ${CPACK_PACKAGE_VERSION_MAJOR}.${CPACK_PACKAGE_VERSION_MINOR}.${CPACK_PACKAGE_VERSION_PATCH}
1096
1097 Libs: -L\${libdir} -lwebsockets
1098 Cflags: -I\${includedir}"
1099 )
1100
1101         install(FILES "${PROJECT_BINARY_DIR}/libwebsockets.pc"
1102                 DESTINATION lib${LIB_SUFFIX}/pkgconfig)
1103 endif(UNIX)
1104
1105 #
1106 # Installation preparations.
1107 #
1108
1109 if(WIN32 AND NOT CYGWIN)
1110   set(DEF_INSTALL_CMAKE_DIR cmake)
1111 else()
1112   set(DEF_INSTALL_CMAKE_DIR lib${LIB_SUFFIX}/cmake/libwebsockets)
1113 endif()
1114
1115 set(LWS_INSTALL_CMAKE_DIR ${DEF_INSTALL_CMAKE_DIR} CACHE PATH "Installation directory for CMake files")
1116
1117 # Export targets (This is used for other CMake projects to easily find the libraries and include files).
1118 export(TARGETS ${LWS_LIBRARIES}
1119         FILE "${PROJECT_BINARY_DIR}/LibwebsocketsTargets.cmake")
1120 export(PACKAGE libwebsockets)
1121
1122 # Generate the config file for the build-tree.
1123 set(LWS__INCLUDE_DIRS
1124     "${PROJECT_SOURCE_DIR}/lib"
1125     "${PROJECT_BINARY_DIR}")
1126 set(LIBWEBSOCKETS_INCLUDE_DIRS ${LWS__INCLUDE_DIRS} CACHE PATH "Libwebsockets include directories")
1127 configure_file(${PROJECT_SOURCE_DIR}/cmake/LibwebsocketsConfig.cmake.in
1128                 ${PROJECT_BINARY_DIR}/LibwebsocketsConfig.cmake
1129                 @ONLY)
1130
1131 # Generate the config file for the installation tree.
1132 get_filename_component(LWS_ABSOLUTE_INSTALL_CMAKE_DIR ${LWS_INSTALL_CMAKE_DIR} ABSOLUTE)
1133 get_filename_component(LWS_ABSOLUTE_INSTALL_INCLUDE_DIR ${LWS_INSTALL_INCLUDE_DIR} ABSOLUTE)
1134 file(RELATIVE_PATH
1135     REL_INCLUDE_DIR
1136     "${LWS_ABSOLUTE_INSTALL_CMAKE_DIR}"
1137     "${LWS_ABSOLUTE_INSTALL_INCLUDE_DIR}") # Calculate the relative directory from the cmake dir.
1138
1139 # Note the EVENT_CMAKE_DIR is defined in JanssonConfig.cmake.in,
1140 # we escape it here so it's evaluated when it is included instead
1141 # so that the include dirs are given relative to where the
1142 # config file is located.
1143 set(LWS__INCLUDE_DIRS
1144     "\${LWS_CMAKE_DIR}/${REL_INCLUDE_DIR}")
1145 configure_file(${PROJECT_SOURCE_DIR}/cmake/LibwebsocketsConfig.cmake.in
1146                 ${PROJECT_BINARY_DIR}${CMAKE_FILES_DIRECTORY}/LibwebsocketsConfig.cmake
1147                 @ONLY)
1148
1149 # Generate version info for both build-tree and install-tree.
1150 configure_file(${PROJECT_SOURCE_DIR}/cmake/LibwebsocketsConfigVersion.cmake.in
1151                 ${PROJECT_BINARY_DIR}/LibwebsocketsConfigVersion.cmake
1152                 @ONLY)
1153
1154                         set_target_properties(${LWS_LIBRARIES}
1155                                         PROPERTIES PUBLIC_HEADER "${HDR_PUBLIC}")
1156
1157 #
1158 # Installation.
1159 #
1160
1161 # Install libs and headers.
1162 install(TARGETS ${LWS_LIBRARIES}
1163                 EXPORT LibwebsocketsTargets
1164                 LIBRARY DESTINATION "${LWS_INSTALL_LIB_DIR}${LIB_SUFFIX}" COMPONENT libraries
1165                 ARCHIVE DESTINATION "${LWS_INSTALL_LIB_DIR}${LIB_SUFFIX}" COMPONENT libraries
1166                 RUNTIME DESTINATION "${LWS_INSTALL_BIN_DIR}" COMPONENT libraries # Windows DLLs
1167                 PUBLIC_HEADER DESTINATION "${LWS_INSTALL_INCLUDE_DIR}" COMPONENT dev)
1168 set(CPACK_COMPONENT_LIBRARIES_DISPLAY_NAME "Libraries")
1169 set(CPACK_COMPONENT_DEV_DISPLAY_NAME "Development files")
1170
1171 # Install test apps.
1172 if (NOT LWS_WITHOUT_TESTAPPS AND NOT LWS_WITHOUT_CLIENT)
1173         install(TARGETS test-client ${TEST_APP_LIST}
1174                         RUNTIME DESTINATION ${LWS_INSTALL_EXAMPLES_DIR}
1175                         COMPONENT examples)
1176         set(CPACK_COMPONENT_EXAMPLES_DISPLAY_NAME "Example files")
1177 endif()
1178
1179 # Programs shared files used by the test-server.
1180 if (NOT LWS_WITHOUT_TESTAPPS AND NOT LWS_WITHOUT_SERVER)
1181         install(FILES ${TEST_SERVER_DATA}
1182                         DESTINATION share/libwebsockets-test-server
1183                         COMPONENT examples)
1184 if (LWS_WITH_CGI)
1185         set(CGI_TEST_SCRIPT "${PROJECT_SOURCE_DIR}/test-server/lws-cgi-test.sh")
1186         install(FILES ${CGI_TEST_SCRIPT}
1187                         PERMISSIONS  OWNER_EXECUTE GROUP_EXECUTE WORLD_EXECUTE OWNER_READ GROUP_READ WORLD_READ
1188                         DESTINATION share/libwebsockets-test-server
1189                         COMPONENT examples)
1190         endif()
1191 endif()
1192
1193 # Install the LibwebsocketsConfig.cmake and LibwebsocketsConfigVersion.cmake
1194 install(FILES
1195                "${PROJECT_BINARY_DIR}${CMAKE_FILES_DIRECTORY}/LibwebsocketsConfig.cmake"
1196                "${PROJECT_BINARY_DIR}/LibwebsocketsConfigVersion.cmake"
1197                DESTINATION "${LWS_INSTALL_CMAKE_DIR}" COMPONENT dev)
1198
1199 # build subdir is not part of sources
1200 set(CPACK_SOURCE_IGNORE_FILES $(CPACK_SOURCE_IGNORE_FILES) ".git" "build" "tgz" "tar.gz")
1201
1202 # Most people are more used to "make dist" compared to "make package_source"
1203 add_custom_target(dist COMMAND "${CMAKE_MAKE_PROGRAM}" package_source)
1204
1205 include(UseRPMTools)
1206 if (RPMTools_FOUND)
1207         RPMTools_ADD_RPM_TARGETS(libwebsockets libwebsockets.spec)
1208 endif()
1209
1210 message("---------------------------------------------------------------------")
1211 message("  Settings:  (For more help do cmake -LH <srcpath>)")
1212 message("---------------------------------------------------------------------")
1213 message(" LWS_WITH_STATIC = ${LWS_WITH_STATIC}")
1214 message(" LWS_WITH_SHARED = ${LWS_WITH_SHARED}")
1215 message(" LWS_WITH_SSL = ${LWS_WITH_SSL} (SSL Support)")
1216 message(" LWS_SSL_CLIENT_USE_OS_CA_CERTS = ${LWS_SSL_CLIENT_USE_OS_CA_CERTS}")
1217 message(" LWS_USE_WOLFSSL = ${LWS_USE_WOLFSSL} (wolfSSL/CyaSSL replacement for OpenSSL)")
1218 if (LWS_USE_WOLFSSL)
1219         message("   LWS_WOLFSSL_LIBRARIES = ${LWS_WOLFSSL_LIBRARIES}")
1220         message("   LWS_WOLFSSL_INCLUDE_DIRS = ${LWS_WOLFSSL_INCLUDE_DIRS}")
1221 endif()
1222 message(" LWS_WITHOUT_BUILTIN_SHA1 = ${LWS_WITHOUT_BUILTIN_SHA1}")
1223 message(" LWS_WITHOUT_BUILTIN_GETIFADDRS = ${LWS_WITHOUT_BUILTIN_GETIFADDRS}")
1224 message(" LWS_WITHOUT_CLIENT = ${LWS_WITHOUT_CLIENT}")
1225 message(" LWS_WITHOUT_SERVER = ${LWS_WITHOUT_SERVER}")
1226 message(" LWS_LINK_TESTAPPS_DYNAMIC = ${LWS_LINK_TESTAPPS_DYNAMIC}")
1227 message(" LWS_WITHOUT_TESTAPPS = ${LWS_WITHOUT_TESTAPPS}")
1228 message(" LWS_WITHOUT_TEST_SERVER = ${LWS_WITHOUT_TEST_SERVER}")
1229 message(" LWS_WITHOUT_TEST_SERVER_EXTPOLL = ${LWS_WITHOUT_TEST_SERVER_EXTPOLL}")
1230 message(" LWS_WITHOUT_TEST_PING = ${LWS_WITHOUT_TEST_PING}")
1231 message(" LWS_WITHOUT_TEST_ECHO = ${LWS_WITHOUT_TEST_ECHO}")
1232 message(" LWS_WITHOUT_TEST_CLIENT = ${LWS_WITHOUT_TEST_CLIENT}")
1233 message(" LWS_WITHOUT_TEST_FRAGGLE = ${LWS_WITHOUT_TEST_FRAGGLE}")
1234 message(" LWS_WITHOUT_EXTENSIONS = ${LWS_WITHOUT_EXTENSIONS}")
1235 message(" LWS_WITH_LATENCY = ${LWS_WITH_LATENCY}")
1236 message(" LWS_WITHOUT_DAEMONIZE = ${LWS_WITHOUT_DAEMONIZE}")
1237 message(" LWS_USE_LIBEV = ${LWS_USE_LIBEV}")
1238 message(" LWS_USE_LIBUV = ${LWS_USE_LIBUV}")
1239 message(" LWS_IPV6 = ${LWS_IPV6}")
1240 message(" LWS_WITH_HTTP2 = ${LWS_WITH_HTTP2}")
1241 message(" LWS_MBED3 = ${LWS_MBED3}")
1242 message(" LWS_SSL_SERVER_WITH_ECDH_CERT = ${LWS_SSL_SERVER_WITH_ECDH_CERT}")
1243 message(" LWS_MAX_SMP = ${LWS_MAX_SMP}")
1244 message(" LWS_WITH_CGI = ${LWS_WITH_CGI}")
1245 message(" LWS_HAVE_OPENSSL_ECDH_H = ${LWS_HAVE_OPENSSL_ECDH_H}")
1246 message(" LWS_WITH_HTTP_PROXY = ${LWS_WITH_HTTP_PROXY}")
1247 message(" LIBHUBBUB_LIBRARIES = ${LIBHUBBUB_LIBRARIES}")
1248 message("---------------------------------------------------------------------")
1249
1250 # These will be available to parent projects including libwebsockets using add_subdirectory()
1251 set(LIBWEBSOCKETS_LIBRARIES ${LWS_LIBRARIES} CACHE STRING "Libwebsocket libraries")
1252 if (LWS_WITH_STATIC)
1253         set(LIBWEBSOCKETS_LIBRARIES_STATIC websocket CACHE STRING "Libwebsocket static library")
1254 endif()
1255 if (LWS_WITH_SHARED)
1256         set(LIBWEBSOCKETS_LIBRARIES_SHARED websockets_shared CACHE STRING "Libwebsocket shared library")
1257 endif()
1258
1259 # This must always be last!
1260 include(CPack)