CMakeLists.txt

   1 # ----------------------------------------------------------------------------
   2 #  Root CMake file for OpenCV
   3 #
   4 #    From the off-tree build directory, invoke:
   5 #      $ cmake <PATH_TO_OPENCV_ROOT>
   6 #
   7 # ----------------------------------------------------------------------------
   8
   9 # Disable in-source builds to prevent source tree corruption.
  10 if(" ${CMAKE_SOURCE_DIR}" STREQUAL " ${CMAKE_BINARY_DIR}")
  11   message(FATAL_ERROR "
  12 FATAL: In-source builds are not allowed.
  13        You should create a separate directory for build files.
  14 ")
  15 endif()
  16
  17
  18 include(cmake/OpenCVMinDepVersions.cmake)
  19
  20 if(CMAKE_SYSTEM_NAME MATCHES WindowsPhone OR CMAKE_SYSTEM_NAME MATCHES WindowsStore)
  21   cmake_minimum_required(VERSION 3.1 FATAL_ERROR)
  22   #Required to resolve linker error issues due to incompatibility with CMake v3.0+ policies.
  23   #CMake fails to find _fseeko() which leads to subsequent linker error.
  24   #See details here: http://www.cmake.org/Wiki/CMake/Policies
  25   cmake_policy(VERSION 2.8)
  26 else()
  27   cmake_minimum_required(VERSION "${MIN_VER_CMAKE}" FATAL_ERROR)
  28 endif()
  29
  30 #
  31 # Configure CMake policies
  32 #
  33 if(POLICY CMP0026)
  34   cmake_policy(SET CMP0026 NEW)
  35 endif()
  36
  37 if(POLICY CMP0042)
  38   cmake_policy(SET CMP0042 NEW)  # CMake 3.0+ (2.8.12): MacOS "@rpath" in target's install name
  39 endif()
  40
  41 if(POLICY CMP0046)
  42   cmake_policy(SET CMP0046 NEW)  # warn about non-existed dependencies
  43 endif()
  44
  45 if(POLICY CMP0051)
  46   cmake_policy(SET CMP0051 NEW)
  47 endif()
  48
  49 if(POLICY CMP0054)  # CMake 3.1: Only interpret if() arguments as variables or keywords when unquoted.
  50   cmake_policy(SET CMP0054 NEW)
  51 endif()
  52
  53 if(POLICY CMP0056)
  54   cmake_policy(SET CMP0056 NEW)  # try_compile(): link flags
  55 endif()
  56
  57 if(POLICY CMP0066)
  58   cmake_policy(SET CMP0066 NEW)  # CMake 3.7: try_compile(): use per-config flags, like CMAKE_CXX_FLAGS_RELEASE
  59 endif()
  60
  61 if(POLICY CMP0067)
  62   cmake_policy(SET CMP0067 NEW)  # CMake 3.8: try_compile(): honor language standard variables (like C++11)
  63 endif()
  64
  65 if(POLICY CMP0068)
  66   cmake_policy(SET CMP0068 NEW)  # CMake 3.9+: `RPATH` settings on macOS do not affect `install_name`.
  67 endif()
  68
  69 if(POLICY CMP0075)
  70   cmake_policy(SET CMP0075 NEW)  # CMake 3.12+: Include file check macros honor `CMAKE_REQUIRED_LIBRARIES`
  71 endif()
  72
  73 if(POLICY CMP0077)
  74   cmake_policy(SET CMP0077 NEW)  # CMake 3.13+: option() honors normal variables.
  75 endif()
  76
  77 #
  78 # Configure OpenCV CMake hooks
  79 #
  80 include(cmake/OpenCVUtils.cmake)
  81 ocv_cmake_reset_hooks()
  82 ocv_check_environment_variables(OPENCV_CMAKE_HOOKS_DIR)
  83 if(DEFINED OPENCV_CMAKE_HOOKS_DIR)
  84   foreach(__dir ${OPENCV_CMAKE_HOOKS_DIR})
  85     get_filename_component(__dir "${__dir}" ABSOLUTE)
  86     ocv_cmake_hook_register_dir(${__dir})
  87   endforeach()
  88 endif()
  89
  90 ocv_cmake_hook(CMAKE_INIT)
  91
  92 # must go before the project()/enable_language() commands
  93 ocv_update(CMAKE_CONFIGURATION_TYPES "Debug;Release" CACHE STRING "Configs" FORCE)
  94 if(DEFINED CMAKE_BUILD_TYPE)
  95   set_property(CACHE CMAKE_BUILD_TYPE PROPERTY STRINGS "${CMAKE_CONFIGURATION_TYPES}")
  96 endif()
  97
  98 option(ENABLE_PIC "Generate position independent code (necessary for shared libraries)" TRUE)
  99 set(CMAKE_POSITION_INDEPENDENT_CODE ${ENABLE_PIC})
 100
 101 ocv_cmake_hook(PRE_CMAKE_BOOTSTRAP)
 102
 103 # Bootstap CMake system: setup CMAKE_SYSTEM_NAME and other vars
 104 if(OPENCV_WORKAROUND_CMAKE_20989)
 105   set(CMAKE_SYSTEM_PROCESSOR_BACKUP ${CMAKE_SYSTEM_PROCESSOR})
 106 endif()
 107 enable_language(CXX C)
 108 if(OPENCV_WORKAROUND_CMAKE_20989)
 109   set(CMAKE_SYSTEM_PROCESSOR ${CMAKE_SYSTEM_PROCESSOR_BACKUP})
 110 endif()
 111
 112 ocv_cmake_hook(POST_CMAKE_BOOTSTRAP)
 113
 114 if(NOT OPENCV_SKIP_CMAKE_SYSTEM_FILE)
 115   include("cmake/platforms/OpenCV-${CMAKE_SYSTEM_NAME}.cmake" OPTIONAL RESULT_VARIABLE "OPENCV_CMAKE_SYSTEM_FILE")
 116   if(NOT OPENCV_CMAKE_SYSTEM_FILE)
 117     message(STATUS "OpenCV: system-specific configuration file is not found: '${CMAKE_SYSTEM_NAME}'")
 118   endif()
 119 endif()
 120
 121 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)  # https://cmake.org/cmake/help/latest/variable/CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT.html
 122   if(NOT CMAKE_TOOLCHAIN_FILE)
 123     if(WIN32)
 124       set(CMAKE_INSTALL_PREFIX "${CMAKE_BINARY_DIR}/install" CACHE PATH "Installation Directory" FORCE)
 125     else()
 126       set(CMAKE_INSTALL_PREFIX "/usr/local" CACHE PATH "Installation Directory" FORCE)
 127     endif()
 128   else()
 129     # any cross-compiling
 130     set(CMAKE_INSTALL_PREFIX "${CMAKE_BINARY_DIR}/install" CACHE PATH "Installation Directory" FORCE)
 131   endif()
 132 endif()
 133
 134 enable_testing()
 135
 136 project(OpenCV CXX C)
 137
 138 if(MSVC)
 139   set(CMAKE_USE_RELATIVE_PATHS ON CACHE INTERNAL "" FORCE)
 140 endif()
 141
 142 ocv_cmake_eval(DEBUG_PRE ONCE)
 143
 144 ocv_clear_vars(OpenCVModules_TARGETS)
 145
 146 include(cmake/OpenCVDownload.cmake)
 147
 148 set(BUILD_LIST "" CACHE STRING "Build only listed modules (comma-separated, e.g. 'videoio,dnn,ts')")
 149
 150 # ----------------------------------------------------------------------------
 151 # Break in case of popular CMake configuration mistakes
 152 # ----------------------------------------------------------------------------
 153 if(NOT CMAKE_SIZEOF_VOID_P GREATER 0)
 154   message(FATAL_ERROR "CMake fails to determine the bitness of the target platform.
 155   Please check your CMake and compiler installation. If you are cross-compiling then ensure that your CMake toolchain file correctly sets the compiler details.")
 156 endif()
 157
 158 # ----------------------------------------------------------------------------
 159 # Detect compiler and target platform architecture
 160 # ----------------------------------------------------------------------------
 161 include(cmake/OpenCVDetectCXXCompiler.cmake)
 162 ocv_cmake_hook(POST_DETECT_COMPILER)
 163
 164 # Add these standard paths to the search paths for FIND_LIBRARY
 165 # to find libraries from these locations first
 166 if(UNIX AND NOT ANDROID)
 167   if(X86_64 OR CMAKE_SIZEOF_VOID_P EQUAL 8)
 168     if(EXISTS /lib64)
 169       list(APPEND CMAKE_LIBRARY_PATH /lib64)
 170     else()
 171       list(APPEND CMAKE_LIBRARY_PATH /lib)
 172     endif()
 173     if(EXISTS /usr/lib64)
 174       list(APPEND CMAKE_LIBRARY_PATH /usr/lib64)
 175     else()
 176       list(APPEND CMAKE_LIBRARY_PATH /usr/lib)
 177     endif()
 178   elseif(X86 OR CMAKE_SIZEOF_VOID_P EQUAL 4)
 179     if(EXISTS /lib32)
 180       list(APPEND CMAKE_LIBRARY_PATH /lib32)
 181     else()
 182       list(APPEND CMAKE_LIBRARY_PATH /lib)
 183     endif()
 184     if(EXISTS /usr/lib32)
 185       list(APPEND CMAKE_LIBRARY_PATH /usr/lib32)
 186     else()
 187       list(APPEND CMAKE_LIBRARY_PATH /usr/lib)
 188     endif()
 189   endif()
 190 endif()
 191
 192 # Add these standard paths to the search paths for FIND_PATH
 193 # to find include files from these locations first
 194 if(MINGW)
 195   if(EXISTS /mingw)
 196       list(APPEND CMAKE_INCLUDE_PATH /mingw)
 197   endif()
 198   if(EXISTS /mingw32)
 199       list(APPEND CMAKE_INCLUDE_PATH /mingw32)
 200   endif()
 201   if(EXISTS /mingw64)
 202       list(APPEND CMAKE_INCLUDE_PATH /mingw64)
 203   endif()
 204 endif()
 205
 206 # ----------------------------------------------------------------------------
 207 # OpenCV cmake options
 208 # ----------------------------------------------------------------------------
 209
 210 OCV_OPTION(OPENCV_ENABLE_NONFREE "Enable non-free algorithms" OFF)
 211
 212 # 3rd party libs
 213 OCV_OPTION(OPENCV_FORCE_3RDPARTY_BUILD   "Force using 3rdparty code from source" OFF)
 214 OCV_OPTION(BUILD_ZLIB               "Build zlib from source"             (WIN32 OR APPLE OR OPENCV_FORCE_3RDPARTY_BUILD) )
 215 OCV_OPTION(BUILD_TIFF               "Build libtiff from source"          (WIN32 OR ANDROID OR APPLE OR OPENCV_FORCE_3RDPARTY_BUILD) )
 216 OCV_OPTION(BUILD_OPENJPEG           "Build OpenJPEG from source"         (WIN32 OR ANDROID OR APPLE OR OPENCV_FORCE_3RDPARTY_BUILD) )
 217 OCV_OPTION(BUILD_JASPER             "Build libjasper from source"        (WIN32 OR ANDROID OR APPLE OR OPENCV_FORCE_3RDPARTY_BUILD) )
 218 OCV_OPTION(BUILD_JPEG               "Build libjpeg from source"          (WIN32 OR ANDROID OR APPLE OR OPENCV_FORCE_3RDPARTY_BUILD) )
 219 OCV_OPTION(BUILD_PNG                "Build libpng from source"           (WIN32 OR ANDROID OR APPLE OR OPENCV_FORCE_3RDPARTY_BUILD) )
 220 OCV_OPTION(BUILD_OPENEXR            "Build openexr from source"          (((WIN32 OR ANDROID OR APPLE) AND NOT WINRT) OR OPENCV_FORCE_3RDPARTY_BUILD) )
 221 OCV_OPTION(BUILD_WEBP               "Build WebP from source"             (((WIN32 OR ANDROID OR APPLE) AND NOT WINRT) OR OPENCV_FORCE_3RDPARTY_BUILD) )
 222 OCV_OPTION(BUILD_TBB                "Download and build TBB from source" (ANDROID OR OPENCV_FORCE_3RDPARTY_BUILD) )
 223 OCV_OPTION(BUILD_IPP_IW             "Build IPP IW from source"           (NOT MINGW OR OPENCV_FORCE_3RDPARTY_BUILD) IF (X86_64 OR X86) AND NOT WINRT )
 224 OCV_OPTION(BUILD_ITT                "Build Intel ITT from source"
 225     (NOT MINGW OR OPENCV_FORCE_3RDPARTY_BUILD)
 226     IF (X86_64 OR X86 OR ARM OR AARCH64 OR PPC64 OR PPC64LE) AND NOT WINRT AND NOT APPLE_FRAMEWORK
 227 )
 228
 229 # Optional 3rd party components
 230 # ===================================================
 231 OCV_OPTION(WITH_1394 "Include IEEE1394 support" ON
 232   VISIBLE_IF NOT ANDROID AND NOT IOS AND NOT WINRT
 233   VERIFY HAVE_DC1394_2)
 234 OCV_OPTION(WITH_AVFOUNDATION "Use AVFoundation for Video I/O (iOS/Mac)" ON
 235   VISIBLE_IF APPLE
 236   VERIFY HAVE_AVFOUNDATION)
 237 OCV_OPTION(WITH_CAP_IOS "Enable iOS video capture" ON
 238   VISIBLE_IF IOS
 239   VERIFY HAVE_CAP_IOS)
 240 OCV_OPTION(WITH_CAROTENE "Use NVidia carotene acceleration library for ARM platform" ON
 241   VISIBLE_IF (ARM OR AARCH64) AND NOT IOS AND NOT (CMAKE_VERSION VERSION_LESS "2.8.11"))
 242 OCV_OPTION(WITH_CPUFEATURES "Use cpufeatures Android library" ON
 243   VISIBLE_IF ANDROID
 244   VERIFY HAVE_CPUFEATURES)
 245 OCV_OPTION(WITH_VTK "Include VTK library support (and build opencv_viz module eiher)" ON
 246   VISIBLE_IF NOT ANDROID AND NOT IOS AND NOT WINRT AND NOT CMAKE_CROSSCOMPILING
 247   VERIFY HAVE_VTK)
 248 OCV_OPTION(WITH_CUDA "Include NVidia Cuda Runtime support" OFF
 249   VISIBLE_IF NOT IOS AND NOT WINRT
 250   VERIFY HAVE_CUDA)
 251 OCV_OPTION(WITH_CUFFT "Include NVidia Cuda Fast Fourier Transform (FFT) library support" WITH_CUDA
 252   VISIBLE_IF WITH_CUDA
 253   VERIFY HAVE_CUFFT)
 254 OCV_OPTION(WITH_CUBLAS "Include NVidia Cuda Basic Linear Algebra Subprograms (BLAS) library support" WITH_CUDA
 255   VISIBLE_IF WITH_CUDA
 256   VERIFY HAVE_CUBLAS)
 257 OCV_OPTION(WITH_CUDNN "Include NVIDIA CUDA Deep Neural Network (cuDNN) library support" WITH_CUDA
 258   VISIBLE_IF WITH_CUDA
 259   VERIFY HAVE_CUDNN)
 260 OCV_OPTION(WITH_NVCUVID "Include NVidia Video Decoding library support" OFF  # disabled, details: https://github.com/opencv/opencv/issues/14850
 261   VISIBLE_IF WITH_CUDA
 262   VERIFY HAVE_NVCUVID)
 263 OCV_OPTION(WITH_EIGEN "Include Eigen2/Eigen3 support" (NOT CV_DISABLE_OPTIMIZATION AND NOT CMAKE_CROSSCOMPILING)
 264   VISIBLE_IF NOT WINRT
 265   VERIFY HAVE_EIGEN)
 266 OCV_OPTION(WITH_FFMPEG "Include FFMPEG support" (NOT ANDROID)
 267   VISIBLE_IF NOT IOS AND NOT WINRT
 268   VERIFY HAVE_FFMPEG)
 269 OCV_OPTION(WITH_GSTREAMER "Include Gstreamer support" ON
 270   VISIBLE_IF NOT ANDROID AND NOT IOS AND NOT WINRT
 271   VERIFY HAVE_GSTREAMER AND GSTREAMER_VERSION VERSION_GREATER "0.99")
 272 OCV_OPTION(WITH_GTK "Include GTK support" ON
 273   VISIBLE_IF UNIX AND NOT APPLE AND NOT ANDROID
 274   VERIFY HAVE_GTK)
 275 OCV_OPTION(WITH_GTK_2_X "Use GTK version 2" OFF
 276   VISIBLE_IF UNIX AND NOT APPLE AND NOT ANDROID
 277   VERIFY HAVE_GTK AND NOT HAVE_GTK3)
 278 OCV_OPTION(WITH_IPP "Include Intel IPP support" (NOT MINGW AND NOT CV_DISABLE_OPTIMIZATION)
 279   VISIBLE_IF (X86_64 OR X86) AND NOT WINRT AND NOT IOS
 280   VERIFY HAVE_IPP)
 281 OCV_OPTION(WITH_HALIDE "Include Halide support" OFF
 282   VISIBLE_IF TRUE
 283   VERIFY HAVE_HALIDE)
 284 OCV_OPTION(WITH_VULKAN "Include Vulkan support" OFF
 285   VISIBLE_IF TRUE
 286   VERIFY HAVE_VULKAN)
 287 OCV_OPTION(WITH_INF_ENGINE "Include Intel Inference Engine support" OFF
 288   VISIBLE_IF TRUE
 289   VERIFY INF_ENGINE_TARGET)
 290 OCV_OPTION(WITH_NGRAPH "Include nGraph support" WITH_INF_ENGINE
 291   VISIBLE_IF TRUE
 292   VERIFY TARGET ngraph::ngraph)
 293 OCV_OPTION(WITH_JASPER "Include JPEG2K support (Jasper)" ON
 294   VISIBLE_IF NOT IOS
 295   VERIFY HAVE_JASPER)
 296 OCV_OPTION(WITH_OPENJPEG "Include JPEG2K support (OpenJPEG)" ON
 297   VISIBLE_IF NOT IOS
 298   VERIFY HAVE_OPENJPEG)
 299 OCV_OPTION(WITH_JPEG "Include JPEG support" ON
 300   VISIBLE_IF TRUE
 301   VERIFY HAVE_JPEG)
 302 OCV_OPTION(WITH_WEBP "Include WebP support" ON
 303   VISIBLE_IF NOT WINRT
 304   VERIFY HAVE_WEBP)
 305 OCV_OPTION(WITH_OPENEXR "Include ILM support via OpenEXR" BUILD_OPENEXR OR NOT CMAKE_CROSSCOMPILING
 306   VISIBLE_IF NOT APPLE_FRAMEWORK AND NOT WINRT
 307   VERIFY HAVE_OPENEXR)
 308 OCV_OPTION(WITH_OPENGL "Include OpenGL support" OFF
 309   VISIBLE_IF NOT ANDROID AND NOT WINRT
 310   VERIFY HAVE_OPENGL)
 311 OCV_OPTION(WITH_OPENVX "Include OpenVX support" OFF
 312   VISIBLE_IF TRUE
 313   VERIFY HAVE_OPENVX)
 314 OCV_OPTION(WITH_OPENNI "Include OpenNI support" OFF
 315   VISIBLE_IF NOT ANDROID AND NOT IOS AND NOT WINRT
 316   VERIFY HAVE_OPENNI)
 317 OCV_OPTION(WITH_OPENNI2 "Include OpenNI2 support" OFF
 318   VISIBLE_IF NOT ANDROID AND NOT IOS AND NOT WINRT
 319   VERIFY HAVE_OPENNI2)
 320 OCV_OPTION(WITH_PNG "Include PNG support" ON
 321   VISIBLE_IF TRUE
 322   VERIFY HAVE_PNG)
 323 OCV_OPTION(WITH_GDCM "Include DICOM support" OFF
 324   VISIBLE_IF TRUE
 325   VERIFY HAVE_GDCM)
 326 OCV_OPTION(WITH_PVAPI "Include Prosilica GigE support" OFF
 327   VISIBLE_IF NOT ANDROID AND NOT IOS AND NOT WINRT
 328   VERIFY HAVE_PVAPI)
 329 OCV_OPTION(WITH_ARAVIS "Include Aravis GigE support" OFF
 330   VISIBLE_IF NOT ANDROID AND NOT IOS AND NOT WINRT AND NOT WIN32
 331   VERIFY HAVE_ARAVIS_API)
 332 OCV_OPTION(WITH_QT "Build with Qt Backend support" OFF
 333   VISIBLE_IF NOT ANDROID AND NOT IOS AND NOT WINRT
 334   VERIFY HAVE_QT)
 335 OCV_OPTION(WITH_WIN32UI "Build with Win32 UI Backend support" ON
 336   VISIBLE_IF WIN32 AND NOT WINRT
 337   VERIFY HAVE_WIN32UI)
 338 OCV_OPTION(WITH_TBB "Include Intel TBB support" OFF
 339   VISIBLE_IF NOT IOS AND NOT WINRT
 340   VERIFY HAVE_TBB)
 341 OCV_OPTION(WITH_HPX "Include Ste||ar Group HPX support" OFF
 342   VISIBLE_IF TRUE
 343   VERIFY HAVE_HPX)
 344 OCV_OPTION(WITH_OPENMP "Include OpenMP support" OFF
 345   VISIBLE_IF TRUE
 346   VERIFY HAVE_OPENMP)
 347 OCV_OPTION(WITH_PTHREADS_PF "Use pthreads-based parallel_for" ON
 348   VISIBLE_IF NOT WIN32 OR MINGW
 349   VERIFY HAVE_PTHREADS_PF)
 350 OCV_OPTION(WITH_TIFF "Include TIFF support" ON
 351   VISIBLE_IF NOT IOS
 352   VERIFY HAVE_TIFF)
 353 OCV_OPTION(WITH_V4L "Include Video 4 Linux support" ON
 354   VISIBLE_IF UNIX AND NOT ANDROID AND NOT APPLE
 355   VERIFY HAVE_CAMV4L OR HAVE_CAMV4L2 OR HAVE_VIDEOIO)
 356 OCV_OPTION(WITH_DSHOW "Build VideoIO with DirectShow support" ON
 357   VISIBLE_IF WIN32 AND NOT ARM AND NOT WINRT
 358   VERIFY HAVE_DSHOW)
 359 OCV_OPTION(WITH_MSMF "Build VideoIO with Media Foundation support" NOT MINGW
 360   VISIBLE_IF WIN32
 361   VERIFY HAVE_MSMF)
 362 OCV_OPTION(WITH_MSMF_DXVA "Enable hardware acceleration in Media Foundation backend" WITH_MSMF
 363   VISIBLE_IF WIN32
 364   VERIFY HAVE_MSMF_DXVA)
 365 OCV_OPTION(WITH_XIMEA "Include XIMEA cameras support" OFF
 366   VISIBLE_IF NOT ANDROID AND NOT WINRT
 367   VERIFY HAVE_XIMEA)
 368 OCV_OPTION(WITH_UEYE "Include UEYE camera support" OFF
 369   VISIBLE_IF NOT ANDROID AND NOT APPLE AND NOT WINRT
 370   VERIFY HAVE_UEYE)
 371 OCV_OPTION(WITH_XINE "Include Xine support (GPL)" OFF
 372   VISIBLE_IF UNIX AND NOT APPLE AND NOT ANDROID
 373   VERIFY HAVE_XINE)
 374 OCV_OPTION(WITH_CLP "Include Clp support (EPL)" OFF
 375   VISIBLE_IF TRUE
 376   VERIFY HAVE_CLP)
 377 OCV_OPTION(WITH_OPENCL "Include OpenCL Runtime support" (NOT ANDROID AND NOT CV_DISABLE_OPTIMIZATION)
 378   VISIBLE_IF NOT IOS AND NOT WINRT
 379   VERIFY HAVE_OPENCL)
 380 OCV_OPTION(WITH_OPENCL_SVM "Include OpenCL Shared Virtual Memory support" OFF
 381   VISIBLE_IF TRUE
 382   VERIFY HAVE_OPENCL_SVM) # experimental
 383 OCV_OPTION(WITH_OPENCLAMDFFT "Include AMD OpenCL FFT library support" ON
 384   VISIBLE_IF NOT ANDROID AND NOT IOS AND NOT WINRT
 385   VERIFY HAVE_CLAMDFFT)
 386 OCV_OPTION(WITH_OPENCLAMDBLAS "Include AMD OpenCL BLAS library support" ON
 387   VISIBLE_IF NOT ANDROID AND NOT IOS AND NOT WINRT
 388   VERIFY HAVE_CLAMDBLAS)
 389 OCV_OPTION(WITH_DIRECTX "Include DirectX support" ON
 390   VISIBLE_IF WIN32 AND NOT WINRT
 391   VERIFY HAVE_DIRECTX)
 392 OCV_OPTION(WITH_OPENCL_D3D11_NV "Include NVIDIA OpenCL D3D11 support" WITH_DIRECTX
 393   VISIBLE_IF WIN32 AND NOT WINRT
 394   VERIFY HAVE_OPENCL_D3D11_NV)
 395 OCV_OPTION(WITH_LIBREALSENSE "Include Intel librealsense support" OFF
 396   VISIBLE_IF NOT WITH_INTELPERC
 397   VERIFY HAVE_LIBREALSENSE)
 398 OCV_OPTION(WITH_VA "Include VA support" (X86_64 OR X86)
 399   VISIBLE_IF UNIX AND NOT APPLE AND NOT ANDROID
 400   VERIFY HAVE_VA)
 401 OCV_OPTION(WITH_VA_INTEL "Include Intel VA-API/OpenCL support" (X86_64 OR X86)
 402   VISIBLE_IF UNIX AND NOT APPLE AND NOT ANDROID
 403   VERIFY HAVE_VA_INTEL)
 404 OCV_OPTION(WITH_MFX "Include Intel Media SDK support" OFF
 405   VISIBLE_IF (UNIX AND NOT ANDROID) OR (WIN32 AND NOT WINRT AND NOT MINGW)
 406   VERIFY HAVE_MFX)
 407 OCV_OPTION(WITH_GDAL "Include GDAL Support" OFF
 408   VISIBLE_IF NOT ANDROID AND NOT IOS AND NOT WINRT
 409   VERIFY HAVE_GDAL)
 410 OCV_OPTION(WITH_GPHOTO2 "Include gPhoto2 library support" OFF
 411   VISIBLE_IF UNIX AND NOT ANDROID AND NOT IOS
 412   VERIFY HAVE_GPHOTO2)
 413 OCV_OPTION(WITH_LAPACK "Include Lapack library support" (NOT CV_DISABLE_OPTIMIZATION)
 414   VISIBLE_IF NOT ANDROID AND NOT IOS
 415   VERIFY HAVE_LAPACK)
 416 OCV_OPTION(WITH_ITT "Include Intel ITT support" ON
 417   VISIBLE_IF NOT APPLE_FRAMEWORK
 418   VERIFY HAVE_ITT)
 419 OCV_OPTION(WITH_PROTOBUF "Enable libprotobuf" ON
 420   VISIBLE_IF TRUE
 421   VERIFY HAVE_PROTOBUF)
 422 OCV_OPTION(WITH_IMGCODEC_HDR "Include HDR support" ON
 423   VISIBLE_IF TRUE
 424   VERIFY HAVE_IMGCODEC_HDR)
 425 OCV_OPTION(WITH_IMGCODEC_SUNRASTER "Include SUNRASTER support" ON
 426   VISIBLE_IF TRUE
 427   VERIFY HAVE_IMGCODEC_SUNRASTER)
 428 OCV_OPTION(WITH_IMGCODEC_PXM "Include PNM (PBM,PGM,PPM) and PAM formats support" ON
 429   VISIBLE_IF TRUE
 430   VERIFY HAVE_IMGCODEC_PXM)
 431 OCV_OPTION(WITH_IMGCODEC_PFM "Include PFM formats support" ON
 432   VISIBLE_IF TRUE
 433   VERIFY HAVE_IMGCODEC_PFM)
 434 OCV_OPTION(WITH_QUIRC "Include library QR-code decoding" ON
 435   VISIBLE_IF TRUE
 436   VERIFY HAVE_QUIRC)
 437 OCV_OPTION(WITH_ANDROID_MEDIANDK "Use Android Media NDK for Video I/O (Android)" (ANDROID_NATIVE_API_LEVEL GREATER 20)
 438   VISIBLE_IF ANDROID
 439   VERIFY HAVE_ANDROID_MEDIANDK)
 440 OCV_OPTION(WITH_ANDROID_NATIVE_CAMERA "Use Android NDK for Camera I/O (Android)" (ANDROID_NATIVE_API_LEVEL GREATER 23)
 441   VISIBLE_IF ANDROID
 442   VERIFY HAVE_ANDROID_NATIVE_CAMERA)
 443 OCV_OPTION(WITH_TENGINE "Include Arm Inference Tengine support" OFF
 444   VISIBLE_IF (ARM OR AARCH64) AND (UNIX OR ANDROID) AND NOT IOS
 445   VERIFY HAVE_TENGINE)
 446 OCV_OPTION(WITH_ONNX "Include Microsoft ONNX Runtime support" OFF
 447   VISIBLE_IF TRUE
 448   VERIFY HAVE_ONNX)
 449
 450 # OpenCV build components
 451 # ===================================================
 452 OCV_OPTION(BUILD_SHARED_LIBS        "Build shared libraries (.dll/.so) instead of static ones (.lib/.a)" NOT (ANDROID OR APPLE_FRAMEWORK) )
 453 OCV_OPTION(BUILD_opencv_apps        "Build utility applications (used for example to train classifiers)" (NOT ANDROID AND NOT WINRT) IF (NOT APPLE_FRAMEWORK) )
 454 OCV_OPTION(BUILD_opencv_js          "Build JavaScript bindings by Emscripten" OFF )
 455 OCV_OPTION(BUILD_ANDROID_PROJECTS   "Build Android projects providing .apk files" ON  IF ANDROID )
 456 OCV_OPTION(BUILD_ANDROID_EXAMPLES   "Build examples for Android platform"         ON  IF ANDROID )
 457 OCV_OPTION(BUILD_DOCS               "Create build rules for OpenCV Documentation" OFF  IF (NOT WINRT AND NOT APPLE_FRAMEWORK))
 458 OCV_OPTION(BUILD_EXAMPLES           "Build all examples"                          OFF )
 459 OCV_OPTION(BUILD_PACKAGE            "Enables 'make package_source' command"       ON  IF NOT WINRT)
 460 OCV_OPTION(BUILD_PERF_TESTS         "Build performance tests"                     NOT INSTALL_CREATE_DISTRIB  IF (NOT APPLE_FRAMEWORK) )
 461 OCV_OPTION(BUILD_TESTS              "Build accuracy & regression tests"           NOT INSTALL_CREATE_DISTRIB  IF (NOT APPLE_FRAMEWORK) )
 462 OCV_OPTION(BUILD_WITH_DEBUG_INFO    "Include debug info into release binaries ('OFF' means default settings)" OFF )
 463 OCV_OPTION(BUILD_WITH_STATIC_CRT    "Enables use of statically linked CRT for statically linked OpenCV" ON IF MSVC )
 464 OCV_OPTION(BUILD_WITH_DYNAMIC_IPP   "Enables dynamic linking of IPP (only for standalone IPP)" OFF )
 465 OCV_OPTION(BUILD_FAT_JAVA_LIB       "Create Java wrapper exporting all functions of OpenCV library (requires static build of OpenCV modules)" ANDROID IF NOT BUILD_SHARED_LIBS)
 466 OCV_OPTION(BUILD_ANDROID_SERVICE    "Build OpenCV Manager for Google Play" OFF IF ANDROID )
 467 OCV_OPTION(BUILD_CUDA_STUBS         "Build CUDA modules stubs when no CUDA SDK" OFF  IF (NOT APPLE_FRAMEWORK) )
 468 OCV_OPTION(BUILD_JAVA               "Enable Java support"                         (ANDROID OR NOT CMAKE_CROSSCOMPILING)  IF (ANDROID OR (NOT APPLE_FRAMEWORK AND NOT WINRT)) )
 469 OCV_OPTION(BUILD_OBJC               "Enable Objective-C support"                  ON  IF APPLE_FRAMEWORK )
 470
 471 # OpenCV installation options
 472 # ===================================================
 473 OCV_OPTION(INSTALL_CREATE_DISTRIB   "Change install rules to build the distribution package" OFF )
 474 OCV_OPTION(INSTALL_BIN_EXAMPLES     "Install prebuilt examples" WIN32 IF BUILD_EXAMPLES)
 475 OCV_OPTION(INSTALL_C_EXAMPLES       "Install C examples"        OFF )
 476 OCV_OPTION(INSTALL_PYTHON_EXAMPLES  "Install Python examples"   OFF )
 477 OCV_OPTION(INSTALL_ANDROID_EXAMPLES "Install Android examples"  OFF IF ANDROID )
 478 OCV_OPTION(INSTALL_TO_MANGLED_PATHS "Enables mangled install paths, that help with side by side installs." OFF IF (UNIX AND NOT ANDROID AND NOT APPLE_FRAMEWORK AND BUILD_SHARED_LIBS) )
 479 OCV_OPTION(INSTALL_TESTS            "Install accuracy and performance test binaries and test data" OFF)
 480
 481 # OpenCV build options
 482 # ===================================================
 483 OCV_OPTION(ENABLE_CCACHE              "Use ccache"                                               (UNIX AND (CMAKE_GENERATOR MATCHES "Makefile" OR CMAKE_GENERATOR MATCHES "Ninja" OR CMAKE_GENERATOR MATCHES "Xcode")) )
 484 OCV_OPTION(ENABLE_PRECOMPILED_HEADERS "Use precompiled headers"                                  MSVC IF (MSVC OR (NOT IOS AND NOT CMAKE_CROSSCOMPILING) ) )
 485 OCV_OPTION(ENABLE_SOLUTION_FOLDERS    "Solution folder in Visual Studio or in other IDEs"        (MSVC_IDE OR CMAKE_GENERATOR MATCHES Xcode) )
 486 OCV_OPTION(ENABLE_PROFILING           "Enable profiling in the GCC compiler (Add flags: -g -pg)" OFF  IF CV_GCC )
 487 OCV_OPTION(ENABLE_COVERAGE            "Enable coverage collection with  GCov"                    OFF  IF CV_GCC )
 488 OCV_OPTION(OPENCV_ENABLE_MEMORY_SANITIZER "Better support for memory/address sanitizers"         OFF)
 489 OCV_OPTION(ENABLE_OMIT_FRAME_POINTER  "Enable -fomit-frame-pointer for GCC"                      ON   IF CV_GCC )
 490 OCV_OPTION(ENABLE_POWERPC             "Enable PowerPC for GCC"                                   ON   IF (CV_GCC AND CMAKE_SYSTEM_PROCESSOR MATCHES powerpc.*) )
 491 OCV_OPTION(ENABLE_FAST_MATH           "Enable compiler options for fast math optimizations on FP computations (not recommended)" OFF)
 492 if(NOT IOS AND (NOT ANDROID OR OPENCV_ANDROID_USE_LEGACY_FLAGS) AND CMAKE_CROSSCOMPILING)  # Use CPU_BASELINE instead
 493 OCV_OPTION(ENABLE_NEON                "Enable NEON instructions"                                 (NEON OR ANDROID_ARM_NEON OR AARCH64) IF (CV_GCC OR CV_CLANG) AND (ARM OR AARCH64 OR IOS) )
 494 OCV_OPTION(ENABLE_VFPV3               "Enable VFPv3-D32 instructions"                            OFF  IF (CV_GCC OR CV_CLANG) AND (ARM OR AARCH64 OR IOS) )
 495 endif()
 496 OCV_OPTION(ENABLE_NOISY_WARNINGS      "Show all warnings even if they are too noisy"             OFF )
 497 OCV_OPTION(OPENCV_WARNINGS_ARE_ERRORS "Treat warnings as errors"                                 OFF )
 498 OCV_OPTION(ANDROID_EXAMPLES_WITH_LIBS "Build binaries of Android examples with native libraries" OFF  IF ANDROID )
 499 OCV_OPTION(ENABLE_IMPL_COLLECTION     "Collect implementation data on function call"             OFF )
 500 OCV_OPTION(ENABLE_INSTRUMENTATION     "Instrument functions to collect calls trace and performance" OFF )
 501 OCV_OPTION(ENABLE_GNU_STL_DEBUG       "Enable GNU STL Debug mode (defines _GLIBCXX_DEBUG)"       OFF IF ((NOT CMAKE_VERSION VERSION_LESS "2.8.11") AND CV_GCC) )
 502 OCV_OPTION(ENABLE_BUILD_HARDENING     "Enable hardening of the resulting binaries (against security attacks, detects memory corruption, etc)" OFF)
 503 OCV_OPTION(ENABLE_LTO                 "Enable Link Time Optimization" OFF IF CV_GCC OR MSVC)
 504 OCV_OPTION(ENABLE_THIN_LTO            "Enable Thin LTO" OFF IF CV_CLANG)
 505 OCV_OPTION(GENERATE_ABI_DESCRIPTOR    "Generate XML file for abi_compliance_checker tool" OFF IF UNIX)
 506 OCV_OPTION(OPENCV_GENERATE_PKGCONFIG  "Generate .pc file for pkg-config build tool (deprecated)" OFF)
 507 OCV_OPTION(CV_ENABLE_INTRINSICS       "Use intrinsic-based optimized code" ON )
 508 OCV_OPTION(CV_DISABLE_OPTIMIZATION    "Disable explicit optimized code (dispatched code/intrinsics/loop unrolling/etc)" OFF )
 509 OCV_OPTION(CV_TRACE                   "Enable OpenCV code trace" ON)
 510 OCV_OPTION(OPENCV_GENERATE_SETUPVARS  "Generate setup_vars* scripts" ON IF (NOT ANDROID AND NOT APPLE_FRAMEWORK) )
 511 OCV_OPTION(ENABLE_CONFIG_VERIFICATION "Fail build if actual configuration doesn't match requested (WITH_XXX != HAVE_XXX)" OFF)
 512 OCV_OPTION(OPENCV_ENABLE_MEMALIGN     "Enable posix_memalign or memalign usage" ON)
 513
 514 OCV_OPTION(ENABLE_PYLINT              "Add target with Pylint checks"                            (BUILD_DOCS OR BUILD_EXAMPLES) IF (NOT CMAKE_CROSSCOMPILING AND NOT APPLE_FRAMEWORK) )
 515 OCV_OPTION(ENABLE_FLAKE8              "Add target with Python flake8 checker"                    (BUILD_DOCS OR BUILD_EXAMPLES) IF (NOT CMAKE_CROSSCOMPILING AND NOT APPLE_FRAMEWORK) )
 516
 517 if(ENABLE_IMPL_COLLECTION)
 518   add_definitions(-DCV_COLLECT_IMPL_DATA)
 519 endif()
 520
 521 set(OPENCV_MATHJAX_RELPATH "https://cdnjs.cloudflare.com/ajax/libs/mathjax/2.7.0" CACHE STRING "URI to a MathJax installation")
 522
 523 # ----------------------------------------------------------------------------
 524 #  Get actual OpenCV version number from sources
 525 # ----------------------------------------------------------------------------
 526 include(cmake/OpenCVVersion.cmake)
 527
 528 ocv_cmake_hook(POST_OPTIONS)
 529
 530 # ----------------------------------------------------------------------------
 531 #  Build & install layouts
 532 # ----------------------------------------------------------------------------
 533
 534 if(OPENCV_TEST_DATA_PATH)
 535   get_filename_component(OPENCV_TEST_DATA_PATH ${OPENCV_TEST_DATA_PATH} ABSOLUTE)
 536 endif()
 537
 538 # Save libs and executables in the same place
 539 set(EXECUTABLE_OUTPUT_PATH "${CMAKE_BINARY_DIR}/bin" CACHE PATH "Output directory for applications")
 540
 541 if(ANDROID)
 542   set(LIBRARY_OUTPUT_PATH                "${OpenCV_BINARY_DIR}/lib/${ANDROID_NDK_ABI_NAME}")
 543   ocv_update(3P_LIBRARY_OUTPUT_PATH      "${OpenCV_BINARY_DIR}/3rdparty/lib/${ANDROID_NDK_ABI_NAME}")
 544 else()
 545   set(LIBRARY_OUTPUT_PATH                "${OpenCV_BINARY_DIR}/lib")
 546   ocv_update(3P_LIBRARY_OUTPUT_PATH      "${OpenCV_BINARY_DIR}/3rdparty/lib")
 547 endif()
 548
 549 if(ANDROID)
 550   if(ANDROID_ABI MATCHES "NEON")
 551     set(ENABLE_NEON ON)
 552   endif()
 553   if(ANDROID_ABI MATCHES "VFPV3")
 554     set(ENABLE_VFPV3 ON)
 555   endif()
 556 endif()
 557
 558 if(WIN32)
 559   # Postfix of DLLs:
 560   ocv_update(OPENCV_DLLVERSION "${OPENCV_VERSION_MAJOR}${OPENCV_VERSION_MINOR}${OPENCV_VERSION_PATCH}")
 561   ocv_update(OPENCV_DEBUG_POSTFIX d)
 562 else()
 563   # Postfix of so's:
 564   ocv_update(OPENCV_DLLVERSION "")
 565   ocv_update(OPENCV_DEBUG_POSTFIX "")
 566 endif()
 567
 568 if(DEFINED CMAKE_DEBUG_POSTFIX)
 569   set(OPENCV_DEBUG_POSTFIX "${CMAKE_DEBUG_POSTFIX}")
 570 endif()
 571
 572 if((INSTALL_CREATE_DISTRIB AND BUILD_SHARED_LIBS AND NOT DEFINED BUILD_opencv_world) OR APPLE_FRAMEWORK)
 573   set(BUILD_opencv_world ON CACHE INTERNAL "")
 574 endif()
 575
 576 include(cmake/OpenCVInstallLayout.cmake)
 577
 578 # ----------------------------------------------------------------------------
 579 #  Path for build/platform -specific headers
 580 # ----------------------------------------------------------------------------
 581 ocv_update(OPENCV_CONFIG_FILE_INCLUDE_DIR "${CMAKE_BINARY_DIR}/" CACHE PATH "Where to create the platform-dependant cvconfig.h")
 582 ocv_include_directories(${OPENCV_CONFIG_FILE_INCLUDE_DIR})
 583
 584 # ----------------------------------------------------------------------------
 585 #  Path for additional modules
 586 # ----------------------------------------------------------------------------
 587 set(OPENCV_EXTRA_MODULES_PATH "" CACHE PATH "Where to look for additional OpenCV modules (can be ;-separated list of paths)")
 588
 589 # ----------------------------------------------------------------------------
 590 #  Autodetect if we are in a GIT repository
 591 # ----------------------------------------------------------------------------
 592 find_host_package(Git QUIET)
 593
 594 if(NOT DEFINED OPENCV_VCSVERSION AND GIT_FOUND)
 595   ocv_git_describe(OPENCV_VCSVERSION "${OpenCV_SOURCE_DIR}")
 596 elseif(NOT DEFINED OPENCV_VCSVERSION)
 597   # We don't have git:
 598   set(OPENCV_VCSVERSION "unknown")
 599 endif()
 600
 601
 602 # ----------------------------------------------------------------------------
 603 # OpenCV compiler and linker options
 604 # ----------------------------------------------------------------------------
 605 # In case of Makefiles if the user does not setup CMAKE_BUILD_TYPE, assume it's Release:
 606 if(CMAKE_GENERATOR MATCHES "Makefiles|Ninja" AND "${CMAKE_BUILD_TYPE}" STREQUAL "")
 607   set(CMAKE_BUILD_TYPE Release)
 608 endif()
 609
 610 ocv_cmake_hook(POST_CMAKE_BUILD_OPTIONS)
 611
 612 # --- Python Support ---
 613 if(NOT IOS)
 614   include(cmake/OpenCVDetectPython.cmake)
 615 endif()
 616
 617 include(cmake/OpenCVCompilerOptions.cmake)
 618
 619 ocv_cmake_hook(POST_COMPILER_OPTIONS)
 620
 621 # ----------------------------------------------------------------------------
 622 #       CHECK FOR SYSTEM LIBRARIES, OPTIONS, ETC..
 623 # ----------------------------------------------------------------------------
 624 if(UNIX)
 625   if(NOT APPLE_FRAMEWORK OR OPENCV_ENABLE_PKG_CONFIG)
 626     if(CMAKE_CROSSCOMPILING AND NOT DEFINED ENV{PKG_CONFIG_LIBDIR} AND NOT DEFINED ENV{PKG_CONFIG_SYSROOT_DIR}
 627         AND NOT OPENCV_ENABLE_PKG_CONFIG
 628     )
 629       if(NOT PkgConfig_FOUND)
 630         message(STATUS "OpenCV disables pkg-config to avoid using of host libraries. Consider using PKG_CONFIG_LIBDIR to specify target SYSROOT")
 631       elseif(OPENCV_SKIP_PKG_CONFIG_WARNING)
 632         message(WARNING "pkg-config is enabled in cross-compilation mode without defining of PKG_CONFIG_LIBDIR environment variable. This may lead to misconfigured host-based dependencies.")
 633       endif()
 634     elseif(OPENCV_DISABLE_PKG_CONFIG)
 635       if(PkgConfig_FOUND)
 636         message(WARNING "OPENCV_DISABLE_PKG_CONFIG flag has no effect")
 637       endif()
 638     else()
 639       find_package(PkgConfig QUIET)
 640     endif()
 641   endif()
 642   include(CheckFunctionExists)
 643   include(CheckIncludeFile)
 644   include(CheckSymbolExists)
 645
 646   if(NOT APPLE)
 647     CHECK_INCLUDE_FILE(pthread.h HAVE_PTHREAD)
 648     if(ANDROID)
 649       set(OPENCV_LINKER_LIBS ${OPENCV_LINKER_LIBS} dl m log)
 650     elseif(CMAKE_SYSTEM_NAME MATCHES "FreeBSD|NetBSD|DragonFly|OpenBSD|Haiku")
 651       set(OPENCV_LINKER_LIBS ${OPENCV_LINKER_LIBS} m pthread)
 652     elseif(EMSCRIPTEN)
 653       # no need to link to system libs with emscripten
 654     else()
 655       set(OPENCV_LINKER_LIBS ${OPENCV_LINKER_LIBS} dl m pthread rt)
 656     endif()
 657   else()
 658     set(HAVE_PTHREAD 1)
 659   endif()
 660
 661   if(OPENCV_ENABLE_MEMALIGN)
 662     CHECK_SYMBOL_EXISTS(posix_memalign stdlib.h HAVE_POSIX_MEMALIGN)
 663     CHECK_INCLUDE_FILE(malloc.h HAVE_MALLOC_H)
 664     if(HAVE_MALLOC_H)
 665       CHECK_SYMBOL_EXISTS(memalign malloc.h HAVE_MEMALIGN)
 666     endif()
 667     # TODO:
 668     # - std::aligned_alloc() C++17 / C11
 669   endif()
 670 elseif(WIN32)
 671   include(CheckIncludeFile)
 672   include(CheckSymbolExists)
 673
 674   if(OPENCV_ENABLE_MEMALIGN)
 675     CHECK_INCLUDE_FILE(malloc.h HAVE_MALLOC_H)
 676     if(HAVE_MALLOC_H)
 677       CHECK_SYMBOL_EXISTS(_aligned_malloc malloc.h HAVE_WIN32_ALIGNED_MALLOC)
 678     endif()
 679   endif()
 680 endif()
 681
 682 include(cmake/OpenCVPCHSupport.cmake)
 683 include(cmake/OpenCVModule.cmake)
 684
 685 # ----------------------------------------------------------------------------
 686 #  Detect endianness of build platform
 687 # ----------------------------------------------------------------------------
 688
 689 if(IOS)
 690   # test_big_endian needs try_compile, which doesn't work for iOS
 691   # http://public.kitware.com/Bug/view.php?id=12288
 692   set(WORDS_BIGENDIAN 0)
 693 else()
 694   include(TestBigEndian)
 695   test_big_endian(WORDS_BIGENDIAN)
 696 endif()
 697
 698 # ----------------------------------------------------------------------------
 699 #  Detect 3rd-party libraries
 700 # ----------------------------------------------------------------------------
 701
 702 if(ANDROID AND WITH_CPUFEATURES)
 703   add_subdirectory(3rdparty/cpufeatures)
 704   set(HAVE_CPUFEATURES 1)
 705 endif()
 706
 707 include(cmake/OpenCVFindFrameworks.cmake)
 708
 709 include(cmake/OpenCVFindLibsGrfmt.cmake)
 710 include(cmake/OpenCVFindLibsGUI.cmake)
 711 include(cmake/OpenCVFindLibsVideo.cmake)
 712 include(cmake/OpenCVFindLibsPerf.cmake)
 713 include(cmake/OpenCVFindLAPACK.cmake)
 714 include(cmake/OpenCVFindProtobuf.cmake)
 715 if(WITH_TENGINE)
 716   include(cmake/OpenCVFindTengine.cmake)
 717 endif()
 718
 719 # ----------------------------------------------------------------------------
 720 #  Detect other 3rd-party libraries/tools
 721 # ----------------------------------------------------------------------------
 722
 723 # --- Java Support ---
 724 if(BUILD_JAVA)
 725   if(ANDROID)
 726     include(cmake/android/OpenCVDetectAndroidSDK.cmake)
 727   else()
 728     include(cmake/OpenCVDetectApacheAnt.cmake)
 729     find_package(JNI)
 730   endif()
 731 endif()
 732
 733 if(ENABLE_PYLINT AND PYTHON_DEFAULT_AVAILABLE)
 734   include(cmake/OpenCVPylint.cmake)
 735 endif()
 736 if(ENABLE_FLAKE8 AND PYTHON_DEFAULT_AVAILABLE)
 737   find_package(Flake8 QUIET)
 738   if(NOT FLAKE8_FOUND OR NOT FLAKE8_EXECUTABLE)
 739     include("${CMAKE_CURRENT_LIST_DIR}/cmake/FindFlake8.cmake")
 740   endif()
 741   if(FLAKE8_FOUND)
 742     list(APPEND OPENCV_FLAKE8_EXCLUDES ".git" "__pycache__" "config.py" "*.config.py" "config-*.py")
 743     list(APPEND OPENCV_FLAKE8_EXCLUDES "svgfig.py")  # 3rdparty
 744     if(NOT PYTHON3_VERSION_STRING VERSION_GREATER 3.6)
 745       # Python 3.6+ (PEP 526): variable annotations (type hints)
 746       list(APPEND OPENCV_FLAKE8_EXCLUDES "samples/dnn/dnn_model_runner/dnn_conversion/common/test/configs")
 747     endif()
 748     string(REPLACE ";" "," OPENCV_FLAKE8_EXCLUDES_STR "${OPENCV_FLAKE8_EXCLUDES}")
 749     add_custom_target(check_flake8
 750         COMMAND "${FLAKE8_EXECUTABLE}" . --count --select=E9,E901,E999,F821,F822,F823 --show-source --statistics --exclude='${OPENCV_FLAKE8_EXCLUDES_STR}'
 751         WORKING_DIRECTORY "${OpenCV_SOURCE_DIR}"
 752         COMMENT "Running flake8"
 753     )
 754   endif()
 755 endif()
 756
 757
 758 if(ANDROID AND ANDROID_EXECUTABLE AND ANT_EXECUTABLE AND (ANT_VERSION VERSION_GREATER 1.7) AND (ANDROID_TOOLS_Pkg_Revision GREATER 13))
 759   SET(CAN_BUILD_ANDROID_PROJECTS TRUE)
 760 else()
 761   SET(CAN_BUILD_ANDROID_PROJECTS FALSE)
 762 endif()
 763
 764 # --- OpenCL ---
 765 if(WITH_OPENCL)
 766   include(cmake/OpenCVDetectOpenCL.cmake)
 767 endif()
 768
 769 # --- Halide ---
 770 if(WITH_HALIDE)
 771   include(cmake/OpenCVDetectHalide.cmake)
 772 endif()
 773
 774 # --- VkCom ---
 775 if(WITH_VULKAN)
 776   include(cmake/OpenCVDetectVulkan.cmake)
 777 endif()
 778
 779 # --- Inference Engine ---
 780 if(WITH_INF_ENGINE)
 781   include(cmake/OpenCVDetectInferenceEngine.cmake)
 782 endif()
 783
 784 # --- DirectX ---
 785 if(WITH_DIRECTX)
 786   include(cmake/OpenCVDetectDirectX.cmake)
 787 endif()
 788
 789 if(WITH_VTK)
 790   include(cmake/OpenCVDetectVTK.cmake)
 791 endif()
 792
 793 if(WITH_OPENVX)
 794   include(cmake/FindOpenVX.cmake)
 795 endif()
 796
 797 if(WITH_QUIRC)
 798   add_subdirectory(3rdparty/quirc)
 799   set(HAVE_QUIRC TRUE)
 800 endif()
 801
 802 if(WITH_ONNX)
 803   include(cmake/FindONNX.cmake)
 804 endif()
 805
 806 # ----------------------------------------------------------------------------
 807 # OpenCV HAL
 808 # ----------------------------------------------------------------------------
 809 set(_hal_includes "")
 810 macro(ocv_hal_register HAL_LIBRARIES_VAR HAL_HEADERS_VAR HAL_INCLUDE_DIRS_VAR)
 811   # 1. libraries
 812   foreach (l ${${HAL_LIBRARIES_VAR}})
 813     if(NOT TARGET ${l})
 814       get_filename_component(l "${l}" ABSOLUTE)
 815     endif()
 816     list(APPEND OPENCV_HAL_LINKER_LIBS ${l})
 817   endforeach()
 818   # 2. headers
 819   foreach (h ${${HAL_HEADERS_VAR}})
 820     set(_hal_includes "${_hal_includes}\n#include \"${h}\"")
 821   endforeach()
 822   # 3. include paths
 823   ocv_include_directories(${${HAL_INCLUDE_DIRS_VAR}})
 824 endmacro()
 825
 826 if(NOT DEFINED OpenCV_HAL)
 827   set(OpenCV_HAL "OpenCV_HAL")
 828 endif()
 829
 830 if(HAVE_OPENVX)
 831   if(NOT ";${OpenCV_HAL};" MATCHES ";openvx;")
 832     set(OpenCV_HAL "openvx;${OpenCV_HAL}")
 833   endif()
 834 endif()
 835
 836 if(WITH_CAROTENE)
 837   ocv_debug_message(STATUS "Enable carotene acceleration")
 838   if(NOT ";${OpenCV_HAL};" MATCHES ";carotene;")
 839     set(OpenCV_HAL "carotene;${OpenCV_HAL}")
 840   endif()
 841 endif()
 842
 843 foreach(hal ${OpenCV_HAL})
 844   if(hal STREQUAL "carotene")
 845     if(";${CPU_BASELINE_FINAL};" MATCHES ";NEON;")
 846       add_subdirectory(3rdparty/carotene/hal)
 847       ocv_hal_register(CAROTENE_HAL_LIBRARIES CAROTENE_HAL_HEADERS CAROTENE_HAL_INCLUDE_DIRS)
 848       list(APPEND OpenCV_USED_HAL "carotene (ver ${CAROTENE_HAL_VERSION})")
 849     else()
 850       message(STATUS "Carotene: NEON is not available, disabling carotene...")
 851     endif()
 852   elseif(hal STREQUAL "openvx")
 853     add_subdirectory(3rdparty/openvx)
 854     ocv_hal_register(OPENVX_HAL_LIBRARIES OPENVX_HAL_HEADERS OPENVX_HAL_INCLUDE_DIRS)
 855     list(APPEND OpenCV_USED_HAL "openvx (ver ${OPENVX_HAL_VERSION})")
 856   else()
 857     ocv_debug_message(STATUS "OpenCV HAL: ${hal} ...")
 858     ocv_clear_vars(OpenCV_HAL_LIBRARIES OpenCV_HAL_HEADERS OpenCV_HAL_INCLUDE_DIRS)
 859     find_package(${hal} NO_MODULE QUIET)
 860     if(${hal}_FOUND)
 861       ocv_hal_register(OpenCV_HAL_LIBRARIES OpenCV_HAL_HEADERS OpenCV_HAL_INCLUDE_DIRS)
 862       list(APPEND OpenCV_USED_HAL "${hal} (ver ${${hal}_VERSION})")
 863     endif()
 864   endif()
 865 endforeach()
 866 configure_file("${OpenCV_SOURCE_DIR}/cmake/templates/custom_hal.hpp.in" "${CMAKE_BINARY_DIR}/custom_hal.hpp" @ONLY)
 867 unset(_hal_includes)
 868
 869
 870 # ----------------------------------------------------------------------------
 871 # Code trace support
 872 # ----------------------------------------------------------------------------
 873 if(CV_TRACE)
 874   include(cmake/OpenCVDetectTrace.cmake)
 875 endif()
 876
 877 ocv_cmake_hook(POST_DETECT_DEPENDECIES)  # typo, deprecated (2019-06)
 878 ocv_cmake_hook(POST_DETECT_DEPENDENCIES)
 879
 880 # ----------------------------------------------------------------------------
 881 # Solution folders:
 882 # ----------------------------------------------------------------------------
 883 if(ENABLE_SOLUTION_FOLDERS)
 884   set_property(GLOBAL PROPERTY USE_FOLDERS ON)
 885   set_property(GLOBAL PROPERTY PREDEFINED_TARGETS_FOLDER "CMakeTargets")
 886 endif()
 887
 888 # Extra OpenCV targets: uninstall, package_source, perf, etc.
 889 include(cmake/OpenCVExtraTargets.cmake)
 890
 891 # ----------------------------------------------------------------------------
 892 # Process subdirectories
 893 # ----------------------------------------------------------------------------
 894
 895 # opencv.hpp and legacy headers
 896 add_subdirectory(include)
 897
 898 # Enable compiler options for OpenCV modules/apps/samples only (ignore 3rdparty)
 899 ocv_add_modules_compiler_options()
 900
 901 # OpenCV modules
 902 add_subdirectory(modules)
 903
 904 # Generate targets for documentation
 905 add_subdirectory(doc)
 906
 907 # various data that is used by cv libraries and/or demo applications.
 908 add_subdirectory(data)
 909
 910 # extra applications
 911 if(BUILD_opencv_apps)
 912   add_subdirectory(apps)
 913 endif()
 914
 915 # examples
 916 if(BUILD_EXAMPLES OR BUILD_ANDROID_EXAMPLES OR INSTALL_ANDROID_EXAMPLES OR INSTALL_PYTHON_EXAMPLES OR INSTALL_C_EXAMPLES)
 917   add_subdirectory(samples)
 918 endif()
 919
 920 if(ANDROID)
 921   add_subdirectory(platforms/android/service)
 922 endif()
 923
 924 # ----------------------------------------------------------------------------
 925 # Finalization: generate configuration-based files
 926 # ----------------------------------------------------------------------------
 927
 928 ocv_cmake_hook(PRE_FINALIZE)
 929
 930 # Generate platform-dependent and configuration-dependent headers
 931 include(cmake/OpenCVGenHeaders.cmake)
 932
 933 # Generate opencv.pc for pkg-config command
 934 if(OPENCV_GENERATE_PKGCONFIG)
 935   include(cmake/OpenCVGenPkgconfig.cmake)
 936 endif()
 937
 938 # Generate OpenCV.mk for ndk-build (Android build tool)
 939 include(cmake/OpenCVGenAndroidMK.cmake)
 940
 941 # Generate OpenCVConfig.cmake and OpenCVConfig-version.cmake for cmake projects
 942 include(cmake/OpenCVGenConfig.cmake)
 943
 944 # Generate Info.plist for the IOS framework
 945 if(APPLE_FRAMEWORK)
 946   include(cmake/OpenCVGenInfoPlist.cmake)
 947 endif()
 948
 949 # Generate ABI descriptor
 950 include(cmake/OpenCVGenABI.cmake)
 951
 952 # Generate environment setup file
 953 if(INSTALL_TESTS AND OPENCV_TEST_DATA_PATH)
 954   if(ANDROID)
 955     get_filename_component(TEST_PATH ${OPENCV_TEST_INSTALL_PATH} DIRECTORY)
 956     configure_file("${CMAKE_CURRENT_SOURCE_DIR}/cmake/templates/opencv_run_all_tests_android.sh.in"
 957                    "${CMAKE_BINARY_DIR}/unix-install/opencv_run_all_tests.sh" @ONLY)
 958     install(PROGRAMS "${CMAKE_BINARY_DIR}/unix-install/opencv_run_all_tests.sh"
 959             DESTINATION ./ COMPONENT tests)
 960   elseif(WIN32)
 961     configure_file("${CMAKE_CURRENT_SOURCE_DIR}/cmake/templates/opencv_run_all_tests_windows.cmd.in"
 962                    "${CMAKE_BINARY_DIR}/win-install/opencv_run_all_tests.cmd" @ONLY)
 963     install(PROGRAMS "${CMAKE_BINARY_DIR}/win-install/opencv_run_all_tests.cmd"
 964             DESTINATION ${OPENCV_TEST_INSTALL_PATH} COMPONENT tests)
 965   elseif(UNIX)
 966     configure_file("${CMAKE_CURRENT_SOURCE_DIR}/cmake/templates/opencv_run_all_tests_unix.sh.in"
 967                    "${CMAKE_BINARY_DIR}/unix-install/opencv_run_all_tests.sh" @ONLY)
 968     install(PROGRAMS "${CMAKE_BINARY_DIR}/unix-install/opencv_run_all_tests.sh"
 969             DESTINATION ${OPENCV_TEST_INSTALL_PATH} COMPONENT tests)
 970   endif()
 971 endif()
 972
 973 if(NOT OPENCV_README_FILE)
 974   if(ANDROID)
 975     set(OPENCV_README_FILE ${CMAKE_CURRENT_SOURCE_DIR}/platforms/android/README.android)
 976   endif()
 977 endif()
 978
 979 if(NOT OPENCV_LICENSE_FILE)
 980   set(OPENCV_LICENSE_FILE ${CMAKE_CURRENT_SOURCE_DIR}/LICENSE)
 981 endif()
 982
 983 # for UNIX it does not make sense as LICENSE and readme will be part of the package automatically
 984 if(ANDROID OR NOT UNIX)
 985   install(FILES ${OPENCV_LICENSE_FILE}
 986         PERMISSIONS OWNER_READ OWNER_WRITE GROUP_READ WORLD_READ
 987         DESTINATION ./ COMPONENT libs)
 988   if(OPENCV_README_FILE)
 989     install(FILES ${OPENCV_README_FILE}
 990             PERMISSIONS OWNER_READ OWNER_WRITE GROUP_READ WORLD_READ
 991             DESTINATION ./ COMPONENT libs)
 992   endif()
 993 endif()
 994
 995 if(COMMAND ocv_pylint_finalize)
 996   ocv_pylint_add_directory(${CMAKE_CURRENT_LIST_DIR}/modules/python/test)
 997   ocv_pylint_add_directory(${CMAKE_CURRENT_LIST_DIR}/samples/python)
 998   ocv_pylint_add_directory(${CMAKE_CURRENT_LIST_DIR}/samples/dnn)
 999   ocv_pylint_add_directory_recurse(${CMAKE_CURRENT_LIST_DIR}/samples/python/tutorial_code)
1000   ocv_pylint_finalize()
1001 endif()
1002 if(TARGET check_pylint)
1003   message(STATUS "Registered 'check_pylint' target: using ${PYLINT_EXECUTABLE} (ver: ${PYLINT_VERSION}), checks: ${PYLINT_TOTAL_TARGETS}")
1004 endif()
1005 if(TARGET check_flake8)
1006   message(STATUS "Registered 'check_flake8' target: using ${FLAKE8_EXECUTABLE} (ver: ${FLAKE8_VERSION})")
1007 endif()
1008
1009 if(OPENCV_GENERATE_SETUPVARS)
1010   include(cmake/OpenCVGenSetupVars.cmake)
1011 endif()
1012
1013 # ----------------------------------------------------------------------------
1014 # Summary:
1015 # ----------------------------------------------------------------------------
1016 status("")
1017 status("General configuration for OpenCV ${OPENCV_VERSION} =====================================")
1018 if(OPENCV_VCSVERSION)
1019   status("  Version control:" ${OPENCV_VCSVERSION})
1020 endif()
1021 if(OPENCV_EXTRA_MODULES_PATH AND NOT BUILD_INFO_SKIP_EXTRA_MODULES)
1022   set(__dump_extra_header OFF)
1023   foreach(p ${OPENCV_EXTRA_MODULES_PATH})
1024     if(EXISTS ${p})
1025       if(NOT __dump_extra_header)
1026         set(__dump_extra_header ON)
1027         status("")
1028         status("  Extra modules:")
1029       else()
1030         status("")
1031       endif()
1032       ocv_git_describe(EXTRA_MODULES_VCSVERSION "${p}")
1033       status("    Location (extra):" ${p})
1034       status("    Version control (extra):" ${EXTRA_MODULES_VCSVERSION})
1035     endif()
1036   endforeach()
1037   unset(__dump_extra_header)
1038 endif()
1039
1040 # ========================== build platform ==========================
1041 status("")
1042 status("  Platform:")
1043 if(NOT DEFINED OPENCV_TIMESTAMP
1044     AND NOT CMAKE_VERSION VERSION_LESS 2.8.11
1045     AND NOT BUILD_INFO_SKIP_TIMESTAMP
1046 )
1047   string(TIMESTAMP OPENCV_TIMESTAMP "" UTC)
1048   set(OPENCV_TIMESTAMP "${OPENCV_TIMESTAMP}" CACHE STRING "Timestamp of OpenCV build configuration" FORCE)
1049 endif()
1050 if(OPENCV_TIMESTAMP)
1051   status("    Timestamp:"      ${OPENCV_TIMESTAMP})
1052 endif()
1053 status("    Host:"             ${CMAKE_HOST_SYSTEM_NAME} ${CMAKE_HOST_SYSTEM_VERSION} ${CMAKE_HOST_SYSTEM_PROCESSOR})
1054 if(CMAKE_CROSSCOMPILING)
1055   status("    Target:"         ${CMAKE_SYSTEM_NAME} ${CMAKE_SYSTEM_VERSION} ${CMAKE_SYSTEM_PROCESSOR})
1056 endif()
1057 status("    CMake:"            ${CMAKE_VERSION})
1058 status("    CMake generator:"  ${CMAKE_GENERATOR})
1059 status("    CMake build tool:" ${CMAKE_BUILD_TOOL})
1060 if(MSVC)
1061   status("    MSVC:"           ${MSVC_VERSION})
1062 endif()
1063 if(CMAKE_GENERATOR MATCHES Xcode)
1064   status("    Xcode:"          ${XCODE_VERSION})
1065 endif()
1066 if(CMAKE_GENERATOR MATCHES "Xcode|Visual Studio|Multi-Config")
1067   status("    Configuration:"  ${CMAKE_CONFIGURATION_TYPES})
1068 else()
1069   status("    Configuration:"  ${CMAKE_BUILD_TYPE})
1070 endif()
1071
1072
1073 # ========================= CPU code generation mode =========================
1074 status("")
1075 status("  CPU/HW features:")
1076 status("    Baseline:"  "${CPU_BASELINE_FINAL}")
1077 if(NOT CPU_BASELINE STREQUAL CPU_BASELINE_FINAL)
1078   status("      requested:"  "${CPU_BASELINE}")
1079 endif()
1080 if(CPU_BASELINE_REQUIRE)
1081   status("      required:"  "${CPU_BASELINE_REQUIRE}")
1082 endif()
1083 if(CPU_BASELINE_DISABLE)
1084   status("      disabled:"  "${CPU_BASELINE_DISABLE}")
1085 endif()
1086 if(CPU_DISPATCH_FINAL OR CPU_DISPATCH)
1087   status("    Dispatched code generation:"  "${CPU_DISPATCH_FINAL}")
1088   if(NOT CPU_DISPATCH STREQUAL CPU_DISPATCH_FINAL)
1089     status("      requested:"  "${CPU_DISPATCH}")
1090   endif()
1091   if(CPU_DISPATCH_REQUIRE)
1092     status("      required:"  "${CPU_DISPATCH_REQUIRE}")
1093   endif()
1094   foreach(OPT ${CPU_DISPATCH_FINAL})
1095     status("      ${OPT} (${CPU_${OPT}_USAGE_COUNT} files):"  "+ ${CPU_DISPATCH_${OPT}_INCLUDED}")
1096   endforeach()
1097 endif()
1098
1099 # ========================== C/C++ options ==========================
1100 if(CMAKE_CXX_COMPILER_VERSION)
1101   set(OPENCV_COMPILER_STR "${CMAKE_CXX_COMPILER} ${CMAKE_CXX_COMPILER_ARG1} (ver ${CMAKE_CXX_COMPILER_VERSION})")
1102 else()
1103   set(OPENCV_COMPILER_STR "${CMAKE_CXX_COMPILER} ${CMAKE_CXX_COMPILER_ARG1}")
1104 endif()
1105 string(STRIP "${OPENCV_COMPILER_STR}" OPENCV_COMPILER_STR)
1106
1107 status("")
1108 status("  C/C++:")
1109 status("    Built as dynamic libs?:" BUILD_SHARED_LIBS THEN YES ELSE NO)
1110 if(DEFINED CMAKE_CXX_STANDARD AND CMAKE_CXX_STANDARD)
1111   status("    C++ standard:"           "${CMAKE_CXX_STANDARD}")
1112 endif()
1113 status("    C++ Compiler:"           ${OPENCV_COMPILER_STR})
1114 status("    C++ flags (Release):"    ${CMAKE_CXX_FLAGS} ${CMAKE_CXX_FLAGS_RELEASE})
1115 status("    C++ flags (Debug):"      ${CMAKE_CXX_FLAGS} ${CMAKE_CXX_FLAGS_DEBUG})
1116 status("    C Compiler:"             ${CMAKE_C_COMPILER} ${CMAKE_C_COMPILER_ARG1})
1117 status("    C flags (Release):"      ${CMAKE_C_FLAGS} ${CMAKE_C_FLAGS_RELEASE})
1118 status("    C flags (Debug):"        ${CMAKE_C_FLAGS} ${CMAKE_C_FLAGS_DEBUG})
1119 if(WIN32)
1120   status("    Linker flags (Release):" ${CMAKE_EXE_LINKER_FLAGS} ${CMAKE_EXE_LINKER_FLAGS_RELEASE})
1121   status("    Linker flags (Debug):"   ${CMAKE_EXE_LINKER_FLAGS} ${CMAKE_EXE_LINKER_FLAGS_DEBUG})
1122 else()
1123   status("    Linker flags (Release):" ${CMAKE_SHARED_LINKER_FLAGS} ${CMAKE_SHARED_LINKER_FLAGS_RELEASE})
1124   status("    Linker flags (Debug):"   ${CMAKE_SHARED_LINKER_FLAGS} ${CMAKE_SHARED_LINKER_FLAGS_DEBUG})
1125 endif()
1126 status("    ccache:"                  OPENCV_COMPILER_IS_CCACHE THEN YES ELSE NO)
1127 status("    Precompiled headers:"     PCHSupport_FOUND AND ENABLE_PRECOMPILED_HEADERS THEN YES ELSE NO)
1128
1129 # ========================== Dependencies ============================
1130 ocv_get_all_libs(deps_modules deps_extra deps_3rdparty)
1131 status("    Extra dependencies:" ${deps_extra})
1132 status("    3rdparty dependencies:" ${deps_3rdparty})
1133
1134 # ========================== OpenCV modules ==========================
1135 status("")
1136 status("  OpenCV modules:")
1137 set(OPENCV_MODULES_BUILD_ST "")
1138 foreach(the_module ${OPENCV_MODULES_BUILD})
1139   if(NOT OPENCV_MODULE_${the_module}_CLASS STREQUAL "INTERNAL" OR the_module STREQUAL "opencv_ts")
1140     list(APPEND OPENCV_MODULES_BUILD_ST "${the_module}")
1141   endif()
1142 endforeach()
1143 string(REPLACE "opencv_" "" OPENCV_MODULES_BUILD_ST          "${OPENCV_MODULES_BUILD_ST}")
1144 string(REPLACE "opencv_" "" OPENCV_MODULES_DISABLED_USER_ST  "${OPENCV_MODULES_DISABLED_USER}")
1145 string(REPLACE "opencv_" "" OPENCV_MODULES_DISABLED_AUTO_ST  "${OPENCV_MODULES_DISABLED_AUTO}")
1146 string(REPLACE "opencv_" "" OPENCV_MODULES_DISABLED_FORCE_ST "${OPENCV_MODULES_DISABLED_FORCE}")
1147 list(SORT OPENCV_MODULES_BUILD_ST)
1148 list(SORT OPENCV_MODULES_DISABLED_USER_ST)
1149 list(SORT OPENCV_MODULES_DISABLED_AUTO_ST)
1150 list(SORT OPENCV_MODULES_DISABLED_FORCE_ST)
1151 status("    To be built:"            OPENCV_MODULES_BUILD          THEN ${OPENCV_MODULES_BUILD_ST}          ELSE "-")
1152 status("    Disabled:"               OPENCV_MODULES_DISABLED_USER  THEN ${OPENCV_MODULES_DISABLED_USER_ST}  ELSE "-")
1153 status("    Disabled by dependency:" OPENCV_MODULES_DISABLED_AUTO  THEN ${OPENCV_MODULES_DISABLED_AUTO_ST}  ELSE "-")
1154 status("    Unavailable:"            OPENCV_MODULES_DISABLED_FORCE THEN ${OPENCV_MODULES_DISABLED_FORCE_ST} ELSE "-")
1155
1156 ocv_build_features_string(apps_status
1157   IF BUILD_TESTS AND HAVE_opencv_ts THEN "tests"
1158   IF BUILD_PERF_TESTS AND HAVE_opencv_ts THEN "perf_tests"
1159   IF BUILD_EXAMPLES THEN "examples"
1160   IF BUILD_opencv_apps THEN "apps"
1161   IF BUILD_ANDROID_SERVICE THEN "android_service"
1162   IF (BUILD_ANDROID_EXAMPLES OR INSTALL_ANDROID_EXAMPLES) AND CAN_BUILD_ANDROID_PROJECTS THEN "android_examples"
1163   ELSE "-")
1164 status("    Applications:" "${apps_status}")
1165 ocv_build_features_string(docs_status
1166     IF TARGET doxygen_cpp THEN "doxygen"
1167     IF TARGET doxygen_python THEN "python"
1168     IF TARGET doxygen_javadoc THEN "javadoc"
1169     IF BUILD_opencv_js OR DEFINED OPENCV_JS_LOCATION THEN "js"
1170     ELSE "NO"
1171 )
1172 status("    Documentation:" "${docs_status}")
1173 status("    Non-free algorithms:" OPENCV_ENABLE_NONFREE THEN "YES" ELSE "NO")
1174
1175 # ========================== Android details ==========================
1176 if(ANDROID)
1177   status("")
1178   if(DEFINED ANDROID_NDK_REVISION)
1179     set(__msg "${ANDROID_NDK} (ver ${ANDROID_NDK_REVISION})")
1180   else()
1181     set(__msg "location: ${ANDROID_NDK}")
1182   endif()
1183   status("  Android NDK: " ${__msg})
1184   status("    Android ABI:" ${ANDROID_ABI})
1185   if(BUILD_WITH_STANDALONE_TOOLCHAIN)
1186     status("    NDK toolchain:" "standalone: ${ANDROID_STANDALONE_TOOLCHAIN}")
1187   elseif(BUILD_WITH_ANDROID_NDK OR DEFINED ANDROID_TOOLCHAIN_NAME)
1188     status("    NDK toolchain:" "${ANDROID_TOOLCHAIN_NAME}")
1189   endif()
1190   status("    STL type:" ${ANDROID_STL})
1191   status("    Native API level:" ${ANDROID_NATIVE_API_LEVEL})
1192
1193   if(BUILD_ANDROID_PROJECTS)
1194     status("  Android SDK: " "${ANDROID_SDK} (tools: ${ANDROID_SDK_TOOLS_VERSION} build tools: ${ANDROID_SDK_BUILD_TOOLS_VERSION})")
1195     if(ANDROID_EXECUTABLE)
1196       status("    android tool:"  "${ANDROID_EXECUTABLE}")
1197     endif()
1198   else()
1199     status("  Android SDK: " "not used, projects are not built")
1200   endif()
1201   if(DEFINED ANDROID_SDK_COMPATIBLE_TARGET)
1202     status("    SDK target:" "${ANDROID_SDK_COMPATIBLE_TARGET}")
1203   endif()
1204   if(DEFINED ANDROID_PROJECTS_BUILD_TYPE)
1205     if(ANDROID_PROJECTS_BUILD_TYPE STREQUAL "ANT")
1206       status("    Projects build scripts:" "Ant/Eclipse compatible")
1207     elseif(ANDROID_PROJECTS_BUILD_TYPE STREQUAL "ANT")
1208       status("    Projects build scripts:" "Gradle")
1209     endif()
1210   endif()
1211 endif()
1212
1213 # ================== Windows RT features ==================
1214 if(WIN32)
1215 status("")
1216 status("  Windows RT support:" WINRT THEN YES ELSE NO)
1217   if(WINRT)
1218     status("    Building for Microsoft platform: " ${CMAKE_SYSTEM_NAME})
1219     status("    Building for architectures: " ${CMAKE_VS_EFFECTIVE_PLATFORMS})
1220     status("    Building for version: " ${CMAKE_SYSTEM_VERSION})
1221     if (DEFINED ENABLE_WINRT_MODE_NATIVE)
1222       status("    Building for C++ without CX extensions")
1223     endif()
1224   endif()
1225 endif(WIN32)
1226
1227 # ========================== GUI ==========================
1228 status("")
1229 status("  GUI: ")
1230
1231 if(WITH_QT OR HAVE_QT)
1232   if(HAVE_QT5)
1233     status("    QT:" "YES (ver ${Qt5Core_VERSION_STRING})")
1234     status("      QT OpenGL support:" HAVE_QT_OPENGL THEN "YES (${Qt5OpenGL_LIBRARIES} ${Qt5OpenGL_VERSION_STRING})" ELSE NO)
1235   elseif(HAVE_QT)
1236     status("    QT:" "YES (ver ${QT_VERSION_MAJOR}.${QT_VERSION_MINOR}.${QT_VERSION_PATCH} ${QT_EDITION})")
1237     status("      QT OpenGL support:" HAVE_QT_OPENGL THEN "YES (${QT_QTOPENGL_LIBRARY})" ELSE NO)
1238   else()
1239     status("    QT:" "NO")
1240   endif()
1241 endif()
1242
1243 if(WITH_WIN32UI)
1244   status("    Win32 UI:" HAVE_WIN32UI THEN YES ELSE NO)
1245 endif()
1246
1247 if(HAVE_COCOA)  # APPLE
1248   status("    Cocoa:"  YES)
1249 endif()
1250
1251 if(WITH_GTK OR HAVE_GTK)
1252   if(HAVE_GTK3)
1253     status("    GTK+:" "YES (ver ${GTK3_VERSION})")
1254   elseif(HAVE_GTK)
1255     status("    GTK+:" "YES (ver ${GTK2_VERSION})")
1256   else()
1257     status("    GTK+:" "NO")
1258   endif()
1259   if(HAVE_GTK)
1260     status(  "      GThread :" HAVE_GTHREAD THEN "YES (ver ${GTHREAD_VERSION})" ELSE NO)
1261     status(  "      GtkGlExt:" HAVE_GTKGLEXT THEN "YES (ver ${GTKGLEXT_VERSION})" ELSE NO)
1262   endif()
1263 endif()
1264
1265 if(WITH_OPENGL OR HAVE_OPENGL)
1266   status("    OpenGL support:" HAVE_OPENGL THEN "YES (${OPENGL_LIBRARIES})" ELSE NO)
1267 endif()
1268
1269 if(WITH_VTK OR HAVE_VTK)
1270   status("    VTK support:" HAVE_VTK THEN "YES (ver ${VTK_VERSION})" ELSE NO)
1271 endif()
1272
1273 # ========================== MEDIA IO ==========================
1274 status("")
1275 status("  Media I/O: ")
1276 status("    ZLib:"   ZLIB_FOUND THEN "${ZLIB_LIBRARIES} (ver ${ZLIB_VERSION_STRING})" ELSE "build (ver ${ZLIB_VERSION_STRING})")
1277
1278 if(WITH_JPEG OR HAVE_JPEG)
1279   if(NOT HAVE_JPEG)
1280     status("    JPEG:" NO)
1281   elseif(BUILD_JPEG)
1282     status("    JPEG:" "build-${JPEG_LIBRARY} (ver ${JPEG_LIB_VERSION})")
1283   else()
1284     status("    JPEG:" "${JPEG_LIBRARY} (ver ${JPEG_LIB_VERSION})")
1285   endif()
1286 endif()
1287
1288 if(WITH_WEBP OR HAVE_WEBP)
1289   status("    WEBP:" WEBP_FOUND THEN "${WEBP_LIBRARY} (ver ${WEBP_VERSION})" ELSE "build (ver ${WEBP_VERSION})")
1290 endif()
1291
1292 if(WITH_PNG OR HAVE_PNG)
1293   status("    PNG:"  PNG_FOUND  THEN "${PNG_LIBRARY} (ver ${PNG_VERSION})" ELSE "build (ver ${PNG_VERSION})")
1294 endif()
1295
1296 if(WITH_TIFF OR HAVE_TIFF)
1297   status("    TIFF:" TIFF_FOUND THEN "${TIFF_LIBRARY} (ver ${TIFF_VERSION} / ${TIFF_VERSION_STRING})" ELSE "build (ver ${TIFF_VERSION} - ${TIFF_VERSION_STRING})")
1298 endif()
1299
1300 if(HAVE_OPENJPEG)
1301   status("    JPEG 2000:" OpenJPEG_FOUND
1302       THEN "OpenJPEG (ver ${OPENJPEG_MAJOR_VERSION}.${OPENJPEG_MINOR_VERSION}.${OPENJPEG_BUILD_VERSION})"
1303       ELSE "build (ver ${OPENJPEG_VERSION})"
1304   )
1305 elseif(HAVE_JASPER)
1306   status("    JPEG 2000:" JASPER_FOUND THEN "${JASPER_LIBRARY} (ver ${JASPER_VERSION_STRING})" ELSE "build Jasper (ver ${JASPER_VERSION_STRING})")
1307 elseif(WITH_OPENJPEG OR WITH_JASPER)
1308   status("    JPEG 2000:" "NO")
1309 endif()
1310
1311 if(WITH_OPENEXR OR HAVE_OPENEXR)
1312   if(HAVE_OPENEXR)
1313     status("    OpenEXR:" OPENEXR_FOUND THEN "${OPENEXR_LIBRARIES} (ver ${OPENEXR_VERSION})" ELSE "build (ver ${OPENEXR_VERSION})")
1314   else()
1315     status("    OpenEXR:" "NO")
1316   endif()
1317 endif()
1318
1319 if(WITH_GDAL OR HAVE_GDAL)
1320   status("    GDAL:" HAVE_GDAL THEN "YES (${GDAL_LIBRARY})" ELSE "NO")
1321 endif()
1322
1323 if(WITH_GDCM OR HAVE_GDCM)
1324   status("    GDCM:" HAVE_GDCM THEN "YES (${GDCM_VERSION})" ELSE "NO")
1325 endif()
1326
1327 if(WITH_IMGCODEC_HDR OR DEFINED HAVE_IMGCODEC_HDR)
1328   status("    HDR:" HAVE_IMGCODEC_HDR THEN "YES" ELSE "NO")
1329 endif()
1330
1331 if(WITH_IMGCODEC_SUNRASTER OR DEFINED HAVE_IMGCODEC_SUNRASTER)
1332   status("    SUNRASTER:" HAVE_IMGCODEC_SUNRASTER THEN "YES" ELSE "NO")
1333 endif()
1334
1335 if(WITH_IMGCODEC_PXM OR DEFINED HAVE_IMGCODEC_PXM)
1336   status("    PXM:" HAVE_IMGCODEC_PXM THEN "YES" ELSE "NO")
1337 endif()
1338
1339 if(WITH_IMGCODEC_PFM OR DEFINED HAVE_IMGCODEC_PFM)
1340   status("    PFM:" HAVE_IMGCODEC_PFM THEN "YES" ELSE "NO")
1341 endif()
1342
1343 # ========================== VIDEO IO ==========================
1344 status("")
1345 status("  Video I/O:")
1346
1347 if(WITH_1394 OR HAVE_DC1394_2)
1348   status("    DC1394:" HAVE_DC1394_2 THEN "YES (${DC1394_2_VERSION})" ELSE NO)
1349 endif()
1350
1351 if(WITH_FFMPEG OR HAVE_FFMPEG)
1352   if(OPENCV_FFMPEG_USE_FIND_PACKAGE)
1353     status("    FFMPEG:"       HAVE_FFMPEG         THEN "YES (find_package)"                       ELSE "NO (find_package)")
1354   elseif(WIN32)
1355     status("    FFMPEG:"       HAVE_FFMPEG         THEN "YES (prebuilt binaries)"                  ELSE NO)
1356   else()
1357     status("    FFMPEG:"       HAVE_FFMPEG         THEN YES ELSE NO)
1358   endif()
1359   status("      avcodec:"      FFMPEG_libavcodec_VERSION    THEN "YES (${FFMPEG_libavcodec_VERSION})"    ELSE NO)
1360   status("      avformat:"     FFMPEG_libavformat_VERSION   THEN "YES (${FFMPEG_libavformat_VERSION})"   ELSE NO)
1361   status("      avutil:"       FFMPEG_libavutil_VERSION     THEN "YES (${FFMPEG_libavutil_VERSION})"     ELSE NO)
1362   status("      swscale:"      FFMPEG_libswscale_VERSION    THEN "YES (${FFMPEG_libswscale_VERSION})"    ELSE NO)
1363   status("      avresample:"   FFMPEG_libavresample_VERSION THEN "YES (${FFMPEG_libavresample_VERSION})" ELSE NO)
1364 endif()
1365
1366 if(WITH_GSTREAMER OR HAVE_GSTREAMER)
1367   status("    GStreamer:" HAVE_GSTREAMER THEN "YES (${GSTREAMER_VERSION})" ELSE NO)
1368 endif()
1369
1370 if(WITH_OPENNI2 OR HAVE_OPENNI2)
1371   status("    OpenNI2:"        HAVE_OPENNI2    THEN "YES (${OPENNI2_VERSION})" ELSE NO)
1372 endif()
1373
1374 if(WITH_PVAPI OR HAVE_PVAPI)
1375   status("    PvAPI:" HAVE_PVAPI THEN YES ELSE NO)
1376 endif()
1377
1378 if(WITH_ARAVIS OR HAVE_ARAVIS_API)
1379   status("    Aravis SDK:" HAVE_ARAVIS_API THEN "YES (${ARAVIS_VERSION})" ELSE NO)
1380 endif()
1381
1382 if(WITH_AVFOUNDATION OR HAVE_AVFOUNDATION)
1383   status("    AVFoundation:" HAVE_AVFOUNDATION THEN YES ELSE NO)
1384 endif()
1385
1386 if(HAVE_CAP_IOS)
1387   status("    iOS capture:" YES)
1388 endif()
1389
1390 if(WITH_V4L OR HAVE_V4L)
1391   ocv_build_features_string(v4l_status
1392     IF HAVE_CAMV4L2 THEN "linux/videodev2.h"
1393     IF HAVE_VIDEOIO THEN "sys/videoio.h"
1394     ELSE "NO")
1395   status("    v4l/v4l2:" HAVE_V4L THEN "YES (${v4l_status})" ELSE NO)
1396 endif()
1397
1398 if(WITH_DSHOW OR HAVE_DSHOW)
1399   status("    DirectShow:" HAVE_DSHOW THEN YES ELSE NO)
1400 endif()
1401
1402 if(WITH_MSMF OR HAVE_MSMF)
1403   status("    Media Foundation:" HAVE_MSMF THEN YES ELSE NO)
1404   status("      DXVA:" HAVE_MSMF_DXVA THEN YES ELSE NO)
1405 endif()
1406
1407 if(WITH_XIMEA OR HAVE_XIMEA)
1408   status("    XIMEA:" HAVE_XIMEA THEN YES ELSE NO)
1409 endif()
1410
1411 if(WITH_UEYE OR HAVE_UEYE)
1412   status("    uEye:" HAVE_UEYE THEN YES ELSE NO)
1413 endif()
1414
1415 if(WITH_XINE OR HAVE_XINE)
1416   status("    Xine:"           HAVE_XINE           THEN "YES (ver ${XINE_VERSION})"     ELSE NO)
1417 endif()
1418
1419 if(WITH_LIBREALSENSE OR HAVE_LIBREALSENSE)
1420   status("    Intel RealSense:" HAVE_LIBREALSENSE THEN "YES (${LIBREALSENSE_VERSION})" ELSE NO)
1421 endif()
1422
1423 if(WITH_MFX OR HAVE_MFX)
1424   status("    Intel Media SDK:" HAVE_MFX      THEN "YES (${MFX_LIBRARY})" ELSE NO)
1425 endif()
1426
1427 if(WITH_GPHOTO2 OR HAVE_GPHOTO2)
1428   status("    gPhoto2:"        HAVE_GPHOTO2        THEN "YES"                                 ELSE NO)
1429 endif()
1430
1431 # Order is similar to CV_PARALLEL_FRAMEWORK in core/src/parallel.cpp
1432 ocv_build_features_string(parallel_status EXCLUSIVE
1433   IF HAVE_TBB THEN "TBB (ver ${TBB_VERSION_MAJOR}.${TBB_VERSION_MINOR} interface ${TBB_INTERFACE_VERSION})"
1434   IF HAVE_HPX THEN "HPX"
1435   IF HAVE_OPENMP THEN "OpenMP"
1436   IF HAVE_GCD THEN "GCD"
1437   IF WINRT OR HAVE_CONCURRENCY THEN "Concurrency"
1438   IF HAVE_PTHREADS_PF THEN "pthreads"
1439   ELSE "none")
1440 status("")
1441 status("  Parallel framework:" "${parallel_status}")
1442
1443 if(CV_TRACE OR OPENCV_TRACE)
1444   ocv_build_features_string(trace_status EXCLUSIVE
1445     IF HAVE_ITT THEN "with Intel ITT"
1446     ELSE "built-in")
1447   status("")
1448   status("  Trace: " OPENCV_TRACE THEN "YES (${trace_status})" ELSE NO)
1449 endif()
1450
1451 # ========================== Other third-party libraries ==========================
1452 status("")
1453 status("  Other third-party libraries:")
1454
1455 if(WITH_IPP AND HAVE_IPP)
1456   status("    Intel IPP:" "${IPP_VERSION_STR} [${IPP_VERSION_MAJOR}.${IPP_VERSION_MINOR}.${IPP_VERSION_BUILD}]")
1457   status("           at:" "${IPP_ROOT_DIR}")
1458   if(NOT HAVE_IPP_ICV)
1459     status("       linked:" BUILD_WITH_DYNAMIC_IPP THEN "dynamic" ELSE "static")
1460   endif()
1461   if(HAVE_IPP_IW)
1462     if(BUILD_IPP_IW)
1463       status("    Intel IPP IW:" "sources (${IW_VERSION_MAJOR}.${IW_VERSION_MINOR}.${IW_VERSION_UPDATE})")
1464     else()
1465       status("    Intel IPP IW:" "binaries (${IW_VERSION_MAJOR}.${IW_VERSION_MINOR}.${IW_VERSION_UPDATE})")
1466     endif()
1467     status("              at:" "${IPP_IW_PATH}")
1468   else()
1469     status("    Intel IPP IW:"   NO)
1470   endif()
1471 endif()
1472
1473 if(WITH_VA OR HAVE_VA)
1474   status("    VA:"            HAVE_VA          THEN "YES" ELSE NO)
1475 endif()
1476
1477 if(WITH_TENGINE OR HAVE_TENGINE)
1478   status("    Tengine:"      HAVE_TENGINE     THEN "YES (${TENGINE_LIBRARIES})" ELSE NO)
1479 endif()
1480
1481 if(WITH_LAPACK OR HAVE_LAPACK)
1482   status("    Lapack:"      HAVE_LAPACK     THEN "YES (${LAPACK_LIBRARIES})" ELSE NO)
1483 endif()
1484
1485 if(WITH_HALIDE OR HAVE_HALIDE)
1486   status("    Halide:"     HAVE_HALIDE      THEN "YES (${HALIDE_LIBRARIES} ${HALIDE_INCLUDE_DIRS})" ELSE NO)
1487 endif()
1488
1489 if(WITH_INF_ENGINE OR INF_ENGINE_TARGET)
1490   if(INF_ENGINE_TARGET)
1491     list(GET INF_ENGINE_TARGET 0 ie_target)
1492     set(__msg "YES (${INF_ENGINE_RELEASE} / ${INF_ENGINE_VERSION})")
1493     get_target_property(_lib ${ie_target} IMPORTED_LOCATION)
1494     get_target_property(_lib_imp_rel ${ie_target} IMPORTED_IMPLIB_RELEASE)
1495     get_target_property(_lib_imp_dbg ${ie_target} IMPORTED_IMPLIB_DEBUG)
1496     get_target_property(_lib_rel ${ie_target} IMPORTED_LOCATION_RELEASE)
1497     get_target_property(_lib_dbg ${ie_target} IMPORTED_LOCATION_DEBUG)
1498     ocv_build_features_string(_lib
1499       IF _lib THEN "${_lib}"
1500       IF _lib_imp_rel AND _lib_imp_dbg THEN "${_lib_imp_rel} / ${_lib_imp_dbg}"
1501       IF _lib_rel AND _lib_dbg THEN "${_lib_rel} / ${_lib_dbg}"
1502       IF _lib_rel  THEN "${_lib_rel}"
1503       IF _lib_dbg  THEN "${_lib_dbg}"
1504       ELSE "unknown"
1505     )
1506     get_target_property(_inc ${ie_target} INTERFACE_INCLUDE_DIRECTORIES)
1507     status("    Inference Engine:" "${__msg}")
1508     status("        * libs:" "${_lib}")
1509     status("        * includes:" "${_inc}")
1510   else()
1511     status("    Inference Engine:"     "NO")
1512   endif()
1513 endif()
1514 if(WITH_NGRAPH OR HAVE_NGRAPH)
1515   if(HAVE_NGRAPH)
1516     set(__target ngraph::ngraph)
1517     set(__msg "YES (${ngraph_VERSION})")
1518     get_target_property(_lib ${__target} IMPORTED_LOCATION)
1519     get_target_property(_lib_imp_rel ${__target} IMPORTED_IMPLIB_RELEASE)
1520     get_target_property(_lib_imp_dbg ${__target} IMPORTED_IMPLIB_DEBUG)
1521     get_target_property(_lib_rel ${__target} IMPORTED_LOCATION_RELEASE)
1522     get_target_property(_lib_dbg ${__target} IMPORTED_LOCATION_DEBUG)
1523     ocv_build_features_string(_lib
1524       IF _lib THEN "${_lib}"
1525       IF _lib_imp_rel AND _lib_imp_dbg THEN "${_lib_imp_rel} / ${_lib_imp_dbg}"
1526       IF _lib_rel AND _lib_dbg THEN "${_lib_rel} / ${_lib_dbg}"
1527       IF _lib_rel  THEN "${_lib_rel}"
1528       IF _lib_dbg  THEN "${_lib_dbg}"
1529       ELSE "unknown"
1530     )
1531     get_target_property(_inc ${__target} INTERFACE_INCLUDE_DIRECTORIES)
1532     status("    nGraph:" "${__msg}")
1533     status("        * libs:" "${_lib}")
1534     status("        * includes:" "${_inc}")
1535   else()
1536     status("    nGraph:"     "NO")
1537   endif()
1538 endif()
1539
1540 if(WITH_EIGEN OR HAVE_EIGEN)
1541   status("    Eigen:"      HAVE_EIGEN       THEN "YES (ver ${EIGEN_WORLD_VERSION}.${EIGEN_MAJOR_VERSION}.${EIGEN_MINOR_VERSION})" ELSE NO)
1542 endif()
1543
1544 if(WITH_OPENVX OR HAVE_OPENVX)
1545   status("    OpenVX:"     HAVE_OPENVX      THEN "YES (${OPENVX_LIBRARIES})" ELSE "NO")
1546 endif()
1547
1548 status("    Custom HAL:" OpenCV_USED_HAL  THEN "YES (${OpenCV_USED_HAL})" ELSE "NO")
1549
1550 foreach(s ${CUSTOM_STATUS})
1551   status(${CUSTOM_STATUS_${s}})
1552 endforeach()
1553
1554 if(WITH_CUDA OR HAVE_CUDA)
1555   ocv_build_features_string(cuda_features
1556     IF HAVE_CUFFT THEN "CUFFT"
1557     IF HAVE_CUBLAS THEN "CUBLAS"
1558     IF HAVE_NVCUVID THEN "NVCUVID"
1559     IF CUDA_FAST_MATH THEN "FAST_MATH"
1560     ELSE "no extra features")
1561   status("")
1562   status("  NVIDIA CUDA:" HAVE_CUDA THEN "YES (ver ${CUDA_VERSION_STRING}, ${cuda_features})" ELSE NO)
1563   if(HAVE_CUDA)
1564     status("    NVIDIA GPU arch:"      ${OPENCV_CUDA_ARCH_BIN})
1565     status("    NVIDIA PTX archs:"     ${OPENCV_CUDA_ARCH_PTX})
1566   endif()
1567  endif()
1568
1569  if(WITH_CUDNN OR HAVE_CUDNN)
1570     status("")
1571     status("  cuDNN:" HAVE_CUDNN THEN "YES (ver ${CUDNN_VERSION})" ELSE NO)
1572 endif()
1573
1574 if(WITH_VULKAN OR HAVE_VULKAN)
1575   status("")
1576   status("  Vulkan:"     HAVE_VULKAN THEN "YES" ELSE "NO")
1577   if(HAVE_VULKAN)
1578     status("    Include path:"  VULKAN_INCLUDE_DIRS THEN "${VULKAN_INCLUDE_DIRS}" ELSE "NO")
1579     status("    Link libraries:" VULKAN_LIBRARIES THEN "${VULKAN_LIBRARIES}" ELSE "Dynamic load")
1580   endif()
1581 endif()
1582
1583 if(WITH_OPENCL OR HAVE_OPENCL)
1584   ocv_build_features_string(opencl_features
1585     IF HAVE_OPENCL_SVM THEN "SVM"
1586     IF HAVE_CLAMDFFT THEN "AMDFFT"
1587     IF HAVE_CLAMDBLAS THEN "AMDBLAS"
1588     IF HAVE_OPENCL_D3D11_NV THEN "NVD3D11"
1589     IF HAVE_VA_INTEL THEN "INTELVA"
1590     ELSE "no extra features")
1591   status("")
1592   status("  OpenCL:"     HAVE_OPENCL   THEN   "YES (${opencl_features})" ELSE "NO")
1593   if(HAVE_OPENCL)
1594     status("    Include path:"  OPENCL_INCLUDE_DIRS THEN "${OPENCL_INCLUDE_DIRS}" ELSE "NO")
1595     status("    Link libraries:"       OPENCL_LIBRARIES THEN "${OPENCL_LIBRARIES}" ELSE "Dynamic load")
1596   endif()
1597 endif()
1598
1599 if(WITH_ONNX OR HAVE_ONNX)
1600   status("")
1601   status("  ONNX:"     HAVE_ONNX THEN "YES" ELSE "NO")
1602   if(HAVE_ONNX)
1603     status("    Include path:"  ONNX_INCLUDE_DIR THEN "${ONNX_INCLUDE_DIR}" ELSE "NO")
1604     status("    Link libraries:" ONNX_LIBRARIES THEN "${ONNX_LIBRARIES}" ELSE "NO")
1605   endif()
1606 endif()
1607
1608 # ========================== python ==========================
1609 if(BUILD_opencv_python2)
1610   status("")
1611   status("  Python 2:")
1612   status("    Interpreter:"     PYTHON2INTERP_FOUND  THEN "${PYTHON2_EXECUTABLE} (ver ${PYTHON2_VERSION_STRING})"       ELSE NO)
1613   if(PYTHON2LIBS_VERSION_STRING)
1614     status("    Libraries:"   HAVE_opencv_python2  THEN  "${PYTHON2_LIBRARIES} (ver ${PYTHON2LIBS_VERSION_STRING})"   ELSE NO)
1615   else()
1616     status("    Libraries:"   HAVE_opencv_python2  THEN  "${PYTHON2_LIBRARIES}"                                      ELSE NO)
1617   endif()
1618   status("    numpy:"         PYTHON2_NUMPY_INCLUDE_DIRS THEN "${PYTHON2_NUMPY_INCLUDE_DIRS} (ver ${PYTHON2_NUMPY_VERSION})" ELSE "NO (Python wrappers can not be generated)")
1619   status("    install path:"  HAVE_opencv_python2  THEN "${__INSTALL_PATH_PYTHON2}"                            ELSE "-")
1620 endif()
1621
1622 if(BUILD_opencv_python3)
1623   status("")
1624   status("  Python 3:")
1625   status("    Interpreter:"     PYTHON3INTERP_FOUND  THEN "${PYTHON3_EXECUTABLE} (ver ${PYTHON3_VERSION_STRING})"       ELSE NO)
1626   if(PYTHON3LIBS_VERSION_STRING)
1627     status("    Libraries:"   HAVE_opencv_python3  THEN  "${PYTHON3_LIBRARIES} (ver ${PYTHON3LIBS_VERSION_STRING})"   ELSE NO)
1628   else()
1629     status("    Libraries:"   HAVE_opencv_python3  THEN  "${PYTHON3_LIBRARIES}"                                      ELSE NO)
1630   endif()
1631   status("    numpy:"         PYTHON3_NUMPY_INCLUDE_DIRS THEN "${PYTHON3_NUMPY_INCLUDE_DIRS} (ver ${PYTHON3_NUMPY_VERSION})" ELSE "NO (Python3 wrappers can not be generated)")
1632   status("    install path:"  HAVE_opencv_python3  THEN "${__INSTALL_PATH_PYTHON3}"                            ELSE "-")
1633 endif()
1634
1635 status("")
1636 status("  Python (for build):"  PYTHON_DEFAULT_AVAILABLE THEN "${PYTHON_DEFAULT_EXECUTABLE}" ELSE NO)
1637
1638 # ========================== java ==========================
1639 if(BUILD_JAVA)
1640   status("")
1641   status("  Java:"            BUILD_FAT_JAVA_LIB  THEN "export all functions"                                      ELSE "")
1642   status("    ant:"           ANT_EXECUTABLE      THEN "${ANT_EXECUTABLE} (ver ${ANT_VERSION})"                    ELSE NO)
1643   if(NOT ANDROID)
1644     status("    JNI:"         JNI_INCLUDE_DIRS    THEN "${JNI_INCLUDE_DIRS}"                                       ELSE NO)
1645   endif()
1646   status("    Java wrappers:" HAVE_opencv_java                                                            THEN YES ELSE NO)
1647   status("    Java tests:"    BUILD_TESTS AND opencv_test_java_BINARY_DIR                                 THEN YES ELSE NO)
1648 endif()
1649
1650 # ========================== Objective-C =======================
1651 if(BUILD_OBJC)
1652   status("")
1653   status("  Objective-C wrappers:" HAVE_opencv_objc                                                       THEN YES ELSE NO)
1654 endif()
1655
1656 ocv_cmake_hook(STATUS_DUMP_EXTRA)
1657
1658 # ========================== auxiliary ==========================
1659 status("")
1660 status("  Install to:" "${CMAKE_INSTALL_PREFIX}")
1661 status("-----------------------------------------------------------------")
1662 status("")
1663
1664
1665 ocv_finalize_status()
1666
1667 if(ENABLE_CONFIG_VERIFICATION)
1668   ocv_verify_config()
1669 endif()
1670
1671 if(HAVE_CUDA AND COMMAND CUDA_BUILD_CLEAN_TARGET)
1672   CUDA_BUILD_CLEAN_TARGET()
1673 endif()
1674
1675 ocv_cmake_hook(POST_FINALIZE)
1676
1677 # ----------------------------------------------------------------------------
1678 # CPack stuff
1679 # ----------------------------------------------------------------------------
1680
1681 include(cmake/OpenCVPackaging.cmake)
1682
1683 # This should be the last command
1684 ocv_cmake_dump_vars("" TOFILE "CMakeVars.txt")
1685 ocv_cmake_eval(DEBUG_POST ONCE)