CMakeLists.txt

   1 PROJECT (libsolv)
   2
   3 CMAKE_MINIMUM_REQUIRED (VERSION 2.4)
   4
   5 OPTION (ENABLE_STATIC "Build a static version of the libraries?" OFF)
   6 OPTION (DISABLE_SHARED "Do not build a shared version of the libraries?" OFF)
   7
   8 OPTION (ENABLE_PERL "Build the perl bindings?" OFF)
   9 OPTION (ENABLE_PYTHON "Build the python bindings?" OFF)
  10 OPTION (ENABLE_RUBY "Build the ruby bindings?" OFF)
  11
  12 OPTION (USE_VENDORDIRS "Install the bindings in vendor directories?" OFF)
  13
  14 OPTION (ENABLE_RPMDB "Build with rpm database support?" OFF)
  15 OPTION (ENABLE_RPMDB_PUBKEY "Build with rpmdb pubkey support?" OFF)
  16 OPTION (ENABLE_RPMMD "Build with rpmmd repository support?" OFF)
  17 OPTION (ENABLE_SUSEREPO "Build with suse repository support?" OFF)
  18 OPTION (ENABLE_COMPS "Build with fedora comps support?" OFF)
  19 OPTION (ENABLE_HELIXREPO "Build with helix repository support?" OFF)
  20 OPTION (ENABLE_DEBIAN "Build with debian database/repository support?" OFF)
  21 OPTION (ENABLE_MDKREPO "Build with mandriva/mageia repository support?" OFF)
  22 OPTION (ENABLE_ARCHREPO "Build with archlinux repository support?" OFF)
  23
  24 OPTION (ENABLE_LZMA_COMPRESSION "Build with lzma/xz compression support?" OFF)
  25
  26 #IF(${CMAKE_MAJOR_VERSION}.${CMAKE_MINOR_VERISION} GREATER 2.4)
  27 #ENDIF(${CMAKE_MAJOR_VERSION}.${CMAKE_MINOR_VERISION} GREATER 2.4)
  28
  29 IF (COMMAND cmake_policy)
  30   # escape preprocessor, see -DVERSION below
  31   CMAKE_POLICY (SET CMP0005 OLD)
  32 ENDIF (COMMAND cmake_policy)
  33
  34 # Library
  35 IF (DEFINED LIB)
  36   SET (LIB_INSTALL_DIR "${CMAKE_INSTALL_PREFIX}/${LIB}")
  37 ELSE (DEFINED  LIB)
  38   IF (CMAKE_SIZEOF_VOID_P MATCHES "8")
  39     SET (LIB_SUFFIX "64")
  40   ENDIF (CMAKE_SIZEOF_VOID_P MATCHES "8")
  41   SET (LIB_INSTALL_DIR "${CMAKE_INSTALL_PREFIX}/lib${LIB_SUFFIX}")
  42 ENDIF (DEFINED  LIB)
  43 MESSAGE (STATUS "Libraries will be installed in ${LIB_INSTALL_DIR}")
  44 SET (BIN_INSTALL_DIR "${CMAKE_INSTALL_PREFIX}/bin")
  45
  46 ####################################################################
  47 # CONFIGURATION                                                    #
  48 ####################################################################
  49
  50 # where to look first for cmake modules, before ${CMAKE_ROOT}/Modules/ is checked
  51 SET (CMAKE_MODULE_PATH ${CMAKE_SOURCE_DIR}/cmake/modules)
  52 INSTALL( FILES ${CMAKE_MODULE_PATH}/FindLibSolv.cmake DESTINATION ${CMAKE_INSTALL_PREFIX}/share/cmake/Modules )
  53
  54 INCLUDE (${CMAKE_SOURCE_DIR}/VERSION.cmake)
  55
  56 FIND_PACKAGE (EXPAT REQUIRED)
  57 FIND_PACKAGE (ZLIB REQUIRED)
  58 IF (ENABLE_LZMA_COMPRESSION)
  59 FIND_PACKAGE (LZMA REQUIRED)
  60 ENDIF (ENABLE_LZMA_COMPRESSION)
  61
  62 IF (FEDORA)
  63 MESSAGE(STATUS "Building for Fedora")
  64 ADD_DEFINITIONS (-DFEDORA)
  65 SET (ENABLE_RPMDB ON)
  66 SET (ENABLE_RPMMD ON)
  67 ENDIF (FEDORA)
  68
  69 IF (DEBIAN)
  70 MESSAGE (STATUS "Building for Debian")
  71 ADD_DEFINITIONS (-DDEBIAN)
  72 SET (ENABLE_DEBIAN ON)
  73 ENDIF (DEBIAN)
  74
  75 IF (RPM5)
  76 MESSAGE (STATUS "Enabling RPM 5 support")
  77 ADD_DEFINITIONS (-DRPM5)
  78 SET (ENABLE_RPMDB ON)
  79 SET (ENABLE_RPMMD ON)
  80 FIND_PACKAGE (PkgConfig REQUIRED)
  81 PKG_CHECK_MODULES (RPM REQUIRED rpm)
  82 INCLUDE_DIRECTORIES (${RPM_INCLUDE_DIRS})
  83 ENDIF (RPM5)
  84
  85 IF (MULTI_SEMANTICS)
  86 MESSAGE (STATUS "Enabling multi dist support")
  87 ADD_DEFINITIONS (-DMULTI_SEMANTICS)
  88 ENDIF (MULTI_SEMANTICS)
  89
  90 # compat: enable some database types
  91 IF (NOT ENABLE_RPMDB AND
  92     NOT ENABLE_RPMMD AND
  93     NOT ENABLE_SUSEREPO AND
  94     NOT ENABLE_HELIXREPO AND
  95     NOT ENABLE_MDKREPO AND
  96     NOT ENABLE_ARCHREPO AND
  97     NOT ENABLE_DEBIAN)
  98     SET (ENABLE_RPMDB ON)
  99     SET (ENABLE_RPMDB_PUBKEY ON)
 100     SET (ENABLE_RPMMD ON)
 101     SET (ENABLE_SUSEREPO ON)
 102     SET (ENABLE_HELIXREPO ON)
 103     SET (ENABLE_DEBIAN ON)
 104 ENDIF ()
 105
 106 IF (ENABLE_RPMDB)
 107   FIND_LIBRARY (RPMDB_LIBRARY NAMES rpmdb)
 108
 109   IF (NOT RPMDB_LIBRARY)
 110     FIND_LIBRARY (RPMDB_LIBRARY NAMES rpm)
 111   ENDIF (NOT RPMDB_LIBRARY)
 112
 113   FIND_LIBRARY (RPMIO_LIBRARY NAMES rpmio)
 114   IF (RPMIO_LIBRARY)
 115     SET(RPMDB_LIBRARY ${RPMIO_LIBRARY} ${RPMDB_LIBRARY})
 116   ENDIF (RPMIO_LIBRARY)
 117
 118   IF (RPM5)
 119     FIND_LIBRARY (RPMMISC_LIBRARY NAMES rpmmisc)
 120     IF (RPMMISC_LIBRARY)
 121       SET (RPMDB_LIBRARY ${RPMMISC_LIBRARY} ${RPMDB_LIBRARY})
 122     ENDIF (RPMMISC_LIBRARY)
 123   ENDIF (RPM5)
 124
 125   IF (RPM5 OR FEDORA)
 126     FIND_LIBRARY (DB_LIBRARY NAMES db)
 127     IF (DB_LIBRARY)
 128       SET (RPMDB_LIBRARY ${DB_LIBRARY} ${RPMDB_LIBRARY})
 129     ENDIF (DB_LIBRARY)
 130   ENDIF (RPM5 OR FEDORA)
 131 ENDIF (ENABLE_RPMDB)
 132
 133 INCLUDE (CheckFunctionExists)
 134 INCLUDE (TestBigEndian)
 135
 136 CHECK_FUNCTION_EXISTS (strchrnul HAVE_STRCHRNUL)
 137 CHECK_FUNCTION_EXISTS (fopencookie HAVE_FOPENCOOKIE)
 138 CHECK_FUNCTION_EXISTS (funopen HAVE_FUNOPEN)
 139 TEST_BIG_ENDIAN (WORDS_BIGENDIAN)
 140
 141 # should create config.h with #cmakedefine instead...
 142 FOREACH (VAR HAVE_STRCHRNUL HAVE_FOPENCOOKIE HAVE_FUNOPEN WORDS_BIGENDIAN
 143   ENABLE_RPMDB ENABLE_RPMDB_PUBKEY ENABLE_RPMMD ENABLE_SUSEREPO ENABLE_COMPS
 144   ENABLE_HELIXREPO ENABLE_MDKREPO ENABLE_ARCHREPO ENABLE_DEBIAN
 145   ENABLE_LZMA_COMPRESSION)
 146   IF(${VAR})
 147     ADD_DEFINITIONS (-D${VAR}=1)
 148     SET (SWIG_FLAGS ${SWIG_FLAGS} -D${VAR})
 149   ENDIF (${VAR})
 150 ENDFOREACH (VAR)
 151
 152 SET (PACKAGE "libsolv")
 153 SET (VERSION "${LIBSOLV_MAJOR}.${LIBSOLV_MINOR}.${LIBSOLV_PATCH}")
 154
 155 ADD_DEFINITIONS (-D_FILE_OFFSET_BITS=64)
 156 ADD_DEFINITIONS (-DVERSION=\\\"${VERSION}\\\")
 157 CONFIGURE_FILE (src/solvversion.h.in src/solvversion.h)
 158
 159 SET (CPACK_PACKAGE_DESCRIPTION_SUMMARY "Package dependency solver library")
 160 SET (CPACK_PACKAGE_VENDOR "SUSE")
 161 SET (CPACK_PACKAGE_VERSION_MAJOR ${LIBSOLV_MAJOR})
 162 SET (CPACK_PACKAGE_VERSION_MINOR ${LIBSOLV_MINOR})
 163 SET (CPACK_PACKAGE_VERSION_PATCH ${LIBSOLV_PATCH})
 164 SET (CPACK_GENERATOR "TBZ2")
 165 SET (CPACK_SOURCE_GENERATOR "TBZ2")
 166 SET (CPACK_SOURCE_PACKAGE_FILE_NAME "${PACKAGE}-${VERSION}")
 167 SET (CPACK_SOURCE_TOPLEVEL_TAG "Linux-Source:")
 168 SET (CPACK_TOPLEVEL_TAG "Linux-Source:")
 169
 170 # The following components are regex's to match anywhere (unless anchored)
 171 # in absolute path + filename to find files or directories to be excluded
 172 # from source tarball.
 173 SET (CPACK_SOURCE_IGNORE_FILES
 174 # temporary files
 175 "\\\\.swp$"
 176 # backup files
 177 "~$"
 178 # eclipse files
 179 "\\\\.cdtproject$"
 180 "\\\\.cproject$"
 181 "\\\\.project$"
 182 "\\\\.settings/"
 183 # others
 184 "\\\\.#"
 185 "/#"
 186 "/build/"
 187 "/_build/"
 188 "/\\\\.git/"
 189 # used before
 190 "/\\\\.libs/"
 191 "/\\\\.deps/"
 192 "\\\\.o$"
 193 "\\\\.lo$"
 194 "\\\\.la$"
 195 "Makefile$"
 196 "Makefile\\\\.in$"
 197 # cmake cache files
 198 "DartConfiguration.tcl$"
 199 "CMakeCache.txt"
 200 "CMakeFiles"
 201 "cmake_install.cmake$"
 202 "CMakeLists.txt.auto$"
 203 "CTestTestfile.cmake"
 204 "CPackConfig.cmake$"
 205 "CPackSourceConfig.cmake$"
 206 "libsolv.spec$"
 207 )
 208
 209 INCLUDE(CPack)
 210
 211 ####################################################################
 212 # INCLUDES                                                         #
 213 ####################################################################
 214
 215 #SET (CMAKE_INCLUDE_DIRECTORIES_BEFORE ON)
 216 INCLUDE_DIRECTORIES (${CMAKE_CURRENT_SOURCE_DIR} ${CMAKE_SOURCE_DIR} ${CMAKE_SOURCE_DIR}/src ${CMAKE_SOURCE_DIR}/ext ${CMAKE_CURRENT_BINARY_DIR} ${CMAKE_BINARY_DIR}/src SYSTEM )
 217
 218 ####################################################################
 219
 220 MESSAGE (STATUS "Looking for modules in ${CMAKE_MODULE_PATH}")
 221
 222 set (CMAKE_C_FLAGS     "${CMAKE_C_FLAGS} -Wall -Wl,--as-needed")
 223 set (CMAKE_C_FLAGS_RELEASE "${CMAKE_C_FLAGS} -O3")
 224 set (CMAKE_C_FLAGS_RELWITHDEBINFO "${CMAKE_C_FLAGS} -g -O3")
 225 set (CMAKE_C_FLAGS_DEBUG     "${CMAKE_C_FLAGS} -g3 -O0")
 226
 227 ADD_SUBDIRECTORY (src)
 228 ADD_SUBDIRECTORY (ext)
 229 ADD_SUBDIRECTORY (tools)
 230 IF (ENABLE_PERL OR ENABLE_PYTHON OR ENABLE_RUBY)
 231     ADD_SUBDIRECTORY (bindings)
 232 ENDIF (ENABLE_PERL OR ENABLE_PYTHON OR ENABLE_RUBY)
 233 ADD_SUBDIRECTORY (examples)
 234
 235 MESSAGE (STATUS "Version: ${VERSION}")
 236
 237 ####################################################################
 238 # RPM SPEC                                                         #
 239 ####################################################################
 240
 241 MACRO (SPECFILE)
 242   MESSAGE (STATUS "Writing spec file...")
 243   CONFIGURE_FILE (${CMAKE_SOURCE_DIR}/package/libsolv.spec.in ${CMAKE_BINARY_DIR}/package/libsolv.spec @ONLY)
 244 ENDMACRO (SPECFILE)
 245
 246 SPECFILE ()
 247
 248 SET (AUTOBUILD_COMMAND
 249   COMMAND ${CMAKE_COMMAND} -E remove ${CMAKE_BINARY_DIR}/package/*.tar.bz2
 250   COMMAND mkdir -p _CPack_Packages/${CPACK_TOPLEVEL_TAG}
 251   COMMAND ${CMAKE_MAKE_PROGRAM} package_source
 252   COMMAND ${CMAKE_COMMAND} -E copy ${CPACK_SOURCE_PACKAGE_FILE_NAME}.tar.bz2 ${CMAKE_BINARY_DIR}/package
 253   COMMAND ${CMAKE_COMMAND} -E remove ${CPACK_SOURCE_PACKAGE_FILE_NAME}.tar.bz2
 254   COMMAND ${CMAKE_COMMAND} -E copy "${CMAKE_SOURCE_DIR}/package/libsolv.changes" "${CMAKE_BINARY_DIR}/package/libsolv.changes"
 255 )
 256
 257 ADD_CUSTOM_TARGET (srcpackage
 258   ${AUTOBUILD_COMMAND}
 259 )
 260
 261 ADD_CUSTOM_TARGET (srcpackage_local
 262   ${AUTOBUILD_COMMAND}
 263 )
 264
 265 ENABLE_TESTING()
 266 ADD_SUBDIRECTORY (test)