CMakeLists.txt

   1 # ~~~
   2 # Copyright (c) 2014-2018 Valve Corporation
   3 # Copyright (c) 2014-2018 LunarG, Inc.
   4 #
   5 # Licensed under the Apache License, Version 2.0 (the "License");
   6 # you may not use this file except in compliance with the License.
   7 # You may obtain a copy of the License at
   8 #
   9 #     http://www.apache.org/licenses/LICENSE-2.0
  10 #
  11 # Unless required by applicable law or agreed to in writing, software
  12 # distributed under the License is distributed on an "AS IS" BASIS,
  13 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  14 # See the License for the specific language governing permissions and
  15 # limitations under the License.
  16 # ~~~
  17
  18 # CMake project initialization ---------------------------------------------------------------------------------------------------
  19 # This section contains pre-project() initialization, and ends with the project() command.
  20
  21 cmake_minimum_required(VERSION 3.10.2)
  22
  23 # Apple: Must be set before enable_language() or project() as it may influence configuration of the toolchain and flags.
  24 set(CMAKE_OSX_DEPLOYMENT_TARGET "10.12" CACHE STRING "Minimum OS X deployment version")
  25
  26 project(Vulkan-Tools)
  27
  28 # find_package(), include() and global project settings --------------------------------------------------------------------------
  29
  30 find_package(PythonInterp 3 QUIET)
  31
  32 # User-interface declarations ----------------------------------------------------------------------------------------------------
  33 # This section contains variables that affect development GUIs (e.g. CMake GUI and IDEs), such as option(), folders, and variables
  34 # with the CACHE property.
  35
  36 # Enable beta Vulkan extensions
  37 add_definitions(-DVK_ENABLE_BETA_EXTENSIONS)
  38
  39 set(CMAKE_MODULE_PATH ${CMAKE_MODULE_PATH} "${CMAKE_CURRENT_SOURCE_DIR}/cmake")
  40
  41 option(BUILD_CUBE "Build cube" ON)
  42 option(BUILD_VULKANINFO "Build vulkaninfo" ON)
  43 option(BUILD_ICD "Build icd" ON)
  44 # Installing the Mock ICD to system directories is probably not desired since this ICD is not a very complete implementation.
  45 # Require the user to ask that it be installed if they really want it.
  46 option(INSTALL_ICD "Install icd" OFF)
  47
  48 # Enable IDE GUI folders
  49 set_property(GLOBAL PROPERTY USE_FOLDERS ON)
  50 # "Helper" targets that don't have interesting source code should set their FOLDER property to this
  51 set(TOOLS_HELPER_FOLDER "Helper Targets")
  52
  53 option(USE_CCACHE "Use ccache" OFF)
  54 if(USE_CCACHE)
  55     find_program(CCACHE_FOUND ccache)
  56     if(CCACHE_FOUND)
  57         set_property(GLOBAL PROPERTY RULE_LAUNCH_COMPILE ccache)
  58     endif()
  59 endif()
  60
  61 # ~~~
  62 # Find Vulkan Headers and Loader
  63 # Search order:
  64 #  User-supplied CMAKE_PREFIX_PATH containing paths to the header and/or loader install dirs
  65 #  CMake options VULKAN_HEADERS_INSTALL_DIR and/or VULKAN_LOADER_INSTALL_DIR
  66 #  Env vars VULKAN_HEADERS_INSTALL_DIR and/or VULKAN_LOADER_INSTALL_DIR
  67 #  If on MacOS
  68 #   CMake option MOTLENVK_REPO_ROOT
  69 #   Env vars MOLTENVK_REPO_ROOT
  70 #  Fallback to FindVulkan operation using SDK install or system installed components.
  71 # ~~~
  72 set(VULKAN_HEADERS_INSTALL_DIR "HEADERS-NOTFOUND" CACHE PATH "Absolute path to a Vulkan-Headers install directory")
  73 set(VULKAN_LOADER_INSTALL_DIR "LOADER-NOTFOUND" CACHE PATH "Absolute path to a Vulkan-Loader install directory")
  74 if(WIN32 AND "${VULKAN_LOADER_INSTALL_DIR}" STREQUAL "LOADER-NOTFOUND")
  75     if(CMAKE_CL_64)
  76         set(VULKAN_LOADER_INSTALL_DIR "${CMAKE_CURRENT_SOURCE_DIR}/external/x64")
  77     else()
  78         set(VULKAN_LOADER_INSTALL_DIR "${CMAKE_CURRENT_SOURCE_DIR}/external/x86")
  79     endif()
  80 endif()
  81 set(CMAKE_PREFIX_PATH ${CMAKE_PREFIX_PATH};${VULKAN_HEADERS_INSTALL_DIR};${VULKAN_LOADER_INSTALL_DIR};
  82     $ENV{VULKAN_HEADERS_INSTALL_DIR};$ENV{VULKAN_LOADER_INSTALL_DIR})
  83
  84 if(APPLE)
  85     set(MOLTENVK_REPO_ROOT "MOLTENVK-NOTFOUND" CACHE PATH "Absolute path to a MoltenVK repo directory")
  86     if(NOT MOLTENVK_REPO_ROOT AND NOT DEFINED ENV{MOLTENVK_REPO_ROOT})
  87         message(FATAL_ERROR "Must define location of MoltenVK repo -- see BUILD.md")
  88     endif()
  89
  90     if(NOT MOLTENVK_REPO_ROOT)
  91         set(MOLTENVK_REPO_ROOT $ENV{MOLTENVK_REPO_ROOT})
  92     endif()
  93     message(STATUS "Using MoltenVK repo location at ${MOLTENVK_REPO_ROOT}")
  94 endif()
  95 message(STATUS "Using find_package to locate Vulkan")
  96 find_package(Vulkan)
  97 find_package(VulkanHeaders)
  98 get_filename_component(Vulkan_LIBRARY_DIR ${Vulkan_LIBRARY} DIRECTORY)
  99 message(STATUS "Vulkan FOUND = ${Vulkan_FOUND}")
 100 message(STATUS "Vulkan Lib Dir = ${Vulkan_LIBRARY_DIR}")
 101 message(STATUS "Vulkan Lib = ${Vulkan_LIBRARY}")
 102 message(STATUS "Vulkan Headers Include = ${VulkanHeaders_INCLUDE_DIR}")
 103 message(STATUS "Vulkan Headers Registry = ${VulkanRegistry_DIR}")
 104
 105 include(GNUInstallDirs)
 106
 107 if(WIN32 AND CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 108     # Windows: if install locations not set by user, set install prefix to "<build_dir>\install".
 109     set(CMAKE_INSTALL_PREFIX "${CMAKE_BINARY_DIR}/install" CACHE PATH "default install path" FORCE)
 110 endif()
 111
 112 # uninstall target
 113 if(NOT TARGET uninstall)
 114     configure_file("${CMAKE_CURRENT_SOURCE_DIR}/cmake/cmake_uninstall.cmake.in"
 115                    "${CMAKE_CURRENT_BINARY_DIR}/cmake_uninstall.cmake"
 116                    IMMEDIATE
 117                    @ONLY)
 118
 119     add_custom_target(uninstall COMMAND ${CMAKE_COMMAND} -P ${CMAKE_CURRENT_BINARY_DIR}/cmake_uninstall.cmake)
 120     set_target_properties(uninstall PROPERTIES FOLDER ${TOOLS_HELPER_FOLDER})
 121 endif()
 122
 123 if(APPLE)
 124     # CMake versions 3 or later need CMAKE_MACOSX_RPATH defined. This avoids the CMP0042 policy message.
 125     set(CMAKE_MACOSX_RPATH 1)
 126 endif()
 127
 128 if(CMAKE_COMPILER_IS_GNUCC OR CMAKE_C_COMPILER_ID MATCHES "Clang")
 129     set(COMMON_COMPILE_FLAGS "-Wall -Wextra -Wno-unused-parameter -Wno-missing-field-initializers")
 130     set(COMMON_COMPILE_FLAGS "${COMMON_COMPILE_FLAGS} -fno-strict-aliasing -fno-builtin-memcmp")
 131
 132     # For GCC version 7.1 or greater, we need to disable the implicit fallthrough warning since there's no consistent way to satisfy
 133     # all compilers until they all accept the C++17 standard
 134     if(CMAKE_COMPILER_IS_GNUCC AND NOT (CMAKE_CXX_COMPILER_VERSION LESS 7.1))
 135         set(COMMON_COMPILE_FLAGS "${COMMON_COMPILE_FLAGS} -Wimplicit-fallthrough=0")
 136     endif()
 137
 138     if(APPLE)
 139         set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} ${COMMON_COMPILE_FLAGS}")
 140     else()
 141         set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -std=c99 ${COMMON_COMPILE_FLAGS}")
 142     endif()
 143     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} ${COMMON_COMPILE_FLAGS} -std=c++11 -fno-rtti")
 144     if(UNIX)
 145         set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -fvisibility=hidden")
 146         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -fvisibility=hidden")
 147     endif()
 148 endif()
 149
 150 # Optional codegen target
 151 if(PYTHONINTERP_FOUND)
 152     add_custom_target(VulkanTools_generated_source
 153                       COMMAND ${PYTHON_EXECUTABLE} ${PROJECT_SOURCE_DIR}/scripts/generate_source.py
 154                               ${VulkanRegistry_DIR} --incremental
 155                       )
 156 else()
 157     message("WARNING: VulkanTools_generated_source target requires python 3")
 158 endif()
 159
 160 if(APPLE)
 161     include(mac_common.cmake)
 162 endif()
 163
 164 if(BUILD_CUBE)
 165     add_subdirectory(cube)
 166 endif()
 167
 168 if(BUILD_VULKANINFO)
 169     add_subdirectory(vulkaninfo)
 170 endif()
 171
 172 if(BUILD_ICD)
 173     add_subdirectory(icd)
 174 endif()