CMakeLists.txt

   1 # ----------------------------------------------------------------------------
   2 #  Root CMake file for OpenCV
   3 #
   4 #    From the off-tree build directory, invoke:
   5 #      $ cmake <PATH_TO_OPENCV_ROOT>
   6 #
   7 # ----------------------------------------------------------------------------
   8
   9 # Disable in-source builds to prevent source tree corruption.
  10 if(" ${CMAKE_SOURCE_DIR}" STREQUAL " ${CMAKE_BINARY_DIR}")
  11   message(FATAL_ERROR "
  12 FATAL: In-source builds are not allowed.
  13        You should create a separate directory for build files.
  14 ")
  15 endif()
  16
  17
  18 include(cmake/OpenCVMinDepVersions.cmake)
  19
  20 if(CMAKE_GENERATOR MATCHES Xcode AND XCODE_VERSION VERSION_GREATER 4.3)
  21   cmake_minimum_required(VERSION 3.0 FATAL_ERROR)
  22 elseif(CMAKE_SYSTEM_NAME MATCHES WindowsPhone OR CMAKE_SYSTEM_NAME MATCHES WindowsStore)
  23   cmake_minimum_required(VERSION 3.1 FATAL_ERROR)
  24   #Required to resolve linker error issues due to incompatibility with CMake v3.0+ policies.
  25   #CMake fails to find _fseeko() which leads to subsequent linker error.
  26   #See details here: http://www.cmake.org/Wiki/CMake/Policies
  27   cmake_policy(VERSION 2.8)
  28 else()
  29   cmake_minimum_required(VERSION "${MIN_VER_CMAKE}" FATAL_ERROR)
  30 endif()
  31
  32 option(ENABLE_PIC "Generate position independent code (necessary for shared libraries)" TRUE)
  33 set(CMAKE_POSITION_INDEPENDENT_CODE ${ENABLE_PIC})
  34
  35 set(OPENCV_MATHJAX_RELPATH "https://cdnjs.cloudflare.com/ajax/libs/mathjax/2.7.0" CACHE STRING "URI to a MathJax installation")
  36
  37 # Following block can break build in case of cross-compiling
  38 # but CMAKE_CROSSCOMPILING variable will be set only on project(OpenCV) command
  39 # so we will try to detect cross-compiling by the presence of CMAKE_TOOLCHAIN_FILE
  40 if(NOT DEFINED CMAKE_INSTALL_PREFIX)
  41   if(NOT CMAKE_TOOLCHAIN_FILE)
  42     # it _must_ go before project(OpenCV) in order to work
  43     if(WIN32)
  44       set(CMAKE_INSTALL_PREFIX "${CMAKE_BINARY_DIR}/install" CACHE PATH "Installation Directory")
  45     else()
  46       set(CMAKE_INSTALL_PREFIX "/usr/local" CACHE PATH "Installation Directory")
  47     endif()
  48   else()
  49     #Android: set output folder to ${CMAKE_BINARY_DIR}
  50     set(LIBRARY_OUTPUT_PATH_ROOT ${CMAKE_BINARY_DIR} CACHE PATH "root for library output, set this to change where android libs are compiled to" )
  51     # any cross-compiling
  52     set(CMAKE_INSTALL_PREFIX "${CMAKE_BINARY_DIR}/install" CACHE PATH "Installation Directory")
  53   endif()
  54 endif()
  55
  56 if(POLICY CMP0026)
  57   cmake_policy(SET CMP0026 NEW)
  58 endif()
  59
  60 if(POLICY CMP0042)
  61   cmake_policy(SET CMP0042 NEW)
  62 endif()
  63
  64 if(POLICY CMP0046)
  65   cmake_policy(SET CMP0046 NEW)
  66 endif()
  67
  68 if(POLICY CMP0051)
  69   cmake_policy(SET CMP0051 NEW)
  70 endif()
  71
  72 if(POLICY CMP0054)  # CMake 3.1: Only interpret if() arguments as variables or keywords when unquoted.
  73   cmake_policy(SET CMP0054 NEW)
  74 endif()
  75
  76 if(POLICY CMP0056)
  77   cmake_policy(SET CMP0056 NEW)
  78 endif()
  79
  80 if(POLICY CMP0067)
  81   cmake_policy(SET CMP0067 NEW)
  82 endif()
  83
  84 if(POLICY CMP0068)
  85   cmake_policy(SET CMP0068 NEW)  # CMake 3.9+: `RPATH` settings on macOS do not affect `install_name`.
  86 endif()
  87
  88 include(cmake/OpenCVUtils.cmake)
  89 ocv_cmake_reset_hooks()
  90 ocv_check_environment_variables(OPENCV_CMAKE_HOOKS_DIR)
  91 if(DEFINED OPENCV_CMAKE_HOOKS_DIR)
  92   foreach(__dir ${OPENCV_CMAKE_HOOKS_DIR})
  93     get_filename_component(__dir "${__dir}" ABSOLUTE)
  94     ocv_cmake_hook_register_dir(${__dir})
  95   endforeach()
  96 endif()
  97
  98 ocv_cmake_hook(CMAKE_INIT)
  99
 100 # must go before the project command
 101 ocv_update(CMAKE_CONFIGURATION_TYPES "Debug;Release" CACHE STRING "Configs" FORCE)
 102 if(DEFINED CMAKE_BUILD_TYPE)
 103   set_property( CACHE CMAKE_BUILD_TYPE PROPERTY STRINGS ${CMAKE_CONFIGURATION_TYPES} )
 104 endif()
 105
 106 enable_testing()
 107
 108 project(OpenCV CXX C)
 109
 110 if(CMAKE_SYSTEM_NAME MATCHES WindowsPhone OR CMAKE_SYSTEM_NAME MATCHES WindowsStore)
 111   set(WINRT TRUE)
 112 endif()
 113
 114 if(WINRT OR WINCE)
 115   add_definitions(-DNO_GETENV)
 116 endif()
 117
 118 if(WINRT)
 119   add_definitions(-DWINRT)
 120
 121   # Making definitions available to other configurations and
 122   # to filter dependency restrictions at compile time.
 123   if(CMAKE_SYSTEM_NAME MATCHES WindowsPhone)
 124     set(WINRT_PHONE TRUE)
 125     add_definitions(-DWINRT_PHONE)
 126   elseif(CMAKE_SYSTEM_NAME MATCHES WindowsStore)
 127     set(WINRT_STORE TRUE)
 128     add_definitions(-DWINRT_STORE)
 129   endif()
 130
 131   if(CMAKE_SYSTEM_VERSION MATCHES 10)
 132     set(WINRT_10 TRUE)
 133     add_definitions(-DWINRT_10)
 134   elseif(CMAKE_SYSTEM_VERSION MATCHES 8.1)
 135     set(WINRT_8_1 TRUE)
 136     add_definitions(-DWINRT_8_1)
 137   elseif(CMAKE_SYSTEM_VERSION MATCHES 8.0)
 138     set(WINRT_8_0 TRUE)
 139     add_definitions(-DWINRT_8_0)
 140   endif()
 141 endif()
 142
 143 if(MSVC)
 144   set(CMAKE_USE_RELATIVE_PATHS ON CACHE INTERNAL "" FORCE)
 145 endif()
 146
 147 ocv_cmake_eval(DEBUG_PRE ONCE)
 148
 149 ocv_clear_vars(OpenCVModules_TARGETS)
 150
 151 include(cmake/OpenCVDownload.cmake)
 152
 153 set(BUILD_LIST "" CACHE STRING "Build only listed modules (comma-separated, e.g. 'videoio,dnn,ts')")
 154
 155 # ----------------------------------------------------------------------------
 156 # Break in case of popular CMake configuration mistakes
 157 # ----------------------------------------------------------------------------
 158 if(NOT CMAKE_SIZEOF_VOID_P GREATER 0)
 159   message(FATAL_ERROR "CMake fails to determine the bitness of the target platform.
 160   Please check your CMake and compiler installation. If you are cross-compiling then ensure that your CMake toolchain file correctly sets the compiler details.")
 161 endif()
 162
 163 # ----------------------------------------------------------------------------
 164 # Detect compiler and target platform architecture
 165 # ----------------------------------------------------------------------------
 166 include(cmake/OpenCVDetectCXXCompiler.cmake)
 167 ocv_cmake_hook(POST_DETECT_COMPILER)
 168
 169 # Add these standard paths to the search paths for FIND_LIBRARY
 170 # to find libraries from these locations first
 171 if(UNIX AND NOT ANDROID)
 172   if(X86_64 OR CMAKE_SIZEOF_VOID_P EQUAL 8)
 173     if(EXISTS /lib64)
 174       list(APPEND CMAKE_LIBRARY_PATH /lib64)
 175     else()
 176       list(APPEND CMAKE_LIBRARY_PATH /lib)
 177     endif()
 178     if(EXISTS /usr/lib64)
 179       list(APPEND CMAKE_LIBRARY_PATH /usr/lib64)
 180     else()
 181       list(APPEND CMAKE_LIBRARY_PATH /usr/lib)
 182     endif()
 183   elseif(X86 OR CMAKE_SIZEOF_VOID_P EQUAL 4)
 184     if(EXISTS /lib32)
 185       list(APPEND CMAKE_LIBRARY_PATH /lib32)
 186     else()
 187       list(APPEND CMAKE_LIBRARY_PATH /lib)
 188     endif()
 189     if(EXISTS /usr/lib32)
 190       list(APPEND CMAKE_LIBRARY_PATH /usr/lib32)
 191     else()
 192       list(APPEND CMAKE_LIBRARY_PATH /usr/lib)
 193     endif()
 194   endif()
 195 endif()
 196
 197 # Add these standard paths to the search paths for FIND_PATH
 198 # to find include files from these locations first
 199 if(MINGW)
 200   if(EXISTS /mingw)
 201       list(APPEND CMAKE_INCLUDE_PATH /mingw)
 202   endif()
 203   if(EXISTS /mingw32)
 204       list(APPEND CMAKE_INCLUDE_PATH /mingw32)
 205   endif()
 206   if(EXISTS /mingw64)
 207       list(APPEND CMAKE_INCLUDE_PATH /mingw64)
 208   endif()
 209 endif()
 210
 211 # ----------------------------------------------------------------------------
 212 # OpenCV cmake options
 213 # ----------------------------------------------------------------------------
 214
 215 OCV_OPTION(OPENCV_ENABLE_NONFREE "Enable non-free algorithms" OFF)
 216
 217 # 3rd party libs
 218 OCV_OPTION(OPENCV_FORCE_3RDPARTY_BUILD   "Force using 3rdparty code from source" OFF)
 219 OCV_OPTION(BUILD_ZLIB               "Build zlib from source"             (WIN32 OR APPLE OR OPENCV_FORCE_3RDPARTY_BUILD) )
 220 OCV_OPTION(BUILD_TIFF               "Build libtiff from source"          (WIN32 OR ANDROID OR APPLE OR OPENCV_FORCE_3RDPARTY_BUILD) )
 221 OCV_OPTION(BUILD_JASPER             "Build libjasper from source"        (WIN32 OR ANDROID OR APPLE OR OPENCV_FORCE_3RDPARTY_BUILD) )
 222 OCV_OPTION(BUILD_JPEG               "Build libjpeg from source"          (WIN32 OR ANDROID OR APPLE OR OPENCV_FORCE_3RDPARTY_BUILD) )
 223 OCV_OPTION(BUILD_PNG                "Build libpng from source"           (WIN32 OR ANDROID OR APPLE OR OPENCV_FORCE_3RDPARTY_BUILD) )
 224 OCV_OPTION(BUILD_OPENEXR            "Build openexr from source"          (((WIN32 OR ANDROID OR APPLE) AND NOT WINRT) OR OPENCV_FORCE_3RDPARTY_BUILD) )
 225 OCV_OPTION(BUILD_WEBP               "Build WebP from source"             (((WIN32 OR ANDROID OR APPLE) AND NOT WINRT) OR OPENCV_FORCE_3RDPARTY_BUILD) )
 226 OCV_OPTION(BUILD_TBB                "Download and build TBB from source" (ANDROID OR OPENCV_FORCE_3RDPARTY_BUILD) )
 227 OCV_OPTION(BUILD_IPP_IW             "Build IPP IW from source"           (NOT MINGW OR OPENCV_FORCE_3RDPARTY_BUILD) IF (X86_64 OR X86) AND NOT WINRT )
 228 OCV_OPTION(BUILD_ITT                "Build Intel ITT from source"
 229     (NOT MINGW OR OPENCV_FORCE_3RDPARTY_BUILD)
 230     IF (X86_64 OR X86 OR ARM OR AARCH64 OR PPC64 OR PPC64LE) AND NOT WINRT AND NOT APPLE_FRAMEWORK
 231 )
 232
 233 # Optional 3rd party components
 234 # ===================================================
 235 OCV_OPTION(WITH_1394 "Include IEEE1394 support" ON
 236   VISIBLE_IF NOT ANDROID AND NOT IOS AND NOT WINRT
 237   VERIFY HAVE_DC1394_2)
 238 OCV_OPTION(WITH_AVFOUNDATION "Use AVFoundation for Video I/O (iOS/Mac)" ON
 239   VISIBLE_IF APPLE
 240   VERIFY HAVE_AVFOUNDATION)
 241 OCV_OPTION(WITH_CAP_IOS "Enable iOS video capture" ON
 242   VISIBLE_IF IOS
 243   VERIFY HAVE_CAP_IOS)
 244 OCV_OPTION(WITH_CAROTENE "Use NVidia carotene acceleration library for ARM platform" ON
 245   VISIBLE_IF (ARM OR AARCH64) AND NOT IOS AND NOT (CMAKE_VERSION VERSION_LESS "2.8.11"))
 246 OCV_OPTION(WITH_CPUFEATURES "Use cpufeatures Android library" ON
 247   VISIBLE_IF ANDROID
 248   VERIFY HAVE_CPUFEATURES)
 249 OCV_OPTION(WITH_VTK "Include VTK library support (and build opencv_viz module eiher)" ON
 250   VISIBLE_IF NOT ANDROID AND NOT IOS AND NOT WINRT AND NOT CMAKE_CROSSCOMPILING
 251   VERIFY HAVE_VTK)
 252 OCV_OPTION(WITH_CUDA "Include NVidia Cuda Runtime support" OFF
 253   VISIBLE_IF NOT IOS AND NOT WINRT
 254   VERIFY HAVE_CUDA)
 255 OCV_OPTION(WITH_CUFFT "Include NVidia Cuda Fast Fourier Transform (FFT) library support" WITH_CUDA
 256   VISIBLE_IF WITH_CUDA
 257   VERIFY HAVE_CUFFT)
 258 OCV_OPTION(WITH_CUBLAS "Include NVidia Cuda Basic Linear Algebra Subprograms (BLAS) library support" WITH_CUDA
 259   VISIBLE_IF WITH_CUDA
 260   VERIFY HAVE_CUBLAS)
 261 OCV_OPTION(WITH_CUDNN "Include NVIDIA CUDA Deep Neural Network (cuDNN) library support" WITH_CUDA
 262   VISIBLE_IF WITH_CUDA
 263   VERIFY HAVE_CUDNN)
 264 OCV_OPTION(WITH_NVCUVID "Include NVidia Video Decoding library support" OFF  # disabled, details: https://github.com/opencv/opencv/issues/14850
 265   VISIBLE_IF WITH_CUDA
 266   VERIFY HAVE_NVCUVID)
 267 OCV_OPTION(WITH_EIGEN "Include Eigen2/Eigen3 support" (NOT CV_DISABLE_OPTIMIZATION AND NOT CMAKE_CROSSCOMPILING)
 268   VISIBLE_IF NOT WINRT
 269   VERIFY HAVE_EIGEN)
 270 OCV_OPTION(WITH_FFMPEG "Include FFMPEG support" (NOT ANDROID)
 271   VISIBLE_IF NOT IOS AND NOT WINRT
 272   VERIFY HAVE_FFMPEG)
 273 OCV_OPTION(WITH_GSTREAMER "Include Gstreamer support" ON
 274   VISIBLE_IF NOT ANDROID AND NOT IOS AND NOT WINRT
 275   VERIFY HAVE_GSTREAMER AND GSTREAMER_VERSION VERSION_GREATER "0.99")
 276 OCV_OPTION(WITH_GTK "Include GTK support" ON
 277   VISIBLE_IF UNIX AND NOT APPLE AND NOT ANDROID
 278   VERIFY HAVE_GTK)
 279 OCV_OPTION(WITH_GTK_2_X "Use GTK version 2" OFF
 280   VISIBLE_IF UNIX AND NOT APPLE AND NOT ANDROID
 281   VERIFY HAVE_GTK AND NOT HAVE_GTK3)
 282 OCV_OPTION(WITH_IPP "Include Intel IPP support" (NOT MINGW AND NOT CV_DISABLE_OPTIMIZATION)
 283   VISIBLE_IF (X86_64 OR X86) AND NOT WINRT AND NOT IOS
 284   VERIFY HAVE_IPP)
 285 OCV_OPTION(WITH_HALIDE "Include Halide support" OFF
 286   VISIBLE_IF TRUE
 287   VERIFY HAVE_HALIDE)
 288 OCV_OPTION(WITH_VULKAN "Include Vulkan support" OFF
 289   VISIBLE_IF TRUE
 290   VERIFY HAVE_VULKAN)
 291 OCV_OPTION(WITH_INF_ENGINE "Include Intel Inference Engine support" OFF
 292   VISIBLE_IF TRUE
 293   VERIFY INF_ENGINE_TARGET)
 294 OCV_OPTION(WITH_JASPER "Include JPEG2K support" ON
 295   VISIBLE_IF NOT IOS
 296   VERIFY HAVE_JASPER)
 297 OCV_OPTION(WITH_JPEG "Include JPEG support" ON
 298   VISIBLE_IF TRUE
 299   VERIFY HAVE_JPEG)
 300 OCV_OPTION(WITH_WEBP "Include WebP support" ON
 301   VISIBLE_IF NOT WINRT
 302   VERIFY HAVE_WEBP)
 303 OCV_OPTION(WITH_OPENEXR "Include ILM support via OpenEXR" BUILD_OPENEXR OR NOT CMAKE_CROSSCOMPILING
 304   VISIBLE_IF NOT APPLE_FRAMEWORK AND NOT WINRT
 305   VERIFY HAVE_OPENEXR)
 306 OCV_OPTION(WITH_OPENGL "Include OpenGL support" OFF
 307   VISIBLE_IF NOT ANDROID AND NOT WINRT
 308   VERIFY HAVE_OPENGL)
 309 OCV_OPTION(WITH_OPENVX "Include OpenVX support" OFF
 310   VISIBLE_IF TRUE
 311   VERIFY HAVE_OPENVX)
 312 OCV_OPTION(WITH_OPENNI "Include OpenNI support" OFF
 313   VISIBLE_IF NOT ANDROID AND NOT IOS AND NOT WINRT
 314   VERIFY HAVE_OPENNI)
 315 OCV_OPTION(WITH_OPENNI2 "Include OpenNI2 support" OFF
 316   VISIBLE_IF NOT ANDROID AND NOT IOS AND NOT WINRT
 317   VERIFY HAVE_OPENNI2)
 318 OCV_OPTION(WITH_PNG "Include PNG support" ON
 319   VISIBLE_IF TRUE
 320   VERIFY HAVE_PNG)
 321 OCV_OPTION(WITH_GDCM "Include DICOM support" OFF
 322   VISIBLE_IF TRUE
 323   VERIFY HAVE_GDCM)
 324 OCV_OPTION(WITH_PVAPI "Include Prosilica GigE support" OFF
 325   VISIBLE_IF NOT ANDROID AND NOT IOS AND NOT WINRT
 326   VERIFY HAVE_PVAPI)
 327 OCV_OPTION(WITH_ARAVIS "Include Aravis GigE support" OFF
 328   VISIBLE_IF NOT ANDROID AND NOT IOS AND NOT WINRT AND NOT WIN32
 329   VERIFY HAVE_ARAVIS_API)
 330 OCV_OPTION(WITH_QT "Build with Qt Backend support" OFF
 331   VISIBLE_IF NOT ANDROID AND NOT IOS AND NOT WINRT
 332   VERIFY HAVE_QT)
 333 OCV_OPTION(WITH_WIN32UI "Build with Win32 UI Backend support" ON
 334   VISIBLE_IF WIN32 AND NOT WINRT
 335   VERIFY HAVE_WIN32UI)
 336 OCV_OPTION(WITH_TBB "Include Intel TBB support" OFF
 337   VISIBLE_IF NOT IOS AND NOT WINRT
 338   VERIFY HAVE_TBB)
 339 OCV_OPTION(WITH_HPX "Include Ste||ar Group HPX support" OFF
 340   VISIBLE_IF TRUE
 341   VERIFY HAVE_HPX)
 342 OCV_OPTION(WITH_OPENMP "Include OpenMP support" OFF
 343   VISIBLE_IF TRUE
 344   VERIFY HAVE_OPENMP)
 345 OCV_OPTION(WITH_PTHREADS_PF "Use pthreads-based parallel_for" ON
 346   VISIBLE_IF NOT WIN32 OR MINGW
 347   VERIFY HAVE_PTHREADS_PF)
 348 OCV_OPTION(WITH_TIFF "Include TIFF support" ON
 349   VISIBLE_IF NOT IOS
 350   VERIFY HAVE_TIFF)
 351 OCV_OPTION(WITH_V4L "Include Video 4 Linux support" ON
 352   VISIBLE_IF UNIX AND NOT ANDROID AND NOT APPLE
 353   VERIFY HAVE_CAMV4L OR HAVE_CAMV4L2 OR HAVE_VIDEOIO)
 354 OCV_OPTION(WITH_DSHOW "Build VideoIO with DirectShow support" ON
 355   VISIBLE_IF WIN32 AND NOT ARM AND NOT WINRT
 356   VERIFY HAVE_DSHOW)
 357 OCV_OPTION(WITH_MSMF "Build VideoIO with Media Foundation support" NOT MINGW
 358   VISIBLE_IF WIN32
 359   VERIFY HAVE_MSMF)
 360 OCV_OPTION(WITH_MSMF_DXVA "Enable hardware acceleration in Media Foundation backend" WITH_MSMF
 361   VISIBLE_IF WIN32
 362   VERIFY HAVE_MSMF_DXVA)
 363 OCV_OPTION(WITH_XIMEA "Include XIMEA cameras support" OFF
 364   VISIBLE_IF NOT ANDROID AND NOT WINRT
 365   VERIFY HAVE_XIMEA)
 366 OCV_OPTION(WITH_XINE "Include Xine support (GPL)" OFF
 367   VISIBLE_IF UNIX AND NOT APPLE AND NOT ANDROID
 368   VERIFY HAVE_XINE)
 369 OCV_OPTION(WITH_CLP "Include Clp support (EPL)" OFF
 370   VISIBLE_IF TRUE
 371   VERIFY HAVE_CLP)
 372 OCV_OPTION(WITH_OPENCL "Include OpenCL Runtime support" (NOT ANDROID AND NOT CV_DISABLE_OPTIMIZATION)
 373   VISIBLE_IF NOT IOS AND NOT WINRT
 374   VERIFY HAVE_OPENCL)
 375 OCV_OPTION(WITH_OPENCL_SVM "Include OpenCL Shared Virtual Memory support" OFF
 376   VISIBLE_IF TRUE
 377   VERIFY HAVE_OPENCL_SVM) # experimental
 378 OCV_OPTION(WITH_OPENCLAMDFFT "Include AMD OpenCL FFT library support" ON
 379   VISIBLE_IF NOT ANDROID AND NOT IOS AND NOT WINRT
 380   VERIFY HAVE_CLAMDFFT)
 381 OCV_OPTION(WITH_OPENCLAMDBLAS "Include AMD OpenCL BLAS library support" ON
 382   VISIBLE_IF NOT ANDROID AND NOT IOS AND NOT WINRT
 383   VERIFY HAVE_CLAMDBLAS)
 384 OCV_OPTION(WITH_DIRECTX "Include DirectX support" ON
 385   VISIBLE_IF WIN32 AND NOT WINRT
 386   VERIFY HAVE_DIRECTX)
 387 OCV_OPTION(WITH_OPENCL_D3D11_NV "Include NVIDIA OpenCL D3D11 support" WITH_DIRECTX
 388   VISIBLE_IF WIN32 AND NOT WINRT
 389   VERIFY HAVE_OPENCL_D3D11_NV)
 390 OCV_OPTION(WITH_LIBREALSENSE "Include Intel librealsense support" OFF
 391   VISIBLE_IF NOT WITH_INTELPERC
 392   VERIFY HAVE_LIBREALSENSE)
 393 OCV_OPTION(WITH_VA "Include VA support" OFF
 394   VISIBLE_IF UNIX AND NOT ANDROID
 395   VERIFY HAVE_VA)
 396 OCV_OPTION(WITH_VA_INTEL "Include Intel VA-API/OpenCL support" OFF
 397   VISIBLE_IF UNIX AND NOT ANDROID
 398   VERIFY HAVE_VA_INTEL)
 399 OCV_OPTION(WITH_MFX "Include Intel Media SDK support" OFF
 400   VISIBLE_IF (UNIX AND NOT ANDROID) OR (WIN32 AND NOT WINRT AND NOT MINGW)
 401   VERIFY HAVE_MFX)
 402 OCV_OPTION(WITH_GDAL "Include GDAL Support" OFF
 403   VISIBLE_IF NOT ANDROID AND NOT IOS AND NOT WINRT
 404   VERIFY HAVE_GDAL)
 405 OCV_OPTION(WITH_GPHOTO2 "Include gPhoto2 library support" OFF
 406   VISIBLE_IF UNIX AND NOT ANDROID AND NOT IOS
 407   VERIFY HAVE_GPHOTO2)
 408 OCV_OPTION(WITH_LAPACK "Include Lapack library support" (NOT CV_DISABLE_OPTIMIZATION)
 409   VISIBLE_IF NOT ANDROID AND NOT IOS
 410   VERIFY HAVE_LAPACK)
 411 OCV_OPTION(WITH_ITT "Include Intel ITT support" ON
 412   VISIBLE_IF NOT APPLE_FRAMEWORK
 413   VERIFY HAVE_ITT)
 414 OCV_OPTION(WITH_PROTOBUF "Enable libprotobuf" ON
 415   VISIBLE_IF TRUE
 416   VERIFY HAVE_PROTOBUF)
 417 OCV_OPTION(WITH_IMGCODEC_HDR "Include HDR support" ON
 418   VISIBLE_IF TRUE
 419   VERIFY HAVE_IMGCODEC_HDR)
 420 OCV_OPTION(WITH_IMGCODEC_SUNRASTER "Include SUNRASTER support" ON
 421   VISIBLE_IF TRUE
 422   VERIFY HAVE_IMGCODEC_SUNRASTER)
 423 OCV_OPTION(WITH_IMGCODEC_PXM "Include PNM (PBM,PGM,PPM) and PAM formats support" ON
 424   VISIBLE_IF TRUE
 425   VERIFY HAVE_IMGCODEC_PXM)
 426 OCV_OPTION(WITH_IMGCODEC_PFM "Include PFM formats support" ON
 427   VISIBLE_IF TRUE
 428   VERIFY HAVE_IMGCODEC_PFM)
 429 OCV_OPTION(WITH_QUIRC "Include library QR-code decoding" ON
 430   VISIBLE_IF TRUE
 431   VERIFY HAVE_QUIRC)
 432 OCV_OPTION(WITH_ANDROID_MEDIANDK "Use Android Media NDK for Video I/O (Android)" (ANDROID_NATIVE_API_LEVEL GREATER 20)
 433   VISIBLE_IF ANDROID
 434   VERIFY HAVE_ANDROID_MEDIANDK)
 435
 436 # OpenCV build components
 437 # ===================================================
 438 OCV_OPTION(BUILD_SHARED_LIBS        "Build shared libraries (.dll/.so) instead of static ones (.lib/.a)" NOT (ANDROID OR APPLE_FRAMEWORK) )
 439 OCV_OPTION(BUILD_opencv_apps        "Build utility applications (used for example to train classifiers)" (NOT ANDROID AND NOT WINRT) IF (NOT APPLE_FRAMEWORK) )
 440 OCV_OPTION(BUILD_opencv_js          "Build JavaScript bindings by Emscripten" OFF )
 441 OCV_OPTION(BUILD_ANDROID_PROJECTS   "Build Android projects providing .apk files" ON  IF ANDROID )
 442 OCV_OPTION(BUILD_ANDROID_EXAMPLES   "Build examples for Android platform"         ON  IF ANDROID )
 443 OCV_OPTION(BUILD_DOCS               "Create build rules for OpenCV Documentation" OFF  IF (NOT WINRT AND NOT APPLE_FRAMEWORK))
 444 OCV_OPTION(BUILD_EXAMPLES           "Build all examples"                          OFF )
 445 OCV_OPTION(BUILD_PACKAGE            "Enables 'make package_source' command"       ON  IF NOT WINRT)
 446 OCV_OPTION(BUILD_PERF_TESTS         "Build performance tests"                     NOT INSTALL_CREATE_DISTRIB  IF (NOT APPLE_FRAMEWORK) )
 447 OCV_OPTION(BUILD_TESTS              "Build accuracy & regression tests"           NOT INSTALL_CREATE_DISTRIB  IF (NOT APPLE_FRAMEWORK) )
 448 OCV_OPTION(BUILD_WITH_DEBUG_INFO    "Include debug info into release binaries ('OFF' means default settings)" OFF )
 449 OCV_OPTION(BUILD_WITH_STATIC_CRT    "Enables use of statically linked CRT for statically linked OpenCV" ON IF MSVC )
 450 OCV_OPTION(BUILD_WITH_DYNAMIC_IPP   "Enables dynamic linking of IPP (only for standalone IPP)" OFF )
 451 OCV_OPTION(BUILD_FAT_JAVA_LIB       "Create Java wrapper exporting all functions of OpenCV library (requires static build of OpenCV modules)" ANDROID IF NOT BUILD_SHARED_LIBS)
 452 OCV_OPTION(BUILD_ANDROID_SERVICE    "Build OpenCV Manager for Google Play" OFF IF ANDROID )
 453 OCV_OPTION(BUILD_CUDA_STUBS         "Build CUDA modules stubs when no CUDA SDK" OFF  IF (NOT APPLE_FRAMEWORK) )
 454 OCV_OPTION(BUILD_JAVA               "Enable Java support"                         (ANDROID OR NOT CMAKE_CROSSCOMPILING)  IF (ANDROID OR (NOT APPLE_FRAMEWORK AND NOT WINRT)) )
 455
 456 # OpenCV installation options
 457 # ===================================================
 458 OCV_OPTION(INSTALL_CREATE_DISTRIB   "Change install rules to build the distribution package" OFF )
 459 OCV_OPTION(INSTALL_C_EXAMPLES       "Install C examples"        OFF )
 460 OCV_OPTION(INSTALL_PYTHON_EXAMPLES  "Install Python examples"   OFF )
 461 OCV_OPTION(INSTALL_ANDROID_EXAMPLES "Install Android examples"  OFF IF ANDROID )
 462 OCV_OPTION(INSTALL_TO_MANGLED_PATHS "Enables mangled install paths, that help with side by side installs." OFF IF (UNIX AND NOT ANDROID AND NOT APPLE_FRAMEWORK AND BUILD_SHARED_LIBS) )
 463 OCV_OPTION(INSTALL_TESTS            "Install accuracy and performance test binaries and test data" OFF)
 464
 465 # OpenCV build options
 466 # ===================================================
 467 OCV_OPTION(ENABLE_CCACHE              "Use ccache"                                               (UNIX AND NOT IOS AND (CMAKE_GENERATOR MATCHES "Makefile" OR CMAKE_GENERATOR MATCHES "Ninja")) )
 468 OCV_OPTION(ENABLE_PRECOMPILED_HEADERS "Use precompiled headers"                                  ON IF (MSVC OR (NOT IOS AND NOT CMAKE_CROSSCOMPILING) ) )
 469 OCV_OPTION(ENABLE_SOLUTION_FOLDERS    "Solution folder in Visual Studio or in other IDEs"        (MSVC_IDE OR CMAKE_GENERATOR MATCHES Xcode) )
 470 OCV_OPTION(ENABLE_PROFILING           "Enable profiling in the GCC compiler (Add flags: -g -pg)" OFF  IF CV_GCC )
 471 OCV_OPTION(ENABLE_COVERAGE            "Enable coverage collection with  GCov"                    OFF  IF CV_GCC )
 472 OCV_OPTION(OPENCV_ENABLE_MEMORY_SANITIZER "Better support for memory/address sanitizers"         OFF)
 473 OCV_OPTION(ENABLE_OMIT_FRAME_POINTER  "Enable -fomit-frame-pointer for GCC"                      ON   IF CV_GCC )
 474 OCV_OPTION(ENABLE_POWERPC             "Enable PowerPC for GCC"                                   ON   IF (CV_GCC AND CMAKE_SYSTEM_PROCESSOR MATCHES powerpc.*) )
 475 OCV_OPTION(ENABLE_FAST_MATH           "Enable compiler options for fast math optimizations on FP computations (not recommended)" OFF)
 476 if(NOT IOS AND (NOT ANDROID OR OPENCV_ANDROID_USE_LEGACY_FLAGS))  # Use CPU_BASELINE instead
 477 OCV_OPTION(ENABLE_NEON                "Enable NEON instructions"                                 (NEON OR ANDROID_ARM_NEON OR AARCH64) IF (CV_GCC OR CV_CLANG) AND (ARM OR AARCH64 OR IOS) )
 478 OCV_OPTION(ENABLE_VFPV3               "Enable VFPv3-D32 instructions"                            OFF  IF (CV_GCC OR CV_CLANG) AND (ARM OR AARCH64 OR IOS) )
 479 endif()
 480 OCV_OPTION(ENABLE_NOISY_WARNINGS      "Show all warnings even if they are too noisy"             OFF )
 481 OCV_OPTION(OPENCV_WARNINGS_ARE_ERRORS "Treat warnings as errors"                                 OFF )
 482 OCV_OPTION(ANDROID_EXAMPLES_WITH_LIBS "Build binaries of Android examples with native libraries" OFF  IF ANDROID )
 483 OCV_OPTION(ENABLE_IMPL_COLLECTION     "Collect implementation data on function call"             OFF )
 484 OCV_OPTION(ENABLE_INSTRUMENTATION     "Instrument functions to collect calls trace and performance" OFF )
 485 OCV_OPTION(ENABLE_GNU_STL_DEBUG       "Enable GNU STL Debug mode (defines _GLIBCXX_DEBUG)"       OFF IF ((NOT CMAKE_VERSION VERSION_LESS "2.8.11") AND CV_GCC) )
 486 OCV_OPTION(ENABLE_BUILD_HARDENING     "Enable hardening of the resulting binaries (against security attacks, detects memory corruption, etc)" OFF)
 487 OCV_OPTION(ENABLE_LTO                 "Enable Link Time Optimization" OFF IF CV_GCC OR MSVC)
 488 OCV_OPTION(ENABLE_THIN_LTO            "Enable Thin LTO" OFF IF CV_CLANG)
 489 OCV_OPTION(GENERATE_ABI_DESCRIPTOR    "Generate XML file for abi_compliance_checker tool" OFF IF UNIX)
 490 OCV_OPTION(OPENCV_GENERATE_PKGCONFIG  "Generate .pc file for pkg-config build tool (deprecated)" OFF)
 491 OCV_OPTION(CV_ENABLE_INTRINSICS       "Use intrinsic-based optimized code" ON )
 492 OCV_OPTION(CV_DISABLE_OPTIMIZATION    "Disable explicit optimized code (dispatched code/intrinsics/loop unrolling/etc)" OFF )
 493 OCV_OPTION(CV_TRACE                   "Enable OpenCV code trace" ON)
 494 OCV_OPTION(OPENCV_GENERATE_SETUPVARS  "Generate setup_vars* scripts" ON IF (NOT ANDROID AND NOT APPLE_FRAMEWORK) )
 495 OCV_OPTION(ENABLE_CONFIG_VERIFICATION "Fail build if actual configuration doesn't match requested (WITH_XXX != HAVE_XXX)" OFF)
 496
 497 OCV_OPTION(ENABLE_PYLINT              "Add target with Pylint checks"                            (BUILD_DOCS OR BUILD_EXAMPLES) IF (NOT CMAKE_CROSSCOMPILING AND NOT APPLE_FRAMEWORK) )
 498 OCV_OPTION(ENABLE_FLAKE8              "Add target with Python flake8 checker"                    (BUILD_DOCS OR BUILD_EXAMPLES) IF (NOT CMAKE_CROSSCOMPILING AND NOT APPLE_FRAMEWORK) )
 499
 500 if(ENABLE_IMPL_COLLECTION)
 501   add_definitions(-DCV_COLLECT_IMPL_DATA)
 502 endif()
 503
 504
 505 # ----------------------------------------------------------------------------
 506 #  Get actual OpenCV version number from sources
 507 # ----------------------------------------------------------------------------
 508 include(cmake/OpenCVVersion.cmake)
 509
 510 ocv_cmake_hook(POST_OPTIONS)
 511
 512 # ----------------------------------------------------------------------------
 513 #  Build & install layouts
 514 # ----------------------------------------------------------------------------
 515
 516 # Save libs and executables in the same place
 517 set(EXECUTABLE_OUTPUT_PATH "${CMAKE_BINARY_DIR}/bin" CACHE PATH "Output directory for applications")
 518
 519 if(ANDROID)
 520   if(ANDROID_ABI MATCHES "NEON")
 521     set(ENABLE_NEON ON)
 522   endif()
 523   if(ANDROID_ABI MATCHES "VFPV3")
 524     set(ENABLE_VFPV3 ON)
 525   endif()
 526 endif()
 527
 528 if(ANDROID OR WIN32)
 529   ocv_update(OPENCV_DOC_INSTALL_PATH doc)
 530 endif()
 531
 532 if(WIN32 AND CMAKE_HOST_SYSTEM_NAME MATCHES Windows)
 533   if(DEFINED OpenCV_RUNTIME AND DEFINED OpenCV_ARCH)
 534     ocv_update(OpenCV_INSTALL_BINARIES_PREFIX "${OpenCV_ARCH}/${OpenCV_RUNTIME}/")
 535   else()
 536     message(STATUS "Can't detect runtime and/or arch")
 537     ocv_update(OpenCV_INSTALL_BINARIES_PREFIX "")
 538   endif()
 539 elseif(ANDROID)
 540   ocv_update(OpenCV_INSTALL_BINARIES_PREFIX "sdk/native/")
 541 else()
 542   ocv_update(OpenCV_INSTALL_BINARIES_PREFIX "")
 543 endif()
 544
 545 if(ANDROID)
 546   ocv_update(OPENCV_SAMPLES_BIN_INSTALL_PATH "${OpenCV_INSTALL_BINARIES_PREFIX}samples/${ANDROID_NDK_ABI_NAME}")
 547 else()
 548   ocv_update(OPENCV_SAMPLES_BIN_INSTALL_PATH "${OpenCV_INSTALL_BINARIES_PREFIX}samples")
 549 endif()
 550
 551 if(ANDROID)
 552   ocv_update(OPENCV_BIN_INSTALL_PATH "${OpenCV_INSTALL_BINARIES_PREFIX}bin/${ANDROID_NDK_ABI_NAME}")
 553 else()
 554   ocv_update(OPENCV_BIN_INSTALL_PATH "${OpenCV_INSTALL_BINARIES_PREFIX}bin")
 555 endif()
 556
 557 if(NOT OPENCV_TEST_INSTALL_PATH)
 558   ocv_update(OPENCV_TEST_INSTALL_PATH "${OPENCV_BIN_INSTALL_PATH}")
 559 endif()
 560
 561 if (OPENCV_TEST_DATA_PATH)
 562   get_filename_component(OPENCV_TEST_DATA_PATH ${OPENCV_TEST_DATA_PATH} ABSOLUTE)
 563 endif()
 564
 565 if(ANDROID)
 566   ocv_update(OPENCV_TEST_DATA_INSTALL_PATH "sdk/etc/testdata")
 567 elseif(WIN32)
 568   ocv_update(OPENCV_TEST_DATA_INSTALL_PATH "testdata")
 569 endif()
 570
 571 if(ANDROID)
 572   set(LIBRARY_OUTPUT_PATH                "${OpenCV_BINARY_DIR}/lib/${ANDROID_NDK_ABI_NAME}")
 573   ocv_update(3P_LIBRARY_OUTPUT_PATH      "${OpenCV_BINARY_DIR}/3rdparty/lib/${ANDROID_NDK_ABI_NAME}")
 574   ocv_update(OPENCV_LIB_INSTALL_PATH     sdk/native/libs/${ANDROID_NDK_ABI_NAME})
 575   ocv_update(OPENCV_LIB_ARCHIVE_INSTALL_PATH sdk/native/staticlibs/${ANDROID_NDK_ABI_NAME})
 576   ocv_update(OPENCV_3P_LIB_INSTALL_PATH  sdk/native/3rdparty/libs/${ANDROID_NDK_ABI_NAME})
 577   ocv_update(OPENCV_CONFIG_INSTALL_PATH  sdk/native/jni)
 578   ocv_update(OPENCV_INCLUDE_INSTALL_PATH sdk/native/jni/include)
 579   ocv_update(OPENCV_SAMPLES_SRC_INSTALL_PATH samples/native)
 580   ocv_update(OPENCV_OTHER_INSTALL_PATH   sdk/etc)
 581   ocv_update(OPENCV_LICENSES_INSTALL_PATH "${OPENCV_OTHER_INSTALL_PATH}/licenses")
 582 else()
 583   set(LIBRARY_OUTPUT_PATH                "${OpenCV_BINARY_DIR}/lib")
 584   ocv_update(3P_LIBRARY_OUTPUT_PATH      "${OpenCV_BINARY_DIR}/3rdparty/lib${LIB_SUFFIX}")
 585
 586   if(WIN32 AND CMAKE_HOST_SYSTEM_NAME MATCHES Windows)
 587     if(OpenCV_STATIC)
 588       ocv_update(OPENCV_LIB_INSTALL_PATH   "${OpenCV_INSTALL_BINARIES_PREFIX}staticlib${LIB_SUFFIX}")
 589     else()
 590       ocv_update(OPENCV_LIB_INSTALL_PATH   "${OpenCV_INSTALL_BINARIES_PREFIX}lib${LIB_SUFFIX}")
 591     endif()
 592     ocv_update(OPENCV_3P_LIB_INSTALL_PATH  "${OpenCV_INSTALL_BINARIES_PREFIX}staticlib${LIB_SUFFIX}")
 593     ocv_update(OPENCV_SAMPLES_SRC_INSTALL_PATH    samples)
 594     ocv_update(OPENCV_JAR_INSTALL_PATH java)
 595     ocv_update(OPENCV_OTHER_INSTALL_PATH   etc)
 596     ocv_update(OPENCV_CONFIG_INSTALL_PATH  ".")
 597     ocv_update(OPENCV_INCLUDE_INSTALL_PATH "include")
 598     ocv_update(OPENCV_LICENSES_INSTALL_PATH "${OPENCV_OTHER_INSTALL_PATH}/licenses")
 599   else()
 600     # Note: layout differs from OpenCV 3.4
 601     include(GNUInstallDirs)
 602     ocv_update(OPENCV_INCLUDE_INSTALL_PATH       "${CMAKE_INSTALL_INCLUDEDIR}/opencv4")
 603     ocv_update(OPENCV_LIB_INSTALL_PATH           "${CMAKE_INSTALL_LIBDIR}")
 604     ocv_update(OPENCV_CONFIG_INSTALL_PATH        "${OPENCV_LIB_INSTALL_PATH}/cmake/opencv4")
 605     ocv_update(OPENCV_3P_LIB_INSTALL_PATH        "${OPENCV_LIB_INSTALL_PATH}/opencv4/3rdparty")
 606     ocv_update(OPENCV_SAMPLES_SRC_INSTALL_PATH   "${CMAKE_INSTALL_DATAROOTDIR}/opencv4/samples")
 607     ocv_update(OPENCV_DOC_INSTALL_PATH           "${CMAKE_INSTALL_DATAROOTDIR}/doc/opencv4")
 608     ocv_update(OPENCV_JAR_INSTALL_PATH           "${CMAKE_INSTALL_DATAROOTDIR}/java/opencv4")
 609     ocv_update(OPENCV_TEST_DATA_INSTALL_PATH     "${CMAKE_INSTALL_DATAROOTDIR}/opencv4/testdata")
 610     ocv_update(OPENCV_OTHER_INSTALL_PATH         "${CMAKE_INSTALL_DATAROOTDIR}/opencv4")
 611     ocv_update(OPENCV_LICENSES_INSTALL_PATH      "${CMAKE_INSTALL_DATAROOTDIR}/licenses/opencv4")
 612   endif()
 613   #ocv_update(OPENCV_PYTHON_INSTALL_PATH  "python")  # no default value, see https://github.com/opencv/opencv/issues/13202
 614 endif()
 615
 616 ocv_update(CMAKE_INSTALL_RPATH "${CMAKE_INSTALL_PREFIX}/${OPENCV_LIB_INSTALL_PATH}")
 617 set(CMAKE_INSTALL_RPATH_USE_LINK_PATH TRUE)
 618
 619 if(INSTALL_TO_MANGLED_PATHS)
 620   foreach(v
 621       OPENCV_INCLUDE_INSTALL_PATH
 622       # file names include version (.so/.dll): OPENCV_LIB_INSTALL_PATH
 623       OPENCV_CONFIG_INSTALL_PATH
 624       OPENCV_3P_LIB_INSTALL_PATH
 625       OPENCV_SAMPLES_SRC_INSTALL_PATH
 626       OPENCV_DOC_INSTALL_PATH
 627       # JAR file name includes version: OPENCV_JAR_INSTALL_PATH
 628       OPENCV_TEST_DATA_INSTALL_PATH
 629       OPENCV_OTHER_INSTALL_PATH
 630     )
 631     string(REGEX REPLACE "opencv[0-9]*" "opencv-${OPENCV_VERSION}" ${v} "${${v}}")
 632   endforeach()
 633 endif()
 634
 635 if(ANDROID)
 636   ocv_update(OPENCV_JNI_INSTALL_PATH "${OPENCV_LIB_INSTALL_PATH}")
 637 elseif(INSTALL_CREATE_DISTRIB)
 638   ocv_update(OPENCV_JNI_INSTALL_PATH "${OPENCV_JAR_INSTALL_PATH}/${OpenCV_ARCH}")
 639 else()
 640   ocv_update(OPENCV_JNI_INSTALL_PATH "${OPENCV_JAR_INSTALL_PATH}")
 641 endif()
 642 ocv_update(OPENCV_JNI_BIN_INSTALL_PATH "${OPENCV_JNI_INSTALL_PATH}")
 643
 644 if(NOT OPENCV_LIB_ARCHIVE_INSTALL_PATH)
 645   set(OPENCV_LIB_ARCHIVE_INSTALL_PATH ${OPENCV_LIB_INSTALL_PATH})
 646 endif()
 647
 648 if(WIN32)
 649   # Postfix of DLLs:
 650   set(OPENCV_DLLVERSION "${OPENCV_VERSION_MAJOR}${OPENCV_VERSION_MINOR}${OPENCV_VERSION_PATCH}")
 651   set(OPENCV_DEBUG_POSTFIX d)
 652 else()
 653   # Postfix of so's:
 654   set(OPENCV_DLLVERSION "")
 655   set(OPENCV_DEBUG_POSTFIX "")
 656 endif()
 657
 658 if(DEFINED CMAKE_DEBUG_POSTFIX)
 659   set(OPENCV_DEBUG_POSTFIX "${CMAKE_DEBUG_POSTFIX}")
 660 endif()
 661
 662 if((INSTALL_CREATE_DISTRIB AND BUILD_SHARED_LIBS AND NOT DEFINED BUILD_opencv_world) OR APPLE_FRAMEWORK)
 663   set(BUILD_opencv_world ON CACHE INTERNAL "")
 664 endif()
 665
 666 # ----------------------------------------------------------------------------
 667 #  Path for build/platform -specific headers
 668 # ----------------------------------------------------------------------------
 669 ocv_update(OPENCV_CONFIG_FILE_INCLUDE_DIR "${CMAKE_BINARY_DIR}/" CACHE PATH "Where to create the platform-dependant cvconfig.h")
 670 ocv_include_directories(${OPENCV_CONFIG_FILE_INCLUDE_DIR})
 671
 672 # ----------------------------------------------------------------------------
 673 #  Path for additional modules
 674 # ----------------------------------------------------------------------------
 675 set(OPENCV_EXTRA_MODULES_PATH "" CACHE PATH "Where to look for additional OpenCV modules (can be ;-separated list of paths)")
 676
 677 # ----------------------------------------------------------------------------
 678 #  Autodetect if we are in a GIT repository
 679 # ----------------------------------------------------------------------------
 680 find_host_package(Git QUIET)
 681
 682 if(NOT DEFINED OPENCV_VCSVERSION AND GIT_FOUND)
 683   ocv_git_describe(OPENCV_VCSVERSION "${OpenCV_SOURCE_DIR}")
 684 elseif(NOT DEFINED OPENCV_VCSVERSION)
 685   # We don't have git:
 686   set(OPENCV_VCSVERSION "unknown")
 687 endif()
 688
 689
 690 # ----------------------------------------------------------------------------
 691 # OpenCV compiler and linker options
 692 # ----------------------------------------------------------------------------
 693 # In case of Makefiles if the user does not setup CMAKE_BUILD_TYPE, assume it's Release:
 694 if(CMAKE_GENERATOR MATCHES "Makefiles|Ninja" AND "${CMAKE_BUILD_TYPE}" STREQUAL "")
 695   set(CMAKE_BUILD_TYPE Release)
 696 endif()
 697
 698 ocv_cmake_hook(POST_CMAKE_BUILD_OPTIONS)
 699
 700 # --- Python Support ---
 701 if(NOT IOS)
 702   include(cmake/OpenCVDetectPython.cmake)
 703 endif()
 704
 705 include(cmake/OpenCVCompilerOptions.cmake)
 706
 707 ocv_cmake_hook(POST_COMPILER_OPTIONS)
 708
 709 # ----------------------------------------------------------------------------
 710 #       CHECK FOR SYSTEM LIBRARIES, OPTIONS, ETC..
 711 # ----------------------------------------------------------------------------
 712 if(UNIX)
 713   if(NOT APPLE_FRAMEWORK OR OPENCV_ENABLE_PKG_CONFIG)
 714     if(CMAKE_CROSSCOMPILING AND NOT DEFINED ENV{PKG_CONFIG_LIBDIR} AND NOT DEFINED ENV{PKG_CONFIG_SYSROOT_DIR}
 715         AND NOT OPENCV_ENABLE_PKG_CONFIG
 716     )
 717       if(NOT PkgConfig_FOUND)
 718         message(STATUS "OpenCV disables pkg-config to avoid using of host libraries. Consider using PKG_CONFIG_LIBDIR to specify target SYSROOT")
 719       elseif(OPENCV_SKIP_PKG_CONFIG_WARNING)
 720         message(WARNING "pkg-config is enabled in cross-compilation mode without defining of PKG_CONFIG_LIBDIR environment variable. This may lead to misconfigured host-based dependencies.")
 721       endif()
 722     elseif(OPENCV_DISABLE_PKG_CONFIG)
 723       if(PkgConfig_FOUND)
 724         message(WARNING "OPENCV_DISABLE_PKG_CONFIG flag has no effect")
 725       endif()
 726     else()
 727       find_package(PkgConfig QUIET)
 728     endif()
 729   endif()
 730   include(CheckFunctionExists)
 731   include(CheckIncludeFile)
 732   include(CheckSymbolExists)
 733
 734   if(NOT APPLE)
 735     CHECK_INCLUDE_FILE(pthread.h HAVE_PTHREAD)
 736     if(ANDROID)
 737       set(OPENCV_LINKER_LIBS ${OPENCV_LINKER_LIBS} dl m log)
 738     elseif(CMAKE_SYSTEM_NAME MATCHES "FreeBSD|NetBSD|DragonFly|OpenBSD|Haiku")
 739       set(OPENCV_LINKER_LIBS ${OPENCV_LINKER_LIBS} m pthread)
 740     elseif(EMSCRIPTEN)
 741       # no need to link to system libs with emscripten
 742     else()
 743       set(OPENCV_LINKER_LIBS ${OPENCV_LINKER_LIBS} dl m pthread rt)
 744     endif()
 745   else()
 746     set(HAVE_PTHREAD 1)
 747   endif()
 748
 749   CHECK_SYMBOL_EXISTS(posix_memalign stdlib.h HAVE_POSIX_MEMALIGN)
 750   CHECK_INCLUDE_FILE(malloc.h HAVE_MALLOC_H)
 751   if(HAVE_MALLOC_H)
 752     CHECK_SYMBOL_EXISTS(memalign malloc.h HAVE_MEMALIGN)
 753   endif()
 754 endif()
 755
 756 include(cmake/OpenCVPCHSupport.cmake)
 757 include(cmake/OpenCVModule.cmake)
 758
 759 # ----------------------------------------------------------------------------
 760 #  Detect endianness of build platform
 761 # ----------------------------------------------------------------------------
 762
 763 if(IOS)
 764   # test_big_endian needs try_compile, which doesn't work for iOS
 765   # http://public.kitware.com/Bug/view.php?id=12288
 766   set(WORDS_BIGENDIAN 0)
 767 else()
 768   include(TestBigEndian)
 769   test_big_endian(WORDS_BIGENDIAN)
 770 endif()
 771
 772 # ----------------------------------------------------------------------------
 773 #  Detect 3rd-party libraries
 774 # ----------------------------------------------------------------------------
 775
 776 if(ANDROID AND WITH_CPUFEATURES)
 777   add_subdirectory(3rdparty/cpufeatures)
 778   set(HAVE_CPUFEATURES 1)
 779 endif()
 780
 781 include(cmake/OpenCVFindFrameworks.cmake)
 782
 783 include(cmake/OpenCVFindLibsGrfmt.cmake)
 784 include(cmake/OpenCVFindLibsGUI.cmake)
 785 include(cmake/OpenCVFindLibsVideo.cmake)
 786 include(cmake/OpenCVFindLibsPerf.cmake)
 787 include(cmake/OpenCVFindLAPACK.cmake)
 788 include(cmake/OpenCVFindProtobuf.cmake)
 789
 790 # ----------------------------------------------------------------------------
 791 #  Detect other 3rd-party libraries/tools
 792 # ----------------------------------------------------------------------------
 793
 794 # --- Java Support ---
 795 if(BUILD_JAVA)
 796   if(ANDROID)
 797     include(cmake/android/OpenCVDetectAndroidSDK.cmake)
 798   else()
 799     include(cmake/OpenCVDetectApacheAnt.cmake)
 800     find_package(JNI)
 801   endif()
 802 endif()
 803
 804 if(ENABLE_PYLINT AND PYTHON_DEFAULT_AVAILABLE)
 805   include(cmake/OpenCVPylint.cmake)
 806 endif()
 807 if(ENABLE_FLAKE8 AND PYTHON_DEFAULT_AVAILABLE)
 808   find_package(Flake8 QUIET)
 809   if(NOT FLAKE8_FOUND OR NOT FLAKE8_EXECUTABLE)
 810     include("${CMAKE_CURRENT_LIST_DIR}/cmake/FindFlake8.cmake")
 811   endif()
 812   if(FLAKE8_FOUND)
 813     add_custom_target(check_flake8
 814         COMMAND "${FLAKE8_EXECUTABLE}" . --count --select=E9,E901,E999,F821,F822,F823 --show-source --statistics --exclude='.git,__pycache__,*.config.py,svgfig.py'
 815         WORKING_DIRECTORY "${OpenCV_SOURCE_DIR}"
 816         COMMENT "Running flake8"
 817     )
 818   endif()
 819 endif()
 820
 821
 822 if(ANDROID AND ANDROID_EXECUTABLE AND ANT_EXECUTABLE AND (ANT_VERSION VERSION_GREATER 1.7) AND (ANDROID_TOOLS_Pkg_Revision GREATER 13))
 823   SET(CAN_BUILD_ANDROID_PROJECTS TRUE)
 824 else()
 825   SET(CAN_BUILD_ANDROID_PROJECTS FALSE)
 826 endif()
 827
 828 # --- OpenCL ---
 829 if(WITH_OPENCL)
 830   include(cmake/OpenCVDetectOpenCL.cmake)
 831 endif()
 832
 833 # --- Halide ---
 834 if(WITH_HALIDE)
 835   include(cmake/OpenCVDetectHalide.cmake)
 836 endif()
 837
 838 # --- VkCom ---
 839 if(WITH_VULKAN)
 840   include(cmake/OpenCVDetectVulkan.cmake)
 841 endif()
 842
 843 # --- Inference Engine ---
 844 if(WITH_INF_ENGINE)
 845   include(cmake/OpenCVDetectInferenceEngine.cmake)
 846 endif()
 847
 848 # --- DirectX ---
 849 if(WITH_DIRECTX)
 850   include(cmake/OpenCVDetectDirectX.cmake)
 851 endif()
 852
 853 if(WITH_VTK)
 854   include(cmake/OpenCVDetectVTK.cmake)
 855 endif()
 856
 857 if(WITH_OPENVX)
 858   include(cmake/FindOpenVX.cmake)
 859 endif()
 860
 861 if(WITH_QUIRC)
 862   add_subdirectory(3rdparty/quirc)
 863   set(HAVE_QUIRC TRUE)
 864 endif()
 865 # ----------------------------------------------------------------------------
 866 # OpenCV HAL
 867 # ----------------------------------------------------------------------------
 868 set(_hal_includes "")
 869 macro(ocv_hal_register HAL_LIBRARIES_VAR HAL_HEADERS_VAR HAL_INCLUDE_DIRS_VAR)
 870   # 1. libraries
 871   foreach (l ${${HAL_LIBRARIES_VAR}})
 872     if(NOT TARGET ${l})
 873       get_filename_component(l "${l}" ABSOLUTE)
 874     endif()
 875     list(APPEND OPENCV_HAL_LINKER_LIBS ${l})
 876   endforeach()
 877   # 2. headers
 878   foreach (h ${${HAL_HEADERS_VAR}})
 879     set(_hal_includes "${_hal_includes}\n#include \"${h}\"")
 880   endforeach()
 881   # 3. include paths
 882   ocv_include_directories(${${HAL_INCLUDE_DIRS_VAR}})
 883 endmacro()
 884
 885 if(NOT DEFINED OpenCV_HAL)
 886   set(OpenCV_HAL "OpenCV_HAL")
 887 endif()
 888
 889 if(HAVE_OPENVX)
 890   if(NOT ";${OpenCV_HAL};" MATCHES ";openvx;")
 891     set(OpenCV_HAL "openvx;${OpenCV_HAL}")
 892   endif()
 893 endif()
 894
 895 if(WITH_CAROTENE)
 896   ocv_debug_message(STATUS "Enable carotene acceleration")
 897   if(NOT ";${OpenCV_HAL};" MATCHES ";carotene;")
 898     set(OpenCV_HAL "carotene;${OpenCV_HAL}")
 899   endif()
 900 endif()
 901
 902 foreach(hal ${OpenCV_HAL})
 903   if(hal STREQUAL "carotene")
 904     add_subdirectory(3rdparty/carotene/hal)
 905     ocv_hal_register(CAROTENE_HAL_LIBRARIES CAROTENE_HAL_HEADERS CAROTENE_HAL_INCLUDE_DIRS)
 906     list(APPEND OpenCV_USED_HAL "carotene (ver ${CAROTENE_HAL_VERSION})")
 907   elseif(hal STREQUAL "openvx")
 908     add_subdirectory(3rdparty/openvx)
 909     ocv_hal_register(OPENVX_HAL_LIBRARIES OPENVX_HAL_HEADERS OPENVX_HAL_INCLUDE_DIRS)
 910     list(APPEND OpenCV_USED_HAL "openvx (ver ${OPENVX_HAL_VERSION})")
 911   else()
 912     ocv_debug_message(STATUS "OpenCV HAL: ${hal} ...")
 913     ocv_clear_vars(OpenCV_HAL_LIBRARIES OpenCV_HAL_HEADERS OpenCV_HAL_INCLUDE_DIRS)
 914     find_package(${hal} NO_MODULE QUIET)
 915     if(${hal}_FOUND)
 916       ocv_hal_register(OpenCV_HAL_LIBRARIES OpenCV_HAL_HEADERS OpenCV_HAL_INCLUDE_DIRS)
 917       list(APPEND OpenCV_USED_HAL "${hal} (ver ${${hal}_VERSION})")
 918     endif()
 919   endif()
 920 endforeach()
 921 configure_file("${OpenCV_SOURCE_DIR}/cmake/templates/custom_hal.hpp.in" "${CMAKE_BINARY_DIR}/custom_hal.hpp" @ONLY)
 922 unset(_hal_includes)
 923
 924
 925 # ----------------------------------------------------------------------------
 926 # Code trace support
 927 # ----------------------------------------------------------------------------
 928 if(CV_TRACE)
 929   include(cmake/OpenCVDetectTrace.cmake)
 930 endif()
 931
 932 ocv_cmake_hook(POST_DETECT_DEPENDECIES)  # typo, deprecated (2019-06)
 933 ocv_cmake_hook(POST_DETECT_DEPENDENCIES)
 934
 935 # ----------------------------------------------------------------------------
 936 # Solution folders:
 937 # ----------------------------------------------------------------------------
 938 if(ENABLE_SOLUTION_FOLDERS)
 939   set_property(GLOBAL PROPERTY USE_FOLDERS ON)
 940   set_property(GLOBAL PROPERTY PREDEFINED_TARGETS_FOLDER "CMakeTargets")
 941 endif()
 942
 943 # Extra OpenCV targets: uninstall, package_source, perf, etc.
 944 include(cmake/OpenCVExtraTargets.cmake)
 945
 946 # ----------------------------------------------------------------------------
 947 # Process subdirectories
 948 # ----------------------------------------------------------------------------
 949
 950 # opencv.hpp and legacy headers
 951 add_subdirectory(include)
 952
 953 # Enable compiler options for OpenCV modules/apps/samples only (ignore 3rdparty)
 954 ocv_add_modules_compiler_options()
 955
 956 # OpenCV modules
 957 add_subdirectory(modules)
 958
 959 # Generate targets for documentation
 960 add_subdirectory(doc)
 961
 962 # various data that is used by cv libraries and/or demo applications.
 963 add_subdirectory(data)
 964
 965 # extra applications
 966 if(BUILD_opencv_apps)
 967   add_subdirectory(apps)
 968 endif()
 969
 970 # examples
 971 if(BUILD_EXAMPLES OR BUILD_ANDROID_EXAMPLES OR INSTALL_ANDROID_EXAMPLES OR INSTALL_PYTHON_EXAMPLES OR INSTALL_C_EXAMPLES)
 972   add_subdirectory(samples)
 973 endif()
 974
 975 if(ANDROID)
 976   add_subdirectory(platforms/android/service)
 977 endif()
 978
 979 # ----------------------------------------------------------------------------
 980 # Finalization: generate configuration-based files
 981 # ----------------------------------------------------------------------------
 982
 983 ocv_cmake_hook(PRE_FINALIZE)
 984
 985 # Generate platform-dependent and configuration-dependent headers
 986 include(cmake/OpenCVGenHeaders.cmake)
 987
 988 # Generate opencv.pc for pkg-config command
 989 if(OPENCV_GENERATE_PKGCONFIG)
 990   include(cmake/OpenCVGenPkgconfig.cmake)
 991 endif()
 992
 993 # Generate OpenCV.mk for ndk-build (Android build tool)
 994 include(cmake/OpenCVGenAndroidMK.cmake)
 995
 996 # Generate OpenCVConfig.cmake and OpenCVConfig-version.cmake for cmake projects
 997 include(cmake/OpenCVGenConfig.cmake)
 998
 999 # Generate Info.plist for the IOS framework
1000 if(APPLE_FRAMEWORK)
1001   include(cmake/OpenCVGenInfoPlist.cmake)
1002 endif()
1003
1004 # Generate ABI descriptor
1005 include(cmake/OpenCVGenABI.cmake)
1006
1007 # Generate environment setup file
1008 if(INSTALL_TESTS AND OPENCV_TEST_DATA_PATH)
1009   if(ANDROID)
1010     get_filename_component(TEST_PATH ${OPENCV_TEST_INSTALL_PATH} DIRECTORY)
1011     configure_file("${CMAKE_CURRENT_SOURCE_DIR}/cmake/templates/opencv_run_all_tests_android.sh.in"
1012                    "${CMAKE_BINARY_DIR}/unix-install/opencv_run_all_tests.sh" @ONLY)
1013     install(PROGRAMS "${CMAKE_BINARY_DIR}/unix-install/opencv_run_all_tests.sh"
1014             DESTINATION ./ COMPONENT tests)
1015   elseif(WIN32)
1016     configure_file("${CMAKE_CURRENT_SOURCE_DIR}/cmake/templates/opencv_run_all_tests_windows.cmd.in"
1017                    "${CMAKE_BINARY_DIR}/win-install/opencv_run_all_tests.cmd" @ONLY)
1018     install(PROGRAMS "${CMAKE_BINARY_DIR}/win-install/opencv_run_all_tests.cmd"
1019             DESTINATION ${OPENCV_TEST_INSTALL_PATH} COMPONENT tests)
1020   elseif(UNIX)
1021     configure_file("${CMAKE_CURRENT_SOURCE_DIR}/cmake/templates/opencv_run_all_tests_unix.sh.in"
1022                    "${CMAKE_BINARY_DIR}/unix-install/opencv_run_all_tests.sh" @ONLY)
1023     install(PROGRAMS "${CMAKE_BINARY_DIR}/unix-install/opencv_run_all_tests.sh"
1024             DESTINATION ${OPENCV_TEST_INSTALL_PATH} COMPONENT tests)
1025   endif()
1026 endif()
1027
1028 if(NOT OPENCV_README_FILE)
1029   if(ANDROID)
1030     set(OPENCV_README_FILE ${CMAKE_CURRENT_SOURCE_DIR}/platforms/android/README.android)
1031   endif()
1032 endif()
1033
1034 if(NOT OPENCV_LICENSE_FILE)
1035   set(OPENCV_LICENSE_FILE ${CMAKE_CURRENT_SOURCE_DIR}/LICENSE)
1036 endif()
1037
1038 # for UNIX it does not make sense as LICENSE and readme will be part of the package automatically
1039 if(ANDROID OR NOT UNIX)
1040   install(FILES ${OPENCV_LICENSE_FILE}
1041         PERMISSIONS OWNER_READ GROUP_READ WORLD_READ
1042         DESTINATION ./ COMPONENT libs)
1043   if(OPENCV_README_FILE)
1044     install(FILES ${OPENCV_README_FILE}
1045             PERMISSIONS OWNER_READ GROUP_READ WORLD_READ
1046             DESTINATION ./ COMPONENT libs)
1047   endif()
1048 endif()
1049
1050 if(COMMAND ocv_pylint_finalize)
1051   ocv_pylint_add_directory(${CMAKE_CURRENT_LIST_DIR}/modules/python/test)
1052   ocv_pylint_add_directory(${CMAKE_CURRENT_LIST_DIR}/samples/python)
1053   ocv_pylint_add_directory(${CMAKE_CURRENT_LIST_DIR}/samples/dnn)
1054   ocv_pylint_add_directory_recurse(${CMAKE_CURRENT_LIST_DIR}/samples/python/tutorial_code)
1055   ocv_pylint_finalize()
1056 endif()
1057
1058 if(OPENCV_GENERATE_SETUPVARS)
1059   include(cmake/OpenCVGenSetupVars.cmake)
1060 endif()
1061
1062 # ----------------------------------------------------------------------------
1063 # Summary:
1064 # ----------------------------------------------------------------------------
1065 status("")
1066 status("General configuration for OpenCV ${OPENCV_VERSION} =====================================")
1067 if(OPENCV_VCSVERSION)
1068   status("  Version control:" ${OPENCV_VCSVERSION})
1069 endif()
1070 if(OPENCV_EXTRA_MODULES_PATH AND NOT BUILD_INFO_SKIP_EXTRA_MODULES)
1071   set(__dump_extra_header OFF)
1072   foreach(p ${OPENCV_EXTRA_MODULES_PATH})
1073     if(EXISTS ${p})
1074       if(NOT __dump_extra_header)
1075         set(__dump_extra_header ON)
1076         status("")
1077         status("  Extra modules:")
1078       else()
1079         status("")
1080       endif()
1081       ocv_git_describe(EXTRA_MODULES_VCSVERSION "${p}")
1082       status("    Location (extra):" ${p})
1083       status("    Version control (extra):" ${EXTRA_MODULES_VCSVERSION})
1084     endif()
1085   endforeach()
1086   unset(__dump_extra_header)
1087 endif()
1088
1089 # ========================== build platform ==========================
1090 status("")
1091 status("  Platform:")
1092 if(NOT DEFINED OPENCV_TIMESTAMP
1093     AND NOT CMAKE_VERSION VERSION_LESS 2.8.11
1094     AND NOT BUILD_INFO_SKIP_TIMESTAMP
1095 )
1096   string(TIMESTAMP OPENCV_TIMESTAMP "" UTC)
1097   set(OPENCV_TIMESTAMP "${OPENCV_TIMESTAMP}" CACHE STRING "Timestamp of OpenCV build configuration" FORCE)
1098 endif()
1099 if(OPENCV_TIMESTAMP)
1100   status("    Timestamp:"      ${OPENCV_TIMESTAMP})
1101 endif()
1102 status("    Host:"             ${CMAKE_HOST_SYSTEM_NAME} ${CMAKE_HOST_SYSTEM_VERSION} ${CMAKE_HOST_SYSTEM_PROCESSOR})
1103 if(CMAKE_CROSSCOMPILING)
1104   status("    Target:"         ${CMAKE_SYSTEM_NAME} ${CMAKE_SYSTEM_VERSION} ${CMAKE_SYSTEM_PROCESSOR})
1105 endif()
1106 status("    CMake:"            ${CMAKE_VERSION})
1107 status("    CMake generator:"  ${CMAKE_GENERATOR})
1108 status("    CMake build tool:" ${CMAKE_BUILD_TOOL})
1109 if(MSVC)
1110   status("    MSVC:"           ${MSVC_VERSION})
1111 endif()
1112 if(CMAKE_GENERATOR MATCHES Xcode)
1113   status("    Xcode:"          ${XCODE_VERSION})
1114 endif()
1115 if(NOT CMAKE_GENERATOR MATCHES "Xcode|Visual Studio")
1116   status("    Configuration:"  ${CMAKE_BUILD_TYPE})
1117 endif()
1118
1119
1120 # ========================= CPU code generation mode =========================
1121 status("")
1122 status("  CPU/HW features:")
1123 status("    Baseline:"  "${CPU_BASELINE_FINAL}")
1124 if(NOT CPU_BASELINE STREQUAL CPU_BASELINE_FINAL)
1125   status("      requested:"  "${CPU_BASELINE}")
1126 endif()
1127 if(CPU_BASELINE_REQUIRE)
1128   status("      required:"  "${CPU_BASELINE_REQUIRE}")
1129 endif()
1130 if(CPU_BASELINE_DISABLE)
1131   status("      disabled:"  "${CPU_BASELINE_DISABLE}")
1132 endif()
1133 if(CPU_DISPATCH_FINAL OR CPU_DISPATCH)
1134   status("    Dispatched code generation:"  "${CPU_DISPATCH_FINAL}")
1135   if(NOT CPU_DISPATCH STREQUAL CPU_DISPATCH_FINAL)
1136     status("      requested:"  "${CPU_DISPATCH}")
1137   endif()
1138   if(CPU_DISPATCH_REQUIRE)
1139     status("      required:"  "${CPU_DISPATCH_REQUIRE}")
1140   endif()
1141   foreach(OPT ${CPU_DISPATCH_FINAL})
1142     status("      ${OPT} (${CPU_${OPT}_USAGE_COUNT} files):"  "+ ${CPU_DISPATCH_${OPT}_INCLUDED}")
1143   endforeach()
1144 endif()
1145
1146 # ========================== C/C++ options ==========================
1147 if(CMAKE_CXX_COMPILER_VERSION)
1148   set(OPENCV_COMPILER_STR "${CMAKE_CXX_COMPILER} ${CMAKE_CXX_COMPILER_ARG1} (ver ${CMAKE_CXX_COMPILER_VERSION})")
1149 else()
1150   set(OPENCV_COMPILER_STR "${CMAKE_CXX_COMPILER} ${CMAKE_CXX_COMPILER_ARG1}")
1151 endif()
1152 string(STRIP "${OPENCV_COMPILER_STR}" OPENCV_COMPILER_STR)
1153
1154 status("")
1155 status("  C/C++:")
1156 status("    Built as dynamic libs?:" BUILD_SHARED_LIBS THEN YES ELSE NO)
1157 status("    C++ Compiler:"           ${OPENCV_COMPILER_STR})
1158 status("    C++ flags (Release):"    ${CMAKE_CXX_FLAGS} ${CMAKE_CXX_FLAGS_RELEASE})
1159 status("    C++ flags (Debug):"      ${CMAKE_CXX_FLAGS} ${CMAKE_CXX_FLAGS_DEBUG})
1160 status("    C Compiler:"             ${CMAKE_C_COMPILER} ${CMAKE_C_COMPILER_ARG1})
1161 status("    C flags (Release):"      ${CMAKE_C_FLAGS} ${CMAKE_C_FLAGS_RELEASE})
1162 status("    C flags (Debug):"        ${CMAKE_C_FLAGS} ${CMAKE_C_FLAGS_DEBUG})
1163 if(WIN32)
1164   status("    Linker flags (Release):" ${CMAKE_EXE_LINKER_FLAGS} ${CMAKE_EXE_LINKER_FLAGS_RELEASE})
1165   status("    Linker flags (Debug):"   ${CMAKE_EXE_LINKER_FLAGS} ${CMAKE_EXE_LINKER_FLAGS_DEBUG})
1166 else()
1167   status("    Linker flags (Release):" ${CMAKE_SHARED_LINKER_FLAGS} ${CMAKE_SHARED_LINKER_FLAGS_RELEASE})
1168   status("    Linker flags (Debug):"   ${CMAKE_SHARED_LINKER_FLAGS} ${CMAKE_SHARED_LINKER_FLAGS_DEBUG})
1169 endif()
1170 status("    ccache:"                  OPENCV_COMPILER_IS_CCACHE THEN YES ELSE NO)
1171 status("    Precompiled headers:"     PCHSupport_FOUND AND ENABLE_PRECOMPILED_HEADERS THEN YES ELSE NO)
1172
1173 # ========================== Dependencies ============================
1174 ocv_get_all_libs(deps_modules deps_extra deps_3rdparty)
1175 status("    Extra dependencies:" ${deps_extra})
1176 status("    3rdparty dependencies:" ${deps_3rdparty})
1177
1178 # ========================== OpenCV modules ==========================
1179 status("")
1180 status("  OpenCV modules:")
1181 set(OPENCV_MODULES_BUILD_ST "")
1182 foreach(the_module ${OPENCV_MODULES_BUILD})
1183   if(NOT OPENCV_MODULE_${the_module}_CLASS STREQUAL "INTERNAL" OR the_module STREQUAL "opencv_ts")
1184     list(APPEND OPENCV_MODULES_BUILD_ST "${the_module}")
1185   endif()
1186 endforeach()
1187 string(REPLACE "opencv_" "" OPENCV_MODULES_BUILD_ST          "${OPENCV_MODULES_BUILD_ST}")
1188 string(REPLACE "opencv_" "" OPENCV_MODULES_DISABLED_USER_ST  "${OPENCV_MODULES_DISABLED_USER}")
1189 string(REPLACE "opencv_" "" OPENCV_MODULES_DISABLED_AUTO_ST  "${OPENCV_MODULES_DISABLED_AUTO}")
1190 string(REPLACE "opencv_" "" OPENCV_MODULES_DISABLED_FORCE_ST "${OPENCV_MODULES_DISABLED_FORCE}")
1191 list(SORT OPENCV_MODULES_BUILD_ST)
1192 list(SORT OPENCV_MODULES_DISABLED_USER_ST)
1193 list(SORT OPENCV_MODULES_DISABLED_AUTO_ST)
1194 list(SORT OPENCV_MODULES_DISABLED_FORCE_ST)
1195 status("    To be built:"            OPENCV_MODULES_BUILD          THEN ${OPENCV_MODULES_BUILD_ST}          ELSE "-")
1196 status("    Disabled:"               OPENCV_MODULES_DISABLED_USER  THEN ${OPENCV_MODULES_DISABLED_USER_ST}  ELSE "-")
1197 status("    Disabled by dependency:" OPENCV_MODULES_DISABLED_AUTO  THEN ${OPENCV_MODULES_DISABLED_AUTO_ST}  ELSE "-")
1198 status("    Unavailable:"            OPENCV_MODULES_DISABLED_FORCE THEN ${OPENCV_MODULES_DISABLED_FORCE_ST} ELSE "-")
1199
1200 ocv_build_features_string(apps_status
1201   IF BUILD_TESTS AND HAVE_opencv_ts THEN "tests"
1202   IF BUILD_PERF_TESTS AND HAVE_opencv_ts THEN "perf_tests"
1203   IF BUILD_EXAMPLES THEN "examples"
1204   IF BUILD_opencv_apps THEN "apps"
1205   IF BUILD_ANDROID_SERVICE THEN "android_service"
1206   IF (BUILD_ANDROID_EXAMPLES OR INSTALL_ANDROID_EXAMPLES) AND CAN_BUILD_ANDROID_PROJECTS THEN "android_examples"
1207   ELSE "-")
1208 status("    Applications:" "${apps_status}")
1209 ocv_build_features_string(docs_status
1210     IF TARGET doxygen_cpp THEN "doxygen"
1211     IF TARGET doxygen_python THEN "python"
1212     IF TARGET doxygen_javadoc THEN "javadoc"
1213     IF BUILD_opencv_js OR DEFINED OPENCV_JS_LOCATION THEN "js"
1214     ELSE "NO"
1215 )
1216 status("    Documentation:" "${docs_status}")
1217 status("    Non-free algorithms:" OPENCV_ENABLE_NONFREE THEN "YES" ELSE "NO")
1218
1219 # ========================== Android details ==========================
1220 if(ANDROID)
1221   status("")
1222   if(DEFINED ANDROID_NDK_REVISION)
1223     set(__msg "${ANDROID_NDK} (ver ${ANDROID_NDK_REVISION})")
1224   else()
1225     set(__msg "location: ${ANDROID_NDK}")
1226   endif()
1227   status("  Android NDK: " ${__msg})
1228   status("    Android ABI:" ${ANDROID_ABI})
1229   if(BUILD_WITH_STANDALONE_TOOLCHAIN)
1230     status("    NDK toolchain:" "standalone: ${ANDROID_STANDALONE_TOOLCHAIN}")
1231   elseif(BUILD_WITH_ANDROID_NDK OR DEFINED ANDROID_TOOLCHAIN_NAME)
1232     status("    NDK toolchain:" "${ANDROID_TOOLCHAIN_NAME}")
1233   endif()
1234   status("    STL type:" ${ANDROID_STL})
1235   status("    Native API level:" ${ANDROID_NATIVE_API_LEVEL})
1236
1237   if(BUILD_ANDROID_PROJECTS)
1238     status("  Android SDK: " "${ANDROID_SDK} (tools: ${ANDROID_SDK_TOOLS_VERSION} build tools: ${ANDROID_SDK_BUILD_TOOLS_VERSION})")
1239     if(ANDROID_EXECUTABLE)
1240       status("    android tool:"  "${ANDROID_EXECUTABLE}")
1241     endif()
1242   else()
1243     status("  Android SDK: " "not used, projects are not built")
1244   endif()
1245   if(DEFINED ANDROID_SDK_COMPATIBLE_TARGET)
1246     status("    SDK target:" "${ANDROID_SDK_COMPATIBLE_TARGET}")
1247   endif()
1248   if(DEFINED ANDROID_PROJECTS_BUILD_TYPE)
1249     if(ANDROID_PROJECTS_BUILD_TYPE STREQUAL "ANT")
1250       status("    Projects build scripts:" "Ant/Eclipse compatible")
1251     elseif(ANDROID_PROJECTS_BUILD_TYPE STREQUAL "ANT")
1252       status("    Projects build scripts:" "Gradle")
1253     endif()
1254   endif()
1255 endif()
1256
1257 # ================== Windows RT features ==================
1258 if(WIN32)
1259 status("")
1260 status("  Windows RT support:" WINRT THEN YES ELSE NO)
1261   if(WINRT)
1262     status("    Building for Microsoft platform: " ${CMAKE_SYSTEM_NAME})
1263     status("    Building for architectures: " ${CMAKE_VS_EFFECTIVE_PLATFORMS})
1264     status("    Building for version: " ${CMAKE_SYSTEM_VERSION})
1265     if (DEFINED ENABLE_WINRT_MODE_NATIVE)
1266       status("    Building for C++ without CX extensions")
1267     endif()
1268   endif()
1269 endif(WIN32)
1270
1271 # ========================== GUI ==========================
1272 status("")
1273 status("  GUI: ")
1274
1275 if(WITH_QT OR HAVE_QT)
1276   if(HAVE_QT5)
1277     status("    QT:" "YES (ver ${Qt5Core_VERSION_STRING})")
1278     status("      QT OpenGL support:" HAVE_QT_OPENGL THEN "YES (${Qt5OpenGL_LIBRARIES} ${Qt5OpenGL_VERSION_STRING})" ELSE NO)
1279   elseif(HAVE_QT)
1280     status("    QT:" "YES (ver ${QT_VERSION_MAJOR}.${QT_VERSION_MINOR}.${QT_VERSION_PATCH} ${QT_EDITION})")
1281     status("      QT OpenGL support:" HAVE_QT_OPENGL THEN "YES (${QT_QTOPENGL_LIBRARY})" ELSE NO)
1282   else()
1283     status("    QT:" "NO")
1284   endif()
1285 endif()
1286
1287 if(WITH_WIN32UI)
1288   status("    Win32 UI:" HAVE_WIN32UI THEN YES ELSE NO)
1289 endif()
1290
1291 if(HAVE_COCOA)  # APPLE
1292   status("    Cocoa:"  YES)
1293 endif()
1294
1295 if(WITH_GTK OR HAVE_GTK)
1296   if(HAVE_GTK3)
1297     status("    GTK+:" "YES (ver ${GTK3_VERSION})")
1298   elseif(HAVE_GTK)
1299     status("    GTK+:" "YES (ver ${GTK2_VERSION})")
1300   else()
1301     status("    GTK+:" "NO")
1302   endif()
1303   if(HAVE_GTK)
1304     status(  "      GThread :" HAVE_GTHREAD THEN "YES (ver ${GTHREAD_VERSION})" ELSE NO)
1305     status(  "      GtkGlExt:" HAVE_GTKGLEXT THEN "YES (ver ${GTKGLEXT_VERSION})" ELSE NO)
1306   endif()
1307 endif()
1308
1309 if(WITH_OPENGL OR HAVE_OPENGL)
1310   status("    OpenGL support:" HAVE_OPENGL THEN "YES (${OPENGL_LIBRARIES})" ELSE NO)
1311 endif()
1312
1313 if(WITH_VTK OR HAVE_VTK)
1314   status("    VTK support:" HAVE_VTK THEN "YES (ver ${VTK_VERSION})" ELSE NO)
1315 endif()
1316
1317 # ========================== MEDIA IO ==========================
1318 status("")
1319 status("  Media I/O: ")
1320 status("    ZLib:"   ZLIB_FOUND THEN "${ZLIB_LIBRARIES} (ver ${ZLIB_VERSION_STRING})" ELSE "build (ver ${ZLIB_VERSION_STRING})")
1321
1322 if(WITH_JPEG OR HAVE_JPEG)
1323   if(NOT HAVE_JPEG)
1324     status("    JPEG:" NO)
1325   elseif(BUILD_JPEG)
1326     status("    JPEG:" "build-${JPEG_LIBRARY} (ver ${JPEG_LIB_VERSION})")
1327   else()
1328     status("    JPEG:" "${JPEG_LIBRARY} (ver ${JPEG_LIB_VERSION})")
1329   endif()
1330 endif()
1331
1332 if(WITH_WEBP OR HAVE_WEBP)
1333   status("    WEBP:" WEBP_FOUND THEN "${WEBP_LIBRARY} (ver ${WEBP_VERSION})" ELSE "build (ver ${WEBP_VERSION})")
1334 endif()
1335
1336 if(WITH_PNG OR HAVE_PNG)
1337   status("    PNG:"  PNG_FOUND  THEN "${PNG_LIBRARY} (ver ${PNG_VERSION})" ELSE "build (ver ${PNG_VERSION})")
1338 endif()
1339
1340 if(WITH_TIFF OR HAVE_TIFF)
1341   status("    TIFF:" TIFF_FOUND THEN "${TIFF_LIBRARY} (ver ${TIFF_VERSION} / ${TIFF_VERSION_STRING})" ELSE "build (ver ${TIFF_VERSION} - ${TIFF_VERSION_STRING})")
1342 endif()
1343
1344 if(WITH_JASPER OR HAVE_JASPER)
1345   status("    JPEG 2000:" JASPER_FOUND THEN "${JASPER_LIBRARY} (ver ${JASPER_VERSION_STRING})" ELSE "build (ver ${JASPER_VERSION_STRING})")
1346 endif()
1347
1348 if(WITH_OPENEXR OR HAVE_OPENEXR)
1349   if(HAVE_OPENEXR)
1350     status("    OpenEXR:" OPENEXR_FOUND THEN "${OPENEXR_LIBRARIES} (ver ${OPENEXR_VERSION})" ELSE "build (ver ${OPENEXR_VERSION})")
1351   else()
1352     status("    OpenEXR:" "NO")
1353   endif()
1354 endif()
1355
1356 if(WITH_GDAL OR HAVE_GDAL)
1357   status("    GDAL:" HAVE_GDAL THEN "YES (${GDAL_LIBRARY})" ELSE "NO")
1358 endif()
1359
1360 if(WITH_GDCM OR HAVE_GDCM)
1361   status("    GDCM:" HAVE_GDCM THEN "YES (${GDCM_VERSION})" ELSE "NO")
1362 endif()
1363
1364 if(WITH_IMGCODEC_HDR OR DEFINED HAVE_IMGCODEC_HDR)
1365   status("    HDR:" HAVE_IMGCODEC_HDR THEN "YES" ELSE "NO")
1366 endif()
1367
1368 if(WITH_IMGCODEC_SUNRASTER OR DEFINED HAVE_IMGCODEC_SUNRASTER)
1369   status("    SUNRASTER:" HAVE_IMGCODEC_SUNRASTER THEN "YES" ELSE "NO")
1370 endif()
1371
1372 if(WITH_IMGCODEC_PXM OR DEFINED HAVE_IMGCODEC_PXM)
1373   status("    PXM:" HAVE_IMGCODEC_PXM THEN "YES" ELSE "NO")
1374 endif()
1375
1376 if(WITH_IMGCODEC_PFM OR DEFINED HAVE_IMGCODEC_PFM)
1377   status("    PFM:" HAVE_IMGCODEC_PFM THEN "YES" ELSE "NO")
1378 endif()
1379
1380 # ========================== VIDEO IO ==========================
1381 status("")
1382 status("  Video I/O:")
1383
1384 if(WITH_1394 OR HAVE_DC1394_2)
1385   status("    DC1394:" HAVE_DC1394_2 THEN "YES (${DC1394_2_VERSION})" ELSE NO)
1386 endif()
1387
1388 if(WITH_FFMPEG OR HAVE_FFMPEG)
1389   if(OPENCV_FFMPEG_USE_FIND_PACKAGE)
1390     status("    FFMPEG:"       HAVE_FFMPEG         THEN "YES (find_package)"                       ELSE "NO (find_package)")
1391   elseif(WIN32)
1392     status("    FFMPEG:"       HAVE_FFMPEG         THEN "YES (prebuilt binaries)"                  ELSE NO)
1393   else()
1394     status("    FFMPEG:"       HAVE_FFMPEG         THEN YES ELSE NO)
1395   endif()
1396   status("      avcodec:"      FFMPEG_libavcodec_VERSION    THEN "YES (${FFMPEG_libavcodec_VERSION})"    ELSE NO)
1397   status("      avformat:"     FFMPEG_libavformat_VERSION   THEN "YES (${FFMPEG_libavformat_VERSION})"   ELSE NO)
1398   status("      avutil:"       FFMPEG_libavutil_VERSION     THEN "YES (${FFMPEG_libavutil_VERSION})"     ELSE NO)
1399   status("      swscale:"      FFMPEG_libswscale_VERSION    THEN "YES (${FFMPEG_libswscale_VERSION})"    ELSE NO)
1400   status("      avresample:"   FFMPEG_libavresample_VERSION THEN "YES (${FFMPEG_libavresample_VERSION})" ELSE NO)
1401 endif()
1402
1403 if(WITH_GSTREAMER OR HAVE_GSTREAMER)
1404   status("    GStreamer:" HAVE_GSTREAMER THEN "YES (${GSTREAMER_VERSION})" ELSE NO)
1405 endif()
1406
1407 if(WITH_OPENNI2 OR HAVE_OPENNI2)
1408   status("    OpenNI2:"        HAVE_OPENNI2    THEN "YES (${OPENNI2_VERSION})" ELSE NO)
1409 endif()
1410
1411 if(WITH_PVAPI OR HAVE_PVAPI)
1412   status("    PvAPI:" HAVE_PVAPI THEN YES ELSE NO)
1413 endif()
1414
1415 if(WITH_ARAVIS OR HAVE_ARAVIS_API)
1416   status("    Aravis SDK:" HAVE_ARAVIS_API THEN "YES (${ARAVIS_VERSION})" ELSE NO)
1417 endif()
1418
1419 if(WITH_AVFOUNDATION OR HAVE_AVFOUNDATION)
1420   status("    AVFoundation:" HAVE_AVFOUNDATION THEN YES ELSE NO)
1421 endif()
1422
1423 if(HAVE_CAP_IOS)
1424   status("    iOS capture:" YES)
1425 endif()
1426
1427 if(WITH_V4L OR HAVE_V4L)
1428   ocv_build_features_string(v4l_status
1429     IF HAVE_CAMV4L2 THEN "linux/videodev2.h"
1430     IF HAVE_VIDEOIO THEN "sys/videoio.h"
1431     ELSE "NO")
1432   status("    v4l/v4l2:" HAVE_V4L THEN "YES (${v4l_status})" ELSE NO)
1433 endif()
1434
1435 if(WITH_DSHOW OR HAVE_DSHOW)
1436   status("    DirectShow:" HAVE_DSHOW THEN YES ELSE NO)
1437 endif()
1438
1439 if(WITH_MSMF OR HAVE_MSMF)
1440   status("    Media Foundation:" HAVE_MSMF THEN YES ELSE NO)
1441   status("      DXVA:" HAVE_MSMF_DXVA THEN YES ELSE NO)
1442 endif()
1443
1444 if(WITH_XIMEA OR HAVE_XIMEA)
1445   status("    XIMEA:" HAVE_XIMEA THEN YES ELSE NO)
1446 endif()
1447
1448 if(WITH_XINE OR HAVE_XINE)
1449   status("    Xine:"           HAVE_XINE           THEN "YES (ver ${XINE_VERSION})"     ELSE NO)
1450 endif()
1451
1452 if(WITH_LIBREALSENSE OR HAVE_LIBREALSENSE)
1453   status("    Intel RealSense:" HAVE_LIBREALSENSE THEN "YES (${LIBREALSENSE_VERSION})" ELSE NO)
1454 endif()
1455
1456 if(WITH_MFX OR HAVE_MFX)
1457   status("    Intel Media SDK:" HAVE_MFX      THEN "YES (${MFX_LIBRARY})" ELSE NO)
1458 endif()
1459
1460 if(WITH_GPHOTO2 OR HAVE_GPHOTO2)
1461   status("    gPhoto2:"        HAVE_GPHOTO2        THEN "YES"                                 ELSE NO)
1462 endif()
1463
1464 # Order is similar to CV_PARALLEL_FRAMEWORK in core/src/parallel.cpp
1465 ocv_build_features_string(parallel_status EXCLUSIVE
1466   IF HAVE_TBB THEN "TBB (ver ${TBB_VERSION_MAJOR}.${TBB_VERSION_MINOR} interface ${TBB_INTERFACE_VERSION})"
1467   IF HAVE_HPX THEN "HPX"
1468   IF HAVE_OPENMP THEN "OpenMP"
1469   IF HAVE_GCD THEN "GCD"
1470   IF WINRT OR HAVE_CONCURRENCY THEN "Concurrency"
1471   IF HAVE_PTHREADS_PF THEN "pthreads"
1472   ELSE "none")
1473 status("")
1474 status("  Parallel framework:" "${parallel_status}")
1475
1476 if(CV_TRACE OR OPENCV_TRACE)
1477   ocv_build_features_string(trace_status EXCLUSIVE
1478     IF HAVE_ITT THEN "with Intel ITT"
1479     ELSE "built-in")
1480   status("")
1481   status("  Trace: " OPENCV_TRACE THEN "YES (${trace_status})" ELSE NO)
1482 endif()
1483
1484 # ========================== Other third-party libraries ==========================
1485 status("")
1486 status("  Other third-party libraries:")
1487
1488 if(WITH_IPP AND HAVE_IPP)
1489   status("    Intel IPP:" "${IPP_VERSION_STR} [${IPP_VERSION_MAJOR}.${IPP_VERSION_MINOR}.${IPP_VERSION_BUILD}]")
1490   status("           at:" "${IPP_ROOT_DIR}")
1491   if(NOT HAVE_IPP_ICV)
1492     status("       linked:" BUILD_WITH_DYNAMIC_IPP THEN "dynamic" ELSE "static")
1493   endif()
1494   if(HAVE_IPP_IW)
1495     if(BUILD_IPP_IW)
1496       status("    Intel IPP IW:" "sources (${IW_VERSION_MAJOR}.${IW_VERSION_MINOR}.${IW_VERSION_UPDATE})")
1497     else()
1498       status("    Intel IPP IW:" "binaries (${IW_VERSION_MAJOR}.${IW_VERSION_MINOR}.${IW_VERSION_UPDATE})")
1499     endif()
1500     status("              at:" "${IPP_IW_PATH}")
1501   else()
1502     status("    Intel IPP IW:"   NO)
1503   endif()
1504 endif()
1505
1506 if(WITH_VA OR HAVE_VA)
1507   status("    VA:"            HAVE_VA          THEN "YES" ELSE NO)
1508 endif()
1509
1510 if(WITH_VA_INTEL OR HAVE_VA_INTEL)
1511   status("    Intel VA-API/OpenCL:"  HAVE_VA_INTEL       THEN "YES (OpenCL: ${VA_INTEL_IOCL_ROOT})" ELSE NO)
1512 endif()
1513
1514 if(WITH_LAPACK OR HAVE_LAPACK)
1515   status("    Lapack:"      HAVE_LAPACK     THEN "YES (${LAPACK_LIBRARIES})" ELSE NO)
1516 endif()
1517
1518 if(WITH_HALIDE OR HAVE_HALIDE)
1519   status("    Halide:"     HAVE_HALIDE      THEN "YES (${HALIDE_LIBRARIES} ${HALIDE_INCLUDE_DIRS})" ELSE NO)
1520 endif()
1521
1522 if(WITH_INF_ENGINE OR INF_ENGINE_TARGET)
1523   if(INF_ENGINE_TARGET)
1524     set(__msg "YES (${INF_ENGINE_RELEASE} / ${INF_ENGINE_VERSION})")
1525     get_target_property(_lib ${INF_ENGINE_TARGET} IMPORTED_LOCATION)
1526     get_target_property(_lib_imp_rel ${INF_ENGINE_TARGET} IMPORTED_IMPLIB_RELEASE)
1527     get_target_property(_lib_imp_dbg ${INF_ENGINE_TARGET} IMPORTED_IMPLIB_DEBUG)
1528     get_target_property(_lib_rel ${INF_ENGINE_TARGET} IMPORTED_LOCATION_RELEASE)
1529     get_target_property(_lib_dbg ${INF_ENGINE_TARGET} IMPORTED_LOCATION_DEBUG)
1530     ocv_build_features_string(_lib
1531       IF _lib THEN "${_lib}"
1532       IF _lib_imp_rel AND _lib_imp_dbg THEN "${_lib_imp_rel} / ${_lib_imp_dbg}"
1533       IF _lib_rel AND _lib_dbg THEN "${_lib_rel} / ${_lib_dbg}"
1534       ELSE "unknown"
1535     )
1536     get_target_property(_inc ${INF_ENGINE_TARGET} INTERFACE_INCLUDE_DIRECTORIES)
1537     status("    Inference Engine:" "${__msg}")
1538     status("                libs:" "${_lib}")
1539     status("            includes:" "${_inc}")
1540   else()
1541     status("    Inference Engine:"     "NO")
1542   endif()
1543 endif()
1544
1545 if(WITH_EIGEN OR HAVE_EIGEN)
1546   status("    Eigen:"      HAVE_EIGEN       THEN "YES (ver ${EIGEN_WORLD_VERSION}.${EIGEN_MAJOR_VERSION}.${EIGEN_MINOR_VERSION})" ELSE NO)
1547 endif()
1548
1549 if(WITH_OPENVX OR HAVE_OPENVX)
1550   status("    OpenVX:"     HAVE_OPENVX      THEN "YES (${OPENVX_LIBRARIES})" ELSE "NO")
1551 endif()
1552
1553 status("    Custom HAL:" OpenCV_USED_HAL  THEN "YES (${OpenCV_USED_HAL})" ELSE "NO")
1554
1555 foreach(s ${CUSTOM_STATUS})
1556   status(${CUSTOM_STATUS_${s}})
1557 endforeach()
1558
1559 if(WITH_CUDA OR HAVE_CUDA)
1560   ocv_build_features_string(cuda_features
1561     IF HAVE_CUFFT THEN "CUFFT"
1562     IF HAVE_CUBLAS THEN "CUBLAS"
1563     IF HAVE_NVCUVID THEN "NVCUVID"
1564     IF CUDA_FAST_MATH THEN "FAST_MATH"
1565     ELSE "no extra features")
1566   status("")
1567   status("  NVIDIA CUDA:" HAVE_CUDA THEN "YES (ver ${CUDA_VERSION_STRING}, ${cuda_features})" ELSE NO)
1568   if(HAVE_CUDA)
1569     status("    NVIDIA GPU arch:"      ${OPENCV_CUDA_ARCH_BIN})
1570     status("    NVIDIA PTX archs:"     ${OPENCV_CUDA_ARCH_PTX})
1571   endif()
1572  endif()
1573
1574  if(WITH_CUDNN OR HAVE_CUDNN)
1575     status("")
1576     status("  cuDNN:" HAVE_CUDNN THEN "YES (ver ${CUDNN_VERSION})" ELSE NO)
1577 endif()
1578
1579 if(WITH_VULKAN OR HAVE_VULKAN)
1580   status("")
1581   status("  Vulkan:"     HAVE_VULKAN THEN "YES" ELSE "NO")
1582   if(HAVE_VULKAN)
1583     status("    Include path:"  VULKAN_INCLUDE_DIRS THEN "${VULKAN_INCLUDE_DIRS}" ELSE "NO")
1584     status("    Link libraries:" VULKAN_LIBRARIES THEN "${VULKAN_LIBRARIES}" ELSE "Dynamic load")
1585   endif()
1586 endif()
1587
1588 if(WITH_OPENCL OR HAVE_OPENCL)
1589   ocv_build_features_string(opencl_features
1590     IF HAVE_OPENCL_SVM THEN "SVM"
1591     IF HAVE_CLAMDFFT THEN "AMDFFT"
1592     IF HAVE_CLAMDBLAS THEN "AMDBLAS"
1593     IF HAVE_OPENCL_D3D11_NV THEN "NVD3D11"
1594     ELSE "no extra features")
1595   status("")
1596   status("  OpenCL:"     HAVE_OPENCL   THEN   "YES (${opencl_features})" ELSE "NO")
1597   if(HAVE_OPENCL)
1598     status("    Include path:"  OPENCL_INCLUDE_DIRS THEN "${OPENCL_INCLUDE_DIRS}" ELSE "NO")
1599     status("    Link libraries:"       OPENCL_LIBRARIES THEN "${OPENCL_LIBRARIES}" ELSE "Dynamic load")
1600   endif()
1601 endif()
1602
1603 # ========================== python ==========================
1604 if(BUILD_opencv_python2)
1605   status("")
1606   status("  Python 2:")
1607   status("    Interpreter:"     PYTHON2INTERP_FOUND  THEN "${PYTHON2_EXECUTABLE} (ver ${PYTHON2_VERSION_STRING})"       ELSE NO)
1608   if(PYTHON2LIBS_VERSION_STRING)
1609     status("    Libraries:"   HAVE_opencv_python2  THEN  "${PYTHON2_LIBRARIES} (ver ${PYTHON2LIBS_VERSION_STRING})"   ELSE NO)
1610   else()
1611     status("    Libraries:"   HAVE_opencv_python2  THEN  "${PYTHON2_LIBRARIES}"                                      ELSE NO)
1612   endif()
1613   status("    numpy:"         PYTHON2_NUMPY_INCLUDE_DIRS THEN "${PYTHON2_NUMPY_INCLUDE_DIRS} (ver ${PYTHON2_NUMPY_VERSION})" ELSE "NO (Python wrappers can not be generated)")
1614   status("    install path:"  HAVE_opencv_python2  THEN "${__INSTALL_PATH_PYTHON2}"                            ELSE "-")
1615 endif()
1616
1617 if(BUILD_opencv_python3)
1618   status("")
1619   status("  Python 3:")
1620   status("    Interpreter:"     PYTHON3INTERP_FOUND  THEN "${PYTHON3_EXECUTABLE} (ver ${PYTHON3_VERSION_STRING})"       ELSE NO)
1621   if(PYTHON3LIBS_VERSION_STRING)
1622     status("    Libraries:"   HAVE_opencv_python3  THEN  "${PYTHON3_LIBRARIES} (ver ${PYTHON3LIBS_VERSION_STRING})"   ELSE NO)
1623   else()
1624     status("    Libraries:"   HAVE_opencv_python3  THEN  "${PYTHON3_LIBRARIES}"                                      ELSE NO)
1625   endif()
1626   status("    numpy:"         PYTHON3_NUMPY_INCLUDE_DIRS THEN "${PYTHON3_NUMPY_INCLUDE_DIRS} (ver ${PYTHON3_NUMPY_VERSION})" ELSE "NO (Python3 wrappers can not be generated)")
1627   status("    install path:"  HAVE_opencv_python3  THEN "${__INSTALL_PATH_PYTHON3}"                            ELSE "-")
1628 endif()
1629
1630 status("")
1631 status("  Python (for build):"  PYTHON_DEFAULT_AVAILABLE THEN "${PYTHON_DEFAULT_EXECUTABLE}" ELSE NO)
1632 if(PYLINT_FOUND AND PYLINT_EXECUTABLE)
1633   status("    Pylint:"  PYLINT_FOUND THEN "${PYLINT_EXECUTABLE} (ver: ${PYLINT_VERSION}, checks: ${PYLINT_TOTAL_TARGETS})" ELSE NO)
1634 endif()
1635 if(FLAKE8_FOUND AND FLAKE8_EXECUTABLE)
1636   status("    Flake8:"  FLAKE8_FOUND THEN "${FLAKE8_EXECUTABLE} (ver: ${FLAKE8_VERSION})" ELSE NO)
1637 endif()
1638
1639 # ========================== java ==========================
1640 if(BUILD_JAVA OR BUILD_opencv_java)
1641   status("")
1642   status("  Java:"            BUILD_FAT_JAVA_LIB  THEN "export all functions"                                      ELSE "")
1643   status("    ant:"           ANT_EXECUTABLE      THEN "${ANT_EXECUTABLE} (ver ${ANT_VERSION})"                    ELSE NO)
1644   if(NOT ANDROID)
1645     status("    JNI:"         JNI_INCLUDE_DIRS    THEN "${JNI_INCLUDE_DIRS}"                                       ELSE NO)
1646   endif()
1647   status("    Java wrappers:" HAVE_opencv_java                                                            THEN YES ELSE NO)
1648   status("    Java tests:"    BUILD_TESTS AND opencv_test_java_BINARY_DIR                                 THEN YES ELSE NO)
1649 endif()
1650
1651 ocv_cmake_hook(STATUS_DUMP_EXTRA)
1652
1653 # ========================== auxiliary ==========================
1654 status("")
1655 status("  Install to:" "${CMAKE_INSTALL_PREFIX}")
1656 status("-----------------------------------------------------------------")
1657 status("")
1658
1659
1660 ocv_finalize_status()
1661
1662 if(ENABLE_CONFIG_VERIFICATION)
1663   ocv_verify_config()
1664 endif()
1665
1666 ocv_cmake_hook(POST_FINALIZE)
1667
1668 # ----------------------------------------------------------------------------
1669 # CPack stuff
1670 # ----------------------------------------------------------------------------
1671
1672 include(cmake/OpenCVPackaging.cmake)
1673
1674 # This should be the last command
1675 ocv_cmake_dump_vars("" TOFILE "CMakeVars.txt")
1676 ocv_cmake_eval(DEBUG_POST ONCE)