CMakeLists.txt

   1 # increase to 3.1 once all major distributions
   2 # include a version of CMake >= 3.1
   3 cmake_minimum_required(VERSION 2.8.12)
   4 if (POLICY CMP0048)
   5   cmake_policy(SET CMP0048 NEW)
   6 endif()
   7 set_property(GLOBAL PROPERTY USE_FOLDERS ON)
   8
   9 # Enable compile commands database
  10 set(CMAKE_EXPORT_COMPILE_COMMANDS ON)
  11
  12 # Adhere to GNU filesystem layout conventions
  13 include(GNUInstallDirs)
  14
  15 # Needed for CMAKE_DEPENDENT_OPTION macro
  16 include(CMakeDependentOption)
  17
  18 option(BUILD_SHARED_LIBS "Build Shared Libraries" OFF)
  19 option(BUILD_EXTERNAL "Build external dependencies in /External" ON)
  20
  21 set(LIB_TYPE STATIC)
  22
  23 if(BUILD_SHARED_LIBS)
  24     set(LIB_TYPE SHARED)
  25 endif()
  26
  27 option(SKIP_GLSLANG_INSTALL "Skip installation" ${SKIP_GLSLANG_INSTALL})
  28 if(NOT ${SKIP_GLSLANG_INSTALL})
  29   set(ENABLE_GLSLANG_INSTALL ON)
  30 endif()
  31 option(ENABLE_SPVREMAPPER "Enables building of SPVRemapper" ON)
  32
  33 option(ENABLE_GLSLANG_BINARIES "Builds glslangValidator and spirv-remap" ON)
  34
  35 option(ENABLE_GLSLANG_JS
  36     "If using Emscripten, build glslang.js. Otherwise, builds a sample executable for binary-size testing." OFF)
  37 CMAKE_DEPENDENT_OPTION(ENABLE_GLSLANG_WEBMIN
  38     "Reduces glslang to minimum needed for web use"
  39     OFF "ENABLE_GLSLANG_JS"
  40     OFF)
  41 CMAKE_DEPENDENT_OPTION(ENABLE_GLSLANG_WEBMIN_DEVEL
  42     "For ENABLE_GLSLANG_WEBMIN builds, enables compilation error messages"
  43     OFF "ENABLE_GLSLANG_WEBMIN"
  44     OFF)
  45 CMAKE_DEPENDENT_OPTION(ENABLE_EMSCRIPTEN_SINGLE_FILE
  46     "If using Emscripten, enables SINGLE_FILE build"
  47     OFF "ENABLE_GLSLANG_JS AND EMSCRIPTEN"
  48     OFF)
  49 CMAKE_DEPENDENT_OPTION(ENABLE_EMSCRIPTEN_ENVIRONMENT_NODE
  50     "If using Emscripten, builds to run on Node instead of Web"
  51     OFF "ENABLE_GLSLANG_JS AND EMSCRIPTEN"
  52     OFF)
  53
  54 CMAKE_DEPENDENT_OPTION(ENABLE_HLSL
  55     "Enables HLSL input support"
  56     ON "NOT ENABLE_GLSLANG_WEBMIN"
  57     OFF)
  58
  59 option(ENABLE_RTTI "Enables RTTI" OFF)
  60 option(ENABLE_OPT "Enables spirv-opt capability if present" ON)
  61 option(ENABLE_PCH "Enables Precompiled header" ON)
  62 option(ENABLE_CTEST "Enables testing" ON)
  63
  64 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT AND WIN32)
  65     set(CMAKE_INSTALL_PREFIX "install" CACHE STRING "..." FORCE)
  66 endif()
  67
  68 option(USE_CCACHE "Use ccache" OFF)
  69 if(USE_CCACHE)
  70     find_program(CCACHE_FOUND ccache)
  71     if(CCACHE_FOUND)
  72         set_property(GLOBAL PROPERTY RULE_LAUNCH_COMPILE ccache)
  73     endif(CCACHE_FOUND)
  74 endif()
  75
  76 # Precompiled header macro. Parameters are source file list and filename for pch cpp file.
  77 macro(glslang_pch SRCS PCHCPP)
  78   if(MSVC AND CMAKE_GENERATOR MATCHES "^Visual Studio" AND ENABLE_PCH)
  79     set(PCH_NAME "$(IntDir)\\pch.pch")
  80     # make source files use/depend on PCH_NAME
  81     set_source_files_properties(${${SRCS}} PROPERTIES COMPILE_FLAGS "/Yupch.h /FIpch.h /Fp${PCH_NAME} /Zm300" OBJECT_DEPENDS "${PCH_NAME}")
  82     # make PCHCPP file compile and generate PCH_NAME
  83     set_source_files_properties(${PCHCPP} PROPERTIES COMPILE_FLAGS "/Ycpch.h /Fp${PCH_NAME} /Zm300" OBJECT_OUTPUTS "${PCH_NAME}")
  84     list(APPEND ${SRCS} "${PCHCPP}")
  85   endif()
  86 endmacro(glslang_pch)
  87
  88 project(glslang)
  89
  90 if(ENABLE_CTEST)
  91     include(CTest)
  92 endif()
  93
  94 if(ENABLE_HLSL)
  95     add_definitions(-DENABLE_HLSL)
  96 endif(ENABLE_HLSL)
  97
  98 if(ENABLE_GLSLANG_WEBMIN)
  99     add_definitions(-DGLSLANG_WEB)
 100     if(ENABLE_GLSLANG_WEBMIN_DEVEL)
 101         add_definitions(-DGLSLANG_WEB_DEVEL)
 102     endif(ENABLE_GLSLANG_WEBMIN_DEVEL)
 103 endif(ENABLE_GLSLANG_WEBMIN)
 104
 105 if(WIN32)
 106     set(CMAKE_DEBUG_POSTFIX "d")
 107     if(MSVC)
 108         include(ChooseMSVCCRT.cmake)
 109     endif(MSVC)
 110     add_definitions(-DGLSLANG_OSINCLUDE_WIN32)
 111 elseif(UNIX)
 112     add_definitions(-DGLSLANG_OSINCLUDE_UNIX)
 113 else(WIN32)
 114     message("unknown platform")
 115 endif(WIN32)
 116
 117 if(${CMAKE_CXX_COMPILER_ID} MATCHES "GNU")
 118     add_compile_options(-Wall -Wmaybe-uninitialized -Wuninitialized -Wunused -Wunused-local-typedefs
 119                         -Wunused-parameter -Wunused-value  -Wunused-variable -Wunused-but-set-parameter -Wunused-but-set-variable -fno-exceptions)
 120     add_compile_options(-Wno-reorder)  # disable this from -Wall, since it happens all over.
 121     if(NOT ENABLE_RTTI)
 122         add_compile_options(-fno-rtti)
 123     endif()
 124     if(NOT CMAKE_CXX_COMPILER_VERSION VERSION_LESS "9.0.0")
 125         add_compile_options(-Werror=deprecated-copy)
 126     endif()
 127 elseif(${CMAKE_CXX_COMPILER_ID} MATCHES "Clang")
 128     add_compile_options(-Wall -Wuninitialized -Wunused -Wunused-local-typedefs
 129                         -Wunused-parameter -Wunused-value  -Wunused-variable)
 130     add_compile_options(-Wno-reorder)  # disable this from -Wall, since it happens all over.
 131     if(NOT ENABLE_RTTI)
 132         add_compile_options(-fno-rtti)
 133     endif()
 134 elseif(${CMAKE_CXX_COMPILER_ID} MATCHES "MSVC")
 135     if(NOT ENABLE_RTTI)
 136         add_compile_options(/GR-) # Disable RTTI
 137     endif()
 138 endif()
 139
 140 if(ENABLE_GLSLANG_JS)
 141     if(MSVC)
 142         add_compile_options(/Os /GR-)
 143     else()
 144         add_compile_options(-Os -fno-exceptions)
 145         add_link_options(-Os)
 146     endif()
 147 endif(ENABLE_GLSLANG_JS)
 148
 149 # Request C++11
 150 if(${CMAKE_VERSION} VERSION_LESS 3.1)
 151     # CMake versions before 3.1 do not understand CMAKE_CXX_STANDARD
 152     # remove this block once CMake >=3.1 has fixated in the ecosystem
 153     add_compile_options(-std=c++11)
 154 else()
 155     set(CMAKE_CXX_STANDARD 11)
 156     set(CMAKE_CXX_STANDARD_REQUIRED ON)
 157     set(CMAKE_CXX_EXTENSIONS OFF)
 158 endif()
 159
 160 function(glslang_set_link_args TARGET)
 161     # For MinGW compiles, statically link against the GCC and C++ runtimes.
 162     # This avoids the need to ship those runtimes as DLLs.
 163     if(WIN32 AND ${CMAKE_CXX_COMPILER_ID} MATCHES "GNU")
 164         set_target_properties(${TARGET} PROPERTIES
 165                               LINK_FLAGS "-static -static-libgcc -static-libstdc++")
 166     endif()
 167 endfunction(glslang_set_link_args)
 168
 169 # CMake needs to find the right version of python, right from the beginning,
 170 # otherwise, it will find the wrong version and fail later
 171 if(BUILD_EXTERNAL AND IS_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}/External)
 172     find_package(PythonInterp 3 REQUIRED)
 173
 174         # We depend on these for later projects, so they should come first.
 175         add_subdirectory(External)
 176 endif()
 177
 178 if(NOT TARGET SPIRV-Tools-opt)
 179     set(ENABLE_OPT OFF)
 180 endif()
 181
 182 if(ENABLE_OPT)
 183     message(STATUS "optimizer enabled")
 184     add_definitions(-DENABLE_OPT=1)
 185 else()
 186     if(ENABLE_HLSL)
 187         message(STATUS "spirv-tools not linked - illegal SPIRV may be generated for HLSL")
 188     endif()
 189     add_definitions(-DENABLE_OPT=0)
 190 endif()
 191
 192 add_subdirectory(glslang)
 193 add_subdirectory(OGLCompilersDLL)
 194 if(ENABLE_GLSLANG_BINARIES)
 195     add_subdirectory(StandAlone)
 196 endif()
 197 add_subdirectory(SPIRV)
 198 if(ENABLE_HLSL)
 199     add_subdirectory(hlsl)
 200 endif(ENABLE_HLSL)
 201 if(ENABLE_CTEST)
 202     add_subdirectory(gtests)
 203 endif()
 204
 205 if(BUILD_TESTING)
 206     # glslang-testsuite runs a bash script on Windows.
 207     # Make sure to use '-o igncr' flag to ignore carriage returns (\r).
 208     set(IGNORE_CR_FLAG "")
 209     if(WIN32)
 210         set(IGNORE_CR_FLAG -o igncr)
 211     endif()
 212
 213     if (CMAKE_CONFIGURATION_TYPES)
 214         set(RESULTS_PATH ${CMAKE_CURRENT_BINARY_DIR}/$<CONFIGURATION>/localResults)
 215         set(VALIDATOR_PATH ${CMAKE_CURRENT_BINARY_DIR}/StandAlone/$<CONFIGURATION>/glslangValidator)
 216         set(REMAP_PATH ${CMAKE_CURRENT_BINARY_DIR}/StandAlone/$<CONFIGURATION>/spirv-remap)
 217     else(CMAKE_CONFIGURATION_TYPES)
 218         set(RESULTS_PATH ${CMAKE_CURRENT_BINARY_DIR}/localResults)
 219         set(VALIDATOR_PATH ${CMAKE_CURRENT_BINARY_DIR}/StandAlone/glslangValidator)
 220         set(REMAP_PATH ${CMAKE_CURRENT_BINARY_DIR}/StandAlone/spirv-remap)
 221     endif(CMAKE_CONFIGURATION_TYPES)
 222
 223     add_test(NAME glslang-testsuite
 224         COMMAND bash ${IGNORE_CR_FLAG} runtests ${RESULTS_PATH} ${VALIDATOR_PATH} ${REMAP_PATH}
 225         WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}/Test/)
 226 endif(BUILD_TESTING)