CMakeLists.txt

   1 cmake_minimum_required (VERSION 2.8.4 FATAL_ERROR)
   2
   3 # ----------------------------------------------------------------------------
   4 # includes
   5 set (CMAKE_MODULE_PATH "${CMAKE_CURRENT_SOURCE_DIR}/cmake")
   6 include (utils)
   7
   8 # ----------------------------------------------------------------------------
   9 # package information
  10 set (PACKAGE_NAME      "gflags")
  11 set (PACKAGE_VERSION   "2.1")
  12 set (PACKAGE_STRING    "${PACKAGE_NAME} ${PACKAGE_VERSION}")
  13 set (PACKAGE_TARNAME   "${PACKAGE_NAME}-${PACKAGE_VERSION}")
  14 set (PACKAGE_BUGREPORT "https://code.google.com/p/gflags/issues/")
  15
  16 project (${PACKAGE_NAME} CXX)
  17
  18 version_numbers (
  19   ${PACKAGE_VERSION}
  20     PACKAGE_VERSION_MAJOR
  21     PACKAGE_VERSION_MINOR
  22     PACKAGE_VERSION_PATCH
  23 )
  24
  25 # ----------------------------------------------------------------------------
  26 # options
  27 set (GFLAGS_NAMESPACE "${PACKAGE_NAME}" CACHE STRING "C++ namespace identifier of gflags library.")
  28
  29 option (BUILD_SHARED_LIBS          "Request build of shared libraries."                                       OFF)
  30 option (BUILD_STATIC_LIBS          "Request build of static libraries (default if BUILD_SHARED_LIBS is OFF)." OFF)
  31 option (BUILD_gflags_LIB           "Request build of the multi-threaded gflags library."                      ON)
  32 option (BUILD_gflags_nothreads_LIB "Request build of the single-threaded gflags library."                     ON)
  33 option (BUILD_PACKAGING            "Enable build of distribution packages using CPack."                       OFF)
  34 option (BUILD_TESTING              "Enable build of the unit tests and their execution using CTest."          OFF)
  35 option (BUILD_NC_TESTS             "Request addition of negative compilation tests."                          OFF)
  36 option (INSTALL_HEADERS            "Request packaging of headers and other development files."                ON)
  37
  38 mark_as_advanced (CLEAR CMAKE_INSTALL_PREFIX)
  39 mark_as_advanced (CMAKE_CONFIGURATION_TYPES
  40                   GFLAGS_NAMESPACE
  41                   BUILD_STATIC_LIBS
  42                   BUILD_NC_TESTS
  43                   INSTALL_HEADERS)
  44 if (APPLE)
  45   mark_as_advanced(CMAKE_OSX_ARCHITECTURES
  46                    CMAKE_OSX_DEPLOYMENT_TARGET
  47                    CMAKE_OSX_SYSROOT)
  48 endif ()
  49
  50 if (NOT BUILD_SHARED_LIBS AND NOT BUILD_STATIC_LIBS)
  51   set (BUILD_STATIC_LIBS ON)
  52 endif ()
  53 if (NOT BUILD_gflags_LIB AND NOT BUILD_gflags_nothreads_LIB)
  54  message (FATAL_ERROR "At least one of BUILD_gflags_LIB and BUILD_gflags_nothreads_LIB must be ON.")
  55 endif ()
  56
  57 if (NOT CMAKE_BUILD_TYPE AND NOT CMAKE_CXX_FLAGS)
  58   set_property (CACHE CMAKE_BUILD_TYPE PROPERTY VALUE Release)
  59 endif ()
  60
  61 # ----------------------------------------------------------------------------
  62 # system checks
  63 include (CheckTypeSize)
  64 include (CheckIncludeFileCXX)
  65 include (CheckCXXSymbolExists)
  66
  67 if (WIN32 AND NOT CYGWIN)
  68   set (OS_WINDOWS 1)
  69 else ()
  70   set (OS_WINDOWS 0)
  71 endif ()
  72
  73 if (MSVC)
  74   set (HAVE_SYS_TYPES_H 1)
  75   set (HAVE_STDINT_H    1)
  76   set (HAVE_STDDEF_H    1) # used by CheckTypeSize module
  77   set (HAVE_INTTYPES_H  0)
  78   set (HAVE_UNISTD_H    0)
  79   set (HAVE_SYS_STAT_H  1)
  80   set (HAVE_SHLWAPI_H   1)
  81 else ()
  82   foreach (fname IN ITEMS unistd stdint inttypes sys/types sys/stat fnmatch)
  83     string (TOUPPER "${fname}" FNAME)
  84     string (REPLACE "/" "_" FNAME "${FNAME}")
  85     if (NOT HAVE_${FNAME}_H)
  86       check_include_file_cxx ("${fname}.h" HAVE_${FNAME}_H)
  87     endif ()
  88   endforeach ()
  89   # the following are used in #if directives not #ifdef
  90   bool_to_int (HAVE_STDINT_H)
  91   bool_to_int (HAVE_SYS_TYPES_H)
  92   bool_to_int (HAVE_INTTYPES_H)
  93   if (NOT HAVE_FNMATCH_H AND OS_WINDOWS)
  94     check_include_file_cxx ("shlwapi.h" HAVE_SHLWAPI_H)
  95   endif ()
  96 endif ()
  97
  98 set (GFLAGS_INTTYPES_FORMAT "" CACHE STRING "Format of integer types: \"C99\" (uint32_t), \"BSD\" (u_int32_t), \"VC7\" (__int32)")
  99 set_property (CACHE GFLAGS_INTTYPES_FORMAT PROPERTY STRINGS "C99;BSD;VC7")
 100 mark_as_advanced (GFLAGS_INTTYPES_FORMAT)
 101 if (NOT GFLAGS_INTTYPES_FORMAT)
 102   set (TYPES uint32_t u_int32_t)
 103   if (MSVC)
 104     list (INSERT TYPES 0 __int32)
 105   endif ()
 106   foreach (type IN LISTS TYPES)
 107     check_type_size (${type} ${type} LANGUAGE CXX)
 108     if (HAVE_${type})
 109       break ()
 110     endif ()
 111   endforeach ()
 112   if (HAVE_uint32_t)
 113     set_property (CACHE GFLAGS_INTTYPES_FORMAT PROPERTY VALUE C99)
 114   elseif (HAVE_u_int32_t)
 115     set_property (CACHE GFLAGS_INTTYPES_FORMAT PROPERTY VALUE BSD)
 116   elseif (HAVE___int32)
 117     set_property (CACHE GFLAGS_INTTYPES_FORMAT PROPERTY VALUE VC7)
 118   else ()
 119     mark_as_advanced (CLEAR GFLAGS_INTTYPES_FORMAT)
 120     message (FATAL_ERROR "Do not know how to define a 32-bit integer quantity on your system!"
 121                          " Neither uint32_t, u_int32_t, nor __int32 seem to be available."
 122                          " Set GFLAGS_INTTYPES_FORMAT to either C99, BSD, or VC7 and try again.")
 123   endif ()
 124 endif ()
 125 # use of special characters in strings to circumvent bug #0008226
 126 if ("^${GFLAGS_INTTYPES_FORMAT}$" STREQUAL "^WIN$")
 127   set_property (CACHE GFLAGS_INTTYPES_FORMAT PROPERTY VALUE VC7)
 128 endif ()
 129 if (NOT GFLAGS_INTTYPES_FORMAT MATCHES "^(C99|BSD|VC7)$")
 130   message (FATAL_ERROR "Invalid value for GFLAGS_INTTYPES_FORMAT! Choose one of \"C99\", \"BSD\", or \"VC7\"")
 131 endif ()
 132 set (GFLAGS_INTTYPES_FORMAT_C99 0)
 133 set (GFLAGS_INTTYPES_FORMAT_BSD 0)
 134 set (GFLAGS_INTTYPES_FORMAT_VC7 0)
 135 set ("GFLAGS_INTTYPES_FORMAT_${GFLAGS_INTTYPES_FORMAT}" 1)
 136
 137 if (MSVC)
 138   set (HAVE_strtoll 0)
 139   set (HAVE_strtoq  0)
 140 else ()
 141   check_cxx_symbol_exists (strtoll stdlib.h HAVE_STRTOLL)
 142   if (NOT HAVE_STRTOLL)
 143     check_cxx_symbol_exists (strtoq stdlib.h HAVE_STRTOQ)
 144   endif ()
 145 endif ()
 146
 147 set (CMAKE_THREAD_PREFER_PTHREAD TRUE)
 148 find_package (ThreadsCXX)
 149 if (Threads_FOUND AND CMAKE_USE_PTHREADS_INIT)
 150   set (HAVE_PTHREAD 1)
 151   check_type_size (pthread_rwlock_t RWLOCK LANGUAGE CXX)
 152 else ()
 153   set (HAVE_PTHREAD 0)
 154 endif ()
 155
 156 if (UNIX AND NOT HAVE_PTHREAD AND BUILD_gflags_LIB)
 157   if (CMAKE_HAVE_PTHREAD_H)
 158     set (what "library")
 159   else ()
 160     set (what ".h file")
 161   endif ()
 162   message (FATAL_ERROR "Could not find pthread${what}. Check the log file"
 163                        "\n\t${CMAKE_BINARY_DIR}${CMAKE_FILES_DIRECTORY}/CMakeError.log"
 164                        "\nor disable the build of the multi-threaded gflags library (BUILD_gflags_LIB=OFF).")
 165 endif ()
 166
 167 # ----------------------------------------------------------------------------
 168 # source files - excluding root subdirectory and/or .in suffix
 169 set (PUBLIC_HDRS
 170   "gflags.h"
 171   "gflags_declare.h"
 172   "gflags_completions.h"
 173 )
 174
 175 set (PRIVATE_HDRS
 176   "config.h"
 177   "util.h"
 178   "mutex.h"
 179 )
 180
 181 set (GFLAGS_SRCS
 182   "gflags.cc"
 183   "gflags_reporting.cc"
 184   "gflags_completions.cc"
 185 )
 186
 187 if (OS_WINDOWS)
 188   list (APPEND PRIVATE_HDRS "windows_port.h")
 189   list (APPEND GFLAGS_SRCS  "windows_port.cc")
 190 endif ()
 191
 192 # ----------------------------------------------------------------------------
 193 # configure source files
 194 if (CMAKE_COMPILER_IS_GNUCXX)
 195   set (GFLAGS_ATTRIBUTE_UNUSED "__attribute((unused))")
 196 else ()
 197   set (GFLAGS_ATTRIBUTE_UNUSED)
 198 endif ()
 199
 200 configure_headers (PUBLIC_HDRS  ${PUBLIC_HDRS})
 201 configure_sources (PRIVATE_HDRS ${PRIVATE_HDRS})
 202 configure_sources (GFLAGS_SRCS  ${GFLAGS_SRCS})
 203
 204 include_directories ("${PROJECT_SOURCE_DIR}/src")
 205 include_directories ("${PROJECT_BINARY_DIR}/include")
 206 include_directories ("${PROJECT_BINARY_DIR}/include/${GFLAGS_NAMESPACE}")
 207
 208 # ----------------------------------------------------------------------------
 209 # output directories
 210 set (CMAKE_RUNTIME_OUTPUT_DIRECTORY "bin")
 211 set (CMAKE_LIBRARY_OUTPUT_DIRECTORY "lib")
 212 set (CMAKE_ARCHIVE_OUTPUT_DIRECTORY "lib")
 213
 214 # ----------------------------------------------------------------------------
 215 # add library targets
 216 set (TARGETS)
 217 # static vs. shared
 218 foreach (TYPE IN ITEMS STATIC SHARED)
 219   if (BUILD_${TYPE}_LIBS)
 220     # whether or not targets are a DLL
 221     if (OS_WINDOWS AND "^${TYPE}$" STREQUAL "^SHARED$")
 222       set (GFLAGS_IS_A_DLL 1)
 223     else ()
 224       set (GFLAGS_IS_A_DLL 0)
 225     endif ()
 226     string (TOLOWER "${TYPE}" type)
 227     # multi-threaded vs. single-threaded
 228     foreach (opts IN ITEMS "" _nothreads)
 229       if (BUILD_gflags${opts}_LIB)
 230         add_library (gflags${opts}-${type} ${TYPE} ${GFLAGS_SRCS} ${PRIVATE_HDRS} ${PUBLIC_HDRS})
 231         if (opts MATCHES "nothreads")
 232           set (defines "GFLAGS_IS_A_DLL=${GFLAGS_IS_A_DLL};NOTHREADS")
 233         else ()
 234           set (defines "GFLAGS_IS_A_DLL=${GFLAGS_IS_A_DLL}")
 235         endif ()
 236         set_target_properties (
 237           gflags${opts}-${type} PROPERTIES COMPILE_DEFINITIONS "${defines}"
 238                                            OUTPUT_NAME "gflags${opts}"
 239         )
 240         if (HAVE_SHLWAPI_H)
 241           target_link_libraries (gflags${opts}-${type} shlwapi.lib)
 242         endif ()
 243         if (NOT TARGET gflags${opts})
 244           add_custom_target (gflags${opts})
 245         endif ()
 246         add_dependencies (gflags${opts} gflags${opts}-${type})
 247         list (APPEND TARGETS gflags${opts}-${type})
 248       endif ()
 249     endforeach ()
 250   endif ()
 251 endforeach ()
 252
 253 # ----------------------------------------------------------------------------
 254 # installation
 255 if (OS_WINDOWS)
 256   set (RUNTIME_INSTALL_DIR Bin)
 257   set (LIBRARY_INSTALL_DIR Lib)
 258   set (INCLUDE_INSTALL_DIR Include)
 259   set (CONFIG_INSTALL_DIR  CMake)
 260 else ()
 261   set (RUNTIME_INSTALL_DIR bin)
 262   set (LIBRARY_INSTALL_DIR lib)
 263   set (INCLUDE_INSTALL_DIR include)
 264   set (CONFIG_INSTALL_DIR  lib/cmake/${PACKAGE_NAME})
 265 endif ()
 266
 267 file (RELATIVE_PATH INSTALL_PREFIX_REL2CONFIG_DIR "${CMAKE_INSTALL_PREFIX}/${CONFIG_INSTALL_DIR}" "${CMAKE_INSTALL_PREFIX}")
 268 configure_file (cmake/config.cmake.in  "${PROJECT_BINARY_DIR}/${PACKAGE_NAME}-config-install.cmake" @ONLY)
 269 configure_file (cmake/version.cmake.in "${PROJECT_BINARY_DIR}/${PACKAGE_NAME}-config-version.cmake" @ONLY)
 270
 271 install (TARGETS ${TARGETS} DESTINATION ${LIBRARY_INSTALL_DIR} EXPORT gflags-lib)
 272 if (INSTALL_HEADERS)
 273   install (FILES ${PUBLIC_HDRS} DESTINATION ${INCLUDE_INSTALL_DIR}/${GFLAGS_NAMESPACE})
 274   install (
 275     FILES "${PROJECT_BINARY_DIR}/${PACKAGE_NAME}-config-install.cmake"
 276     RENAME ${PACKAGE_NAME}-config.cmake
 277     DESTINATION ${CONFIG_INSTALL_DIR}
 278   )
 279   install (
 280     FILES "${PROJECT_BINARY_DIR}/${PACKAGE_NAME}-config-version.cmake"
 281     DESTINATION ${CONFIG_INSTALL_DIR}
 282   )
 283   install (EXPORT gflags-lib DESTINATION ${CONFIG_INSTALL_DIR} FILE ${PACKAGE_NAME}-export.cmake)
 284   if (UNIX)
 285     install (PROGRAMS src/gflags_completions.sh DESTINATION ${RUNTIME_INSTALL_DIR})
 286   endif ()
 287 endif ()
 288
 289 # ----------------------------------------------------------------------------
 290 # support direct use of build tree
 291 set (INSTALL_PREFIX_REL2CONFIG_DIR .)
 292 export (TARGETS ${TARGETS} FILE "${PROJECT_BINARY_DIR}/${PACKAGE_NAME}-export.cmake")
 293 export (PACKAGE gflags)
 294 configure_file (cmake/config.cmake.in "${PROJECT_BINARY_DIR}/${PACKAGE_NAME}-config.cmake" @ONLY)
 295
 296 # ----------------------------------------------------------------------------
 297 # testing - MUST follow the generation of the build tree config file
 298 if (BUILD_TESTING)
 299   include (CTest)
 300   enable_testing ()
 301   add_subdirectory (test)
 302 endif ()
 303
 304 # ----------------------------------------------------------------------------
 305 # packaging
 306 if (BUILD_PACKAGING)
 307
 308   if (NOT BUILD_SHARED_LIBS AND NOT INSTALL_HEADERS)
 309     message (WARNING "Package will contain static libraries without headers!"
 310                      "\nRecommended options for generation of runtime package:"
 311                      "\n  BUILD_SHARED_LIBS=ON"
 312                      "\n  BUILD_STATIC_LIBS=OFF"
 313                      "\n  INSTALL_HEADERS=OFF"
 314                      "\nRecommended options for generation of development package:"
 315                      "\n  BUILD_SHARED_LIBS=ON"
 316                      "\n  BUILD_STATIC_LIBS=ON"
 317                      "\n  INSTALL_HEADERS=ON")
 318   endif ()
 319
 320   # default package generators
 321   if (APPLE)
 322     set (PACKAGE_GENERATOR        "PackageMaker")
 323     set (PACKAGE_SOURCE_GENERATOR "TGZ;ZIP")
 324   elseif (UNIX)
 325     set (PACKAGE_GENERATOR        "DEB;RPM")
 326     set (PACKAGE_SOURCE_GENERATOR "TGZ;ZIP")
 327   else ()
 328     set (PACKAGE_GENERATOR        "ZIP")
 329     set (PACKAGE_SOURCE_GENERATOR "ZIP")
 330   endif ()
 331
 332   # used package generators
 333   set (CPACK_GENERATOR        "${PACKAGE_GENERATOR}"        CACHE STRING "List of binary package generators (CPack).")
 334   set (CPACK_SOURCE_GENERATOR "${PACKAGE_SOURCE_GENERATOR}" CACHE STRING "List of source package generators (CPack).")
 335   mark_as_advanced (CPACK_GENERATOR CPACK_SOURCE_GENERATOR)
 336
 337   # common package information
 338   set (CPACK_PACKAGE_VENDOR              "Open Source by Andreas Schuh")
 339   set (CPACK_PACKAGE_CONTACT             "google-gflags@googlegroups.com")
 340   set (CPACK_PACKAGE_NAME                "${PACKAGE_NAME}")
 341   set (CPACK_PACKAGE_VERSION             "${PACKAGE_VERSION}")
 342   set (CPACK_PACKAGE_VERSION_MAJOR       "${PACKAGE_VERSION_MAJOR}")
 343   set (CPACK_PACKAGE_VERSION_MINOR       "${PACKAGE_VERSION_MINOR}")
 344   set (CPACK_PACKAGE_VERSION_PATCH       "${PACKAGE_VERSION_PATCH}")
 345   set (CPACK_PACKAGE_DESCRIPTION_SUMMARY "A commandline flags library that allows for distributed flags.")
 346   set (CPACK_RESOURCE_FILE_WELCOME       "${CMAKE_CURRENT_LIST_DIR}/README.txt")
 347   set (CPACK_RESOURCE_FILE_LICENSE       "${CMAKE_CURRENT_LIST_DIR}/COPYING.txt")
 348   set (CPACK_PACKAGE_DESCRIPTION_FILE    "${CMAKE_CURRENT_LIST_DIR}/INSTALL.txt")
 349   set (CPACK_INSTALL_PREFIX              "${CMAKE_INSTALL_PREFIX}")
 350   set (CPACK_OUTPUT_FILE_PREFIX          packages)
 351   set (CPACK_PACKAGE_RELOCATABLE         TRUE)
 352   set (CPACK_MONOLITHIC_INSTALL          TRUE)
 353
 354   if (INSTALL_HEADERS)
 355     set (CPACK_RESOURCE_FILE_README "${CMAKE_CURRENT_LIST_DIR}/doc/gflags.html")
 356   else ()
 357     set (CPACK_RESOURCE_FILE_README "${CMAKE_CURRENT_LIST_DIR}/cmake/README_runtime.txt")
 358   endif ()
 359
 360   # system name used for binary package file name
 361   if (WINDOWS)
 362     if (CMAKE_CL_64)
 363       set (CPACK_SYSTEM_NAME "win64")
 364     else ()
 365       set (CPACK_SYSTEM_NAME "win32")
 366     endif ()
 367   else ()
 368     string (TOLOWER "${CMAKE_SYSTEM_NAME}" CPACK_SYSTEM_NAME)
 369   endif ()
 370
 371   # source package settings
 372   set (CPACK_SOURCE_TOPLEVEL_TAG      "source")
 373   set (CPACK_SOURCE_PACKAGE_FILE_NAME "${CPACK_PACKAGE_NAME}-${CPACK_PACKAGE_VERSION}")
 374   set (CPACK_SOURCE_IGNORE_FILES      "/\\\\.git/;\\\\.swp$;\\\\.#;/#;\\\\.*~;cscope\\\\.*;/[Bb]uild[.+-_a-zA-Z0-9]*/")
 375
 376   # default binary package settings
 377   set (CPACK_INCLUDE_TOPLEVEL_DIRECTORY  TRUE)
 378   set (CPACK_PACKAGE_FILE_NAME           "${CPACK_PACKAGE_NAME}-${CPACK_PACKAGE_VERSION}-${CPACK_SYSTEM_NAME}")
 379   if (CMAKE_SYSTEM_PROCESSOR)
 380     set (CPACK_PACKAGE_FILE_NAME         "${CPACK_PACKAGE_FILE_NAME}-${CMAKE_SYSTEM_PROCESSOR}")
 381   endif ()
 382
 383   # generator specific configuration file
 384   #
 385   # allow package maintainers to use their own configuration file
 386   # $ cmake -DCPACK_PROJECT_CONFIG_FILE:FILE=/path/to/package/config
 387   if (NOT CPACK_PROJECT_CONFIG_FILE)
 388     configure_file (
 389       "${CMAKE_CURRENT_LIST_DIR}/cmake/package.cmake.in"
 390       "${PROJECT_BINARY_DIR}/${PACKAGE_NAME}-package.cmake" @ONLY
 391     )
 392     set (CPACK_PROJECT_CONFIG_FILE "${PROJECT_BINARY_DIR}/${PACKAGE_NAME}-package.cmake")
 393   endif ()
 394
 395   include (CPack)
 396
 397 endif () # BUILD_PACKAGING