CMakeLists.txt

   1 # ----------------------------------------------------------------------------
   2 #  Root CMake file for OpenCV
   3 #
   4 #    From the off-tree build directory, invoke:
   5 #      $ cmake <PATH_TO_OPENCV_ROOT>
   6 #
   7 # ----------------------------------------------------------------------------
   8
   9 # Disable in-source builds to prevent source tree corruption.
  10 if(" ${CMAKE_SOURCE_DIR}" STREQUAL " ${CMAKE_BINARY_DIR}")
  11   message(FATAL_ERROR "
  12 FATAL: In-source builds are not allowed.
  13        You should create a separate directory for build files.
  14 ")
  15 endif()
  16
  17
  18 include(cmake/OpenCVMinDepVersions.cmake)
  19
  20 if(CMAKE_GENERATOR MATCHES Xcode AND XCODE_VERSION VERSION_GREATER 4.3)
  21   cmake_minimum_required(VERSION 3.0 FATAL_ERROR)
  22 elseif(CMAKE_SYSTEM_NAME MATCHES WindowsPhone OR CMAKE_SYSTEM_NAME MATCHES WindowsStore)
  23   cmake_minimum_required(VERSION 3.1 FATAL_ERROR)
  24   #Required to resolve linker error issues due to incompatibility with CMake v3.0+ policies.
  25   #CMake fails to find _fseeko() which leads to subsequent linker error.
  26   #See details here: http://www.cmake.org/Wiki/CMake/Policies
  27   cmake_policy(VERSION 2.8)
  28 else()
  29   cmake_minimum_required(VERSION "${MIN_VER_CMAKE}" FATAL_ERROR)
  30 endif()
  31
  32 #
  33 # Configure CMake policies
  34 #
  35 if(POLICY CMP0026)
  36   cmake_policy(SET CMP0026 NEW)
  37 endif()
  38
  39 if(POLICY CMP0042)
  40   cmake_policy(SET CMP0042 NEW)  # CMake 3.0+ (2.8.12): MacOS "@rpath" in target's install name
  41 endif()
  42
  43 if(POLICY CMP0046)
  44   cmake_policy(SET CMP0046 NEW)  # warn about non-existed dependencies
  45 endif()
  46
  47 if(POLICY CMP0051)
  48   cmake_policy(SET CMP0051 NEW)
  49 endif()
  50
  51 if(POLICY CMP0054)  # CMake 3.1: Only interpret if() arguments as variables or keywords when unquoted.
  52   cmake_policy(SET CMP0054 NEW)
  53 endif()
  54
  55 if(POLICY CMP0056)
  56   cmake_policy(SET CMP0056 NEW)  # try_compile(): link flags
  57 endif()
  58
  59 if(POLICY CMP0066)
  60   cmake_policy(SET CMP0066 NEW)  # CMake 3.7: try_compile(): use per-config flags, like CMAKE_CXX_FLAGS_RELEASE
  61 endif()
  62
  63 if(POLICY CMP0067)
  64   cmake_policy(SET CMP0067 NEW)  # CMake 3.8: try_compile(): honor language standard variables (like C++11)
  65 endif()
  66
  67 if(POLICY CMP0068)
  68   cmake_policy(SET CMP0068 NEW)  # CMake 3.9+: `RPATH` settings on macOS do not affect `install_name`.
  69 endif()
  70
  71 if(POLICY CMP0075)
  72   cmake_policy(SET CMP0075 NEW)  # CMake 3.12+: Include file check macros honor `CMAKE_REQUIRED_LIBRARIES`
  73 endif()
  74
  75 if(POLICY CMP0077)
  76   cmake_policy(SET CMP0077 NEW)  # CMake 3.13+: option() honors normal variables.
  77 endif()
  78
  79 #
  80 # Configure OpenCV CMake hooks
  81 #
  82 include(cmake/OpenCVUtils.cmake)
  83 ocv_cmake_reset_hooks()
  84 ocv_check_environment_variables(OPENCV_CMAKE_HOOKS_DIR)
  85 if(DEFINED OPENCV_CMAKE_HOOKS_DIR)
  86   foreach(__dir ${OPENCV_CMAKE_HOOKS_DIR})
  87     get_filename_component(__dir "${__dir}" ABSOLUTE)
  88     ocv_cmake_hook_register_dir(${__dir})
  89   endforeach()
  90 endif()
  91
  92 ocv_cmake_hook(CMAKE_INIT)
  93
  94 # must go before the project()/enable_language() commands
  95 ocv_update(CMAKE_CONFIGURATION_TYPES "Debug;Release" CACHE STRING "Configs" FORCE)
  96 if(DEFINED CMAKE_BUILD_TYPE)
  97   set_property(CACHE CMAKE_BUILD_TYPE PROPERTY STRINGS "${CMAKE_CONFIGURATION_TYPES}")
  98 endif()
  99
 100 option(ENABLE_PIC "Generate position independent code (necessary for shared libraries)" TRUE)
 101 set(CMAKE_POSITION_INDEPENDENT_CODE ${ENABLE_PIC})
 102
 103 ocv_cmake_hook(PRE_CMAKE_BOOTSTRAP)
 104
 105 # Bootstap CMake system: setup CMAKE_SYSTEM_NAME and other vars
 106 enable_language(CXX C)
 107
 108 ocv_cmake_hook(POST_CMAKE_BOOTSTRAP)
 109
 110 if(NOT OPENCV_SKIP_CMAKE_SYSTEM_FILE)
 111   include("cmake/platforms/OpenCV-${CMAKE_SYSTEM_NAME}.cmake" OPTIONAL RESULT_VARIABLE "OPENCV_CMAKE_SYSTEM_FILE")
 112   if(NOT OPENCV_CMAKE_SYSTEM_FILE)
 113     message(STATUS "OpenCV: system-specific configuration file is not found: '${CMAKE_SYSTEM_NAME}'")
 114   endif()
 115 endif()
 116
 117 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)  # https://cmake.org/cmake/help/latest/variable/CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT.html
 118   if(NOT CMAKE_TOOLCHAIN_FILE)
 119     if(WIN32)
 120       set(CMAKE_INSTALL_PREFIX "${CMAKE_BINARY_DIR}/install" CACHE PATH "Installation Directory" FORCE)
 121     else()
 122       set(CMAKE_INSTALL_PREFIX "/usr/local" CACHE PATH "Installation Directory" FORCE)
 123     endif()
 124   else()
 125     # any cross-compiling
 126     set(CMAKE_INSTALL_PREFIX "${CMAKE_BINARY_DIR}/install" CACHE PATH "Installation Directory" FORCE)
 127   endif()
 128 endif()
 129
 130 enable_testing()
 131
 132 project(OpenCV CXX C)
 133
 134 if(MSVC)
 135   set(CMAKE_USE_RELATIVE_PATHS ON CACHE INTERNAL "" FORCE)
 136 endif()
 137
 138 ocv_cmake_eval(DEBUG_PRE ONCE)
 139
 140 ocv_clear_vars(OpenCVModules_TARGETS)
 141
 142 include(cmake/OpenCVDownload.cmake)
 143
 144 set(BUILD_LIST "" CACHE STRING "Build only listed modules (comma-separated, e.g. 'videoio,dnn,ts')")
 145
 146 # ----------------------------------------------------------------------------
 147 # Break in case of popular CMake configuration mistakes
 148 # ----------------------------------------------------------------------------
 149 if(NOT CMAKE_SIZEOF_VOID_P GREATER 0)
 150   message(FATAL_ERROR "CMake fails to determine the bitness of the target platform.
 151   Please check your CMake and compiler installation. If you are cross-compiling then ensure that your CMake toolchain file correctly sets the compiler details.")
 152 endif()
 153
 154 # ----------------------------------------------------------------------------
 155 # Detect compiler and target platform architecture
 156 # ----------------------------------------------------------------------------
 157 include(cmake/OpenCVDetectCXXCompiler.cmake)
 158 ocv_cmake_hook(POST_DETECT_COMPILER)
 159
 160 # Add these standard paths to the search paths for FIND_LIBRARY
 161 # to find libraries from these locations first
 162 if(UNIX AND NOT ANDROID)
 163   if(X86_64 OR CMAKE_SIZEOF_VOID_P EQUAL 8)
 164     if(EXISTS /lib64)
 165       list(APPEND CMAKE_LIBRARY_PATH /lib64)
 166     else()
 167       list(APPEND CMAKE_LIBRARY_PATH /lib)
 168     endif()
 169     if(EXISTS /usr/lib64)
 170       list(APPEND CMAKE_LIBRARY_PATH /usr/lib64)
 171     else()
 172       list(APPEND CMAKE_LIBRARY_PATH /usr/lib)
 173     endif()
 174   elseif(X86 OR CMAKE_SIZEOF_VOID_P EQUAL 4)
 175     if(EXISTS /lib32)
 176       list(APPEND CMAKE_LIBRARY_PATH /lib32)
 177     else()
 178       list(APPEND CMAKE_LIBRARY_PATH /lib)
 179     endif()
 180     if(EXISTS /usr/lib32)
 181       list(APPEND CMAKE_LIBRARY_PATH /usr/lib32)
 182     else()
 183       list(APPEND CMAKE_LIBRARY_PATH /usr/lib)
 184     endif()
 185   endif()
 186 endif()
 187
 188 # Add these standard paths to the search paths for FIND_PATH
 189 # to find include files from these locations first
 190 if(MINGW)
 191   if(EXISTS /mingw)
 192       list(APPEND CMAKE_INCLUDE_PATH /mingw)
 193   endif()
 194   if(EXISTS /mingw32)
 195       list(APPEND CMAKE_INCLUDE_PATH /mingw32)
 196   endif()
 197   if(EXISTS /mingw64)
 198       list(APPEND CMAKE_INCLUDE_PATH /mingw64)
 199   endif()
 200 endif()
 201
 202 # ----------------------------------------------------------------------------
 203 # OpenCV cmake options
 204 # ----------------------------------------------------------------------------
 205
 206 OCV_OPTION(OPENCV_ENABLE_NONFREE "Enable non-free algorithms" OFF)
 207
 208 # 3rd party libs
 209 OCV_OPTION(OPENCV_FORCE_3RDPARTY_BUILD   "Force using 3rdparty code from source" OFF)
 210 OCV_OPTION(BUILD_ZLIB               "Build zlib from source"             (WIN32 OR APPLE OR OPENCV_FORCE_3RDPARTY_BUILD) )
 211 OCV_OPTION(BUILD_TIFF               "Build libtiff from source"          (WIN32 OR ANDROID OR APPLE OR OPENCV_FORCE_3RDPARTY_BUILD) )
 212 OCV_OPTION(BUILD_JASPER             "Build libjasper from source"        (WIN32 OR ANDROID OR APPLE OR OPENCV_FORCE_3RDPARTY_BUILD) )
 213 OCV_OPTION(BUILD_JPEG               "Build libjpeg from source"          (WIN32 OR ANDROID OR APPLE OR OPENCV_FORCE_3RDPARTY_BUILD) )
 214 OCV_OPTION(BUILD_PNG                "Build libpng from source"           (WIN32 OR ANDROID OR APPLE OR OPENCV_FORCE_3RDPARTY_BUILD) )
 215 OCV_OPTION(BUILD_OPENEXR            "Build openexr from source"          (((WIN32 OR ANDROID OR APPLE) AND NOT WINRT) OR OPENCV_FORCE_3RDPARTY_BUILD) )
 216 OCV_OPTION(BUILD_WEBP               "Build WebP from source"             (((WIN32 OR ANDROID OR APPLE) AND NOT WINRT) OR OPENCV_FORCE_3RDPARTY_BUILD) )
 217 OCV_OPTION(BUILD_TBB                "Download and build TBB from source" (ANDROID OR OPENCV_FORCE_3RDPARTY_BUILD) )
 218 OCV_OPTION(BUILD_IPP_IW             "Build IPP IW from source"           (NOT MINGW OR OPENCV_FORCE_3RDPARTY_BUILD) IF (X86_64 OR X86) AND NOT WINRT )
 219 OCV_OPTION(BUILD_ITT                "Build Intel ITT from source"
 220     (NOT MINGW OR OPENCV_FORCE_3RDPARTY_BUILD)
 221     IF (X86_64 OR X86 OR ARM OR AARCH64 OR PPC64 OR PPC64LE) AND NOT WINRT AND NOT APPLE_FRAMEWORK
 222 )
 223
 224 # Optional 3rd party components
 225 # ===================================================
 226 OCV_OPTION(WITH_1394 "Include IEEE1394 support" ON
 227   VISIBLE_IF NOT ANDROID AND NOT IOS AND NOT WINRT
 228   VERIFY HAVE_DC1394_2)
 229 OCV_OPTION(WITH_AVFOUNDATION "Use AVFoundation for Video I/O (iOS/Mac)" ON
 230   VISIBLE_IF APPLE
 231   VERIFY HAVE_AVFOUNDATION)
 232 OCV_OPTION(WITH_CAP_IOS "Enable iOS video capture" ON
 233   VISIBLE_IF IOS
 234   VERIFY HAVE_CAP_IOS)
 235 OCV_OPTION(WITH_CAROTENE "Use NVidia carotene acceleration library for ARM platform" ON
 236   VISIBLE_IF (ARM OR AARCH64) AND NOT IOS AND NOT (CMAKE_VERSION VERSION_LESS "2.8.11"))
 237 OCV_OPTION(WITH_CPUFEATURES "Use cpufeatures Android library" ON
 238   VISIBLE_IF ANDROID
 239   VERIFY HAVE_CPUFEATURES)
 240 OCV_OPTION(WITH_VTK "Include VTK library support (and build opencv_viz module eiher)" ON
 241   VISIBLE_IF NOT ANDROID AND NOT IOS AND NOT WINRT AND NOT CMAKE_CROSSCOMPILING
 242   VERIFY HAVE_VTK)
 243 OCV_OPTION(WITH_CUDA "Include NVidia Cuda Runtime support" OFF
 244   VISIBLE_IF NOT IOS AND NOT WINRT
 245   VERIFY HAVE_CUDA)
 246 OCV_OPTION(WITH_CUFFT "Include NVidia Cuda Fast Fourier Transform (FFT) library support" WITH_CUDA
 247   VISIBLE_IF WITH_CUDA
 248   VERIFY HAVE_CUFFT)
 249 OCV_OPTION(WITH_CUBLAS "Include NVidia Cuda Basic Linear Algebra Subprograms (BLAS) library support" WITH_CUDA
 250   VISIBLE_IF WITH_CUDA
 251   VERIFY HAVE_CUBLAS)
 252 OCV_OPTION(WITH_CUDNN "Include NVIDIA CUDA Deep Neural Network (cuDNN) library support" WITH_CUDA
 253   VISIBLE_IF WITH_CUDA
 254   VERIFY HAVE_CUDNN)
 255 OCV_OPTION(WITH_NVCUVID "Include NVidia Video Decoding library support" OFF  # disabled, details: https://github.com/opencv/opencv/issues/14850
 256   VISIBLE_IF WITH_CUDA
 257   VERIFY HAVE_NVCUVID)
 258 OCV_OPTION(WITH_EIGEN "Include Eigen2/Eigen3 support" (NOT CV_DISABLE_OPTIMIZATION AND NOT CMAKE_CROSSCOMPILING)
 259   VISIBLE_IF NOT WINRT
 260   VERIFY HAVE_EIGEN)
 261 OCV_OPTION(WITH_FFMPEG "Include FFMPEG support" (NOT ANDROID)
 262   VISIBLE_IF NOT IOS AND NOT WINRT
 263   VERIFY HAVE_FFMPEG)
 264 OCV_OPTION(WITH_GSTREAMER "Include Gstreamer support" ON
 265   VISIBLE_IF NOT ANDROID AND NOT IOS AND NOT WINRT
 266   VERIFY HAVE_GSTREAMER AND GSTREAMER_VERSION VERSION_GREATER "0.99")
 267 OCV_OPTION(WITH_GTK "Include GTK support" ON
 268   VISIBLE_IF UNIX AND NOT APPLE AND NOT ANDROID
 269   VERIFY HAVE_GTK)
 270 OCV_OPTION(WITH_GTK_2_X "Use GTK version 2" OFF
 271   VISIBLE_IF UNIX AND NOT APPLE AND NOT ANDROID
 272   VERIFY HAVE_GTK AND NOT HAVE_GTK3)
 273 OCV_OPTION(WITH_IPP "Include Intel IPP support" (NOT MINGW AND NOT CV_DISABLE_OPTIMIZATION)
 274   VISIBLE_IF (X86_64 OR X86) AND NOT WINRT AND NOT IOS
 275   VERIFY HAVE_IPP)
 276 OCV_OPTION(WITH_HALIDE "Include Halide support" OFF
 277   VISIBLE_IF TRUE
 278   VERIFY HAVE_HALIDE)
 279 OCV_OPTION(WITH_VULKAN "Include Vulkan support" OFF
 280   VISIBLE_IF TRUE
 281   VERIFY HAVE_VULKAN)
 282 OCV_OPTION(WITH_INF_ENGINE "Include Intel Inference Engine support" OFF
 283   VISIBLE_IF TRUE
 284   VERIFY INF_ENGINE_TARGET)
 285 OCV_OPTION(WITH_NGRAPH "Include nGraph support" WITH_INF_ENGINE
 286   VISIBLE_IF TRUE
 287   VERIFY TARGET ngraph::ngraph)
 288 OCV_OPTION(WITH_JASPER "Include JPEG2K support (Jasper)" ON
 289   VISIBLE_IF NOT IOS
 290   VERIFY HAVE_JASPER)
 291 OCV_OPTION(WITH_OPENJPEG "Include JPEG2K support (OpenJPEG)" ON
 292   VISIBLE_IF NOT IOS
 293   VERIFY HAVE_OPENJPEG)
 294 OCV_OPTION(WITH_JPEG "Include JPEG support" ON
 295   VISIBLE_IF TRUE
 296   VERIFY HAVE_JPEG)
 297 OCV_OPTION(WITH_WEBP "Include WebP support" ON
 298   VISIBLE_IF NOT WINRT
 299   VERIFY HAVE_WEBP)
 300 OCV_OPTION(WITH_OPENEXR "Include ILM support via OpenEXR" BUILD_OPENEXR OR NOT CMAKE_CROSSCOMPILING
 301   VISIBLE_IF NOT APPLE_FRAMEWORK AND NOT WINRT
 302   VERIFY HAVE_OPENEXR)
 303 OCV_OPTION(WITH_OPENGL "Include OpenGL support" OFF
 304   VISIBLE_IF NOT ANDROID AND NOT WINRT
 305   VERIFY HAVE_OPENGL)
 306 OCV_OPTION(WITH_OPENVX "Include OpenVX support" OFF
 307   VISIBLE_IF TRUE
 308   VERIFY HAVE_OPENVX)
 309 OCV_OPTION(WITH_OPENNI "Include OpenNI support" OFF
 310   VISIBLE_IF NOT ANDROID AND NOT IOS AND NOT WINRT
 311   VERIFY HAVE_OPENNI)
 312 OCV_OPTION(WITH_OPENNI2 "Include OpenNI2 support" OFF
 313   VISIBLE_IF NOT ANDROID AND NOT IOS AND NOT WINRT
 314   VERIFY HAVE_OPENNI2)
 315 OCV_OPTION(WITH_PNG "Include PNG support" ON
 316   VISIBLE_IF TRUE
 317   VERIFY HAVE_PNG)
 318 OCV_OPTION(WITH_GDCM "Include DICOM support" OFF
 319   VISIBLE_IF TRUE
 320   VERIFY HAVE_GDCM)
 321 OCV_OPTION(WITH_PVAPI "Include Prosilica GigE support" OFF
 322   VISIBLE_IF NOT ANDROID AND NOT IOS AND NOT WINRT
 323   VERIFY HAVE_PVAPI)
 324 OCV_OPTION(WITH_ARAVIS "Include Aravis GigE support" OFF
 325   VISIBLE_IF NOT ANDROID AND NOT IOS AND NOT WINRT AND NOT WIN32
 326   VERIFY HAVE_ARAVIS_API)
 327 OCV_OPTION(WITH_QT "Build with Qt Backend support" OFF
 328   VISIBLE_IF NOT ANDROID AND NOT IOS AND NOT WINRT
 329   VERIFY HAVE_QT)
 330 OCV_OPTION(WITH_WIN32UI "Build with Win32 UI Backend support" ON
 331   VISIBLE_IF WIN32 AND NOT WINRT
 332   VERIFY HAVE_WIN32UI)
 333 OCV_OPTION(WITH_TBB "Include Intel TBB support" OFF
 334   VISIBLE_IF NOT IOS AND NOT WINRT
 335   VERIFY HAVE_TBB)
 336 OCV_OPTION(WITH_HPX "Include Ste||ar Group HPX support" OFF
 337   VISIBLE_IF TRUE
 338   VERIFY HAVE_HPX)
 339 OCV_OPTION(WITH_OPENMP "Include OpenMP support" OFF
 340   VISIBLE_IF TRUE
 341   VERIFY HAVE_OPENMP)
 342 OCV_OPTION(WITH_PTHREADS_PF "Use pthreads-based parallel_for" ON
 343   VISIBLE_IF NOT WIN32 OR MINGW
 344   VERIFY HAVE_PTHREADS_PF)
 345 OCV_OPTION(WITH_TIFF "Include TIFF support" ON
 346   VISIBLE_IF NOT IOS
 347   VERIFY HAVE_TIFF)
 348 OCV_OPTION(WITH_V4L "Include Video 4 Linux support" ON
 349   VISIBLE_IF UNIX AND NOT ANDROID AND NOT APPLE
 350   VERIFY HAVE_CAMV4L OR HAVE_CAMV4L2 OR HAVE_VIDEOIO)
 351 OCV_OPTION(WITH_DSHOW "Build VideoIO with DirectShow support" ON
 352   VISIBLE_IF WIN32 AND NOT ARM AND NOT WINRT
 353   VERIFY HAVE_DSHOW)
 354 OCV_OPTION(WITH_MSMF "Build VideoIO with Media Foundation support" NOT MINGW
 355   VISIBLE_IF WIN32
 356   VERIFY HAVE_MSMF)
 357 OCV_OPTION(WITH_MSMF_DXVA "Enable hardware acceleration in Media Foundation backend" WITH_MSMF
 358   VISIBLE_IF WIN32
 359   VERIFY HAVE_MSMF_DXVA)
 360 OCV_OPTION(WITH_XIMEA "Include XIMEA cameras support" OFF
 361   VISIBLE_IF NOT ANDROID AND NOT WINRT
 362   VERIFY HAVE_XIMEA)
 363 OCV_OPTION(WITH_XINE "Include Xine support (GPL)" OFF
 364   VISIBLE_IF UNIX AND NOT APPLE AND NOT ANDROID
 365   VERIFY HAVE_XINE)
 366 OCV_OPTION(WITH_CLP "Include Clp support (EPL)" OFF
 367   VISIBLE_IF TRUE
 368   VERIFY HAVE_CLP)
 369 OCV_OPTION(WITH_OPENCL "Include OpenCL Runtime support" (NOT ANDROID AND NOT CV_DISABLE_OPTIMIZATION)
 370   VISIBLE_IF NOT IOS AND NOT WINRT
 371   VERIFY HAVE_OPENCL)
 372 OCV_OPTION(WITH_OPENCL_SVM "Include OpenCL Shared Virtual Memory support" OFF
 373   VISIBLE_IF TRUE
 374   VERIFY HAVE_OPENCL_SVM) # experimental
 375 OCV_OPTION(WITH_OPENCLAMDFFT "Include AMD OpenCL FFT library support" ON
 376   VISIBLE_IF NOT ANDROID AND NOT IOS AND NOT WINRT
 377   VERIFY HAVE_CLAMDFFT)
 378 OCV_OPTION(WITH_OPENCLAMDBLAS "Include AMD OpenCL BLAS library support" ON
 379   VISIBLE_IF NOT ANDROID AND NOT IOS AND NOT WINRT
 380   VERIFY HAVE_CLAMDBLAS)
 381 OCV_OPTION(WITH_DIRECTX "Include DirectX support" ON
 382   VISIBLE_IF WIN32 AND NOT WINRT
 383   VERIFY HAVE_DIRECTX)
 384 OCV_OPTION(WITH_OPENCL_D3D11_NV "Include NVIDIA OpenCL D3D11 support" WITH_DIRECTX
 385   VISIBLE_IF WIN32 AND NOT WINRT
 386   VERIFY HAVE_OPENCL_D3D11_NV)
 387 OCV_OPTION(WITH_LIBREALSENSE "Include Intel librealsense support" OFF
 388   VISIBLE_IF NOT WITH_INTELPERC
 389   VERIFY HAVE_LIBREALSENSE)
 390 OCV_OPTION(WITH_VA "Include VA support" OFF
 391   VISIBLE_IF UNIX AND NOT ANDROID
 392   VERIFY HAVE_VA)
 393 OCV_OPTION(WITH_VA_INTEL "Include Intel VA-API/OpenCL support" OFF
 394   VISIBLE_IF UNIX AND NOT ANDROID
 395   VERIFY HAVE_VA_INTEL)
 396 OCV_OPTION(WITH_MFX "Include Intel Media SDK support" OFF
 397   VISIBLE_IF (UNIX AND NOT ANDROID) OR (WIN32 AND NOT WINRT AND NOT MINGW)
 398   VERIFY HAVE_MFX)
 399 OCV_OPTION(WITH_GDAL "Include GDAL Support" OFF
 400   VISIBLE_IF NOT ANDROID AND NOT IOS AND NOT WINRT
 401   VERIFY HAVE_GDAL)
 402 OCV_OPTION(WITH_GPHOTO2 "Include gPhoto2 library support" OFF
 403   VISIBLE_IF UNIX AND NOT ANDROID AND NOT IOS
 404   VERIFY HAVE_GPHOTO2)
 405 OCV_OPTION(WITH_LAPACK "Include Lapack library support" (NOT CV_DISABLE_OPTIMIZATION)
 406   VISIBLE_IF NOT ANDROID AND NOT IOS
 407   VERIFY HAVE_LAPACK)
 408 OCV_OPTION(WITH_ITT "Include Intel ITT support" ON
 409   VISIBLE_IF NOT APPLE_FRAMEWORK
 410   VERIFY HAVE_ITT)
 411 OCV_OPTION(WITH_PROTOBUF "Enable libprotobuf" ON
 412   VISIBLE_IF TRUE
 413   VERIFY HAVE_PROTOBUF)
 414 OCV_OPTION(WITH_IMGCODEC_HDR "Include HDR support" ON
 415   VISIBLE_IF TRUE
 416   VERIFY HAVE_IMGCODEC_HDR)
 417 OCV_OPTION(WITH_IMGCODEC_SUNRASTER "Include SUNRASTER support" ON
 418   VISIBLE_IF TRUE
 419   VERIFY HAVE_IMGCODEC_SUNRASTER)
 420 OCV_OPTION(WITH_IMGCODEC_PXM "Include PNM (PBM,PGM,PPM) and PAM formats support" ON
 421   VISIBLE_IF TRUE
 422   VERIFY HAVE_IMGCODEC_PXM)
 423 OCV_OPTION(WITH_IMGCODEC_PFM "Include PFM formats support" ON
 424   VISIBLE_IF TRUE
 425   VERIFY HAVE_IMGCODEC_PFM)
 426 OCV_OPTION(WITH_QUIRC "Include library QR-code decoding" ON
 427   VISIBLE_IF TRUE
 428   VERIFY HAVE_QUIRC)
 429 OCV_OPTION(WITH_ANDROID_MEDIANDK "Use Android Media NDK for Video I/O (Android)" (ANDROID_NATIVE_API_LEVEL GREATER 20)
 430   VISIBLE_IF ANDROID
 431   VERIFY HAVE_ANDROID_MEDIANDK)
 432 OCV_OPTION(WITH_TENGINE "Include Arm Inference Tengine support" OFF
 433   VISIBLE_IF (ARM OR AARCH64) AND (UNIX OR ANDROID) AND NOT IOS
 434   VERIFY HAVE_TENGINE)
 435
 436 # OpenCV build components
 437 # ===================================================
 438 OCV_OPTION(BUILD_SHARED_LIBS        "Build shared libraries (.dll/.so) instead of static ones (.lib/.a)" NOT (ANDROID OR APPLE_FRAMEWORK) )
 439 OCV_OPTION(BUILD_opencv_apps        "Build utility applications (used for example to train classifiers)" (NOT ANDROID AND NOT WINRT) IF (NOT APPLE_FRAMEWORK) )
 440 OCV_OPTION(BUILD_opencv_js          "Build JavaScript bindings by Emscripten" OFF )
 441 OCV_OPTION(BUILD_ANDROID_PROJECTS   "Build Android projects providing .apk files" ON  IF ANDROID )
 442 OCV_OPTION(BUILD_ANDROID_EXAMPLES   "Build examples for Android platform"         ON  IF ANDROID )
 443 OCV_OPTION(BUILD_DOCS               "Create build rules for OpenCV Documentation" OFF  IF (NOT WINRT AND NOT APPLE_FRAMEWORK))
 444 OCV_OPTION(BUILD_EXAMPLES           "Build all examples"                          OFF )
 445 OCV_OPTION(BUILD_PACKAGE            "Enables 'make package_source' command"       ON  IF NOT WINRT)
 446 OCV_OPTION(BUILD_PERF_TESTS         "Build performance tests"                     NOT INSTALL_CREATE_DISTRIB  IF (NOT APPLE_FRAMEWORK) )
 447 OCV_OPTION(BUILD_TESTS              "Build accuracy & regression tests"           NOT INSTALL_CREATE_DISTRIB  IF (NOT APPLE_FRAMEWORK) )
 448 OCV_OPTION(BUILD_WITH_DEBUG_INFO    "Include debug info into release binaries ('OFF' means default settings)" OFF )
 449 OCV_OPTION(BUILD_WITH_STATIC_CRT    "Enables use of statically linked CRT for statically linked OpenCV" ON IF MSVC )
 450 OCV_OPTION(BUILD_WITH_DYNAMIC_IPP   "Enables dynamic linking of IPP (only for standalone IPP)" OFF )
 451 OCV_OPTION(BUILD_FAT_JAVA_LIB       "Create Java wrapper exporting all functions of OpenCV library (requires static build of OpenCV modules)" ANDROID IF NOT BUILD_SHARED_LIBS)
 452 OCV_OPTION(BUILD_ANDROID_SERVICE    "Build OpenCV Manager for Google Play" OFF IF ANDROID )
 453 OCV_OPTION(BUILD_CUDA_STUBS         "Build CUDA modules stubs when no CUDA SDK" OFF  IF (NOT APPLE_FRAMEWORK) )
 454 OCV_OPTION(BUILD_JAVA               "Enable Java support"                         (ANDROID OR NOT CMAKE_CROSSCOMPILING)  IF (ANDROID OR (NOT APPLE_FRAMEWORK AND NOT WINRT)) )
 455 OCV_OPTION(BUILD_OBJC               "Enable Objective-C support"                  ON  IF APPLE_FRAMEWORK )
 456
 457 # OpenCV installation options
 458 # ===================================================
 459 OCV_OPTION(INSTALL_CREATE_DISTRIB   "Change install rules to build the distribution package" OFF )
 460 OCV_OPTION(INSTALL_C_EXAMPLES       "Install C examples"        OFF )
 461 OCV_OPTION(INSTALL_PYTHON_EXAMPLES  "Install Python examples"   OFF )
 462 OCV_OPTION(INSTALL_ANDROID_EXAMPLES "Install Android examples"  OFF IF ANDROID )
 463 OCV_OPTION(INSTALL_TO_MANGLED_PATHS "Enables mangled install paths, that help with side by side installs." OFF IF (UNIX AND NOT ANDROID AND NOT APPLE_FRAMEWORK AND BUILD_SHARED_LIBS) )
 464 OCV_OPTION(INSTALL_TESTS            "Install accuracy and performance test binaries and test data" OFF)
 465
 466 # OpenCV build options
 467 # ===================================================
 468 OCV_OPTION(ENABLE_CCACHE              "Use ccache"                                               (UNIX AND NOT IOS AND (CMAKE_GENERATOR MATCHES "Makefile" OR CMAKE_GENERATOR MATCHES "Ninja")) )
 469 OCV_OPTION(ENABLE_PRECOMPILED_HEADERS "Use precompiled headers"                                  MSVC IF (MSVC OR (NOT IOS AND NOT CMAKE_CROSSCOMPILING) ) )
 470 OCV_OPTION(ENABLE_SOLUTION_FOLDERS    "Solution folder in Visual Studio or in other IDEs"        (MSVC_IDE OR CMAKE_GENERATOR MATCHES Xcode) )
 471 OCV_OPTION(ENABLE_PROFILING           "Enable profiling in the GCC compiler (Add flags: -g -pg)" OFF  IF CV_GCC )
 472 OCV_OPTION(ENABLE_COVERAGE            "Enable coverage collection with  GCov"                    OFF  IF CV_GCC )
 473 OCV_OPTION(OPENCV_ENABLE_MEMORY_SANITIZER "Better support for memory/address sanitizers"         OFF)
 474 OCV_OPTION(ENABLE_OMIT_FRAME_POINTER  "Enable -fomit-frame-pointer for GCC"                      ON   IF CV_GCC )
 475 OCV_OPTION(ENABLE_POWERPC             "Enable PowerPC for GCC"                                   ON   IF (CV_GCC AND CMAKE_SYSTEM_PROCESSOR MATCHES powerpc.*) )
 476 OCV_OPTION(ENABLE_FAST_MATH           "Enable compiler options for fast math optimizations on FP computations (not recommended)" OFF)
 477 if(NOT IOS AND (NOT ANDROID OR OPENCV_ANDROID_USE_LEGACY_FLAGS))  # Use CPU_BASELINE instead
 478 OCV_OPTION(ENABLE_NEON                "Enable NEON instructions"                                 (NEON OR ANDROID_ARM_NEON OR AARCH64) IF (CV_GCC OR CV_CLANG) AND (ARM OR AARCH64 OR IOS) )
 479 OCV_OPTION(ENABLE_VFPV3               "Enable VFPv3-D32 instructions"                            OFF  IF (CV_GCC OR CV_CLANG) AND (ARM OR AARCH64 OR IOS) )
 480 endif()
 481 OCV_OPTION(ENABLE_NOISY_WARNINGS      "Show all warnings even if they are too noisy"             OFF )
 482 OCV_OPTION(OPENCV_WARNINGS_ARE_ERRORS "Treat warnings as errors"                                 OFF )
 483 OCV_OPTION(ANDROID_EXAMPLES_WITH_LIBS "Build binaries of Android examples with native libraries" OFF  IF ANDROID )
 484 OCV_OPTION(ENABLE_IMPL_COLLECTION     "Collect implementation data on function call"             OFF )
 485 OCV_OPTION(ENABLE_INSTRUMENTATION     "Instrument functions to collect calls trace and performance" OFF )
 486 OCV_OPTION(ENABLE_GNU_STL_DEBUG       "Enable GNU STL Debug mode (defines _GLIBCXX_DEBUG)"       OFF IF ((NOT CMAKE_VERSION VERSION_LESS "2.8.11") AND CV_GCC) )
 487 OCV_OPTION(ENABLE_BUILD_HARDENING     "Enable hardening of the resulting binaries (against security attacks, detects memory corruption, etc)" OFF)
 488 OCV_OPTION(ENABLE_LTO                 "Enable Link Time Optimization" OFF IF CV_GCC OR MSVC)
 489 OCV_OPTION(ENABLE_THIN_LTO            "Enable Thin LTO" OFF IF CV_CLANG)
 490 OCV_OPTION(GENERATE_ABI_DESCRIPTOR    "Generate XML file for abi_compliance_checker tool" OFF IF UNIX)
 491 OCV_OPTION(OPENCV_GENERATE_PKGCONFIG  "Generate .pc file for pkg-config build tool (deprecated)" OFF)
 492 OCV_OPTION(CV_ENABLE_INTRINSICS       "Use intrinsic-based optimized code" ON )
 493 OCV_OPTION(CV_DISABLE_OPTIMIZATION    "Disable explicit optimized code (dispatched code/intrinsics/loop unrolling/etc)" OFF )
 494 OCV_OPTION(CV_TRACE                   "Enable OpenCV code trace" ON)
 495 OCV_OPTION(OPENCV_GENERATE_SETUPVARS  "Generate setup_vars* scripts" ON IF (NOT ANDROID AND NOT APPLE_FRAMEWORK) )
 496 OCV_OPTION(ENABLE_CONFIG_VERIFICATION "Fail build if actual configuration doesn't match requested (WITH_XXX != HAVE_XXX)" OFF)
 497 OCV_OPTION(OPENCV_ENABLE_MEMALIGN     "Enable posix_memalign or memalign usage" ON)
 498
 499 OCV_OPTION(ENABLE_PYLINT              "Add target with Pylint checks"                            (BUILD_DOCS OR BUILD_EXAMPLES) IF (NOT CMAKE_CROSSCOMPILING AND NOT APPLE_FRAMEWORK) )
 500 OCV_OPTION(ENABLE_FLAKE8              "Add target with Python flake8 checker"                    (BUILD_DOCS OR BUILD_EXAMPLES) IF (NOT CMAKE_CROSSCOMPILING AND NOT APPLE_FRAMEWORK) )
 501
 502 if(ENABLE_IMPL_COLLECTION)
 503   add_definitions(-DCV_COLLECT_IMPL_DATA)
 504 endif()
 505
 506 set(OPENCV_MATHJAX_RELPATH "https://cdnjs.cloudflare.com/ajax/libs/mathjax/2.7.0" CACHE STRING "URI to a MathJax installation")
 507
 508 # ----------------------------------------------------------------------------
 509 #  Get actual OpenCV version number from sources
 510 # ----------------------------------------------------------------------------
 511 include(cmake/OpenCVVersion.cmake)
 512
 513 ocv_cmake_hook(POST_OPTIONS)
 514
 515 # ----------------------------------------------------------------------------
 516 #  Build & install layouts
 517 # ----------------------------------------------------------------------------
 518
 519 if(OPENCV_TEST_DATA_PATH)
 520   get_filename_component(OPENCV_TEST_DATA_PATH ${OPENCV_TEST_DATA_PATH} ABSOLUTE)
 521 endif()
 522
 523 # Save libs and executables in the same place
 524 set(EXECUTABLE_OUTPUT_PATH "${CMAKE_BINARY_DIR}/bin" CACHE PATH "Output directory for applications")
 525
 526 if(ANDROID)
 527   set(LIBRARY_OUTPUT_PATH                "${OpenCV_BINARY_DIR}/lib/${ANDROID_NDK_ABI_NAME}")
 528   ocv_update(3P_LIBRARY_OUTPUT_PATH      "${OpenCV_BINARY_DIR}/3rdparty/lib/${ANDROID_NDK_ABI_NAME}")
 529 else()
 530   set(LIBRARY_OUTPUT_PATH                "${OpenCV_BINARY_DIR}/lib")
 531   ocv_update(3P_LIBRARY_OUTPUT_PATH      "${OpenCV_BINARY_DIR}/3rdparty/lib")
 532 endif()
 533
 534 if(ANDROID)
 535   if(ANDROID_ABI MATCHES "NEON")
 536     set(ENABLE_NEON ON)
 537   endif()
 538   if(ANDROID_ABI MATCHES "VFPV3")
 539     set(ENABLE_VFPV3 ON)
 540   endif()
 541 endif()
 542
 543 if(WIN32)
 544   # Postfix of DLLs:
 545   ocv_update(OPENCV_DLLVERSION "${OPENCV_VERSION_MAJOR}${OPENCV_VERSION_MINOR}${OPENCV_VERSION_PATCH}")
 546   ocv_update(OPENCV_DEBUG_POSTFIX d)
 547 else()
 548   # Postfix of so's:
 549   ocv_update(OPENCV_DLLVERSION "")
 550   ocv_update(OPENCV_DEBUG_POSTFIX "")
 551 endif()
 552
 553 if(DEFINED CMAKE_DEBUG_POSTFIX)
 554   set(OPENCV_DEBUG_POSTFIX "${CMAKE_DEBUG_POSTFIX}")
 555 endif()
 556
 557 if((INSTALL_CREATE_DISTRIB AND BUILD_SHARED_LIBS AND NOT DEFINED BUILD_opencv_world) OR APPLE_FRAMEWORK)
 558   set(BUILD_opencv_world ON CACHE INTERNAL "")
 559 endif()
 560
 561 include(cmake/OpenCVInstallLayout.cmake)
 562
 563 # ----------------------------------------------------------------------------
 564 #  Path for build/platform -specific headers
 565 # ----------------------------------------------------------------------------
 566 ocv_update(OPENCV_CONFIG_FILE_INCLUDE_DIR "${CMAKE_BINARY_DIR}/" CACHE PATH "Where to create the platform-dependant cvconfig.h")
 567 ocv_include_directories(${OPENCV_CONFIG_FILE_INCLUDE_DIR})
 568
 569 # ----------------------------------------------------------------------------
 570 #  Path for additional modules
 571 # ----------------------------------------------------------------------------
 572 set(OPENCV_EXTRA_MODULES_PATH "" CACHE PATH "Where to look for additional OpenCV modules (can be ;-separated list of paths)")
 573
 574 # ----------------------------------------------------------------------------
 575 #  Autodetect if we are in a GIT repository
 576 # ----------------------------------------------------------------------------
 577 find_host_package(Git QUIET)
 578
 579 if(NOT DEFINED OPENCV_VCSVERSION AND GIT_FOUND)
 580   ocv_git_describe(OPENCV_VCSVERSION "${OpenCV_SOURCE_DIR}")
 581 elseif(NOT DEFINED OPENCV_VCSVERSION)
 582   # We don't have git:
 583   set(OPENCV_VCSVERSION "unknown")
 584 endif()
 585
 586
 587 # ----------------------------------------------------------------------------
 588 # OpenCV compiler and linker options
 589 # ----------------------------------------------------------------------------
 590 # In case of Makefiles if the user does not setup CMAKE_BUILD_TYPE, assume it's Release:
 591 if(CMAKE_GENERATOR MATCHES "Makefiles|Ninja" AND "${CMAKE_BUILD_TYPE}" STREQUAL "")
 592   set(CMAKE_BUILD_TYPE Release)
 593 endif()
 594
 595 ocv_cmake_hook(POST_CMAKE_BUILD_OPTIONS)
 596
 597 # --- Python Support ---
 598 if(NOT IOS)
 599   include(cmake/OpenCVDetectPython.cmake)
 600 endif()
 601
 602 include(cmake/OpenCVCompilerOptions.cmake)
 603
 604 ocv_cmake_hook(POST_COMPILER_OPTIONS)
 605
 606 # ----------------------------------------------------------------------------
 607 #       CHECK FOR SYSTEM LIBRARIES, OPTIONS, ETC..
 608 # ----------------------------------------------------------------------------
 609 if(UNIX)
 610   if(NOT APPLE_FRAMEWORK OR OPENCV_ENABLE_PKG_CONFIG)
 611     if(CMAKE_CROSSCOMPILING AND NOT DEFINED ENV{PKG_CONFIG_LIBDIR} AND NOT DEFINED ENV{PKG_CONFIG_SYSROOT_DIR}
 612         AND NOT OPENCV_ENABLE_PKG_CONFIG
 613     )
 614       if(NOT PkgConfig_FOUND)
 615         message(STATUS "OpenCV disables pkg-config to avoid using of host libraries. Consider using PKG_CONFIG_LIBDIR to specify target SYSROOT")
 616       elseif(OPENCV_SKIP_PKG_CONFIG_WARNING)
 617         message(WARNING "pkg-config is enabled in cross-compilation mode without defining of PKG_CONFIG_LIBDIR environment variable. This may lead to misconfigured host-based dependencies.")
 618       endif()
 619     elseif(OPENCV_DISABLE_PKG_CONFIG)
 620       if(PkgConfig_FOUND)
 621         message(WARNING "OPENCV_DISABLE_PKG_CONFIG flag has no effect")
 622       endif()
 623     else()
 624       find_package(PkgConfig QUIET)
 625     endif()
 626   endif()
 627   include(CheckFunctionExists)
 628   include(CheckIncludeFile)
 629   include(CheckSymbolExists)
 630
 631   if(NOT APPLE)
 632     CHECK_INCLUDE_FILE(pthread.h HAVE_PTHREAD)
 633     if(ANDROID)
 634       set(OPENCV_LINKER_LIBS ${OPENCV_LINKER_LIBS} dl m log)
 635     elseif(CMAKE_SYSTEM_NAME MATCHES "FreeBSD|NetBSD|DragonFly|OpenBSD|Haiku")
 636       set(OPENCV_LINKER_LIBS ${OPENCV_LINKER_LIBS} m pthread)
 637     elseif(EMSCRIPTEN)
 638       # no need to link to system libs with emscripten
 639     else()
 640       set(OPENCV_LINKER_LIBS ${OPENCV_LINKER_LIBS} dl m pthread rt)
 641     endif()
 642   else()
 643     set(HAVE_PTHREAD 1)
 644   endif()
 645
 646   if(OPENCV_ENABLE_MEMALIGN)
 647     CHECK_SYMBOL_EXISTS(posix_memalign stdlib.h HAVE_POSIX_MEMALIGN)
 648     CHECK_INCLUDE_FILE(malloc.h HAVE_MALLOC_H)
 649     if(HAVE_MALLOC_H)
 650       CHECK_SYMBOL_EXISTS(memalign malloc.h HAVE_MEMALIGN)
 651     endif()
 652     # TODO:
 653     # - _aligned_malloc() on Win32
 654     # - std::aligned_alloc() C++17 / C11
 655   endif()
 656 endif()
 657
 658 include(cmake/OpenCVPCHSupport.cmake)
 659 include(cmake/OpenCVModule.cmake)
 660
 661 # ----------------------------------------------------------------------------
 662 #  Detect endianness of build platform
 663 # ----------------------------------------------------------------------------
 664
 665 if(IOS)
 666   # test_big_endian needs try_compile, which doesn't work for iOS
 667   # http://public.kitware.com/Bug/view.php?id=12288
 668   set(WORDS_BIGENDIAN 0)
 669 else()
 670   include(TestBigEndian)
 671   test_big_endian(WORDS_BIGENDIAN)
 672 endif()
 673
 674 # ----------------------------------------------------------------------------
 675 #  Detect 3rd-party libraries
 676 # ----------------------------------------------------------------------------
 677
 678 if(ANDROID AND WITH_CPUFEATURES)
 679   add_subdirectory(3rdparty/cpufeatures)
 680   set(HAVE_CPUFEATURES 1)
 681 endif()
 682
 683 include(cmake/OpenCVFindFrameworks.cmake)
 684
 685 include(cmake/OpenCVFindLibsGrfmt.cmake)
 686 include(cmake/OpenCVFindLibsGUI.cmake)
 687 include(cmake/OpenCVFindLibsVideo.cmake)
 688 include(cmake/OpenCVFindLibsPerf.cmake)
 689 include(cmake/OpenCVFindLAPACK.cmake)
 690 include(cmake/OpenCVFindProtobuf.cmake)
 691 if(WITH_TENGINE)
 692   include(cmake/OpenCVFindTengine.cmake)
 693 endif()
 694
 695 # ----------------------------------------------------------------------------
 696 #  Detect other 3rd-party libraries/tools
 697 # ----------------------------------------------------------------------------
 698
 699 # --- Java Support ---
 700 if(BUILD_JAVA)
 701   if(ANDROID)
 702     include(cmake/android/OpenCVDetectAndroidSDK.cmake)
 703   else()
 704     include(cmake/OpenCVDetectApacheAnt.cmake)
 705     find_package(JNI)
 706   endif()
 707 endif()
 708
 709 if(ENABLE_PYLINT AND PYTHON_DEFAULT_AVAILABLE)
 710   include(cmake/OpenCVPylint.cmake)
 711 endif()
 712 if(ENABLE_FLAKE8 AND PYTHON_DEFAULT_AVAILABLE)
 713   find_package(Flake8 QUIET)
 714   if(NOT FLAKE8_FOUND OR NOT FLAKE8_EXECUTABLE)
 715     include("${CMAKE_CURRENT_LIST_DIR}/cmake/FindFlake8.cmake")
 716   endif()
 717   if(FLAKE8_FOUND)
 718     add_custom_target(check_flake8
 719         COMMAND "${FLAKE8_EXECUTABLE}" . --count --select=E9,E901,E999,F821,F822,F823 --show-source --statistics --exclude='.git,__pycache__,*.config.py,svgfig.py'
 720         WORKING_DIRECTORY "${OpenCV_SOURCE_DIR}"
 721         COMMENT "Running flake8"
 722     )
 723   endif()
 724 endif()
 725
 726
 727 if(ANDROID AND ANDROID_EXECUTABLE AND ANT_EXECUTABLE AND (ANT_VERSION VERSION_GREATER 1.7) AND (ANDROID_TOOLS_Pkg_Revision GREATER 13))
 728   SET(CAN_BUILD_ANDROID_PROJECTS TRUE)
 729 else()
 730   SET(CAN_BUILD_ANDROID_PROJECTS FALSE)
 731 endif()
 732
 733 # --- OpenCL ---
 734 if(WITH_OPENCL)
 735   include(cmake/OpenCVDetectOpenCL.cmake)
 736 endif()
 737
 738 # --- Halide ---
 739 if(WITH_HALIDE)
 740   include(cmake/OpenCVDetectHalide.cmake)
 741 endif()
 742
 743 # --- VkCom ---
 744 if(WITH_VULKAN)
 745   include(cmake/OpenCVDetectVulkan.cmake)
 746 endif()
 747
 748 # --- Inference Engine ---
 749 if(WITH_INF_ENGINE)
 750   include(cmake/OpenCVDetectInferenceEngine.cmake)
 751 endif()
 752
 753 # --- DirectX ---
 754 if(WITH_DIRECTX)
 755   include(cmake/OpenCVDetectDirectX.cmake)
 756 endif()
 757
 758 if(WITH_VTK)
 759   include(cmake/OpenCVDetectVTK.cmake)
 760 endif()
 761
 762 if(WITH_OPENVX)
 763   include(cmake/FindOpenVX.cmake)
 764 endif()
 765
 766 if(WITH_QUIRC)
 767   add_subdirectory(3rdparty/quirc)
 768   set(HAVE_QUIRC TRUE)
 769 endif()
 770 # ----------------------------------------------------------------------------
 771 # OpenCV HAL
 772 # ----------------------------------------------------------------------------
 773 set(_hal_includes "")
 774 macro(ocv_hal_register HAL_LIBRARIES_VAR HAL_HEADERS_VAR HAL_INCLUDE_DIRS_VAR)
 775   # 1. libraries
 776   foreach (l ${${HAL_LIBRARIES_VAR}})
 777     if(NOT TARGET ${l})
 778       get_filename_component(l "${l}" ABSOLUTE)
 779     endif()
 780     list(APPEND OPENCV_HAL_LINKER_LIBS ${l})
 781   endforeach()
 782   # 2. headers
 783   foreach (h ${${HAL_HEADERS_VAR}})
 784     set(_hal_includes "${_hal_includes}\n#include \"${h}\"")
 785   endforeach()
 786   # 3. include paths
 787   ocv_include_directories(${${HAL_INCLUDE_DIRS_VAR}})
 788 endmacro()
 789
 790 if(NOT DEFINED OpenCV_HAL)
 791   set(OpenCV_HAL "OpenCV_HAL")
 792 endif()
 793
 794 if(HAVE_OPENVX)
 795   if(NOT ";${OpenCV_HAL};" MATCHES ";openvx;")
 796     set(OpenCV_HAL "openvx;${OpenCV_HAL}")
 797   endif()
 798 endif()
 799
 800 if(WITH_CAROTENE)
 801   ocv_debug_message(STATUS "Enable carotene acceleration")
 802   if(NOT ";${OpenCV_HAL};" MATCHES ";carotene;")
 803     set(OpenCV_HAL "carotene;${OpenCV_HAL}")
 804   endif()
 805 endif()
 806
 807 foreach(hal ${OpenCV_HAL})
 808   if(hal STREQUAL "carotene")
 809     if(";${CPU_BASELINE_FINAL};" MATCHES ";NEON;")
 810       add_subdirectory(3rdparty/carotene/hal)
 811       ocv_hal_register(CAROTENE_HAL_LIBRARIES CAROTENE_HAL_HEADERS CAROTENE_HAL_INCLUDE_DIRS)
 812       list(APPEND OpenCV_USED_HAL "carotene (ver ${CAROTENE_HAL_VERSION})")
 813     else()
 814       message(STATUS "Carotene: NEON is not available, disabling carotene...")
 815     endif()
 816   elseif(hal STREQUAL "openvx")
 817     add_subdirectory(3rdparty/openvx)
 818     ocv_hal_register(OPENVX_HAL_LIBRARIES OPENVX_HAL_HEADERS OPENVX_HAL_INCLUDE_DIRS)
 819     list(APPEND OpenCV_USED_HAL "openvx (ver ${OPENVX_HAL_VERSION})")
 820   else()
 821     ocv_debug_message(STATUS "OpenCV HAL: ${hal} ...")
 822     ocv_clear_vars(OpenCV_HAL_LIBRARIES OpenCV_HAL_HEADERS OpenCV_HAL_INCLUDE_DIRS)
 823     find_package(${hal} NO_MODULE QUIET)
 824     if(${hal}_FOUND)
 825       ocv_hal_register(OpenCV_HAL_LIBRARIES OpenCV_HAL_HEADERS OpenCV_HAL_INCLUDE_DIRS)
 826       list(APPEND OpenCV_USED_HAL "${hal} (ver ${${hal}_VERSION})")
 827     endif()
 828   endif()
 829 endforeach()
 830 configure_file("${OpenCV_SOURCE_DIR}/cmake/templates/custom_hal.hpp.in" "${CMAKE_BINARY_DIR}/custom_hal.hpp" @ONLY)
 831 unset(_hal_includes)
 832
 833
 834 # ----------------------------------------------------------------------------
 835 # Code trace support
 836 # ----------------------------------------------------------------------------
 837 if(CV_TRACE)
 838   include(cmake/OpenCVDetectTrace.cmake)
 839 endif()
 840
 841 ocv_cmake_hook(POST_DETECT_DEPENDECIES)  # typo, deprecated (2019-06)
 842 ocv_cmake_hook(POST_DETECT_DEPENDENCIES)
 843
 844 # ----------------------------------------------------------------------------
 845 # Solution folders:
 846 # ----------------------------------------------------------------------------
 847 if(ENABLE_SOLUTION_FOLDERS)
 848   set_property(GLOBAL PROPERTY USE_FOLDERS ON)
 849   set_property(GLOBAL PROPERTY PREDEFINED_TARGETS_FOLDER "CMakeTargets")
 850 endif()
 851
 852 # Extra OpenCV targets: uninstall, package_source, perf, etc.
 853 include(cmake/OpenCVExtraTargets.cmake)
 854
 855 # ----------------------------------------------------------------------------
 856 # Process subdirectories
 857 # ----------------------------------------------------------------------------
 858
 859 # opencv.hpp and legacy headers
 860 add_subdirectory(include)
 861
 862 # Enable compiler options for OpenCV modules/apps/samples only (ignore 3rdparty)
 863 ocv_add_modules_compiler_options()
 864
 865 # OpenCV modules
 866 add_subdirectory(modules)
 867
 868 # Generate targets for documentation
 869 add_subdirectory(doc)
 870
 871 # various data that is used by cv libraries and/or demo applications.
 872 add_subdirectory(data)
 873
 874 # extra applications
 875 if(BUILD_opencv_apps)
 876   add_subdirectory(apps)
 877 endif()
 878
 879 # examples
 880 if(BUILD_EXAMPLES OR BUILD_ANDROID_EXAMPLES OR INSTALL_ANDROID_EXAMPLES OR INSTALL_PYTHON_EXAMPLES OR INSTALL_C_EXAMPLES)
 881   add_subdirectory(samples)
 882 endif()
 883
 884 if(ANDROID)
 885   add_subdirectory(platforms/android/service)
 886 endif()
 887
 888 # ----------------------------------------------------------------------------
 889 # Finalization: generate configuration-based files
 890 # ----------------------------------------------------------------------------
 891
 892 ocv_cmake_hook(PRE_FINALIZE)
 893
 894 # Generate platform-dependent and configuration-dependent headers
 895 include(cmake/OpenCVGenHeaders.cmake)
 896
 897 # Generate opencv.pc for pkg-config command
 898 if(OPENCV_GENERATE_PKGCONFIG)
 899   include(cmake/OpenCVGenPkgconfig.cmake)
 900 endif()
 901
 902 # Generate OpenCV.mk for ndk-build (Android build tool)
 903 include(cmake/OpenCVGenAndroidMK.cmake)
 904
 905 # Generate OpenCVConfig.cmake and OpenCVConfig-version.cmake for cmake projects
 906 include(cmake/OpenCVGenConfig.cmake)
 907
 908 # Generate Info.plist for the IOS framework
 909 if(APPLE_FRAMEWORK)
 910   include(cmake/OpenCVGenInfoPlist.cmake)
 911 endif()
 912
 913 # Generate ABI descriptor
 914 include(cmake/OpenCVGenABI.cmake)
 915
 916 # Generate environment setup file
 917 if(INSTALL_TESTS AND OPENCV_TEST_DATA_PATH)
 918   if(ANDROID)
 919     get_filename_component(TEST_PATH ${OPENCV_TEST_INSTALL_PATH} DIRECTORY)
 920     configure_file("${CMAKE_CURRENT_SOURCE_DIR}/cmake/templates/opencv_run_all_tests_android.sh.in"
 921                    "${CMAKE_BINARY_DIR}/unix-install/opencv_run_all_tests.sh" @ONLY)
 922     install(PROGRAMS "${CMAKE_BINARY_DIR}/unix-install/opencv_run_all_tests.sh"
 923             DESTINATION ./ COMPONENT tests)
 924   elseif(WIN32)
 925     configure_file("${CMAKE_CURRENT_SOURCE_DIR}/cmake/templates/opencv_run_all_tests_windows.cmd.in"
 926                    "${CMAKE_BINARY_DIR}/win-install/opencv_run_all_tests.cmd" @ONLY)
 927     install(PROGRAMS "${CMAKE_BINARY_DIR}/win-install/opencv_run_all_tests.cmd"
 928             DESTINATION ${OPENCV_TEST_INSTALL_PATH} COMPONENT tests)
 929   elseif(UNIX)
 930     configure_file("${CMAKE_CURRENT_SOURCE_DIR}/cmake/templates/opencv_run_all_tests_unix.sh.in"
 931                    "${CMAKE_BINARY_DIR}/unix-install/opencv_run_all_tests.sh" @ONLY)
 932     install(PROGRAMS "${CMAKE_BINARY_DIR}/unix-install/opencv_run_all_tests.sh"
 933             DESTINATION ${OPENCV_TEST_INSTALL_PATH} COMPONENT tests)
 934   endif()
 935 endif()
 936
 937 if(NOT OPENCV_README_FILE)
 938   if(ANDROID)
 939     set(OPENCV_README_FILE ${CMAKE_CURRENT_SOURCE_DIR}/platforms/android/README.android)
 940   endif()
 941 endif()
 942
 943 if(NOT OPENCV_LICENSE_FILE)
 944   set(OPENCV_LICENSE_FILE ${CMAKE_CURRENT_SOURCE_DIR}/LICENSE)
 945 endif()
 946
 947 # for UNIX it does not make sense as LICENSE and readme will be part of the package automatically
 948 if(ANDROID OR NOT UNIX)
 949   install(FILES ${OPENCV_LICENSE_FILE}
 950         PERMISSIONS OWNER_READ OWNER_WRITE GROUP_READ WORLD_READ
 951         DESTINATION ./ COMPONENT libs)
 952   if(OPENCV_README_FILE)
 953     install(FILES ${OPENCV_README_FILE}
 954             PERMISSIONS OWNER_READ OWNER_WRITE GROUP_READ WORLD_READ
 955             DESTINATION ./ COMPONENT libs)
 956   endif()
 957 endif()
 958
 959 if(COMMAND ocv_pylint_finalize)
 960   ocv_pylint_add_directory(${CMAKE_CURRENT_LIST_DIR}/modules/python/test)
 961   ocv_pylint_add_directory(${CMAKE_CURRENT_LIST_DIR}/samples/python)
 962   ocv_pylint_add_directory(${CMAKE_CURRENT_LIST_DIR}/samples/dnn)
 963   ocv_pylint_add_directory_recurse(${CMAKE_CURRENT_LIST_DIR}/samples/python/tutorial_code)
 964   ocv_pylint_finalize()
 965 endif()
 966
 967 if(OPENCV_GENERATE_SETUPVARS)
 968   include(cmake/OpenCVGenSetupVars.cmake)
 969 endif()
 970
 971 # ----------------------------------------------------------------------------
 972 # Summary:
 973 # ----------------------------------------------------------------------------
 974 status("")
 975 status("General configuration for OpenCV ${OPENCV_VERSION} =====================================")
 976 if(OPENCV_VCSVERSION)
 977   status("  Version control:" ${OPENCV_VCSVERSION})
 978 endif()
 979 if(OPENCV_EXTRA_MODULES_PATH AND NOT BUILD_INFO_SKIP_EXTRA_MODULES)
 980   set(__dump_extra_header OFF)
 981   foreach(p ${OPENCV_EXTRA_MODULES_PATH})
 982     if(EXISTS ${p})
 983       if(NOT __dump_extra_header)
 984         set(__dump_extra_header ON)
 985         status("")
 986         status("  Extra modules:")
 987       else()
 988         status("")
 989       endif()
 990       ocv_git_describe(EXTRA_MODULES_VCSVERSION "${p}")
 991       status("    Location (extra):" ${p})
 992       status("    Version control (extra):" ${EXTRA_MODULES_VCSVERSION})
 993     endif()
 994   endforeach()
 995   unset(__dump_extra_header)
 996 endif()
 997
 998 # ========================== build platform ==========================
 999 status("")
1000 status("  Platform:")
1001 if(NOT DEFINED OPENCV_TIMESTAMP
1002     AND NOT CMAKE_VERSION VERSION_LESS 2.8.11
1003     AND NOT BUILD_INFO_SKIP_TIMESTAMP
1004 )
1005   string(TIMESTAMP OPENCV_TIMESTAMP "" UTC)
1006   set(OPENCV_TIMESTAMP "${OPENCV_TIMESTAMP}" CACHE STRING "Timestamp of OpenCV build configuration" FORCE)
1007 endif()
1008 if(OPENCV_TIMESTAMP)
1009   status("    Timestamp:"      ${OPENCV_TIMESTAMP})
1010 endif()
1011 status("    Host:"             ${CMAKE_HOST_SYSTEM_NAME} ${CMAKE_HOST_SYSTEM_VERSION} ${CMAKE_HOST_SYSTEM_PROCESSOR})
1012 if(CMAKE_CROSSCOMPILING)
1013   status("    Target:"         ${CMAKE_SYSTEM_NAME} ${CMAKE_SYSTEM_VERSION} ${CMAKE_SYSTEM_PROCESSOR})
1014 endif()
1015 status("    CMake:"            ${CMAKE_VERSION})
1016 status("    CMake generator:"  ${CMAKE_GENERATOR})
1017 status("    CMake build tool:" ${CMAKE_BUILD_TOOL})
1018 if(MSVC)
1019   status("    MSVC:"           ${MSVC_VERSION})
1020 endif()
1021 if(CMAKE_GENERATOR MATCHES Xcode)
1022   status("    Xcode:"          ${XCODE_VERSION})
1023 endif()
1024 if(NOT CMAKE_GENERATOR MATCHES "Xcode|Visual Studio")
1025   status("    Configuration:"  ${CMAKE_BUILD_TYPE})
1026 endif()
1027
1028
1029 # ========================= CPU code generation mode =========================
1030 status("")
1031 status("  CPU/HW features:")
1032 status("    Baseline:"  "${CPU_BASELINE_FINAL}")
1033 if(NOT CPU_BASELINE STREQUAL CPU_BASELINE_FINAL)
1034   status("      requested:"  "${CPU_BASELINE}")
1035 endif()
1036 if(CPU_BASELINE_REQUIRE)
1037   status("      required:"  "${CPU_BASELINE_REQUIRE}")
1038 endif()
1039 if(CPU_BASELINE_DISABLE)
1040   status("      disabled:"  "${CPU_BASELINE_DISABLE}")
1041 endif()
1042 if(CPU_DISPATCH_FINAL OR CPU_DISPATCH)
1043   status("    Dispatched code generation:"  "${CPU_DISPATCH_FINAL}")
1044   if(NOT CPU_DISPATCH STREQUAL CPU_DISPATCH_FINAL)
1045     status("      requested:"  "${CPU_DISPATCH}")
1046   endif()
1047   if(CPU_DISPATCH_REQUIRE)
1048     status("      required:"  "${CPU_DISPATCH_REQUIRE}")
1049   endif()
1050   foreach(OPT ${CPU_DISPATCH_FINAL})
1051     status("      ${OPT} (${CPU_${OPT}_USAGE_COUNT} files):"  "+ ${CPU_DISPATCH_${OPT}_INCLUDED}")
1052   endforeach()
1053 endif()
1054
1055 # ========================== C/C++ options ==========================
1056 if(CMAKE_CXX_COMPILER_VERSION)
1057   set(OPENCV_COMPILER_STR "${CMAKE_CXX_COMPILER} ${CMAKE_CXX_COMPILER_ARG1} (ver ${CMAKE_CXX_COMPILER_VERSION})")
1058 else()
1059   set(OPENCV_COMPILER_STR "${CMAKE_CXX_COMPILER} ${CMAKE_CXX_COMPILER_ARG1}")
1060 endif()
1061 string(STRIP "${OPENCV_COMPILER_STR}" OPENCV_COMPILER_STR)
1062
1063 status("")
1064 status("  C/C++:")
1065 status("    Built as dynamic libs?:" BUILD_SHARED_LIBS THEN YES ELSE NO)
1066 if(DEFINED CMAKE_CXX_STANDARD AND CMAKE_CXX_STANDARD)
1067   status("    C++ standard:"           "${CMAKE_CXX_STANDARD}")
1068 endif()
1069 status("    C++ Compiler:"           ${OPENCV_COMPILER_STR})
1070 status("    C++ flags (Release):"    ${CMAKE_CXX_FLAGS} ${CMAKE_CXX_FLAGS_RELEASE})
1071 status("    C++ flags (Debug):"      ${CMAKE_CXX_FLAGS} ${CMAKE_CXX_FLAGS_DEBUG})
1072 status("    C Compiler:"             ${CMAKE_C_COMPILER} ${CMAKE_C_COMPILER_ARG1})
1073 status("    C flags (Release):"      ${CMAKE_C_FLAGS} ${CMAKE_C_FLAGS_RELEASE})
1074 status("    C flags (Debug):"        ${CMAKE_C_FLAGS} ${CMAKE_C_FLAGS_DEBUG})
1075 if(WIN32)
1076   status("    Linker flags (Release):" ${CMAKE_EXE_LINKER_FLAGS} ${CMAKE_EXE_LINKER_FLAGS_RELEASE})
1077   status("    Linker flags (Debug):"   ${CMAKE_EXE_LINKER_FLAGS} ${CMAKE_EXE_LINKER_FLAGS_DEBUG})
1078 else()
1079   status("    Linker flags (Release):" ${CMAKE_SHARED_LINKER_FLAGS} ${CMAKE_SHARED_LINKER_FLAGS_RELEASE})
1080   status("    Linker flags (Debug):"   ${CMAKE_SHARED_LINKER_FLAGS} ${CMAKE_SHARED_LINKER_FLAGS_DEBUG})
1081 endif()
1082 status("    ccache:"                  OPENCV_COMPILER_IS_CCACHE THEN YES ELSE NO)
1083 status("    Precompiled headers:"     PCHSupport_FOUND AND ENABLE_PRECOMPILED_HEADERS THEN YES ELSE NO)
1084
1085 # ========================== Dependencies ============================
1086 ocv_get_all_libs(deps_modules deps_extra deps_3rdparty)
1087 status("    Extra dependencies:" ${deps_extra})
1088 status("    3rdparty dependencies:" ${deps_3rdparty})
1089
1090 # ========================== OpenCV modules ==========================
1091 status("")
1092 status("  OpenCV modules:")
1093 set(OPENCV_MODULES_BUILD_ST "")
1094 foreach(the_module ${OPENCV_MODULES_BUILD})
1095   if(NOT OPENCV_MODULE_${the_module}_CLASS STREQUAL "INTERNAL" OR the_module STREQUAL "opencv_ts")
1096     list(APPEND OPENCV_MODULES_BUILD_ST "${the_module}")
1097   endif()
1098 endforeach()
1099 string(REPLACE "opencv_" "" OPENCV_MODULES_BUILD_ST          "${OPENCV_MODULES_BUILD_ST}")
1100 string(REPLACE "opencv_" "" OPENCV_MODULES_DISABLED_USER_ST  "${OPENCV_MODULES_DISABLED_USER}")
1101 string(REPLACE "opencv_" "" OPENCV_MODULES_DISABLED_AUTO_ST  "${OPENCV_MODULES_DISABLED_AUTO}")
1102 string(REPLACE "opencv_" "" OPENCV_MODULES_DISABLED_FORCE_ST "${OPENCV_MODULES_DISABLED_FORCE}")
1103 list(SORT OPENCV_MODULES_BUILD_ST)
1104 list(SORT OPENCV_MODULES_DISABLED_USER_ST)
1105 list(SORT OPENCV_MODULES_DISABLED_AUTO_ST)
1106 list(SORT OPENCV_MODULES_DISABLED_FORCE_ST)
1107 status("    To be built:"            OPENCV_MODULES_BUILD          THEN ${OPENCV_MODULES_BUILD_ST}          ELSE "-")
1108 status("    Disabled:"               OPENCV_MODULES_DISABLED_USER  THEN ${OPENCV_MODULES_DISABLED_USER_ST}  ELSE "-")
1109 status("    Disabled by dependency:" OPENCV_MODULES_DISABLED_AUTO  THEN ${OPENCV_MODULES_DISABLED_AUTO_ST}  ELSE "-")
1110 status("    Unavailable:"            OPENCV_MODULES_DISABLED_FORCE THEN ${OPENCV_MODULES_DISABLED_FORCE_ST} ELSE "-")
1111
1112 ocv_build_features_string(apps_status
1113   IF BUILD_TESTS AND HAVE_opencv_ts THEN "tests"
1114   IF BUILD_PERF_TESTS AND HAVE_opencv_ts THEN "perf_tests"
1115   IF BUILD_EXAMPLES THEN "examples"
1116   IF BUILD_opencv_apps THEN "apps"
1117   IF BUILD_ANDROID_SERVICE THEN "android_service"
1118   IF (BUILD_ANDROID_EXAMPLES OR INSTALL_ANDROID_EXAMPLES) AND CAN_BUILD_ANDROID_PROJECTS THEN "android_examples"
1119   ELSE "-")
1120 status("    Applications:" "${apps_status}")
1121 ocv_build_features_string(docs_status
1122     IF TARGET doxygen_cpp THEN "doxygen"
1123     IF TARGET doxygen_python THEN "python"
1124     IF TARGET doxygen_javadoc THEN "javadoc"
1125     IF BUILD_opencv_js OR DEFINED OPENCV_JS_LOCATION THEN "js"
1126     ELSE "NO"
1127 )
1128 status("    Documentation:" "${docs_status}")
1129 status("    Non-free algorithms:" OPENCV_ENABLE_NONFREE THEN "YES" ELSE "NO")
1130
1131 # ========================== Android details ==========================
1132 if(ANDROID)
1133   status("")
1134   if(DEFINED ANDROID_NDK_REVISION)
1135     set(__msg "${ANDROID_NDK} (ver ${ANDROID_NDK_REVISION})")
1136   else()
1137     set(__msg "location: ${ANDROID_NDK}")
1138   endif()
1139   status("  Android NDK: " ${__msg})
1140   status("    Android ABI:" ${ANDROID_ABI})
1141   if(BUILD_WITH_STANDALONE_TOOLCHAIN)
1142     status("    NDK toolchain:" "standalone: ${ANDROID_STANDALONE_TOOLCHAIN}")
1143   elseif(BUILD_WITH_ANDROID_NDK OR DEFINED ANDROID_TOOLCHAIN_NAME)
1144     status("    NDK toolchain:" "${ANDROID_TOOLCHAIN_NAME}")
1145   endif()
1146   status("    STL type:" ${ANDROID_STL})
1147   status("    Native API level:" ${ANDROID_NATIVE_API_LEVEL})
1148
1149   if(BUILD_ANDROID_PROJECTS)
1150     status("  Android SDK: " "${ANDROID_SDK} (tools: ${ANDROID_SDK_TOOLS_VERSION} build tools: ${ANDROID_SDK_BUILD_TOOLS_VERSION})")
1151     if(ANDROID_EXECUTABLE)
1152       status("    android tool:"  "${ANDROID_EXECUTABLE}")
1153     endif()
1154   else()
1155     status("  Android SDK: " "not used, projects are not built")
1156   endif()
1157   if(DEFINED ANDROID_SDK_COMPATIBLE_TARGET)
1158     status("    SDK target:" "${ANDROID_SDK_COMPATIBLE_TARGET}")
1159   endif()
1160   if(DEFINED ANDROID_PROJECTS_BUILD_TYPE)
1161     if(ANDROID_PROJECTS_BUILD_TYPE STREQUAL "ANT")
1162       status("    Projects build scripts:" "Ant/Eclipse compatible")
1163     elseif(ANDROID_PROJECTS_BUILD_TYPE STREQUAL "ANT")
1164       status("    Projects build scripts:" "Gradle")
1165     endif()
1166   endif()
1167 endif()
1168
1169 # ================== Windows RT features ==================
1170 if(WIN32)
1171 status("")
1172 status("  Windows RT support:" WINRT THEN YES ELSE NO)
1173   if(WINRT)
1174     status("    Building for Microsoft platform: " ${CMAKE_SYSTEM_NAME})
1175     status("    Building for architectures: " ${CMAKE_VS_EFFECTIVE_PLATFORMS})
1176     status("    Building for version: " ${CMAKE_SYSTEM_VERSION})
1177     if (DEFINED ENABLE_WINRT_MODE_NATIVE)
1178       status("    Building for C++ without CX extensions")
1179     endif()
1180   endif()
1181 endif(WIN32)
1182
1183 # ========================== GUI ==========================
1184 status("")
1185 status("  GUI: ")
1186
1187 if(WITH_QT OR HAVE_QT)
1188   if(HAVE_QT5)
1189     status("    QT:" "YES (ver ${Qt5Core_VERSION_STRING})")
1190     status("      QT OpenGL support:" HAVE_QT_OPENGL THEN "YES (${Qt5OpenGL_LIBRARIES} ${Qt5OpenGL_VERSION_STRING})" ELSE NO)
1191   elseif(HAVE_QT)
1192     status("    QT:" "YES (ver ${QT_VERSION_MAJOR}.${QT_VERSION_MINOR}.${QT_VERSION_PATCH} ${QT_EDITION})")
1193     status("      QT OpenGL support:" HAVE_QT_OPENGL THEN "YES (${QT_QTOPENGL_LIBRARY})" ELSE NO)
1194   else()
1195     status("    QT:" "NO")
1196   endif()
1197 endif()
1198
1199 if(WITH_WIN32UI)
1200   status("    Win32 UI:" HAVE_WIN32UI THEN YES ELSE NO)
1201 endif()
1202
1203 if(HAVE_COCOA)  # APPLE
1204   status("    Cocoa:"  YES)
1205 endif()
1206
1207 if(WITH_GTK OR HAVE_GTK)
1208   if(HAVE_GTK3)
1209     status("    GTK+:" "YES (ver ${GTK3_VERSION})")
1210   elseif(HAVE_GTK)
1211     status("    GTK+:" "YES (ver ${GTK2_VERSION})")
1212   else()
1213     status("    GTK+:" "NO")
1214   endif()
1215   if(HAVE_GTK)
1216     status(  "      GThread :" HAVE_GTHREAD THEN "YES (ver ${GTHREAD_VERSION})" ELSE NO)
1217     status(  "      GtkGlExt:" HAVE_GTKGLEXT THEN "YES (ver ${GTKGLEXT_VERSION})" ELSE NO)
1218   endif()
1219 endif()
1220
1221 if(WITH_OPENGL OR HAVE_OPENGL)
1222   status("    OpenGL support:" HAVE_OPENGL THEN "YES (${OPENGL_LIBRARIES})" ELSE NO)
1223 endif()
1224
1225 if(WITH_VTK OR HAVE_VTK)
1226   status("    VTK support:" HAVE_VTK THEN "YES (ver ${VTK_VERSION})" ELSE NO)
1227 endif()
1228
1229 # ========================== MEDIA IO ==========================
1230 status("")
1231 status("  Media I/O: ")
1232 status("    ZLib:"   ZLIB_FOUND THEN "${ZLIB_LIBRARIES} (ver ${ZLIB_VERSION_STRING})" ELSE "build (ver ${ZLIB_VERSION_STRING})")
1233
1234 if(WITH_JPEG OR HAVE_JPEG)
1235   if(NOT HAVE_JPEG)
1236     status("    JPEG:" NO)
1237   elseif(BUILD_JPEG)
1238     status("    JPEG:" "build-${JPEG_LIBRARY} (ver ${JPEG_LIB_VERSION})")
1239   else()
1240     status("    JPEG:" "${JPEG_LIBRARY} (ver ${JPEG_LIB_VERSION})")
1241   endif()
1242 endif()
1243
1244 if(WITH_WEBP OR HAVE_WEBP)
1245   status("    WEBP:" WEBP_FOUND THEN "${WEBP_LIBRARY} (ver ${WEBP_VERSION})" ELSE "build (ver ${WEBP_VERSION})")
1246 endif()
1247
1248 if(WITH_PNG OR HAVE_PNG)
1249   status("    PNG:"  PNG_FOUND  THEN "${PNG_LIBRARY} (ver ${PNG_VERSION})" ELSE "build (ver ${PNG_VERSION})")
1250 endif()
1251
1252 if(WITH_TIFF OR HAVE_TIFF)
1253   status("    TIFF:" TIFF_FOUND THEN "${TIFF_LIBRARY} (ver ${TIFF_VERSION} / ${TIFF_VERSION_STRING})" ELSE "build (ver ${TIFF_VERSION} - ${TIFF_VERSION_STRING})")
1254 endif()
1255
1256 if(HAVE_OPENJPEG)
1257   status("    JPEG 2000:" "OpenJPEG (ver ${OPENJPEG_MAJOR_VERSION}.${OPENJPEG_MINOR_VERSION}.${OPENJPEG_BUILD_VERSION})")
1258 elseif(HAVE_JASPER)
1259   status("    JPEG 2000:" JASPER_FOUND THEN "${JASPER_LIBRARY} (ver ${JASPER_VERSION_STRING})" ELSE "build Jasper (ver ${JASPER_VERSION_STRING})")
1260 elseif(WITH_OPENJPEG OR WITH_JASPER)
1261   status("    JPEG 2000:" "NO")
1262 endif()
1263
1264 if(WITH_OPENEXR OR HAVE_OPENEXR)
1265   if(HAVE_OPENEXR)
1266     status("    OpenEXR:" OPENEXR_FOUND THEN "${OPENEXR_LIBRARIES} (ver ${OPENEXR_VERSION})" ELSE "build (ver ${OPENEXR_VERSION})")
1267   else()
1268     status("    OpenEXR:" "NO")
1269   endif()
1270 endif()
1271
1272 if(WITH_GDAL OR HAVE_GDAL)
1273   status("    GDAL:" HAVE_GDAL THEN "YES (${GDAL_LIBRARY})" ELSE "NO")
1274 endif()
1275
1276 if(WITH_GDCM OR HAVE_GDCM)
1277   status("    GDCM:" HAVE_GDCM THEN "YES (${GDCM_VERSION})" ELSE "NO")
1278 endif()
1279
1280 if(WITH_IMGCODEC_HDR OR DEFINED HAVE_IMGCODEC_HDR)
1281   status("    HDR:" HAVE_IMGCODEC_HDR THEN "YES" ELSE "NO")
1282 endif()
1283
1284 if(WITH_IMGCODEC_SUNRASTER OR DEFINED HAVE_IMGCODEC_SUNRASTER)
1285   status("    SUNRASTER:" HAVE_IMGCODEC_SUNRASTER THEN "YES" ELSE "NO")
1286 endif()
1287
1288 if(WITH_IMGCODEC_PXM OR DEFINED HAVE_IMGCODEC_PXM)
1289   status("    PXM:" HAVE_IMGCODEC_PXM THEN "YES" ELSE "NO")
1290 endif()
1291
1292 if(WITH_IMGCODEC_PFM OR DEFINED HAVE_IMGCODEC_PFM)
1293   status("    PFM:" HAVE_IMGCODEC_PFM THEN "YES" ELSE "NO")
1294 endif()
1295
1296 # ========================== VIDEO IO ==========================
1297 status("")
1298 status("  Video I/O:")
1299
1300 if(WITH_1394 OR HAVE_DC1394_2)
1301   status("    DC1394:" HAVE_DC1394_2 THEN "YES (${DC1394_2_VERSION})" ELSE NO)
1302 endif()
1303
1304 if(WITH_FFMPEG OR HAVE_FFMPEG)
1305   if(OPENCV_FFMPEG_USE_FIND_PACKAGE)
1306     status("    FFMPEG:"       HAVE_FFMPEG         THEN "YES (find_package)"                       ELSE "NO (find_package)")
1307   elseif(WIN32)
1308     status("    FFMPEG:"       HAVE_FFMPEG         THEN "YES (prebuilt binaries)"                  ELSE NO)
1309   else()
1310     status("    FFMPEG:"       HAVE_FFMPEG         THEN YES ELSE NO)
1311   endif()
1312   status("      avcodec:"      FFMPEG_libavcodec_VERSION    THEN "YES (${FFMPEG_libavcodec_VERSION})"    ELSE NO)
1313   status("      avformat:"     FFMPEG_libavformat_VERSION   THEN "YES (${FFMPEG_libavformat_VERSION})"   ELSE NO)
1314   status("      avutil:"       FFMPEG_libavutil_VERSION     THEN "YES (${FFMPEG_libavutil_VERSION})"     ELSE NO)
1315   status("      swscale:"      FFMPEG_libswscale_VERSION    THEN "YES (${FFMPEG_libswscale_VERSION})"    ELSE NO)
1316   status("      avresample:"   FFMPEG_libavresample_VERSION THEN "YES (${FFMPEG_libavresample_VERSION})" ELSE NO)
1317 endif()
1318
1319 if(WITH_GSTREAMER OR HAVE_GSTREAMER)
1320   status("    GStreamer:" HAVE_GSTREAMER THEN "YES (${GSTREAMER_VERSION})" ELSE NO)
1321 endif()
1322
1323 if(WITH_OPENNI2 OR HAVE_OPENNI2)
1324   status("    OpenNI2:"        HAVE_OPENNI2    THEN "YES (${OPENNI2_VERSION})" ELSE NO)
1325 endif()
1326
1327 if(WITH_PVAPI OR HAVE_PVAPI)
1328   status("    PvAPI:" HAVE_PVAPI THEN YES ELSE NO)
1329 endif()
1330
1331 if(WITH_ARAVIS OR HAVE_ARAVIS_API)
1332   status("    Aravis SDK:" HAVE_ARAVIS_API THEN "YES (${ARAVIS_VERSION})" ELSE NO)
1333 endif()
1334
1335 if(WITH_AVFOUNDATION OR HAVE_AVFOUNDATION)
1336   status("    AVFoundation:" HAVE_AVFOUNDATION THEN YES ELSE NO)
1337 endif()
1338
1339 if(HAVE_CAP_IOS)
1340   status("    iOS capture:" YES)
1341 endif()
1342
1343 if(WITH_V4L OR HAVE_V4L)
1344   ocv_build_features_string(v4l_status
1345     IF HAVE_CAMV4L2 THEN "linux/videodev2.h"
1346     IF HAVE_VIDEOIO THEN "sys/videoio.h"
1347     ELSE "NO")
1348   status("    v4l/v4l2:" HAVE_V4L THEN "YES (${v4l_status})" ELSE NO)
1349 endif()
1350
1351 if(WITH_DSHOW OR HAVE_DSHOW)
1352   status("    DirectShow:" HAVE_DSHOW THEN YES ELSE NO)
1353 endif()
1354
1355 if(WITH_MSMF OR HAVE_MSMF)
1356   status("    Media Foundation:" HAVE_MSMF THEN YES ELSE NO)
1357   status("      DXVA:" HAVE_MSMF_DXVA THEN YES ELSE NO)
1358 endif()
1359
1360 if(WITH_XIMEA OR HAVE_XIMEA)
1361   status("    XIMEA:" HAVE_XIMEA THEN YES ELSE NO)
1362 endif()
1363
1364 if(WITH_XINE OR HAVE_XINE)
1365   status("    Xine:"           HAVE_XINE           THEN "YES (ver ${XINE_VERSION})"     ELSE NO)
1366 endif()
1367
1368 if(WITH_LIBREALSENSE OR HAVE_LIBREALSENSE)
1369   status("    Intel RealSense:" HAVE_LIBREALSENSE THEN "YES (${LIBREALSENSE_VERSION})" ELSE NO)
1370 endif()
1371
1372 if(WITH_MFX OR HAVE_MFX)
1373   status("    Intel Media SDK:" HAVE_MFX      THEN "YES (${MFX_LIBRARY})" ELSE NO)
1374 endif()
1375
1376 if(WITH_GPHOTO2 OR HAVE_GPHOTO2)
1377   status("    gPhoto2:"        HAVE_GPHOTO2        THEN "YES"                                 ELSE NO)
1378 endif()
1379
1380 # Order is similar to CV_PARALLEL_FRAMEWORK in core/src/parallel.cpp
1381 ocv_build_features_string(parallel_status EXCLUSIVE
1382   IF HAVE_TBB THEN "TBB (ver ${TBB_VERSION_MAJOR}.${TBB_VERSION_MINOR} interface ${TBB_INTERFACE_VERSION})"
1383   IF HAVE_HPX THEN "HPX"
1384   IF HAVE_OPENMP THEN "OpenMP"
1385   IF HAVE_GCD THEN "GCD"
1386   IF WINRT OR HAVE_CONCURRENCY THEN "Concurrency"
1387   IF HAVE_PTHREADS_PF THEN "pthreads"
1388   ELSE "none")
1389 status("")
1390 status("  Parallel framework:" "${parallel_status}")
1391
1392 if(CV_TRACE OR OPENCV_TRACE)
1393   ocv_build_features_string(trace_status EXCLUSIVE
1394     IF HAVE_ITT THEN "with Intel ITT"
1395     ELSE "built-in")
1396   status("")
1397   status("  Trace: " OPENCV_TRACE THEN "YES (${trace_status})" ELSE NO)
1398 endif()
1399
1400 # ========================== Other third-party libraries ==========================
1401 status("")
1402 status("  Other third-party libraries:")
1403
1404 if(WITH_IPP AND HAVE_IPP)
1405   status("    Intel IPP:" "${IPP_VERSION_STR} [${IPP_VERSION_MAJOR}.${IPP_VERSION_MINOR}.${IPP_VERSION_BUILD}]")
1406   status("           at:" "${IPP_ROOT_DIR}")
1407   if(NOT HAVE_IPP_ICV)
1408     status("       linked:" BUILD_WITH_DYNAMIC_IPP THEN "dynamic" ELSE "static")
1409   endif()
1410   if(HAVE_IPP_IW)
1411     if(BUILD_IPP_IW)
1412       status("    Intel IPP IW:" "sources (${IW_VERSION_MAJOR}.${IW_VERSION_MINOR}.${IW_VERSION_UPDATE})")
1413     else()
1414       status("    Intel IPP IW:" "binaries (${IW_VERSION_MAJOR}.${IW_VERSION_MINOR}.${IW_VERSION_UPDATE})")
1415     endif()
1416     status("              at:" "${IPP_IW_PATH}")
1417   else()
1418     status("    Intel IPP IW:"   NO)
1419   endif()
1420 endif()
1421
1422 if(WITH_VA OR HAVE_VA)
1423   status("    VA:"            HAVE_VA          THEN "YES" ELSE NO)
1424 endif()
1425
1426 if(WITH_VA_INTEL OR HAVE_VA_INTEL)
1427   status("    Intel VA-API/OpenCL:"  HAVE_VA_INTEL       THEN "YES (OpenCL: ${VA_INTEL_IOCL_ROOT})" ELSE NO)
1428 endif()
1429
1430 if(WITH_TENGINE OR HAVE_TENGINE)
1431   status("    Tengine:"      HAVE_TENGINE     THEN "YES (${TENGINE_LIBRARIES})" ELSE NO)
1432 endif()
1433
1434 if(WITH_LAPACK OR HAVE_LAPACK)
1435   status("    Lapack:"      HAVE_LAPACK     THEN "YES (${LAPACK_LIBRARIES})" ELSE NO)
1436 endif()
1437
1438 if(WITH_HALIDE OR HAVE_HALIDE)
1439   status("    Halide:"     HAVE_HALIDE      THEN "YES (${HALIDE_LIBRARIES} ${HALIDE_INCLUDE_DIRS})" ELSE NO)
1440 endif()
1441
1442 if(WITH_INF_ENGINE OR INF_ENGINE_TARGET)
1443   if(INF_ENGINE_TARGET)
1444     list(GET INF_ENGINE_TARGET 0 ie_target)
1445     set(__msg "YES (${INF_ENGINE_RELEASE} / ${INF_ENGINE_VERSION})")
1446     get_target_property(_lib ${ie_target} IMPORTED_LOCATION)
1447     get_target_property(_lib_imp_rel ${ie_target} IMPORTED_IMPLIB_RELEASE)
1448     get_target_property(_lib_imp_dbg ${ie_target} IMPORTED_IMPLIB_DEBUG)
1449     get_target_property(_lib_rel ${ie_target} IMPORTED_LOCATION_RELEASE)
1450     get_target_property(_lib_dbg ${ie_target} IMPORTED_LOCATION_DEBUG)
1451     ocv_build_features_string(_lib
1452       IF _lib THEN "${_lib}"
1453       IF _lib_imp_rel AND _lib_imp_dbg THEN "${_lib_imp_rel} / ${_lib_imp_dbg}"
1454       IF _lib_rel AND _lib_dbg THEN "${_lib_rel} / ${_lib_dbg}"
1455       IF _lib_rel  THEN "${_lib_rel}"
1456       IF _lib_dbg  THEN "${_lib_dbg}"
1457       ELSE "unknown"
1458     )
1459     get_target_property(_inc ${ie_target} INTERFACE_INCLUDE_DIRECTORIES)
1460     status("    Inference Engine:" "${__msg}")
1461     status("        * libs:" "${_lib}")
1462     status("        * includes:" "${_inc}")
1463   else()
1464     status("    Inference Engine:"     "NO")
1465   endif()
1466 endif()
1467 if(WITH_NGRAPH OR HAVE_NGRAPH)
1468   if(HAVE_NGRAPH)
1469     set(__target ngraph::ngraph)
1470     set(__msg "YES (${ngraph_VERSION})")
1471     get_target_property(_lib ${__target} IMPORTED_LOCATION)
1472     get_target_property(_lib_imp_rel ${__target} IMPORTED_IMPLIB_RELEASE)
1473     get_target_property(_lib_imp_dbg ${__target} IMPORTED_IMPLIB_DEBUG)
1474     get_target_property(_lib_rel ${__target} IMPORTED_LOCATION_RELEASE)
1475     get_target_property(_lib_dbg ${__target} IMPORTED_LOCATION_DEBUG)
1476     ocv_build_features_string(_lib
1477       IF _lib THEN "${_lib}"
1478       IF _lib_imp_rel AND _lib_imp_dbg THEN "${_lib_imp_rel} / ${_lib_imp_dbg}"
1479       IF _lib_rel AND _lib_dbg THEN "${_lib_rel} / ${_lib_dbg}"
1480       IF _lib_rel  THEN "${_lib_rel}"
1481       IF _lib_dbg  THEN "${_lib_dbg}"
1482       ELSE "unknown"
1483     )
1484     get_target_property(_inc ${__target} INTERFACE_INCLUDE_DIRECTORIES)
1485     status("    nGraph:" "${__msg}")
1486     status("        * libs:" "${_lib}")
1487     status("        * includes:" "${_inc}")
1488   else()
1489     status("    nGraph:"     "NO")
1490   endif()
1491 endif()
1492
1493 if(WITH_EIGEN OR HAVE_EIGEN)
1494   status("    Eigen:"      HAVE_EIGEN       THEN "YES (ver ${EIGEN_WORLD_VERSION}.${EIGEN_MAJOR_VERSION}.${EIGEN_MINOR_VERSION})" ELSE NO)
1495 endif()
1496
1497 if(WITH_OPENVX OR HAVE_OPENVX)
1498   status("    OpenVX:"     HAVE_OPENVX      THEN "YES (${OPENVX_LIBRARIES})" ELSE "NO")
1499 endif()
1500
1501 status("    Custom HAL:" OpenCV_USED_HAL  THEN "YES (${OpenCV_USED_HAL})" ELSE "NO")
1502
1503 foreach(s ${CUSTOM_STATUS})
1504   status(${CUSTOM_STATUS_${s}})
1505 endforeach()
1506
1507 if(WITH_CUDA OR HAVE_CUDA)
1508   ocv_build_features_string(cuda_features
1509     IF HAVE_CUFFT THEN "CUFFT"
1510     IF HAVE_CUBLAS THEN "CUBLAS"
1511     IF HAVE_NVCUVID THEN "NVCUVID"
1512     IF CUDA_FAST_MATH THEN "FAST_MATH"
1513     ELSE "no extra features")
1514   status("")
1515   status("  NVIDIA CUDA:" HAVE_CUDA THEN "YES (ver ${CUDA_VERSION_STRING}, ${cuda_features})" ELSE NO)
1516   if(HAVE_CUDA)
1517     status("    NVIDIA GPU arch:"      ${OPENCV_CUDA_ARCH_BIN})
1518     status("    NVIDIA PTX archs:"     ${OPENCV_CUDA_ARCH_PTX})
1519   endif()
1520  endif()
1521
1522  if(WITH_CUDNN OR HAVE_CUDNN)
1523     status("")
1524     status("  cuDNN:" HAVE_CUDNN THEN "YES (ver ${CUDNN_VERSION})" ELSE NO)
1525 endif()
1526
1527 if(WITH_VULKAN OR HAVE_VULKAN)
1528   status("")
1529   status("  Vulkan:"     HAVE_VULKAN THEN "YES" ELSE "NO")
1530   if(HAVE_VULKAN)
1531     status("    Include path:"  VULKAN_INCLUDE_DIRS THEN "${VULKAN_INCLUDE_DIRS}" ELSE "NO")
1532     status("    Link libraries:" VULKAN_LIBRARIES THEN "${VULKAN_LIBRARIES}" ELSE "Dynamic load")
1533   endif()
1534 endif()
1535
1536 if(WITH_OPENCL OR HAVE_OPENCL)
1537   ocv_build_features_string(opencl_features
1538     IF HAVE_OPENCL_SVM THEN "SVM"
1539     IF HAVE_CLAMDFFT THEN "AMDFFT"
1540     IF HAVE_CLAMDBLAS THEN "AMDBLAS"
1541     IF HAVE_OPENCL_D3D11_NV THEN "NVD3D11"
1542     ELSE "no extra features")
1543   status("")
1544   status("  OpenCL:"     HAVE_OPENCL   THEN   "YES (${opencl_features})" ELSE "NO")
1545   if(HAVE_OPENCL)
1546     status("    Include path:"  OPENCL_INCLUDE_DIRS THEN "${OPENCL_INCLUDE_DIRS}" ELSE "NO")
1547     status("    Link libraries:"       OPENCL_LIBRARIES THEN "${OPENCL_LIBRARIES}" ELSE "Dynamic load")
1548   endif()
1549 endif()
1550
1551 # ========================== python ==========================
1552 if(BUILD_opencv_python2)
1553   status("")
1554   status("  Python 2:")
1555   status("    Interpreter:"     PYTHON2INTERP_FOUND  THEN "${PYTHON2_EXECUTABLE} (ver ${PYTHON2_VERSION_STRING})"       ELSE NO)
1556   if(PYTHON2LIBS_VERSION_STRING)
1557     status("    Libraries:"   HAVE_opencv_python2  THEN  "${PYTHON2_LIBRARIES} (ver ${PYTHON2LIBS_VERSION_STRING})"   ELSE NO)
1558   else()
1559     status("    Libraries:"   HAVE_opencv_python2  THEN  "${PYTHON2_LIBRARIES}"                                      ELSE NO)
1560   endif()
1561   status("    numpy:"         PYTHON2_NUMPY_INCLUDE_DIRS THEN "${PYTHON2_NUMPY_INCLUDE_DIRS} (ver ${PYTHON2_NUMPY_VERSION})" ELSE "NO (Python wrappers can not be generated)")
1562   status("    install path:"  HAVE_opencv_python2  THEN "${__INSTALL_PATH_PYTHON2}"                            ELSE "-")
1563 endif()
1564
1565 if(BUILD_opencv_python3)
1566   status("")
1567   status("  Python 3:")
1568   status("    Interpreter:"     PYTHON3INTERP_FOUND  THEN "${PYTHON3_EXECUTABLE} (ver ${PYTHON3_VERSION_STRING})"       ELSE NO)
1569   if(PYTHON3LIBS_VERSION_STRING)
1570     status("    Libraries:"   HAVE_opencv_python3  THEN  "${PYTHON3_LIBRARIES} (ver ${PYTHON3LIBS_VERSION_STRING})"   ELSE NO)
1571   else()
1572     status("    Libraries:"   HAVE_opencv_python3  THEN  "${PYTHON3_LIBRARIES}"                                      ELSE NO)
1573   endif()
1574   status("    numpy:"         PYTHON3_NUMPY_INCLUDE_DIRS THEN "${PYTHON3_NUMPY_INCLUDE_DIRS} (ver ${PYTHON3_NUMPY_VERSION})" ELSE "NO (Python3 wrappers can not be generated)")
1575   status("    install path:"  HAVE_opencv_python3  THEN "${__INSTALL_PATH_PYTHON3}"                            ELSE "-")
1576 endif()
1577
1578 status("")
1579 status("  Python (for build):"  PYTHON_DEFAULT_AVAILABLE THEN "${PYTHON_DEFAULT_EXECUTABLE}" ELSE NO)
1580 if(PYLINT_FOUND AND PYLINT_EXECUTABLE)
1581   status("    Pylint:"  PYLINT_FOUND THEN "${PYLINT_EXECUTABLE} (ver: ${PYLINT_VERSION}, checks: ${PYLINT_TOTAL_TARGETS})" ELSE NO)
1582 endif()
1583 if(FLAKE8_FOUND AND FLAKE8_EXECUTABLE)
1584   status("    Flake8:"  FLAKE8_FOUND THEN "${FLAKE8_EXECUTABLE} (ver: ${FLAKE8_VERSION})" ELSE NO)
1585 endif()
1586
1587 # ========================== java ==========================
1588 if(BUILD_JAVA)
1589   status("")
1590   status("  Java:"            BUILD_FAT_JAVA_LIB  THEN "export all functions"                                      ELSE "")
1591   status("    ant:"           ANT_EXECUTABLE      THEN "${ANT_EXECUTABLE} (ver ${ANT_VERSION})"                    ELSE NO)
1592   if(NOT ANDROID)
1593     status("    JNI:"         JNI_INCLUDE_DIRS    THEN "${JNI_INCLUDE_DIRS}"                                       ELSE NO)
1594   endif()
1595   status("    Java wrappers:" HAVE_opencv_java                                                            THEN YES ELSE NO)
1596   status("    Java tests:"    BUILD_TESTS AND opencv_test_java_BINARY_DIR                                 THEN YES ELSE NO)
1597 endif()
1598
1599 # ========================== Objective-C =======================
1600 if(BUILD_OBJC)
1601   status("")
1602   status("  Objective-C wrappers:" HAVE_opencv_objc                                                       THEN YES ELSE NO)
1603 endif()
1604
1605 ocv_cmake_hook(STATUS_DUMP_EXTRA)
1606
1607 # ========================== auxiliary ==========================
1608 status("")
1609 status("  Install to:" "${CMAKE_INSTALL_PREFIX}")
1610 status("-----------------------------------------------------------------")
1611 status("")
1612
1613
1614 ocv_finalize_status()
1615
1616 if(ENABLE_CONFIG_VERIFICATION)
1617   ocv_verify_config()
1618 endif()
1619
1620 ocv_cmake_hook(POST_FINALIZE)
1621
1622 # ----------------------------------------------------------------------------
1623 # CPack stuff
1624 # ----------------------------------------------------------------------------
1625
1626 include(cmake/OpenCVPackaging.cmake)
1627
1628 # This should be the last command
1629 ocv_cmake_dump_vars("" TOFILE "CMakeVars.txt")
1630 ocv_cmake_eval(DEBUG_POST ONCE)